qcsrc/client/view.qc

   1 #if defined(CSQC)
   2         #include "../dpdefs/csprogsdefs.qh"
   3         #include "defs.qh"
   4         #include "../common/constants.qh"
   5         #include "../common/stats.qh"
   6         #include "../warpzonelib/mathlib.qh"
   7         #include "../warpzonelib/common.qh"
   8         #include "../warpzonelib/client.qh"
   9         #include "../common/teams.qh"
  10         #include "../common/util.qh"
  11         #include "../common/nades.qh"
  12         #include "../common/weapons/weapons.qh"
  13         #include "../common/mapinfo.qh"
  14         #include "autocvars.qh"
  15         #include "hud.qh"
  16         #include "scoreboard.qh"
  17         #include "noise.qh"
  18         #include "main.qh"
  19         #include "../csqcmodellib/cl_player.qh"
  20 #elif defined(MENUQC)
  21 #elif defined(SVQC)
  22 #endif
  23
  24 entity porto;
  25 vector polyline[16];
  26 void Porto_Draw()
  27 {
  28         vector p, dir, ang, q, nextdir;
  29         float portal_number, portal1_idx;
  30
  31         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  32                 return;
  33         if(g_balance_porto_secondary)
  34                 return;
  35         if(intermission == 1)
  36                 return;
  37         if(intermission == 2)
  38                 return;
  39         if (getstati(STAT_HEALTH) <= 0)
  40                 return;
  41
  42         dir = view_forward;
  43
  44         if(angles_held_status)
  45         {
  46                 makevectors(angles_held);
  47                 dir = v_forward;
  48         }
  49
  50         p = view_origin;
  51
  52         polyline[0] = p;
  53         int idx = 1;
  54         portal_number = 0;
  55         nextdir = dir;
  56
  57         for (;;)
  58         {
  59                 dir = nextdir;
  60                 traceline(p, p + 65536 * dir, true, porto);
  61                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  62                         return;
  63                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  64                 p = trace_endpos;
  65                 polyline[idx] = p;
  66                 ++idx;
  67                 if(idx >= 16)
  68                         return;
  69                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  70                         continue;
  71                 ++portal_number;
  72                 ang = vectoangles2(trace_plane_normal, dir);
  73                 ang.x = -ang.x;
  74                 makevectors(ang);
  75                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  76                         return;
  77                 if(portal_number == 1)
  78                 {
  79                         portal1_idx = idx;
  80                         if(portal_number >= 2)
  81                                 break;
  82                 }
  83         }
  84
  85         while(idx >= 2)
  86         {
  87                 p = polyline[idx-2];
  88                 q = polyline[idx-1];
  89                 if(idx == 2)
  90                         p = p - view_up * 16;
  91                 if(idx-1 >= portal1_idx)
  92                 {
  93                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  94                 }
  95                 else
  96                 {
  97                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
  98                 }
  99                 --idx;
 100         }
 101 }
 102
 103 void Porto_Init()
 104 {
 105         porto = spawn();
 106         porto.classname = "porto";
 107         porto.draw = Porto_Draw;
 108         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 109 }
 110
 111 float drawtime;
 112 float avgspeed;
 113 vector GetCurrentFov(float fov)
 114 {
 115         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 116         float velocityzoom, curspeed;
 117         vector v;
 118
 119         zoomsensitivity = autocvar_cl_zoomsensitivity;
 120         zoomfactor = autocvar_cl_zoomfactor;
 121         if(zoomfactor < 1 || zoomfactor > 16)
 122                 zoomfactor = 2.5;
 123         zoomspeed = autocvar_cl_zoomspeed;
 124         if(zoomspeed >= 0)
 125         if(zoomspeed < 0.5 || zoomspeed > 16)
 126                         zoomspeed = 3.5;
 127
 128         zoomdir = button_zoom;
 129         if(hud == HUD_NORMAL)
 130         if((activeweapon == WEP_VORTEX && vortex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 131                 zoomdir += button_attack2;
 132         if(spectatee_status > 0 || isdemo())
 133         {
 134                 if(spectatorbutton_zoom)
 135                 {
 136                         if(zoomdir)
 137                                 zoomdir = 0;
 138                         else
 139                                 zoomdir = 1;
 140                 }
 141                 // fteqcc failed twice here already, don't optimize this
 142         }
 143
 144         if(zoomdir) { zoomin_effect = 0; }
 145
 146         if(camera_active)
 147         {
 148                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 149         }
 150         else if(autocvar_cl_spawnzoom && zoomin_effect)
 151         {
 152                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 153
 154                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 155                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 156                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 157         }
 158         else
 159         {
 160                 if(zoomspeed < 0) // instant zoom
 161                 {
 162                         if(zoomdir)
 163                                 current_viewzoom = 1 / zoomfactor;
 164                         else
 165                                 current_viewzoom = 1;
 166                 }
 167                 else
 168                 {
 169                         if(zoomdir)
 170                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 171                         else
 172                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 173                 }
 174         }
 175
 176         if(almost_equals(current_viewzoom, 1))
 177                 current_zoomfraction = 0;
 178         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 179                 current_zoomfraction = 1;
 180         else
 181                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 182
 183         if(zoomsensitivity < 1)
 184                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 185         else
 186                 setsensitivityscale(1);
 187
 188         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 189         {
 190                 if(intermission) { curspeed = 0; }
 191                 else
 192                 {
 193
 194                         makevectors(view_angles);
 195                         v = pmove_vel;
 196                         if(csqcplayer)
 197                                 v = csqcplayer.velocity;
 198
 199                         switch(autocvar_cl_velocityzoom_type)
 200                         {
 201                                 case 3: curspeed = max(0, v_forward * v); break;
 202                                 case 2: curspeed = (v_forward * v); break;
 203                                 case 1: default: curspeed = vlen(v); break;
 204                         }
 205                 }
 206
 207                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 208                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 209                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 210
 211                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 212         }
 213         else
 214                 velocityzoom = 1;
 215
 216         float frustumx, frustumy, fovx, fovy;
 217         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 218         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 219         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 220         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 221
 222         return '1 0 0' * fovx + '0 1 0' * fovy;
 223 }
 224
 225 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 226 {
 227         float fovx, fovy;
 228         float width = (ov_worldmax.x - ov_worldmin.x);
 229         float height = (ov_worldmax.y - ov_worldmin.y);
 230         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 231         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 232         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 233         return '1 0 0' * fovx + '0 1 0' * fovy;
 234 }
 235
 236 // this function must match W_SetupShot!
 237 float zoomscript_caught;
 238
 239 vector wcross_origin;
 240 float wcross_scale_prev, wcross_alpha_prev;
 241 vector wcross_color_prev;
 242 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 243 vector wcross_color_goal_prev;
 244 float wcross_changedonetime;
 245
 246 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 247 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 248 float wcross_name_changestarttime, wcross_name_changedonetime;
 249 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 250
 251 float wcross_ring_prev;
 252
 253 entity trueaim;
 254 entity trueaim_rifle;
 255
 256 const float SHOTTYPE_HITTEAM = 1;
 257 const float SHOTTYPE_HITOBSTRUCTION = 2;
 258 const float SHOTTYPE_HITWORLD = 3;
 259 const float SHOTTYPE_HITENEMY = 4;
 260
 261 void TrueAim_Init()
 262 {
 263         trueaim = spawn();
 264         trueaim.classname = "trueaim";
 265         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 266         trueaim_rifle = spawn();
 267         trueaim_rifle.classname = "trueaim_rifle";
 268         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 269 }
 270
 271 float EnemyHitCheck()
 272 {
 273         float t, n;
 274         wcross_origin = project_3d_to_2d(trace_endpos);
 275         wcross_origin.z = 0;
 276         if(trace_ent)
 277                 n = trace_ent.entnum;
 278         else
 279                 n = trace_networkentity;
 280         if(n < 1)
 281                 return SHOTTYPE_HITWORLD;
 282         if(n > maxclients)
 283                 return SHOTTYPE_HITWORLD;
 284         t = GetPlayerColor(n - 1);
 285         if(teamplay)
 286                 if(t == myteam)
 287                         return SHOTTYPE_HITTEAM;
 288         if(t == NUM_SPECTATOR)
 289                 return SHOTTYPE_HITWORLD;
 290         return SHOTTYPE_HITENEMY;
 291 }
 292
 293 float TrueAimCheck()
 294 {
 295         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 296         vector vecs, trueaimpoint, w_shotorg;
 297         vector mi, ma, dv;
 298         float shottype;
 299         entity ta;
 300         float mv;
 301
 302         mi = ma = '0 0 0';
 303         ta = trueaim;
 304         mv = MOVE_NOMONSTERS;
 305
 306         switch(activeweapon) // WEAPONTODO
 307         {
 308                 case WEP_TUBA: // no aim
 309                 case WEP_PORTO: // shoots from eye
 310                 case WEP_HOOK: // no trueaim
 311                 case WEP_MORTAR: // toss curve
 312                         return SHOTTYPE_HITWORLD;
 313                 case WEP_VORTEX:
 314                 case WEP_VAPORIZER:
 315                         mv = MOVE_NORMAL;
 316                         break;
 317                 case WEP_RIFLE:
 318                         ta = trueaim_rifle;
 319                         mv = MOVE_NORMAL;
 320                         if(zoomscript_caught)
 321                         {
 322                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 323                                 return EnemyHitCheck();
 324                         }
 325                         break;
 326                 case WEP_DEVASTATOR: // projectile has a size!
 327                         mi = '-3 -3 -3';
 328                         ma = '3 3 3';
 329                         break;
 330                 case WEP_FIREBALL: // projectile has a size!
 331                         mi = '-16 -16 -16';
 332                         ma = '16 16 16';
 333                         break;
 334                 case WEP_SEEKER: // projectile has a size!
 335                         mi = '-2 -2 -2';
 336                         ma = '2 2 2';
 337                         break;
 338                 case WEP_ELECTRO: // projectile has a size!
 339                         mi = '0 0 -3';
 340                         ma = '0 0 -3';
 341                         break;
 342         }
 343
 344         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 345
 346         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 347
 348         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 349         trueaimpoint = trace_endpos;
 350
 351         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 352                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 353
 354         if(vecs.x > 0)
 355                 vecs.y = -vecs.y;
 356         else
 357                 vecs = '0 0 0';
 358
 359         dv = view_right * vecs.y + view_up * vecs.z;
 360         w_shotorg = traceorigin + dv;
 361
 362         // now move the vecs forward as much as requested if possible
 363         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 364         w_shotorg = trace_endpos - view_forward * nudge;
 365
 366         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 367         shottype = EnemyHitCheck();
 368         if(shottype != SHOTTYPE_HITWORLD)
 369                 return shottype;
 370
 371 #if 0
 372         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 373         // or rather, I know why, but see no fix
 374         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 375                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 376                 return SHOTTYPE_HITOBSTRUCTION;
 377 #endif
 378
 379         return SHOTTYPE_HITWORLD;
 380 }
 381
 382 void CSQC_common_hud(void);
 383
 384 void PostInit(void);
 385 void CSQC_Demo_Camera();
 386 float HUD_WouldDrawScoreboard();
 387 float camera_mode;
 388 const float CAMERA_FREE = 1;
 389 const float CAMERA_CHASE = 2;
 390 float reticle_type;
 391 string reticle_image;
 392 string NextFrameCommand;
 393 void CSQC_SPIDER_HUD();
 394 void CSQC_RAPTOR_HUD();
 395
 396 vector freeze_org, freeze_ang;
 397 entity nightvision_noise, nightvision_noise2;
 398
 399 const float MAX_TIME_DIFF = 5;
 400 float pickup_crosshair_time, pickup_crosshair_size;
 401 float hitindication_crosshair_size;
 402 float use_vortex_chargepool;
 403
 404 float myhealth, myhealth_prev;
 405 float myhealth_flash;
 406
 407 float old_blurradius, old_bluralpha;
 408 float old_sharpen_intensity;
 409
 410 vector myhealth_gentlergb;
 411
 412 float contentavgalpha, liquidalpha_prev;
 413 vector liquidcolor_prev;
 414
 415 float eventchase_current_distance;
 416 float eventchase_running;
 417 float WantEventchase()
 418 {
 419         if(autocvar_cl_orthoview)
 420                 return false;
 421         if(intermission)
 422                 return true;
 423         if(spectatee_status >= 0)
 424         {
 425                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO)))
 426                         return true;
 427                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 428                 {
 429                         if(autocvar_cl_eventchase_death == 2)
 430                         {
 431                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 432                                 if(self.velocity == '0 0 0' || eventchase_running)
 433                                         return true;
 434                         }
 435                         else return true;
 436                 }
 437         }
 438         return false;
 439 }
 440
 441 vector damage_blurpostprocess, content_blurpostprocess;
 442
 443 float checkfail[16];
 444
 445 float unaccounted_damage = 0;
 446 void UpdateDamage()
 447 {
 448         // accumulate damage with each stat update
 449         static float damage_total_prev = 0;
 450         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 451         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 452         damage_total_prev = damage_total;
 453
 454         static float damage_dealt_time_prev = 0;
 455         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 456         if (damage_dealt_time != damage_dealt_time_prev)
 457         {
 458                 unaccounted_damage += unaccounted_damage_new;
 459                 dprint("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 460         }
 461         damage_dealt_time_prev = damage_dealt_time;
 462
 463         // prevent hitsound when switching spectatee
 464         static float spectatee_status_prev = 0;
 465         if (spectatee_status != spectatee_status_prev)
 466                 unaccounted_damage = 0;
 467         spectatee_status_prev = spectatee_status;
 468 }
 469
 470 void UpdateHitsound()
 471 {
 472         // varying sound pitch
 473
 474         static float hitsound_time_prev = 0;
 475         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 476         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 477         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 478         {
 479                 if (autocvar_cl_hitsound && unaccounted_damage)
 480                 {
 481                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 482                         float a = autocvar_cl_hitsound_max_pitch;
 483                         float b = autocvar_cl_hitsound_min_pitch;
 484                         float c = autocvar_cl_hitsound_nom_damage;
 485                         float x = unaccounted_damage;
 486                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 487
 488                         // if sound variation is disabled, set pitch_shift to 1
 489                         if (autocvar_cl_hitsound == 1)
 490                                 pitch_shift = 1;
 491
 492                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 493                         if (autocvar_cl_hitsound == 3)
 494                         {
 495                                 float mirror_value = (a-b)/2 + b;
 496                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 497                         }
 498
 499                         dprint("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 500
 501                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 502                         // todo: normalize sound pressure levels? seems unnecessary
 503
 504                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 505                 }
 506                 unaccounted_damage = 0;
 507                 hitsound_time_prev = time;
 508         }
 509
 510         static float typehit_time_prev = 0;
 511         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 512         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 513         {
 514                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 515                 typehit_time_prev = typehit_time;
 516         }
 517 }
 518
 519 void UpdateCrosshair()
 520 {
 521         static float rainbow_last_flicker;
 522     static vector rainbow_prev_color;
 523         entity e = self;
 524         float f, i, j;
 525         vector v;
 526         if(getstati(STAT_FROZEN))
 527                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 528         else if (getstatf(STAT_HEALING_ORB)>time)
 529                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
 530         if(!intermission)
 531         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 532         {
 533                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 534                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 535         }
 536         else if(getstatf(STAT_REVIVE_PROGRESS))
 537         {
 538                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 539                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 540         }
 541
 542         if(autocvar_r_letterbox == 0)
 543                 if(autocvar_viewsize < 120)
 544                         CSQC_common_hud();
 545
 546         // crosshair goes VERY LAST
 547         if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
 548         {
 549                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 550                         return;
 551
 552                 string wcross_style;
 553                 float wcross_alpha, wcross_resolution;
 554                 wcross_style = autocvar_crosshair;
 555                 if (wcross_style == "0")
 556                         return;
 557                 wcross_resolution = autocvar_crosshair_size;
 558                 if (wcross_resolution == 0)
 559                         return;
 560                 wcross_alpha = autocvar_crosshair_alpha;
 561                 if (wcross_alpha == 0)
 562                         return;
 563
 564                 // TrueAim check
 565                 float shottype;
 566
 567                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 568                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 569                 wcross_origin.z = 0;
 570                 if(autocvar_crosshair_hittest)
 571                 {
 572                         vector wcross_oldorigin;
 573                         wcross_oldorigin = wcross_origin;
 574                         shottype = TrueAimCheck();
 575                         if(shottype == SHOTTYPE_HITWORLD)
 576                         {
 577                                 v = wcross_origin - wcross_oldorigin;
 578                                 v.x /= vid_conwidth;
 579                                 v.y /= vid_conheight;
 580                                 if(vlen(v) > 0.01)
 581                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 582                         }
 583                         if(!autocvar_crosshair_hittest_showimpact)
 584                                 wcross_origin = wcross_oldorigin;
 585                 }
 586                 else
 587                         shottype = SHOTTYPE_HITWORLD;
 588
 589                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 590                 string wcross_name = "";
 591                 float wcross_scale, wcross_blur;
 592
 593                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 594                 {
 595                         e = get_weaponinfo(switchingweapon);
 596                         if(e)
 597                         {
 598                                 if(autocvar_crosshair_per_weapon)
 599                                 {
 600                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 601                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 602                                         //if (wcross_resolution == 0)
 603                                                 //return;
 604
 605                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 606                                         wcross_resolution *= e.w_crosshair_size;
 607                                         wcross_name = e.w_crosshair;
 608                                 }
 609                         }
 610                 }
 611
 612                 if(wcross_name == "")
 613                         wcross_name = strcat("gfx/crosshair", wcross_style);
 614
 615                 // MAIN CROSSHAIR COLOR DECISION
 616                 switch(autocvar_crosshair_color_special)
 617                 {
 618                         case 1: // crosshair_color_per_weapon
 619                         {
 620                                 if(e)
 621                                 {
 622                                         wcross_color = e.wpcolor;
 623                                         break;
 624                                 }
 625                                 else { goto normalcolor; }
 626                         }
 627
 628                         case 2: // crosshair_color_by_health
 629                         {
 630                                 float x = getstati(STAT_HEALTH);
 631
 632                                 //x = red
 633                                 //y = green
 634                                 //z = blue
 635
 636                                 wcross_color.z = 0;
 637
 638                                 if(x > 200)
 639                                 {
 640                                         wcross_color.x = 0;
 641                                         wcross_color.y = 1;
 642                                 }
 643                                 else if(x > 150)
 644                                 {
 645                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 646                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 647                                 }
 648                                 else if(x > 100)
 649                                 {
 650                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 651                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 652                                         wcross_color.z = 1 - (x-100)*0.02;
 653                                 }
 654                                 else if(x > 50)
 655                                 {
 656                                         wcross_color.x = 1;
 657                                         wcross_color.y = 1;
 658                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 659                                 }
 660                                 else if(x > 20)
 661                                 {
 662                                         wcross_color.x = 1;
 663                                         wcross_color.y = (x-20)*90/27/100;
 664                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 665                                 }
 666                                 else
 667                                 {
 668                                         wcross_color.x = 1;
 669                                         wcross_color.y = 0;
 670                                 }
 671                                 break;
 672                         }
 673
 674                         case 3: // crosshair_color_rainbow
 675                         {
 676                                 if(time >= rainbow_last_flicker)
 677                                 {
 678                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 679                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 680                                 }
 681                                 wcross_color = rainbow_prev_color;
 682                                 break;
 683                         }
 684                         :normalcolor
 685                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 686                 }
 687
 688                 if(autocvar_crosshair_effect_scalefade)
 689                 {
 690                         wcross_scale = wcross_resolution;
 691                         wcross_resolution = 1;
 692                 }
 693                 else
 694                 {
 695                         wcross_scale = 1;
 696                 }
 697
 698                 if(autocvar_crosshair_pickup)
 699                 {
 700                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 701
 702                         if(pickup_crosshair_time < stat_pickup_time)
 703                         {
 704                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 705                                         pickup_crosshair_size = 1;
 706
 707                                 pickup_crosshair_time = stat_pickup_time;
 708                         }
 709
 710                         if(pickup_crosshair_size > 0)
 711                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 712                         else
 713                                 pickup_crosshair_size = 0;
 714
 715                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 716                 }
 717
 718                 // todo: make crosshair hit indication dependent on damage dealt
 719                 if(autocvar_crosshair_hitindication)
 720                 {
 721                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 722
 723                         if(unaccounted_damage)
 724                         {
 725                                 hitindication_crosshair_size = 1;
 726                         }
 727
 728                         if(hitindication_crosshair_size > 0)
 729                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 730                         else
 731                                 hitindication_crosshair_size = 0;
 732
 733                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 734                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 735                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 736                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 737                 }
 738
 739                 if(shottype == SHOTTYPE_HITENEMY)
 740                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 741                 if(shottype == SHOTTYPE_HITTEAM)
 742                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 743
 744                 f = fabs(autocvar_crosshair_effect_time);
 745                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 746                 {
 747                         wcross_changedonetime = time + f;
 748                 }
 749                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 750                 {
 751                         wcross_name_changestarttime = time;
 752                         wcross_name_changedonetime = time + f;
 753                         if(wcross_name_goal_prev_prev)
 754                                 strunzone(wcross_name_goal_prev_prev);
 755                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 756                         wcross_name_goal_prev = strzone(wcross_name);
 757                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 758                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 759                         wcross_resolution_goal_prev = wcross_resolution;
 760                 }
 761
 762                 wcross_scale_goal_prev = wcross_scale;
 763                 wcross_alpha_goal_prev = wcross_alpha;
 764                 wcross_color_goal_prev = wcross_color;
 765
 766                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 767                 {
 768                         wcross_blur = 1;
 769                         wcross_alpha *= 0.75;
 770                 }
 771                 else
 772                         wcross_blur = 0;
 773                 // *_prev is at time-frametime
 774                 // * is at wcross_changedonetime+f
 775                 // what do we have at time?
 776                 if(time < wcross_changedonetime)
 777                 {
 778                         f = frametime / (wcross_changedonetime - time + frametime);
 779                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 780                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 781                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 782                 }
 783
 784                 wcross_scale_prev = wcross_scale;
 785                 wcross_alpha_prev = wcross_alpha;
 786                 wcross_color_prev = wcross_color;
 787
 788                 wcross_scale *= 1 - autocvar__menu_alpha;
 789                 wcross_alpha *= 1 - autocvar__menu_alpha;
 790                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 791
 792                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 793                 {
 794                         // crosshair rings for weapon stats
 795                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 796                         {
 797                                 // declarations and stats
 798                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 799                                 string ring_image = string_null, ring_inner_image = string_null;
 800                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 801
 802                                 ring_scale = autocvar_crosshair_ring_size;
 803
 804                                 float weapon_clipload, weapon_clipsize;
 805                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 806                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 807
 808                                 float ok_ammo_charge, ok_ammo_chargepool;
 809                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 810                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 811
 812                                 float vortex_charge, vortex_chargepool;
 813                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 814                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 815
 816                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 817
 818                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 819                                         vortex_charge_movingavg = vortex_charge;
 820
 821
 822                                 // handle the values
 823                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 824                                 {
 825                                         if (vortex_chargepool || use_vortex_chargepool) {
 826                                                 use_vortex_chargepool = 1;
 827                                                 ring_inner_value = vortex_chargepool;
 828                                         } else {
 829                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 830                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 831                                         }
 832
 833                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 834                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 835                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 836
 837                                         // draw the outer ring to show the current charge of the weapon
 838                                         ring_value = vortex_charge;
 839                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 840                                         ring_rgb = wcross_color;
 841                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 842                                 }
 843                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 844                                 {
 845                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 846                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 847                                         ring_rgb = wcross_color;
 848                                         ring_image = "gfx/crosshair_ring.tga";
 849                                 }
 850                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 851                                 {
 852                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 853                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 854                                         ring_rgb = wcross_color;
 855                                         ring_image = "gfx/crosshair_ring.tga";
 856                                 }
 857                                 else if (ok_ammo_charge)
 858                                 {
 859                                         ring_value = ok_ammo_chargepool;
 860                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 861                                         ring_rgb = wcross_color;
 862                                         ring_image = "gfx/crosshair_ring.tga";
 863                                 }
 864                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 865                                 {
 866                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 867                                         ring_scale = autocvar_crosshair_ring_reload_size;
 868                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 869                                         ring_rgb = wcross_color;
 870
 871                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 872                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 873                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
 874                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 875                                         else
 876                                                 ring_image = "gfx/crosshair_ring.tga";
 877                                 }
 878                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
 879                                 {
 880                                         ring_value = arc_heat;
 881                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 882                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 883                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 884                                         ring_image = "gfx/crosshair_ring.tga";
 885                                 }
 886
 887                                 // if in weapon switch animation, fade ring out/in
 888                                 if(autocvar_crosshair_effect_time > 0)
 889                                 {
 890                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 891                                         if (f >= 1)
 892                                         {
 893                                                 wcross_ring_prev = ((ring_image) ? true : false);
 894                                         }
 895
 896                                         if(wcross_ring_prev)
 897                                         {
 898                                                 if(f < 1)
 899                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 900                                         }
 901                                         else
 902                                         {
 903                                                 if(f < 1)
 904                                                         ring_alpha *= bound(0, f, 1);
 905                                         }
 906                                 }
 907
 908                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 909                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 910
 911                                 if (ring_value)
 912                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 913                         }
 914
 915 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 916                         do \
 917                         { \
 918                                 if(wcross_blur > 0) \
 919                                 { \
 920                                         for(i = -2; i <= 2; ++i) \
 921                                         for(j = -2; j <= 2; ++j) \
 922                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 923                                 } \
 924                                 else \
 925                                 { \
 926                                         M(0,0,sz,wcross_name,wcross_alpha); \
 927                                 } \
 928                         } \
 929                         while(0)
 930
 931 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 932                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 933
 934 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 935                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 936
 937                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 938                         {
 939                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 940                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 941                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 942                                 f = 1 - f;
 943                         }
 944                         else
 945                         {
 946                                 f = 1;
 947                         }
 948                         wcross_name_alpha_goal_prev = f;
 949
 950                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 951                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 952
 953                         if(autocvar_crosshair_dot)
 954                         {
 955                                 vector wcross_color_old;
 956                                 wcross_color_old = wcross_color;
 957
 958                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 959                                         wcross_color = stov(autocvar_crosshair_dot_color);
 960
 961                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 962                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 963                                 wcross_color = wcross_color_old;
 964                         }
 965                 }
 966         }
 967         else
 968         {
 969                 wcross_scale_prev = 0;
 970                 wcross_alpha_prev = 0;
 971                 wcross_scale_goal_prev = 0;
 972                 wcross_alpha_goal_prev = 0;
 973                 wcross_changedonetime = 0;
 974                 if(wcross_name_goal_prev)
 975                         strunzone(wcross_name_goal_prev);
 976                 wcross_name_goal_prev = string_null;
 977                 if(wcross_name_goal_prev_prev)
 978                         strunzone(wcross_name_goal_prev_prev);
 979                 wcross_name_goal_prev_prev = string_null;
 980                 wcross_name_changestarttime = 0;
 981                 wcross_name_changedonetime = 0;
 982                 wcross_name_alpha_goal_prev = 0;
 983                 wcross_name_alpha_goal_prev_prev = 0;
 984                 wcross_resolution_goal_prev = 0;
 985                 wcross_resolution_goal_prev_prev = 0;
 986         }
 987 }
 988
 989 const int BUTTON_3 = 4;
 990 const int BUTTON_4 = 8;
 991 float cl_notice_run();
 992 float prev_myteam;
 993 void CSQC_UpdateView(float w, float h)
 994 {
 995         entity e;
 996         float fov;
 997         float f;
 998         int i;
 999         vector vf_size, vf_min;
1000         float a;
1001
1002         execute_next_frame();
1003
1004         ++framecount;
1005
1006         hud = getstati(STAT_HUD);
1007
1008         if(autocvar__hud_showbinds_reload) // menu can set this one
1009         {
1010                 db_close(binddb);
1011                 binddb = db_create();
1012                 cvar_set("_hud_showbinds_reload", "0");
1013         }
1014
1015         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1016                 view_quality = getproperty(VF_MINFPS_QUALITY);
1017         else
1018                 view_quality = 1;
1019
1020         button_attack2 = (input_buttons & BUTTON_3);
1021         button_zoom = (input_buttons & BUTTON_4);
1022
1023 #define CHECKFAIL_ASSERT(flag,func,parm,val) do {                                                                   \
1024         float checkfailv = (func)(parm);                                                                                \
1025         if (checkfailv != (val)) {                                                                                      \
1026                 if (!checkfail[(flag)])                                                                                     \
1027                 localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv));                           \
1028                 checkfail[(flag)] = 1;                                                                                      \
1029         }                                                                                                               \
1030 } while(0)
1031         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
1032         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
1033         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
1034         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1035         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
1036         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
1037         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1038
1039         vf_size = getpropertyvec(VF_SIZE);
1040         vf_min = getpropertyvec(VF_MIN);
1041         vid_width = vf_size.x;
1042         vid_height = vf_size.y;
1043
1044         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1045         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1046
1047         WaypointSprite_Load();
1048
1049         CSQCPlayer_SetCamera();
1050
1051         myteam = GetPlayerColor(player_localentnum - 1);
1052
1053         if(myteam != prev_myteam)
1054         {
1055                 myteamcolors = colormapPaletteColor(myteam, 1);
1056                 for(i = 0; i < HUD_PANEL_NUM; ++i)
1057                         hud_panel[i].update_time = time;
1058                 prev_myteam = myteam;
1059         }
1060
1061         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1062
1063         float is_dead = (getstati(STAT_HEALTH) <= 0);
1064
1065         // FIXME do we need this hack?
1066         if(isdemo())
1067         {
1068                 // in demos, input_buttons do not work
1069                 button_zoom = (autocvar__togglezoom == "-");
1070         }
1071         else if(button_zoom
1072                 && autocvar_cl_unpress_zoom_on_death
1073                 && (spectatee_status >= 0)
1074                 && (is_dead || intermission))
1075         {
1076                 // no zoom while dead or in intermission please
1077                 localcmd("-zoom\n");
1078                 button_zoom = false;
1079         }
1080
1081         // event chase camera
1082         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1083         {
1084                 if(WantEventchase())
1085                 {
1086                         eventchase_running = true;
1087
1088                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1089                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1090
1091                         // detect maximum viewoffset and use it
1092                         if(autocvar_cl_eventchase_viewoffset)
1093                         {
1094                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1095                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
1096                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1097                         }
1098
1099                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1100                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1101                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1102                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1103
1104                         // make the camera smooth back
1105                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
1106                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1107                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
1108                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
1109
1110                         makevectors(view_angles);
1111
1112                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1113                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1114
1115                         // If the boxtrace fails, revert back to line tracing.
1116                         if(trace_startsolid)
1117                         {
1118                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1119                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1120                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1121                         }
1122                         else { setproperty(VF_ORIGIN, trace_endpos); }
1123
1124                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1125                 }
1126                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1127                 {
1128                         eventchase_running = false;
1129                         cvar_set("chase_active", "0");
1130                         eventchase_current_distance = 0; // start from 0 next time
1131                 }
1132         }
1133         // workaround for camera stuck between player's legs when using chase_active 1
1134         // because the engine stops updating the chase_active camera when the game ends
1135         else if(intermission)
1136         {
1137                 cvar_settemp("chase_active", "-1");
1138                 eventchase_current_distance = 0;
1139         }
1140
1141         // do lockview after event chase camera so that it still applies whenever necessary.
1142         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
1143         {
1144                 setproperty(VF_ORIGIN, freeze_org);
1145                 setproperty(VF_ANGLES, freeze_ang);
1146         }
1147         else
1148         {
1149                 freeze_org = getpropertyvec(VF_ORIGIN);
1150                 freeze_ang = getpropertyvec(VF_ANGLES);
1151         }
1152
1153         WarpZone_FixView();
1154         //WarpZone_FixPMove();
1155
1156         vector ov_org = '0 0 0';
1157         vector ov_mid = '0 0 0';
1158         vector ov_worldmin = '0 0 0';
1159         vector ov_worldmax = '0 0 0';
1160         if(autocvar_cl_orthoview)
1161         {
1162                 ov_worldmin = mi_picmin;
1163                 ov_worldmax = mi_picmax;
1164
1165                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1166                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1167                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1168
1169                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1170                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1171
1172                 float ov_nearest = vlen(ov_org - vec3(
1173                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1174                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1175                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1176                 ));
1177
1178                 float ov_furthest = 0;
1179                 float dist = 0;
1180
1181                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1182                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1183                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1184                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1185                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1186                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1187                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1188                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1189
1190                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1191                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1192                 cvar_settemp("r_farclip_world", "0");
1193                 cvar_settemp("r_novis", "1");
1194                 cvar_settemp("r_useportalculling", "0");
1195                 cvar_settemp("r_useinfinitefarclip", "0");
1196
1197                 setproperty(VF_ORIGIN, ov_org);
1198                 setproperty(VF_ANGLES, '90 0 0');
1199
1200                 #if 0
1201                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1202                         vtos(ov_org),
1203                         vtos(getpropertyvec(VF_ANGLES)),
1204                         ov_distance,
1205                         ov_nearest,
1206                         ov_furthest);
1207                 #endif
1208         }
1209
1210         // Render the Scene
1211         view_origin = getpropertyvec(VF_ORIGIN);
1212         view_angles = getpropertyvec(VF_ANGLES);
1213         makevectors(view_angles);
1214         view_forward = v_forward;
1215         view_right = v_right;
1216         view_up = v_up;
1217
1218 #ifdef BLURTEST
1219         if(time > blurtest_time0 && time < blurtest_time1)
1220         {
1221                 float r, t;
1222
1223                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1224                 r = t * blurtest_radius;
1225                 f = 1 / pow(t, blurtest_power) - 1;
1226
1227                 cvar_set("r_glsl_postprocess", "1");
1228                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1229         }
1230         else
1231         {
1232                 cvar_set("r_glsl_postprocess", "0");
1233                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1234         }
1235 #endif
1236
1237         TargetMusic_Advance();
1238         Fog_Force();
1239
1240         if(drawtime == 0)
1241                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1242         else
1243                 drawframetime = bound(0.000001, time - drawtime, 1);
1244         drawtime = time;
1245
1246         // watch for gametype changes here...
1247         // in ParseStuffCMD the cmd isn't executed yet :/
1248         // might even be better to add the gametype to TE_CSQC_INIT...?
1249         if(!postinit)
1250                 PostInit();
1251
1252         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1253         {
1254                 if(calledhooks & HOOK_START)
1255                 {
1256                         localcmd("\ncl_hook_gameend\n");
1257                         calledhooks |= HOOK_END;
1258                 }
1259         }
1260
1261         Announcer();
1262
1263         fov = autocvar_fov;
1264         if(fov <= 59.5)
1265         {
1266                 if(!zoomscript_caught)
1267                 {
1268                         localcmd("+button9\n");
1269                         zoomscript_caught = 1;
1270                 }
1271         }
1272         else
1273         {
1274                 if(zoomscript_caught)
1275                 {
1276                         localcmd("-button9\n");
1277                         zoomscript_caught = 0;
1278                 }
1279         }
1280
1281         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1282
1283         // next WANTED weapon (for HUD)
1284         switchweapon = getstati(STAT_SWITCHWEAPON);
1285
1286         // currently switching-to weapon (for crosshair)
1287         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1288
1289         // actually active weapon (for zoom)
1290         activeweapon = getstati(STAT_ACTIVEWEAPON);
1291
1292         f = (serverflags & SERVERFLAG_TEAMPLAY);
1293         if(f != teamplay)
1294         {
1295                 teamplay = f;
1296                 HUD_InitScores();
1297         }
1298
1299         if(last_switchweapon != switchweapon)
1300         {
1301                 weapontime = time;
1302                 last_switchweapon = switchweapon;
1303                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1304                 {
1305                         localcmd("-zoom\n");
1306                         button_zoom = false;
1307                 }
1308                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1309                 {
1310                         localcmd("-fire\n");
1311                         localcmd("-fire2\n");
1312                         button_attack2 = false;
1313                 }
1314         }
1315         if(last_activeweapon != activeweapon)
1316         {
1317                 last_activeweapon = activeweapon;
1318
1319                 e = get_weaponinfo(activeweapon);
1320                 if(e.netname != "")
1321                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1322                 else
1323                         localcmd("\ncl_hook_activeweapon none\n");
1324         }
1325
1326         // ALWAYS Clear Current Scene First
1327         clearscene();
1328
1329         setproperty(VF_ORIGIN, view_origin);
1330         setproperty(VF_ANGLES, view_angles);
1331
1332         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1333         setproperty(VF_SIZE, vf_size);
1334         setproperty(VF_MIN, vf_min);
1335
1336         // Assign Standard Viewflags
1337         // Draw the World (and sky)
1338         setproperty(VF_DRAWWORLD, 1);
1339
1340         // Set the console size vars
1341         vid_conwidth = autocvar_vid_conwidth;
1342         vid_conheight = autocvar_vid_conheight;
1343         vid_pixelheight = autocvar_vid_pixelheight;
1344
1345         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1346         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1347
1348         // Camera for demo playback
1349         if(camera_active)
1350         {
1351                 if(autocvar_camera_enable)
1352                         CSQC_Demo_Camera();
1353                 else
1354                 {
1355                         cvar_set("chase_active", ftos(chase_active_backup));
1356                         cvar_set("cl_demo_mousegrab", "0");
1357                         camera_active = false;
1358                 }
1359         }
1360         else
1361         {
1362 #ifdef CAMERATEST
1363                 if(autocvar_camera_enable)
1364 #else
1365                 if(autocvar_camera_enable && isdemo())
1366 #endif
1367                 {
1368                         // Enable required Darkplaces cvars
1369                         chase_active_backup = autocvar_chase_active;
1370                         cvar_set("chase_active", "2");
1371                         cvar_set("cl_demo_mousegrab", "1");
1372                         camera_active = true;
1373                         camera_mode = false;
1374                 }
1375         }
1376
1377         // Draw the Crosshair
1378         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1379
1380         // Draw the Engine Status Bar (the default Quake HUD)
1381         setproperty(VF_DRAWENGINESBAR, 0);
1382
1383         // Update the mouse position
1384         /*
1385            mousepos_x = vid_conwidth;
1386            mousepos_y = vid_conheight;
1387            mousepos = mousepos*0.5 + getmousepos();
1388          */
1389
1390         e = self;
1391         for(self = world; (self = nextent(self)); )
1392                 if(self.draw)
1393                         self.draw();
1394         self = e;
1395
1396         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1397         renderscene();
1398
1399         // now switch to 2D drawing mode by calling a 2D drawing function
1400         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1401         // next R_RenderScene call
1402         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1403
1404         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1405         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1406         {
1407                 // apply night vision effect
1408                 vector tc_00, tc_01, tc_10, tc_11;
1409                 vector rgb = '0 0 0';
1410
1411                 if(!nightvision_noise)
1412                 {
1413                         nightvision_noise = spawn();
1414                         nightvision_noise.classname = "nightvision_noise";
1415                 }
1416                 if(!nightvision_noise2)
1417                 {
1418                         nightvision_noise2 = spawn();
1419                         nightvision_noise2.classname = "nightvision_noise2";
1420                 }
1421
1422                 // color tint in yellow
1423                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1424
1425                 // draw BG
1426                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1427                 rgb = '1 1 1';
1428                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1429                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1430                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1431                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1432                 tc_11 = tc_01 + tc_10 - tc_00;
1433                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1434                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1435                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1436                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1437                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1438                 R_EndPolygon();
1439
1440                 // draw FG
1441                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1442                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1443                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1444                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1445                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1446                 tc_11 = tc_01 + tc_10 - tc_00;
1447                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1448                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1449                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1450                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1451                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1452                 R_EndPolygon();
1453         }
1454
1455         if(autocvar_cl_reticle)
1456         {
1457                 // Draw the aiming reticle for weapons that use it
1458                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1459                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1460                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1461                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1462                 {
1463                         // no zoom reticle while dead
1464                         reticle_type = 0;
1465                 }
1466                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
1467                 {
1468                         if(reticle_image != "") { reticle_type = 2; }
1469                         else { reticle_type = 0; }
1470                 }
1471                 else if(button_zoom || zoomscript_caught)
1472                 {
1473                         // normal zoom
1474                         reticle_type = 1;
1475                 }
1476
1477                 if(reticle_type)
1478                 {
1479                         if(autocvar_cl_reticle_stretch)
1480                         {
1481                                 reticle_size.x = vid_conwidth;
1482                                 reticle_size.y = vid_conheight;
1483                                 reticle_pos.x = 0;
1484                                 reticle_pos.y = 0;
1485                         }
1486                         else
1487                         {
1488                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1489                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1490                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1491                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1492                         }
1493
1494                         if(zoomscript_caught)
1495                                 f = 1;
1496                         else
1497                                 f = current_zoomfraction;
1498
1499                         if(f)
1500                         {
1501                                 switch(reticle_type)
1502                                 {
1503                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1504                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1505                                 }
1506                         }
1507                 }
1508         }
1509         else
1510         {
1511                 if(reticle_type != 0) { reticle_type = 0; }
1512         }
1513
1514
1515         // improved polyblend
1516         if(autocvar_hud_contents)
1517         {
1518                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1519                 vector liquidcolor;
1520
1521                 switch(pointcontents(view_origin))
1522                 {
1523                         case CONTENT_WATER:
1524                                 liquidalpha = autocvar_hud_contents_water_alpha;
1525                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1526                                 incontent = 1;
1527                                 break;
1528
1529                         case CONTENT_LAVA:
1530                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1531                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1532                                 incontent = 1;
1533                                 break;
1534
1535                         case CONTENT_SLIME:
1536                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1537                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1538                                 incontent = 1;
1539                                 break;
1540
1541                         default:
1542                                 liquidalpha = 0;
1543                                 liquidcolor = '0 0 0';
1544                                 incontent = 0;
1545                                 break;
1546                 }
1547
1548                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1549                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1550                         contentfadetime = autocvar_hud_contents_fadeintime;
1551                         liquidalpha_prev = liquidalpha;
1552                         liquidcolor_prev = liquidcolor;
1553                 }
1554                 else
1555                         contentfadetime = autocvar_hud_contents_fadeouttime;
1556
1557                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1558                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1559
1560                 if(contentavgalpha)
1561                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1562
1563                 if(autocvar_hud_postprocessing)
1564                 {
1565                         if(autocvar_hud_contents_blur && contentavgalpha)
1566                         {
1567                                 content_blurpostprocess.x = 1;
1568                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1569                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1570                         }
1571                         else
1572                         {
1573                                 content_blurpostprocess.x = 0;
1574                                 content_blurpostprocess.y = 0;
1575                                 content_blurpostprocess.z = 0;
1576                         }
1577                 }
1578         }
1579
1580         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1581         {
1582                 splash_size.x = max(vid_conwidth, vid_conheight);
1583                 splash_size.y = max(vid_conwidth, vid_conheight);
1584                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1585                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1586
1587                 float myhealth_flash_temp;
1588                 myhealth = getstati(STAT_HEALTH);
1589
1590                 // fade out
1591                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1592                 // add new damage
1593                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1594
1595                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1596                 pain_threshold = autocvar_hud_damage_pain_threshold;
1597                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1598                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1599
1600                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1601                 {
1602                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1603                 }
1604
1605                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1606
1607                 if(myhealth_prev < 1)
1608                 {
1609                         if(myhealth >= 1)
1610                         {
1611                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1612                                 myhealth_flash_temp = 0;
1613                         }
1614                         else
1615                         {
1616                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1617                         }
1618                 }
1619
1620                 if(spectatee_status == -1 || intermission)
1621                 {
1622                         myhealth_flash = 0; // observing, or match ended
1623                         myhealth_flash_temp = 0;
1624                 }
1625
1626                 myhealth_prev = myhealth;
1627
1628                 // IDEA: change damage color/picture based on player model for robot/alien species?
1629                 // pro: matches model better
1630                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1631                 // maybe different reddish pics?
1632                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1633                 {
1634                         if(autocvar_cl_gentle_damage == 2)
1635                         {
1636                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1637                                 {
1638                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1639                                 }
1640                         }
1641                         else
1642                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1643
1644                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1645                 }
1646                 else
1647                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1648
1649                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1650                 {
1651                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1652                         {
1653                                 damage_blurpostprocess.x = 1;
1654                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1655                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1656                         }
1657                         else
1658                         {
1659                                 damage_blurpostprocess.x = 0;
1660                                 damage_blurpostprocess.y = 0;
1661                                 damage_blurpostprocess.z = 0;
1662                         }
1663                 }
1664         }
1665
1666         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1667         float e2 = (autocvar_hud_powerup != 0);
1668         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1669         {
1670                 // enable or disable rendering types if they are used or not
1671                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1672                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1673
1674                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1675                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1676                 {
1677                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1678                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1679                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1680                         {
1681                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1682                                 old_blurradius = blurradius;
1683                                 old_bluralpha = bluralpha;
1684                         }
1685                 }
1686                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1687                 {
1688                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1689                         old_blurradius = 0;
1690                         old_bluralpha = 0;
1691                 }
1692
1693                 // edge detection postprocess handling done second (used by hud_powerup)
1694                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1695                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1696                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1697
1698                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1699
1700                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1701                 {
1702                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1703                         {
1704                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1705                                 old_sharpen_intensity = sharpen_intensity;
1706                         }
1707                 }
1708                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1709                 {
1710                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1711                         old_sharpen_intensity = 0;
1712                 }
1713
1714                 if(cvar("r_glsl_postprocess") == 0)
1715                         cvar_set("r_glsl_postprocess", "2");
1716         }
1717         else if(cvar("r_glsl_postprocess") == 2)
1718                 cvar_set("r_glsl_postprocess", "0");
1719
1720         if(menu_visible)
1721                 menu_show();
1722
1723         /*if(gametype == MAPINFO_TYPE_CTF)
1724           {
1725           ctf_view();
1726           } else */
1727
1728         // draw 2D entities
1729         e = self;
1730         for(self = world; (self = nextent(self)); )
1731                 if(self.draw2d)
1732                         self.draw2d();
1733         self = e;
1734         Draw_ShowNames_All();
1735
1736         scoreboard_active = HUD_WouldDrawScoreboard();
1737
1738         UpdateDamage();
1739         UpdateCrosshair();
1740         UpdateHitsound();
1741         InitializeEntitiesRun();
1742
1743         if(NextFrameCommand)
1744         {
1745                 localcmd("\n", NextFrameCommand, "\n");
1746                 NextFrameCommand = string_null;
1747         }
1748
1749         // we must do this check AFTER a frame was rendered, or it won't work
1750         if(cs_project_is_b0rked == 0)
1751         {
1752                 string w0, h0;
1753                 w0 = ftos(autocvar_vid_conwidth);
1754                 h0 = ftos(autocvar_vid_conheight);
1755                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1756                 //setproperty(VF_FOV, '90 90 0');
1757                 setproperty(VF_ORIGIN, '0 0 0');
1758                 setproperty(VF_ANGLES, '0 0 0');
1759                 setproperty(VF_PERSPECTIVE, 1);
1760                 makevectors('0 0 0');
1761                 vector v1, v2;
1762                 cvar_set("vid_conwidth", "800");
1763                 cvar_set("vid_conheight", "600");
1764                 v1 = cs_project(v_forward);
1765                 cvar_set("vid_conwidth", "640");
1766                 cvar_set("vid_conheight", "480");
1767                 v2 = cs_project(v_forward);
1768                 if(v1 == v2)
1769                         cs_project_is_b0rked = 1;
1770                 else
1771                         cs_project_is_b0rked = -1;
1772                 cvar_set("vid_conwidth", w0);
1773                 cvar_set("vid_conheight", h0);
1774         }
1775
1776         if(autocvar__hud_configure)
1777                 HUD_Panel_Mouse();
1778
1779     if(hud && !intermission)
1780     {
1781         if(hud == HUD_SPIDERBOT)
1782             CSQC_SPIDER_HUD();
1783         else if(hud == HUD_WAKIZASHI)
1784             CSQC_WAKIZASHI_HUD();
1785         else if(hud == HUD_RAPTOR)
1786             CSQC_RAPTOR_HUD();
1787         else if(hud == HUD_BUMBLEBEE)
1788             CSQC_BUMBLE_HUD();
1789         else if(hud == HUD_BUMBLEBEE_GUN)
1790             CSQC_BUMBLE_GUN_HUD();
1791     }
1792
1793         cl_notice_run();
1794
1795         // let's reset the view back to normal for the end
1796         setproperty(VF_MIN, '0 0 0');
1797         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1798 }
1799
1800
1801 void CSQC_common_hud(void)
1802 {
1803         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1804                 Accuracy_LoadLevels();
1805
1806         HUD_Main(); // always run these functions for alpha checks
1807         HUD_DrawScoreboard();
1808
1809         if (scoreboard_active) // scoreboard/accuracy
1810                 HUD_Reset();
1811         else if (intermission == 2) // map voting screen
1812         {
1813                 MapVote_Draw();
1814                 HUD_Reset();
1815         }
1816 }
1817
1818
1819 // following vectors must be global to allow seamless switching between camera modes
1820 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1821 void CSQC_Demo_Camera()
1822 {
1823         float speed, attenuation, dimensions;
1824         vector tmp, delta;
1825
1826         if( autocvar_camera_reset || !camera_mode )
1827         {
1828                 camera_offset = '0 0 0';
1829                 current_angles = '0 0 0';
1830                 camera_direction = '0 0 0';
1831                 camera_offset.z += 30;
1832                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1833                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1834                 current_origin = view_origin;
1835                 current_camera_offset  = camera_offset;
1836                 cvar_set("camera_reset", "0");
1837                 camera_mode = CAMERA_CHASE;
1838         }
1839
1840         // Camera angles
1841         if( camera_roll )
1842                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1843
1844         if(autocvar_camera_look_player)
1845         {
1846                 vector dir;
1847                 float n;
1848
1849                 dir = normalize(view_origin - current_position);
1850                 n = mouse_angles.z;
1851                 mouse_angles = vectoangles(dir);
1852                 mouse_angles.x = mouse_angles.x * -1;
1853                 mouse_angles.z = n;
1854         }
1855         else
1856         {
1857                 tmp = getmousepos() * 0.1;
1858                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1859                 {
1860                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1861                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1862                 }
1863         }
1864
1865         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1866         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1867         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1868         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1869
1870         // Fix difference when angles don't have the same sign
1871         delta = '0 0 0';
1872         if(mouse_angles.y < -60 && current_angles.y > 60)
1873                 delta = '0 360 0';
1874         if(mouse_angles.y > 60 && current_angles.y < -60)
1875                 delta = '0 -360 0';
1876
1877         if(autocvar_camera_look_player)
1878                 attenuation = autocvar_camera_look_attenuation;
1879         else
1880                 attenuation = autocvar_camera_speed_attenuation;
1881
1882         attenuation = 1 / max(1, attenuation);
1883         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1884
1885         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1886         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1887         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1888         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1889
1890         // Camera position
1891         tmp = '0 0 0';
1892         dimensions = 0;
1893
1894         if( camera_direction.x )
1895         {
1896                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1897                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1898                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1899                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1900                 ++dimensions;
1901         }
1902
1903         if( camera_direction.y )
1904         {
1905                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1906                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1907                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1908                 ++dimensions;
1909         }
1910
1911         if( camera_direction.z )
1912         {
1913                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1914                 ++dimensions;
1915         }
1916
1917         if(autocvar_camera_free)
1918                 speed = autocvar_camera_speed_free;
1919         else
1920                 speed = autocvar_camera_speed_chase;
1921
1922         if(dimensions)
1923         {
1924                 speed = speed * sqrt(1 / dimensions);
1925                 camera_offset += tmp * speed;
1926         }
1927
1928         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1929
1930         // Camera modes
1931         if( autocvar_camera_free )
1932         {
1933                 if ( camera_mode == CAMERA_CHASE )
1934                 {
1935                         current_camera_offset = current_origin + current_camera_offset;
1936                         camera_offset = current_origin + camera_offset;
1937                 }
1938
1939                 camera_mode = CAMERA_FREE;
1940                 current_position = current_camera_offset;
1941         }
1942         else
1943         {
1944                 if ( camera_mode == CAMERA_FREE )
1945                 {
1946                         current_origin = view_origin;
1947                         camera_offset = camera_offset - current_origin;
1948                         current_camera_offset = current_camera_offset - current_origin;
1949                 }
1950
1951                 camera_mode = CAMERA_CHASE;
1952
1953                 if(autocvar_camera_chase_smoothly)
1954                         current_origin += (view_origin - current_origin) * attenuation;
1955                 else
1956                         current_origin = view_origin;
1957
1958                 current_position = current_origin + current_camera_offset;
1959         }
1960
1961         setproperty(VF_ANGLES, current_angles);
1962         setproperty(VF_ORIGIN, current_position);
1963 }