Merge branch 'master' into Lyberta/StandaloneOverkillWeapons
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / view.qc
1 #include "view.qh"
2
3 #include "announcer.qh"
4 #include "hud/_mod.qh"
5 #include "mapvoting.qh"
6 #include "shownames.qh"
7 #include "hud/panel/scoreboard.qh"
8 #include "hud/panel/quickmenu.qh"
9
10 #include "mutators/events.qh"
11
12 #include <common/animdecide.qh>
13 #include <common/ent_cs.qh>
14 #include <common/anim.qh>
15 #include <common/constants.qh>
16 #include <common/net_linked.qh>
17 #include <common/debug.qh>
18 #include <common/mapinfo.qh>
19 #include <common/gamemodes/_mod.qh>
20 #include <common/physics/player.qh>
21 #include <common/stats.qh>
22 #include <common/triggers/target/music.qh>
23 #include <common/teams.qh>
24
25 #include <common/weapons/weapon/tuba.qh>
26
27 #include <common/vehicles/all.qh>
28 #include <common/weapons/_all.qh>
29 #include <common/mutators/mutator/overkill/okvortex.qh>
30 #include <common/viewloc.qh>
31 #include <common/minigames/cl_minigames.qh>
32 #include <common/minigames/cl_minigames_hud.qh>
33
34 #include <lib/csqcmodel/cl_player.qh>
35 #include <lib/csqcmodel/cl_model.qh>
36 #include "csqcmodel_hooks.qh"
37
38 #include <lib/warpzone/client.qh>
39 #include <lib/warpzone/common.qh>
40
41 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
42
43 float autocvar_cl_viewmodel_scale;
44
45 bool autocvar_cl_bobmodel;
46 float autocvar_cl_bobmodel_speed;
47 float autocvar_cl_bobmodel_side;
48 float autocvar_cl_bobmodel_up;
49
50 float autocvar_cl_followmodel;
51 float autocvar_cl_followmodel_speed = 0.3;
52 float autocvar_cl_followmodel_limit = 135;
53 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
54 float autocvar_cl_followmodel_highpass = 0.05;
55 float autocvar_cl_followmodel_lowpass = 0.03;
56 bool autocvar_cl_followmodel_velocity_absolute;
57
58 float autocvar_cl_leanmodel;
59 float autocvar_cl_leanmodel_speed = 0.3;
60 float autocvar_cl_leanmodel_limit = 30;
61 float autocvar_cl_leanmodel_highpass1 = 0.2;
62 float autocvar_cl_leanmodel_highpass = 0.2;
63 float autocvar_cl_leanmodel_lowpass = 0.05;
64
65 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
66
67 #define lowpass(value, frac, ref_store, ret) \
68         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
69
70 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
71 { \
72         float __ignore; lowpass(value, frac, ref_store, __ignore); \
73         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
74 } MACRO_END
75
76 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
77 { \
78         float __f = 0; lowpass(value, frac, ref_store, __f); \
79         ret = (value) - __f; \
80 } MACRO_END
81
82 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
83 { \
84         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
85         ret = (value) - __f; \
86 } MACRO_END
87
88 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
89 { \
90         lowpass(value.x, frac, ref_store.x, ref_out.x); \
91         lowpass(value.y, frac, ref_store.y, ref_out.y); \
92 } MACRO_END
93
94 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
95 { \
96         highpass(value.x, frac, ref_store.x, ref_out.x); \
97         highpass(value.y, frac, ref_store.y, ref_out.y); \
98 } MACRO_END
99
100 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
101 { \
102         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
103         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
104 } MACRO_END
105
106 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
107 { \
108         lowpass(value.x, frac, ref_store.x, ref_out.x); \
109         lowpass(value.y, frac, ref_store.y, ref_out.y); \
110         lowpass(value.z, frac, ref_store.z, ref_out.z); \
111 } MACRO_END
112
113 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
114 { \
115         highpass(value.x, frac, ref_store.x, ref_out.x); \
116         highpass(value.y, frac, ref_store.y, ref_out.y); \
117         highpass(value.z, frac, ref_store.z, ref_out.z); \
118 } MACRO_END
119
120 void calc_followmodel_ofs(entity view)
121 {
122         if(cl_followmodel_time == time)
123                 return; // cl_followmodel_ofs already calculated for this frame
124
125         float frac;
126         vector gunorg = '0 0 0';
127         static vector vel_average;
128         static vector gunorg_adjustment_highpass;
129         static vector gunorg_adjustment_lowpass;
130
131         vector vel;
132         if (autocvar_cl_followmodel_velocity_absolute)
133                 vel = view.velocity;
134         else
135         {
136                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
137                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
138                 vel.x = view.velocity * forward;
139                 vel.y = view.velocity * right * -1;
140                 vel.z = view.velocity * up;
141         }
142
143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
146
147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
148         lowpass3(vel, frac, vel_average, gunorg);
149
150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
151
152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
154         frac = avg_factor(autocvar_cl_followmodel_highpass);
155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
158
159         if (autocvar_cl_followmodel_velocity_absolute)
160         {
161                 vector fixed_gunorg;
162                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
163                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
164                 fixed_gunorg.x = gunorg * forward;
165                 fixed_gunorg.y = gunorg * right * -1;
166                 fixed_gunorg.z = gunorg * up;
167                 gunorg = fixed_gunorg;
168         }
169
170         cl_followmodel_ofs = gunorg;
171         cl_followmodel_time = time;
172 }
173
174 vector leanmodel_ofs(entity view)
175 {
176         float frac;
177         vector gunangles = '0 0 0';
178         static vector gunangles_prev = '0 0 0';
179         static vector gunangles_highpass = '0 0 0';
180         static vector gunangles_adjustment_highpass;
181         static vector gunangles_adjustment_lowpass;
182
183         if (view.csqcmodel_teleported)
184                 gunangles_prev = view_angles;
185
186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
187         gunangles_highpass += gunangles_prev;
188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
193         gunangles_prev = view_angles;
194         gunangles_highpass -= gunangles_prev;
195
196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
198
199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
204
205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
206
207         return gunangles;
208 }
209
210 vector bobmodel_ofs(entity view)
211 {
212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
213         static bool oldonground;
214         static float hitgroundtime;
215         if (clonground)
216         {
217                 float f = time; // cl.movecmd[0].time
218                 if (!oldonground)
219                         hitgroundtime = f;
220         }
221         oldonground = clonground;
222
223         // calculate for swinging gun model
224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
225         vector gunorg = '0 0 0';
226         static float bobmodel_scale = 0;
227         static float time_ofs = 0; // makes the effect always restart in the same way
228         if (clonground)
229         {
230                 if (time - hitgroundtime > 0.05)
231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
232         }
233         else
234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
235
236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
237         if (bobmodel_scale && xyspeed)
238         {
239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
243         }
244         else
245                 time_ofs = time;
246
247         return gunorg;
248 }
249
250 void viewmodel_animate(entity this)
251 {
252         if (autocvar_chase_active) return;
253         if (STAT(HEALTH) <= 0) return;
254
255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
256
257         if (autocvar_cl_followmodel)
258         {
259                 calc_followmodel_ofs(view);
260                 this.origin += cl_followmodel_ofs;
261         }
262
263         if (autocvar_cl_leanmodel)
264                 this.angles += leanmodel_ofs(view);
265
266         // vertical view bobbing code
267         // TODO: cl_bob
268
269         // horizontal view bobbing code
270         // TODO: cl_bob2
271
272         // fall bobbing code
273         // causes the view to swing down and back up when touching the ground
274         // TODO: cl_bobfall
275
276         // gun model bobbing code
277         if (autocvar_cl_bobmodel)
278                 this.origin += bobmodel_ofs(view);
279 }
280
281 .vector viewmodel_origin, viewmodel_angles;
282 .float weapon_nextthink;
283 .float weapon_eta_last;
284 .float weapon_switchdelay;
285
286 .string name_last;
287
288 void viewmodel_draw(entity this)
289 {
290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
291                 return;
292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
293         float a = this.alpha;
294         static bool wasinvehicle;
295         bool invehicle = player_localentnum > maxclients;
296         if (invehicle) a = -1;
297         else if (wasinvehicle) a = 1;
298         wasinvehicle = invehicle;
299         Weapon wep = this.activeweapon;
300         int c = entcs_GetClientColors(current_player);
301         vector g = weaponentity_glowmod(wep, NULL, c, this);
302         entity me = CSQCModel_server2csqc(player_localentnum - 1);
303         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
304                 | EF_NODEPTHTEST)
305                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
306         for (entity e = this; e; e = e.weaponchild)
307         {
308                 e.drawmask = mask;
309                 e.alpha = a;
310                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
311                 e.glowmod = g;
312                 e.csqcmodel_effects = fx;
313                 CSQCModel_Effects_Apply(e);
314         }
315         {
316                 string name = wep.mdl;
317                 string newname = wep.wr_viewmodel(wep, this);
318                 if(newname)
319                         name = newname;
320                 bool swap = name != this.name_last;
321                 // if (swap)
322                 {
323                         this.name_last = name;
324                         CL_WeaponEntity_SetModel(this, name, swap);
325                         this.viewmodel_origin = this.origin;
326                         this.viewmodel_angles = this.angles;
327                 }
328                 anim_update(this);
329                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
330                         anim_set(this, this.anim_idle, true, false, false);
331         }
332         float f = 0; // 0..1; 0: fully active
333         float rate = STAT(WEAPONRATEFACTOR);
334         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
335         if (eta <= 0) f = this.weapon_eta_last;
336         else switch (this.state)
337         {
338                 case WS_RAISE:
339                 {
340                         f = eta / max(eta, this.weapon_switchdelay);
341                         break;
342                 }
343                 case WS_DROP:
344                 {
345                         f = 1 - eta / max(eta, this.weapon_switchdelay);
346                         break;
347                 }
348                 case WS_CLEAR:
349                 {
350                         f = 1;
351                         break;
352                 }
353         }
354         this.weapon_eta_last = f;
355         this.origin = this.viewmodel_origin;
356         this.angles = this.viewmodel_angles;
357         this.angles_x = (-90 * f * f);
358         viewmodel_animate(this);
359         MUTATOR_CALLHOOK(DrawViewModel, this);
360         setorigin(this, this.origin);
361 }
362
363 STATIC_INIT(viewmodel) {
364     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
365         viewmodels[slot] = new(viewmodel);
366 }
367
368 void Porto_Draw(entity this);
369 STATIC_INIT(Porto)
370 {
371         entity e = new_pure(porto);
372         e.draw = Porto_Draw;
373         IL_PUSH(g_drawables, e);
374         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
375 }
376
377 const int polyline_length = 16;
378 .vector polyline[polyline_length];
379 void Porto_Draw(entity this)
380 {
381         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
382         {
383                 entity wepent = viewmodels[slot];
384
385                 if (wepent.activeweapon != WEP_PORTO) continue;
386                 if (spectatee_status) continue;
387                 if (WEP_CVAR(porto, secondary)) continue;
388                 if (intermission == 1) continue;
389                 if (intermission == 2) continue;
390                 if (STAT(HEALTH) <= 0) continue;
391
392                 vector pos = view_origin;
393                 vector dir = view_forward;
394                 if (wepent.angles_held_status)
395                 {
396                         makevectors(wepent.angles_held);
397                         dir = v_forward;
398                 }
399
400                 wepent.polyline[0] = pos;
401
402                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
403                 int n = 1 + 2;  // 2 lines == 3 points
404                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
405                 {
406                         traceline(pos, pos + 65536 * dir, true, this);
407                         dir = reflect(dir, trace_plane_normal);
408                         pos = trace_endpos;
409                         wepent.polyline[++idx] = pos;
410                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
411                         {
412                                 n += 1;
413                                 continue;
414                         }
415                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
416                         {
417                                 n = max(2, idx);
418                                 break;
419                         }
420                         // check size
421                         {
422                                 vector ang = vectoangles2(trace_plane_normal, dir);
423                                 ang.x = -ang.x;
424                                 makevectors(ang);
425                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
426                                 {
427                                         n = max(2, idx);
428                                         break;
429                                 }
430                         }
431                         portal_number += 1;
432                         if (portal_number >= portal_max) break;
433                         if (portal_number == 1) portal1_idx = idx;
434                 }
435                 for (int idx = 0; idx < n - 1; ++idx)
436                 {
437                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
438                         if (idx == 0) p -= view_up * 16;  // line from player
439                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
440                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
441                 }
442         }
443 }
444
445 float drawtime;
446 float avgspeed;
447 vector GetCurrentFov(float fov)
448 {
449         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
450         float velocityzoom, curspeed;
451         vector v;
452
453         zoomsensitivity = autocvar_cl_zoomsensitivity;
454         zoomfactor = autocvar_cl_zoomfactor;
455         if(zoomfactor < 1 || zoomfactor > 30)
456                 zoomfactor = 2.5;
457         zoomspeed = autocvar_cl_zoomspeed;
458         if(zoomspeed >= 0)
459         if(zoomspeed < 0.5 || zoomspeed > 16)
460                         zoomspeed = 3.5;
461
462         zoomdir = button_zoom;
463
464         if(hud == HUD_NORMAL && !spectatee_status)
465         {
466                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
467                 {
468                         entity wepent = viewmodels[slot];
469                         if(wepent.switchweapon == wepent.activeweapon)
470                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary)) || (wepent.activeweapon == WEP_OVERKILL_VORTEX && !WEP_CVAR(okvortex, secondary))) // do NOT use switchweapon here
471                                 zoomdir += button_attack2;
472                 }
473         }
474         if(spectatee_status > 0 || isdemo())
475         {
476                 if(spectatorbutton_zoom)
477                 {
478                         if(zoomdir)
479                                 zoomdir = 0;
480                         else
481                                 zoomdir = 1;
482                 }
483                 // fteqcc failed twice here already, don't optimize this
484         }
485
486         if(zoomdir) { zoomin_effect = 0; }
487
488         if(camera_active)
489         {
490                 current_viewzoom = min(1, current_viewzoom + drawframetime);
491         }
492         else if(autocvar_cl_spawnzoom && zoomin_effect)
493         {
494                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
495
496                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
497                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
498                 if(current_viewzoom == 1) { zoomin_effect = 0; }
499         }
500         else
501         {
502                 if(zoomspeed < 0) // instant zoom
503                 {
504                         if(zoomdir)
505                                 current_viewzoom = 1 / zoomfactor;
506                         else
507                                 current_viewzoom = 1;
508                 }
509                 else
510                 {
511                         if(zoomdir)
512                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
513                         else
514                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
515                 }
516         }
517
518         if(almost_equals(current_viewzoom, 1))
519                 current_zoomfraction = 0;
520         else if(almost_equals(current_viewzoom, 1/zoomfactor))
521                 current_zoomfraction = 1;
522         else
523                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
524
525         if(zoomsensitivity < 1)
526                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
527         else
528                 setsensitivityscale(1);
529
530         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
531         {
532                 if(intermission) { curspeed = 0; }
533                 else
534                 {
535
536                         makevectors(view_angles);
537                         v = pmove_vel;
538                         if(csqcplayer)
539                                 v = csqcplayer.velocity;
540
541                         switch(autocvar_cl_velocityzoom_type)
542                         {
543                                 case 3: curspeed = max(0, v_forward * v); break;
544                                 case 2: curspeed = (v_forward * v); break;
545                                 case 1: default: curspeed = vlen(v); break;
546                         }
547                 }
548
549                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
550                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
551                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
552
553                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
554         }
555         else
556                 velocityzoom = 1;
557
558         float frustumx, frustumy, fovx, fovy;
559         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
560         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
561         fovx = atan2(frustumx, 1) / M_PI * 360.0;
562         fovy = atan2(frustumy, 1) / M_PI * 360.0;
563
564         return '1 0 0' * fovx + '0 1 0' * fovy;
565 }
566
567 vector GetViewLocationFOV(float fov)
568 {
569         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
570         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
571         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
572         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
573         return '1 0 0' * fovx + '0 1 0' * fovy;
574 }
575
576 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
577 {
578         float fovx, fovy;
579         float width = (ov_worldmax.x - ov_worldmin.x);
580         float height = (ov_worldmax.y - ov_worldmin.y);
581         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
582         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
583         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
584         return '1 0 0' * fovx + '0 1 0' * fovy;
585 }
586
587 // this function must match W_SetupShot!
588 float zoomscript_caught;
589
590 vector wcross_origin;
591 float wcross_scale_prev, wcross_alpha_prev;
592 vector wcross_color_prev;
593 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
594 vector wcross_color_goal_prev;
595 float wcross_changedonetime;
596
597 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
598 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
599 float wcross_name_changestarttime, wcross_name_changedonetime;
600 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
601
602 float wcross_ring_prev;
603
604 entity trueaim;
605 entity trueaim_rifle;
606
607 const float SHOTTYPE_HITTEAM = 1;
608 const float SHOTTYPE_HITOBSTRUCTION = 2;
609 const float SHOTTYPE_HITWORLD = 3;
610 const float SHOTTYPE_HITENEMY = 4;
611
612 void TrueAim_Init()
613 {
614         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
615         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
616 }
617
618 float EnemyHitCheck()
619 {
620         float t, n;
621         wcross_origin = project_3d_to_2d(trace_endpos);
622         wcross_origin.z = 0;
623         if(trace_ent)
624                 n = trace_ent.entnum;
625         else
626                 n = trace_networkentity;
627         if(n < 1)
628                 return SHOTTYPE_HITWORLD;
629         if(n > maxclients)
630                 return SHOTTYPE_HITWORLD;
631         t = entcs_GetTeam(n - 1);
632         if(teamplay)
633                 if(t == myteam)
634                         return SHOTTYPE_HITTEAM;
635         if(t == NUM_SPECTATOR)
636                 return SHOTTYPE_HITWORLD;
637         return SHOTTYPE_HITENEMY;
638 }
639
640 float TrueAimCheck(entity wepent)
641 {
642         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
643         vector vecs, trueaimpoint, w_shotorg;
644         vector mi, ma, dv;
645         float shottype;
646         entity ta;
647         float mv;
648
649         mi = ma = '0 0 0';
650         ta = trueaim;
651         mv = MOVE_NOMONSTERS;
652
653         switch(wepent.activeweapon) // WEAPONTODO
654         {
655                 case WEP_TUBA: // no aim
656                 case WEP_PORTO: // shoots from eye
657                 case WEP_NEXBALL: // shoots from eye
658                 case WEP_HOOK: // no trueaim
659                 case WEP_MORTAR: // toss curve
660                         return SHOTTYPE_HITWORLD;
661                 case WEP_VORTEX:
662                 case WEP_OVERKILL_VORTEX:
663                 case WEP_VAPORIZER:
664                         mv = MOVE_NORMAL;
665                         break;
666                 case WEP_RIFLE:
667                         ta = trueaim_rifle;
668                         mv = MOVE_NORMAL;
669                         if(zoomscript_caught)
670                         {
671                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
672                                 return EnemyHitCheck();
673                         }
674                         break;
675                 case WEP_DEVASTATOR: // projectile has a size!
676                         mi = '-3 -3 -3';
677                         ma = '3 3 3';
678                         break;
679                 case WEP_FIREBALL: // projectile has a size!
680                         mi = '-16 -16 -16';
681                         ma = '16 16 16';
682                         break;
683                 case WEP_SEEKER: // projectile has a size!
684                         mi = '-2 -2 -2';
685                         ma = '2 2 2';
686                         break;
687                 case WEP_ELECTRO: // projectile has a size!
688                         mi = '0 0 -3';
689                         ma = '0 0 -3';
690                         break;
691         }
692
693         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
694
695         vecs = decompressShotOrigin(STAT(SHOTORG));
696
697         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
698         trueaimpoint = trace_endpos;
699
700         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
701                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
702
703         if(vecs.x > 0)
704                 vecs.y = -vecs.y;
705         else
706                 vecs = '0 0 0';
707
708         dv = view_right * vecs.y + view_up * vecs.z;
709         w_shotorg = traceorigin + dv;
710
711         // now move the vecs forward as much as requested if possible
712         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
713         w_shotorg = trace_endpos - view_forward * nudge;
714
715         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
716         shottype = EnemyHitCheck();
717         if(shottype != SHOTTYPE_HITWORLD)
718                 return shottype;
719
720 #if 0
721         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
722         // or rather, I know why, but see no fix
723         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
724                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
725                 return SHOTTYPE_HITOBSTRUCTION;
726 #endif
727
728         return SHOTTYPE_HITWORLD;
729 }
730
731 void PostInit();
732 void CSQC_Demo_Camera();
733 float camera_mode;
734 const float CAMERA_FREE = 1;
735 const float CAMERA_CHASE = 2;
736 float reticle_type;
737 string NextFrameCommand;
738
739 vector freeze_org, freeze_ang;
740 entity nightvision_noise, nightvision_noise2;
741
742 const float MAX_TIME_DIFF = 5;
743 float pickup_crosshair_time, pickup_crosshair_size;
744 float hitindication_crosshair_size;
745 float use_vortex_chargepool;
746
747 float myhealth, myhealth_prev;
748 float myhealth_flash;
749
750 float old_blurradius, old_bluralpha;
751 float old_sharpen_intensity;
752
753 vector myhealth_gentlergb;
754
755 float contentavgalpha, liquidalpha_prev;
756 vector liquidcolor_prev;
757
758 float eventchase_current_distance;
759 float eventchase_running;
760 bool WantEventchase(entity this)
761 {
762         if(autocvar_cl_orthoview)
763                 return false;
764         if(STAT(GAME_STOPPED) || intermission)
765                 return true;
766         if(this.viewloc)
767                 return true;
768         if(spectatee_status >= 0)
769         {
770                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
771                         return true;
772                 if(MUTATOR_CALLHOOK(WantEventchase, this))
773                         return true;
774                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
775                         return true;
776                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
777                 {
778                         if(autocvar_cl_eventchase_death == 2)
779                         {
780                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
781                                 if(this.velocity == '0 0 0' || eventchase_running)
782                                         return true;
783                         }
784                         else return true;
785                 }
786         }
787         return false;
788 }
789
790 void HUD_Crosshair_Vehicle(entity this)
791 {
792         if(hud != HUD_BUMBLEBEE_GUN)
793         {
794                 Vehicle info = Vehicles_from(hud);
795                 info.vr_crosshair(info, this);
796         }
797 }
798
799 vector damage_blurpostprocess, content_blurpostprocess;
800
801 float unaccounted_damage = 0;
802 void UpdateDamage()
803 {
804         // accumulate damage with each stat update
805         static float damage_total_prev = 0;
806         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
807         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
808         damage_total_prev = damage_total;
809
810         static float damage_dealt_time_prev = 0;
811         float damage_dealt_time = STAT(HIT_TIME);
812         if (damage_dealt_time != damage_dealt_time_prev)
813         {
814                 unaccounted_damage += unaccounted_damage_new;
815                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
816         }
817         damage_dealt_time_prev = damage_dealt_time;
818
819         // prevent hitsound when switching spectatee
820         static float spectatee_status_prev = 0;
821         if (spectatee_status != spectatee_status_prev)
822                 unaccounted_damage = 0;
823         spectatee_status_prev = spectatee_status;
824 }
825
826 void HitSound()
827 {
828         // varying sound pitch
829
830         bool have_arc = false;
831         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
832         {
833                 entity wepent = viewmodels[slot];
834
835                 if(wepent.activeweapon == WEP_ARC)
836                         have_arc = true;
837         }
838
839         static float hitsound_time_prev = 0;
840         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
841         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
842         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
843         {
844                 if (autocvar_cl_hitsound && unaccounted_damage)
845                 {
846                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
847                         float a = autocvar_cl_hitsound_max_pitch;
848                         float b = autocvar_cl_hitsound_min_pitch;
849                         float c = autocvar_cl_hitsound_nom_damage;
850                         float d = unaccounted_damage;
851                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
852
853                         // if sound variation is disabled, set pitch_shift to 1
854                         if (autocvar_cl_hitsound == 1)
855                                 pitch_shift = 1;
856
857                         // if pitch shift is reversed, mirror in (max-min)/2 + min
858                         if (autocvar_cl_hitsound == 3)
859                         {
860                                 float mirror_value = (a-b)/2 + b;
861                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
862                         }
863
864                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
865
866                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
867                         // todo: normalize sound pressure levels? seems unnecessary
868
869                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
870                 }
871                 unaccounted_damage = 0;
872                 hitsound_time_prev = time;
873         }
874
875         static float typehit_time_prev = 0;
876         float typehit_time = STAT(TYPEHIT_TIME);
877         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
878         {
879                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
880                 typehit_time_prev = typehit_time;
881         }
882
883         static float kill_time_prev = 0;
884         float kill_time = STAT(KILL_TIME);
885         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
886         {
887                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
888                 kill_time_prev = kill_time;
889         }
890 }
891
892 vector crosshair_getcolor(entity this, float health_stat)
893 {
894         static float rainbow_last_flicker;
895         static vector rainbow_prev_color;
896         vector wcross_color = '0 0 0';
897         switch(autocvar_crosshair_color_special)
898         {
899                 case 1: // crosshair_color_per_weapon
900                 {
901                         if(this != WEP_Null && hud == HUD_NORMAL)
902                         {
903                                 wcross_color = this.wpcolor;
904                                 break;
905                         }
906                         else { goto normalcolor; }
907                 }
908
909                 case 2: // crosshair_color_by_health
910                 {
911                         float hp = health_stat;
912
913                         //x = red
914                         //y = green
915                         //z = blue
916
917                         wcross_color.z = 0;
918
919                         if(hp > 200)
920                         {
921                                 wcross_color.x = 0;
922                                 wcross_color.y = 1;
923                         }
924                         else if(hp > 150)
925                         {
926                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
927                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
928                         }
929                         else if(hp > 100)
930                         {
931                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
932                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
933                                 wcross_color.z = 1 - (hp-100)*0.02;
934                         }
935                         else if(hp > 50)
936                         {
937                                 wcross_color.x = 1;
938                                 wcross_color.y = 1;
939                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
940                         }
941                         else if(hp > 20)
942                         {
943                                 wcross_color.x = 1;
944                                 wcross_color.y = (hp-20)*90/27/100;
945                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
946                         }
947                         else
948                         {
949                                 wcross_color.x = 1;
950                                 wcross_color.y = 0;
951                         }
952                         break;
953                 }
954
955                 case 3: // crosshair_color_rainbow
956                 {
957                         if(time >= rainbow_last_flicker)
958                         {
959                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
960                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
961                         }
962                         wcross_color = rainbow_prev_color;
963                         break;
964                 }
965 LABEL(normalcolor)
966                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
967         }
968
969         return wcross_color;
970 }
971
972 void HUD_Crosshair(entity this)
973 {
974         float f, i, j;
975         vector v;
976         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
977                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
978                 !HUD_MinigameMenu_IsOpened() )
979         {
980                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
981                         return;
982
983                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
984                         return;
985
986                 if (hud != HUD_NORMAL)
987                 {
988                         HUD_Crosshair_Vehicle(this);
989                         return;
990                 }
991
992                 string wcross_style;
993                 float wcross_alpha, wcross_resolution;
994                 wcross_style = autocvar_crosshair;
995                 if (wcross_style == "0")
996                         return;
997                 wcross_resolution = autocvar_crosshair_size;
998                 if (wcross_resolution == 0)
999                         return;
1000                 wcross_alpha = autocvar_crosshair_alpha;
1001                 if (wcross_alpha == 0)
1002                         return;
1003
1004                 // TrueAim check
1005                 float shottype;
1006
1007                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1008                 wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1009                 wcross_origin.z = 0;
1010                 if(autocvar_crosshair_hittest)
1011                 {
1012                         vector wcross_oldorigin;
1013                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1014                         wcross_oldorigin = wcross_origin;
1015                         shottype = TrueAimCheck(thiswep);
1016                         if(shottype == SHOTTYPE_HITWORLD)
1017                         {
1018                                 v = wcross_origin - wcross_oldorigin;
1019                                 v.x /= vid_conwidth;
1020                                 v.y /= vid_conheight;
1021                                 if(vdist(v, >, 0.01))
1022                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1023                         }
1024                         if(!autocvar_crosshair_hittest_showimpact)
1025                                 wcross_origin = wcross_oldorigin;
1026                 }
1027                 else
1028                         shottype = SHOTTYPE_HITWORLD;
1029
1030                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1031                 string wcross_name = "";
1032                 float wcross_scale, wcross_blur;
1033
1034         entity e = WEP_Null;
1035                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1036                 {
1037                         entity wepent = viewmodels[0]; // TODO: unhardcode
1038                         e = wepent.switchingweapon;
1039                         if(e)
1040                         {
1041                                 if(autocvar_crosshair_per_weapon)
1042                                 {
1043                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1044                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1045                                         //if (wcross_resolution == 0)
1046                                                 //return;
1047
1048                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1049                                         wcross_resolution *= e.w_crosshair_size;
1050                                         wcross_name = e.w_crosshair;
1051                                 }
1052                         }
1053                 }
1054
1055                 if(wcross_name == "")
1056                         wcross_name = strcat("gfx/crosshair", wcross_style);
1057
1058                 // MAIN CROSSHAIR COLOR DECISION
1059                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1060
1061                 if(autocvar_crosshair_effect_scalefade)
1062                 {
1063                         wcross_scale = wcross_resolution;
1064                         wcross_resolution = 1;
1065                 }
1066                 else
1067                 {
1068                         wcross_scale = 1;
1069                 }
1070
1071                 if(autocvar_crosshair_pickup)
1072                 {
1073                         float stat_pickup_time = STAT(LAST_PICKUP);
1074
1075                         if(pickup_crosshair_time < stat_pickup_time)
1076                         {
1077                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1078                                         pickup_crosshair_size = 1;
1079
1080                                 pickup_crosshair_time = stat_pickup_time;
1081                         }
1082
1083                         if(pickup_crosshair_size > 0)
1084                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1085                         else
1086                                 pickup_crosshair_size = 0;
1087
1088                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1089                 }
1090
1091                 // todo: make crosshair hit indication dependent on damage dealt
1092                 if(autocvar_crosshair_hitindication)
1093                 {
1094                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1095
1096                         if(unaccounted_damage)
1097                         {
1098                                 hitindication_crosshair_size = 1;
1099                         }
1100
1101                         if(hitindication_crosshair_size > 0)
1102                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1103                         else
1104                                 hitindication_crosshair_size = 0;
1105
1106                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1107                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1108                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1109                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1110                 }
1111
1112                 if(shottype == SHOTTYPE_HITENEMY)
1113                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1114                 if(shottype == SHOTTYPE_HITTEAM)
1115                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1116
1117                 f = fabs(autocvar_crosshair_effect_time);
1118                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1119                 {
1120                         wcross_changedonetime = time + f;
1121                 }
1122                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1123                 {
1124                         wcross_name_changestarttime = time;
1125                         wcross_name_changedonetime = time + f;
1126                         if(wcross_name_goal_prev_prev)
1127                                 strunzone(wcross_name_goal_prev_prev);
1128                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1129                         wcross_name_goal_prev = strzone(wcross_name);
1130                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1131                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1132                         wcross_resolution_goal_prev = wcross_resolution;
1133                 }
1134
1135                 wcross_scale_goal_prev = wcross_scale;
1136                 wcross_alpha_goal_prev = wcross_alpha;
1137                 wcross_color_goal_prev = wcross_color;
1138
1139                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1140                 {
1141                         wcross_blur = 1;
1142                         wcross_alpha *= 0.75;
1143                 }
1144                 else
1145                         wcross_blur = 0;
1146                 // *_prev is at time-frametime
1147                 // * is at wcross_changedonetime+f
1148                 // what do we have at time?
1149                 if(time < wcross_changedonetime)
1150                 {
1151                         f = frametime / (wcross_changedonetime - time + frametime);
1152                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1153                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1154                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1155                 }
1156
1157                 wcross_scale_prev = wcross_scale;
1158                 wcross_alpha_prev = wcross_alpha;
1159                 wcross_color_prev = wcross_color;
1160
1161                 MUTATOR_CALLHOOK(UpdateCrosshair);
1162
1163                 wcross_scale *= 1 - autocvar__menu_alpha;
1164                 wcross_alpha *= 1 - autocvar__menu_alpha;
1165                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1166
1167                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1168                 {
1169                         // crosshair rings for weapon stats
1170                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1171                         {
1172                                 // declarations and stats
1173                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1174                                 string ring_image = string_null, ring_inner_image = string_null;
1175                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1176
1177                                 ring_scale = autocvar_crosshair_ring_size;
1178
1179                                 float weapon_clipload, weapon_clipsize;
1180                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1181                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1182
1183                                 float vortex_charge, vortex_chargepool;
1184                                 vortex_charge = STAT(VORTEX_CHARGE);
1185                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1186
1187                                 float okvortex_charge, okvortex_chargepool;
1188                                 okvortex_charge = STAT(OVERKILL_VORTEX_CHARGE);
1189                                 okvortex_chargepool = STAT(OVERKILL_VORTEX_CHARGEPOOL);
1190
1191                                 float arc_heat = STAT(ARC_HEAT);
1192
1193                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1194                                         vortex_charge_movingavg = vortex_charge;
1195
1196                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1197
1198                                 // handle the values
1199                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1200                                 {
1201                                         if (vortex_chargepool || use_vortex_chargepool) {
1202                                                 use_vortex_chargepool = 1;
1203                                                 ring_inner_value = vortex_chargepool;
1204                                         } else {
1205                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1206                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1207                                         }
1208
1209                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1210                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1211                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1212
1213                                         // draw the outer ring to show the current charge of the weapon
1214                                         ring_value = vortex_charge;
1215                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1216                                         ring_rgb = wcross_color;
1217                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1218                                 }
1219                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_VORTEX) && okvortex_charge && autocvar_crosshair_ring_vortex)
1220                                 {
1221                                         if (okvortex_chargepool || use_vortex_chargepool) {
1222                                                 use_vortex_chargepool = 1;
1223                                                 ring_inner_value = okvortex_chargepool;
1224                                         } else {
1225                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * okvortex_charge;
1226                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (okvortex_charge - vortex_charge_movingavg), 1);
1227                                         }
1228
1229                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1230                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1231                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1232
1233                                         // draw the outer ring to show the current charge of the weapon
1234                                         ring_value = okvortex_charge;
1235                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1236                                         ring_rgb = wcross_color;
1237                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1238                                 }
1239                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1240                                 {
1241                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1242                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1243                                         ring_rgb = wcross_color;
1244                                         ring_image = "gfx/crosshair_ring.tga";
1245                                 }
1246                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1247                                 {
1248                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1249                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1250                                         ring_rgb = wcross_color;
1251                                         ring_image = "gfx/crosshair_ring.tga";
1252                                 }
1253                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1254                                 {
1255                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1256                                         ring_scale = autocvar_crosshair_ring_reload_size;
1257                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1258                                         ring_rgb = wcross_color;
1259
1260                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1261                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1262                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1263                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1264                                         else
1265                                                 ring_image = "gfx/crosshair_ring.tga";
1266                                 }
1267                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1268                                 {
1269                                         ring_value = arc_heat;
1270                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1271                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1272                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1273                                         ring_image = "gfx/crosshair_ring.tga";
1274                                 }
1275
1276                                 // if in weapon switch animation, fade ring out/in
1277                                 if(autocvar_crosshair_effect_time > 0)
1278                                 {
1279                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1280                                         if (f >= 1)
1281                                         {
1282                                                 wcross_ring_prev = ((ring_image) ? true : false);
1283                                         }
1284
1285                                         if(wcross_ring_prev)
1286                                         {
1287                                                 if(f < 1)
1288                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1289                                         }
1290                                         else
1291                                         {
1292                                                 if(f < 1)
1293                                                         ring_alpha *= bound(0, f, 1);
1294                                         }
1295                                 }
1296
1297                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1298                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1299
1300                                 if (ring_value)
1301                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1302                         }
1303
1304 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1305                         MACRO_BEGIN { \
1306                                 if(wcross_blur > 0) \
1307                                 { \
1308                                         for(i = -2; i <= 2; ++i) \
1309                                         for(j = -2; j <= 2; ++j) \
1310                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1311                                 } \
1312                                 else \
1313                                 { \
1314                                         M(0,0,sz,wcross_name,wcross_alpha); \
1315                                 } \
1316                         } MACRO_END
1317
1318 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1319                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1320
1321 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1322                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1323
1324                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1325                         {
1326                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1327                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1328                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1329                                 f = 1 - f;
1330                         }
1331                         else
1332                         {
1333                                 f = 1;
1334                         }
1335                         wcross_name_alpha_goal_prev = f;
1336
1337                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1338                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1339
1340                         if(autocvar_crosshair_dot)
1341                         {
1342                                 vector wcross_color_old;
1343                                 wcross_color_old = wcross_color;
1344
1345                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1346                                         wcross_color = stov(autocvar_crosshair_dot_color);
1347
1348                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1349                                 // FIXME why don't we use wcross_alpha here?
1350                                 wcross_color = wcross_color_old;
1351                         }
1352                 }
1353         }
1354         else
1355         {
1356                 wcross_scale_prev = 0;
1357                 wcross_alpha_prev = 0;
1358                 wcross_scale_goal_prev = 0;
1359                 wcross_alpha_goal_prev = 0;
1360                 wcross_changedonetime = 0;
1361                 if(wcross_name_goal_prev)
1362                         strunzone(wcross_name_goal_prev);
1363                 wcross_name_goal_prev = string_null;
1364                 if(wcross_name_goal_prev_prev)
1365                         strunzone(wcross_name_goal_prev_prev);
1366                 wcross_name_goal_prev_prev = string_null;
1367                 wcross_name_changestarttime = 0;
1368                 wcross_name_changedonetime = 0;
1369                 wcross_name_alpha_goal_prev = 0;
1370                 wcross_name_alpha_goal_prev_prev = 0;
1371                 wcross_resolution_goal_prev = 0;
1372                 wcross_resolution_goal_prev_prev = 0;
1373         }
1374 }
1375
1376 void HUD_Draw(entity this)
1377 {
1378         // if we don't know gametype and scores yet avoid drawing the scoreboard
1379         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1380         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1381         // cl_deathscoreboard would show the scoreboard and so on
1382         if(!gametype)
1383                 return;
1384
1385         Hud_Dynamic_Frame();
1386
1387         if(!intermission)
1388         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1389         {
1390                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1391         }
1392         else if(STAT(FROZEN))
1393         {
1394                 vector col = '0.25 0.90 1';
1395                 if(STAT(REVIVE_PROGRESS))
1396                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1397                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1398         }
1399
1400         HUD_Scale_Enable();
1401         if(!intermission)
1402         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1403         {
1404                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1405                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1406                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1407         }
1408         else if(STAT(CAPTURE_PROGRESS))
1409         {
1410                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1411                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1412         }
1413         else if(STAT(REVIVE_PROGRESS))
1414         {
1415                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1416                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1417         }
1418         HUD_Scale_Disable();
1419
1420         if(autocvar_r_letterbox == 0)
1421                 if(autocvar_viewsize < 120)
1422                 {
1423                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1424                                 Accuracy_LoadLevels();
1425
1426                         HUD_Main();
1427                         HUD_Scale_Disable();
1428                 }
1429
1430         // crosshair goes VERY LAST
1431         UpdateDamage();
1432         HUD_Crosshair(this);
1433         HitSound();
1434 }
1435
1436 bool ov_enabled;
1437 float oldr_nearclip;
1438 float oldr_farclip_base;
1439 float oldr_farclip_world;
1440 float oldr_novis;
1441 float oldr_useportalculling;
1442 float oldr_useinfinitefarclip;
1443
1444 void cl_notice_run();
1445
1446 float prev_myteam;
1447 int lasthud;
1448 float vh_notice_time;
1449 void WaypointSprite_Load();
1450 void CSQC_UpdateView(entity this, float w, float h)
1451 {
1452     TC(int, w); TC(int, h);
1453         entity e;
1454         float fov;
1455         float f;
1456         vector vf_size, vf_min;
1457         float a;
1458
1459         execute_next_frame();
1460
1461         ++framecount;
1462
1463         stats_get();
1464         hud = STAT(HUD);
1465
1466         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1467                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1468
1469         lasthud = hud;
1470
1471         HUD_Scale_Disable();
1472
1473         if(autocvar__hud_showbinds_reload) // menu can set this one
1474         {
1475                 db_close(binddb);
1476                 binddb = db_create();
1477                 cvar_set("_hud_showbinds_reload", "0");
1478         }
1479
1480         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1481                 view_quality = getproperty(VF_MINFPS_QUALITY);
1482         else
1483                 view_quality = 1;
1484
1485         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1486         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1487
1488         vf_size = getpropertyvec(VF_SIZE);
1489         vf_min = getpropertyvec(VF_MIN);
1490         vid_width = vf_size.x;
1491         vid_height = vf_size.y;
1492
1493         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1494         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1495
1496         WaypointSprite_Load();
1497
1498         CSQCPlayer_SetCamera();
1499
1500         if(player_localentnum <= maxclients) // is it a client?
1501                 current_player = player_localentnum - 1;
1502         else // then player_localentnum is the vehicle I'm driving
1503                 current_player = player_localnum;
1504         myteam = entcs_GetTeam(current_player);
1505
1506         if(myteam != prev_myteam)
1507         {
1508                 myteamcolors = colormapPaletteColor(myteam, 1);
1509                 FOREACH(hud_panels, true, it.update_time = time);
1510                 prev_myteam = myteam;
1511         }
1512
1513         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1514
1515         float is_dead = (STAT(HEALTH) <= 0);
1516
1517         // FIXME do we need this hack?
1518         if(isdemo())
1519         {
1520                 // in demos, input_buttons do not work
1521                 button_zoom = (autocvar__togglezoom == "-");
1522         }
1523         else if(button_zoom
1524                 && autocvar_cl_unpress_zoom_on_death
1525                 && (spectatee_status >= 0)
1526                 && (is_dead || intermission))
1527         {
1528                 // no zoom while dead or in intermission please
1529                 localcmd("-zoom\n");
1530                 button_zoom = false;
1531         }
1532
1533         // event chase camera
1534         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1535         {
1536                 if(STAT(CAMERA_SPECTATOR))
1537                 {
1538                         if(spectatee_status > 0)
1539                         {
1540                                 if(!autocvar_chase_active)
1541                                 {
1542                                         cvar_set("chase_active", "-2");
1543                                         goto skip_eventchase_death;
1544                                 }
1545                         }
1546                         else if(autocvar_chase_active == -2)
1547                                 cvar_set("chase_active", "0");
1548
1549                         if(autocvar_chase_active == -2)
1550                                 goto skip_eventchase_death;
1551                 }
1552                 else if(autocvar_chase_active == -2)
1553                         cvar_set("chase_active", "0");
1554
1555                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1556
1557                 float vehicle_viewdist = 0;
1558                 vector vehicle_viewofs = '0 0 0';
1559
1560                 if(vehicle_chase)
1561                 {
1562                         if(hud != HUD_BUMBLEBEE_GUN)
1563                         {
1564                                 Vehicle info = Vehicles_from(hud);
1565                                 vehicle_viewdist = info.height;
1566                                 vehicle_viewofs = info.view_ofs;
1567                         }
1568                 }
1569
1570                 if(WantEventchase(this))
1571                 {
1572                         vector current_view_origin_override = '0 0 0';
1573                         vector view_offset_override = '0 0 0';
1574                         float chase_distance_override = 0;
1575                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1576                         if(custom_eventchase)
1577                         {
1578                                 current_view_origin_override = M_ARGV(0, vector);
1579                                 view_offset_override = M_ARGV(1, vector);
1580                                 chase_distance_override = M_ARGV(0, float);
1581                         }
1582                         eventchase_running = true;
1583
1584                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1585                         if(!local_player)
1586                                 local_player = this; // fall back!
1587
1588                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1589                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1590                         if (custom_eventchase)
1591                                 current_view_origin = current_view_origin_override;
1592
1593                         // detect maximum viewoffset and use it
1594                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1595                         if(vehicle_chase)
1596                         {
1597                                 if(vehicle_viewofs)
1598                                         view_offset = vehicle_viewofs;
1599                                 else
1600                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1601                         }
1602                         if (custom_eventchase)
1603                                 view_offset = view_offset_override;
1604
1605                         if(view_offset)
1606                         {
1607                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1608                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1609                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1610                         }
1611
1612                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1613                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1614                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1615                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1616
1617                         // make the camera smooth back
1618                         float chase_distance = autocvar_cl_eventchase_distance;
1619                         if(vehicle_chase)
1620                         {
1621                                 if(vehicle_viewofs)
1622                                         chase_distance = vehicle_viewdist;
1623                                 else
1624                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1625                         }
1626                         if (custom_eventchase)
1627                                 chase_distance = chase_distance_override;
1628
1629                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1630                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1631                         else if(eventchase_current_distance != chase_distance)
1632                                 eventchase_current_distance = chase_distance;
1633
1634                         makevectors(view_angles);
1635
1636                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1637                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1638
1639                         // If the boxtrace fails, revert back to line tracing.
1640                         if(!local_player.viewloc)
1641                         if(trace_startsolid)
1642                         {
1643                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1644                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1645                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1646                         }
1647                         else { setproperty(VF_ORIGIN, trace_endpos); }
1648
1649                         if(!local_player.viewloc)
1650                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1651                 }
1652                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1653                 {
1654                         eventchase_running = false;
1655                         cvar_set("chase_active", "0");
1656                         eventchase_current_distance = 0; // start from 0 next time
1657                 }
1658         }
1659         // workaround for camera stuck between player's legs when using chase_active 1
1660         // because the engine stops updating the chase_active camera when the game ends
1661         else if(intermission)
1662         {
1663                 cvar_settemp("chase_active", "-1");
1664                 eventchase_current_distance = 0;
1665         }
1666
1667         LABEL(skip_eventchase_death);
1668
1669         // do lockview after event chase camera so that it still applies whenever necessary.
1670         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1671         {
1672                 setproperty(VF_ORIGIN, freeze_org);
1673                 setproperty(VF_ANGLES, freeze_ang);
1674         }
1675         else
1676         {
1677                 freeze_org = getpropertyvec(VF_ORIGIN);
1678                 freeze_ang = getpropertyvec(VF_ANGLES);
1679         }
1680
1681         WarpZone_FixView();
1682         //WarpZone_FixPMove();
1683
1684         vector ov_org = '0 0 0';
1685         vector ov_mid = '0 0 0';
1686         vector ov_worldmin = '0 0 0';
1687         vector ov_worldmax = '0 0 0';
1688         if(autocvar_cl_orthoview)
1689         {
1690                 ov_worldmin = mi_picmin;
1691                 ov_worldmax = mi_picmax;
1692
1693                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1694                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1695                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1696
1697                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1698                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1699
1700                 float ov_nearest = vlen(ov_org - vec3(
1701                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1702                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1703                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1704                 ));
1705
1706                 float ov_furthest = 0;
1707                 float dist = 0;
1708
1709                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1710                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1711                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1712                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1713                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1714                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1715                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1716                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1717
1718                 if(!ov_enabled)
1719                 {
1720                         oldr_nearclip = cvar("r_nearclip");
1721                         oldr_farclip_base = cvar("r_farclip_base");
1722                         oldr_farclip_world = cvar("r_farclip_world");
1723                         oldr_novis = cvar("r_novis");
1724                         oldr_useportalculling = cvar("r_useportalculling");
1725                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1726                 }
1727
1728                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1729                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1730                 cvar_settemp("r_farclip_world", "0");
1731                 cvar_settemp("r_novis", "1");
1732                 cvar_settemp("r_useportalculling", "0");
1733                 cvar_settemp("r_useinfinitefarclip", "0");
1734
1735                 setproperty(VF_ORIGIN, ov_org);
1736                 setproperty(VF_ANGLES, '90 0 0');
1737
1738                 ov_enabled = true;
1739
1740                 #if 0
1741                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1742                         vtos(ov_org),
1743                         vtos(getpropertyvec(VF_ANGLES)),
1744                         ov_distance,
1745                         ov_nearest,
1746                         ov_furthest);
1747                 #endif
1748         }
1749         else
1750         {
1751                 if(ov_enabled)
1752                 {
1753                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1754                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1755                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1756                         cvar_set("r_novis", ftos(oldr_novis));
1757                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1758                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1759                 }
1760                 ov_enabled = false;
1761         }
1762
1763         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1764         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1765         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1766                 viewmodel_draw(viewmodels[slot]);
1767
1768         // Render the Scene
1769         view_origin = getpropertyvec(VF_ORIGIN);
1770         view_angles = getpropertyvec(VF_ANGLES);
1771         makevectors(view_angles);
1772         view_forward = v_forward;
1773         view_right = v_right;
1774         view_up = v_up;
1775
1776 #ifdef BLURTEST
1777         if(time > blurtest_time0 && time < blurtest_time1)
1778         {
1779                 float r, t;
1780
1781                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1782                 r = t * blurtest_radius;
1783                 f = 1 / (t ** blurtest_power) - 1;
1784
1785                 cvar_set("r_glsl_postprocess", "1");
1786                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1787         }
1788         else
1789         {
1790                 cvar_set("r_glsl_postprocess", "0");
1791                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1792         }
1793 #endif
1794
1795         TargetMusic_Advance();
1796         Fog_Force();
1797
1798         if(drawtime == 0)
1799                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1800         else
1801                 drawframetime = bound(0.000001, time - drawtime, 1);
1802         drawtime = time;
1803
1804         // watch for gametype changes here...
1805         // in ParseStuffCMD the cmd isn't executed yet :/
1806         // might even be better to add the gametype to TE_CSQC_INIT...?
1807         if(!postinit)
1808                 PostInit();
1809
1810         if(intermission && !intermission_time)
1811                 intermission_time = time;
1812
1813         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1814         {
1815                 if(calledhooks & HOOK_START)
1816                 {
1817                         localcmd("\ncl_hook_gameend\n");
1818                         calledhooks |= HOOK_END;
1819                 }
1820         }
1821
1822         Announcer();
1823
1824         fov = autocvar_fov;
1825         if(fov <= 59.5)
1826         {
1827                 if(!zoomscript_caught)
1828                 {
1829                         localcmd("+button9\n");
1830                         zoomscript_caught = 1;
1831                 }
1832         }
1833         else
1834         {
1835                 if(zoomscript_caught)
1836                 {
1837                         localcmd("-button9\n");
1838                         zoomscript_caught = 0;
1839                 }
1840         }
1841
1842         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1843
1844         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1845         {
1846                 entity wepent = viewmodels[slot];
1847
1848                 if(wepent.last_switchweapon != wepent.switchweapon)
1849                 {
1850                         weapontime = time;
1851                         wepent.last_switchweapon = wepent.switchweapon;
1852                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1853                         {
1854                                 localcmd("-zoom\n");
1855                                 button_zoom = false;
1856                         }
1857                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1858                         {
1859                                 localcmd("-fire\n");
1860                                 localcmd("-fire2\n");
1861                                 button_attack2 = false;
1862                         }
1863                 }
1864                 if(wepent.last_activeweapon != wepent.activeweapon)
1865                 {
1866                         wepent.last_activeweapon = wepent.activeweapon;
1867
1868                         e = wepent.activeweapon;
1869                         if(e.netname != "")
1870                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1871                         else if(slot == 0)
1872                                 localcmd("\ncl_hook_activeweapon none\n");
1873                 }
1874         }
1875
1876         // ALWAYS Clear Current Scene First
1877         clearscene();
1878
1879         setproperty(VF_ORIGIN, view_origin);
1880         setproperty(VF_ANGLES, view_angles);
1881
1882         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1883         setproperty(VF_SIZE, vf_size);
1884         setproperty(VF_MIN, vf_min);
1885
1886         // Assign Standard Viewflags
1887         // Draw the World (and sky)
1888         setproperty(VF_DRAWWORLD, 1);
1889
1890         // Set the console size vars
1891         vid_conwidth = autocvar_vid_conwidth;
1892         vid_conheight = autocvar_vid_conheight;
1893         vid_pixelheight = autocvar_vid_pixelheight;
1894
1895         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1896         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1897         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1898
1899         if(camera_active) // Camera for demo playback
1900         {
1901                 if(autocvar_camera_enable)
1902                         CSQC_Demo_Camera();
1903                 else
1904                 {
1905                         cvar_set("chase_active", ftos(chase_active_backup));
1906                         cvar_set("cl_demo_mousegrab", "0");
1907                         camera_active = false;
1908                 }
1909         }
1910         else
1911         {
1912 #ifdef CAMERATEST
1913                 if(autocvar_camera_enable)
1914 #else
1915                 if(autocvar_camera_enable && isdemo())
1916 #endif
1917                 {
1918                         // Enable required Darkplaces cvars
1919                         chase_active_backup = autocvar_chase_active;
1920                         cvar_set("chase_active", "2");
1921                         cvar_set("cl_demo_mousegrab", "1");
1922                         camera_active = true;
1923                         camera_mode = false;
1924                 }
1925         }
1926
1927         // Draw the Crosshair
1928         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1929
1930         // Draw the Engine Status Bar (the default Quake HUD)
1931         setproperty(VF_DRAWENGINESBAR, 0);
1932
1933         // Update the mouse position
1934         /*
1935            mousepos_x = vid_conwidth;
1936            mousepos_y = vid_conheight;
1937            mousepos = mousepos*0.5 + getmousepos();
1938          */
1939
1940         IL_EACH(g_drawables, it.draw, it.draw(it));
1941
1942         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1943         renderscene();
1944
1945         // now switch to 2D drawing mode by calling a 2D drawing function
1946         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1947         // next R_RenderScene call
1948         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1949
1950         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1951         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1952         {
1953                 // apply night vision effect
1954                 vector tc_00, tc_01, tc_10, tc_11;
1955                 vector rgb = '0 0 0';
1956
1957                 if(!nightvision_noise)
1958                 {
1959                         nightvision_noise = new(nightvision_noise);
1960                 }
1961                 if(!nightvision_noise2)
1962                 {
1963                         nightvision_noise2 = new(nightvision_noise2);
1964                 }
1965
1966                 // color tint in yellow
1967                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1968
1969                 // draw BG
1970                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1971                 rgb = '1 1 1';
1972                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1973                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1974                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1975                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1976                 tc_11 = tc_01 + tc_10 - tc_00;
1977                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1978                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1979                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1980                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1981                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1982                 R_EndPolygon();
1983
1984                 // draw FG
1985                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1986                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1987                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1988                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1989                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1990                 tc_11 = tc_01 + tc_10 - tc_00;
1991                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1992                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1993                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1994                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1995                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1996                 R_EndPolygon();
1997         }
1998
1999         if(autocvar_cl_reticle)
2000         {
2001                 string reticle_image = string_null;
2002                 bool wep_zoomed = false;
2003                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2004                 {
2005                         entity wepe = viewmodels[slot];
2006                         Weapon wep = wepe.activeweapon;
2007                         if(wep != WEP_Null && wep.wr_zoom)
2008                         {
2009                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2010                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2011                                         reticle_image = wep.w_reticle;
2012                                 wep_zoomed += do_zoom;
2013                         }
2014                 }
2015                 // Draw the aiming reticle for weapons that use it
2016                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2017                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2018                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2019                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
2020                 {
2021                         // no zoom reticle while dead
2022                         reticle_type = 0;
2023                 }
2024                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2025                 {
2026                         if(reticle_image) { reticle_type = 2; }
2027                         else { reticle_type = 0; }
2028                 }
2029                 else if(button_zoom || zoomscript_caught)
2030                 {
2031                         // normal zoom
2032                         reticle_type = 1;
2033                 }
2034
2035                 if(reticle_type)
2036                 {
2037                         if(autocvar_cl_reticle_stretch)
2038                         {
2039                                 reticle_size.x = vid_conwidth;
2040                                 reticle_size.y = vid_conheight;
2041                                 reticle_pos.x = 0;
2042                                 reticle_pos.y = 0;
2043                         }
2044                         else
2045                         {
2046                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2047                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2048                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2049                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2050                         }
2051
2052                         if(zoomscript_caught)
2053                                 f = 1;
2054                         else
2055                                 f = current_zoomfraction;
2056
2057                         if(f)
2058                         {
2059                                 switch(reticle_type)
2060                                 {
2061                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2062                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2063                                 }
2064                         }
2065                 }
2066         }
2067         else
2068         {
2069                 if(reticle_type != 0) { reticle_type = 0; }
2070         }
2071
2072
2073         // improved polyblend
2074         if(autocvar_hud_contents)
2075         {
2076                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2077                 vector liquidcolor;
2078
2079                 switch(pointcontents(view_origin))
2080                 {
2081                         case CONTENT_WATER:
2082                                 liquidalpha = autocvar_hud_contents_water_alpha;
2083                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2084                                 incontent = 1;
2085                                 break;
2086
2087                         case CONTENT_LAVA:
2088                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2089                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2090                                 incontent = 1;
2091                                 break;
2092
2093                         case CONTENT_SLIME:
2094                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2095                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2096                                 incontent = 1;
2097                                 break;
2098
2099                         default:
2100                                 liquidalpha = 0;
2101                                 liquidcolor = '0 0 0';
2102                                 incontent = 0;
2103                                 break;
2104                 }
2105
2106                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2107                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2108                         contentfadetime = autocvar_hud_contents_fadeintime;
2109                         liquidalpha_prev = liquidalpha;
2110                         liquidcolor_prev = liquidcolor;
2111                 }
2112                 else
2113                         contentfadetime = autocvar_hud_contents_fadeouttime;
2114
2115                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2116                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2117
2118                 if(contentavgalpha)
2119                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2120
2121                 if(autocvar_hud_postprocessing)
2122                 {
2123                         if(autocvar_hud_contents_blur && contentavgalpha)
2124                         {
2125                                 content_blurpostprocess.x = 1;
2126                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2127                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2128                         }
2129                         else
2130                         {
2131                                 content_blurpostprocess.x = 0;
2132                                 content_blurpostprocess.y = 0;
2133                                 content_blurpostprocess.z = 0;
2134                         }
2135                 }
2136         }
2137
2138         if(autocvar_hud_damage && !STAT(FROZEN))
2139         {
2140                 splash_size.x = max(vid_conwidth, vid_conheight);
2141                 splash_size.y = max(vid_conwidth, vid_conheight);
2142                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2143                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2144
2145                 float myhealth_flash_temp;
2146                 myhealth = STAT(HEALTH);
2147
2148                 // fade out
2149                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2150                 // add new damage
2151                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2152
2153                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2154                 pain_threshold = autocvar_hud_damage_pain_threshold;
2155                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2156                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2157
2158                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2159                 {
2160                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2161                 }
2162
2163                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2164
2165                 if(myhealth_prev < 1)
2166                 {
2167                         if(myhealth >= 1)
2168                         {
2169                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2170                                 myhealth_flash_temp = 0;
2171                         }
2172                         else
2173                         {
2174                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2175                         }
2176                 }
2177
2178                 if(spectatee_status == -1 || intermission)
2179                 {
2180                         myhealth_flash = 0; // observing, or match ended
2181                         myhealth_flash_temp = 0;
2182                 }
2183
2184                 myhealth_prev = myhealth;
2185
2186                 // IDEA: change damage color/picture based on player model for robot/alien species?
2187                 // pro: matches model better
2188                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2189                 // maybe different reddish pics?
2190                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2191                 {
2192                         if(autocvar_cl_gentle_damage == 2)
2193                         {
2194                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2195                                         myhealth_gentlergb = randomvec();
2196                         }
2197                         else
2198                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2199
2200                         if(myhealth_flash_temp > 0)
2201                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2202                 }
2203                 else if(myhealth_flash_temp > 0)
2204                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2205
2206                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2207                 {
2208                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2209                         {
2210                                 damage_blurpostprocess.x = 1;
2211                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2212                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2213                         }
2214                         else
2215                         {
2216                                 damage_blurpostprocess.x = 0;
2217                                 damage_blurpostprocess.y = 0;
2218                                 damage_blurpostprocess.z = 0;
2219                         }
2220                 }
2221         }
2222
2223         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2224         float e2 = (autocvar_hud_powerup != 0);
2225         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2226         {
2227                 // enable or disable rendering types if they are used or not
2228                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2229                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2230
2231                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2232                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2233                 {
2234                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2235                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2236                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2237                         {
2238                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2239                                 old_blurradius = blurradius;
2240                                 old_bluralpha = bluralpha;
2241                         }
2242                 }
2243                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2244                 {
2245                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2246                         old_blurradius = 0;
2247                         old_bluralpha = 0;
2248                 }
2249
2250                 // edge detection postprocess handling done second (used by hud_powerup)
2251                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2252                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2253                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2254
2255                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2256
2257                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2258                 {
2259                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2260                         {
2261                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2262                                 old_sharpen_intensity = sharpen_intensity;
2263                         }
2264                 }
2265                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2266                 {
2267                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2268                         old_sharpen_intensity = 0;
2269                 }
2270
2271                 if(cvar("r_glsl_postprocess") == 0)
2272                         cvar_set("r_glsl_postprocess", "2");
2273         }
2274         else if(cvar("r_glsl_postprocess") == 2)
2275                 cvar_set("r_glsl_postprocess", "0");
2276
2277         /*if(gametype == MAPINFO_TYPE_CTF)
2278           {
2279           ctf_view();
2280           } else */
2281
2282         // draw 2D entities
2283         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2284         Draw_ShowNames_All();
2285 #ifdef DEBUGDRAW
2286         Debug_Draw();
2287 #endif
2288
2289         scoreboard_active = Scoreboard_WouldDraw();
2290
2291         HUD_Draw(this); // this parameter for deep vehicle function
2292
2293         if(NextFrameCommand)
2294         {
2295                 localcmd("\n", NextFrameCommand, "\n");
2296                 NextFrameCommand = string_null;
2297         }
2298
2299         // we must do this check AFTER a frame was rendered, or it won't work
2300         if(cs_project_is_b0rked == 0)
2301         {
2302                 string w0, h0;
2303                 w0 = ftos(autocvar_vid_conwidth);
2304                 h0 = ftos(autocvar_vid_conheight);
2305                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2306                 //setproperty(VF_FOV, '90 90 0');
2307                 setproperty(VF_ORIGIN, '0 0 0');
2308                 setproperty(VF_ANGLES, '0 0 0');
2309                 setproperty(VF_PERSPECTIVE, 1);
2310                 makevectors('0 0 0');
2311                 vector v1, v2;
2312                 cvar_set("vid_conwidth", "800");
2313                 cvar_set("vid_conheight", "600");
2314                 v1 = cs_project(v_forward);
2315                 cvar_set("vid_conwidth", "640");
2316                 cvar_set("vid_conheight", "480");
2317                 v2 = cs_project(v_forward);
2318                 if(v1 == v2)
2319                         cs_project_is_b0rked = 1;
2320                 else
2321                         cs_project_is_b0rked = -1;
2322                 cvar_set("vid_conwidth", w0);
2323                 cvar_set("vid_conheight", h0);
2324         }
2325
2326         if(autocvar__hud_configure)
2327                 HUD_Panel_Mouse();
2328         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2329                 HUD_Minigame_Mouse();
2330         else if(QuickMenu_IsOpened())
2331                 QuickMenu_Mouse();
2332         else
2333                 HUD_Radar_Mouse();
2334
2335         cl_notice_run();
2336         unpause_update();
2337         Net_Flush();
2338
2339         // let's reset the view back to normal for the end
2340         setproperty(VF_MIN, '0 0 0');
2341         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2342
2343         IL_ENDFRAME();
2344 }
2345
2346
2347 // following vectors must be global to allow seamless switching between camera modes
2348 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2349 void CSQC_Demo_Camera()
2350 {
2351         float speed, attenuation, dimensions;
2352         vector tmp, delta;
2353
2354         if( autocvar_camera_reset || !camera_mode )
2355         {
2356                 camera_offset = '0 0 0';
2357                 current_angles = '0 0 0';
2358                 camera_direction = '0 0 0';
2359                 camera_offset.z += 30;
2360                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2361                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2362                 current_origin = view_origin;
2363                 current_camera_offset  = camera_offset;
2364                 cvar_set("camera_reset", "0");
2365                 camera_mode = CAMERA_CHASE;
2366         }
2367
2368         // Camera angles
2369         if( camera_roll )
2370                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2371
2372         if(autocvar_camera_look_player)
2373         {
2374                 vector dir;
2375                 float n;
2376
2377                 dir = normalize(view_origin - current_position);
2378                 n = mouse_angles.z;
2379                 mouse_angles = vectoangles(dir);
2380                 mouse_angles.x = mouse_angles.x * -1;
2381                 mouse_angles.z = n;
2382         }
2383         else
2384         {
2385                 tmp = getmousepos() * 0.1;
2386                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2387                 {
2388                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2389                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2390                 }
2391         }
2392
2393         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2394         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2395         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2396         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2397
2398         // Fix difference when angles don't have the same sign
2399         delta = '0 0 0';
2400         if(mouse_angles.y < -60 && current_angles.y > 60)
2401                 delta = '0 360 0';
2402         if(mouse_angles.y > 60 && current_angles.y < -60)
2403                 delta = '0 -360 0';
2404
2405         if(autocvar_camera_look_player)
2406                 attenuation = autocvar_camera_look_attenuation;
2407         else
2408                 attenuation = autocvar_camera_speed_attenuation;
2409
2410         attenuation = 1 / max(1, attenuation);
2411         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2412
2413         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2414         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2415         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2416         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2417
2418         // Camera position
2419         tmp = '0 0 0';
2420         dimensions = 0;
2421
2422         if( camera_direction.x )
2423         {
2424                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2425                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2426                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2427                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2428                 ++dimensions;
2429         }
2430
2431         if( camera_direction.y )
2432         {
2433                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2434                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2435                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2436                 ++dimensions;
2437         }
2438
2439         if( camera_direction.z )
2440         {
2441                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2442                 ++dimensions;
2443         }
2444
2445         if(autocvar_camera_free)
2446                 speed = autocvar_camera_speed_free;
2447         else
2448                 speed = autocvar_camera_speed_chase;
2449
2450         if(dimensions)
2451         {
2452                 speed = speed * sqrt(1 / dimensions);
2453                 camera_offset += tmp * speed;
2454         }
2455
2456         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2457
2458         // Camera modes
2459         if( autocvar_camera_free )
2460         {
2461                 if ( camera_mode == CAMERA_CHASE )
2462                 {
2463                         current_camera_offset = current_origin + current_camera_offset;
2464                         camera_offset = current_origin + camera_offset;
2465                 }
2466
2467                 camera_mode = CAMERA_FREE;
2468                 current_position = current_camera_offset;
2469         }
2470         else
2471         {
2472                 if ( camera_mode == CAMERA_FREE )
2473                 {
2474                         current_origin = view_origin;
2475                         camera_offset = camera_offset - current_origin;
2476                         current_camera_offset = current_camera_offset - current_origin;
2477                 }
2478
2479                 camera_mode = CAMERA_CHASE;
2480
2481                 if(autocvar_camera_chase_smoothly)
2482                         current_origin += (view_origin - current_origin) * attenuation;
2483                 else
2484                         current_origin = view_origin;
2485
2486                 current_position = current_origin + current_camera_offset;
2487         }
2488
2489         setproperty(VF_ANGLES, current_angles);
2490         setproperty(VF_ORIGIN, current_position);
2491 }