qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51
  52 bool autocvar_cl_bobmodel;
  53 float autocvar_cl_bobmodel_speed;
  54 float autocvar_cl_bobmodel_side;
  55 float autocvar_cl_bobmodel_up;
  56
  57 float autocvar_cl_followmodel;
  58 float autocvar_cl_followmodel_speed = 0.3;
  59 float autocvar_cl_followmodel_limit = 135;
  60 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  61 float autocvar_cl_followmodel_highpass = 0.05;
  62 float autocvar_cl_followmodel_lowpass = 0.03;
  63 bool autocvar_cl_followmodel_velocity_absolute;
  64
  65 float autocvar_cl_leanmodel;
  66 float autocvar_cl_leanmodel_speed = 0.3;
  67 float autocvar_cl_leanmodel_limit = 30;
  68 float autocvar_cl_leanmodel_highpass1 = 0.2;
  69 float autocvar_cl_leanmodel_highpass = 0.2;
  70 float autocvar_cl_leanmodel_lowpass = 0.05;
  71
  72 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  73
  74 #define lowpass(value, frac, ref_store, ret) \
  75         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  76
  77 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  78 { \
  79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  81 } MACRO_END
  82
  83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  84 { \
  85         float __f = 0; lowpass(value, frac, ref_store, __f); \
  86         ret = (value) - __f; \
  87 } MACRO_END
  88
  89 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  90 { \
  91         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  92         ret = (value) - __f; \
  93 } MACRO_END
  94
  95 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  96 { \
  97         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  98         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  99 } MACRO_END
 100
 101 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
 102 { \
 103         highpass(value.x, frac, ref_store.x, ref_out.x); \
 104         highpass(value.y, frac, ref_store.y, ref_out.y); \
 105 } MACRO_END
 106
 107 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 108 { \
 109         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 110         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 111 } MACRO_END
 112
 113 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 114 { \
 115         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 116         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 117         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 118 } MACRO_END
 119
 120 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 121 { \
 122         highpass(value.x, frac, ref_store.x, ref_out.x); \
 123         highpass(value.y, frac, ref_store.y, ref_out.y); \
 124         highpass(value.z, frac, ref_store.z, ref_out.z); \
 125 } MACRO_END
 126
 127 void calc_followmodel_ofs(entity view)
 128 {
 129         if(cl_followmodel_time == time)
 130                 return; // cl_followmodel_ofs already calculated for this frame
 131
 132         float frac;
 133         vector gunorg = '0 0 0';
 134         static vector vel_average;
 135         static vector gunorg_adjustment_highpass;
 136         static vector gunorg_adjustment_lowpass;
 137
 138         vector vel;
 139         if (autocvar_cl_followmodel_velocity_absolute)
 140                 vel = view.velocity;
 141         else
 142         {
 143                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 144                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 145                 vel.x = view.velocity * forward;
 146                 vel.y = view.velocity * right * -1;
 147                 vel.z = view.velocity * up;
 148         }
 149
 150         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 151         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 152         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 153
 154         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 155         lowpass3(vel, frac, vel_average, gunorg);
 156
 157         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 158
 159         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 160         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 161         frac = avg_factor(autocvar_cl_followmodel_highpass);
 162         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 163         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 164         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 165
 166         if (autocvar_cl_followmodel_velocity_absolute)
 167         {
 168                 vector fixed_gunorg;
 169                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 170                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 171                 fixed_gunorg.x = gunorg * forward;
 172                 fixed_gunorg.y = gunorg * right * -1;
 173                 fixed_gunorg.z = gunorg * up;
 174                 gunorg = fixed_gunorg;
 175         }
 176
 177         cl_followmodel_ofs = gunorg;
 178         cl_followmodel_time = time;
 179 }
 180
 181 vector leanmodel_ofs(entity view)
 182 {
 183         float frac;
 184         vector gunangles = '0 0 0';
 185         static vector gunangles_prev = '0 0 0';
 186         static vector gunangles_highpass = '0 0 0';
 187         static vector gunangles_adjustment_highpass;
 188         static vector gunangles_adjustment_lowpass;
 189
 190         if (view.csqcmodel_teleported)
 191                 gunangles_prev = view_angles;
 192
 193         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 194         gunangles_highpass += gunangles_prev;
 195         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 196         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 197         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 198         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 199         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 200         gunangles_prev = view_angles;
 201         gunangles_highpass -= gunangles_prev;
 202
 203         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 204         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 205
 206         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 207         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 208         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 209         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 210         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 211
 212         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 213
 214         return gunangles;
 215 }
 216
 217 vector bobmodel_ofs(entity view)
 218 {
 219         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 220         static bool oldonground;
 221         static float hitgroundtime;
 222         if (clonground)
 223         {
 224                 float f = time; // cl.movecmd[0].time
 225                 if (!oldonground)
 226                         hitgroundtime = f;
 227         }
 228         oldonground = clonground;
 229
 230         // calculate for swinging gun model
 231         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 232         vector gunorg = '0 0 0';
 233         static float bobmodel_scale = 0;
 234         static float time_ofs = 0; // makes the effect always restart in the same way
 235         if (clonground)
 236         {
 237                 if (time - hitgroundtime > 0.05)
 238                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 239         }
 240         else
 241                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 242
 243         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 244         if (bobmodel_scale && xyspeed)
 245         {
 246                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 247                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 248                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 249                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 250         }
 251         else
 252                 time_ofs = time;
 253
 254         return gunorg;
 255 }
 256
 257 void viewmodel_animate(entity this)
 258 {
 259         if (autocvar_chase_active) return;
 260         if (STAT(HEALTH) <= 0) return;
 261
 262         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 263
 264         if (autocvar_cl_followmodel)
 265         {
 266                 calc_followmodel_ofs(view);
 267                 this.origin += cl_followmodel_ofs;
 268         }
 269
 270         if (autocvar_cl_leanmodel)
 271                 this.angles += leanmodel_ofs(view);
 272
 273         // vertical view bobbing code
 274         // TODO: cl_bob
 275
 276         // horizontal view bobbing code
 277         // TODO: cl_bob2
 278
 279         // fall bobbing code
 280         // causes the view to swing down and back up when touching the ground
 281         // TODO: cl_bobfall
 282
 283         // gun model bobbing code
 284         if (autocvar_cl_bobmodel)
 285                 this.origin += bobmodel_ofs(view);
 286 }
 287
 288 .vector viewmodel_origin, viewmodel_angles;
 289 .float weapon_nextthink;
 290 .float weapon_eta_last;
 291 .float weapon_switchdelay;
 292
 293 .string name_last;
 294
 295 void viewmodel_draw(entity this)
 296 {
 297         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 298                 return;
 299         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 300         float a = this.alpha;
 301         static bool wasinvehicle;
 302         bool invehicle = player_localentnum > maxclients;
 303         if (invehicle) a = -1;
 304         else if (wasinvehicle) a = 1;
 305         wasinvehicle = invehicle;
 306         Weapon wep = this.activeweapon;
 307         int c = entcs_GetClientColors(current_player);
 308         vector g = weaponentity_glowmod(wep, NULL, c, this);
 309         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 310         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 311                 | EF_NODEPTHTEST)
 312                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 313         for (entity e = this; e; e = e.weaponchild)
 314         {
 315                 e.drawmask = mask;
 316                 e.alpha = a;
 317                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 318                 e.glowmod = g;
 319                 e.csqcmodel_effects = fx;
 320                 CSQCModel_Effects_Apply(e);
 321         }
 322         if(a >= 0)
 323         {
 324                 string name = wep.mdl;
 325                 string newname = wep.wr_viewmodel(wep, this);
 326                 if(newname)
 327                         name = newname;
 328                 bool swap = name != this.name_last;
 329                 // if (swap)
 330                 {
 331                         this.name_last = name;
 332                         CL_WeaponEntity_SetModel(this, name, swap);
 333                         this.viewmodel_origin = this.origin;
 334                         this.viewmodel_angles = this.angles;
 335                 }
 336                 anim_update(this);
 337                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 338                         anim_set(this, this.anim_idle, true, false, false);
 339         }
 340         float f = 0; // 0..1; 0: fully active
 341         float rate = STAT(WEAPONRATEFACTOR);
 342         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 343         if (eta <= 0) f = this.weapon_eta_last;
 344         else switch (this.state)
 345         {
 346                 case WS_RAISE:
 347                 {
 348                         f = eta / max(eta, this.weapon_switchdelay);
 349                         break;
 350                 }
 351                 case WS_DROP:
 352                 {
 353                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 354                         break;
 355                 }
 356                 case WS_CLEAR:
 357                 {
 358                         f = 1;
 359                         break;
 360                 }
 361         }
 362         this.weapon_eta_last = f;
 363         this.origin = this.viewmodel_origin;
 364         this.angles = this.viewmodel_angles;
 365         this.angles_x = (-90 * f * f);
 366         viewmodel_animate(this);
 367         MUTATOR_CALLHOOK(DrawViewModel, this);
 368         setorigin(this, this.origin);
 369 }
 370
 371 STATIC_INIT(viewmodel) {
 372     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 373         viewmodels[slot] = new(viewmodel);
 374 }
 375
 376 float showfps_prevfps;
 377 float showfps_prevfps_time;
 378 int showfps_framecounter;
 379
 380 void fpscounter_update()
 381 {
 382         if(!STAT(SHOWFPS))
 383                 return;
 384
 385         float currentTime = gettime(GETTIME_REALTIME);
 386         showfps_framecounter += 1;
 387         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 388         {
 389                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 390                 showfps_framecounter = 0;
 391                 showfps_prevfps_time = currentTime;
 392
 393                 int channel = MSG_C2S;
 394                 WriteHeader(channel, fpsreport);
 395                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 396         }
 397 }
 398
 399 STATIC_INIT(fpscounter_init)
 400 {
 401         float currentTime = gettime(GETTIME_REALTIME);
 402         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 403 }
 404
 405 STATIC_INIT(Porto)
 406 {
 407         entity e = new_pure(porto);
 408         e.draw = Porto_Draw;
 409         IL_PUSH(g_drawables, e);
 410         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 411 }
 412
 413 const int polyline_length = 16;
 414 .vector polyline[polyline_length];
 415 void Porto_Draw(entity this)
 416 {
 417         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 418         {
 419                 entity wepent = viewmodels[slot];
 420
 421                 if (wepent.activeweapon != WEP_PORTO) continue;
 422                 if (spectatee_status) continue;
 423                 if (WEP_CVAR(porto, secondary)) continue;
 424                 if (intermission == 1) continue;
 425                 if (intermission == 2) continue;
 426                 if (STAT(HEALTH) <= 0) continue;
 427
 428                 vector pos = view_origin;
 429                 vector dir = view_forward;
 430                 if (wepent.angles_held_status)
 431                 {
 432                         makevectors(wepent.angles_held);
 433                         dir = v_forward;
 434                 }
 435
 436                 wepent.polyline[0] = pos;
 437
 438                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 439                 int n = 1 + 2;  // 2 lines == 3 points
 440                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 441                 {
 442                         traceline(pos, pos + 65536 * dir, true, this);
 443                         dir = reflect(dir, trace_plane_normal);
 444                         pos = trace_endpos;
 445                         wepent.polyline[++idx] = pos;
 446                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 447                         {
 448                                 n += 1;
 449                                 continue;
 450                         }
 451                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 452                         {
 453                                 n = max(2, idx);
 454                                 break;
 455                         }
 456                         // check size
 457                         {
 458                                 vector ang = vectoangles2(trace_plane_normal, dir);
 459                                 ang.x = -ang.x;
 460                                 makevectors(ang);
 461                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 462                                 {
 463                                         n = max(2, idx);
 464                                         break;
 465                                 }
 466                         }
 467                         portal_number += 1;
 468                         if (portal_number >= portal_max) break;
 469                         if (portal_number == 1) portal1_idx = idx;
 470                 }
 471                 for (int idx = 0; idx < n - 1; ++idx)
 472                 {
 473                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 474                         if (idx == 0) p -= view_up * 16;  // line from player
 475                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 476                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 477                 }
 478         }
 479 }
 480
 481 float drawtime;
 482 float avgspeed;
 483 vector GetCurrentFov(float fov)
 484 {
 485         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 486         float velocityzoom, curspeed;
 487         vector v;
 488
 489         zoomsensitivity = autocvar_cl_zoomsensitivity;
 490         zoomfactor = autocvar_cl_zoomfactor;
 491         if(zoomfactor < 1 || zoomfactor > 30)
 492                 zoomfactor = 2.5;
 493         zoomspeed = autocvar_cl_zoomspeed;
 494         if(zoomspeed >= 0)
 495         if(zoomspeed < 0.5 || zoomspeed > 16)
 496                         zoomspeed = 3.5;
 497
 498         zoomdir = button_zoom;
 499
 500         if(hud == HUD_NORMAL && !spectatee_status)
 501         {
 502                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 503                 {
 504                         entity wepent = viewmodels[slot];
 505                         if(wepent.switchweapon != wepent.activeweapon)
 506                                 continue;
 507                         Weapon wep = wepent.activeweapon;
 508                         if(wep != WEP_Null && wep.wr_zoomdir)
 509                         {
 510                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 511                                 zoomdir += do_zoom;
 512                         }
 513                 }
 514         }
 515         if(spectatee_status > 0 || isdemo())
 516         {
 517                 if(spectatorbutton_zoom)
 518                 {
 519                         if(zoomdir)
 520                                 zoomdir = 0;
 521                         else
 522                                 zoomdir = 1;
 523                 }
 524                 // fteqcc failed twice here already, don't optimize this
 525         }
 526
 527         if(zoomdir) { zoomin_effect = 0; }
 528
 529         if(camera_active)
 530         {
 531                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 532         }
 533         else if(autocvar_cl_spawnzoom && zoomin_effect)
 534         {
 535                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 536
 537                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 538                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 539                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 540         }
 541         else
 542         {
 543                 if(zoomspeed < 0) // instant zoom
 544                 {
 545                         if(zoomdir)
 546                                 current_viewzoom = 1 / zoomfactor;
 547                         else
 548                                 current_viewzoom = 1;
 549                 }
 550                 else
 551                 {
 552                         if(zoomdir)
 553                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 554                         else
 555                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 556                 }
 557         }
 558
 559         if(almost_equals(current_viewzoom, 1))
 560                 current_zoomfraction = 0;
 561         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 562                 current_zoomfraction = 1;
 563         else
 564                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 565
 566         if(zoomsensitivity < 1)
 567                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 568         else
 569                 setsensitivityscale(1);
 570
 571         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 572         {
 573                 if(intermission) { curspeed = 0; }
 574                 else
 575                 {
 576
 577                         makevectors(view_angles);
 578                         v = pmove_vel;
 579                         if(csqcplayer)
 580                                 v = csqcplayer.velocity;
 581
 582                         switch(autocvar_cl_velocityzoom_type)
 583                         {
 584                                 case 3: curspeed = max(0, v_forward * v); break;
 585                                 case 2: curspeed = (v_forward * v); break;
 586                                 case 1: default: curspeed = vlen(v); break;
 587                         }
 588                 }
 589
 590                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 591                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 592                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 593
 594                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 595         }
 596         else
 597                 velocityzoom = 1;
 598
 599         float frustumx, frustumy, fovx, fovy;
 600         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 601         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 602         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 603         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 604
 605         return '1 0 0' * fovx + '0 1 0' * fovy;
 606 }
 607
 608 vector GetViewLocationFOV(float fov)
 609 {
 610         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 611         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 612         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 613         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 614         return '1 0 0' * fovx + '0 1 0' * fovy;
 615 }
 616
 617 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 618 {
 619         float fovx, fovy;
 620         float width = (ov_worldmax.x - ov_worldmin.x);
 621         float height = (ov_worldmax.y - ov_worldmin.y);
 622         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 623         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 624         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 625         return '1 0 0' * fovx + '0 1 0' * fovy;
 626 }
 627
 628 // this function must match W_SetupShot!
 629 float zoomscript_caught;
 630
 631 vector wcross_origin;
 632 float wcross_scale_prev, wcross_alpha_prev;
 633 vector wcross_color_prev;
 634 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 635 vector wcross_color_goal_prev;
 636 float wcross_changedonetime;
 637
 638 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 639 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 640 float wcross_name_changestarttime, wcross_name_changedonetime;
 641 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 642
 643 float wcross_ring_prev;
 644
 645 entity trueaim;
 646 entity trueaim_rifle;
 647
 648 const float SHOTTYPE_HITTEAM = 1;
 649 const float SHOTTYPE_HITOBSTRUCTION = 2;
 650 const float SHOTTYPE_HITWORLD = 3;
 651 const float SHOTTYPE_HITENEMY = 4;
 652
 653 void TrueAim_Init()
 654 {
 655         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 656         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 657 }
 658
 659 float EnemyHitCheck()
 660 {
 661         float t, n;
 662         wcross_origin = project_3d_to_2d(trace_endpos);
 663         wcross_origin.z = 0;
 664         if(trace_ent)
 665                 n = trace_ent.entnum;
 666         else
 667                 n = trace_networkentity;
 668         if(n < 1)
 669                 return SHOTTYPE_HITWORLD;
 670         if(n > maxclients)
 671                 return SHOTTYPE_HITWORLD;
 672         t = entcs_GetTeam(n - 1);
 673         if(teamplay)
 674                 if(t == myteam)
 675                         return SHOTTYPE_HITTEAM;
 676         if(t == NUM_SPECTATOR)
 677                 return SHOTTYPE_HITWORLD;
 678         return SHOTTYPE_HITENEMY;
 679 }
 680
 681 float TrueAimCheck(entity wepent)
 682 {
 683         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 684         vector vecs, trueaimpoint, w_shotorg;
 685         vector mi, ma, dv;
 686         float shottype;
 687         entity ta;
 688         float mv;
 689
 690         mi = ma = '0 0 0';
 691         ta = trueaim;
 692         mv = MOVE_NOMONSTERS;
 693
 694         switch(wepent.activeweapon) // WEAPONTODO
 695         {
 696                 case WEP_TUBA: // no aim
 697                 case WEP_PORTO: // shoots from eye
 698                 case WEP_NEXBALL: // shoots from eye
 699                 case WEP_HOOK: // no trueaim
 700                 case WEP_MORTAR: // toss curve
 701                         return SHOTTYPE_HITWORLD;
 702                 case WEP_VORTEX:
 703                 case WEP_OVERKILL_NEX:
 704                 case WEP_VAPORIZER:
 705                         mv = MOVE_NORMAL;
 706                         break;
 707                 case WEP_RIFLE:
 708                         ta = trueaim_rifle;
 709                         mv = MOVE_NORMAL;
 710                         if(zoomscript_caught)
 711                         {
 712                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 713                                 return EnemyHitCheck();
 714                         }
 715                         break;
 716                 case WEP_DEVASTATOR: // projectile has a size!
 717                         mi = '-3 -3 -3';
 718                         ma = '3 3 3';
 719                         break;
 720                 case WEP_FIREBALL: // projectile has a size!
 721                         mi = '-16 -16 -16';
 722                         ma = '16 16 16';
 723                         break;
 724                 case WEP_SEEKER: // projectile has a size!
 725                         mi = '-2 -2 -2';
 726                         ma = '2 2 2';
 727                         break;
 728                 case WEP_ELECTRO: // projectile has a size!
 729                         mi = '0 0 -3';
 730                         ma = '0 0 -3';
 731                         break;
 732         }
 733
 734         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 735
 736         vecs = decompressShotOrigin(STAT(SHOTORG));
 737
 738         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 739         trueaimpoint = trace_endpos;
 740
 741         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 742                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 743
 744         if(vecs.x > 0)
 745                 vecs.y = -vecs.y;
 746         else
 747                 vecs = '0 0 0';
 748
 749         dv = view_right * vecs.y + view_up * vecs.z;
 750         w_shotorg = traceorigin + dv;
 751
 752         // now move the vecs forward as much as requested if possible
 753         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 754         w_shotorg = trace_endpos - view_forward * nudge;
 755
 756         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 757         shottype = EnemyHitCheck();
 758         if(shottype != SHOTTYPE_HITWORLD)
 759                 return shottype;
 760
 761 #if 0
 762         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 763         // or rather, I know why, but see no fix
 764         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 765                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 766                 return SHOTTYPE_HITOBSTRUCTION;
 767 #endif
 768
 769         return SHOTTYPE_HITWORLD;
 770 }
 771
 772 float camera_mode;
 773 const float CAMERA_FREE = 1;
 774 const float CAMERA_CHASE = 2;
 775 float reticle_type;
 776 string NextFrameCommand;
 777
 778 vector freeze_org, freeze_ang;
 779 entity nightvision_noise, nightvision_noise2;
 780
 781 const float MAX_TIME_DIFF = 5;
 782 float pickup_crosshair_time, pickup_crosshair_size;
 783 float hitindication_crosshair_size;
 784 float use_vortex_chargepool;
 785
 786 float myhealth, myhealth_prev;
 787 float myhealth_flash;
 788
 789 float old_blurradius, old_bluralpha;
 790 float old_sharpen_intensity;
 791
 792 vector myhealth_gentlergb;
 793
 794 float contentavgalpha, liquidalpha_prev;
 795 vector liquidcolor_prev;
 796
 797 float eventchase_current_distance;
 798 float eventchase_running;
 799 bool WantEventchase(entity this)
 800 {
 801         if(autocvar_cl_orthoview)
 802                 return false;
 803         if(STAT(GAME_STOPPED) || intermission)
 804                 return true;
 805         if(this.viewloc)
 806                 return true;
 807         if(spectatee_status >= 0)
 808         {
 809                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 810                         return true;
 811                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 812                         return true;
 813                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 814                         return true;
 815                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 816                 {
 817                         if(autocvar_cl_eventchase_death == 2)
 818                         {
 819                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 820                                 if(this.velocity == '0 0 0' || eventchase_running)
 821                                         return true;
 822                         }
 823                         else return true;
 824                 }
 825         }
 826         return false;
 827 }
 828
 829 void HUD_Crosshair_Vehicle(entity this)
 830 {
 831         if(hud != HUD_BUMBLEBEE_GUN)
 832         {
 833                 Vehicle info = Vehicles_from(hud);
 834                 info.vr_crosshair(info, this);
 835         }
 836 }
 837
 838 vector damage_blurpostprocess, content_blurpostprocess;
 839
 840 float unaccounted_damage = 0;
 841 void UpdateDamage()
 842 {
 843         // accumulate damage with each stat update
 844         static float damage_total_prev = 0;
 845         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 846         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 847         damage_total_prev = damage_total;
 848
 849         static float damage_dealt_time_prev = 0;
 850         float damage_dealt_time = STAT(HIT_TIME);
 851         if (damage_dealt_time != damage_dealt_time_prev)
 852         {
 853                 unaccounted_damage += unaccounted_damage_new;
 854                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 855         }
 856         damage_dealt_time_prev = damage_dealt_time;
 857
 858         // prevent hitsound when switching spectatee
 859         static float spectatee_status_prev = 0;
 860         if (spectatee_status != spectatee_status_prev)
 861                 unaccounted_damage = 0;
 862         spectatee_status_prev = spectatee_status;
 863 }
 864
 865 void HitSound()
 866 {
 867         // varying sound pitch
 868
 869         bool have_arc = false;
 870         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 871         {
 872                 entity wepent = viewmodels[slot];
 873
 874                 if(wepent.activeweapon == WEP_ARC)
 875                         have_arc = true;
 876         }
 877
 878         static float hitsound_time_prev = 0;
 879         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 880         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 881         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 882         {
 883                 if (autocvar_cl_hitsound && unaccounted_damage)
 884                 {
 885                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 886                         float a = autocvar_cl_hitsound_max_pitch;
 887                         float b = autocvar_cl_hitsound_min_pitch;
 888                         float c = autocvar_cl_hitsound_nom_damage;
 889                         float d = unaccounted_damage;
 890                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 891
 892                         // if sound variation is disabled, set pitch_shift to 1
 893                         if (autocvar_cl_hitsound == 1)
 894                                 pitch_shift = 1;
 895
 896                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 897                         if (autocvar_cl_hitsound == 3)
 898                         {
 899                                 float mirror_value = (a-b)/2 + b;
 900                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 901                         }
 902
 903                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 904
 905                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 906                         // todo: normalize sound pressure levels? seems unnecessary
 907
 908                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 909                 }
 910                 unaccounted_damage = 0;
 911                 hitsound_time_prev = time;
 912         }
 913
 914         static float typehit_time_prev = 0;
 915         float typehit_time = STAT(TYPEHIT_TIME);
 916         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 917         {
 918                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 919                 typehit_time_prev = typehit_time;
 920         }
 921
 922         static float kill_time_prev = 0;
 923         float kill_time = STAT(KILL_TIME);
 924         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 925         {
 926                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 927                 kill_time_prev = kill_time;
 928         }
 929 }
 930
 931 vector crosshair_getcolor(entity this, float health_stat)
 932 {
 933         static float rainbow_last_flicker;
 934         static vector rainbow_prev_color;
 935         vector wcross_color = '0 0 0';
 936         switch(autocvar_crosshair_color_special)
 937         {
 938                 case 1: // crosshair_color_per_weapon
 939                 {
 940                         if(this != WEP_Null && hud == HUD_NORMAL)
 941                         {
 942                                 wcross_color = this.wpcolor;
 943                                 break;
 944                         }
 945                         else { goto normalcolor; }
 946                 }
 947
 948                 case 2: // crosshair_color_by_health
 949                 {
 950                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 951                         float hp = floor(v.x + 1);
 952
 953                         //x = red
 954                         //y = green
 955                         //z = blue
 956
 957                         wcross_color.z = 0;
 958
 959                         if(hp > 200)
 960                         {
 961                                 wcross_color.x = 0;
 962                                 wcross_color.y = 1;
 963                         }
 964                         else if(hp > 150)
 965                         {
 966                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 967                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 968                         }
 969                         else if(hp > 100)
 970                         {
 971                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 972                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 973                                 wcross_color.z = 1 - (hp-100)*0.02;
 974                         }
 975                         else if(hp > 50)
 976                         {
 977                                 wcross_color.x = 1;
 978                                 wcross_color.y = 1;
 979                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 980                         }
 981                         else if(hp > 20)
 982                         {
 983                                 wcross_color.x = 1;
 984                                 wcross_color.y = (hp-20)*90/27/100;
 985                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 986                         }
 987                         else
 988                         {
 989                                 wcross_color.x = 1;
 990                                 wcross_color.y = 0;
 991                         }
 992                         break;
 993                 }
 994
 995                 case 3: // crosshair_color_rainbow
 996                 {
 997                         if(time >= rainbow_last_flicker)
 998                         {
 999                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1000                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1001                         }
1002                         wcross_color = rainbow_prev_color;
1003                         break;
1004                 }
1005 LABEL(normalcolor)
1006                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1007         }
1008
1009         return wcross_color;
1010 }
1011
1012 void HUD_Crosshair(entity this)
1013 {
1014         float f, i, j;
1015         vector v;
1016         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
1017                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
1018                 !HUD_MinigameMenu_IsOpened() )
1019         {
1020                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1021                         return;
1022
1023                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
1024                         return;
1025
1026                 if (hud != HUD_NORMAL)
1027                 {
1028                         HUD_Crosshair_Vehicle(this);
1029                         return;
1030                 }
1031
1032                 string wcross_style;
1033                 float wcross_alpha, wcross_resolution;
1034                 wcross_style = autocvar_crosshair;
1035                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1036                         wcross_style = autocvar_crosshair_2d;
1037                 if (wcross_style == "0")
1038                         return;
1039                 wcross_resolution = autocvar_crosshair_size;
1040                 if (wcross_resolution == 0)
1041                         return;
1042                 wcross_alpha = autocvar_crosshair_alpha;
1043                 if (wcross_alpha == 0)
1044                         return;
1045
1046                 // TrueAim check
1047                 float shottype;
1048
1049                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1050                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1051                         wcross_origin = viewloc_mousepos;
1052                 else
1053                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1054                 wcross_origin.z = 0;
1055                 if(autocvar_crosshair_hittest)
1056                 {
1057                         vector wcross_oldorigin;
1058                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1059                         wcross_oldorigin = wcross_origin;
1060                         shottype = TrueAimCheck(thiswep);
1061                         if(shottype == SHOTTYPE_HITWORLD)
1062                         {
1063                                 v = wcross_origin - wcross_oldorigin;
1064                                 v.x /= vid_conwidth;
1065                                 v.y /= vid_conheight;
1066                                 if(vdist(v, >, 0.01))
1067                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1068                         }
1069                         if(!autocvar_crosshair_hittest_showimpact)
1070                                 wcross_origin = wcross_oldorigin;
1071                 }
1072                 else
1073                         shottype = SHOTTYPE_HITWORLD;
1074
1075                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1076                 string wcross_name = "";
1077                 float wcross_scale, wcross_blur;
1078
1079         entity e = WEP_Null;
1080                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1081                 {
1082                         entity wepent = viewmodels[0]; // TODO: unhardcode
1083                         e = wepent.switchingweapon;
1084                         if(e)
1085                         {
1086                                 if(autocvar_crosshair_per_weapon)
1087                                 {
1088                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1089                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1090                                         //if (wcross_resolution == 0)
1091                                                 //return;
1092
1093                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1094                                         wcross_resolution *= e.w_crosshair_size;
1095                                         wcross_name = e.w_crosshair;
1096                                 }
1097                         }
1098                 }
1099
1100                 if(wcross_name == "")
1101                         wcross_name = strcat("gfx/crosshair", wcross_style);
1102
1103                 // MAIN CROSSHAIR COLOR DECISION
1104                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1105
1106                 if(autocvar_crosshair_effect_scalefade)
1107                 {
1108                         wcross_scale = wcross_resolution;
1109                         wcross_resolution = 1;
1110                 }
1111                 else
1112                 {
1113                         wcross_scale = 1;
1114                 }
1115
1116                 if(autocvar_crosshair_pickup)
1117                 {
1118                         float stat_pickup_time = STAT(LAST_PICKUP);
1119
1120                         if(pickup_crosshair_time < stat_pickup_time)
1121                         {
1122                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1123                                         pickup_crosshair_size = 1;
1124
1125                                 pickup_crosshair_time = stat_pickup_time;
1126                         }
1127
1128                         if(pickup_crosshair_size > 0)
1129                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1130                         else
1131                                 pickup_crosshair_size = 0;
1132
1133                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1134                 }
1135
1136                 // todo: make crosshair hit indication dependent on damage dealt
1137                 if(autocvar_crosshair_hitindication)
1138                 {
1139                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1140
1141                         if(unaccounted_damage)
1142                         {
1143                                 hitindication_crosshair_size = 1;
1144                         }
1145
1146                         if(hitindication_crosshair_size > 0)
1147                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1148                         else
1149                                 hitindication_crosshair_size = 0;
1150
1151                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1152                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1153                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1154                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1155                 }
1156
1157                 if(shottype == SHOTTYPE_HITENEMY)
1158                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1159                 if(shottype == SHOTTYPE_HITTEAM)
1160                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1161
1162                 f = fabs(autocvar_crosshair_effect_time);
1163                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1164                 {
1165                         wcross_changedonetime = time + f;
1166                 }
1167                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1168                 {
1169                         wcross_name_changestarttime = time;
1170                         wcross_name_changedonetime = time + f;
1171                         if(wcross_name_goal_prev_prev)
1172                                 strunzone(wcross_name_goal_prev_prev);
1173                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1174                         wcross_name_goal_prev = strzone(wcross_name);
1175                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1176                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1177                         wcross_resolution_goal_prev = wcross_resolution;
1178                 }
1179
1180                 wcross_scale_goal_prev = wcross_scale;
1181                 wcross_alpha_goal_prev = wcross_alpha;
1182                 wcross_color_goal_prev = wcross_color;
1183
1184                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1185                 {
1186                         wcross_blur = 1;
1187                         wcross_alpha *= 0.75;
1188                 }
1189                 else
1190                         wcross_blur = 0;
1191                 // *_prev is at time-frametime
1192                 // * is at wcross_changedonetime+f
1193                 // what do we have at time?
1194                 if(time < wcross_changedonetime)
1195                 {
1196                         f = frametime / (wcross_changedonetime - time + frametime);
1197                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1198                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1199                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1200                 }
1201
1202                 wcross_scale_prev = wcross_scale;
1203                 wcross_alpha_prev = wcross_alpha;
1204                 wcross_color_prev = wcross_color;
1205
1206                 MUTATOR_CALLHOOK(UpdateCrosshair);
1207
1208                 wcross_scale *= 1 - autocvar__menu_alpha;
1209                 wcross_alpha *= 1 - autocvar__menu_alpha;
1210                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1211
1212                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1213                 {
1214                         // crosshair rings for weapon stats
1215                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1216                         {
1217                                 // declarations and stats
1218                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1219                                 string ring_image = string_null, ring_inner_image = string_null;
1220                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1221
1222                                 ring_scale = autocvar_crosshair_ring_size;
1223
1224                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1225
1226                                 int weapon_clipload = wepent.clip_load;
1227                                 int weapon_clipsize = wepent.clip_size;
1228
1229                                 float arc_heat = wepent.arc_heat_percent;
1230                                 float vcharge = wepent.vortex_charge;
1231                                 float vchargepool = wepent.vortex_chargepool_ammo;
1232                                 float oknex_charge_ = wepent.oknex_charge;
1233                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1234
1235                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1236                                         vortex_charge_movingavg = vcharge;
1237
1238                                 // handle the values
1239                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1240                                 {
1241                                         if (vchargepool || use_vortex_chargepool) {
1242                                                 use_vortex_chargepool = 1;
1243                                                 ring_inner_value = vchargepool;
1244                                         } else {
1245                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1246                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1247                                         }
1248
1249                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1250                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1251                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1252
1253                                         // draw the outer ring to show the current charge of the weapon
1254                                         ring_value = vcharge;
1255                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1256                                         ring_rgb = wcross_color;
1257                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1258                                 }
1259                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1260                                 {
1261                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1262                                                 use_vortex_chargepool = 1;
1263                                                 ring_inner_value = oknex_chargepool_;
1264                                         } else {
1265                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1266                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1267                                         }
1268
1269                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1270                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1271                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1272
1273                                         // draw the outer ring to show the current charge of the weapon
1274                                         ring_value = oknex_charge_;
1275                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1276                                         ring_rgb = wcross_color;
1277                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1278                                 }
1279                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1280                                 {
1281                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1282                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1283                                         ring_rgb = wcross_color;
1284                                         ring_image = "gfx/crosshair_ring.tga";
1285                                 }
1286                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1287                                 {
1288                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1289                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1290                                         ring_rgb = wcross_color;
1291                                         ring_image = "gfx/crosshair_ring.tga";
1292                                 }
1293                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1294                                 {
1295                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1296                                         ring_scale = autocvar_crosshair_ring_reload_size;
1297                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1298                                         ring_rgb = wcross_color;
1299
1300                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1301                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1302                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1303                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1304                                         else
1305                                                 ring_image = "gfx/crosshair_ring.tga";
1306                                 }
1307                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1308                                 {
1309                                         ring_value = arc_heat;
1310                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1311                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1312                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1313                                         ring_image = "gfx/crosshair_ring.tga";
1314                                 }
1315
1316                                 // if in weapon switch animation, fade ring out/in
1317                                 if(autocvar_crosshair_effect_time > 0)
1318                                 {
1319                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1320                                         if (f >= 1)
1321                                         {
1322                                                 wcross_ring_prev = ((ring_image) ? true : false);
1323                                         }
1324
1325                                         if(wcross_ring_prev)
1326                                         {
1327                                                 if(f < 1)
1328                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1329                                         }
1330                                         else
1331                                         {
1332                                                 if(f < 1)
1333                                                         ring_alpha *= bound(0, f, 1);
1334                                         }
1335                                 }
1336
1337                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1338                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1339
1340                                 if (ring_value)
1341                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1342                         }
1343
1344 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1345                         MACRO_BEGIN { \
1346                                 if(wcross_blur > 0) \
1347                                 { \
1348                                         for(i = -2; i <= 2; ++i) \
1349                                         for(j = -2; j <= 2; ++j) \
1350                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1351                                 } \
1352                                 else \
1353                                 { \
1354                                         M(0,0,sz,wcross_name,wcross_alpha); \
1355                                 } \
1356                         } MACRO_END
1357
1358 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1359                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1360
1361 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1362                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1363
1364                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1365                         {
1366                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1367                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1368                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1369                                 f = 1 - f;
1370                         }
1371                         else
1372                         {
1373                                 f = 1;
1374                         }
1375                         wcross_name_alpha_goal_prev = f;
1376
1377                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1378                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1379
1380                         if(autocvar_crosshair_dot)
1381                         {
1382                                 vector wcross_color_old;
1383                                 wcross_color_old = wcross_color;
1384
1385                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1386                                         wcross_color = stov(autocvar_crosshair_dot_color);
1387
1388                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1389                                 // FIXME why don't we use wcross_alpha here?
1390                                 wcross_color = wcross_color_old;
1391                         }
1392                 }
1393         }
1394         else
1395         {
1396                 wcross_scale_prev = 0;
1397                 wcross_alpha_prev = 0;
1398                 wcross_scale_goal_prev = 0;
1399                 wcross_alpha_goal_prev = 0;
1400                 wcross_changedonetime = 0;
1401                 strfree(wcross_name_goal_prev);
1402                 strfree(wcross_name_goal_prev_prev);
1403                 wcross_name_changestarttime = 0;
1404                 wcross_name_changedonetime = 0;
1405                 wcross_name_alpha_goal_prev = 0;
1406                 wcross_name_alpha_goal_prev_prev = 0;
1407                 wcross_resolution_goal_prev = 0;
1408                 wcross_resolution_goal_prev_prev = 0;
1409         }
1410 }
1411
1412 const int MAX_SPECIALCOMMAND = 15;
1413 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1414 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1415 const float SPECIALCOMMAND_SPEED = 150;
1416 const float SPECIALCOMMAND_TURNSPEED = 2;
1417 const float SPECIALCOMMAND_SIZE = 0.025;
1418 const float SPECIALCOMMAND_CHANCE = 0.35;
1419 float sc_spawntime, sc_changetime;
1420 vector sc_color = '1 1 1';
1421 void SpecialCommand()
1422 {
1423         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1424                 return;
1425
1426         if(time >= sc_changetime)
1427         {
1428                 sc_changetime = time + 1;
1429                 sc_color = randomvec() * 1.5;
1430                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1431                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1432                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1433         }
1434         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1435
1436         if(!precache_pic("gfx/smile"))
1437                 return; // damn party poopers
1438
1439         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1440         {
1441                 vector slot = specialcommand_slots[j];
1442                 if(slot.y)
1443                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1444                 //if(slot.z)
1445                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1446                 if(slot.y >= vid_conheight)
1447                         slot = '0 0 0';
1448
1449                 if(slot == '0 0 0')
1450                 {
1451                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1452                         {
1453                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1454                                 slot.y = 1; // start it off 0 so we can use it
1455                                 slot.z = floor(random() * Weapons_MAX);
1456                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1457                                 vector newcolor = randomvec() * 2;
1458                                 newcolor.x = bound(0.4, newcolor.x, 1);
1459                                 newcolor.y = bound(0.4, newcolor.y, 1);
1460                                 newcolor.z = bound(0.4, newcolor.z, 1);
1461                                 specialcommand_colors[j] = newcolor;
1462                         }
1463                 }
1464                 else
1465                 {
1466                         vector splash_size = '0 0 0';
1467                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1468                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1469                         entity wep = Weapons_from(slot.z);
1470                         if(wep == WEP_Null)
1471                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1472                         else
1473                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1474                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1475                 }
1476
1477                 specialcommand_slots[j] = slot;
1478         }
1479 }
1480
1481 void HUD_Draw(entity this)
1482 {
1483         // if we don't know gametype and scores yet avoid drawing the scoreboard
1484         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1485         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1486         // cl_deathscoreboard would show the scoreboard and so on
1487         if(!gametype)
1488                 return;
1489
1490         Hud_Dynamic_Frame();
1491
1492         if(!intermission)
1493         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1494         {
1495                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1496         }
1497         else if(STAT(FROZEN))
1498         {
1499                 vector col = '0.25 0.90 1';
1500                 if(STAT(REVIVE_PROGRESS))
1501                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1502                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1503         }
1504
1505         HUD_Scale_Enable();
1506         if(!intermission)
1507         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1508         {
1509                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1510                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1511                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1512         }
1513         else if(STAT(CAPTURE_PROGRESS))
1514         {
1515                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1516                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1517         }
1518         else if(STAT(REVIVE_PROGRESS))
1519         {
1520                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1521                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1522         }
1523         HUD_Scale_Disable();
1524
1525         if(autocvar_r_letterbox == 0)
1526                 if(autocvar_viewsize < 120)
1527                 {
1528                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1529                                 Accuracy_LoadLevels();
1530
1531                         HUD_Main();
1532                         HUD_Scale_Disable();
1533                 }
1534
1535         // crosshair goes VERY LAST
1536         SpecialCommand();
1537         UpdateDamage();
1538         HUD_Crosshair(this);
1539         HitSound();
1540 }
1541
1542 void ViewLocation_Mouse()
1543 {
1544         if(spectatee_status)
1545                 return; // don't draw it as spectator!
1546
1547         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1548         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1549         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1550
1551         //float cursor_alpha = 1 - autocvar__menu_alpha;
1552         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1553 }
1554
1555 bool ov_enabled;
1556 float oldr_nearclip;
1557 float oldr_farclip_base;
1558 float oldr_farclip_world;
1559 float oldr_novis;
1560 float oldr_useportalculling;
1561 float oldr_useinfinitefarclip;
1562
1563 float prev_myteam;
1564 int lasthud;
1565 float vh_notice_time;
1566 void CSQC_UpdateView(entity this, float w, float h)
1567 {
1568     TC(int, w); TC(int, h);
1569         entity e;
1570         float fov;
1571         float f;
1572         vector vf_size, vf_min;
1573         float a;
1574
1575         execute_next_frame();
1576
1577         ++framecount;
1578
1579         stats_get();
1580         hud = STAT(HUD);
1581
1582         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1583                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1584
1585         lasthud = hud;
1586
1587         HUD_Scale_Disable();
1588
1589         if(autocvar__hud_showbinds_reload) // menu can set this one
1590         {
1591                 db_close(binddb);
1592                 binddb = db_create();
1593                 cvar_set("_hud_showbinds_reload", "0");
1594         }
1595
1596         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1597                 view_quality = getproperty(VF_MINFPS_QUALITY);
1598         else
1599                 view_quality = 1;
1600
1601         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1602         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1603
1604         vf_size = getpropertyvec(VF_SIZE);
1605         vf_min = getpropertyvec(VF_MIN);
1606         vid_width = vf_size.x;
1607         vid_height = vf_size.y;
1608
1609         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1610         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1611
1612         WaypointSprite_Load();
1613
1614         CSQCPlayer_SetCamera();
1615
1616         if(player_localentnum <= maxclients) // is it a client?
1617                 current_player = player_localentnum - 1;
1618         else // then player_localentnum is the vehicle I'm driving
1619                 current_player = player_localnum;
1620         myteam = entcs_GetTeam(current_player);
1621
1622         if(myteam != prev_myteam)
1623         {
1624                 myteamcolors = colormapPaletteColor(myteam, 1);
1625                 FOREACH(hud_panels, true, it.update_time = time);
1626                 prev_myteam = myteam;
1627         }
1628
1629         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1630
1631         float is_dead = (STAT(HEALTH) <= 0);
1632
1633         // FIXME do we need this hack?
1634         if(isdemo())
1635         {
1636                 // in demos, input_buttons do not work
1637                 button_zoom = (autocvar__togglezoom == "-");
1638         }
1639         else if(button_zoom
1640                 && autocvar_cl_unpress_zoom_on_death
1641                 && (spectatee_status >= 0)
1642                 && (is_dead || intermission))
1643         {
1644                 // no zoom while dead or in intermission please
1645                 localcmd("-zoom\n");
1646                 button_zoom = false;
1647         }
1648
1649         // abused multiple places below
1650         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1651         if(!local_player)
1652                 local_player = this; // fall back!
1653
1654         // event chase camera
1655         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1656         {
1657                 if(STAT(CAMERA_SPECTATOR))
1658                 {
1659                         if(spectatee_status > 0)
1660                         {
1661                                 if(!autocvar_chase_active)
1662                                 {
1663                                         cvar_set("chase_active", "-2");
1664                                         goto skip_eventchase_death;
1665                                 }
1666                         }
1667                         else if(autocvar_chase_active == -2)
1668                                 cvar_set("chase_active", "0");
1669
1670                         if(autocvar_chase_active == -2)
1671                                 goto skip_eventchase_death;
1672                 }
1673                 else if(autocvar_chase_active == -2)
1674                         cvar_set("chase_active", "0");
1675
1676                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1677
1678                 float vehicle_viewdist = 0;
1679                 vector vehicle_viewofs = '0 0 0';
1680
1681                 if(vehicle_chase)
1682                 {
1683                         if(hud != HUD_BUMBLEBEE_GUN)
1684                         {
1685                                 Vehicle info = Vehicles_from(hud);
1686                                 vehicle_viewdist = info.height;
1687                                 vehicle_viewofs = info.view_ofs;
1688                         }
1689                 }
1690
1691                 if(WantEventchase(this))
1692                 {
1693                         vector current_view_origin_override = '0 0 0';
1694                         vector view_offset_override = '0 0 0';
1695                         float chase_distance_override = 0;
1696                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1697                         if(custom_eventchase)
1698                         {
1699                                 current_view_origin_override = M_ARGV(0, vector);
1700                                 view_offset_override = M_ARGV(1, vector);
1701                                 chase_distance_override = M_ARGV(0, float);
1702                         }
1703                         eventchase_running = true;
1704
1705                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1706                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1707                         if (custom_eventchase)
1708                                 current_view_origin = current_view_origin_override;
1709
1710                         // detect maximum viewoffset and use it
1711                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1712                         if(vehicle_chase)
1713                         {
1714                                 if(vehicle_viewofs)
1715                                         view_offset = vehicle_viewofs;
1716                                 else
1717                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1718                         }
1719                         if (custom_eventchase)
1720                                 view_offset = view_offset_override;
1721
1722                         if(view_offset)
1723                         {
1724                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1725                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1726                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1727                         }
1728
1729                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1730                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1731                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1732                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1733
1734                         // make the camera smooth back
1735                         float chase_distance = autocvar_cl_eventchase_distance;
1736                         if(vehicle_chase)
1737                         {
1738                                 if(vehicle_viewofs)
1739                                         chase_distance = vehicle_viewdist;
1740                                 else
1741                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1742                         }
1743                         if (custom_eventchase)
1744                                 chase_distance = chase_distance_override;
1745
1746                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1747                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1748                         else if(eventchase_current_distance != chase_distance)
1749                                 eventchase_current_distance = chase_distance;
1750
1751                         makevectors(view_angles);
1752
1753                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1754                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1755
1756                         // If the boxtrace fails, revert back to line tracing.
1757                         if(!local_player.viewloc)
1758                         if(trace_startsolid)
1759                         {
1760                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1761                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1762                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1763                         }
1764                         else { setproperty(VF_ORIGIN, trace_endpos); }
1765
1766                         if(!local_player.viewloc)
1767                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1768                 }
1769                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1770                 {
1771                         eventchase_running = false;
1772                         cvar_set("chase_active", "0");
1773                         eventchase_current_distance = 0; // start from 0 next time
1774                 }
1775         }
1776         // workaround for camera stuck between player's legs when using chase_active 1
1777         // because the engine stops updating the chase_active camera when the game ends
1778         else if(intermission)
1779         {
1780                 cvar_settemp("chase_active", "-1");
1781                 eventchase_current_distance = 0;
1782         }
1783
1784         LABEL(skip_eventchase_death);
1785
1786         // do lockview after event chase camera so that it still applies whenever necessary.
1787         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1788         {
1789                 setproperty(VF_ORIGIN, freeze_org);
1790                 setproperty(VF_ANGLES, freeze_ang);
1791         }
1792         else
1793         {
1794                 freeze_org = getpropertyvec(VF_ORIGIN);
1795                 freeze_ang = getpropertyvec(VF_ANGLES);
1796         }
1797
1798         WarpZone_FixView();
1799         //WarpZone_FixPMove();
1800
1801         vector ov_org = '0 0 0';
1802         vector ov_mid = '0 0 0';
1803         vector ov_worldmin = '0 0 0';
1804         vector ov_worldmax = '0 0 0';
1805         if(autocvar_cl_orthoview)
1806         {
1807                 ov_worldmin = mi_picmin;
1808                 ov_worldmax = mi_picmax;
1809
1810                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1811                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1812                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1813
1814                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1815                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1816
1817                 float ov_nearest = vlen(ov_org - vec3(
1818                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1819                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1820                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1821                 ));
1822
1823                 float ov_furthest = 0;
1824                 float dist = 0;
1825
1826                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1827                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1828                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1829                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1830                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1831                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1832                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1833                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1834
1835                 if(!ov_enabled)
1836                 {
1837                         oldr_nearclip = cvar("r_nearclip");
1838                         oldr_farclip_base = cvar("r_farclip_base");
1839                         oldr_farclip_world = cvar("r_farclip_world");
1840                         oldr_novis = cvar("r_novis");
1841                         oldr_useportalculling = cvar("r_useportalculling");
1842                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1843                 }
1844
1845                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1846                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1847                 cvar_settemp("r_farclip_world", "0");
1848                 cvar_settemp("r_novis", "1");
1849                 cvar_settemp("r_useportalculling", "0");
1850                 cvar_settemp("r_useinfinitefarclip", "0");
1851
1852                 setproperty(VF_ORIGIN, ov_org);
1853                 setproperty(VF_ANGLES, '90 0 0');
1854
1855                 ov_enabled = true;
1856
1857                 #if 0
1858                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1859                         vtos(ov_org),
1860                         vtos(getpropertyvec(VF_ANGLES)),
1861                         ov_distance,
1862                         ov_nearest,
1863                         ov_furthest);
1864                 #endif
1865         }
1866         else
1867         {
1868                 if(ov_enabled)
1869                 {
1870                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1871                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1872                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1873                         cvar_set("r_novis", ftos(oldr_novis));
1874                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1875                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1876                 }
1877                 ov_enabled = false;
1878         }
1879
1880         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1881         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1882         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1883                 viewmodel_draw(viewmodels[slot]);
1884
1885         // Render the Scene
1886         view_origin = getpropertyvec(VF_ORIGIN);
1887         view_angles = getpropertyvec(VF_ANGLES);
1888         makevectors(view_angles);
1889         view_forward = v_forward;
1890         view_right = v_right;
1891         view_up = v_up;
1892
1893 #ifdef BLURTEST
1894         if(time > blurtest_time0 && time < blurtest_time1)
1895         {
1896                 float r, t;
1897
1898                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1899                 r = t * blurtest_radius;
1900                 f = 1 / (t ** blurtest_power) - 1;
1901
1902                 cvar_set("r_glsl_postprocess", "1");
1903                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1904         }
1905         else
1906         {
1907                 cvar_set("r_glsl_postprocess", "0");
1908                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1909         }
1910 #endif
1911
1912         TargetMusic_Advance();
1913         Fog_Force();
1914         fpscounter_update();
1915
1916         if(drawtime == 0)
1917                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1918         else
1919                 drawframetime = bound(0.000001, time - drawtime, 1);
1920         drawtime = time;
1921
1922         // watch for gametype changes here...
1923         // in ParseStuffCMD the cmd isn't executed yet :/
1924         // might even be better to add the gametype to TE_CSQC_INIT...?
1925         if(!postinit)
1926                 PostInit();
1927
1928         if(intermission && !intermission_time)
1929                 intermission_time = time;
1930
1931         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1932         {
1933                 if(calledhooks & HOOK_START)
1934                 {
1935                         localcmd("\ncl_hook_gameend\n");
1936                         calledhooks |= HOOK_END;
1937                 }
1938         }
1939
1940         Announcer();
1941
1942         fov = autocvar_fov;
1943         if(fov <= 59.5)
1944         {
1945                 if(!zoomscript_caught)
1946                 {
1947                         localcmd("+button9\n");
1948                         zoomscript_caught = 1;
1949                 }
1950         }
1951         else
1952         {
1953                 if(zoomscript_caught)
1954                 {
1955                         localcmd("-button9\n");
1956                         zoomscript_caught = 0;
1957                 }
1958         }
1959
1960         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1961
1962         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1963         {
1964                 entity wepent = viewmodels[slot];
1965
1966                 if(wepent.last_switchweapon != wepent.switchweapon)
1967                 {
1968                         weapontime = time;
1969                         wepent.last_switchweapon = wepent.switchweapon;
1970                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1971                         {
1972                                 localcmd("-zoom\n");
1973                                 button_zoom = false;
1974                         }
1975                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1976                         {
1977                                 localcmd("-fire\n");
1978                                 localcmd("-fire2\n");
1979                                 button_attack2 = false;
1980                         }
1981                 }
1982                 if(wepent.last_activeweapon != wepent.activeweapon)
1983                 {
1984                         wepent.last_activeweapon = wepent.activeweapon;
1985
1986                         e = wepent.activeweapon;
1987                         if(e.netname != "")
1988                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1989                         else if(slot == 0)
1990                                 localcmd("\ncl_hook_activeweapon none\n");
1991                 }
1992         }
1993
1994         // ALWAYS Clear Current Scene First
1995         clearscene();
1996
1997         setproperty(VF_ORIGIN, view_origin);
1998         setproperty(VF_ANGLES, view_angles);
1999
2000         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2001         setproperty(VF_SIZE, vf_size);
2002         setproperty(VF_MIN, vf_min);
2003
2004         // Assign Standard Viewflags
2005         // Draw the World (and sky)
2006         setproperty(VF_DRAWWORLD, 1);
2007
2008         // Set the console size vars
2009         vid_conwidth = autocvar_vid_conwidth;
2010         vid_conheight = autocvar_vid_conheight;
2011         vid_pixelheight = autocvar_vid_pixelheight;
2012
2013         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2014         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2015         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2016
2017         if(camera_active) // Camera for demo playback
2018         {
2019                 if(autocvar_camera_enable)
2020                         CSQC_Demo_Camera();
2021                 else
2022                 {
2023                         cvar_set("chase_active", ftos(chase_active_backup));
2024                         cvar_set("cl_demo_mousegrab", "0");
2025                         camera_active = false;
2026                 }
2027         }
2028         else
2029         {
2030 #ifdef CAMERATEST
2031                 if(autocvar_camera_enable)
2032 #else
2033                 if(autocvar_camera_enable && isdemo())
2034 #endif
2035                 {
2036                         // Enable required Darkplaces cvars
2037                         chase_active_backup = autocvar_chase_active;
2038                         cvar_set("chase_active", "2");
2039                         cvar_set("cl_demo_mousegrab", "1");
2040                         camera_active = true;
2041                         camera_mode = false;
2042                 }
2043         }
2044
2045         // Draw the Crosshair
2046         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2047
2048         // Draw the Engine Status Bar (the default Quake HUD)
2049         setproperty(VF_DRAWENGINESBAR, 0);
2050
2051         // Update the mouse position
2052         /*
2053            mousepos_x = vid_conwidth;
2054            mousepos_y = vid_conheight;
2055            mousepos = mousepos*0.5 + getmousepos();
2056          */
2057
2058         IL_EACH(g_drawables, it.draw, it.draw(it));
2059
2060         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
2061         renderscene();
2062
2063         // now switch to 2D drawing mode by calling a 2D drawing function
2064         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2065         // next R_RenderScene call
2066         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2067
2068         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2069         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2070         {
2071                 // apply night vision effect
2072                 vector tc_00, tc_01, tc_10, tc_11;
2073                 vector rgb = '0 0 0';
2074
2075                 if(!nightvision_noise)
2076                 {
2077                         nightvision_noise = new(nightvision_noise);
2078                 }
2079                 if(!nightvision_noise2)
2080                 {
2081                         nightvision_noise2 = new(nightvision_noise2);
2082                 }
2083
2084                 // color tint in yellow
2085                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2086
2087                 // draw BG
2088                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2089                 rgb = '1 1 1';
2090                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2091                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2092                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2093                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2094                 tc_11 = tc_01 + tc_10 - tc_00;
2095                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2096                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2097                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2098                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2099                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2100                 R_EndPolygon();
2101
2102                 // draw FG
2103                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2104                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2105                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2106                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2107                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2108                 tc_11 = tc_01 + tc_10 - tc_00;
2109                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2110                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2111                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2112                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2113                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2114                 R_EndPolygon();
2115         }
2116
2117         if(autocvar_cl_reticle)
2118         {
2119                 string reticle_image = string_null;
2120                 bool wep_zoomed = false;
2121                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2122                 {
2123                         entity wepe = viewmodels[slot];
2124                         Weapon wep = wepe.activeweapon;
2125                         if(wep != WEP_Null && wep.wr_zoom)
2126                         {
2127                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2128                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2129                                         reticle_image = wep.w_reticle;
2130                                 wep_zoomed += do_zoom;
2131                         }
2132                 }
2133                 // Draw the aiming reticle for weapons that use it
2134                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2135                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2136                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2137                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2138                 {
2139                         // no zoom reticle while dead
2140                         reticle_type = 0;
2141                 }
2142                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2143                 {
2144                         if(reticle_image) { reticle_type = 2; }
2145                         else { reticle_type = 0; }
2146                 }
2147                 else if(button_zoom || zoomscript_caught)
2148                 {
2149                         // normal zoom
2150                         reticle_type = 1;
2151                 }
2152
2153                 if(reticle_type)
2154                 {
2155                         if(autocvar_cl_reticle_stretch)
2156                         {
2157                                 reticle_size.x = vid_conwidth;
2158                                 reticle_size.y = vid_conheight;
2159                                 reticle_pos.x = 0;
2160                                 reticle_pos.y = 0;
2161                         }
2162                         else
2163                         {
2164                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2165                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2166                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2167                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2168                         }
2169
2170                         if(zoomscript_caught)
2171                                 f = 1;
2172                         else
2173                                 f = current_zoomfraction;
2174
2175                         if(f)
2176                         {
2177                                 switch(reticle_type)
2178                                 {
2179                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2180                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2181                                 }
2182                         }
2183                 }
2184         }
2185         else
2186         {
2187                 if(reticle_type != 0) { reticle_type = 0; }
2188         }
2189
2190
2191         // improved polyblend
2192         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2193         {
2194                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2195                 vector liquidcolor;
2196
2197                 switch(pointcontents(view_origin))
2198                 {
2199                         case CONTENT_WATER:
2200                                 liquidalpha = autocvar_hud_contents_water_alpha;
2201                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2202                                 incontent = 1;
2203                                 break;
2204
2205                         case CONTENT_LAVA:
2206                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2207                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2208                                 incontent = 1;
2209                                 break;
2210
2211                         case CONTENT_SLIME:
2212                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2213                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2214                                 incontent = 1;
2215                                 break;
2216
2217                         default:
2218                                 liquidalpha = 0;
2219                                 liquidcolor = '0 0 0';
2220                                 incontent = 0;
2221                                 break;
2222                 }
2223
2224                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2225                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2226                         contentfadetime = autocvar_hud_contents_fadeintime;
2227                         liquidalpha_prev = liquidalpha;
2228                         liquidcolor_prev = liquidcolor;
2229                 }
2230                 else
2231                         contentfadetime = autocvar_hud_contents_fadeouttime;
2232
2233                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2234                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2235
2236                 if(contentavgalpha)
2237                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2238
2239                 if(autocvar_hud_postprocessing)
2240                 {
2241                         if(autocvar_hud_contents_blur && contentavgalpha)
2242                         {
2243                                 content_blurpostprocess.x = 1;
2244                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2245                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2246                         }
2247                         else
2248                         {
2249                                 content_blurpostprocess.x = 0;
2250                                 content_blurpostprocess.y = 0;
2251                                 content_blurpostprocess.z = 0;
2252                         }
2253                 }
2254         }
2255
2256         if(autocvar_hud_damage && !STAT(FROZEN))
2257         {
2258                 splash_size.x = max(vid_conwidth, vid_conheight);
2259                 splash_size.y = max(vid_conwidth, vid_conheight);
2260                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2261                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2262
2263                 float myhealth_flash_temp;
2264                 myhealth = STAT(HEALTH);
2265
2266                 // fade out
2267                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2268                 // add new damage
2269                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2270
2271                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2272                 pain_threshold = autocvar_hud_damage_pain_threshold;
2273                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2274                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2275
2276                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2277                 {
2278                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2279                 }
2280
2281                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2282
2283                 if(myhealth_prev < 1)
2284                 {
2285                         if(myhealth >= 1)
2286                         {
2287                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2288                                 myhealth_flash_temp = 0;
2289                         }
2290                         else
2291                         {
2292                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2293                         }
2294                 }
2295
2296                 if(spectatee_status == -1 || intermission)
2297                 {
2298                         myhealth_flash = 0; // observing, or match ended
2299                         myhealth_flash_temp = 0;
2300                 }
2301
2302                 myhealth_prev = myhealth;
2303
2304                 // IDEA: change damage color/picture based on player model for robot/alien species?
2305                 // pro: matches model better
2306                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2307                 // maybe different reddish pics?
2308                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2309                 {
2310                         if(autocvar_cl_gentle_damage == 2)
2311                         {
2312                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2313                                         myhealth_gentlergb = randomvec();
2314                         }
2315                         else
2316                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2317
2318                         if(myhealth_flash_temp > 0)
2319                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2320                 }
2321                 else if(myhealth_flash_temp > 0)
2322                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2323
2324                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2325                 {
2326                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2327                         {
2328                                 damage_blurpostprocess.x = 1;
2329                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2330                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2331                         }
2332                         else
2333                         {
2334                                 damage_blurpostprocess.x = 0;
2335                                 damage_blurpostprocess.y = 0;
2336                                 damage_blurpostprocess.z = 0;
2337                         }
2338                 }
2339         }
2340
2341         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2342         float e2 = (autocvar_hud_powerup != 0);
2343         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2344         {
2345                 // enable or disable rendering types if they are used or not
2346                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2347                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2348
2349                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2350                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2351                 {
2352                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2353                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2354                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2355                         {
2356                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2357                                 old_blurradius = blurradius;
2358                                 old_bluralpha = bluralpha;
2359                         }
2360                 }
2361                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2362                 {
2363                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2364                         old_blurradius = 0;
2365                         old_bluralpha = 0;
2366                 }
2367
2368                 // edge detection postprocess handling done second (used by hud_powerup)
2369                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2370                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2371                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2372
2373                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2374
2375                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2376                 {
2377                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2378                         {
2379                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2380                                 old_sharpen_intensity = sharpen_intensity;
2381                         }
2382                 }
2383                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2384                 {
2385                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2386                         old_sharpen_intensity = 0;
2387                 }
2388
2389                 if(cvar("r_glsl_postprocess") == 0)
2390                         cvar_set("r_glsl_postprocess", "2");
2391         }
2392         else if(cvar("r_glsl_postprocess") == 2)
2393                 cvar_set("r_glsl_postprocess", "0");
2394
2395         /*if(gametype == MAPINFO_TYPE_CTF)
2396           {
2397           ctf_view();
2398           } else */
2399
2400         // draw 2D entities
2401         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2402         Draw_ShowNames_All();
2403 #if ENABLE_DEBUGDRAW
2404         Debug_Draw();
2405 #endif
2406
2407         scoreboard_active = Scoreboard_WouldDraw();
2408
2409         HUD_Draw(this); // this parameter for deep vehicle function
2410
2411         if(NextFrameCommand)
2412         {
2413                 localcmd("\n", NextFrameCommand, "\n");
2414                 NextFrameCommand = string_null;
2415         }
2416
2417         // we must do this check AFTER a frame was rendered, or it won't work
2418         if(cs_project_is_b0rked == 0)
2419         {
2420                 string w0, h0;
2421                 w0 = ftos(autocvar_vid_conwidth);
2422                 h0 = ftos(autocvar_vid_conheight);
2423                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2424                 //setproperty(VF_FOV, '90 90 0');
2425                 setproperty(VF_ORIGIN, '0 0 0');
2426                 setproperty(VF_ANGLES, '0 0 0');
2427                 setproperty(VF_PERSPECTIVE, 1);
2428                 makevectors('0 0 0');
2429                 vector v1, v2;
2430                 cvar_set("vid_conwidth", "800");
2431                 cvar_set("vid_conheight", "600");
2432                 v1 = cs_project(v_forward);
2433                 cvar_set("vid_conwidth", "640");
2434                 cvar_set("vid_conheight", "480");
2435                 v2 = cs_project(v_forward);
2436                 if(v1 == v2)
2437                         cs_project_is_b0rked = 1;
2438                 else
2439                         cs_project_is_b0rked = -1;
2440                 cvar_set("vid_conwidth", w0);
2441                 cvar_set("vid_conheight", h0);
2442         }
2443
2444         if(autocvar__hud_configure)
2445                 HUD_Panel_Mouse();
2446         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2447                 HUD_Minigame_Mouse();
2448         else if(QuickMenu_IsOpened())
2449                 QuickMenu_Mouse();
2450         else if(local_player.viewloc && (local_player.viewloc.spawnflags & VIEWLOC_FREEAIM))
2451                 ViewLocation_Mouse(); // NOTE: doesn't use cursormode
2452         else
2453                 HUD_Radar_Mouse();
2454
2455         cl_notice_run();
2456         unpause_update();
2457         Net_Flush();
2458
2459         // let's reset the view back to normal for the end
2460         setproperty(VF_MIN, '0 0 0');
2461         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2462
2463         IL_ENDFRAME();
2464 }
2465
2466
2467 // following vectors must be global to allow seamless switching between camera modes
2468 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2469 void CSQC_Demo_Camera()
2470 {
2471         float speed, attenuation, dimensions;
2472         vector tmp, delta;
2473
2474         if( autocvar_camera_reset || !camera_mode )
2475         {
2476                 camera_offset = '0 0 0';
2477                 current_angles = '0 0 0';
2478                 camera_direction = '0 0 0';
2479                 camera_offset.z += 30;
2480                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2481                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2482                 current_origin = view_origin;
2483                 current_camera_offset  = camera_offset;
2484                 cvar_set("camera_reset", "0");
2485                 camera_mode = CAMERA_CHASE;
2486         }
2487
2488         // Camera angles
2489         if( camera_roll )
2490                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2491
2492         if(autocvar_camera_look_player)
2493         {
2494                 vector dir;
2495                 float n;
2496
2497                 dir = normalize(view_origin - current_position);
2498                 n = mouse_angles.z;
2499                 mouse_angles = vectoangles(dir);
2500                 mouse_angles.x = mouse_angles.x * -1;
2501                 mouse_angles.z = n;
2502         }
2503         else
2504         {
2505                 tmp = getmousepos() * 0.1;
2506                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2507                 {
2508                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2509                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2510                 }
2511         }
2512
2513         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2514         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2515         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2516         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2517
2518         // Fix difference when angles don't have the same sign
2519         delta = '0 0 0';
2520         if(mouse_angles.y < -60 && current_angles.y > 60)
2521                 delta = '0 360 0';
2522         if(mouse_angles.y > 60 && current_angles.y < -60)
2523                 delta = '0 -360 0';
2524
2525         if(autocvar_camera_look_player)
2526                 attenuation = autocvar_camera_look_attenuation;
2527         else
2528                 attenuation = autocvar_camera_speed_attenuation;
2529
2530         attenuation = 1 / max(1, attenuation);
2531         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2532
2533         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2534         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2535         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2536         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2537
2538         // Camera position
2539         tmp = '0 0 0';
2540         dimensions = 0;
2541
2542         if( camera_direction.x )
2543         {
2544                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2545                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2546                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2547                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2548                 ++dimensions;
2549         }
2550
2551         if( camera_direction.y )
2552         {
2553                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2554                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2555                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2556                 ++dimensions;
2557         }
2558
2559         if( camera_direction.z )
2560         {
2561                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2562                 ++dimensions;
2563         }
2564
2565         if(autocvar_camera_free)
2566                 speed = autocvar_camera_speed_free;
2567         else
2568                 speed = autocvar_camera_speed_chase;
2569
2570         if(dimensions)
2571         {
2572                 speed = speed * sqrt(1 / dimensions);
2573                 camera_offset += tmp * speed;
2574         }
2575
2576         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2577
2578         // Camera modes
2579         if( autocvar_camera_free )
2580         {
2581                 if ( camera_mode == CAMERA_CHASE )
2582                 {
2583                         current_camera_offset = current_origin + current_camera_offset;
2584                         camera_offset = current_origin + camera_offset;
2585                 }
2586
2587                 camera_mode = CAMERA_FREE;
2588                 current_position = current_camera_offset;
2589         }
2590         else
2591         {
2592                 if ( camera_mode == CAMERA_FREE )
2593                 {
2594                         current_origin = view_origin;
2595                         camera_offset = camera_offset - current_origin;
2596                         current_camera_offset = current_camera_offset - current_origin;
2597                 }
2598
2599                 camera_mode = CAMERA_CHASE;
2600
2601                 if(autocvar_camera_chase_smoothly)
2602                         current_origin += (view_origin - current_origin) * attenuation;
2603                 else
2604                         current_origin = view_origin;
2605
2606                 current_position = current_origin + current_camera_offset;
2607         }
2608
2609         setproperty(VF_ANGLES, current_angles);
2610         setproperty(VF_ORIGIN, current_position);
2611 }