qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include "mutators/events.qh"
  13
  14 #include <common/animdecide.qh>
  15 #include <common/ent_cs.qh>
  16 #include <common/anim.qh>
  17 #include <common/constants.qh>
  18 #include <common/net_linked.qh>
  19 #include <common/debug.qh>
  20 #include <common/mapinfo.qh>
  21 #include <common/gamemodes/_mod.qh>
  22 #include <common/physics/player.qh>
  23 #include <common/stats.qh>
  24 #include <common/triggers/target/music.qh>
  25 #include <common/teams.qh>
  26 #include <common/wepent.qh>
  27
  28 #include <common/weapons/weapon/tuba.qh>
  29
  30 #include <common/vehicles/all.qh>
  31 #include <common/weapons/_all.qh>
  32 #include <common/viewloc.qh>
  33 #include <common/minigames/cl_minigames.qh>
  34 #include <common/minigames/cl_minigames_hud.qh>
  35
  36 #include <lib/csqcmodel/cl_player.qh>
  37 #include <lib/csqcmodel/cl_model.qh>
  38 #include "csqcmodel_hooks.qh"
  39
  40 #include <lib/warpzone/client.qh>
  41 #include <lib/warpzone/common.qh>
  42
  43 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  44
  45 float autocvar_cl_viewmodel_scale;
  46
  47 bool autocvar_cl_bobmodel;
  48 float autocvar_cl_bobmodel_speed;
  49 float autocvar_cl_bobmodel_side;
  50 float autocvar_cl_bobmodel_up;
  51
  52 float autocvar_cl_followmodel;
  53 float autocvar_cl_followmodel_speed = 0.3;
  54 float autocvar_cl_followmodel_limit = 135;
  55 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  56 float autocvar_cl_followmodel_highpass = 0.05;
  57 float autocvar_cl_followmodel_lowpass = 0.03;
  58 bool autocvar_cl_followmodel_velocity_absolute;
  59
  60 float autocvar_cl_leanmodel;
  61 float autocvar_cl_leanmodel_speed = 0.3;
  62 float autocvar_cl_leanmodel_limit = 30;
  63 float autocvar_cl_leanmodel_highpass1 = 0.2;
  64 float autocvar_cl_leanmodel_highpass = 0.2;
  65 float autocvar_cl_leanmodel_lowpass = 0.05;
  66
  67 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  68
  69 #define lowpass(value, frac, ref_store, ret) \
  70         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  71
  72 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  73 { \
  74         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  75         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  76 } MACRO_END
  77
  78 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  79 { \
  80         float __f = 0; lowpass(value, frac, ref_store, __f); \
  81         ret = (value) - __f; \
  82 } MACRO_END
  83
  84 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  85 { \
  86         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  87         ret = (value) - __f; \
  88 } MACRO_END
  89
  90 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  91 { \
  92         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  93         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  94 } MACRO_END
  95
  96 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  97 { \
  98         highpass(value.x, frac, ref_store.x, ref_out.x); \
  99         highpass(value.y, frac, ref_store.y, ref_out.y); \
 100 } MACRO_END
 101
 102 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 103 { \
 104         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 105         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 106 } MACRO_END
 107
 108 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 109 { \
 110         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 111         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 112         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 113 } MACRO_END
 114
 115 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 116 { \
 117         highpass(value.x, frac, ref_store.x, ref_out.x); \
 118         highpass(value.y, frac, ref_store.y, ref_out.y); \
 119         highpass(value.z, frac, ref_store.z, ref_out.z); \
 120 } MACRO_END
 121
 122 void calc_followmodel_ofs(entity view)
 123 {
 124         if(cl_followmodel_time == time)
 125                 return; // cl_followmodel_ofs already calculated for this frame
 126
 127         float frac;
 128         vector gunorg = '0 0 0';
 129         static vector vel_average;
 130         static vector gunorg_adjustment_highpass;
 131         static vector gunorg_adjustment_lowpass;
 132
 133         vector vel;
 134         if (autocvar_cl_followmodel_velocity_absolute)
 135                 vel = view.velocity;
 136         else
 137         {
 138                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 139                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 140                 vel.x = view.velocity * forward;
 141                 vel.y = view.velocity * right * -1;
 142                 vel.z = view.velocity * up;
 143         }
 144
 145         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 146         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 147         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 148
 149         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 150         lowpass3(vel, frac, vel_average, gunorg);
 151
 152         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 153
 154         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 155         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 156         frac = avg_factor(autocvar_cl_followmodel_highpass);
 157         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 158         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 159         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 160
 161         if (autocvar_cl_followmodel_velocity_absolute)
 162         {
 163                 vector fixed_gunorg;
 164                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 165                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 166                 fixed_gunorg.x = gunorg * forward;
 167                 fixed_gunorg.y = gunorg * right * -1;
 168                 fixed_gunorg.z = gunorg * up;
 169                 gunorg = fixed_gunorg;
 170         }
 171
 172         cl_followmodel_ofs = gunorg;
 173         cl_followmodel_time = time;
 174 }
 175
 176 vector leanmodel_ofs(entity view)
 177 {
 178         float frac;
 179         vector gunangles = '0 0 0';
 180         static vector gunangles_prev = '0 0 0';
 181         static vector gunangles_highpass = '0 0 0';
 182         static vector gunangles_adjustment_highpass;
 183         static vector gunangles_adjustment_lowpass;
 184
 185         if (view.csqcmodel_teleported)
 186                 gunangles_prev = view_angles;
 187
 188         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 189         gunangles_highpass += gunangles_prev;
 190         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 191         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 192         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 193         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 194         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 195         gunangles_prev = view_angles;
 196         gunangles_highpass -= gunangles_prev;
 197
 198         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 199         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 200
 201         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 202         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 203         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 204         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 205         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 206
 207         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 208
 209         return gunangles;
 210 }
 211
 212 vector bobmodel_ofs(entity view)
 213 {
 214         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 215         static bool oldonground;
 216         static float hitgroundtime;
 217         if (clonground)
 218         {
 219                 float f = time; // cl.movecmd[0].time
 220                 if (!oldonground)
 221                         hitgroundtime = f;
 222         }
 223         oldonground = clonground;
 224
 225         // calculate for swinging gun model
 226         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 227         vector gunorg = '0 0 0';
 228         static float bobmodel_scale = 0;
 229         static float time_ofs = 0; // makes the effect always restart in the same way
 230         if (clonground)
 231         {
 232                 if (time - hitgroundtime > 0.05)
 233                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 234         }
 235         else
 236                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 237
 238         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 239         if (bobmodel_scale && xyspeed)
 240         {
 241                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 242                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 243                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 244                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 245         }
 246         else
 247                 time_ofs = time;
 248
 249         return gunorg;
 250 }
 251
 252 void viewmodel_animate(entity this)
 253 {
 254         if (autocvar_chase_active) return;
 255         if (STAT(HEALTH) <= 0) return;
 256
 257         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 258
 259         if (autocvar_cl_followmodel)
 260         {
 261                 calc_followmodel_ofs(view);
 262                 this.origin += cl_followmodel_ofs;
 263         }
 264
 265         if (autocvar_cl_leanmodel)
 266                 this.angles += leanmodel_ofs(view);
 267
 268         // vertical view bobbing code
 269         // TODO: cl_bob
 270
 271         // horizontal view bobbing code
 272         // TODO: cl_bob2
 273
 274         // fall bobbing code
 275         // causes the view to swing down and back up when touching the ground
 276         // TODO: cl_bobfall
 277
 278         // gun model bobbing code
 279         if (autocvar_cl_bobmodel)
 280                 this.origin += bobmodel_ofs(view);
 281 }
 282
 283 .vector viewmodel_origin, viewmodel_angles;
 284 .float weapon_nextthink;
 285 .float weapon_eta_last;
 286 .float weapon_switchdelay;
 287
 288 .string name_last;
 289
 290 void viewmodel_draw(entity this)
 291 {
 292         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 293                 return;
 294         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 295         float a = this.alpha;
 296         static bool wasinvehicle;
 297         bool invehicle = player_localentnum > maxclients;
 298         if (invehicle) a = -1;
 299         else if (wasinvehicle) a = 1;
 300         wasinvehicle = invehicle;
 301         Weapon wep = this.activeweapon;
 302         int c = entcs_GetClientColors(current_player);
 303         vector g = weaponentity_glowmod(wep, NULL, c, this);
 304         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 305         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 306                 | EF_NODEPTHTEST)
 307                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 308         for (entity e = this; e; e = e.weaponchild)
 309         {
 310                 e.drawmask = mask;
 311                 e.alpha = a;
 312                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 313                 e.glowmod = g;
 314                 e.csqcmodel_effects = fx;
 315                 CSQCModel_Effects_Apply(e);
 316         }
 317         if(a >= 0)
 318         {
 319                 string name = wep.mdl;
 320                 string newname = wep.wr_viewmodel(wep, this);
 321                 if(newname)
 322                         name = newname;
 323                 bool swap = name != this.name_last;
 324                 // if (swap)
 325                 {
 326                         this.name_last = name;
 327                         CL_WeaponEntity_SetModel(this, name, swap);
 328                         this.viewmodel_origin = this.origin;
 329                         this.viewmodel_angles = this.angles;
 330                 }
 331                 anim_update(this);
 332                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 333                         anim_set(this, this.anim_idle, true, false, false);
 334         }
 335         float f = 0; // 0..1; 0: fully active
 336         float rate = STAT(WEAPONRATEFACTOR);
 337         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 338         if (eta <= 0) f = this.weapon_eta_last;
 339         else switch (this.state)
 340         {
 341                 case WS_RAISE:
 342                 {
 343                         f = eta / max(eta, this.weapon_switchdelay);
 344                         break;
 345                 }
 346                 case WS_DROP:
 347                 {
 348                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 349                         break;
 350                 }
 351                 case WS_CLEAR:
 352                 {
 353                         f = 1;
 354                         break;
 355                 }
 356         }
 357         this.weapon_eta_last = f;
 358         this.origin = this.viewmodel_origin;
 359         this.angles = this.viewmodel_angles;
 360         this.angles_x = (-90 * f * f);
 361         viewmodel_animate(this);
 362         MUTATOR_CALLHOOK(DrawViewModel, this);
 363         setorigin(this, this.origin);
 364 }
 365
 366 STATIC_INIT(viewmodel) {
 367     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 368         viewmodels[slot] = new(viewmodel);
 369 }
 370
 371 void Porto_Draw(entity this);
 372 STATIC_INIT(Porto)
 373 {
 374         entity e = new_pure(porto);
 375         e.draw = Porto_Draw;
 376         IL_PUSH(g_drawables, e);
 377         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 378 }
 379
 380 const int polyline_length = 16;
 381 .vector polyline[polyline_length];
 382 void Porto_Draw(entity this)
 383 {
 384         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 385         {
 386                 entity wepent = viewmodels[slot];
 387
 388                 if (wepent.activeweapon != WEP_PORTO) continue;
 389                 if (spectatee_status) continue;
 390                 if (WEP_CVAR(porto, secondary)) continue;
 391                 if (intermission == 1) continue;
 392                 if (intermission == 2) continue;
 393                 if (STAT(HEALTH) <= 0) continue;
 394
 395                 vector pos = view_origin;
 396                 vector dir = view_forward;
 397                 if (wepent.angles_held_status)
 398                 {
 399                         makevectors(wepent.angles_held);
 400                         dir = v_forward;
 401                 }
 402
 403                 wepent.polyline[0] = pos;
 404
 405                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 406                 int n = 1 + 2;  // 2 lines == 3 points
 407                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 408                 {
 409                         traceline(pos, pos + 65536 * dir, true, this);
 410                         dir = reflect(dir, trace_plane_normal);
 411                         pos = trace_endpos;
 412                         wepent.polyline[++idx] = pos;
 413                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 414                         {
 415                                 n += 1;
 416                                 continue;
 417                         }
 418                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 419                         {
 420                                 n = max(2, idx);
 421                                 break;
 422                         }
 423                         // check size
 424                         {
 425                                 vector ang = vectoangles2(trace_plane_normal, dir);
 426                                 ang.x = -ang.x;
 427                                 makevectors(ang);
 428                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 429                                 {
 430                                         n = max(2, idx);
 431                                         break;
 432                                 }
 433                         }
 434                         portal_number += 1;
 435                         if (portal_number >= portal_max) break;
 436                         if (portal_number == 1) portal1_idx = idx;
 437                 }
 438                 for (int idx = 0; idx < n - 1; ++idx)
 439                 {
 440                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 441                         if (idx == 0) p -= view_up * 16;  // line from player
 442                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 443                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 444                 }
 445         }
 446 }
 447
 448 float drawtime;
 449 float avgspeed;
 450 vector GetCurrentFov(float fov)
 451 {
 452         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 453         float velocityzoom, curspeed;
 454         vector v;
 455
 456         zoomsensitivity = autocvar_cl_zoomsensitivity;
 457         zoomfactor = autocvar_cl_zoomfactor;
 458         if(zoomfactor < 1 || zoomfactor > 30)
 459                 zoomfactor = 2.5;
 460         zoomspeed = autocvar_cl_zoomspeed;
 461         if(zoomspeed >= 0)
 462         if(zoomspeed < 0.5 || zoomspeed > 16)
 463                         zoomspeed = 3.5;
 464
 465         zoomdir = button_zoom;
 466
 467         if(hud == HUD_NORMAL && !spectatee_status)
 468         {
 469                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 470                 {
 471                         entity wepent = viewmodels[slot];
 472                         if(wepent.switchweapon == wepent.activeweapon)
 473                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 474                                 zoomdir += button_attack2;
 475                 }
 476         }
 477         if(spectatee_status > 0 || isdemo())
 478         {
 479                 if(spectatorbutton_zoom)
 480                 {
 481                         if(zoomdir)
 482                                 zoomdir = 0;
 483                         else
 484                                 zoomdir = 1;
 485                 }
 486                 // fteqcc failed twice here already, don't optimize this
 487         }
 488
 489         if(zoomdir) { zoomin_effect = 0; }
 490
 491         if(camera_active)
 492         {
 493                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 494         }
 495         else if(autocvar_cl_spawnzoom && zoomin_effect)
 496         {
 497                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 498
 499                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 500                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 501                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 502         }
 503         else
 504         {
 505                 if(zoomspeed < 0) // instant zoom
 506                 {
 507                         if(zoomdir)
 508                                 current_viewzoom = 1 / zoomfactor;
 509                         else
 510                                 current_viewzoom = 1;
 511                 }
 512                 else
 513                 {
 514                         if(zoomdir)
 515                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 516                         else
 517                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 518                 }
 519         }
 520
 521         if(almost_equals(current_viewzoom, 1))
 522                 current_zoomfraction = 0;
 523         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 524                 current_zoomfraction = 1;
 525         else
 526                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 527
 528         if(zoomsensitivity < 1)
 529                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 530         else
 531                 setsensitivityscale(1);
 532
 533         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 534         {
 535                 if(intermission) { curspeed = 0; }
 536                 else
 537                 {
 538
 539                         makevectors(view_angles);
 540                         v = pmove_vel;
 541                         if(csqcplayer)
 542                                 v = csqcplayer.velocity;
 543
 544                         switch(autocvar_cl_velocityzoom_type)
 545                         {
 546                                 case 3: curspeed = max(0, v_forward * v); break;
 547                                 case 2: curspeed = (v_forward * v); break;
 548                                 case 1: default: curspeed = vlen(v); break;
 549                         }
 550                 }
 551
 552                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 553                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 554                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 555
 556                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 557         }
 558         else
 559                 velocityzoom = 1;
 560
 561         float frustumx, frustumy, fovx, fovy;
 562         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 563         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 564         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 565         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 566
 567         return '1 0 0' * fovx + '0 1 0' * fovy;
 568 }
 569
 570 vector GetViewLocationFOV(float fov)
 571 {
 572         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 573         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 574         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 575         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 576         return '1 0 0' * fovx + '0 1 0' * fovy;
 577 }
 578
 579 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 580 {
 581         float fovx, fovy;
 582         float width = (ov_worldmax.x - ov_worldmin.x);
 583         float height = (ov_worldmax.y - ov_worldmin.y);
 584         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 585         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 586         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 587         return '1 0 0' * fovx + '0 1 0' * fovy;
 588 }
 589
 590 // this function must match W_SetupShot!
 591 float zoomscript_caught;
 592
 593 vector wcross_origin;
 594 float wcross_scale_prev, wcross_alpha_prev;
 595 vector wcross_color_prev;
 596 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 597 vector wcross_color_goal_prev;
 598 float wcross_changedonetime;
 599
 600 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 601 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 602 float wcross_name_changestarttime, wcross_name_changedonetime;
 603 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 604
 605 float wcross_ring_prev;
 606
 607 entity trueaim;
 608 entity trueaim_rifle;
 609
 610 const float SHOTTYPE_HITTEAM = 1;
 611 const float SHOTTYPE_HITOBSTRUCTION = 2;
 612 const float SHOTTYPE_HITWORLD = 3;
 613 const float SHOTTYPE_HITENEMY = 4;
 614
 615 void TrueAim_Init()
 616 {
 617         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 618         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 619 }
 620
 621 float EnemyHitCheck()
 622 {
 623         float t, n;
 624         wcross_origin = project_3d_to_2d(trace_endpos);
 625         wcross_origin.z = 0;
 626         if(trace_ent)
 627                 n = trace_ent.entnum;
 628         else
 629                 n = trace_networkentity;
 630         if(n < 1)
 631                 return SHOTTYPE_HITWORLD;
 632         if(n > maxclients)
 633                 return SHOTTYPE_HITWORLD;
 634         t = entcs_GetTeam(n - 1);
 635         if(teamplay)
 636                 if(t == myteam)
 637                         return SHOTTYPE_HITTEAM;
 638         if(t == NUM_SPECTATOR)
 639                 return SHOTTYPE_HITWORLD;
 640         return SHOTTYPE_HITENEMY;
 641 }
 642
 643 float TrueAimCheck(entity wepent)
 644 {
 645         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 646         vector vecs, trueaimpoint, w_shotorg;
 647         vector mi, ma, dv;
 648         float shottype;
 649         entity ta;
 650         float mv;
 651
 652         mi = ma = '0 0 0';
 653         ta = trueaim;
 654         mv = MOVE_NOMONSTERS;
 655
 656         switch(wepent.activeweapon) // WEAPONTODO
 657         {
 658                 case WEP_TUBA: // no aim
 659                 case WEP_PORTO: // shoots from eye
 660                 case WEP_NEXBALL: // shoots from eye
 661                 case WEP_HOOK: // no trueaim
 662                 case WEP_MORTAR: // toss curve
 663                         return SHOTTYPE_HITWORLD;
 664                 case WEP_VORTEX:
 665                 case WEP_VAPORIZER:
 666                         mv = MOVE_NORMAL;
 667                         break;
 668                 case WEP_RIFLE:
 669                         ta = trueaim_rifle;
 670                         mv = MOVE_NORMAL;
 671                         if(zoomscript_caught)
 672                         {
 673                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 674                                 return EnemyHitCheck();
 675                         }
 676                         break;
 677                 case WEP_DEVASTATOR: // projectile has a size!
 678                         mi = '-3 -3 -3';
 679                         ma = '3 3 3';
 680                         break;
 681                 case WEP_FIREBALL: // projectile has a size!
 682                         mi = '-16 -16 -16';
 683                         ma = '16 16 16';
 684                         break;
 685                 case WEP_SEEKER: // projectile has a size!
 686                         mi = '-2 -2 -2';
 687                         ma = '2 2 2';
 688                         break;
 689                 case WEP_ELECTRO: // projectile has a size!
 690                         mi = '0 0 -3';
 691                         ma = '0 0 -3';
 692                         break;
 693         }
 694
 695         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 696
 697         vecs = decompressShotOrigin(STAT(SHOTORG));
 698
 699         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 700         trueaimpoint = trace_endpos;
 701
 702         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 703                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 704
 705         if(vecs.x > 0)
 706                 vecs.y = -vecs.y;
 707         else
 708                 vecs = '0 0 0';
 709
 710         dv = view_right * vecs.y + view_up * vecs.z;
 711         w_shotorg = traceorigin + dv;
 712
 713         // now move the vecs forward as much as requested if possible
 714         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 715         w_shotorg = trace_endpos - view_forward * nudge;
 716
 717         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 718         shottype = EnemyHitCheck();
 719         if(shottype != SHOTTYPE_HITWORLD)
 720                 return shottype;
 721
 722 #if 0
 723         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 724         // or rather, I know why, but see no fix
 725         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 726                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 727                 return SHOTTYPE_HITOBSTRUCTION;
 728 #endif
 729
 730         return SHOTTYPE_HITWORLD;
 731 }
 732
 733 void PostInit();
 734 void CSQC_Demo_Camera();
 735 float camera_mode;
 736 const float CAMERA_FREE = 1;
 737 const float CAMERA_CHASE = 2;
 738 float reticle_type;
 739 string NextFrameCommand;
 740
 741 vector freeze_org, freeze_ang;
 742 entity nightvision_noise, nightvision_noise2;
 743
 744 const float MAX_TIME_DIFF = 5;
 745 float pickup_crosshair_time, pickup_crosshair_size;
 746 float hitindication_crosshair_size;
 747 float use_vortex_chargepool;
 748
 749 float myhealth, myhealth_prev;
 750 float myhealth_flash;
 751
 752 float old_blurradius, old_bluralpha;
 753 float old_sharpen_intensity;
 754
 755 vector myhealth_gentlergb;
 756
 757 float contentavgalpha, liquidalpha_prev;
 758 vector liquidcolor_prev;
 759
 760 float eventchase_current_distance;
 761 float eventchase_running;
 762 bool WantEventchase(entity this)
 763 {
 764         if(autocvar_cl_orthoview)
 765                 return false;
 766         if(STAT(GAME_STOPPED) || intermission)
 767                 return true;
 768         if(this.viewloc)
 769                 return true;
 770         if(spectatee_status >= 0)
 771         {
 772                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 773                         return true;
 774                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 775                         return true;
 776                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 777                         return true;
 778                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 779                 {
 780                         if(autocvar_cl_eventchase_death == 2)
 781                         {
 782                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 783                                 if(this.velocity == '0 0 0' || eventchase_running)
 784                                         return true;
 785                         }
 786                         else return true;
 787                 }
 788         }
 789         return false;
 790 }
 791
 792 void HUD_Crosshair_Vehicle(entity this)
 793 {
 794         if(hud != HUD_BUMBLEBEE_GUN)
 795         {
 796                 Vehicle info = Vehicles_from(hud);
 797                 info.vr_crosshair(info, this);
 798         }
 799 }
 800
 801 vector damage_blurpostprocess, content_blurpostprocess;
 802
 803 float unaccounted_damage = 0;
 804 void UpdateDamage()
 805 {
 806         // accumulate damage with each stat update
 807         static float damage_total_prev = 0;
 808         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 809         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 810         damage_total_prev = damage_total;
 811
 812         static float damage_dealt_time_prev = 0;
 813         float damage_dealt_time = STAT(HIT_TIME);
 814         if (damage_dealt_time != damage_dealt_time_prev)
 815         {
 816                 unaccounted_damage += unaccounted_damage_new;
 817                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 818         }
 819         damage_dealt_time_prev = damage_dealt_time;
 820
 821         // prevent hitsound when switching spectatee
 822         static float spectatee_status_prev = 0;
 823         if (spectatee_status != spectatee_status_prev)
 824                 unaccounted_damage = 0;
 825         spectatee_status_prev = spectatee_status;
 826 }
 827
 828 void HitSound()
 829 {
 830         // varying sound pitch
 831
 832         bool have_arc = false;
 833         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 834         {
 835                 entity wepent = viewmodels[slot];
 836
 837                 if(wepent.activeweapon == WEP_ARC)
 838                         have_arc = true;
 839         }
 840
 841         static float hitsound_time_prev = 0;
 842         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 843         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 844         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 845         {
 846                 if (autocvar_cl_hitsound && unaccounted_damage)
 847                 {
 848                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 849                         float a = autocvar_cl_hitsound_max_pitch;
 850                         float b = autocvar_cl_hitsound_min_pitch;
 851                         float c = autocvar_cl_hitsound_nom_damage;
 852                         float d = unaccounted_damage;
 853                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 854
 855                         // if sound variation is disabled, set pitch_shift to 1
 856                         if (autocvar_cl_hitsound == 1)
 857                                 pitch_shift = 1;
 858
 859                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 860                         if (autocvar_cl_hitsound == 3)
 861                         {
 862                                 float mirror_value = (a-b)/2 + b;
 863                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 864                         }
 865
 866                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 867
 868                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 869                         // todo: normalize sound pressure levels? seems unnecessary
 870
 871                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 872                 }
 873                 unaccounted_damage = 0;
 874                 hitsound_time_prev = time;
 875         }
 876
 877         static float typehit_time_prev = 0;
 878         float typehit_time = STAT(TYPEHIT_TIME);
 879         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 880         {
 881                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 882                 typehit_time_prev = typehit_time;
 883         }
 884
 885         static float kill_time_prev = 0;
 886         float kill_time = STAT(KILL_TIME);
 887         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 888         {
 889                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 890                 kill_time_prev = kill_time;
 891         }
 892 }
 893
 894 vector crosshair_getcolor(entity this, float health_stat)
 895 {
 896         static float rainbow_last_flicker;
 897         static vector rainbow_prev_color;
 898         vector wcross_color = '0 0 0';
 899         switch(autocvar_crosshair_color_special)
 900         {
 901                 case 1: // crosshair_color_per_weapon
 902                 {
 903                         if(this != WEP_Null && hud == HUD_NORMAL)
 904                         {
 905                                 wcross_color = this.wpcolor;
 906                                 break;
 907                         }
 908                         else { goto normalcolor; }
 909                 }
 910
 911                 case 2: // crosshair_color_by_health
 912                 {
 913                         float hp = health_stat;
 914
 915                         //x = red
 916                         //y = green
 917                         //z = blue
 918
 919                         wcross_color.z = 0;
 920
 921                         if(hp > 200)
 922                         {
 923                                 wcross_color.x = 0;
 924                                 wcross_color.y = 1;
 925                         }
 926                         else if(hp > 150)
 927                         {
 928                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 929                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 930                         }
 931                         else if(hp > 100)
 932                         {
 933                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 934                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 935                                 wcross_color.z = 1 - (hp-100)*0.02;
 936                         }
 937                         else if(hp > 50)
 938                         {
 939                                 wcross_color.x = 1;
 940                                 wcross_color.y = 1;
 941                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 942                         }
 943                         else if(hp > 20)
 944                         {
 945                                 wcross_color.x = 1;
 946                                 wcross_color.y = (hp-20)*90/27/100;
 947                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 948                         }
 949                         else
 950                         {
 951                                 wcross_color.x = 1;
 952                                 wcross_color.y = 0;
 953                         }
 954                         break;
 955                 }
 956
 957                 case 3: // crosshair_color_rainbow
 958                 {
 959                         if(time >= rainbow_last_flicker)
 960                         {
 961                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 962                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 963                         }
 964                         wcross_color = rainbow_prev_color;
 965                         break;
 966                 }
 967 LABEL(normalcolor)
 968                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 969         }
 970
 971         return wcross_color;
 972 }
 973
 974 void HUD_Crosshair(entity this)
 975 {
 976         float f, i, j;
 977         vector v;
 978         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 979                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 980                 !HUD_MinigameMenu_IsOpened() )
 981         {
 982                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 983                         return;
 984
 985                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 986                         return;
 987
 988                 if (hud != HUD_NORMAL)
 989                 {
 990                         HUD_Crosshair_Vehicle(this);
 991                         return;
 992                 }
 993
 994                 string wcross_style;
 995                 float wcross_alpha, wcross_resolution;
 996                 wcross_style = autocvar_crosshair;
 997                 if (wcross_style == "0")
 998                         return;
 999                 wcross_resolution = autocvar_crosshair_size;
1000                 if (wcross_resolution == 0)
1001                         return;
1002                 wcross_alpha = autocvar_crosshair_alpha;
1003                 if (wcross_alpha == 0)
1004                         return;
1005
1006                 // TrueAim check
1007                 float shottype;
1008
1009                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1010                 wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1011                 wcross_origin.z = 0;
1012                 if(autocvar_crosshair_hittest)
1013                 {
1014                         vector wcross_oldorigin;
1015                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1016                         wcross_oldorigin = wcross_origin;
1017                         shottype = TrueAimCheck(thiswep);
1018                         if(shottype == SHOTTYPE_HITWORLD)
1019                         {
1020                                 v = wcross_origin - wcross_oldorigin;
1021                                 v.x /= vid_conwidth;
1022                                 v.y /= vid_conheight;
1023                                 if(vdist(v, >, 0.01))
1024                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1025                         }
1026                         if(!autocvar_crosshair_hittest_showimpact)
1027                                 wcross_origin = wcross_oldorigin;
1028                 }
1029                 else
1030                         shottype = SHOTTYPE_HITWORLD;
1031
1032                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1033                 string wcross_name = "";
1034                 float wcross_scale, wcross_blur;
1035
1036         entity e = WEP_Null;
1037                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1038                 {
1039                         entity wepent = viewmodels[0]; // TODO: unhardcode
1040                         e = wepent.switchingweapon;
1041                         if(e)
1042                         {
1043                                 if(autocvar_crosshair_per_weapon)
1044                                 {
1045                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1046                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1047                                         //if (wcross_resolution == 0)
1048                                                 //return;
1049
1050                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1051                                         wcross_resolution *= e.w_crosshair_size;
1052                                         wcross_name = e.w_crosshair;
1053                                 }
1054                         }
1055                 }
1056
1057                 if(wcross_name == "")
1058                         wcross_name = strcat("gfx/crosshair", wcross_style);
1059
1060                 // MAIN CROSSHAIR COLOR DECISION
1061                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1062
1063                 if(autocvar_crosshair_effect_scalefade)
1064                 {
1065                         wcross_scale = wcross_resolution;
1066                         wcross_resolution = 1;
1067                 }
1068                 else
1069                 {
1070                         wcross_scale = 1;
1071                 }
1072
1073                 if(autocvar_crosshair_pickup)
1074                 {
1075                         float stat_pickup_time = STAT(LAST_PICKUP);
1076
1077                         if(pickup_crosshair_time < stat_pickup_time)
1078                         {
1079                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1080                                         pickup_crosshair_size = 1;
1081
1082                                 pickup_crosshair_time = stat_pickup_time;
1083                         }
1084
1085                         if(pickup_crosshair_size > 0)
1086                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1087                         else
1088                                 pickup_crosshair_size = 0;
1089
1090                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1091                 }
1092
1093                 // todo: make crosshair hit indication dependent on damage dealt
1094                 if(autocvar_crosshair_hitindication)
1095                 {
1096                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1097
1098                         if(unaccounted_damage)
1099                         {
1100                                 hitindication_crosshair_size = 1;
1101                         }
1102
1103                         if(hitindication_crosshair_size > 0)
1104                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1105                         else
1106                                 hitindication_crosshair_size = 0;
1107
1108                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1109                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1110                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1111                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1112                 }
1113
1114                 if(shottype == SHOTTYPE_HITENEMY)
1115                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1116                 if(shottype == SHOTTYPE_HITTEAM)
1117                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1118
1119                 f = fabs(autocvar_crosshair_effect_time);
1120                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1121                 {
1122                         wcross_changedonetime = time + f;
1123                 }
1124                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1125                 {
1126                         wcross_name_changestarttime = time;
1127                         wcross_name_changedonetime = time + f;
1128                         if(wcross_name_goal_prev_prev)
1129                                 strunzone(wcross_name_goal_prev_prev);
1130                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1131                         wcross_name_goal_prev = strzone(wcross_name);
1132                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1133                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1134                         wcross_resolution_goal_prev = wcross_resolution;
1135                 }
1136
1137                 wcross_scale_goal_prev = wcross_scale;
1138                 wcross_alpha_goal_prev = wcross_alpha;
1139                 wcross_color_goal_prev = wcross_color;
1140
1141                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1142                 {
1143                         wcross_blur = 1;
1144                         wcross_alpha *= 0.75;
1145                 }
1146                 else
1147                         wcross_blur = 0;
1148                 // *_prev is at time-frametime
1149                 // * is at wcross_changedonetime+f
1150                 // what do we have at time?
1151                 if(time < wcross_changedonetime)
1152                 {
1153                         f = frametime / (wcross_changedonetime - time + frametime);
1154                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1155                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1156                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1157                 }
1158
1159                 wcross_scale_prev = wcross_scale;
1160                 wcross_alpha_prev = wcross_alpha;
1161                 wcross_color_prev = wcross_color;
1162
1163                 MUTATOR_CALLHOOK(UpdateCrosshair);
1164
1165                 wcross_scale *= 1 - autocvar__menu_alpha;
1166                 wcross_alpha *= 1 - autocvar__menu_alpha;
1167                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1168
1169                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1170                 {
1171                         // crosshair rings for weapon stats
1172                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1173                         {
1174                                 // declarations and stats
1175                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1176                                 string ring_image = string_null, ring_inner_image = string_null;
1177                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1178
1179                                 ring_scale = autocvar_crosshair_ring_size;
1180
1181                                 float weapon_clipload, weapon_clipsize;
1182                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1183                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1184
1185                                 float vortex_charge, vortex_chargepool;
1186                                 vortex_charge = STAT(VORTEX_CHARGE);
1187                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1188
1189                                 float arc_heat = STAT(ARC_HEAT);
1190
1191                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1192                                         vortex_charge_movingavg = vortex_charge;
1193
1194                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1195
1196                                 // handle the values
1197                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1198                                 {
1199                                         if (vortex_chargepool || use_vortex_chargepool) {
1200                                                 use_vortex_chargepool = 1;
1201                                                 ring_inner_value = vortex_chargepool;
1202                                         } else {
1203                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1204                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1205                                         }
1206
1207                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1208                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1209                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1210
1211                                         // draw the outer ring to show the current charge of the weapon
1212                                         ring_value = vortex_charge;
1213                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1214                                         ring_rgb = wcross_color;
1215                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1216                                 }
1217                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1218                                 {
1219                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1220                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1221                                         ring_rgb = wcross_color;
1222                                         ring_image = "gfx/crosshair_ring.tga";
1223                                 }
1224                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1225                                 {
1226                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1227                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1228                                         ring_rgb = wcross_color;
1229                                         ring_image = "gfx/crosshair_ring.tga";
1230                                 }
1231                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1232                                 {
1233                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1234                                         ring_scale = autocvar_crosshair_ring_reload_size;
1235                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1236                                         ring_rgb = wcross_color;
1237
1238                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1239                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1240                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1241                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1242                                         else
1243                                                 ring_image = "gfx/crosshair_ring.tga";
1244                                 }
1245                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1246                                 {
1247                                         ring_value = arc_heat;
1248                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1249                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1250                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1251                                         ring_image = "gfx/crosshair_ring.tga";
1252                                 }
1253
1254                                 // if in weapon switch animation, fade ring out/in
1255                                 if(autocvar_crosshair_effect_time > 0)
1256                                 {
1257                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1258                                         if (f >= 1)
1259                                         {
1260                                                 wcross_ring_prev = ((ring_image) ? true : false);
1261                                         }
1262
1263                                         if(wcross_ring_prev)
1264                                         {
1265                                                 if(f < 1)
1266                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1267                                         }
1268                                         else
1269                                         {
1270                                                 if(f < 1)
1271                                                         ring_alpha *= bound(0, f, 1);
1272                                         }
1273                                 }
1274
1275                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1276                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1277
1278                                 if (ring_value)
1279                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1280                         }
1281
1282 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1283                         MACRO_BEGIN { \
1284                                 if(wcross_blur > 0) \
1285                                 { \
1286                                         for(i = -2; i <= 2; ++i) \
1287                                         for(j = -2; j <= 2; ++j) \
1288                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1289                                 } \
1290                                 else \
1291                                 { \
1292                                         M(0,0,sz,wcross_name,wcross_alpha); \
1293                                 } \
1294                         } MACRO_END
1295
1296 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1297                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1298
1299 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1300                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1301
1302                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1303                         {
1304                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1305                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1306                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1307                                 f = 1 - f;
1308                         }
1309                         else
1310                         {
1311                                 f = 1;
1312                         }
1313                         wcross_name_alpha_goal_prev = f;
1314
1315                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1316                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1317
1318                         if(autocvar_crosshair_dot)
1319                         {
1320                                 vector wcross_color_old;
1321                                 wcross_color_old = wcross_color;
1322
1323                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1324                                         wcross_color = stov(autocvar_crosshair_dot_color);
1325
1326                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1327                                 // FIXME why don't we use wcross_alpha here?
1328                                 wcross_color = wcross_color_old;
1329                         }
1330                 }
1331         }
1332         else
1333         {
1334                 wcross_scale_prev = 0;
1335                 wcross_alpha_prev = 0;
1336                 wcross_scale_goal_prev = 0;
1337                 wcross_alpha_goal_prev = 0;
1338                 wcross_changedonetime = 0;
1339                 if(wcross_name_goal_prev)
1340                         strunzone(wcross_name_goal_prev);
1341                 wcross_name_goal_prev = string_null;
1342                 if(wcross_name_goal_prev_prev)
1343                         strunzone(wcross_name_goal_prev_prev);
1344                 wcross_name_goal_prev_prev = string_null;
1345                 wcross_name_changestarttime = 0;
1346                 wcross_name_changedonetime = 0;
1347                 wcross_name_alpha_goal_prev = 0;
1348                 wcross_name_alpha_goal_prev_prev = 0;
1349                 wcross_resolution_goal_prev = 0;
1350                 wcross_resolution_goal_prev_prev = 0;
1351         }
1352 }
1353
1354 const int MAX_SPECIALCOMMAND = 15;
1355 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1356 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1357 const float SPECIALCOMMAND_SPEED = 150;
1358 const float SPECIALCOMMAND_TURNSPEED = 2;
1359 const float SPECIALCOMMAND_SIZE = 0.025;
1360 const float SPECIALCOMMAND_CHANCE = 0.35;
1361 float sc_spawntime, sc_changetime;
1362 vector sc_color = '1 1 1';
1363 void SpecialCommand()
1364 {
1365         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1366                 return;
1367
1368         if(time >= sc_changetime)
1369         {
1370                 sc_changetime = time + 1;
1371                 sc_color = randomvec() * 1.5;
1372                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1373                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1374                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1375         }
1376         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1377
1378         if(!precache_pic("gfx/smile"))
1379                 return; // damn party poopers
1380
1381         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1382         {
1383                 vector slot = specialcommand_slots[j];
1384                 if(slot.y)
1385                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1386                 if(slot.z)
1387                         slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1388                 if(slot.y >= vid_conheight)
1389                         slot = '0 0 0';
1390
1391                 if(slot == '0 0 0')
1392                 {
1393                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1394                         {
1395                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1396                                 slot.y = 1; // start it off 0 so we can use it
1397                                 slot.z = random();
1398                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1399                                 vector newcolor = randomvec() * 2;
1400                                 newcolor.x = bound(0.4, newcolor.x, 1);
1401                                 newcolor.y = bound(0.4, newcolor.y, 1);
1402                                 newcolor.z = bound(0.4, newcolor.z, 1);
1403                                 specialcommand_colors[j] = newcolor;
1404                         }
1405                 }
1406                 else
1407                 {
1408                         vector splash_size = '0 0 0';
1409                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1410                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1411                         drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1412                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1413                 }
1414
1415                 specialcommand_slots[j] = slot;
1416         }
1417 }
1418
1419 void HUD_Draw(entity this)
1420 {
1421         // if we don't know gametype and scores yet avoid drawing the scoreboard
1422         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1423         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1424         // cl_deathscoreboard would show the scoreboard and so on
1425         if(!gametype)
1426                 return;
1427
1428         Hud_Dynamic_Frame();
1429
1430         if(!intermission)
1431         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1432         {
1433                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1434         }
1435         else if(STAT(FROZEN))
1436         {
1437                 vector col = '0.25 0.90 1';
1438                 if(STAT(REVIVE_PROGRESS))
1439                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1440                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1441         }
1442
1443         HUD_Scale_Enable();
1444         if(!intermission)
1445         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1446         {
1447                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1448                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1449                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1450         }
1451         else if(STAT(CAPTURE_PROGRESS))
1452         {
1453                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1454                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1455         }
1456         else if(STAT(REVIVE_PROGRESS))
1457         {
1458                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1459                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1460         }
1461         HUD_Scale_Disable();
1462
1463         if(autocvar_r_letterbox == 0)
1464                 if(autocvar_viewsize < 120)
1465                 {
1466                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1467                                 Accuracy_LoadLevels();
1468
1469                         HUD_Main();
1470                         HUD_Scale_Disable();
1471                 }
1472
1473         // crosshair goes VERY LAST
1474         SpecialCommand();
1475         UpdateDamage();
1476         HUD_Crosshair(this);
1477         HitSound();
1478 }
1479
1480 bool ov_enabled;
1481 float oldr_nearclip;
1482 float oldr_farclip_base;
1483 float oldr_farclip_world;
1484 float oldr_novis;
1485 float oldr_useportalculling;
1486 float oldr_useinfinitefarclip;
1487
1488 void cl_notice_run();
1489
1490 float prev_myteam;
1491 int lasthud;
1492 float vh_notice_time;
1493 void WaypointSprite_Load();
1494 void CSQC_UpdateView(entity this, float w, float h)
1495 {
1496     TC(int, w); TC(int, h);
1497         entity e;
1498         float fov;
1499         float f;
1500         vector vf_size, vf_min;
1501         float a;
1502
1503         execute_next_frame();
1504
1505         ++framecount;
1506
1507         stats_get();
1508         hud = STAT(HUD);
1509
1510         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1511                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1512
1513         lasthud = hud;
1514
1515         HUD_Scale_Disable();
1516
1517         if(autocvar__hud_showbinds_reload) // menu can set this one
1518         {
1519                 db_close(binddb);
1520                 binddb = db_create();
1521                 cvar_set("_hud_showbinds_reload", "0");
1522         }
1523
1524         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1525                 view_quality = getproperty(VF_MINFPS_QUALITY);
1526         else
1527                 view_quality = 1;
1528
1529         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1530         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1531
1532         vf_size = getpropertyvec(VF_SIZE);
1533         vf_min = getpropertyvec(VF_MIN);
1534         vid_width = vf_size.x;
1535         vid_height = vf_size.y;
1536
1537         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1538         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1539
1540         WaypointSprite_Load();
1541
1542         CSQCPlayer_SetCamera();
1543
1544         if(player_localentnum <= maxclients) // is it a client?
1545                 current_player = player_localentnum - 1;
1546         else // then player_localentnum is the vehicle I'm driving
1547                 current_player = player_localnum;
1548         myteam = entcs_GetTeam(current_player);
1549
1550         if(myteam != prev_myteam)
1551         {
1552                 myteamcolors = colormapPaletteColor(myteam, 1);
1553                 FOREACH(hud_panels, true, it.update_time = time);
1554                 prev_myteam = myteam;
1555         }
1556
1557         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1558
1559         float is_dead = (STAT(HEALTH) <= 0);
1560
1561         // FIXME do we need this hack?
1562         if(isdemo())
1563         {
1564                 // in demos, input_buttons do not work
1565                 button_zoom = (autocvar__togglezoom == "-");
1566         }
1567         else if(button_zoom
1568                 && autocvar_cl_unpress_zoom_on_death
1569                 && (spectatee_status >= 0)
1570                 && (is_dead || intermission))
1571         {
1572                 // no zoom while dead or in intermission please
1573                 localcmd("-zoom\n");
1574                 button_zoom = false;
1575         }
1576
1577         // event chase camera
1578         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1579         {
1580                 if(STAT(CAMERA_SPECTATOR))
1581                 {
1582                         if(spectatee_status > 0)
1583                         {
1584                                 if(!autocvar_chase_active)
1585                                 {
1586                                         cvar_set("chase_active", "-2");
1587                                         goto skip_eventchase_death;
1588                                 }
1589                         }
1590                         else if(autocvar_chase_active == -2)
1591                                 cvar_set("chase_active", "0");
1592
1593                         if(autocvar_chase_active == -2)
1594                                 goto skip_eventchase_death;
1595                 }
1596                 else if(autocvar_chase_active == -2)
1597                         cvar_set("chase_active", "0");
1598
1599                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1600
1601                 float vehicle_viewdist = 0;
1602                 vector vehicle_viewofs = '0 0 0';
1603
1604                 if(vehicle_chase)
1605                 {
1606                         if(hud != HUD_BUMBLEBEE_GUN)
1607                         {
1608                                 Vehicle info = Vehicles_from(hud);
1609                                 vehicle_viewdist = info.height;
1610                                 vehicle_viewofs = info.view_ofs;
1611                         }
1612                 }
1613
1614                 if(WantEventchase(this))
1615                 {
1616                         vector current_view_origin_override = '0 0 0';
1617                         vector view_offset_override = '0 0 0';
1618                         float chase_distance_override = 0;
1619                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1620                         if(custom_eventchase)
1621                         {
1622                                 current_view_origin_override = M_ARGV(0, vector);
1623                                 view_offset_override = M_ARGV(1, vector);
1624                                 chase_distance_override = M_ARGV(0, float);
1625                         }
1626                         eventchase_running = true;
1627
1628                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1629                         if(!local_player)
1630                                 local_player = this; // fall back!
1631
1632                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1633                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1634                         if (custom_eventchase)
1635                                 current_view_origin = current_view_origin_override;
1636
1637                         // detect maximum viewoffset and use it
1638                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1639                         if(vehicle_chase)
1640                         {
1641                                 if(vehicle_viewofs)
1642                                         view_offset = vehicle_viewofs;
1643                                 else
1644                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1645                         }
1646                         if (custom_eventchase)
1647                                 view_offset = view_offset_override;
1648
1649                         if(view_offset)
1650                         {
1651                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1652                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1653                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1654                         }
1655
1656                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1657                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1658                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1659                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1660
1661                         // make the camera smooth back
1662                         float chase_distance = autocvar_cl_eventchase_distance;
1663                         if(vehicle_chase)
1664                         {
1665                                 if(vehicle_viewofs)
1666                                         chase_distance = vehicle_viewdist;
1667                                 else
1668                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1669                         }
1670                         if (custom_eventchase)
1671                                 chase_distance = chase_distance_override;
1672
1673                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1674                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1675                         else if(eventchase_current_distance != chase_distance)
1676                                 eventchase_current_distance = chase_distance;
1677
1678                         makevectors(view_angles);
1679
1680                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1681                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1682
1683                         // If the boxtrace fails, revert back to line tracing.
1684                         if(!local_player.viewloc)
1685                         if(trace_startsolid)
1686                         {
1687                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1688                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1689                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1690                         }
1691                         else { setproperty(VF_ORIGIN, trace_endpos); }
1692
1693                         if(!local_player.viewloc)
1694                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1695                 }
1696                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1697                 {
1698                         eventchase_running = false;
1699                         cvar_set("chase_active", "0");
1700                         eventchase_current_distance = 0; // start from 0 next time
1701                 }
1702         }
1703         // workaround for camera stuck between player's legs when using chase_active 1
1704         // because the engine stops updating the chase_active camera when the game ends
1705         else if(intermission)
1706         {
1707                 cvar_settemp("chase_active", "-1");
1708                 eventchase_current_distance = 0;
1709         }
1710
1711         LABEL(skip_eventchase_death);
1712
1713         // do lockview after event chase camera so that it still applies whenever necessary.
1714         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1715         {
1716                 setproperty(VF_ORIGIN, freeze_org);
1717                 setproperty(VF_ANGLES, freeze_ang);
1718         }
1719         else
1720         {
1721                 freeze_org = getpropertyvec(VF_ORIGIN);
1722                 freeze_ang = getpropertyvec(VF_ANGLES);
1723         }
1724
1725         WarpZone_FixView();
1726         //WarpZone_FixPMove();
1727
1728         vector ov_org = '0 0 0';
1729         vector ov_mid = '0 0 0';
1730         vector ov_worldmin = '0 0 0';
1731         vector ov_worldmax = '0 0 0';
1732         if(autocvar_cl_orthoview)
1733         {
1734                 ov_worldmin = mi_picmin;
1735                 ov_worldmax = mi_picmax;
1736
1737                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1738                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1739                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1740
1741                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1742                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1743
1744                 float ov_nearest = vlen(ov_org - vec3(
1745                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1746                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1747                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1748                 ));
1749
1750                 float ov_furthest = 0;
1751                 float dist = 0;
1752
1753                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1754                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1755                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1756                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1757                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1758                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1759                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1760                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1761
1762                 if(!ov_enabled)
1763                 {
1764                         oldr_nearclip = cvar("r_nearclip");
1765                         oldr_farclip_base = cvar("r_farclip_base");
1766                         oldr_farclip_world = cvar("r_farclip_world");
1767                         oldr_novis = cvar("r_novis");
1768                         oldr_useportalculling = cvar("r_useportalculling");
1769                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1770                 }
1771
1772                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1773                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1774                 cvar_settemp("r_farclip_world", "0");
1775                 cvar_settemp("r_novis", "1");
1776                 cvar_settemp("r_useportalculling", "0");
1777                 cvar_settemp("r_useinfinitefarclip", "0");
1778
1779                 setproperty(VF_ORIGIN, ov_org);
1780                 setproperty(VF_ANGLES, '90 0 0');
1781
1782                 ov_enabled = true;
1783
1784                 #if 0
1785                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1786                         vtos(ov_org),
1787                         vtos(getpropertyvec(VF_ANGLES)),
1788                         ov_distance,
1789                         ov_nearest,
1790                         ov_furthest);
1791                 #endif
1792         }
1793         else
1794         {
1795                 if(ov_enabled)
1796                 {
1797                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1798                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1799                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1800                         cvar_set("r_novis", ftos(oldr_novis));
1801                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1802                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1803                 }
1804                 ov_enabled = false;
1805         }
1806
1807         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1808         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1809         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1810                 viewmodel_draw(viewmodels[slot]);
1811
1812         // Render the Scene
1813         view_origin = getpropertyvec(VF_ORIGIN);
1814         view_angles = getpropertyvec(VF_ANGLES);
1815         makevectors(view_angles);
1816         view_forward = v_forward;
1817         view_right = v_right;
1818         view_up = v_up;
1819
1820 #ifdef BLURTEST
1821         if(time > blurtest_time0 && time < blurtest_time1)
1822         {
1823                 float r, t;
1824
1825                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1826                 r = t * blurtest_radius;
1827                 f = 1 / (t ** blurtest_power) - 1;
1828
1829                 cvar_set("r_glsl_postprocess", "1");
1830                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1831         }
1832         else
1833         {
1834                 cvar_set("r_glsl_postprocess", "0");
1835                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1836         }
1837 #endif
1838
1839         TargetMusic_Advance();
1840         Fog_Force();
1841
1842         if(drawtime == 0)
1843                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1844         else
1845                 drawframetime = bound(0.000001, time - drawtime, 1);
1846         drawtime = time;
1847
1848         // watch for gametype changes here...
1849         // in ParseStuffCMD the cmd isn't executed yet :/
1850         // might even be better to add the gametype to TE_CSQC_INIT...?
1851         if(!postinit)
1852                 PostInit();
1853
1854         if(intermission && !intermission_time)
1855                 intermission_time = time;
1856
1857         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1858         {
1859                 if(calledhooks & HOOK_START)
1860                 {
1861                         localcmd("\ncl_hook_gameend\n");
1862                         calledhooks |= HOOK_END;
1863                 }
1864         }
1865
1866         Announcer();
1867
1868         fov = autocvar_fov;
1869         if(fov <= 59.5)
1870         {
1871                 if(!zoomscript_caught)
1872                 {
1873                         localcmd("+button9\n");
1874                         zoomscript_caught = 1;
1875                 }
1876         }
1877         else
1878         {
1879                 if(zoomscript_caught)
1880                 {
1881                         localcmd("-button9\n");
1882                         zoomscript_caught = 0;
1883                 }
1884         }
1885
1886         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1887
1888         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1889         {
1890                 entity wepent = viewmodels[slot];
1891
1892                 if(wepent.last_switchweapon != wepent.switchweapon)
1893                 {
1894                         weapontime = time;
1895                         wepent.last_switchweapon = wepent.switchweapon;
1896                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1897                         {
1898                                 localcmd("-zoom\n");
1899                                 button_zoom = false;
1900                         }
1901                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1902                         {
1903                                 localcmd("-fire\n");
1904                                 localcmd("-fire2\n");
1905                                 button_attack2 = false;
1906                         }
1907                 }
1908                 if(wepent.last_activeweapon != wepent.activeweapon)
1909                 {
1910                         wepent.last_activeweapon = wepent.activeweapon;
1911
1912                         e = wepent.activeweapon;
1913                         if(e.netname != "")
1914                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1915                         else if(slot == 0)
1916                                 localcmd("\ncl_hook_activeweapon none\n");
1917                 }
1918         }
1919
1920         // ALWAYS Clear Current Scene First
1921         clearscene();
1922
1923         setproperty(VF_ORIGIN, view_origin);
1924         setproperty(VF_ANGLES, view_angles);
1925
1926         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1927         setproperty(VF_SIZE, vf_size);
1928         setproperty(VF_MIN, vf_min);
1929
1930         // Assign Standard Viewflags
1931         // Draw the World (and sky)
1932         setproperty(VF_DRAWWORLD, 1);
1933
1934         // Set the console size vars
1935         vid_conwidth = autocvar_vid_conwidth;
1936         vid_conheight = autocvar_vid_conheight;
1937         vid_pixelheight = autocvar_vid_pixelheight;
1938
1939         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1940         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1941         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1942
1943         if(camera_active) // Camera for demo playback
1944         {
1945                 if(autocvar_camera_enable)
1946                         CSQC_Demo_Camera();
1947                 else
1948                 {
1949                         cvar_set("chase_active", ftos(chase_active_backup));
1950                         cvar_set("cl_demo_mousegrab", "0");
1951                         camera_active = false;
1952                 }
1953         }
1954         else
1955         {
1956 #ifdef CAMERATEST
1957                 if(autocvar_camera_enable)
1958 #else
1959                 if(autocvar_camera_enable && isdemo())
1960 #endif
1961                 {
1962                         // Enable required Darkplaces cvars
1963                         chase_active_backup = autocvar_chase_active;
1964                         cvar_set("chase_active", "2");
1965                         cvar_set("cl_demo_mousegrab", "1");
1966                         camera_active = true;
1967                         camera_mode = false;
1968                 }
1969         }
1970
1971         // Draw the Crosshair
1972         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1973
1974         // Draw the Engine Status Bar (the default Quake HUD)
1975         setproperty(VF_DRAWENGINESBAR, 0);
1976
1977         // Update the mouse position
1978         /*
1979            mousepos_x = vid_conwidth;
1980            mousepos_y = vid_conheight;
1981            mousepos = mousepos*0.5 + getmousepos();
1982          */
1983
1984         IL_EACH(g_drawables, it.draw, it.draw(it));
1985
1986         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1987         renderscene();
1988
1989         // now switch to 2D drawing mode by calling a 2D drawing function
1990         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1991         // next R_RenderScene call
1992         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1993
1994         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1995         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1996         {
1997                 // apply night vision effect
1998                 vector tc_00, tc_01, tc_10, tc_11;
1999                 vector rgb = '0 0 0';
2000
2001                 if(!nightvision_noise)
2002                 {
2003                         nightvision_noise = new(nightvision_noise);
2004                 }
2005                 if(!nightvision_noise2)
2006                 {
2007                         nightvision_noise2 = new(nightvision_noise2);
2008                 }
2009
2010                 // color tint in yellow
2011                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2012
2013                 // draw BG
2014                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2015                 rgb = '1 1 1';
2016                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2017                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2018                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2019                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2020                 tc_11 = tc_01 + tc_10 - tc_00;
2021                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2022                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2023                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2024                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2025                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2026                 R_EndPolygon();
2027
2028                 // draw FG
2029                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2030                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2031                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2032                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2033                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2034                 tc_11 = tc_01 + tc_10 - tc_00;
2035                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2036                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2037                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2038                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2039                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2040                 R_EndPolygon();
2041         }
2042
2043         if(autocvar_cl_reticle)
2044         {
2045                 string reticle_image = string_null;
2046                 bool wep_zoomed = false;
2047                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2048                 {
2049                         entity wepe = viewmodels[slot];
2050                         Weapon wep = wepe.activeweapon;
2051                         if(wep != WEP_Null && wep.wr_zoom)
2052                         {
2053                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2054                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2055                                         reticle_image = wep.w_reticle;
2056                                 wep_zoomed += do_zoom;
2057                         }
2058                 }
2059                 // Draw the aiming reticle for weapons that use it
2060                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2061                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2062                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2063                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
2064                 {
2065                         // no zoom reticle while dead
2066                         reticle_type = 0;
2067                 }
2068                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2069                 {
2070                         if(reticle_image) { reticle_type = 2; }
2071                         else { reticle_type = 0; }
2072                 }
2073                 else if(button_zoom || zoomscript_caught)
2074                 {
2075                         // normal zoom
2076                         reticle_type = 1;
2077                 }
2078
2079                 if(reticle_type)
2080                 {
2081                         if(autocvar_cl_reticle_stretch)
2082                         {
2083                                 reticle_size.x = vid_conwidth;
2084                                 reticle_size.y = vid_conheight;
2085                                 reticle_pos.x = 0;
2086                                 reticle_pos.y = 0;
2087                         }
2088                         else
2089                         {
2090                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2091                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2092                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2093                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2094                         }
2095
2096                         if(zoomscript_caught)
2097                                 f = 1;
2098                         else
2099                                 f = current_zoomfraction;
2100
2101                         if(f)
2102                         {
2103                                 switch(reticle_type)
2104                                 {
2105                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2106                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2107                                 }
2108                         }
2109                 }
2110         }
2111         else
2112         {
2113                 if(reticle_type != 0) { reticle_type = 0; }
2114         }
2115
2116
2117         // improved polyblend
2118         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2119         {
2120                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2121                 vector liquidcolor;
2122
2123                 switch(pointcontents(view_origin))
2124                 {
2125                         case CONTENT_WATER:
2126                                 liquidalpha = autocvar_hud_contents_water_alpha;
2127                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2128                                 incontent = 1;
2129                                 break;
2130
2131                         case CONTENT_LAVA:
2132                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2133                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2134                                 incontent = 1;
2135                                 break;
2136
2137                         case CONTENT_SLIME:
2138                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2139                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2140                                 incontent = 1;
2141                                 break;
2142
2143                         default:
2144                                 liquidalpha = 0;
2145                                 liquidcolor = '0 0 0';
2146                                 incontent = 0;
2147                                 break;
2148                 }
2149
2150                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2151                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2152                         contentfadetime = autocvar_hud_contents_fadeintime;
2153                         liquidalpha_prev = liquidalpha;
2154                         liquidcolor_prev = liquidcolor;
2155                 }
2156                 else
2157                         contentfadetime = autocvar_hud_contents_fadeouttime;
2158
2159                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2160                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2161
2162                 if(contentavgalpha)
2163                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2164
2165                 if(autocvar_hud_postprocessing)
2166                 {
2167                         if(autocvar_hud_contents_blur && contentavgalpha)
2168                         {
2169                                 content_blurpostprocess.x = 1;
2170                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2171                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2172                         }
2173                         else
2174                         {
2175                                 content_blurpostprocess.x = 0;
2176                                 content_blurpostprocess.y = 0;
2177                                 content_blurpostprocess.z = 0;
2178                         }
2179                 }
2180         }
2181
2182         if(autocvar_hud_damage && !STAT(FROZEN))
2183         {
2184                 splash_size.x = max(vid_conwidth, vid_conheight);
2185                 splash_size.y = max(vid_conwidth, vid_conheight);
2186                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2187                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2188
2189                 float myhealth_flash_temp;
2190                 myhealth = STAT(HEALTH);
2191
2192                 // fade out
2193                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2194                 // add new damage
2195                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2196
2197                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2198                 pain_threshold = autocvar_hud_damage_pain_threshold;
2199                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2200                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2201
2202                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2203                 {
2204                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2205                 }
2206
2207                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2208
2209                 if(myhealth_prev < 1)
2210                 {
2211                         if(myhealth >= 1)
2212                         {
2213                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2214                                 myhealth_flash_temp = 0;
2215                         }
2216                         else
2217                         {
2218                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2219                         }
2220                 }
2221
2222                 if(spectatee_status == -1 || intermission)
2223                 {
2224                         myhealth_flash = 0; // observing, or match ended
2225                         myhealth_flash_temp = 0;
2226                 }
2227
2228                 myhealth_prev = myhealth;
2229
2230                 // IDEA: change damage color/picture based on player model for robot/alien species?
2231                 // pro: matches model better
2232                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2233                 // maybe different reddish pics?
2234                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2235                 {
2236                         if(autocvar_cl_gentle_damage == 2)
2237                         {
2238                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2239                                         myhealth_gentlergb = randomvec();
2240                         }
2241                         else
2242                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2243
2244                         if(myhealth_flash_temp > 0)
2245                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2246                 }
2247                 else if(myhealth_flash_temp > 0)
2248                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2249
2250                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2251                 {
2252                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2253                         {
2254                                 damage_blurpostprocess.x = 1;
2255                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2256                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2257                         }
2258                         else
2259                         {
2260                                 damage_blurpostprocess.x = 0;
2261                                 damage_blurpostprocess.y = 0;
2262                                 damage_blurpostprocess.z = 0;
2263                         }
2264                 }
2265         }
2266
2267         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2268         float e2 = (autocvar_hud_powerup != 0);
2269         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2270         {
2271                 // enable or disable rendering types if they are used or not
2272                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2273                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2274
2275                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2276                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2277                 {
2278                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2279                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2280                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2281                         {
2282                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2283                                 old_blurradius = blurradius;
2284                                 old_bluralpha = bluralpha;
2285                         }
2286                 }
2287                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2288                 {
2289                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2290                         old_blurradius = 0;
2291                         old_bluralpha = 0;
2292                 }
2293
2294                 // edge detection postprocess handling done second (used by hud_powerup)
2295                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2296                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2297                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2298
2299                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2300
2301                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2302                 {
2303                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2304                         {
2305                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2306                                 old_sharpen_intensity = sharpen_intensity;
2307                         }
2308                 }
2309                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2310                 {
2311                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2312                         old_sharpen_intensity = 0;
2313                 }
2314
2315                 if(cvar("r_glsl_postprocess") == 0)
2316                         cvar_set("r_glsl_postprocess", "2");
2317         }
2318         else if(cvar("r_glsl_postprocess") == 2)
2319                 cvar_set("r_glsl_postprocess", "0");
2320
2321         /*if(gametype == MAPINFO_TYPE_CTF)
2322           {
2323           ctf_view();
2324           } else */
2325
2326         // draw 2D entities
2327         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2328         Draw_ShowNames_All();
2329 #if ENABLE_DEBUGDRAW
2330         Debug_Draw();
2331 #endif
2332
2333         scoreboard_active = Scoreboard_WouldDraw();
2334
2335         HUD_Draw(this); // this parameter for deep vehicle function
2336
2337         if(NextFrameCommand)
2338         {
2339                 localcmd("\n", NextFrameCommand, "\n");
2340                 NextFrameCommand = string_null;
2341         }
2342
2343         // we must do this check AFTER a frame was rendered, or it won't work
2344         if(cs_project_is_b0rked == 0)
2345         {
2346                 string w0, h0;
2347                 w0 = ftos(autocvar_vid_conwidth);
2348                 h0 = ftos(autocvar_vid_conheight);
2349                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2350                 //setproperty(VF_FOV, '90 90 0');
2351                 setproperty(VF_ORIGIN, '0 0 0');
2352                 setproperty(VF_ANGLES, '0 0 0');
2353                 setproperty(VF_PERSPECTIVE, 1);
2354                 makevectors('0 0 0');
2355                 vector v1, v2;
2356                 cvar_set("vid_conwidth", "800");
2357                 cvar_set("vid_conheight", "600");
2358                 v1 = cs_project(v_forward);
2359                 cvar_set("vid_conwidth", "640");
2360                 cvar_set("vid_conheight", "480");
2361                 v2 = cs_project(v_forward);
2362                 if(v1 == v2)
2363                         cs_project_is_b0rked = 1;
2364                 else
2365                         cs_project_is_b0rked = -1;
2366                 cvar_set("vid_conwidth", w0);
2367                 cvar_set("vid_conheight", h0);
2368         }
2369
2370         if(autocvar__hud_configure)
2371                 HUD_Panel_Mouse();
2372         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2373                 HUD_Minigame_Mouse();
2374         else if(QuickMenu_IsOpened())
2375                 QuickMenu_Mouse();
2376         else
2377                 HUD_Radar_Mouse();
2378
2379         cl_notice_run();
2380         unpause_update();
2381         Net_Flush();
2382
2383         // let's reset the view back to normal for the end
2384         setproperty(VF_MIN, '0 0 0');
2385         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2386
2387         IL_ENDFRAME();
2388 }
2389
2390
2391 // following vectors must be global to allow seamless switching between camera modes
2392 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2393 void CSQC_Demo_Camera()
2394 {
2395         float speed, attenuation, dimensions;
2396         vector tmp, delta;
2397
2398         if( autocvar_camera_reset || !camera_mode )
2399         {
2400                 camera_offset = '0 0 0';
2401                 current_angles = '0 0 0';
2402                 camera_direction = '0 0 0';
2403                 camera_offset.z += 30;
2404                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2405                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2406                 current_origin = view_origin;
2407                 current_camera_offset  = camera_offset;
2408                 cvar_set("camera_reset", "0");
2409                 camera_mode = CAMERA_CHASE;
2410         }
2411
2412         // Camera angles
2413         if( camera_roll )
2414                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2415
2416         if(autocvar_camera_look_player)
2417         {
2418                 vector dir;
2419                 float n;
2420
2421                 dir = normalize(view_origin - current_position);
2422                 n = mouse_angles.z;
2423                 mouse_angles = vectoangles(dir);
2424                 mouse_angles.x = mouse_angles.x * -1;
2425                 mouse_angles.z = n;
2426         }
2427         else
2428         {
2429                 tmp = getmousepos() * 0.1;
2430                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2431                 {
2432                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2433                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2434                 }
2435         }
2436
2437         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2438         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2439         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2440         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2441
2442         // Fix difference when angles don't have the same sign
2443         delta = '0 0 0';
2444         if(mouse_angles.y < -60 && current_angles.y > 60)
2445                 delta = '0 360 0';
2446         if(mouse_angles.y > 60 && current_angles.y < -60)
2447                 delta = '0 -360 0';
2448
2449         if(autocvar_camera_look_player)
2450                 attenuation = autocvar_camera_look_attenuation;
2451         else
2452                 attenuation = autocvar_camera_speed_attenuation;
2453
2454         attenuation = 1 / max(1, attenuation);
2455         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2456
2457         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2458         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2459         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2460         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2461
2462         // Camera position
2463         tmp = '0 0 0';
2464         dimensions = 0;
2465
2466         if( camera_direction.x )
2467         {
2468                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2469                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2470                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2471                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2472                 ++dimensions;
2473         }
2474
2475         if( camera_direction.y )
2476         {
2477                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2478                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2479                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2480                 ++dimensions;
2481         }
2482
2483         if( camera_direction.z )
2484         {
2485                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2486                 ++dimensions;
2487         }
2488
2489         if(autocvar_camera_free)
2490                 speed = autocvar_camera_speed_free;
2491         else
2492                 speed = autocvar_camera_speed_chase;
2493
2494         if(dimensions)
2495         {
2496                 speed = speed * sqrt(1 / dimensions);
2497                 camera_offset += tmp * speed;
2498         }
2499
2500         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2501
2502         // Camera modes
2503         if( autocvar_camera_free )
2504         {
2505                 if ( camera_mode == CAMERA_CHASE )
2506                 {
2507                         current_camera_offset = current_origin + current_camera_offset;
2508                         camera_offset = current_origin + camera_offset;
2509                 }
2510
2511                 camera_mode = CAMERA_FREE;
2512                 current_position = current_camera_offset;
2513         }
2514         else
2515         {
2516                 if ( camera_mode == CAMERA_FREE )
2517                 {
2518                         current_origin = view_origin;
2519                         camera_offset = camera_offset - current_origin;
2520                         current_camera_offset = current_camera_offset - current_origin;
2521                 }
2522
2523                 camera_mode = CAMERA_CHASE;
2524
2525                 if(autocvar_camera_chase_smoothly)
2526                         current_origin += (view_origin - current_origin) * attenuation;
2527                 else
2528                         current_origin = view_origin;
2529
2530                 current_position = current_origin + current_camera_offset;
2531         }
2532
2533         setproperty(VF_ANGLES, current_angles);
2534         setproperty(VF_ORIGIN, current_position);
2535 }