qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/net_linked.qh>
  17 #include <common/debug.qh>
  18 #include <common/mapinfo.qh>
  19 #include <common/gamemodes/_mod.qh>
  20 #include <common/physics/player.qh>
  21 #include <common/stats.qh>
  22 #include <common/triggers/target/music.qh>
  23 #include <common/teams.qh>
  24
  25 #include <common/weapons/weapon/tuba.qh>
  26
  27 #include <common/vehicles/all.qh>
  28 #include <common/weapons/_all.qh>
  29 #include <common/viewloc.qh>
  30 #include <common/minigames/cl_minigames.qh>
  31 #include <common/minigames/cl_minigames_hud.qh>
  32
  33 #include <lib/csqcmodel/cl_player.qh>
  34 #include <lib/csqcmodel/cl_model.qh>
  35 #include "csqcmodel_hooks.qh"
  36
  37 #include <lib/warpzone/client.qh>
  38 #include <lib/warpzone/common.qh>
  39
  40 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  41
  42 float autocvar_cl_viewmodel_scale;
  43
  44 bool autocvar_cl_bobmodel;
  45 float autocvar_cl_bobmodel_speed;
  46 float autocvar_cl_bobmodel_side;
  47 float autocvar_cl_bobmodel_up;
  48
  49 float autocvar_cl_followmodel;
  50 float autocvar_cl_followmodel_speed = 0.3;
  51 float autocvar_cl_followmodel_limit = 135;
  52 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  53 float autocvar_cl_followmodel_highpass = 0.05;
  54 float autocvar_cl_followmodel_lowpass = 0.03;
  55 bool autocvar_cl_followmodel_velocity_absolute;
  56
  57 float autocvar_cl_leanmodel;
  58 float autocvar_cl_leanmodel_speed = 0.3;
  59 float autocvar_cl_leanmodel_limit = 30;
  60 float autocvar_cl_leanmodel_highpass1 = 0.2;
  61 float autocvar_cl_leanmodel_highpass = 0.2;
  62 float autocvar_cl_leanmodel_lowpass = 0.05;
  63
  64 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  65
  66 #define lowpass(value, frac, ref_store, ret) \
  67         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  68
  69 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  70 { \
  71         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  72         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  73 } MACRO_END
  74
  75 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  76 { \
  77         float __f = 0; lowpass(value, frac, ref_store, __f); \
  78         ret = (value) - __f; \
  79 } MACRO_END
  80
  81 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  82 { \
  83         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  84         ret = (value) - __f; \
  85 } MACRO_END
  86
  87 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  88 { \
  89         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  90         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  91 } MACRO_END
  92
  93 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94 { \
  95         highpass(value.x, frac, ref_store.x, ref_out.x); \
  96         highpass(value.y, frac, ref_store.y, ref_out.y); \
  97 } MACRO_END
  98
  99 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 100 { \
 101         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 102         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 103 } MACRO_END
 104
 105 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 106 { \
 107         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 108         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 109         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 110 } MACRO_END
 111
 112 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 113 { \
 114         highpass(value.x, frac, ref_store.x, ref_out.x); \
 115         highpass(value.y, frac, ref_store.y, ref_out.y); \
 116         highpass(value.z, frac, ref_store.z, ref_out.z); \
 117 } MACRO_END
 118
 119 void calc_followmodel_ofs(entity view)
 120 {
 121         if(cl_followmodel_time == time)
 122                 return; // cl_followmodel_ofs already calculated for this frame
 123
 124         float frac;
 125         vector gunorg = '0 0 0';
 126         static vector vel_average;
 127         static vector gunorg_adjustment_highpass;
 128         static vector gunorg_adjustment_lowpass;
 129
 130         vector vel;
 131         if (autocvar_cl_followmodel_velocity_absolute)
 132                 vel = view.velocity;
 133         else
 134         {
 135                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 136                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 137                 vel.x = view.velocity * forward;
 138                 vel.y = view.velocity * right * -1;
 139                 vel.z = view.velocity * up;
 140         }
 141
 142         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 143         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 144         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 145
 146         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 147         lowpass3(vel, frac, vel_average, gunorg);
 148
 149         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 150
 151         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 152         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 153         frac = avg_factor(autocvar_cl_followmodel_highpass);
 154         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 155         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 156         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 157
 158         if (autocvar_cl_followmodel_velocity_absolute)
 159         {
 160                 vector fixed_gunorg;
 161                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 162                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 163                 fixed_gunorg.x = gunorg * forward;
 164                 fixed_gunorg.y = gunorg * right * -1;
 165                 fixed_gunorg.z = gunorg * up;
 166                 gunorg = fixed_gunorg;
 167         }
 168
 169         cl_followmodel_ofs = gunorg;
 170         cl_followmodel_time = time;
 171 }
 172
 173 vector leanmodel_ofs(entity view)
 174 {
 175         float frac;
 176         vector gunangles = '0 0 0';
 177         static vector gunangles_prev = '0 0 0';
 178         static vector gunangles_highpass = '0 0 0';
 179         static vector gunangles_adjustment_highpass;
 180         static vector gunangles_adjustment_lowpass;
 181
 182         if (view.csqcmodel_teleported)
 183                 gunangles_prev = view_angles;
 184
 185         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 186         gunangles_highpass += gunangles_prev;
 187         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 188         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 189         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 190         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 191         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 192         gunangles_prev = view_angles;
 193         gunangles_highpass -= gunangles_prev;
 194
 195         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 196         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 197
 198         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 199         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 200         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 201         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 202         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 203
 204         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 205
 206         return gunangles;
 207 }
 208
 209 vector bobmodel_ofs(entity view)
 210 {
 211         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 212         static bool oldonground;
 213         static float hitgroundtime;
 214         if (clonground)
 215         {
 216                 float f = time; // cl.movecmd[0].time
 217                 if (!oldonground)
 218                         hitgroundtime = f;
 219         }
 220         oldonground = clonground;
 221
 222         // calculate for swinging gun model
 223         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 224         vector gunorg = '0 0 0';
 225         static float bobmodel_scale = 0;
 226         static float time_ofs = 0; // makes the effect always restart in the same way
 227         if (clonground)
 228         {
 229                 if (time - hitgroundtime > 0.05)
 230                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 231         }
 232         else
 233                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 234
 235         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 236         if (bobmodel_scale && xyspeed)
 237         {
 238                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 239                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 240                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 241                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 242         }
 243         else
 244                 time_ofs = time;
 245
 246         return gunorg;
 247 }
 248
 249 void viewmodel_animate(entity this)
 250 {
 251         if (autocvar_chase_active) return;
 252         if (STAT(HEALTH) <= 0) return;
 253
 254         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 255
 256         if (autocvar_cl_followmodel)
 257         {
 258                 calc_followmodel_ofs(view);
 259                 this.origin += cl_followmodel_ofs;
 260         }
 261
 262         if (autocvar_cl_leanmodel)
 263                 this.angles += leanmodel_ofs(view);
 264
 265         // vertical view bobbing code
 266         // TODO: cl_bob
 267
 268         // horizontal view bobbing code
 269         // TODO: cl_bob2
 270
 271         // fall bobbing code
 272         // causes the view to swing down and back up when touching the ground
 273         // TODO: cl_bobfall
 274
 275         // gun model bobbing code
 276         if (autocvar_cl_bobmodel)
 277                 this.origin += bobmodel_ofs(view);
 278 }
 279
 280 .vector viewmodel_origin, viewmodel_angles;
 281 .float weapon_nextthink;
 282 .float weapon_eta_last;
 283 .float weapon_switchdelay;
 284
 285 .string name_last;
 286
 287 void viewmodel_draw(entity this)
 288 {
 289         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 290                 return;
 291         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 292         float a = this.alpha;
 293         static bool wasinvehicle;
 294         bool invehicle = player_localentnum > maxclients;
 295         if (invehicle) a = -1;
 296         else if (wasinvehicle) a = 1;
 297         wasinvehicle = invehicle;
 298         Weapon wep = this.activeweapon;
 299         int c = entcs_GetClientColors(current_player);
 300         vector g = weaponentity_glowmod(wep, NULL, c, this);
 301         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 302         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 303                 | EF_NODEPTHTEST)
 304                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 305         for (entity e = this; e; e = e.weaponchild)
 306         {
 307                 e.drawmask = mask;
 308                 e.alpha = a;
 309                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 310                 e.glowmod = g;
 311                 e.csqcmodel_effects = fx;
 312                 CSQCModel_Effects_Apply(e);
 313         }
 314         if(a >= 0)
 315         {
 316                 string name = wep.mdl;
 317                 string newname = wep.wr_viewmodel(wep, this);
 318                 if(newname)
 319                         name = newname;
 320                 bool swap = name != this.name_last;
 321                 // if (swap)
 322                 {
 323                         this.name_last = name;
 324                         CL_WeaponEntity_SetModel(this, name, swap);
 325                         this.viewmodel_origin = this.origin;
 326                         this.viewmodel_angles = this.angles;
 327                 }
 328                 anim_update(this);
 329                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 330                         anim_set(this, this.anim_idle, true, false, false);
 331         }
 332         float f = 0; // 0..1; 0: fully active
 333         float rate = STAT(WEAPONRATEFACTOR);
 334         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 335         if (eta <= 0) f = this.weapon_eta_last;
 336         else switch (this.state)
 337         {
 338                 case WS_RAISE:
 339                 {
 340                         f = eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_DROP:
 344                 {
 345                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 346                         break;
 347                 }
 348                 case WS_CLEAR:
 349                 {
 350                         f = 1;
 351                         break;
 352                 }
 353         }
 354         this.weapon_eta_last = f;
 355         this.origin = this.viewmodel_origin;
 356         this.angles = this.viewmodel_angles;
 357         this.angles_x = (-90 * f * f);
 358         viewmodel_animate(this);
 359         MUTATOR_CALLHOOK(DrawViewModel, this);
 360         setorigin(this, this.origin);
 361 }
 362
 363 STATIC_INIT(viewmodel) {
 364     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         viewmodels[slot] = new(viewmodel);
 366 }
 367
 368 void Porto_Draw(entity this);
 369 STATIC_INIT(Porto)
 370 {
 371         entity e = new_pure(porto);
 372         e.draw = Porto_Draw;
 373         IL_PUSH(g_drawables, e);
 374         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 375 }
 376
 377 const int polyline_length = 16;
 378 .vector polyline[polyline_length];
 379 void Porto_Draw(entity this)
 380 {
 381         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 382         {
 383                 entity wepent = viewmodels[slot];
 384
 385                 if (wepent.activeweapon != WEP_PORTO) continue;
 386                 if (spectatee_status) continue;
 387                 if (WEP_CVAR(porto, secondary)) continue;
 388                 if (intermission == 1) continue;
 389                 if (intermission == 2) continue;
 390                 if (STAT(HEALTH) <= 0) continue;
 391
 392                 vector pos = view_origin;
 393                 vector dir = view_forward;
 394                 if (wepent.angles_held_status)
 395                 {
 396                         makevectors(wepent.angles_held);
 397                         dir = v_forward;
 398                 }
 399
 400                 wepent.polyline[0] = pos;
 401
 402                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 403                 int n = 1 + 2;  // 2 lines == 3 points
 404                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 405                 {
 406                         traceline(pos, pos + 65536 * dir, true, this);
 407                         dir = reflect(dir, trace_plane_normal);
 408                         pos = trace_endpos;
 409                         wepent.polyline[++idx] = pos;
 410                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 411                         {
 412                                 n += 1;
 413                                 continue;
 414                         }
 415                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 416                         {
 417                                 n = max(2, idx);
 418                                 break;
 419                         }
 420                         // check size
 421                         {
 422                                 vector ang = vectoangles2(trace_plane_normal, dir);
 423                                 ang.x = -ang.x;
 424                                 makevectors(ang);
 425                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 426                                 {
 427                                         n = max(2, idx);
 428                                         break;
 429                                 }
 430                         }
 431                         portal_number += 1;
 432                         if (portal_number >= portal_max) break;
 433                         if (portal_number == 1) portal1_idx = idx;
 434                 }
 435                 for (int idx = 0; idx < n - 1; ++idx)
 436                 {
 437                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 438                         if (idx == 0) p -= view_up * 16;  // line from player
 439                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 440                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 441                 }
 442         }
 443 }
 444
 445 float drawtime;
 446 float avgspeed;
 447 vector GetCurrentFov(float fov)
 448 {
 449         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 450         float velocityzoom, curspeed;
 451         vector v;
 452
 453         zoomsensitivity = autocvar_cl_zoomsensitivity;
 454         zoomfactor = autocvar_cl_zoomfactor;
 455         if(zoomfactor < 1 || zoomfactor > 30)
 456                 zoomfactor = 2.5;
 457         zoomspeed = autocvar_cl_zoomspeed;
 458         if(zoomspeed >= 0)
 459         if(zoomspeed < 0.5 || zoomspeed > 16)
 460                         zoomspeed = 3.5;
 461
 462         zoomdir = button_zoom;
 463
 464         if(hud == HUD_NORMAL && !spectatee_status)
 465         {
 466                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 467                 {
 468                         entity wepent = viewmodels[slot];
 469                         if(wepent.switchweapon == wepent.activeweapon)
 470                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 471                                 zoomdir += button_attack2;
 472                 }
 473         }
 474         if(spectatee_status > 0 || isdemo())
 475         {
 476                 if(spectatorbutton_zoom)
 477                 {
 478                         if(zoomdir)
 479                                 zoomdir = 0;
 480                         else
 481                                 zoomdir = 1;
 482                 }
 483                 // fteqcc failed twice here already, don't optimize this
 484         }
 485
 486         if(zoomdir) { zoomin_effect = 0; }
 487
 488         if(camera_active)
 489         {
 490                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 491         }
 492         else if(autocvar_cl_spawnzoom && zoomin_effect)
 493         {
 494                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 495
 496                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 497                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 498                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 499         }
 500         else
 501         {
 502                 if(zoomspeed < 0) // instant zoom
 503                 {
 504                         if(zoomdir)
 505                                 current_viewzoom = 1 / zoomfactor;
 506                         else
 507                                 current_viewzoom = 1;
 508                 }
 509                 else
 510                 {
 511                         if(zoomdir)
 512                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 513                         else
 514                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 515                 }
 516         }
 517
 518         if(almost_equals(current_viewzoom, 1))
 519                 current_zoomfraction = 0;
 520         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 521                 current_zoomfraction = 1;
 522         else
 523                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 524
 525         if(zoomsensitivity < 1)
 526                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 527         else
 528                 setsensitivityscale(1);
 529
 530         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 531         {
 532                 if(intermission) { curspeed = 0; }
 533                 else
 534                 {
 535
 536                         makevectors(view_angles);
 537                         v = pmove_vel;
 538                         if(csqcplayer)
 539                                 v = csqcplayer.velocity;
 540
 541                         switch(autocvar_cl_velocityzoom_type)
 542                         {
 543                                 case 3: curspeed = max(0, v_forward * v); break;
 544                                 case 2: curspeed = (v_forward * v); break;
 545                                 case 1: default: curspeed = vlen(v); break;
 546                         }
 547                 }
 548
 549                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 550                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 551                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 552
 553                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 554         }
 555         else
 556                 velocityzoom = 1;
 557
 558         float frustumx, frustumy, fovx, fovy;
 559         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 560         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 561         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 562         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 563
 564         return '1 0 0' * fovx + '0 1 0' * fovy;
 565 }
 566
 567 vector GetViewLocationFOV(float fov)
 568 {
 569         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 570         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 571         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 572         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 573         return '1 0 0' * fovx + '0 1 0' * fovy;
 574 }
 575
 576 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 577 {
 578         float fovx, fovy;
 579         float width = (ov_worldmax.x - ov_worldmin.x);
 580         float height = (ov_worldmax.y - ov_worldmin.y);
 581         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 582         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 583         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 584         return '1 0 0' * fovx + '0 1 0' * fovy;
 585 }
 586
 587 // this function must match W_SetupShot!
 588 float zoomscript_caught;
 589
 590 vector wcross_origin;
 591 float wcross_scale_prev, wcross_alpha_prev;
 592 vector wcross_color_prev;
 593 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 594 vector wcross_color_goal_prev;
 595 float wcross_changedonetime;
 596
 597 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 598 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 599 float wcross_name_changestarttime, wcross_name_changedonetime;
 600 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 601
 602 float wcross_ring_prev;
 603
 604 entity trueaim;
 605 entity trueaim_rifle;
 606
 607 const float SHOTTYPE_HITTEAM = 1;
 608 const float SHOTTYPE_HITOBSTRUCTION = 2;
 609 const float SHOTTYPE_HITWORLD = 3;
 610 const float SHOTTYPE_HITENEMY = 4;
 611
 612 void TrueAim_Init()
 613 {
 614         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 615         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 616 }
 617
 618 float EnemyHitCheck()
 619 {
 620         float t, n;
 621         wcross_origin = project_3d_to_2d(trace_endpos);
 622         wcross_origin.z = 0;
 623         if(trace_ent)
 624                 n = trace_ent.entnum;
 625         else
 626                 n = trace_networkentity;
 627         if(n < 1)
 628                 return SHOTTYPE_HITWORLD;
 629         if(n > maxclients)
 630                 return SHOTTYPE_HITWORLD;
 631         t = entcs_GetTeam(n - 1);
 632         if(teamplay)
 633                 if(t == myteam)
 634                         return SHOTTYPE_HITTEAM;
 635         if(t == NUM_SPECTATOR)
 636                 return SHOTTYPE_HITWORLD;
 637         return SHOTTYPE_HITENEMY;
 638 }
 639
 640 float TrueAimCheck(entity wepent)
 641 {
 642         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 643         vector vecs, trueaimpoint, w_shotorg;
 644         vector mi, ma, dv;
 645         float shottype;
 646         entity ta;
 647         float mv;
 648
 649         mi = ma = '0 0 0';
 650         ta = trueaim;
 651         mv = MOVE_NOMONSTERS;
 652
 653         switch(wepent.activeweapon) // WEAPONTODO
 654         {
 655                 case WEP_TUBA: // no aim
 656                 case WEP_PORTO: // shoots from eye
 657                 case WEP_NEXBALL: // shoots from eye
 658                 case WEP_HOOK: // no trueaim
 659                 case WEP_MORTAR: // toss curve
 660                         return SHOTTYPE_HITWORLD;
 661                 case WEP_VORTEX:
 662                 case WEP_VAPORIZER:
 663                         mv = MOVE_NORMAL;
 664                         break;
 665                 case WEP_RIFLE:
 666                         ta = trueaim_rifle;
 667                         mv = MOVE_NORMAL;
 668                         if(zoomscript_caught)
 669                         {
 670                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 671                                 return EnemyHitCheck();
 672                         }
 673                         break;
 674                 case WEP_DEVASTATOR: // projectile has a size!
 675                         mi = '-3 -3 -3';
 676                         ma = '3 3 3';
 677                         break;
 678                 case WEP_FIREBALL: // projectile has a size!
 679                         mi = '-16 -16 -16';
 680                         ma = '16 16 16';
 681                         break;
 682                 case WEP_SEEKER: // projectile has a size!
 683                         mi = '-2 -2 -2';
 684                         ma = '2 2 2';
 685                         break;
 686                 case WEP_ELECTRO: // projectile has a size!
 687                         mi = '0 0 -3';
 688                         ma = '0 0 -3';
 689                         break;
 690         }
 691
 692         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 693
 694         vecs = decompressShotOrigin(STAT(SHOTORG));
 695
 696         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 697         trueaimpoint = trace_endpos;
 698
 699         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 700                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 701
 702         if(vecs.x > 0)
 703                 vecs.y = -vecs.y;
 704         else
 705                 vecs = '0 0 0';
 706
 707         dv = view_right * vecs.y + view_up * vecs.z;
 708         w_shotorg = traceorigin + dv;
 709
 710         // now move the vecs forward as much as requested if possible
 711         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 712         w_shotorg = trace_endpos - view_forward * nudge;
 713
 714         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 715         shottype = EnemyHitCheck();
 716         if(shottype != SHOTTYPE_HITWORLD)
 717                 return shottype;
 718
 719 #if 0
 720         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 721         // or rather, I know why, but see no fix
 722         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 723                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 724                 return SHOTTYPE_HITOBSTRUCTION;
 725 #endif
 726
 727         return SHOTTYPE_HITWORLD;
 728 }
 729
 730 void PostInit();
 731 void CSQC_Demo_Camera();
 732 float camera_mode;
 733 const float CAMERA_FREE = 1;
 734 const float CAMERA_CHASE = 2;
 735 float reticle_type;
 736 string NextFrameCommand;
 737
 738 vector freeze_org, freeze_ang;
 739 entity nightvision_noise, nightvision_noise2;
 740
 741 const float MAX_TIME_DIFF = 5;
 742 float pickup_crosshair_time, pickup_crosshair_size;
 743 float hitindication_crosshair_size;
 744 float use_vortex_chargepool;
 745
 746 float myhealth, myhealth_prev;
 747 float myhealth_flash;
 748
 749 float old_blurradius, old_bluralpha;
 750 float old_sharpen_intensity;
 751
 752 vector myhealth_gentlergb;
 753
 754 float contentavgalpha, liquidalpha_prev;
 755 vector liquidcolor_prev;
 756
 757 float eventchase_current_distance;
 758 float eventchase_running;
 759 bool WantEventchase(entity this)
 760 {
 761         if(autocvar_cl_orthoview)
 762                 return false;
 763         if(STAT(GAME_STOPPED) || intermission)
 764                 return true;
 765         if(this.viewloc)
 766                 return true;
 767         if(spectatee_status >= 0)
 768         {
 769                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 770                         return true;
 771                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 772                         return true;
 773                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 774                         return true;
 775                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 776                 {
 777                         if(autocvar_cl_eventchase_death == 2)
 778                         {
 779                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 780                                 if(this.velocity == '0 0 0' || eventchase_running)
 781                                         return true;
 782                         }
 783                         else return true;
 784                 }
 785         }
 786         return false;
 787 }
 788
 789 void HUD_Crosshair_Vehicle(entity this)
 790 {
 791         if(hud != HUD_BUMBLEBEE_GUN)
 792         {
 793                 Vehicle info = Vehicles_from(hud);
 794                 info.vr_crosshair(info, this);
 795         }
 796 }
 797
 798 vector damage_blurpostprocess, content_blurpostprocess;
 799
 800 float unaccounted_damage = 0;
 801 void UpdateDamage()
 802 {
 803         // accumulate damage with each stat update
 804         static float damage_total_prev = 0;
 805         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 806         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 807         damage_total_prev = damage_total;
 808
 809         static float damage_dealt_time_prev = 0;
 810         float damage_dealt_time = STAT(HIT_TIME);
 811         if (damage_dealt_time != damage_dealt_time_prev)
 812         {
 813                 unaccounted_damage += unaccounted_damage_new;
 814                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 815         }
 816         damage_dealt_time_prev = damage_dealt_time;
 817
 818         // prevent hitsound when switching spectatee
 819         static float spectatee_status_prev = 0;
 820         if (spectatee_status != spectatee_status_prev)
 821                 unaccounted_damage = 0;
 822         spectatee_status_prev = spectatee_status;
 823 }
 824
 825 void HitSound()
 826 {
 827         // varying sound pitch
 828
 829         bool have_arc = false;
 830         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 831         {
 832                 entity wepent = viewmodels[slot];
 833
 834                 if(wepent.activeweapon == WEP_ARC)
 835                         have_arc = true;
 836         }
 837
 838         static float hitsound_time_prev = 0;
 839         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 840         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 841         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 842         {
 843                 if (autocvar_cl_hitsound && unaccounted_damage)
 844                 {
 845                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 846                         float a = autocvar_cl_hitsound_max_pitch;
 847                         float b = autocvar_cl_hitsound_min_pitch;
 848                         float c = autocvar_cl_hitsound_nom_damage;
 849                         float d = unaccounted_damage;
 850                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 851
 852                         // if sound variation is disabled, set pitch_shift to 1
 853                         if (autocvar_cl_hitsound == 1)
 854                                 pitch_shift = 1;
 855
 856                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 857                         if (autocvar_cl_hitsound == 3)
 858                         {
 859                                 float mirror_value = (a-b)/2 + b;
 860                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 861                         }
 862
 863                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 864
 865                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 866                         // todo: normalize sound pressure levels? seems unnecessary
 867
 868                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 869                 }
 870                 unaccounted_damage = 0;
 871                 hitsound_time_prev = time;
 872         }
 873
 874         static float typehit_time_prev = 0;
 875         float typehit_time = STAT(TYPEHIT_TIME);
 876         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 877         {
 878                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 879                 typehit_time_prev = typehit_time;
 880         }
 881
 882         static float kill_time_prev = 0;
 883         float kill_time = STAT(KILL_TIME);
 884         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 885         {
 886                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 887                 kill_time_prev = kill_time;
 888         }
 889 }
 890
 891 vector crosshair_getcolor(entity this, float health_stat)
 892 {
 893         static float rainbow_last_flicker;
 894         static vector rainbow_prev_color;
 895         vector wcross_color = '0 0 0';
 896         switch(autocvar_crosshair_color_special)
 897         {
 898                 case 1: // crosshair_color_per_weapon
 899                 {
 900                         if(this != WEP_Null && hud == HUD_NORMAL)
 901                         {
 902                                 wcross_color = this.wpcolor;
 903                                 break;
 904                         }
 905                         else { goto normalcolor; }
 906                 }
 907
 908                 case 2: // crosshair_color_by_health
 909                 {
 910                         float hp = health_stat;
 911
 912                         //x = red
 913                         //y = green
 914                         //z = blue
 915
 916                         wcross_color.z = 0;
 917
 918                         if(hp > 200)
 919                         {
 920                                 wcross_color.x = 0;
 921                                 wcross_color.y = 1;
 922                         }
 923                         else if(hp > 150)
 924                         {
 925                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 926                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 927                         }
 928                         else if(hp > 100)
 929                         {
 930                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 931                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 932                                 wcross_color.z = 1 - (hp-100)*0.02;
 933                         }
 934                         else if(hp > 50)
 935                         {
 936                                 wcross_color.x = 1;
 937                                 wcross_color.y = 1;
 938                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 939                         }
 940                         else if(hp > 20)
 941                         {
 942                                 wcross_color.x = 1;
 943                                 wcross_color.y = (hp-20)*90/27/100;
 944                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 945                         }
 946                         else
 947                         {
 948                                 wcross_color.x = 1;
 949                                 wcross_color.y = 0;
 950                         }
 951                         break;
 952                 }
 953
 954                 case 3: // crosshair_color_rainbow
 955                 {
 956                         if(time >= rainbow_last_flicker)
 957                         {
 958                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 959                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 960                         }
 961                         wcross_color = rainbow_prev_color;
 962                         break;
 963                 }
 964 LABEL(normalcolor)
 965                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 966         }
 967
 968         return wcross_color;
 969 }
 970
 971 void HUD_Crosshair(entity this)
 972 {
 973         float f, i, j;
 974         vector v;
 975         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 976                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 977                 !HUD_MinigameMenu_IsOpened() )
 978         {
 979                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 980                         return;
 981
 982                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 983                         return;
 984
 985                 if (hud != HUD_NORMAL)
 986                 {
 987                         HUD_Crosshair_Vehicle(this);
 988                         return;
 989                 }
 990
 991                 string wcross_style;
 992                 float wcross_alpha, wcross_resolution;
 993                 wcross_style = autocvar_crosshair;
 994                 if (wcross_style == "0")
 995                         return;
 996                 wcross_resolution = autocvar_crosshair_size;
 997                 if (wcross_resolution == 0)
 998                         return;
 999                 wcross_alpha = autocvar_crosshair_alpha;
1000                 if (wcross_alpha == 0)
1001                         return;
1002
1003                 // TrueAim check
1004                 float shottype;
1005
1006                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1007                 wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1008                 wcross_origin.z = 0;
1009                 if(autocvar_crosshair_hittest)
1010                 {
1011                         vector wcross_oldorigin;
1012                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1013                         wcross_oldorigin = wcross_origin;
1014                         shottype = TrueAimCheck(thiswep);
1015                         if(shottype == SHOTTYPE_HITWORLD)
1016                         {
1017                                 v = wcross_origin - wcross_oldorigin;
1018                                 v.x /= vid_conwidth;
1019                                 v.y /= vid_conheight;
1020                                 if(vdist(v, >, 0.01))
1021                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1022                         }
1023                         if(!autocvar_crosshair_hittest_showimpact)
1024                                 wcross_origin = wcross_oldorigin;
1025                 }
1026                 else
1027                         shottype = SHOTTYPE_HITWORLD;
1028
1029                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1030                 string wcross_name = "";
1031                 float wcross_scale, wcross_blur;
1032
1033         entity e = WEP_Null;
1034                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1035                 {
1036                         entity wepent = viewmodels[0]; // TODO: unhardcode
1037                         e = wepent.switchingweapon;
1038                         if(e)
1039                         {
1040                                 if(autocvar_crosshair_per_weapon)
1041                                 {
1042                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1043                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1044                                         //if (wcross_resolution == 0)
1045                                                 //return;
1046
1047                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1048                                         wcross_resolution *= e.w_crosshair_size;
1049                                         wcross_name = e.w_crosshair;
1050                                 }
1051                         }
1052                 }
1053
1054                 if(wcross_name == "")
1055                         wcross_name = strcat("gfx/crosshair", wcross_style);
1056
1057                 // MAIN CROSSHAIR COLOR DECISION
1058                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1059
1060                 if(autocvar_crosshair_effect_scalefade)
1061                 {
1062                         wcross_scale = wcross_resolution;
1063                         wcross_resolution = 1;
1064                 }
1065                 else
1066                 {
1067                         wcross_scale = 1;
1068                 }
1069
1070                 if(autocvar_crosshair_pickup)
1071                 {
1072                         float stat_pickup_time = STAT(LAST_PICKUP);
1073
1074                         if(pickup_crosshair_time < stat_pickup_time)
1075                         {
1076                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1077                                         pickup_crosshair_size = 1;
1078
1079                                 pickup_crosshair_time = stat_pickup_time;
1080                         }
1081
1082                         if(pickup_crosshair_size > 0)
1083                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1084                         else
1085                                 pickup_crosshair_size = 0;
1086
1087                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1088                 }
1089
1090                 // todo: make crosshair hit indication dependent on damage dealt
1091                 if(autocvar_crosshair_hitindication)
1092                 {
1093                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1094
1095                         if(unaccounted_damage)
1096                         {
1097                                 hitindication_crosshair_size = 1;
1098                         }
1099
1100                         if(hitindication_crosshair_size > 0)
1101                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1102                         else
1103                                 hitindication_crosshair_size = 0;
1104
1105                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1106                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1107                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1108                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1109                 }
1110
1111                 if(shottype == SHOTTYPE_HITENEMY)
1112                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1113                 if(shottype == SHOTTYPE_HITTEAM)
1114                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1115
1116                 f = fabs(autocvar_crosshair_effect_time);
1117                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1118                 {
1119                         wcross_changedonetime = time + f;
1120                 }
1121                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1122                 {
1123                         wcross_name_changestarttime = time;
1124                         wcross_name_changedonetime = time + f;
1125                         if(wcross_name_goal_prev_prev)
1126                                 strunzone(wcross_name_goal_prev_prev);
1127                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1128                         wcross_name_goal_prev = strzone(wcross_name);
1129                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1130                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1131                         wcross_resolution_goal_prev = wcross_resolution;
1132                 }
1133
1134                 wcross_scale_goal_prev = wcross_scale;
1135                 wcross_alpha_goal_prev = wcross_alpha;
1136                 wcross_color_goal_prev = wcross_color;
1137
1138                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1139                 {
1140                         wcross_blur = 1;
1141                         wcross_alpha *= 0.75;
1142                 }
1143                 else
1144                         wcross_blur = 0;
1145                 // *_prev is at time-frametime
1146                 // * is at wcross_changedonetime+f
1147                 // what do we have at time?
1148                 if(time < wcross_changedonetime)
1149                 {
1150                         f = frametime / (wcross_changedonetime - time + frametime);
1151                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1152                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1153                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1154                 }
1155
1156                 wcross_scale_prev = wcross_scale;
1157                 wcross_alpha_prev = wcross_alpha;
1158                 wcross_color_prev = wcross_color;
1159
1160                 MUTATOR_CALLHOOK(UpdateCrosshair);
1161
1162                 wcross_scale *= 1 - autocvar__menu_alpha;
1163                 wcross_alpha *= 1 - autocvar__menu_alpha;
1164                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1165
1166                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1167                 {
1168                         // crosshair rings for weapon stats
1169                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1170                         {
1171                                 // declarations and stats
1172                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1173                                 string ring_image = string_null, ring_inner_image = string_null;
1174                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1175
1176                                 ring_scale = autocvar_crosshair_ring_size;
1177
1178                                 float weapon_clipload, weapon_clipsize;
1179                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1180                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1181
1182                                 float vortex_charge, vortex_chargepool;
1183                                 vortex_charge = STAT(VORTEX_CHARGE);
1184                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1185
1186                                 float arc_heat = STAT(ARC_HEAT);
1187
1188                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1189                                         vortex_charge_movingavg = vortex_charge;
1190
1191                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1192
1193                                 // handle the values
1194                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1195                                 {
1196                                         if (vortex_chargepool || use_vortex_chargepool) {
1197                                                 use_vortex_chargepool = 1;
1198                                                 ring_inner_value = vortex_chargepool;
1199                                         } else {
1200                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1201                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1202                                         }
1203
1204                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1205                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1206                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1207
1208                                         // draw the outer ring to show the current charge of the weapon
1209                                         ring_value = vortex_charge;
1210                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1211                                         ring_rgb = wcross_color;
1212                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1213                                 }
1214                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1215                                 {
1216                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1217                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1218                                         ring_rgb = wcross_color;
1219                                         ring_image = "gfx/crosshair_ring.tga";
1220                                 }
1221                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1222                                 {
1223                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1224                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1225                                         ring_rgb = wcross_color;
1226                                         ring_image = "gfx/crosshair_ring.tga";
1227                                 }
1228                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1229                                 {
1230                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1231                                         ring_scale = autocvar_crosshair_ring_reload_size;
1232                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1233                                         ring_rgb = wcross_color;
1234
1235                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1236                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1237                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1238                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1239                                         else
1240                                                 ring_image = "gfx/crosshair_ring.tga";
1241                                 }
1242                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1243                                 {
1244                                         ring_value = arc_heat;
1245                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1246                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1247                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1248                                         ring_image = "gfx/crosshair_ring.tga";
1249                                 }
1250
1251                                 // if in weapon switch animation, fade ring out/in
1252                                 if(autocvar_crosshair_effect_time > 0)
1253                                 {
1254                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1255                                         if (f >= 1)
1256                                         {
1257                                                 wcross_ring_prev = ((ring_image) ? true : false);
1258                                         }
1259
1260                                         if(wcross_ring_prev)
1261                                         {
1262                                                 if(f < 1)
1263                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1264                                         }
1265                                         else
1266                                         {
1267                                                 if(f < 1)
1268                                                         ring_alpha *= bound(0, f, 1);
1269                                         }
1270                                 }
1271
1272                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1273                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1274
1275                                 if (ring_value)
1276                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1277                         }
1278
1279 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1280                         MACRO_BEGIN { \
1281                                 if(wcross_blur > 0) \
1282                                 { \
1283                                         for(i = -2; i <= 2; ++i) \
1284                                         for(j = -2; j <= 2; ++j) \
1285                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1286                                 } \
1287                                 else \
1288                                 { \
1289                                         M(0,0,sz,wcross_name,wcross_alpha); \
1290                                 } \
1291                         } MACRO_END
1292
1293 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1294                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1295
1296 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1297                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1298
1299                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1300                         {
1301                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1302                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1303                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1304                                 f = 1 - f;
1305                         }
1306                         else
1307                         {
1308                                 f = 1;
1309                         }
1310                         wcross_name_alpha_goal_prev = f;
1311
1312                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1313                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1314
1315                         if(autocvar_crosshair_dot)
1316                         {
1317                                 vector wcross_color_old;
1318                                 wcross_color_old = wcross_color;
1319
1320                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1321                                         wcross_color = stov(autocvar_crosshair_dot_color);
1322
1323                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1324                                 // FIXME why don't we use wcross_alpha here?
1325                                 wcross_color = wcross_color_old;
1326                         }
1327                 }
1328         }
1329         else
1330         {
1331                 wcross_scale_prev = 0;
1332                 wcross_alpha_prev = 0;
1333                 wcross_scale_goal_prev = 0;
1334                 wcross_alpha_goal_prev = 0;
1335                 wcross_changedonetime = 0;
1336                 if(wcross_name_goal_prev)
1337                         strunzone(wcross_name_goal_prev);
1338                 wcross_name_goal_prev = string_null;
1339                 if(wcross_name_goal_prev_prev)
1340                         strunzone(wcross_name_goal_prev_prev);
1341                 wcross_name_goal_prev_prev = string_null;
1342                 wcross_name_changestarttime = 0;
1343                 wcross_name_changedonetime = 0;
1344                 wcross_name_alpha_goal_prev = 0;
1345                 wcross_name_alpha_goal_prev_prev = 0;
1346                 wcross_resolution_goal_prev = 0;
1347                 wcross_resolution_goal_prev_prev = 0;
1348         }
1349 }
1350
1351 const int MAX_SPECIALCOMMAND = 15;
1352 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1353 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1354 const float SPECIALCOMMAND_SPEED = 150;
1355 const float SPECIALCOMMAND_TURNSPEED = 2;
1356 const float SPECIALCOMMAND_SIZE = 0.025;
1357 const float SPECIALCOMMAND_CHANCE = 0.35;
1358 float sc_spawntime, sc_changetime;
1359 vector sc_color = '1 1 1';
1360 void SpecialCommand()
1361 {
1362         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1363                 return;
1364
1365         if(time >= sc_changetime)
1366         {
1367                 sc_changetime = time + 1;
1368                 sc_color = randomvec() * 1.5;
1369                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1370                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1371                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1372         }
1373         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1374
1375         if(!precache_pic("gfx/smile"))
1376                 return; // damn party poopers
1377
1378         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1379         {
1380                 vector slot = specialcommand_slots[j];
1381                 if(slot.y)
1382                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1383                 if(slot.z)
1384                         slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1385                 if(slot.y >= vid_conheight)
1386                         slot = '0 0 0';
1387
1388                 if(slot == '0 0 0')
1389                 {
1390                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1391                         {
1392                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1393                                 slot.y = 1; // start it off 0 so we can use it
1394                                 slot.z = random();
1395                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1396                                 vector newcolor = randomvec() * 2;
1397                                 newcolor.x = bound(0.4, newcolor.x, 1);
1398                                 newcolor.y = bound(0.4, newcolor.y, 1);
1399                                 newcolor.z = bound(0.4, newcolor.z, 1);
1400                                 specialcommand_colors[j] = newcolor;
1401                         }
1402                 }
1403                 else
1404                 {
1405                         vector splash_size = '0 0 0';
1406                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1407                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1408                         drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1409                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1410                 }
1411
1412                 specialcommand_slots[j] = slot;
1413         }
1414 }
1415
1416 void HUD_Draw(entity this)
1417 {
1418         // if we don't know gametype and scores yet avoid drawing the scoreboard
1419         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1420         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1421         // cl_deathscoreboard would show the scoreboard and so on
1422         if(!gametype)
1423                 return;
1424
1425         Hud_Dynamic_Frame();
1426
1427         if(!intermission)
1428         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1429         {
1430                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1431         }
1432         else if(STAT(FROZEN))
1433         {
1434                 vector col = '0.25 0.90 1';
1435                 if(STAT(REVIVE_PROGRESS))
1436                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1437                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1438         }
1439
1440         HUD_Scale_Enable();
1441         if(!intermission)
1442         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1443         {
1444                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1445                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1446                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1447         }
1448         else if(STAT(CAPTURE_PROGRESS))
1449         {
1450                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1451                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1452         }
1453         else if(STAT(REVIVE_PROGRESS))
1454         {
1455                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1456                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1457         }
1458         HUD_Scale_Disable();
1459
1460         if(autocvar_r_letterbox == 0)
1461                 if(autocvar_viewsize < 120)
1462                 {
1463                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1464                                 Accuracy_LoadLevels();
1465
1466                         HUD_Main();
1467                         HUD_Scale_Disable();
1468                 }
1469
1470         // crosshair goes VERY LAST
1471         SpecialCommand();
1472         UpdateDamage();
1473         HUD_Crosshair(this);
1474         HitSound();
1475 }
1476
1477 bool ov_enabled;
1478 float oldr_nearclip;
1479 float oldr_farclip_base;
1480 float oldr_farclip_world;
1481 float oldr_novis;
1482 float oldr_useportalculling;
1483 float oldr_useinfinitefarclip;
1484
1485 void cl_notice_run();
1486
1487 float prev_myteam;
1488 int lasthud;
1489 float vh_notice_time;
1490 void WaypointSprite_Load();
1491 void CSQC_UpdateView(entity this, float w, float h)
1492 {
1493     TC(int, w); TC(int, h);
1494         entity e;
1495         float fov;
1496         float f;
1497         vector vf_size, vf_min;
1498         float a;
1499
1500         execute_next_frame();
1501
1502         ++framecount;
1503
1504         stats_get();
1505         hud = STAT(HUD);
1506
1507         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1508                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1509
1510         lasthud = hud;
1511
1512         HUD_Scale_Disable();
1513
1514         if(autocvar__hud_showbinds_reload) // menu can set this one
1515         {
1516                 db_close(binddb);
1517                 binddb = db_create();
1518                 cvar_set("_hud_showbinds_reload", "0");
1519         }
1520
1521         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1522                 view_quality = getproperty(VF_MINFPS_QUALITY);
1523         else
1524                 view_quality = 1;
1525
1526         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1527         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1528
1529         vf_size = getpropertyvec(VF_SIZE);
1530         vf_min = getpropertyvec(VF_MIN);
1531         vid_width = vf_size.x;
1532         vid_height = vf_size.y;
1533
1534         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1535         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1536
1537         WaypointSprite_Load();
1538
1539         CSQCPlayer_SetCamera();
1540
1541         if(player_localentnum <= maxclients) // is it a client?
1542                 current_player = player_localentnum - 1;
1543         else // then player_localentnum is the vehicle I'm driving
1544                 current_player = player_localnum;
1545         myteam = entcs_GetTeam(current_player);
1546
1547         if(myteam != prev_myteam)
1548         {
1549                 myteamcolors = colormapPaletteColor(myteam, 1);
1550                 FOREACH(hud_panels, true, it.update_time = time);
1551                 prev_myteam = myteam;
1552         }
1553
1554         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1555
1556         float is_dead = (STAT(HEALTH) <= 0);
1557
1558         // FIXME do we need this hack?
1559         if(isdemo())
1560         {
1561                 // in demos, input_buttons do not work
1562                 button_zoom = (autocvar__togglezoom == "-");
1563         }
1564         else if(button_zoom
1565                 && autocvar_cl_unpress_zoom_on_death
1566                 && (spectatee_status >= 0)
1567                 && (is_dead || intermission))
1568         {
1569                 // no zoom while dead or in intermission please
1570                 localcmd("-zoom\n");
1571                 button_zoom = false;
1572         }
1573
1574         // event chase camera
1575         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1576         {
1577                 if(STAT(CAMERA_SPECTATOR))
1578                 {
1579                         if(spectatee_status > 0)
1580                         {
1581                                 if(!autocvar_chase_active)
1582                                 {
1583                                         cvar_set("chase_active", "-2");
1584                                         goto skip_eventchase_death;
1585                                 }
1586                         }
1587                         else if(autocvar_chase_active == -2)
1588                                 cvar_set("chase_active", "0");
1589
1590                         if(autocvar_chase_active == -2)
1591                                 goto skip_eventchase_death;
1592                 }
1593                 else if(autocvar_chase_active == -2)
1594                         cvar_set("chase_active", "0");
1595
1596                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1597
1598                 float vehicle_viewdist = 0;
1599                 vector vehicle_viewofs = '0 0 0';
1600
1601                 if(vehicle_chase)
1602                 {
1603                         if(hud != HUD_BUMBLEBEE_GUN)
1604                         {
1605                                 Vehicle info = Vehicles_from(hud);
1606                                 vehicle_viewdist = info.height;
1607                                 vehicle_viewofs = info.view_ofs;
1608                         }
1609                 }
1610
1611                 if(WantEventchase(this))
1612                 {
1613                         vector current_view_origin_override = '0 0 0';
1614                         vector view_offset_override = '0 0 0';
1615                         float chase_distance_override = 0;
1616                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1617                         if(custom_eventchase)
1618                         {
1619                                 current_view_origin_override = M_ARGV(0, vector);
1620                                 view_offset_override = M_ARGV(1, vector);
1621                                 chase_distance_override = M_ARGV(0, float);
1622                         }
1623                         eventchase_running = true;
1624
1625                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1626                         if(!local_player)
1627                                 local_player = this; // fall back!
1628
1629                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1630                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1631                         if (custom_eventchase)
1632                                 current_view_origin = current_view_origin_override;
1633
1634                         // detect maximum viewoffset and use it
1635                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1636                         if(vehicle_chase)
1637                         {
1638                                 if(vehicle_viewofs)
1639                                         view_offset = vehicle_viewofs;
1640                                 else
1641                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1642                         }
1643                         if (custom_eventchase)
1644                                 view_offset = view_offset_override;
1645
1646                         if(view_offset)
1647                         {
1648                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1649                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1650                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1651                         }
1652
1653                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1654                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1655                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1656                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1657
1658                         // make the camera smooth back
1659                         float chase_distance = autocvar_cl_eventchase_distance;
1660                         if(vehicle_chase)
1661                         {
1662                                 if(vehicle_viewofs)
1663                                         chase_distance = vehicle_viewdist;
1664                                 else
1665                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1666                         }
1667                         if (custom_eventchase)
1668                                 chase_distance = chase_distance_override;
1669
1670                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1671                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1672                         else if(eventchase_current_distance != chase_distance)
1673                                 eventchase_current_distance = chase_distance;
1674
1675                         makevectors(view_angles);
1676
1677                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1678                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1679
1680                         // If the boxtrace fails, revert back to line tracing.
1681                         if(!local_player.viewloc)
1682                         if(trace_startsolid)
1683                         {
1684                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1685                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1686                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1687                         }
1688                         else { setproperty(VF_ORIGIN, trace_endpos); }
1689
1690                         if(!local_player.viewloc)
1691                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1692                 }
1693                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1694                 {
1695                         eventchase_running = false;
1696                         cvar_set("chase_active", "0");
1697                         eventchase_current_distance = 0; // start from 0 next time
1698                 }
1699         }
1700         // workaround for camera stuck between player's legs when using chase_active 1
1701         // because the engine stops updating the chase_active camera when the game ends
1702         else if(intermission)
1703         {
1704                 cvar_settemp("chase_active", "-1");
1705                 eventchase_current_distance = 0;
1706         }
1707
1708         LABEL(skip_eventchase_death);
1709
1710         // do lockview after event chase camera so that it still applies whenever necessary.
1711         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1712         {
1713                 setproperty(VF_ORIGIN, freeze_org);
1714                 setproperty(VF_ANGLES, freeze_ang);
1715         }
1716         else
1717         {
1718                 freeze_org = getpropertyvec(VF_ORIGIN);
1719                 freeze_ang = getpropertyvec(VF_ANGLES);
1720         }
1721
1722         WarpZone_FixView();
1723         //WarpZone_FixPMove();
1724
1725         vector ov_org = '0 0 0';
1726         vector ov_mid = '0 0 0';
1727         vector ov_worldmin = '0 0 0';
1728         vector ov_worldmax = '0 0 0';
1729         if(autocvar_cl_orthoview)
1730         {
1731                 ov_worldmin = mi_picmin;
1732                 ov_worldmax = mi_picmax;
1733
1734                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1735                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1736                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1737
1738                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1739                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1740
1741                 float ov_nearest = vlen(ov_org - vec3(
1742                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1743                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1744                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1745                 ));
1746
1747                 float ov_furthest = 0;
1748                 float dist = 0;
1749
1750                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1751                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1752                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1753                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1754                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1755                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1756                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1757                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1758
1759                 if(!ov_enabled)
1760                 {
1761                         oldr_nearclip = cvar("r_nearclip");
1762                         oldr_farclip_base = cvar("r_farclip_base");
1763                         oldr_farclip_world = cvar("r_farclip_world");
1764                         oldr_novis = cvar("r_novis");
1765                         oldr_useportalculling = cvar("r_useportalculling");
1766                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1767                 }
1768
1769                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1770                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1771                 cvar_settemp("r_farclip_world", "0");
1772                 cvar_settemp("r_novis", "1");
1773                 cvar_settemp("r_useportalculling", "0");
1774                 cvar_settemp("r_useinfinitefarclip", "0");
1775
1776                 setproperty(VF_ORIGIN, ov_org);
1777                 setproperty(VF_ANGLES, '90 0 0');
1778
1779                 ov_enabled = true;
1780
1781                 #if 0
1782                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1783                         vtos(ov_org),
1784                         vtos(getpropertyvec(VF_ANGLES)),
1785                         ov_distance,
1786                         ov_nearest,
1787                         ov_furthest);
1788                 #endif
1789         }
1790         else
1791         {
1792                 if(ov_enabled)
1793                 {
1794                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1795                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1796                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1797                         cvar_set("r_novis", ftos(oldr_novis));
1798                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1799                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1800                 }
1801                 ov_enabled = false;
1802         }
1803
1804         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1805         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1806         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1807                 viewmodel_draw(viewmodels[slot]);
1808
1809         // Render the Scene
1810         view_origin = getpropertyvec(VF_ORIGIN);
1811         view_angles = getpropertyvec(VF_ANGLES);
1812         makevectors(view_angles);
1813         view_forward = v_forward;
1814         view_right = v_right;
1815         view_up = v_up;
1816
1817 #ifdef BLURTEST
1818         if(time > blurtest_time0 && time < blurtest_time1)
1819         {
1820                 float r, t;
1821
1822                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1823                 r = t * blurtest_radius;
1824                 f = 1 / (t ** blurtest_power) - 1;
1825
1826                 cvar_set("r_glsl_postprocess", "1");
1827                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1828         }
1829         else
1830         {
1831                 cvar_set("r_glsl_postprocess", "0");
1832                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1833         }
1834 #endif
1835
1836         TargetMusic_Advance();
1837         Fog_Force();
1838
1839         if(drawtime == 0)
1840                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1841         else
1842                 drawframetime = bound(0.000001, time - drawtime, 1);
1843         drawtime = time;
1844
1845         // watch for gametype changes here...
1846         // in ParseStuffCMD the cmd isn't executed yet :/
1847         // might even be better to add the gametype to TE_CSQC_INIT...?
1848         if(!postinit)
1849                 PostInit();
1850
1851         if(intermission && !intermission_time)
1852                 intermission_time = time;
1853
1854         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1855         {
1856                 if(calledhooks & HOOK_START)
1857                 {
1858                         localcmd("\ncl_hook_gameend\n");
1859                         calledhooks |= HOOK_END;
1860                 }
1861         }
1862
1863         Announcer();
1864
1865         fov = autocvar_fov;
1866         if(fov <= 59.5)
1867         {
1868                 if(!zoomscript_caught)
1869                 {
1870                         localcmd("+button9\n");
1871                         zoomscript_caught = 1;
1872                 }
1873         }
1874         else
1875         {
1876                 if(zoomscript_caught)
1877                 {
1878                         localcmd("-button9\n");
1879                         zoomscript_caught = 0;
1880                 }
1881         }
1882
1883         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1884
1885         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1886         {
1887                 entity wepent = viewmodels[slot];
1888
1889                 if(wepent.last_switchweapon != wepent.switchweapon)
1890                 {
1891                         weapontime = time;
1892                         wepent.last_switchweapon = wepent.switchweapon;
1893                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1894                         {
1895                                 localcmd("-zoom\n");
1896                                 button_zoom = false;
1897                         }
1898                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1899                         {
1900                                 localcmd("-fire\n");
1901                                 localcmd("-fire2\n");
1902                                 button_attack2 = false;
1903                         }
1904                 }
1905                 if(wepent.last_activeweapon != wepent.activeweapon)
1906                 {
1907                         wepent.last_activeweapon = wepent.activeweapon;
1908
1909                         e = wepent.activeweapon;
1910                         if(e.netname != "")
1911                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1912                         else if(slot == 0)
1913                                 localcmd("\ncl_hook_activeweapon none\n");
1914                 }
1915         }
1916
1917         // ALWAYS Clear Current Scene First
1918         clearscene();
1919
1920         setproperty(VF_ORIGIN, view_origin);
1921         setproperty(VF_ANGLES, view_angles);
1922
1923         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1924         setproperty(VF_SIZE, vf_size);
1925         setproperty(VF_MIN, vf_min);
1926
1927         // Assign Standard Viewflags
1928         // Draw the World (and sky)
1929         setproperty(VF_DRAWWORLD, 1);
1930
1931         // Set the console size vars
1932         vid_conwidth = autocvar_vid_conwidth;
1933         vid_conheight = autocvar_vid_conheight;
1934         vid_pixelheight = autocvar_vid_pixelheight;
1935
1936         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1937         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1938         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1939
1940         if(camera_active) // Camera for demo playback
1941         {
1942                 if(autocvar_camera_enable)
1943                         CSQC_Demo_Camera();
1944                 else
1945                 {
1946                         cvar_set("chase_active", ftos(chase_active_backup));
1947                         cvar_set("cl_demo_mousegrab", "0");
1948                         camera_active = false;
1949                 }
1950         }
1951         else
1952         {
1953 #ifdef CAMERATEST
1954                 if(autocvar_camera_enable)
1955 #else
1956                 if(autocvar_camera_enable && isdemo())
1957 #endif
1958                 {
1959                         // Enable required Darkplaces cvars
1960                         chase_active_backup = autocvar_chase_active;
1961                         cvar_set("chase_active", "2");
1962                         cvar_set("cl_demo_mousegrab", "1");
1963                         camera_active = true;
1964                         camera_mode = false;
1965                 }
1966         }
1967
1968         // Draw the Crosshair
1969         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1970
1971         // Draw the Engine Status Bar (the default Quake HUD)
1972         setproperty(VF_DRAWENGINESBAR, 0);
1973
1974         // Update the mouse position
1975         /*
1976            mousepos_x = vid_conwidth;
1977            mousepos_y = vid_conheight;
1978            mousepos = mousepos*0.5 + getmousepos();
1979          */
1980
1981         IL_EACH(g_drawables, it.draw, it.draw(it));
1982
1983         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1984         renderscene();
1985
1986         // now switch to 2D drawing mode by calling a 2D drawing function
1987         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1988         // next R_RenderScene call
1989         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1990
1991         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1992         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1993         {
1994                 // apply night vision effect
1995                 vector tc_00, tc_01, tc_10, tc_11;
1996                 vector rgb = '0 0 0';
1997
1998                 if(!nightvision_noise)
1999                 {
2000                         nightvision_noise = new(nightvision_noise);
2001                 }
2002                 if(!nightvision_noise2)
2003                 {
2004                         nightvision_noise2 = new(nightvision_noise2);
2005                 }
2006
2007                 // color tint in yellow
2008                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2009
2010                 // draw BG
2011                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2012                 rgb = '1 1 1';
2013                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2014                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2015                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2016                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2017                 tc_11 = tc_01 + tc_10 - tc_00;
2018                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2019                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2020                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2021                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2022                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2023                 R_EndPolygon();
2024
2025                 // draw FG
2026                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2027                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2028                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2029                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2030                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2031                 tc_11 = tc_01 + tc_10 - tc_00;
2032                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2033                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2034                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2035                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2036                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2037                 R_EndPolygon();
2038         }
2039
2040         if(autocvar_cl_reticle)
2041         {
2042                 string reticle_image = string_null;
2043                 bool wep_zoomed = false;
2044                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2045                 {
2046                         entity wepe = viewmodels[slot];
2047                         Weapon wep = wepe.activeweapon;
2048                         if(wep != WEP_Null && wep.wr_zoom)
2049                         {
2050                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2051                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2052                                         reticle_image = wep.w_reticle;
2053                                 wep_zoomed += do_zoom;
2054                         }
2055                 }
2056                 // Draw the aiming reticle for weapons that use it
2057                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2058                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2059                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2060                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
2061                 {
2062                         // no zoom reticle while dead
2063                         reticle_type = 0;
2064                 }
2065                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2066                 {
2067                         if(reticle_image) { reticle_type = 2; }
2068                         else { reticle_type = 0; }
2069                 }
2070                 else if(button_zoom || zoomscript_caught)
2071                 {
2072                         // normal zoom
2073                         reticle_type = 1;
2074                 }
2075
2076                 if(reticle_type)
2077                 {
2078                         if(autocvar_cl_reticle_stretch)
2079                         {
2080                                 reticle_size.x = vid_conwidth;
2081                                 reticle_size.y = vid_conheight;
2082                                 reticle_pos.x = 0;
2083                                 reticle_pos.y = 0;
2084                         }
2085                         else
2086                         {
2087                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2088                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2089                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2090                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2091                         }
2092
2093                         if(zoomscript_caught)
2094                                 f = 1;
2095                         else
2096                                 f = current_zoomfraction;
2097
2098                         if(f)
2099                         {
2100                                 switch(reticle_type)
2101                                 {
2102                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2103                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2104                                 }
2105                         }
2106                 }
2107         }
2108         else
2109         {
2110                 if(reticle_type != 0) { reticle_type = 0; }
2111         }
2112
2113
2114         // improved polyblend
2115         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2116         {
2117                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2118                 vector liquidcolor;
2119
2120                 switch(pointcontents(view_origin))
2121                 {
2122                         case CONTENT_WATER:
2123                                 liquidalpha = autocvar_hud_contents_water_alpha;
2124                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2125                                 incontent = 1;
2126                                 break;
2127
2128                         case CONTENT_LAVA:
2129                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2130                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2131                                 incontent = 1;
2132                                 break;
2133
2134                         case CONTENT_SLIME:
2135                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2136                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2137                                 incontent = 1;
2138                                 break;
2139
2140                         default:
2141                                 liquidalpha = 0;
2142                                 liquidcolor = '0 0 0';
2143                                 incontent = 0;
2144                                 break;
2145                 }
2146
2147                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2148                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2149                         contentfadetime = autocvar_hud_contents_fadeintime;
2150                         liquidalpha_prev = liquidalpha;
2151                         liquidcolor_prev = liquidcolor;
2152                 }
2153                 else
2154                         contentfadetime = autocvar_hud_contents_fadeouttime;
2155
2156                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2157                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2158
2159                 if(contentavgalpha)
2160                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2161
2162                 if(autocvar_hud_postprocessing)
2163                 {
2164                         if(autocvar_hud_contents_blur && contentavgalpha)
2165                         {
2166                                 content_blurpostprocess.x = 1;
2167                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2168                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2169                         }
2170                         else
2171                         {
2172                                 content_blurpostprocess.x = 0;
2173                                 content_blurpostprocess.y = 0;
2174                                 content_blurpostprocess.z = 0;
2175                         }
2176                 }
2177         }
2178
2179         if(autocvar_hud_damage && !STAT(FROZEN))
2180         {
2181                 splash_size.x = max(vid_conwidth, vid_conheight);
2182                 splash_size.y = max(vid_conwidth, vid_conheight);
2183                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2184                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2185
2186                 float myhealth_flash_temp;
2187                 myhealth = STAT(HEALTH);
2188
2189                 // fade out
2190                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2191                 // add new damage
2192                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2193
2194                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2195                 pain_threshold = autocvar_hud_damage_pain_threshold;
2196                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2197                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2198
2199                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2200                 {
2201                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2202                 }
2203
2204                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2205
2206                 if(myhealth_prev < 1)
2207                 {
2208                         if(myhealth >= 1)
2209                         {
2210                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2211                                 myhealth_flash_temp = 0;
2212                         }
2213                         else
2214                         {
2215                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2216                         }
2217                 }
2218
2219                 if(spectatee_status == -1 || intermission)
2220                 {
2221                         myhealth_flash = 0; // observing, or match ended
2222                         myhealth_flash_temp = 0;
2223                 }
2224
2225                 myhealth_prev = myhealth;
2226
2227                 // IDEA: change damage color/picture based on player model for robot/alien species?
2228                 // pro: matches model better
2229                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2230                 // maybe different reddish pics?
2231                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2232                 {
2233                         if(autocvar_cl_gentle_damage == 2)
2234                         {
2235                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2236                                         myhealth_gentlergb = randomvec();
2237                         }
2238                         else
2239                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2240
2241                         if(myhealth_flash_temp > 0)
2242                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2243                 }
2244                 else if(myhealth_flash_temp > 0)
2245                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2246
2247                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2248                 {
2249                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2250                         {
2251                                 damage_blurpostprocess.x = 1;
2252                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2253                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2254                         }
2255                         else
2256                         {
2257                                 damage_blurpostprocess.x = 0;
2258                                 damage_blurpostprocess.y = 0;
2259                                 damage_blurpostprocess.z = 0;
2260                         }
2261                 }
2262         }
2263
2264         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2265         float e2 = (autocvar_hud_powerup != 0);
2266         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2267         {
2268                 // enable or disable rendering types if they are used or not
2269                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2270                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2271
2272                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2273                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2274                 {
2275                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2276                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2277                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2278                         {
2279                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2280                                 old_blurradius = blurradius;
2281                                 old_bluralpha = bluralpha;
2282                         }
2283                 }
2284                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2285                 {
2286                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2287                         old_blurradius = 0;
2288                         old_bluralpha = 0;
2289                 }
2290
2291                 // edge detection postprocess handling done second (used by hud_powerup)
2292                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2293                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2294                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2295
2296                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2297
2298                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2299                 {
2300                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2301                         {
2302                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2303                                 old_sharpen_intensity = sharpen_intensity;
2304                         }
2305                 }
2306                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2307                 {
2308                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2309                         old_sharpen_intensity = 0;
2310                 }
2311
2312                 if(cvar("r_glsl_postprocess") == 0)
2313                         cvar_set("r_glsl_postprocess", "2");
2314         }
2315         else if(cvar("r_glsl_postprocess") == 2)
2316                 cvar_set("r_glsl_postprocess", "0");
2317
2318         /*if(gametype == MAPINFO_TYPE_CTF)
2319           {
2320           ctf_view();
2321           } else */
2322
2323         // draw 2D entities
2324         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2325         Draw_ShowNames_All();
2326 #if ENABLE_DEBUGDRAW
2327         Debug_Draw();
2328 #endif
2329
2330         scoreboard_active = Scoreboard_WouldDraw();
2331
2332         HUD_Draw(this); // this parameter for deep vehicle function
2333
2334         if(NextFrameCommand)
2335         {
2336                 localcmd("\n", NextFrameCommand, "\n");
2337                 NextFrameCommand = string_null;
2338         }
2339
2340         // we must do this check AFTER a frame was rendered, or it won't work
2341         if(cs_project_is_b0rked == 0)
2342         {
2343                 string w0, h0;
2344                 w0 = ftos(autocvar_vid_conwidth);
2345                 h0 = ftos(autocvar_vid_conheight);
2346                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2347                 //setproperty(VF_FOV, '90 90 0');
2348                 setproperty(VF_ORIGIN, '0 0 0');
2349                 setproperty(VF_ANGLES, '0 0 0');
2350                 setproperty(VF_PERSPECTIVE, 1);
2351                 makevectors('0 0 0');
2352                 vector v1, v2;
2353                 cvar_set("vid_conwidth", "800");
2354                 cvar_set("vid_conheight", "600");
2355                 v1 = cs_project(v_forward);
2356                 cvar_set("vid_conwidth", "640");
2357                 cvar_set("vid_conheight", "480");
2358                 v2 = cs_project(v_forward);
2359                 if(v1 == v2)
2360                         cs_project_is_b0rked = 1;
2361                 else
2362                         cs_project_is_b0rked = -1;
2363                 cvar_set("vid_conwidth", w0);
2364                 cvar_set("vid_conheight", h0);
2365         }
2366
2367         if(autocvar__hud_configure)
2368                 HUD_Panel_Mouse();
2369         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2370                 HUD_Minigame_Mouse();
2371         else if(QuickMenu_IsOpened())
2372                 QuickMenu_Mouse();
2373         else
2374                 HUD_Radar_Mouse();
2375
2376         cl_notice_run();
2377         unpause_update();
2378         Net_Flush();
2379
2380         // let's reset the view back to normal for the end
2381         setproperty(VF_MIN, '0 0 0');
2382         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2383
2384         IL_ENDFRAME();
2385 }
2386
2387
2388 // following vectors must be global to allow seamless switching between camera modes
2389 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2390 void CSQC_Demo_Camera()
2391 {
2392         float speed, attenuation, dimensions;
2393         vector tmp, delta;
2394
2395         if( autocvar_camera_reset || !camera_mode )
2396         {
2397                 camera_offset = '0 0 0';
2398                 current_angles = '0 0 0';
2399                 camera_direction = '0 0 0';
2400                 camera_offset.z += 30;
2401                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2402                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2403                 current_origin = view_origin;
2404                 current_camera_offset  = camera_offset;
2405                 cvar_set("camera_reset", "0");
2406                 camera_mode = CAMERA_CHASE;
2407         }
2408
2409         // Camera angles
2410         if( camera_roll )
2411                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2412
2413         if(autocvar_camera_look_player)
2414         {
2415                 vector dir;
2416                 float n;
2417
2418                 dir = normalize(view_origin - current_position);
2419                 n = mouse_angles.z;
2420                 mouse_angles = vectoangles(dir);
2421                 mouse_angles.x = mouse_angles.x * -1;
2422                 mouse_angles.z = n;
2423         }
2424         else
2425         {
2426                 tmp = getmousepos() * 0.1;
2427                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2428                 {
2429                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2430                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2431                 }
2432         }
2433
2434         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2435         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2436         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2437         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2438
2439         // Fix difference when angles don't have the same sign
2440         delta = '0 0 0';
2441         if(mouse_angles.y < -60 && current_angles.y > 60)
2442                 delta = '0 360 0';
2443         if(mouse_angles.y > 60 && current_angles.y < -60)
2444                 delta = '0 -360 0';
2445
2446         if(autocvar_camera_look_player)
2447                 attenuation = autocvar_camera_look_attenuation;
2448         else
2449                 attenuation = autocvar_camera_speed_attenuation;
2450
2451         attenuation = 1 / max(1, attenuation);
2452         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2453
2454         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2455         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2456         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2457         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2458
2459         // Camera position
2460         tmp = '0 0 0';
2461         dimensions = 0;
2462
2463         if( camera_direction.x )
2464         {
2465                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2466                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2467                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2468                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2469                 ++dimensions;
2470         }
2471
2472         if( camera_direction.y )
2473         {
2474                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2475                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2476                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2477                 ++dimensions;
2478         }
2479
2480         if( camera_direction.z )
2481         {
2482                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2483                 ++dimensions;
2484         }
2485
2486         if(autocvar_camera_free)
2487                 speed = autocvar_camera_speed_free;
2488         else
2489                 speed = autocvar_camera_speed_chase;
2490
2491         if(dimensions)
2492         {
2493                 speed = speed * sqrt(1 / dimensions);
2494                 camera_offset += tmp * speed;
2495         }
2496
2497         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2498
2499         // Camera modes
2500         if( autocvar_camera_free )
2501         {
2502                 if ( camera_mode == CAMERA_CHASE )
2503                 {
2504                         current_camera_offset = current_origin + current_camera_offset;
2505                         camera_offset = current_origin + camera_offset;
2506                 }
2507
2508                 camera_mode = CAMERA_FREE;
2509                 current_position = current_camera_offset;
2510         }
2511         else
2512         {
2513                 if ( camera_mode == CAMERA_FREE )
2514                 {
2515                         current_origin = view_origin;
2516                         camera_offset = camera_offset - current_origin;
2517                         current_camera_offset = current_camera_offset - current_origin;
2518                 }
2519
2520                 camera_mode = CAMERA_CHASE;
2521
2522                 if(autocvar_camera_chase_smoothly)
2523                         current_origin += (view_origin - current_origin) * attenuation;
2524                 else
2525                         current_origin = view_origin;
2526
2527                 current_position = current_origin + current_camera_offset;
2528         }
2529
2530         setproperty(VF_ANGLES, current_angles);
2531         setproperty(VF_ORIGIN, current_position);
2532 }