qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "scoreboard.qh"
   7 #include "shownames.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/debug.qh>
  17 #include <common/mapinfo.qh>
  18 #include <common/gamemodes/all.qh>
  19 #include <common/physics/player.qh>
  20 #include <common/stats.qh>
  21 #include <common/triggers/target/music.qh>
  22 #include <common/teams.qh>
  23
  24 #include <common/vehicles/all.qh>
  25 #include <common/weapons/all.qh>
  26 #include <common/viewloc.qh>
  27 #include <common/minigames/cl_minigames.qh>
  28 #include <common/minigames/cl_minigames_hud.qh>
  29
  30 #include <lib/csqcmodel/cl_player.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include "csqcmodel_hooks.qh"
  33
  34 #include <lib/warpzone/client.qh>
  35 #include <lib/warpzone/common.qh>
  36
  37 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  38
  39 float autocvar_cl_viewmodel_scale;
  40
  41 bool autocvar_cl_bobmodel;
  42 float autocvar_cl_bobmodel_speed;
  43 float autocvar_cl_bobmodel_side;
  44 float autocvar_cl_bobmodel_up;
  45
  46 float autocvar_cl_followmodel;
  47 float autocvar_cl_followmodel_speed = 0.3;
  48 float autocvar_cl_followmodel_limit = 135;
  49 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  50 float autocvar_cl_followmodel_highpass = 0.05;
  51 float autocvar_cl_followmodel_lowpass = 0.03;
  52 bool autocvar_cl_followmodel_velocity_absolute;
  53
  54 float autocvar_cl_leanmodel;
  55 float autocvar_cl_leanmodel_speed = 0.3;
  56 float autocvar_cl_leanmodel_limit = 30;
  57 float autocvar_cl_leanmodel_highpass1 = 0.2;
  58 float autocvar_cl_leanmodel_highpass = 0.2;
  59 float autocvar_cl_leanmodel_lowpass = 0.05;
  60
  61 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  62 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  63 { \
  64         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  65 } MACRO_END
  66
  67 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  68 { \
  69         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  70         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  71 } MACRO_END
  72
  73 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __f = 0; lowpass(value, frac, ref_store, __f); \
  76         ret = (value) - __f; \
  77 } MACRO_END
  78
  79 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  80 { \
  81         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  82         ret = (value) - __f; \
  83 } MACRO_END
  84
  85 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  86 { \
  87         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  88         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  89 } MACRO_END
  90
  91 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  92 { \
  93         highpass(value.x, frac, ref_store.x, ref_out.x); \
  94         highpass(value.y, frac, ref_store.y, ref_out.y); \
  95 } MACRO_END
  96
  97 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 100         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 101 } MACRO_END
 102
 103 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 104 { \
 105         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 106         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 107         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 108 } MACRO_END
 109
 110 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         highpass(value.x, frac, ref_store.x, ref_out.x); \
 113         highpass(value.y, frac, ref_store.y, ref_out.y); \
 114         highpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 void viewmodel_animate(entity this)
 118 {
 119         static float prevtime;
 120         float frametime = (time - prevtime);
 121         prevtime = time;
 122
 123         if (autocvar_chase_active) return;
 124         if (STAT(HEALTH) <= 0) return;
 125
 126         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 127
 128         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 129         static bool oldonground;
 130         static float hitgroundtime;
 131         if (clonground)
 132         {
 133                 float f = time; // cl.movecmd[0].time
 134                 if (!oldonground)
 135                         hitgroundtime = f;
 136         }
 137         oldonground = clonground;
 138
 139
 140         bool teleported = view.csqcmodel_teleported;
 141
 142         float frac;
 143         if(autocvar_cl_followmodel)
 144         {
 145                 vector gunorg = '0 0 0';
 146                 static vector vel_average;
 147                 static vector gunorg_prev = '0 0 0';
 148                 static vector gunorg_adjustment_highpass;
 149                 static vector gunorg_adjustment_lowpass;
 150
 151                 vector vel;
 152                 if(autocvar_cl_followmodel_velocity_absolute)
 153                         vel = view.velocity;
 154                 else
 155                 {
 156                         vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 157                         MAKEVECTORS(makevectors, view_angles, forward, right, up);
 158                         vel.x = view.velocity * forward;
 159                         vel.y = view.velocity * right * -1;
 160                         vel.z = view.velocity * up;
 161                 }
 162
 163                 vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 164                 vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 165                 vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 166
 167                 frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 168                 lowpass3(vel, frac, vel_average, gunorg);
 169
 170                 gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 171
 172                 // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 173                 // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 174                 frac = avg_factor(autocvar_cl_followmodel_highpass);
 175                 highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 176                 frac = avg_factor(autocvar_cl_followmodel_lowpass);
 177                 lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 178
 179                 if(autocvar_cl_followmodel_velocity_absolute)
 180                 {
 181                         vector fixed_gunorg;
 182                         vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 183                         MAKEVECTORS(makevectors, view_angles, forward, right, up);
 184                         fixed_gunorg.x = gunorg * forward;
 185                         fixed_gunorg.y = gunorg * right * -1;
 186                         fixed_gunorg.z = gunorg * up;
 187                         gunorg = fixed_gunorg;
 188                 }
 189
 190                 this.origin += gunorg;
 191         }
 192
 193         if(autocvar_cl_leanmodel)
 194         {
 195                 vector gunangles = '0 0 0';
 196                 static vector gunangles_prev = '0 0 0';
 197                 static vector gunangles_highpass = '0 0 0';
 198                 static vector gunangles_adjustment_highpass;
 199                 static vector gunangles_adjustment_lowpass;
 200
 201                 if (teleported)
 202                         gunangles_prev = view_angles;
 203
 204                 // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 205                 gunangles_highpass += gunangles_prev;
 206                 PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 207                 YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 208                 ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 209                 frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 210                 highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 211                 gunangles_prev = view_angles;
 212                 gunangles_highpass -= gunangles_prev;
 213
 214                 PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 215                 YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 216
 217                 // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 218                 frac = avg_factor(autocvar_cl_leanmodel_highpass);
 219                 highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 220                 frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 221                 lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 222
 223                 gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 224                 this.angles += gunangles;
 225         }
 226
 227         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 228
 229         // vertical view bobbing code
 230         // TODO: cl_bob
 231
 232         // horizontal view bobbing code
 233         // TODO: cl_bob2
 234
 235         // fall bobbing code
 236         // causes the view to swing down and back up when touching the ground
 237         // TODO: cl_bobfall
 238
 239         // gun model bobbing code
 240         if (autocvar_cl_bobmodel)
 241         {
 242                 // calculate for swinging gun model
 243                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 244                 static float bobmodel_scale = 0;
 245                 static float time_ofs = 0; // makes the effect always restart in the same way
 246                 if (clonground)
 247                 {
 248                         if (time - hitgroundtime > 0.05)
 249                                 bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 250                 }
 251                 else
 252                         bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 253                 if(bobmodel_scale && xyspeed)
 254                 {
 255                         float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 256                         float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 257                         vector gunorg = '0 0 0';
 258                         gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 259                         gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 260
 261                         this.origin += gunorg;
 262                 }
 263                 else
 264                         time_ofs = time;
 265         }
 266 }
 267
 268 .vector viewmodel_origin, viewmodel_angles;
 269 .float weapon_nextthink;
 270 .float weapon_eta_last;
 271 .float weapon_switchdelay;
 272
 273 void viewmodel_draw(entity this)
 274 {
 275         if(!activeweapon)
 276                 return;
 277         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 278         float a = this.alpha;
 279         static bool wasinvehicle;
 280         bool invehicle = player_localentnum > maxclients;
 281         if (invehicle) a = -1;
 282         else if (wasinvehicle) a = 1;
 283         wasinvehicle = invehicle;
 284         Weapon wep = activeweapon;
 285         int c = stof(getplayerkeyvalue(current_player, "colors"));
 286         vector g = weaponentity_glowmod(wep, c);
 287         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 288         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 289                 | EF_NODEPTHTEST)
 290                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 291         for (entity e = this; e; e = e.weaponchild)
 292         {
 293                 e.drawmask = mask;
 294                 e.alpha = a;
 295                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 296                 e.glowmod = g;
 297                 e.csqcmodel_effects = fx;
 298                 CSQCModel_Effects_Apply(e);
 299         }
 300         {
 301                 static string name_last;
 302                 string name = wep.mdl;
 303                 bool swap = name != name_last;
 304                 // if (swap)
 305                 {
 306                         name_last = name;
 307                         CL_WeaponEntity_SetModel(this, name, swap);
 308                         this.viewmodel_origin = this.origin;
 309                         this.viewmodel_angles = this.angles;
 310                 }
 311                 anim_update(this);
 312                 if (!this.animstate_override && !this.animstate_looping)
 313                         anim_set(this, this.anim_idle, true, false, false);
 314         }
 315         float f = 0; // 0..1; 0: fully active
 316         float rate = STAT(WEAPONRATEFACTOR);
 317         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 318         if (eta <= 0) f = this.weapon_eta_last;
 319         else switch (this.state)
 320         {
 321                 case WS_RAISE:
 322                 {
 323                         f = eta / max(eta, this.weapon_switchdelay);
 324                         break;
 325                 }
 326                 case WS_DROP:
 327                 {
 328                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 329                         break;
 330                 }
 331                 case WS_CLEAR:
 332                 {
 333                         f = 1;
 334                         break;
 335                 }
 336         }
 337         this.weapon_eta_last = f;
 338         this.origin = this.viewmodel_origin;
 339         this.angles = this.viewmodel_angles;
 340         this.angles_x = (-90 * f * f);
 341         viewmodel_animate(this);
 342         setorigin(this, this.origin);
 343 }
 344
 345 entity viewmodel;
 346 STATIC_INIT(viewmodel) {
 347     viewmodel = new(viewmodel);
 348 }
 349
 350 void Porto_Draw(entity this);
 351 STATIC_INIT(Porto)
 352 {
 353         entity e = new_pure(porto);
 354         e.draw = Porto_Draw;
 355         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 356 }
 357
 358 const int polyline_length = 16;
 359 vector polyline[polyline_length];
 360 void Porto_Draw(entity this)
 361 {
 362         if (activeweapon != WEP_PORTO) return;
 363         if (spectatee_status) return;
 364         if (WEP_CVAR(porto, secondary)) return;
 365         if (intermission == 1) return;
 366         if (intermission == 2) return;
 367         if (STAT(HEALTH) <= 0) return;
 368
 369         vector pos = view_origin;
 370         vector dir = view_forward;
 371         if (angles_held_status)
 372         {
 373                 makevectors(angles_held);
 374                 dir = v_forward;
 375         }
 376
 377         polyline[0] = pos;
 378
 379         int portal_number = 0, portal1_idx = 1, portal_max = 2;
 380         int n = 1 + 2;  // 2 lines == 3 points
 381         for (int idx = 0; idx < n && idx < polyline_length - 1; )
 382         {
 383                 traceline(pos, pos + 65536 * dir, true, this);
 384                 dir = reflect(dir, trace_plane_normal);
 385                 pos = trace_endpos;
 386                 polyline[++idx] = pos;
 387                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 388                 {
 389                         n += 1;
 390                         continue;
 391                 }
 392                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 393                 {
 394                         n = max(2, idx);
 395                         break;
 396                 }
 397                 // check size
 398                 {
 399                         vector ang = vectoangles2(trace_plane_normal, dir);
 400                         ang.x = -ang.x;
 401                         makevectors(ang);
 402                         if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 403                         {
 404                                 n = max(2, idx);
 405                                 break;
 406                         }
 407                 }
 408                 portal_number += 1;
 409                 if (portal_number >= portal_max) break;
 410                 if (portal_number == 1) portal1_idx = idx;
 411         }
 412         for (int idx = 0; idx < n - 1; ++idx)
 413         {
 414                 vector p = polyline[idx], q = polyline[idx + 1];
 415                 if (idx == 0) p -= view_up * 16;  // line from player
 416                 vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 417                 Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 418         }
 419 }
 420
 421 float drawtime;
 422 float avgspeed;
 423 vector GetCurrentFov(float fov)
 424 {
 425         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 426         float velocityzoom, curspeed;
 427         vector v;
 428
 429         zoomsensitivity = autocvar_cl_zoomsensitivity;
 430         zoomfactor = autocvar_cl_zoomfactor;
 431         if(zoomfactor < 1 || zoomfactor > 30)
 432                 zoomfactor = 2.5;
 433         zoomspeed = autocvar_cl_zoomspeed;
 434         if(zoomspeed >= 0)
 435         if(zoomspeed < 0.5 || zoomspeed > 16)
 436                         zoomspeed = 3.5;
 437
 438         zoomdir = button_zoom;
 439         if(hud == HUD_NORMAL)
 440         if(switchweapon == activeweapon)
 441         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 442                 zoomdir += button_attack2;
 443         if(spectatee_status > 0 || isdemo())
 444         {
 445                 if(spectatorbutton_zoom)
 446                 {
 447                         if(zoomdir)
 448                                 zoomdir = 0;
 449                         else
 450                                 zoomdir = 1;
 451                 }
 452                 // fteqcc failed twice here already, don't optimize this
 453         }
 454
 455         if(zoomdir) { zoomin_effect = 0; }
 456
 457         if(camera_active)
 458         {
 459                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 460         }
 461         else if(autocvar_cl_spawnzoom && zoomin_effect)
 462         {
 463                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 464
 465                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 466                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 467                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 468         }
 469         else
 470         {
 471                 if(zoomspeed < 0) // instant zoom
 472                 {
 473                         if(zoomdir)
 474                                 current_viewzoom = 1 / zoomfactor;
 475                         else
 476                                 current_viewzoom = 1;
 477                 }
 478                 else
 479                 {
 480                         if(zoomdir)
 481                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 482                         else
 483                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 484                 }
 485         }
 486
 487         if(almost_equals(current_viewzoom, 1))
 488                 current_zoomfraction = 0;
 489         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 490                 current_zoomfraction = 1;
 491         else
 492                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 493
 494         if(zoomsensitivity < 1)
 495                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 496         else
 497                 setsensitivityscale(1);
 498
 499         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 500         {
 501                 if(intermission) { curspeed = 0; }
 502                 else
 503                 {
 504
 505                         makevectors(view_angles);
 506                         v = pmove_vel;
 507                         if(csqcplayer)
 508                                 v = csqcplayer.velocity;
 509
 510                         switch(autocvar_cl_velocityzoom_type)
 511                         {
 512                                 case 3: curspeed = max(0, v_forward * v); break;
 513                                 case 2: curspeed = (v_forward * v); break;
 514                                 case 1: default: curspeed = vlen(v); break;
 515                         }
 516                 }
 517
 518                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 519                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 520                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 521
 522                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 523         }
 524         else
 525                 velocityzoom = 1;
 526
 527         float frustumx, frustumy, fovx, fovy;
 528         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 529         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 530         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 531         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 532
 533         return '1 0 0' * fovx + '0 1 0' * fovy;
 534 }
 535
 536 vector GetViewLocationFOV(float fov)
 537 {
 538         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 539         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 540         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 541         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 542         return '1 0 0' * fovx + '0 1 0' * fovy;
 543 }
 544
 545 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 546 {
 547         float fovx, fovy;
 548         float width = (ov_worldmax.x - ov_worldmin.x);
 549         float height = (ov_worldmax.y - ov_worldmin.y);
 550         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 551         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 552         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 553         return '1 0 0' * fovx + '0 1 0' * fovy;
 554 }
 555
 556 // this function must match W_SetupShot!
 557 float zoomscript_caught;
 558
 559 vector wcross_origin;
 560 float wcross_scale_prev, wcross_alpha_prev;
 561 vector wcross_color_prev;
 562 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 563 vector wcross_color_goal_prev;
 564 float wcross_changedonetime;
 565
 566 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 567 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 568 float wcross_name_changestarttime, wcross_name_changedonetime;
 569 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 570
 571 float wcross_ring_prev;
 572
 573 entity trueaim;
 574 entity trueaim_rifle;
 575
 576 const float SHOTTYPE_HITTEAM = 1;
 577 const float SHOTTYPE_HITOBSTRUCTION = 2;
 578 const float SHOTTYPE_HITWORLD = 3;
 579 const float SHOTTYPE_HITENEMY = 4;
 580
 581 void TrueAim_Init()
 582 {
 583         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 584         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 585 }
 586
 587 float EnemyHitCheck()
 588 {
 589         float t, n;
 590         wcross_origin = project_3d_to_2d(trace_endpos);
 591         wcross_origin.z = 0;
 592         if(trace_ent)
 593                 n = trace_ent.entnum;
 594         else
 595                 n = trace_networkentity;
 596         if(n < 1)
 597                 return SHOTTYPE_HITWORLD;
 598         if(n > maxclients)
 599                 return SHOTTYPE_HITWORLD;
 600         t = entcs_GetTeam(n - 1);
 601         if(teamplay)
 602                 if(t == myteam)
 603                         return SHOTTYPE_HITTEAM;
 604         if(t == NUM_SPECTATOR)
 605                 return SHOTTYPE_HITWORLD;
 606         return SHOTTYPE_HITENEMY;
 607 }
 608
 609 float TrueAimCheck()
 610 {
 611         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 612         vector vecs, trueaimpoint, w_shotorg;
 613         vector mi, ma, dv;
 614         float shottype;
 615         entity ta;
 616         float mv;
 617
 618         mi = ma = '0 0 0';
 619         ta = trueaim;
 620         mv = MOVE_NOMONSTERS;
 621
 622         switch(activeweapon) // WEAPONTODO
 623         {
 624                 case WEP_TUBA: // no aim
 625                 case WEP_PORTO: // shoots from eye
 626                 case WEP_NEXBALL: // shoots from eye
 627                 case WEP_HOOK: // no trueaim
 628                 case WEP_MORTAR: // toss curve
 629                         return SHOTTYPE_HITWORLD;
 630                 case WEP_VORTEX:
 631                 case WEP_VAPORIZER:
 632                         mv = MOVE_NORMAL;
 633                         break;
 634                 case WEP_RIFLE:
 635                         ta = trueaim_rifle;
 636                         mv = MOVE_NORMAL;
 637                         if(zoomscript_caught)
 638                         {
 639                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 640                                 return EnemyHitCheck();
 641                         }
 642                         break;
 643                 case WEP_DEVASTATOR: // projectile has a size!
 644                         mi = '-3 -3 -3';
 645                         ma = '3 3 3';
 646                         break;
 647                 case WEP_FIREBALL: // projectile has a size!
 648                         mi = '-16 -16 -16';
 649                         ma = '16 16 16';
 650                         break;
 651                 case WEP_SEEKER: // projectile has a size!
 652                         mi = '-2 -2 -2';
 653                         ma = '2 2 2';
 654                         break;
 655                 case WEP_ELECTRO: // projectile has a size!
 656                         mi = '0 0 -3';
 657                         ma = '0 0 -3';
 658                         break;
 659         }
 660
 661         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 662
 663         vecs = decompressShotOrigin(STAT(SHOTORG));
 664
 665         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 666         trueaimpoint = trace_endpos;
 667
 668         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 669                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 670
 671         if(vecs.x > 0)
 672                 vecs.y = -vecs.y;
 673         else
 674                 vecs = '0 0 0';
 675
 676         dv = view_right * vecs.y + view_up * vecs.z;
 677         w_shotorg = traceorigin + dv;
 678
 679         // now move the vecs forward as much as requested if possible
 680         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 681         w_shotorg = trace_endpos - view_forward * nudge;
 682
 683         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 684         shottype = EnemyHitCheck();
 685         if(shottype != SHOTTYPE_HITWORLD)
 686                 return shottype;
 687
 688 #if 0
 689         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 690         // or rather, I know why, but see no fix
 691         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 692                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 693                 return SHOTTYPE_HITOBSTRUCTION;
 694 #endif
 695
 696         return SHOTTYPE_HITWORLD;
 697 }
 698
 699 void PostInit();
 700 void CSQC_Demo_Camera();
 701 float HUD_WouldDrawScoreboard();
 702 float camera_mode;
 703 const float CAMERA_FREE = 1;
 704 const float CAMERA_CHASE = 2;
 705 float reticle_type;
 706 string reticle_image;
 707 string NextFrameCommand;
 708
 709 vector freeze_org, freeze_ang;
 710 entity nightvision_noise, nightvision_noise2;
 711
 712 const float MAX_TIME_DIFF = 5;
 713 float pickup_crosshair_time, pickup_crosshair_size;
 714 float hitindication_crosshair_size;
 715 float use_vortex_chargepool;
 716
 717 float myhealth, myhealth_prev;
 718 float myhealth_flash;
 719
 720 float old_blurradius, old_bluralpha;
 721 float old_sharpen_intensity;
 722
 723 vector myhealth_gentlergb;
 724
 725 float contentavgalpha, liquidalpha_prev;
 726 vector liquidcolor_prev;
 727
 728 float eventchase_current_distance;
 729 float eventchase_running;
 730 bool WantEventchase(entity this)
 731 {
 732         if(autocvar_cl_orthoview)
 733                 return false;
 734         if(intermission)
 735                 return true;
 736         if(this.viewloc)
 737                 return true;
 738         if(spectatee_status >= 0)
 739         {
 740                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 741                         return true;
 742                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 743                         return true;
 744                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 745                 {
 746                         if(autocvar_cl_eventchase_death == 2)
 747                         {
 748                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 749                                 if(this.velocity == '0 0 0' || eventchase_running)
 750                                         return true;
 751                         }
 752                         else return true;
 753                 }
 754         }
 755         return false;
 756 }
 757
 758 void HUD_Crosshair_Vehicle()
 759 {
 760         if(hud != HUD_BUMBLEBEE_GUN)
 761         {
 762                 Vehicle info = Vehicles_from(hud);
 763                 info.vr_crosshair(info);
 764         }
 765 }
 766
 767 vector damage_blurpostprocess, content_blurpostprocess;
 768
 769 float unaccounted_damage = 0;
 770 void UpdateDamage()
 771 {
 772         // accumulate damage with each stat update
 773         static float damage_total_prev = 0;
 774         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 775         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 776         damage_total_prev = damage_total;
 777
 778         static float damage_dealt_time_prev = 0;
 779         float damage_dealt_time = STAT(HIT_TIME);
 780         if (damage_dealt_time != damage_dealt_time_prev)
 781         {
 782                 unaccounted_damage += unaccounted_damage_new;
 783                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 784         }
 785         damage_dealt_time_prev = damage_dealt_time;
 786
 787         // prevent hitsound when switching spectatee
 788         static float spectatee_status_prev = 0;
 789         if (spectatee_status != spectatee_status_prev)
 790                 unaccounted_damage = 0;
 791         spectatee_status_prev = spectatee_status;
 792 }
 793
 794 void HitSound()
 795 {
 796         // varying sound pitch
 797
 798         static float hitsound_time_prev = 0;
 799         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 800         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 801         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 802         {
 803                 if (autocvar_cl_hitsound && unaccounted_damage)
 804                 {
 805                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 806                         float a = autocvar_cl_hitsound_max_pitch;
 807                         float b = autocvar_cl_hitsound_min_pitch;
 808                         float c = autocvar_cl_hitsound_nom_damage;
 809                         float x = unaccounted_damage;
 810                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 811
 812                         // if sound variation is disabled, set pitch_shift to 1
 813                         if (autocvar_cl_hitsound == 1)
 814                                 pitch_shift = 1;
 815
 816                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 817                         if (autocvar_cl_hitsound == 3)
 818                         {
 819                                 float mirror_value = (a-b)/2 + b;
 820                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 821                         }
 822
 823                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 824
 825                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 826                         // todo: normalize sound pressure levels? seems unnecessary
 827
 828                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 829                 }
 830                 unaccounted_damage = 0;
 831                 hitsound_time_prev = time;
 832         }
 833
 834         static float typehit_time_prev = 0;
 835         float typehit_time = STAT(TYPEHIT_TIME);
 836         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 837         {
 838                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 839                 typehit_time_prev = typehit_time;
 840         }
 841 }
 842
 843 vector crosshair_getcolor(entity this, float health_stat)
 844 {
 845         static float rainbow_last_flicker;
 846         static vector rainbow_prev_color;
 847         vector wcross_color = '0 0 0';
 848         switch(autocvar_crosshair_color_special)
 849         {
 850                 case 1: // crosshair_color_per_weapon
 851                 {
 852                         if(this)
 853                         {
 854                                 wcross_color = this.wpcolor;
 855                                 break;
 856                         }
 857                         else { goto normalcolor; }
 858                 }
 859
 860                 case 2: // crosshair_color_by_health
 861                 {
 862                         float x = health_stat;
 863
 864                         //x = red
 865                         //y = green
 866                         //z = blue
 867
 868                         wcross_color.z = 0;
 869
 870                         if(x > 200)
 871                         {
 872                                 wcross_color.x = 0;
 873                                 wcross_color.y = 1;
 874                         }
 875                         else if(x > 150)
 876                         {
 877                                 wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 878                                 wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 879                         }
 880                         else if(x > 100)
 881                         {
 882                                 wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 883                                 wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 884                                 wcross_color.z = 1 - (x-100)*0.02;
 885                         }
 886                         else if(x > 50)
 887                         {
 888                                 wcross_color.x = 1;
 889                                 wcross_color.y = 1;
 890                                 wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 891                         }
 892                         else if(x > 20)
 893                         {
 894                                 wcross_color.x = 1;
 895                                 wcross_color.y = (x-20)*90/27/100;
 896                                 wcross_color.z = (x-20)*90/27/100 * 0.2;
 897                         }
 898                         else
 899                         {
 900                                 wcross_color.x = 1;
 901                                 wcross_color.y = 0;
 902                         }
 903                         break;
 904                 }
 905
 906                 case 3: // crosshair_color_rainbow
 907                 {
 908                         if(time >= rainbow_last_flicker)
 909                         {
 910                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 911                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 912                         }
 913                         wcross_color = rainbow_prev_color;
 914                         break;
 915                 }
 916 LABEL(normalcolor)
 917                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 918         }
 919
 920         return wcross_color;
 921 }
 922
 923 void HUD_Crosshair(entity this)
 924 {
 925         float f, i, j;
 926         vector v;
 927         if(!scoreboard_active && !camera_active && intermission != 2 &&
 928                 spectatee_status != -1 && !csqcplayer.viewloc &&
 929                 !HUD_MinigameMenu_IsOpened() )
 930         {
 931                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 932                         return;
 933
 934                 if (hud != HUD_NORMAL)
 935                 {
 936                         HUD_Crosshair_Vehicle();
 937                         return;
 938                 }
 939
 940                 string wcross_style;
 941                 float wcross_alpha, wcross_resolution;
 942                 wcross_style = autocvar_crosshair;
 943                 if (wcross_style == "0")
 944                         return;
 945                 wcross_resolution = autocvar_crosshair_size;
 946                 if (wcross_resolution == 0)
 947                         return;
 948                 wcross_alpha = autocvar_crosshair_alpha;
 949                 if (wcross_alpha == 0)
 950                         return;
 951
 952                 // TrueAim check
 953                 float shottype;
 954
 955                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 956                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 957                 wcross_origin.z = 0;
 958                 if(autocvar_crosshair_hittest)
 959                 {
 960                         vector wcross_oldorigin;
 961                         wcross_oldorigin = wcross_origin;
 962                         shottype = TrueAimCheck();
 963                         if(shottype == SHOTTYPE_HITWORLD)
 964                         {
 965                                 v = wcross_origin - wcross_oldorigin;
 966                                 v.x /= vid_conwidth;
 967                                 v.y /= vid_conheight;
 968                                 if(vlen(v) > 0.01)
 969                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 970                         }
 971                         if(!autocvar_crosshair_hittest_showimpact)
 972                                 wcross_origin = wcross_oldorigin;
 973                 }
 974                 else
 975                         shottype = SHOTTYPE_HITWORLD;
 976
 977                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 978                 string wcross_name = "";
 979                 float wcross_scale, wcross_blur;
 980
 981         entity e = this; // wtf?
 982                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 983                 {
 984                         e = switchingweapon;
 985                         if(e)
 986                         {
 987                                 if(autocvar_crosshair_per_weapon)
 988                                 {
 989                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 990                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 991                                         //if (wcross_resolution == 0)
 992                                                 //return;
 993
 994                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 995                                         wcross_resolution *= e.w_crosshair_size;
 996                                         wcross_name = e.w_crosshair;
 997                                 }
 998                         }
 999                 }
1000
1001                 if(wcross_name == "")
1002                         wcross_name = strcat("gfx/crosshair", wcross_style);
1003
1004                 // MAIN CROSSHAIR COLOR DECISION
1005                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1006
1007                 if(autocvar_crosshair_effect_scalefade)
1008                 {
1009                         wcross_scale = wcross_resolution;
1010                         wcross_resolution = 1;
1011                 }
1012                 else
1013                 {
1014                         wcross_scale = 1;
1015                 }
1016
1017                 if(autocvar_crosshair_pickup)
1018                 {
1019                         float stat_pickup_time = STAT(LAST_PICKUP);
1020
1021                         if(pickup_crosshair_time < stat_pickup_time)
1022                         {
1023                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1024                                         pickup_crosshair_size = 1;
1025
1026                                 pickup_crosshair_time = stat_pickup_time;
1027                         }
1028
1029                         if(pickup_crosshair_size > 0)
1030                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1031                         else
1032                                 pickup_crosshair_size = 0;
1033
1034                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1035                 }
1036
1037                 // todo: make crosshair hit indication dependent on damage dealt
1038                 if(autocvar_crosshair_hitindication)
1039                 {
1040                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1041
1042                         if(unaccounted_damage)
1043                         {
1044                                 hitindication_crosshair_size = 1;
1045                         }
1046
1047                         if(hitindication_crosshair_size > 0)
1048                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1049                         else
1050                                 hitindication_crosshair_size = 0;
1051
1052                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1053                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1054                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1055                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1056                 }
1057
1058                 if(shottype == SHOTTYPE_HITENEMY)
1059                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1060                 if(shottype == SHOTTYPE_HITTEAM)
1061                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1062
1063                 f = fabs(autocvar_crosshair_effect_time);
1064                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1065                 {
1066                         wcross_changedonetime = time + f;
1067                 }
1068                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1069                 {
1070                         wcross_name_changestarttime = time;
1071                         wcross_name_changedonetime = time + f;
1072                         if(wcross_name_goal_prev_prev)
1073                                 strunzone(wcross_name_goal_prev_prev);
1074                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1075                         wcross_name_goal_prev = strzone(wcross_name);
1076                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1077                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1078                         wcross_resolution_goal_prev = wcross_resolution;
1079                 }
1080
1081                 wcross_scale_goal_prev = wcross_scale;
1082                 wcross_alpha_goal_prev = wcross_alpha;
1083                 wcross_color_goal_prev = wcross_color;
1084
1085                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1086                 {
1087                         wcross_blur = 1;
1088                         wcross_alpha *= 0.75;
1089                 }
1090                 else
1091                         wcross_blur = 0;
1092                 // *_prev is at time-frametime
1093                 // * is at wcross_changedonetime+f
1094                 // what do we have at time?
1095                 if(time < wcross_changedonetime)
1096                 {
1097                         f = frametime / (wcross_changedonetime - time + frametime);
1098                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1099                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1100                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1101                 }
1102
1103                 wcross_scale_prev = wcross_scale;
1104                 wcross_alpha_prev = wcross_alpha;
1105                 wcross_color_prev = wcross_color;
1106
1107                 MUTATOR_CALLHOOK(UpdateCrosshair);
1108
1109                 wcross_scale *= 1 - autocvar__menu_alpha;
1110                 wcross_alpha *= 1 - autocvar__menu_alpha;
1111                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1112
1113                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1114                 {
1115                         // crosshair rings for weapon stats
1116                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1117                         {
1118                                 // declarations and stats
1119                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1120                                 string ring_image = string_null, ring_inner_image = string_null;
1121                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1122
1123                                 ring_scale = autocvar_crosshair_ring_size;
1124
1125                                 float weapon_clipload, weapon_clipsize;
1126                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1127                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1128
1129                                 float ok_ammo_charge, ok_ammo_chargepool;
1130                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1131                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1132
1133                                 float vortex_charge, vortex_chargepool;
1134                                 vortex_charge = STAT(VORTEX_CHARGE);
1135                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1136
1137                                 float arc_heat = STAT(ARC_HEAT);
1138
1139                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1140                                         vortex_charge_movingavg = vortex_charge;
1141
1142
1143                                 // handle the values
1144                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1145                                 {
1146                                         if (vortex_chargepool || use_vortex_chargepool) {
1147                                                 use_vortex_chargepool = 1;
1148                                                 ring_inner_value = vortex_chargepool;
1149                                         } else {
1150                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1151                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1152                                         }
1153
1154                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1155                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1156                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1157
1158                                         // draw the outer ring to show the current charge of the weapon
1159                                         ring_value = vortex_charge;
1160                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1161                                         ring_rgb = wcross_color;
1162                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1163                                 }
1164                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1165                                 {
1166                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1167                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1168                                         ring_rgb = wcross_color;
1169                                         ring_image = "gfx/crosshair_ring.tga";
1170                                 }
1171                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1172                                 {
1173                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1174                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1175                                         ring_rgb = wcross_color;
1176                                         ring_image = "gfx/crosshair_ring.tga";
1177                                 }
1178                                 else if (ok_ammo_charge)
1179                                 {
1180                                         ring_value = ok_ammo_chargepool;
1181                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1182                                         ring_rgb = wcross_color;
1183                                         ring_image = "gfx/crosshair_ring.tga";
1184                                 }
1185                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1186                                 {
1187                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1188                                         ring_scale = autocvar_crosshair_ring_reload_size;
1189                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1190                                         ring_rgb = wcross_color;
1191
1192                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1193                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1194                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1195                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1196                                         else
1197                                                 ring_image = "gfx/crosshair_ring.tga";
1198                                 }
1199                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1200                                 {
1201                                         ring_value = arc_heat;
1202                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1203                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1204                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1205                                         ring_image = "gfx/crosshair_ring.tga";
1206                                 }
1207
1208                                 // if in weapon switch animation, fade ring out/in
1209                                 if(autocvar_crosshair_effect_time > 0)
1210                                 {
1211                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1212                                         if (f >= 1)
1213                                         {
1214                                                 wcross_ring_prev = ((ring_image) ? true : false);
1215                                         }
1216
1217                                         if(wcross_ring_prev)
1218                                         {
1219                                                 if(f < 1)
1220                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1221                                         }
1222                                         else
1223                                         {
1224                                                 if(f < 1)
1225                                                         ring_alpha *= bound(0, f, 1);
1226                                         }
1227                                 }
1228
1229                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1230                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1231
1232                                 if (ring_value)
1233                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1234                         }
1235
1236 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1237                         MACRO_BEGIN { \
1238                                 if(wcross_blur > 0) \
1239                                 { \
1240                                         for(i = -2; i <= 2; ++i) \
1241                                         for(j = -2; j <= 2; ++j) \
1242                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1243                                 } \
1244                                 else \
1245                                 { \
1246                                         M(0,0,sz,wcross_name,wcross_alpha); \
1247                                 } \
1248                         } MACRO_END
1249
1250 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1251                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1252
1253 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1254                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1255
1256                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1257                         {
1258                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1259                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1260                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1261                                 f = 1 - f;
1262                         }
1263                         else
1264                         {
1265                                 f = 1;
1266                         }
1267                         wcross_name_alpha_goal_prev = f;
1268
1269                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1270                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1271
1272                         if(autocvar_crosshair_dot)
1273                         {
1274                                 vector wcross_color_old;
1275                                 wcross_color_old = wcross_color;
1276
1277                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1278                                         wcross_color = stov(autocvar_crosshair_dot_color);
1279
1280                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1281                                 // FIXME why don't we use wcross_alpha here?
1282                                 wcross_color = wcross_color_old;
1283                         }
1284                 }
1285         }
1286         else
1287         {
1288                 wcross_scale_prev = 0;
1289                 wcross_alpha_prev = 0;
1290                 wcross_scale_goal_prev = 0;
1291                 wcross_alpha_goal_prev = 0;
1292                 wcross_changedonetime = 0;
1293                 if(wcross_name_goal_prev)
1294                         strunzone(wcross_name_goal_prev);
1295                 wcross_name_goal_prev = string_null;
1296                 if(wcross_name_goal_prev_prev)
1297                         strunzone(wcross_name_goal_prev_prev);
1298                 wcross_name_goal_prev_prev = string_null;
1299                 wcross_name_changestarttime = 0;
1300                 wcross_name_changedonetime = 0;
1301                 wcross_name_alpha_goal_prev = 0;
1302                 wcross_name_alpha_goal_prev_prev = 0;
1303                 wcross_resolution_goal_prev = 0;
1304                 wcross_resolution_goal_prev_prev = 0;
1305         }
1306 }
1307
1308 void HUD_Draw(entity this)
1309 {
1310         if(!intermission)
1311         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1312         {
1313                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, MUTATOR_ARGV(0, vector), autocvar_hud_colorflash_alpha * MUTATOR_ARGV(0, float), DRAWFLAG_ADDITIVE);
1314         }
1315         else if(STAT(FROZEN))
1316         {
1317                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1318         }
1319         if(!intermission)
1320         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1321         {
1322                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1323                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1324         }
1325         else if(STAT(REVIVE_PROGRESS))
1326         {
1327                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1328                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1329         }
1330
1331         if(autocvar_r_letterbox == 0)
1332                 if(autocvar_viewsize < 120)
1333                 {
1334                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1335                                 Accuracy_LoadLevels();
1336
1337                         HUD_Main();
1338                         HUD_DrawScoreboard();
1339                 }
1340
1341         // crosshair goes VERY LAST
1342         UpdateDamage();
1343         HUD_Crosshair(this);
1344         HitSound();
1345 }
1346
1347 bool ov_enabled;
1348 float oldr_nearclip;
1349 float oldr_farclip_base;
1350 float oldr_farclip_world;
1351 float oldr_novis;
1352 float oldr_useportalculling;
1353 float oldr_useinfinitefarclip;
1354
1355 void cl_notice_run();
1356 float prev_myteam;
1357 int lasthud;
1358 float vh_notice_time;
1359 void WaypointSprite_Load();
1360 void CSQC_UpdateView(float w, float h)
1361 {
1362     SELFPARAM();
1363     TC(int, w); TC(int, h);
1364         entity e;
1365         float fov;
1366         float f;
1367         vector vf_size, vf_min;
1368         float a;
1369
1370         execute_next_frame();
1371
1372         ++framecount;
1373
1374         stats_get();
1375         hud = STAT(HUD);
1376
1377         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1378                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1379
1380         lasthud = hud;
1381
1382         if(autocvar__hud_showbinds_reload) // menu can set this one
1383         {
1384                 db_close(binddb);
1385                 binddb = db_create();
1386                 cvar_set("_hud_showbinds_reload", "0");
1387         }
1388
1389         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1390                 view_quality = getproperty(VF_MINFPS_QUALITY);
1391         else
1392                 view_quality = 1;
1393
1394         // this needs to be updated manually now due to the destruction of engine physics stats
1395         if(!isdemo() && autocvar_slowmo != STAT(MOVEVARS_TIMESCALE))
1396                 cvar_set("slowmo", ftos(STAT(MOVEVARS_TIMESCALE)));
1397
1398         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1399         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1400
1401         vf_size = getpropertyvec(VF_SIZE);
1402         vf_min = getpropertyvec(VF_MIN);
1403         vid_width = vf_size.x;
1404         vid_height = vf_size.y;
1405
1406         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1407         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1408
1409         WaypointSprite_Load();
1410
1411         CSQCPlayer_SetCamera();
1412
1413         if(player_localentnum <= maxclients) // is it a client?
1414                 current_player = player_localentnum - 1;
1415         else // then player_localentnum is the vehicle I'm driving
1416                 current_player = player_localnum;
1417         myteam = entcs_GetTeam(current_player);
1418
1419         if(myteam != prev_myteam)
1420         {
1421                 myteamcolors = colormapPaletteColor(myteam, 1);
1422                 FOREACH(hud_panels, true, it.update_time = time);
1423                 prev_myteam = myteam;
1424         }
1425
1426         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1427
1428         float is_dead = (STAT(HEALTH) <= 0);
1429
1430         // FIXME do we need this hack?
1431         if(isdemo())
1432         {
1433                 // in demos, input_buttons do not work
1434                 button_zoom = (autocvar__togglezoom == "-");
1435         }
1436         else if(button_zoom
1437                 && autocvar_cl_unpress_zoom_on_death
1438                 && (spectatee_status >= 0)
1439                 && (is_dead || intermission))
1440         {
1441                 // no zoom while dead or in intermission please
1442                 localcmd("-zoom\n");
1443                 button_zoom = false;
1444         }
1445
1446         // event chase camera
1447         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1448         {
1449                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1450                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1451                 entity gen = world;
1452
1453                 float vehicle_viewdist = 0;
1454                 vector vehicle_viewofs = '0 0 0';
1455
1456                 if(vehicle_chase)
1457                 {
1458                         if(hud != HUD_BUMBLEBEE_GUN)
1459                         {
1460                                 Vehicle info = Vehicles_from(hud);
1461                                 vehicle_viewdist = info.height;
1462                                 vehicle_viewofs = info.view_ofs;
1463                         }
1464                 }
1465
1466                 if(ons_roundlost)
1467                 {
1468                         FOREACH_ENTITY_CLASS("onslaught_generator", it.health <= 0, {
1469                                 gen = it;
1470                                 break;
1471                         });
1472                         if(!gen)
1473                                 ons_roundlost = false; // don't enforce the 3rd person camera if there is no dead generator to show
1474                 }
1475                 if(WantEventchase(this) || (!autocvar_cl_orthoview && ons_roundlost))
1476                 {
1477                         eventchase_running = true;
1478
1479                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1480                         if(!local_player)
1481                                 local_player = this; // fall back!
1482
1483                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1484                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1485                         if(ons_roundlost) { current_view_origin = gen.origin; }
1486
1487                         // detect maximum viewoffset and use it
1488                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1489                         if(vehicle_chase)
1490                         {
1491                                 if(vehicle_viewofs)
1492                                         view_offset = vehicle_viewofs;
1493                                 else
1494                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1495                         }
1496                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1497
1498                         if(view_offset)
1499                         {
1500                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1501                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1502                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1503                         }
1504
1505                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1506                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1507                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1508                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1509
1510                         // make the camera smooth back
1511                         float chase_distance = autocvar_cl_eventchase_distance;
1512                         if(vehicle_chase)
1513                         {
1514                                 if(vehicle_viewofs)
1515                                         chase_distance = vehicle_viewdist;
1516                                 else
1517                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1518                         }
1519                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1520
1521                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1522                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1523                         else if(eventchase_current_distance != chase_distance)
1524                                 eventchase_current_distance = chase_distance;
1525
1526                         makevectors(view_angles);
1527
1528                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1529                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1530
1531                         // If the boxtrace fails, revert back to line tracing.
1532                         if(!local_player.viewloc)
1533                         if(trace_startsolid)
1534                         {
1535                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1536                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1537                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1538                         }
1539                         else { setproperty(VF_ORIGIN, trace_endpos); }
1540
1541                         if(!local_player.viewloc)
1542                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1543                 }
1544                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1545                 {
1546                         eventchase_running = false;
1547                         cvar_set("chase_active", "0");
1548                         eventchase_current_distance = 0; // start from 0 next time
1549                 }
1550         }
1551         // workaround for camera stuck between player's legs when using chase_active 1
1552         // because the engine stops updating the chase_active camera when the game ends
1553         else if(intermission)
1554         {
1555                 cvar_settemp("chase_active", "-1");
1556                 eventchase_current_distance = 0;
1557         }
1558
1559         // do lockview after event chase camera so that it still applies whenever necessary.
1560         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1561         {
1562                 setproperty(VF_ORIGIN, freeze_org);
1563                 setproperty(VF_ANGLES, freeze_ang);
1564         }
1565         else
1566         {
1567                 freeze_org = getpropertyvec(VF_ORIGIN);
1568                 freeze_ang = getpropertyvec(VF_ANGLES);
1569         }
1570
1571         WarpZone_FixView();
1572         //WarpZone_FixPMove();
1573
1574         vector ov_org = '0 0 0';
1575         vector ov_mid = '0 0 0';
1576         vector ov_worldmin = '0 0 0';
1577         vector ov_worldmax = '0 0 0';
1578         if(autocvar_cl_orthoview)
1579         {
1580                 ov_worldmin = mi_picmin;
1581                 ov_worldmax = mi_picmax;
1582
1583                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1584                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1585                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1586
1587                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1588                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1589
1590                 float ov_nearest = vlen(ov_org - vec3(
1591                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1592                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1593                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1594                 ));
1595
1596                 float ov_furthest = 0;
1597                 float dist = 0;
1598
1599                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1600                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1601                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1602                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1603                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1604                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1605                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1606                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1607
1608                 if(!ov_enabled)
1609                 {
1610                         oldr_nearclip = cvar("r_nearclip");
1611                         oldr_farclip_base = cvar("r_farclip_base");
1612                         oldr_farclip_world = cvar("r_farclip_world");
1613                         oldr_novis = cvar("r_novis");
1614                         oldr_useportalculling = cvar("r_useportalculling");
1615                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1616                 }
1617
1618                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1619                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1620                 cvar_settemp("r_farclip_world", "0");
1621                 cvar_settemp("r_novis", "1");
1622                 cvar_settemp("r_useportalculling", "0");
1623                 cvar_settemp("r_useinfinitefarclip", "0");
1624
1625                 setproperty(VF_ORIGIN, ov_org);
1626                 setproperty(VF_ANGLES, '90 0 0');
1627
1628                 ov_enabled = true;
1629
1630                 #if 0
1631                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1632                         vtos(ov_org),
1633                         vtos(getpropertyvec(VF_ANGLES)),
1634                         ov_distance,
1635                         ov_nearest,
1636                         ov_furthest);
1637                 #endif
1638         }
1639         else
1640         {
1641                 if(ov_enabled)
1642                 {
1643                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1644                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1645                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1646                         cvar_set("r_novis", ftos(oldr_novis));
1647                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1648                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1649                 }
1650                 ov_enabled = false;
1651         }
1652
1653         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1654         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1655         viewmodel_draw(viewmodel);
1656
1657         // Render the Scene
1658         view_origin = getpropertyvec(VF_ORIGIN);
1659         view_angles = getpropertyvec(VF_ANGLES);
1660         makevectors(view_angles);
1661         view_forward = v_forward;
1662         view_right = v_right;
1663         view_up = v_up;
1664
1665 #ifdef BLURTEST
1666         if(time > blurtest_time0 && time < blurtest_time1)
1667         {
1668                 float r, t;
1669
1670                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1671                 r = t * blurtest_radius;
1672                 f = 1 / pow(t, blurtest_power) - 1;
1673
1674                 cvar_set("r_glsl_postprocess", "1");
1675                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1676         }
1677         else
1678         {
1679                 cvar_set("r_glsl_postprocess", "0");
1680                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1681         }
1682 #endif
1683
1684         TargetMusic_Advance();
1685         Fog_Force();
1686
1687         if(drawtime == 0)
1688                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1689         else
1690                 drawframetime = bound(0.000001, time - drawtime, 1);
1691         drawtime = time;
1692
1693         // watch for gametype changes here...
1694         // in ParseStuffCMD the cmd isn't executed yet :/
1695         // might even be better to add the gametype to TE_CSQC_INIT...?
1696         if(!postinit)
1697                 PostInit();
1698
1699         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1700         {
1701                 if(calledhooks & HOOK_START)
1702                 {
1703                         localcmd("\ncl_hook_gameend\n");
1704                         calledhooks |= HOOK_END;
1705                 }
1706         }
1707
1708         Announcer();
1709
1710         fov = autocvar_fov;
1711         if(fov <= 59.5)
1712         {
1713                 if(!zoomscript_caught)
1714                 {
1715                         localcmd("+button9\n");
1716                         zoomscript_caught = 1;
1717                 }
1718         }
1719         else
1720         {
1721                 if(zoomscript_caught)
1722                 {
1723                         localcmd("-button9\n");
1724                         zoomscript_caught = 0;
1725                 }
1726         }
1727
1728         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1729
1730         // currently switching-to weapon (for crosshair)
1731         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1732
1733         // actually active weapon (for zoom)
1734         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1735
1736         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1737
1738         f = (serverflags & SERVERFLAG_TEAMPLAY);
1739         if(f != teamplay)
1740         {
1741                 teamplay = f;
1742                 HUD_InitScores();
1743         }
1744
1745         if(last_switchweapon != switchweapon)
1746         {
1747                 weapontime = time;
1748                 last_switchweapon = switchweapon;
1749                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1750                 {
1751                         localcmd("-zoom\n");
1752                         button_zoom = false;
1753                 }
1754                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1755                 {
1756                         localcmd("-fire\n");
1757                         localcmd("-fire2\n");
1758                         button_attack2 = false;
1759                 }
1760         }
1761         if(last_activeweapon != activeweapon)
1762         {
1763                 last_activeweapon = activeweapon;
1764
1765                 e = activeweapon;
1766                 if(e.netname != "")
1767                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1768                 else
1769                         localcmd("\ncl_hook_activeweapon none\n");
1770         }
1771
1772         // ALWAYS Clear Current Scene First
1773         clearscene();
1774
1775         setproperty(VF_ORIGIN, view_origin);
1776         setproperty(VF_ANGLES, view_angles);
1777
1778         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1779         setproperty(VF_SIZE, vf_size);
1780         setproperty(VF_MIN, vf_min);
1781
1782         // Assign Standard Viewflags
1783         // Draw the World (and sky)
1784         setproperty(VF_DRAWWORLD, 1);
1785
1786         // Set the console size vars
1787         vid_conwidth = autocvar_vid_conwidth;
1788         vid_conheight = autocvar_vid_conheight;
1789         vid_pixelheight = autocvar_vid_pixelheight;
1790
1791         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1792         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1793         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1794
1795         // Camera for demo playback
1796         if(camera_active)
1797         {
1798                 if(autocvar_camera_enable)
1799                         CSQC_Demo_Camera();
1800                 else
1801                 {
1802                         cvar_set("chase_active", ftos(chase_active_backup));
1803                         cvar_set("cl_demo_mousegrab", "0");
1804                         camera_active = false;
1805                 }
1806         }
1807         else
1808         {
1809 #ifdef CAMERATEST
1810                 if(autocvar_camera_enable)
1811 #else
1812                 if(autocvar_camera_enable && isdemo())
1813 #endif
1814                 {
1815                         // Enable required Darkplaces cvars
1816                         chase_active_backup = autocvar_chase_active;
1817                         cvar_set("chase_active", "2");
1818                         cvar_set("cl_demo_mousegrab", "1");
1819                         camera_active = true;
1820                         camera_mode = false;
1821                 }
1822         }
1823
1824         // Draw the Crosshair
1825         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1826
1827         // Draw the Engine Status Bar (the default Quake HUD)
1828         setproperty(VF_DRAWENGINESBAR, 0);
1829
1830         // Update the mouse position
1831         /*
1832            mousepos_x = vid_conwidth;
1833            mousepos_y = vid_conheight;
1834            mousepos = mousepos*0.5 + getmousepos();
1835          */
1836
1837         FOREACH_ENTITY(it.draw, it.draw(it));
1838
1839         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1840         renderscene();
1841
1842         // now switch to 2D drawing mode by calling a 2D drawing function
1843         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1844         // next R_RenderScene call
1845         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1846
1847         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1848         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1849         {
1850                 // apply night vision effect
1851                 vector tc_00, tc_01, tc_10, tc_11;
1852                 vector rgb = '0 0 0';
1853
1854                 if(!nightvision_noise)
1855                 {
1856                         nightvision_noise = new(nightvision_noise);
1857                 }
1858                 if(!nightvision_noise2)
1859                 {
1860                         nightvision_noise2 = new(nightvision_noise2);
1861                 }
1862
1863                 // color tint in yellow
1864                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1865
1866                 // draw BG
1867                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1868                 rgb = '1 1 1';
1869                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1870                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1871                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1872                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1873                 tc_11 = tc_01 + tc_10 - tc_00;
1874                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1875                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1876                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1877                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1878                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1879                 R_EndPolygon();
1880
1881                 // draw FG
1882                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1883                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1884                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1885                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1886                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1887                 tc_11 = tc_01 + tc_10 - tc_00;
1888                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1889                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1890                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1891                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1892                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1893                 R_EndPolygon();
1894         }
1895
1896         if(autocvar_cl_reticle)
1897         {
1898                 Weapon wep = activeweapon;
1899                 // Draw the aiming reticle for weapons that use it
1900                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1901                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1902                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1903                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1904                 {
1905                         // no zoom reticle while dead
1906                         reticle_type = 0;
1907                 }
1908                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1909                 {
1910                         if(reticle_image != "") { reticle_type = 2; }
1911                         else { reticle_type = 0; }
1912                 }
1913                 else if(button_zoom || zoomscript_caught)
1914                 {
1915                         // normal zoom
1916                         reticle_type = 1;
1917                 }
1918
1919                 if(reticle_type)
1920                 {
1921                         if(autocvar_cl_reticle_stretch)
1922                         {
1923                                 reticle_size.x = vid_conwidth;
1924                                 reticle_size.y = vid_conheight;
1925                                 reticle_pos.x = 0;
1926                                 reticle_pos.y = 0;
1927                         }
1928                         else
1929                         {
1930                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1931                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1932                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1933                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1934                         }
1935
1936                         if(zoomscript_caught)
1937                                 f = 1;
1938                         else
1939                                 f = current_zoomfraction;
1940
1941                         if(f)
1942                         {
1943                                 switch(reticle_type)
1944                                 {
1945                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1946                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1947                                 }
1948                         }
1949                 }
1950         }
1951         else
1952         {
1953                 if(reticle_type != 0) { reticle_type = 0; }
1954         }
1955
1956
1957         // improved polyblend
1958         if(autocvar_hud_contents)
1959         {
1960                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1961                 vector liquidcolor;
1962
1963                 switch(pointcontents(view_origin))
1964                 {
1965                         case CONTENT_WATER:
1966                                 liquidalpha = autocvar_hud_contents_water_alpha;
1967                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1968                                 incontent = 1;
1969                                 break;
1970
1971                         case CONTENT_LAVA:
1972                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1973                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1974                                 incontent = 1;
1975                                 break;
1976
1977                         case CONTENT_SLIME:
1978                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1979                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1980                                 incontent = 1;
1981                                 break;
1982
1983                         default:
1984                                 liquidalpha = 0;
1985                                 liquidcolor = '0 0 0';
1986                                 incontent = 0;
1987                                 break;
1988                 }
1989
1990                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1991                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1992                         contentfadetime = autocvar_hud_contents_fadeintime;
1993                         liquidalpha_prev = liquidalpha;
1994                         liquidcolor_prev = liquidcolor;
1995                 }
1996                 else
1997                         contentfadetime = autocvar_hud_contents_fadeouttime;
1998
1999                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2000                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2001
2002                 if(contentavgalpha)
2003                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2004
2005                 if(autocvar_hud_postprocessing)
2006                 {
2007                         if(autocvar_hud_contents_blur && contentavgalpha)
2008                         {
2009                                 content_blurpostprocess.x = 1;
2010                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2011                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2012                         }
2013                         else
2014                         {
2015                                 content_blurpostprocess.x = 0;
2016                                 content_blurpostprocess.y = 0;
2017                                 content_blurpostprocess.z = 0;
2018                         }
2019                 }
2020         }
2021
2022         if(autocvar_hud_damage && !STAT(FROZEN))
2023         {
2024                 splash_size.x = max(vid_conwidth, vid_conheight);
2025                 splash_size.y = max(vid_conwidth, vid_conheight);
2026                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2027                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2028
2029                 float myhealth_flash_temp;
2030                 myhealth = STAT(HEALTH);
2031
2032                 // fade out
2033                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2034                 // add new damage
2035                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2036
2037                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2038                 pain_threshold = autocvar_hud_damage_pain_threshold;
2039                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2040                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2041
2042                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2043                 {
2044                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2045                 }
2046
2047                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2048
2049                 if(myhealth_prev < 1)
2050                 {
2051                         if(myhealth >= 1)
2052                         {
2053                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2054                                 myhealth_flash_temp = 0;
2055                         }
2056                         else
2057                         {
2058                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2059                         }
2060                 }
2061
2062                 if(spectatee_status == -1 || intermission)
2063                 {
2064                         myhealth_flash = 0; // observing, or match ended
2065                         myhealth_flash_temp = 0;
2066                 }
2067
2068                 myhealth_prev = myhealth;
2069
2070                 // IDEA: change damage color/picture based on player model for robot/alien species?
2071                 // pro: matches model better
2072                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2073                 // maybe different reddish pics?
2074                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2075                 {
2076                         if(autocvar_cl_gentle_damage == 2)
2077                         {
2078                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2079                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2080                         }
2081                         else
2082                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2083
2084                         if(myhealth_flash_temp > 0)
2085                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2086                 }
2087                 else if(myhealth_flash_temp > 0)
2088                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2089
2090                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2091                 {
2092                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2093                         {
2094                                 damage_blurpostprocess.x = 1;
2095                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2096                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2097                         }
2098                         else
2099                         {
2100                                 damage_blurpostprocess.x = 0;
2101                                 damage_blurpostprocess.y = 0;
2102                                 damage_blurpostprocess.z = 0;
2103                         }
2104                 }
2105         }
2106
2107         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2108         float e2 = (autocvar_hud_powerup != 0);
2109         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2110         {
2111                 // enable or disable rendering types if they are used or not
2112                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2113                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2114
2115                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2116                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2117                 {
2118                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2119                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2120                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2121                         {
2122                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2123                                 old_blurradius = blurradius;
2124                                 old_bluralpha = bluralpha;
2125                         }
2126                 }
2127                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2128                 {
2129                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2130                         old_blurradius = 0;
2131                         old_bluralpha = 0;
2132                 }
2133
2134                 // edge detection postprocess handling done second (used by hud_powerup)
2135                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2136                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2137                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2138
2139                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2140
2141                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2142                 {
2143                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2144                         {
2145                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2146                                 old_sharpen_intensity = sharpen_intensity;
2147                         }
2148                 }
2149                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2150                 {
2151                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2152                         old_sharpen_intensity = 0;
2153                 }
2154
2155                 if(cvar("r_glsl_postprocess") == 0)
2156                         cvar_set("r_glsl_postprocess", "2");
2157         }
2158         else if(cvar("r_glsl_postprocess") == 2)
2159                 cvar_set("r_glsl_postprocess", "0");
2160
2161         /*if(gametype == MAPINFO_TYPE_CTF)
2162           {
2163           ctf_view();
2164           } else */
2165
2166         // draw 2D entities
2167         FOREACH_ENTITY(it.draw2d, it.draw2d(it));
2168         Draw_ShowNames_All();
2169         Debug_Draw();
2170
2171         scoreboard_active = HUD_WouldDrawScoreboard();
2172
2173         HUD_Draw(this);
2174
2175         if(NextFrameCommand)
2176         {
2177                 localcmd("\n", NextFrameCommand, "\n");
2178                 NextFrameCommand = string_null;
2179         }
2180
2181         // we must do this check AFTER a frame was rendered, or it won't work
2182         if(cs_project_is_b0rked == 0)
2183         {
2184                 string w0, h0;
2185                 w0 = ftos(autocvar_vid_conwidth);
2186                 h0 = ftos(autocvar_vid_conheight);
2187                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2188                 //setproperty(VF_FOV, '90 90 0');
2189                 setproperty(VF_ORIGIN, '0 0 0');
2190                 setproperty(VF_ANGLES, '0 0 0');
2191                 setproperty(VF_PERSPECTIVE, 1);
2192                 makevectors('0 0 0');
2193                 vector v1, v2;
2194                 cvar_set("vid_conwidth", "800");
2195                 cvar_set("vid_conheight", "600");
2196                 v1 = cs_project(v_forward);
2197                 cvar_set("vid_conwidth", "640");
2198                 cvar_set("vid_conheight", "480");
2199                 v2 = cs_project(v_forward);
2200                 if(v1 == v2)
2201                         cs_project_is_b0rked = 1;
2202                 else
2203                         cs_project_is_b0rked = -1;
2204                 cvar_set("vid_conwidth", w0);
2205                 cvar_set("vid_conheight", h0);
2206         }
2207
2208         if(autocvar__hud_configure)
2209                 HUD_Panel_Mouse();
2210         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2211                 HUD_Minigame_Mouse();
2212         else if(QuickMenu_IsOpened())
2213                 QuickMenu_Mouse();
2214         else
2215                 HUD_Radar_Mouse();
2216
2217         cl_notice_run();
2218         unpause_update();
2219         Net_Flush();
2220
2221         // let's reset the view back to normal for the end
2222         setproperty(VF_MIN, '0 0 0');
2223         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2224 }
2225
2226
2227 // following vectors must be global to allow seamless switching between camera modes
2228 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2229 void CSQC_Demo_Camera()
2230 {
2231         float speed, attenuation, dimensions;
2232         vector tmp, delta;
2233
2234         if( autocvar_camera_reset || !camera_mode )
2235         {
2236                 camera_offset = '0 0 0';
2237                 current_angles = '0 0 0';
2238                 camera_direction = '0 0 0';
2239                 camera_offset.z += 30;
2240                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2241                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2242                 current_origin = view_origin;
2243                 current_camera_offset  = camera_offset;
2244                 cvar_set("camera_reset", "0");
2245                 camera_mode = CAMERA_CHASE;
2246         }
2247
2248         // Camera angles
2249         if( camera_roll )
2250                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2251
2252         if(autocvar_camera_look_player)
2253         {
2254                 vector dir;
2255                 float n;
2256
2257                 dir = normalize(view_origin - current_position);
2258                 n = mouse_angles.z;
2259                 mouse_angles = vectoangles(dir);
2260                 mouse_angles.x = mouse_angles.x * -1;
2261                 mouse_angles.z = n;
2262         }
2263         else
2264         {
2265                 tmp = getmousepos() * 0.1;
2266                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2267                 {
2268                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2269                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2270                 }
2271         }
2272
2273         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2274         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2275         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2276         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2277
2278         // Fix difference when angles don't have the same sign
2279         delta = '0 0 0';
2280         if(mouse_angles.y < -60 && current_angles.y > 60)
2281                 delta = '0 360 0';
2282         if(mouse_angles.y > 60 && current_angles.y < -60)
2283                 delta = '0 -360 0';
2284
2285         if(autocvar_camera_look_player)
2286                 attenuation = autocvar_camera_look_attenuation;
2287         else
2288                 attenuation = autocvar_camera_speed_attenuation;
2289
2290         attenuation = 1 / max(1, attenuation);
2291         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2292
2293         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2294         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2295         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2296         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2297
2298         // Camera position
2299         tmp = '0 0 0';
2300         dimensions = 0;
2301
2302         if( camera_direction.x )
2303         {
2304                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2305                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2306                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2307                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2308                 ++dimensions;
2309         }
2310
2311         if( camera_direction.y )
2312         {
2313                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2314                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2315                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2316                 ++dimensions;
2317         }
2318
2319         if( camera_direction.z )
2320         {
2321                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2322                 ++dimensions;
2323         }
2324
2325         if(autocvar_camera_free)
2326                 speed = autocvar_camera_speed_free;
2327         else
2328                 speed = autocvar_camera_speed_chase;
2329
2330         if(dimensions)
2331         {
2332                 speed = speed * sqrt(1 / dimensions);
2333                 camera_offset += tmp * speed;
2334         }
2335
2336         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2337
2338         // Camera modes
2339         if( autocvar_camera_free )
2340         {
2341                 if ( camera_mode == CAMERA_CHASE )
2342                 {
2343                         current_camera_offset = current_origin + current_camera_offset;
2344                         camera_offset = current_origin + camera_offset;
2345                 }
2346
2347                 camera_mode = CAMERA_FREE;
2348                 current_position = current_camera_offset;
2349         }
2350         else
2351         {
2352                 if ( camera_mode == CAMERA_FREE )
2353                 {
2354                         current_origin = view_origin;
2355                         camera_offset = camera_offset - current_origin;
2356                         current_camera_offset = current_camera_offset - current_origin;
2357                 }
2358
2359                 camera_mode = CAMERA_CHASE;
2360
2361                 if(autocvar_camera_chase_smoothly)
2362                         current_origin += (view_origin - current_origin) * attenuation;
2363                 else
2364                         current_origin = view_origin;
2365
2366                 current_position = current_origin + current_camera_offset;
2367         }
2368
2369         setproperty(VF_ANGLES, current_angles);
2370         setproperty(VF_ORIGIN, current_position);
2371 }