qcsrc/client/view.qc

   1 #include "_all.qh"
   2
   3 #include "announcer.qh"
   4 #include "hook.qh"
   5 #include "hud.qh"
   6 #include "hud_config.qh"
   7 #include "mapvoting.qh"
   8 #include "scoreboard.qh"
   9 #include "shownames.qh"
  10
  11 #include "mutators/events.qh"
  12
  13 #include "../common/constants.qh"
  14 #include "../common/mapinfo.qh"
  15 #include "../common/nades.qh"
  16 #include "../common/stats.qh"
  17 #include "../common/triggers/target/music.qh"
  18 #include "../common/teams.qh"
  19 #include "../common/util.qh"
  20
  21 #include "../common/weapons/all.qh"
  22
  23 #include "../csqcmodellib/cl_player.qh"
  24
  25 #include "../warpzonelib/client.qh"
  26 #include "../warpzonelib/common.qh"
  27
  28 entity porto;
  29 vector polyline[16];
  30 void Porto_Draw()
  31 {
  32         vector p, dir, ang, q, nextdir;
  33         float portal_number, portal1_idx;
  34
  35         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  36                 return;
  37         if(g_balance_porto_secondary)
  38                 return;
  39         if(intermission == 1)
  40                 return;
  41         if(intermission == 2)
  42                 return;
  43         if (getstati(STAT_HEALTH) <= 0)
  44                 return;
  45
  46         dir = view_forward;
  47
  48         if(angles_held_status)
  49         {
  50                 makevectors(angles_held);
  51                 dir = v_forward;
  52         }
  53
  54         p = view_origin;
  55
  56         polyline[0] = p;
  57         int idx = 1;
  58         portal_number = 0;
  59         nextdir = dir;
  60
  61         for (;;)
  62         {
  63                 dir = nextdir;
  64                 traceline(p, p + 65536 * dir, true, porto);
  65                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  66                         return;
  67                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  68                 p = trace_endpos;
  69                 polyline[idx] = p;
  70                 ++idx;
  71                 if(idx >= 16)
  72                         return;
  73                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  74                         continue;
  75                 ++portal_number;
  76                 ang = vectoangles2(trace_plane_normal, dir);
  77                 ang.x = -ang.x;
  78                 makevectors(ang);
  79                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  80                         return;
  81                 if(portal_number == 1)
  82                 {
  83                         portal1_idx = idx;
  84                         if(portal_number >= 2)
  85                                 break;
  86                 }
  87         }
  88
  89         while(idx >= 2)
  90         {
  91                 p = polyline[idx-2];
  92                 q = polyline[idx-1];
  93                 if(idx == 2)
  94                         p = p - view_up * 16;
  95                 if(idx-1 >= portal1_idx)
  96                 {
  97                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  98                 }
  99                 else
 100                 {
 101                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 102                 }
 103                 --idx;
 104         }
 105 }
 106
 107 void Porto_Init()
 108 {
 109         porto = spawn();
 110         porto.classname = "porto";
 111         porto.draw = Porto_Draw;
 112         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 113 }
 114
 115 float drawtime;
 116 float avgspeed;
 117 vector GetCurrentFov(float fov)
 118 {
 119         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 120         float velocityzoom, curspeed;
 121         vector v;
 122
 123         zoomsensitivity = autocvar_cl_zoomsensitivity;
 124         zoomfactor = autocvar_cl_zoomfactor;
 125         if(zoomfactor < 1 || zoomfactor > 30)
 126                 zoomfactor = 2.5;
 127         zoomspeed = autocvar_cl_zoomspeed;
 128         if(zoomspeed >= 0)
 129         if(zoomspeed < 0.5 || zoomspeed > 16)
 130                         zoomspeed = 3.5;
 131
 132         zoomdir = button_zoom;
 133         if(hud == HUD_NORMAL)
 134         if(switchweapon == activeweapon)
 135         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
 136                 zoomdir += button_attack2;
 137         if(spectatee_status > 0 || isdemo())
 138         {
 139                 if(spectatorbutton_zoom)
 140                 {
 141                         if(zoomdir)
 142                                 zoomdir = 0;
 143                         else
 144                                 zoomdir = 1;
 145                 }
 146                 // fteqcc failed twice here already, don't optimize this
 147         }
 148
 149         if(zoomdir) { zoomin_effect = 0; }
 150
 151         if(camera_active)
 152         {
 153                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 154         }
 155         else if(autocvar_cl_spawnzoom && zoomin_effect)
 156         {
 157                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 158
 159                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 160                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 161                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 162         }
 163         else
 164         {
 165                 if(zoomspeed < 0) // instant zoom
 166                 {
 167                         if(zoomdir)
 168                                 current_viewzoom = 1 / zoomfactor;
 169                         else
 170                                 current_viewzoom = 1;
 171                 }
 172                 else
 173                 {
 174                         if(zoomdir)
 175                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 176                         else
 177                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 178                 }
 179         }
 180
 181         if(almost_equals(current_viewzoom, 1))
 182                 current_zoomfraction = 0;
 183         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 184                 current_zoomfraction = 1;
 185         else
 186                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 187
 188         if(zoomsensitivity < 1)
 189                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 190         else
 191                 setsensitivityscale(1);
 192
 193         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 194         {
 195                 if(intermission) { curspeed = 0; }
 196                 else
 197                 {
 198
 199                         makevectors(view_angles);
 200                         v = pmove_vel;
 201                         if(csqcplayer)
 202                                 v = csqcplayer.velocity;
 203
 204                         switch(autocvar_cl_velocityzoom_type)
 205                         {
 206                                 case 3: curspeed = max(0, v_forward * v); break;
 207                                 case 2: curspeed = (v_forward * v); break;
 208                                 case 1: default: curspeed = vlen(v); break;
 209                         }
 210                 }
 211
 212                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 213                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 214                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 215
 216                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 217         }
 218         else
 219                 velocityzoom = 1;
 220
 221         float frustumx, frustumy, fovx, fovy;
 222         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 223         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 224         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 225         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 226
 227         return '1 0 0' * fovx + '0 1 0' * fovy;
 228 }
 229
 230 vector GetViewLocationFOV(float fov)
 231 {
 232         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 233         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 234         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 235         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 236         return '1 0 0' * fovx + '0 1 0' * fovy;
 237 }
 238
 239 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 240 {
 241         float fovx, fovy;
 242         float width = (ov_worldmax.x - ov_worldmin.x);
 243         float height = (ov_worldmax.y - ov_worldmin.y);
 244         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 245         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 246         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 247         return '1 0 0' * fovx + '0 1 0' * fovy;
 248 }
 249
 250 // this function must match W_SetupShot!
 251 float zoomscript_caught;
 252
 253 vector wcross_origin;
 254 float wcross_scale_prev, wcross_alpha_prev;
 255 vector wcross_color_prev;
 256 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 257 vector wcross_color_goal_prev;
 258 float wcross_changedonetime;
 259
 260 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 261 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 262 float wcross_name_changestarttime, wcross_name_changedonetime;
 263 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 264
 265 float wcross_ring_prev;
 266
 267 entity trueaim;
 268 entity trueaim_rifle;
 269
 270 const float SHOTTYPE_HITTEAM = 1;
 271 const float SHOTTYPE_HITOBSTRUCTION = 2;
 272 const float SHOTTYPE_HITWORLD = 3;
 273 const float SHOTTYPE_HITENEMY = 4;
 274
 275 void TrueAim_Init()
 276 {
 277         trueaim = spawn();
 278         trueaim.classname = "trueaim";
 279         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 280         trueaim_rifle = spawn();
 281         trueaim_rifle.classname = "trueaim_rifle";
 282         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 283 }
 284
 285 float EnemyHitCheck()
 286 {
 287         float t, n;
 288         wcross_origin = project_3d_to_2d(trace_endpos);
 289         wcross_origin.z = 0;
 290         if(trace_ent)
 291                 n = trace_ent.entnum;
 292         else
 293                 n = trace_networkentity;
 294         if(n < 1)
 295                 return SHOTTYPE_HITWORLD;
 296         if(n > maxclients)
 297                 return SHOTTYPE_HITWORLD;
 298         t = GetPlayerColor(n - 1);
 299         if(teamplay)
 300                 if(t == myteam)
 301                         return SHOTTYPE_HITTEAM;
 302         if(t == NUM_SPECTATOR)
 303                 return SHOTTYPE_HITWORLD;
 304         return SHOTTYPE_HITENEMY;
 305 }
 306
 307 float TrueAimCheck()
 308 {
 309         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 310         vector vecs, trueaimpoint, w_shotorg;
 311         vector mi, ma, dv;
 312         float shottype;
 313         entity ta;
 314         float mv;
 315
 316         mi = ma = '0 0 0';
 317         ta = trueaim;
 318         mv = MOVE_NOMONSTERS;
 319
 320         switch(activeweapon) // WEAPONTODO
 321         {
 322                 case WEP_TUBA.m_id: // no aim
 323                 case WEP_PORTO.m_id: // shoots from eye
 324                 case WEP_HOOK.m_id: // no trueaim
 325                 case WEP_MORTAR.m_id: // toss curve
 326                         return SHOTTYPE_HITWORLD;
 327                 case WEP_VORTEX.m_id:
 328                 case WEP_VAPORIZER.m_id:
 329                         mv = MOVE_NORMAL;
 330                         break;
 331                 case WEP_RIFLE.m_id:
 332                         ta = trueaim_rifle;
 333                         mv = MOVE_NORMAL;
 334                         if(zoomscript_caught)
 335                         {
 336                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 337                                 return EnemyHitCheck();
 338                         }
 339                         break;
 340                 case WEP_DEVASTATOR.m_id: // projectile has a size!
 341                         mi = '-3 -3 -3';
 342                         ma = '3 3 3';
 343                         break;
 344                 case WEP_FIREBALL.m_id: // projectile has a size!
 345                         mi = '-16 -16 -16';
 346                         ma = '16 16 16';
 347                         break;
 348                 case WEP_SEEKER.m_id: // projectile has a size!
 349                         mi = '-2 -2 -2';
 350                         ma = '2 2 2';
 351                         break;
 352                 case WEP_ELECTRO.m_id: // projectile has a size!
 353                         mi = '0 0 -3';
 354                         ma = '0 0 -3';
 355                         break;
 356         }
 357
 358         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 359
 360         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 361
 362         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 363         trueaimpoint = trace_endpos;
 364
 365         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 366                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 367
 368         if(vecs.x > 0)
 369                 vecs.y = -vecs.y;
 370         else
 371                 vecs = '0 0 0';
 372
 373         dv = view_right * vecs.y + view_up * vecs.z;
 374         w_shotorg = traceorigin + dv;
 375
 376         // now move the vecs forward as much as requested if possible
 377         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 378         w_shotorg = trace_endpos - view_forward * nudge;
 379
 380         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 381         shottype = EnemyHitCheck();
 382         if(shottype != SHOTTYPE_HITWORLD)
 383                 return shottype;
 384
 385 #if 0
 386         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 387         // or rather, I know why, but see no fix
 388         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 389                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 390                 return SHOTTYPE_HITOBSTRUCTION;
 391 #endif
 392
 393         return SHOTTYPE_HITWORLD;
 394 }
 395
 396 void CSQC_common_hud(void);
 397
 398 void PostInit(void);
 399 void CSQC_Demo_Camera();
 400 float HUD_WouldDrawScoreboard();
 401 float camera_mode;
 402 const float CAMERA_FREE = 1;
 403 const float CAMERA_CHASE = 2;
 404 float reticle_type;
 405 string reticle_image;
 406 string NextFrameCommand;
 407
 408 vector freeze_org, freeze_ang;
 409 entity nightvision_noise, nightvision_noise2;
 410
 411 const float MAX_TIME_DIFF = 5;
 412 float pickup_crosshair_time, pickup_crosshair_size;
 413 float hitindication_crosshair_size;
 414 float use_vortex_chargepool;
 415
 416 float myhealth, myhealth_prev;
 417 float myhealth_flash;
 418
 419 float old_blurradius, old_bluralpha;
 420 float old_sharpen_intensity;
 421
 422 vector myhealth_gentlergb;
 423
 424 float contentavgalpha, liquidalpha_prev;
 425 vector liquidcolor_prev;
 426
 427 float eventchase_current_distance;
 428 float eventchase_running;
 429 bool WantEventchase()
 430 {
 431         if(autocvar_cl_orthoview)
 432                 return false;
 433         if(intermission)
 434                 return true;
 435         if(self.viewloc)
 436                 return true;
 437         if(spectatee_status >= 0)
 438         {
 439                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 440                         return true;
 441                 if(MUTATOR_CALLHOOK(WantEventchase, self))
 442                         return true;
 443                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO.m_id)))
 444                         return true;
 445                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 446                 {
 447                         if(autocvar_cl_eventchase_death == 2)
 448                         {
 449                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 450                                 if(self.velocity == '0 0 0' || eventchase_running)
 451                                         return true;
 452                         }
 453                         else return true;
 454                 }
 455         }
 456         return false;
 457 }
 458
 459 vector damage_blurpostprocess, content_blurpostprocess;
 460
 461 float unaccounted_damage = 0;
 462 void UpdateDamage()
 463 {
 464         // accumulate damage with each stat update
 465         static float damage_total_prev = 0;
 466         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 467         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 468         damage_total_prev = damage_total;
 469
 470         static float damage_dealt_time_prev = 0;
 471         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 472         if (damage_dealt_time != damage_dealt_time_prev)
 473         {
 474                 unaccounted_damage += unaccounted_damage_new;
 475                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 476         }
 477         damage_dealt_time_prev = damage_dealt_time;
 478
 479         // prevent hitsound when switching spectatee
 480         static float spectatee_status_prev = 0;
 481         if (spectatee_status != spectatee_status_prev)
 482                 unaccounted_damage = 0;
 483         spectatee_status_prev = spectatee_status;
 484 }
 485
 486 void UpdateHitsound()
 487 {
 488         // varying sound pitch
 489
 490         static float hitsound_time_prev = 0;
 491         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 492         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
 493         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 494         {
 495                 if (autocvar_cl_hitsound && unaccounted_damage)
 496                 {
 497                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 498                         float a = autocvar_cl_hitsound_max_pitch;
 499                         float b = autocvar_cl_hitsound_min_pitch;
 500                         float c = autocvar_cl_hitsound_nom_damage;
 501                         float x = unaccounted_damage;
 502                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 503
 504                         // if sound variation is disabled, set pitch_shift to 1
 505                         if (autocvar_cl_hitsound == 1)
 506                                 pitch_shift = 1;
 507
 508                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 509                         if (autocvar_cl_hitsound == 3)
 510                         {
 511                                 float mirror_value = (a-b)/2 + b;
 512                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 513                         }
 514
 515                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 516
 517                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 518                         // todo: normalize sound pressure levels? seems unnecessary
 519
 520                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 521                 }
 522                 unaccounted_damage = 0;
 523                 hitsound_time_prev = time;
 524         }
 525
 526         static float typehit_time_prev = 0;
 527         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 528         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 529         {
 530                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 531                 typehit_time_prev = typehit_time;
 532         }
 533 }
 534
 535 void UpdateCrosshair()
 536 {
 537         static float rainbow_last_flicker;
 538     static vector rainbow_prev_color;
 539         entity e = self;
 540         float f, i, j;
 541         vector v;
 542         if(getstati(STAT_FROZEN))
 543                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 544         else if (getstatf(STAT_HEALING_ORB)>time)
 545                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, NADE_TYPE_HEAL.m_color, autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
 546         if(!intermission)
 547         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 548         {
 549                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 550                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 551         }
 552         else if(getstatf(STAT_REVIVE_PROGRESS))
 553         {
 554                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 555                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 556         }
 557
 558         if(autocvar_r_letterbox == 0)
 559                 if(autocvar_viewsize < 120)
 560                         CSQC_common_hud();
 561
 562         // crosshair goes VERY LAST
 563         if(!scoreboard_active && !camera_active && intermission != 2 &&
 564                 spectatee_status != -1 && hud == HUD_NORMAL && !csqcplayer.viewloc &&
 565                 !HUD_MinigameMenu_IsOpened() )
 566         {
 567                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 568                         return;
 569
 570                 string wcross_style;
 571                 float wcross_alpha, wcross_resolution;
 572                 wcross_style = autocvar_crosshair;
 573                 if (wcross_style == "0")
 574                         return;
 575                 wcross_resolution = autocvar_crosshair_size;
 576                 if (wcross_resolution == 0)
 577                         return;
 578                 wcross_alpha = autocvar_crosshair_alpha;
 579                 if (wcross_alpha == 0)
 580                         return;
 581
 582                 // TrueAim check
 583                 float shottype;
 584
 585                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 586                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 587                 wcross_origin.z = 0;
 588                 if(autocvar_crosshair_hittest)
 589                 {
 590                         vector wcross_oldorigin;
 591                         wcross_oldorigin = wcross_origin;
 592                         shottype = TrueAimCheck();
 593                         if(shottype == SHOTTYPE_HITWORLD)
 594                         {
 595                                 v = wcross_origin - wcross_oldorigin;
 596                                 v.x /= vid_conwidth;
 597                                 v.y /= vid_conheight;
 598                                 if(vlen(v) > 0.01)
 599                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 600                         }
 601                         if(!autocvar_crosshair_hittest_showimpact)
 602                                 wcross_origin = wcross_oldorigin;
 603                 }
 604                 else
 605                         shottype = SHOTTYPE_HITWORLD;
 606
 607                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 608                 string wcross_name = "";
 609                 float wcross_scale, wcross_blur;
 610
 611                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 612                 {
 613                         e = get_weaponinfo(switchingweapon);
 614                         if(e)
 615                         {
 616                                 if(autocvar_crosshair_per_weapon)
 617                                 {
 618                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 619                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 620                                         //if (wcross_resolution == 0)
 621                                                 //return;
 622
 623                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 624                                         wcross_resolution *= e.w_crosshair_size;
 625                                         wcross_name = e.w_crosshair;
 626                                 }
 627                         }
 628                 }
 629
 630                 if(wcross_name == "")
 631                         wcross_name = strcat("gfx/crosshair", wcross_style);
 632
 633                 // MAIN CROSSHAIR COLOR DECISION
 634                 switch(autocvar_crosshair_color_special)
 635                 {
 636                         case 1: // crosshair_color_per_weapon
 637                         {
 638                                 if(e)
 639                                 {
 640                                         wcross_color = e.wpcolor;
 641                                         break;
 642                                 }
 643                                 else { goto normalcolor; }
 644                         }
 645
 646                         case 2: // crosshair_color_by_health
 647                         {
 648                                 float x = getstati(STAT_HEALTH);
 649
 650                                 //x = red
 651                                 //y = green
 652                                 //z = blue
 653
 654                                 wcross_color.z = 0;
 655
 656                                 if(x > 200)
 657                                 {
 658                                         wcross_color.x = 0;
 659                                         wcross_color.y = 1;
 660                                 }
 661                                 else if(x > 150)
 662                                 {
 663                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 664                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 665                                 }
 666                                 else if(x > 100)
 667                                 {
 668                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 669                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 670                                         wcross_color.z = 1 - (x-100)*0.02;
 671                                 }
 672                                 else if(x > 50)
 673                                 {
 674                                         wcross_color.x = 1;
 675                                         wcross_color.y = 1;
 676                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 677                                 }
 678                                 else if(x > 20)
 679                                 {
 680                                         wcross_color.x = 1;
 681                                         wcross_color.y = (x-20)*90/27/100;
 682                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 683                                 }
 684                                 else
 685                                 {
 686                                         wcross_color.x = 1;
 687                                         wcross_color.y = 0;
 688                                 }
 689                                 break;
 690                         }
 691
 692                         case 3: // crosshair_color_rainbow
 693                         {
 694                                 if(time >= rainbow_last_flicker)
 695                                 {
 696                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 697                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 698                                 }
 699                                 wcross_color = rainbow_prev_color;
 700                                 break;
 701                         }
 702                         :normalcolor
 703                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 704                 }
 705
 706                 if(autocvar_crosshair_effect_scalefade)
 707                 {
 708                         wcross_scale = wcross_resolution;
 709                         wcross_resolution = 1;
 710                 }
 711                 else
 712                 {
 713                         wcross_scale = 1;
 714                 }
 715
 716                 if(autocvar_crosshair_pickup)
 717                 {
 718                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 719
 720                         if(pickup_crosshair_time < stat_pickup_time)
 721                         {
 722                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 723                                         pickup_crosshair_size = 1;
 724
 725                                 pickup_crosshair_time = stat_pickup_time;
 726                         }
 727
 728                         if(pickup_crosshair_size > 0)
 729                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 730                         else
 731                                 pickup_crosshair_size = 0;
 732
 733                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 734                 }
 735
 736                 // todo: make crosshair hit indication dependent on damage dealt
 737                 if(autocvar_crosshair_hitindication)
 738                 {
 739                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 740
 741                         if(unaccounted_damage)
 742                         {
 743                                 hitindication_crosshair_size = 1;
 744                         }
 745
 746                         if(hitindication_crosshair_size > 0)
 747                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 748                         else
 749                                 hitindication_crosshair_size = 0;
 750
 751                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 752                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 753                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 754                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 755                 }
 756
 757                 if(shottype == SHOTTYPE_HITENEMY)
 758                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 759                 if(shottype == SHOTTYPE_HITTEAM)
 760                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 761
 762                 f = fabs(autocvar_crosshair_effect_time);
 763                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 764                 {
 765                         wcross_changedonetime = time + f;
 766                 }
 767                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 768                 {
 769                         wcross_name_changestarttime = time;
 770                         wcross_name_changedonetime = time + f;
 771                         if(wcross_name_goal_prev_prev)
 772                                 strunzone(wcross_name_goal_prev_prev);
 773                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 774                         wcross_name_goal_prev = strzone(wcross_name);
 775                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 776                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 777                         wcross_resolution_goal_prev = wcross_resolution;
 778                 }
 779
 780                 wcross_scale_goal_prev = wcross_scale;
 781                 wcross_alpha_goal_prev = wcross_alpha;
 782                 wcross_color_goal_prev = wcross_color;
 783
 784                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 785                 {
 786                         wcross_blur = 1;
 787                         wcross_alpha *= 0.75;
 788                 }
 789                 else
 790                         wcross_blur = 0;
 791                 // *_prev is at time-frametime
 792                 // * is at wcross_changedonetime+f
 793                 // what do we have at time?
 794                 if(time < wcross_changedonetime)
 795                 {
 796                         f = frametime / (wcross_changedonetime - time + frametime);
 797                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 798                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 799                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 800                 }
 801
 802                 wcross_scale_prev = wcross_scale;
 803                 wcross_alpha_prev = wcross_alpha;
 804                 wcross_color_prev = wcross_color;
 805
 806                 MUTATOR_CALLHOOK(UpdateCrosshair);
 807
 808                 wcross_scale *= 1 - autocvar__menu_alpha;
 809                 wcross_alpha *= 1 - autocvar__menu_alpha;
 810                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 811
 812                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 813                 {
 814                         // crosshair rings for weapon stats
 815                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 816                         {
 817                                 // declarations and stats
 818                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 819                                 string ring_image = string_null, ring_inner_image = string_null;
 820                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 821
 822                                 ring_scale = autocvar_crosshair_ring_size;
 823
 824                                 float weapon_clipload, weapon_clipsize;
 825                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 826                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 827
 828                                 float ok_ammo_charge, ok_ammo_chargepool;
 829                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 830                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 831
 832                                 float vortex_charge, vortex_chargepool;
 833                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 834                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 835
 836                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 837
 838                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 839                                         vortex_charge_movingavg = vortex_charge;
 840
 841
 842                                 // handle the values
 843                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 844                                 {
 845                                         if (vortex_chargepool || use_vortex_chargepool) {
 846                                                 use_vortex_chargepool = 1;
 847                                                 ring_inner_value = vortex_chargepool;
 848                                         } else {
 849                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 850                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 851                                         }
 852
 853                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 854                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 855                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 856
 857                                         // draw the outer ring to show the current charge of the weapon
 858                                         ring_value = vortex_charge;
 859                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 860                                         ring_rgb = wcross_color;
 861                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 862                                 }
 863                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 864                                 {
 865                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 866                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 867                                         ring_rgb = wcross_color;
 868                                         ring_image = "gfx/crosshair_ring.tga";
 869                                 }
 870                                 else if (activeweapon == WEP_HAGAR.m_id && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 871                                 {
 872                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 873                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 874                                         ring_rgb = wcross_color;
 875                                         ring_image = "gfx/crosshair_ring.tga";
 876                                 }
 877                                 else if (ok_ammo_charge)
 878                                 {
 879                                         ring_value = ok_ammo_chargepool;
 880                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 881                                         ring_rgb = wcross_color;
 882                                         ring_image = "gfx/crosshair_ring.tga";
 883                                 }
 884                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 885                                 {
 886                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 887                                         ring_scale = autocvar_crosshair_ring_reload_size;
 888                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 889                                         ring_rgb = wcross_color;
 890
 891                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 892                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 893                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
 894                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 895                                         else
 896                                                 ring_image = "gfx/crosshair_ring.tga";
 897                                 }
 898                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
 899                                 {
 900                                         ring_value = arc_heat;
 901                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 902                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 903                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 904                                         ring_image = "gfx/crosshair_ring.tga";
 905                                 }
 906
 907                                 // if in weapon switch animation, fade ring out/in
 908                                 if(autocvar_crosshair_effect_time > 0)
 909                                 {
 910                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 911                                         if (f >= 1)
 912                                         {
 913                                                 wcross_ring_prev = ((ring_image) ? true : false);
 914                                         }
 915
 916                                         if(wcross_ring_prev)
 917                                         {
 918                                                 if(f < 1)
 919                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 920                                         }
 921                                         else
 922                                         {
 923                                                 if(f < 1)
 924                                                         ring_alpha *= bound(0, f, 1);
 925                                         }
 926                                 }
 927
 928                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 929                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 930
 931                                 if (ring_value)
 932                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 933                         }
 934
 935 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 936                         do \
 937                         { \
 938                                 if(wcross_blur > 0) \
 939                                 { \
 940                                         for(i = -2; i <= 2; ++i) \
 941                                         for(j = -2; j <= 2; ++j) \
 942                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 943                                 } \
 944                                 else \
 945                                 { \
 946                                         M(0,0,sz,wcross_name,wcross_alpha); \
 947                                 } \
 948                         } \
 949                         while(0)
 950
 951 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 952                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 953
 954 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 955                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 956
 957                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 958                         {
 959                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 960                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 961                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 962                                 f = 1 - f;
 963                         }
 964                         else
 965                         {
 966                                 f = 1;
 967                         }
 968                         wcross_name_alpha_goal_prev = f;
 969
 970                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 971                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 972
 973                         if(autocvar_crosshair_dot)
 974                         {
 975                                 vector wcross_color_old;
 976                                 wcross_color_old = wcross_color;
 977
 978                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 979                                         wcross_color = stov(autocvar_crosshair_dot_color);
 980
 981                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 982                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 983                                 wcross_color = wcross_color_old;
 984                         }
 985                 }
 986         }
 987         else
 988         {
 989                 wcross_scale_prev = 0;
 990                 wcross_alpha_prev = 0;
 991                 wcross_scale_goal_prev = 0;
 992                 wcross_alpha_goal_prev = 0;
 993                 wcross_changedonetime = 0;
 994                 if(wcross_name_goal_prev)
 995                         strunzone(wcross_name_goal_prev);
 996                 wcross_name_goal_prev = string_null;
 997                 if(wcross_name_goal_prev_prev)
 998                         strunzone(wcross_name_goal_prev_prev);
 999                 wcross_name_goal_prev_prev = string_null;
1000                 wcross_name_changestarttime = 0;
1001                 wcross_name_changedonetime = 0;
1002                 wcross_name_alpha_goal_prev = 0;
1003                 wcross_name_alpha_goal_prev_prev = 0;
1004                 wcross_resolution_goal_prev = 0;
1005                 wcross_resolution_goal_prev_prev = 0;
1006         }
1007 }
1008
1009 const int BUTTON_3 = 4;
1010 const int BUTTON_4 = 8;
1011 float cl_notice_run();
1012 float prev_myteam;
1013 int lasthud;
1014 float vh_notice_time;
1015 void WaypointSprite_Load();
1016 void CSQC_UpdateView(float w, float h)
1017 {
1018         entity e;
1019         float fov;
1020         float f;
1021         int i;
1022         vector vf_size, vf_min;
1023         float a;
1024
1025         execute_next_frame();
1026
1027         ++framecount;
1028
1029         hud = getstati(STAT_HUD);
1030
1031         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1032                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1033
1034         lasthud = hud;
1035
1036         if(autocvar__hud_showbinds_reload) // menu can set this one
1037         {
1038                 db_close(binddb);
1039                 binddb = db_create();
1040                 cvar_set("_hud_showbinds_reload", "0");
1041         }
1042
1043         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1044                 view_quality = getproperty(VF_MINFPS_QUALITY);
1045         else
1046                 view_quality = 1;
1047
1048         button_attack2 = (input_buttons & BUTTON_3);
1049         button_zoom = (input_buttons & BUTTON_4);
1050
1051         vf_size = getpropertyvec(VF_SIZE);
1052         vf_min = getpropertyvec(VF_MIN);
1053         vid_width = vf_size.x;
1054         vid_height = vf_size.y;
1055
1056         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1057         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1058
1059         WaypointSprite_Load();
1060
1061         CSQCPlayer_SetCamera();
1062
1063         if(player_localentnum <= maxclients) // is it a client?
1064                 current_player = player_localentnum - 1;
1065         else // then player_localentnum is the vehicle I'm driving
1066                 current_player = player_localnum;
1067         myteam = GetPlayerColor(current_player);
1068
1069         if(myteam != prev_myteam)
1070         {
1071                 myteamcolors = colormapPaletteColor(myteam, 1);
1072                 for(i = 0; i < HUD_PANEL_NUM; ++i)
1073                         hud_panel[i].update_time = time;
1074                 prev_myteam = myteam;
1075         }
1076
1077         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1078
1079         float is_dead = (getstati(STAT_HEALTH) <= 0);
1080
1081         // FIXME do we need this hack?
1082         if(isdemo())
1083         {
1084                 // in demos, input_buttons do not work
1085                 button_zoom = (autocvar__togglezoom == "-");
1086         }
1087         else if(button_zoom
1088                 && autocvar_cl_unpress_zoom_on_death
1089                 && (spectatee_status >= 0)
1090                 && (is_dead || intermission))
1091         {
1092                 // no zoom while dead or in intermission please
1093                 localcmd("-zoom\n");
1094                 button_zoom = false;
1095         }
1096
1097         // event chase camera
1098         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1099         {
1100                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1101                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && getstati(STAT_ROUNDLOST));
1102                 entity gen = world;
1103
1104                 if(ons_roundlost)
1105                 {
1106                         entity e;
1107                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1108                         {
1109                                 if(e.health <= 0)
1110                                 {
1111                                         gen = e;
1112                                         break;
1113                                 }
1114                         }
1115                         if(!gen)
1116                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1117                 }
1118                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1119                 {
1120                         eventchase_running = true;
1121
1122                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1123                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1124                         if(ons_roundlost) { current_view_origin = gen.origin; }
1125
1126                         // detect maximum viewoffset and use it
1127                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1128                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1129                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1130
1131                         if(view_offset)
1132                         {
1133                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1134                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1135                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1136                         }
1137
1138                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1139                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1140                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1141                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1142
1143                         // make the camera smooth back
1144                         float chase_distance = autocvar_cl_eventchase_distance;
1145                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1146                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1147
1148                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1149                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1150                         else if(eventchase_current_distance != chase_distance)
1151                                 eventchase_current_distance = chase_distance;
1152
1153                         makevectors(view_angles);
1154
1155                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1156                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1157
1158                         // If the boxtrace fails, revert back to line tracing.
1159                         if(!self.viewloc)
1160                         if(trace_startsolid)
1161                         {
1162                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1163                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1164                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1165                         }
1166                         else { setproperty(VF_ORIGIN, trace_endpos); }
1167
1168                         if(!self.viewloc)
1169                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1170                 }
1171                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1172                 {
1173                         eventchase_running = false;
1174                         cvar_set("chase_active", "0");
1175                         eventchase_current_distance = 0; // start from 0 next time
1176                 }
1177         }
1178         // workaround for camera stuck between player's legs when using chase_active 1
1179         // because the engine stops updating the chase_active camera when the game ends
1180         else if(intermission)
1181         {
1182                 cvar_settemp("chase_active", "-1");
1183                 eventchase_current_distance = 0;
1184         }
1185
1186         // do lockview after event chase camera so that it still applies whenever necessary.
1187         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
1188         {
1189                 setproperty(VF_ORIGIN, freeze_org);
1190                 setproperty(VF_ANGLES, freeze_ang);
1191         }
1192         else
1193         {
1194                 freeze_org = getpropertyvec(VF_ORIGIN);
1195                 freeze_ang = getpropertyvec(VF_ANGLES);
1196         }
1197
1198         WarpZone_FixView();
1199         //WarpZone_FixPMove();
1200
1201         vector ov_org = '0 0 0';
1202         vector ov_mid = '0 0 0';
1203         vector ov_worldmin = '0 0 0';
1204         vector ov_worldmax = '0 0 0';
1205         if(autocvar_cl_orthoview)
1206         {
1207                 ov_worldmin = mi_picmin;
1208                 ov_worldmax = mi_picmax;
1209
1210                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1211                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1212                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1213
1214                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1215                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1216
1217                 float ov_nearest = vlen(ov_org - vec3(
1218                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1219                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1220                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1221                 ));
1222
1223                 float ov_furthest = 0;
1224                 float dist = 0;
1225
1226                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1227                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1228                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1229                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1230                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1231                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1232                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1233                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1234
1235                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1236                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1237                 cvar_settemp("r_farclip_world", "0");
1238                 cvar_settemp("r_novis", "1");
1239                 cvar_settemp("r_useportalculling", "0");
1240                 cvar_settemp("r_useinfinitefarclip", "0");
1241
1242                 setproperty(VF_ORIGIN, ov_org);
1243                 setproperty(VF_ANGLES, '90 0 0');
1244
1245                 #if 0
1246                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1247                         vtos(ov_org),
1248                         vtos(getpropertyvec(VF_ANGLES)),
1249                         ov_distance,
1250                         ov_nearest,
1251                         ov_furthest);
1252                 #endif
1253         }
1254
1255         // Render the Scene
1256         view_origin = getpropertyvec(VF_ORIGIN);
1257         view_angles = getpropertyvec(VF_ANGLES);
1258         makevectors(view_angles);
1259         view_forward = v_forward;
1260         view_right = v_right;
1261         view_up = v_up;
1262
1263 #ifdef BLURTEST
1264         if(time > blurtest_time0 && time < blurtest_time1)
1265         {
1266                 float r, t;
1267
1268                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1269                 r = t * blurtest_radius;
1270                 f = 1 / pow(t, blurtest_power) - 1;
1271
1272                 cvar_set("r_glsl_postprocess", "1");
1273                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1274         }
1275         else
1276         {
1277                 cvar_set("r_glsl_postprocess", "0");
1278                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1279         }
1280 #endif
1281
1282         TargetMusic_Advance();
1283         Fog_Force();
1284
1285         if(drawtime == 0)
1286                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1287         else
1288                 drawframetime = bound(0.000001, time - drawtime, 1);
1289         drawtime = time;
1290
1291         // watch for gametype changes here...
1292         // in ParseStuffCMD the cmd isn't executed yet :/
1293         // might even be better to add the gametype to TE_CSQC_INIT...?
1294         if(!postinit)
1295                 PostInit();
1296
1297         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1298         {
1299                 if(calledhooks & HOOK_START)
1300                 {
1301                         localcmd("\ncl_hook_gameend\n");
1302                         calledhooks |= HOOK_END;
1303                 }
1304         }
1305
1306         Announcer();
1307
1308         fov = autocvar_fov;
1309         if(fov <= 59.5)
1310         {
1311                 if(!zoomscript_caught)
1312                 {
1313                         localcmd("+button9\n");
1314                         zoomscript_caught = 1;
1315                 }
1316         }
1317         else
1318         {
1319                 if(zoomscript_caught)
1320                 {
1321                         localcmd("-button9\n");
1322                         zoomscript_caught = 0;
1323                 }
1324         }
1325
1326         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1327
1328         // next WANTED weapon (for HUD)
1329         switchweapon = getstati(STAT_SWITCHWEAPON);
1330
1331         // currently switching-to weapon (for crosshair)
1332         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1333
1334         // actually active weapon (for zoom)
1335         activeweapon = getstati(STAT_ACTIVEWEAPON);
1336
1337         f = (serverflags & SERVERFLAG_TEAMPLAY);
1338         if(f != teamplay)
1339         {
1340                 teamplay = f;
1341                 HUD_InitScores();
1342         }
1343
1344         if(last_switchweapon != switchweapon)
1345         {
1346                 weapontime = time;
1347                 last_switchweapon = switchweapon;
1348                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1349                 {
1350                         localcmd("-zoom\n");
1351                         button_zoom = false;
1352                 }
1353                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1354                 {
1355                         localcmd("-fire\n");
1356                         localcmd("-fire2\n");
1357                         button_attack2 = false;
1358                 }
1359         }
1360         if(last_activeweapon != activeweapon)
1361         {
1362                 last_activeweapon = activeweapon;
1363
1364                 e = get_weaponinfo(activeweapon);
1365                 if(e.netname != "")
1366                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1367                 else
1368                         localcmd("\ncl_hook_activeweapon none\n");
1369         }
1370
1371         // ALWAYS Clear Current Scene First
1372         clearscene();
1373
1374         setproperty(VF_ORIGIN, view_origin);
1375         setproperty(VF_ANGLES, view_angles);
1376
1377         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1378         setproperty(VF_SIZE, vf_size);
1379         setproperty(VF_MIN, vf_min);
1380
1381         // Assign Standard Viewflags
1382         // Draw the World (and sky)
1383         setproperty(VF_DRAWWORLD, 1);
1384
1385         // Set the console size vars
1386         vid_conwidth = autocvar_vid_conwidth;
1387         vid_conheight = autocvar_vid_conheight;
1388         vid_pixelheight = autocvar_vid_pixelheight;
1389
1390         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1391         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1392         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1393
1394         // Camera for demo playback
1395         if(camera_active)
1396         {
1397                 if(autocvar_camera_enable)
1398                         CSQC_Demo_Camera();
1399                 else
1400                 {
1401                         cvar_set("chase_active", ftos(chase_active_backup));
1402                         cvar_set("cl_demo_mousegrab", "0");
1403                         camera_active = false;
1404                 }
1405         }
1406         else
1407         {
1408 #ifdef CAMERATEST
1409                 if(autocvar_camera_enable)
1410 #else
1411                 if(autocvar_camera_enable && isdemo())
1412 #endif
1413                 {
1414                         // Enable required Darkplaces cvars
1415                         chase_active_backup = autocvar_chase_active;
1416                         cvar_set("chase_active", "2");
1417                         cvar_set("cl_demo_mousegrab", "1");
1418                         camera_active = true;
1419                         camera_mode = false;
1420                 }
1421         }
1422
1423         // Draw the Crosshair
1424         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1425
1426         // Draw the Engine Status Bar (the default Quake HUD)
1427         setproperty(VF_DRAWENGINESBAR, 0);
1428
1429         // Update the mouse position
1430         /*
1431            mousepos_x = vid_conwidth;
1432            mousepos_y = vid_conheight;
1433            mousepos = mousepos*0.5 + getmousepos();
1434          */
1435
1436         e = self;
1437         for(self = world; (self = nextent(self)); )
1438                 if(self.draw)
1439                         self.draw();
1440         self = e;
1441
1442         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1443         renderscene();
1444
1445         // now switch to 2D drawing mode by calling a 2D drawing function
1446         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1447         // next R_RenderScene call
1448         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1449
1450         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1451         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1452         {
1453                 // apply night vision effect
1454                 vector tc_00, tc_01, tc_10, tc_11;
1455                 vector rgb = '0 0 0';
1456
1457                 if(!nightvision_noise)
1458                 {
1459                         nightvision_noise = spawn();
1460                         nightvision_noise.classname = "nightvision_noise";
1461                 }
1462                 if(!nightvision_noise2)
1463                 {
1464                         nightvision_noise2 = spawn();
1465                         nightvision_noise2.classname = "nightvision_noise2";
1466                 }
1467
1468                 // color tint in yellow
1469                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1470
1471                 // draw BG
1472                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1473                 rgb = '1 1 1';
1474                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1475                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1476                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1477                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1478                 tc_11 = tc_01 + tc_10 - tc_00;
1479                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1480                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1481                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1482                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1483                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1484                 R_EndPolygon();
1485
1486                 // draw FG
1487                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1488                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1489                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1490                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1491                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1492                 tc_11 = tc_01 + tc_10 - tc_00;
1493                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1494                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1495                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1496                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1497                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1498                 R_EndPolygon();
1499         }
1500
1501         if(autocvar_cl_reticle)
1502         {
1503                 // Draw the aiming reticle for weapons that use it
1504                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1505                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1506                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1507                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1508                 {
1509                         // no zoom reticle while dead
1510                         reticle_type = 0;
1511                 }
1512                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
1513                 {
1514                         if(reticle_image != "") { reticle_type = 2; }
1515                         else { reticle_type = 0; }
1516                 }
1517                 else if(button_zoom || zoomscript_caught)
1518                 {
1519                         // normal zoom
1520                         reticle_type = 1;
1521                 }
1522
1523                 if(reticle_type)
1524                 {
1525                         if(autocvar_cl_reticle_stretch)
1526                         {
1527                                 reticle_size.x = vid_conwidth;
1528                                 reticle_size.y = vid_conheight;
1529                                 reticle_pos.x = 0;
1530                                 reticle_pos.y = 0;
1531                         }
1532                         else
1533                         {
1534                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1535                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1536                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1537                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1538                         }
1539
1540                         if(zoomscript_caught)
1541                                 f = 1;
1542                         else
1543                                 f = current_zoomfraction;
1544
1545                         if(f)
1546                         {
1547                                 switch(reticle_type)
1548                                 {
1549                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1550                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1551                                 }
1552                         }
1553                 }
1554         }
1555         else
1556         {
1557                 if(reticle_type != 0) { reticle_type = 0; }
1558         }
1559
1560
1561         // improved polyblend
1562         if(autocvar_hud_contents)
1563         {
1564                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1565                 vector liquidcolor;
1566
1567                 switch(pointcontents(view_origin))
1568                 {
1569                         case CONTENT_WATER:
1570                                 liquidalpha = autocvar_hud_contents_water_alpha;
1571                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1572                                 incontent = 1;
1573                                 break;
1574
1575                         case CONTENT_LAVA:
1576                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1577                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1578                                 incontent = 1;
1579                                 break;
1580
1581                         case CONTENT_SLIME:
1582                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1583                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1584                                 incontent = 1;
1585                                 break;
1586
1587                         default:
1588                                 liquidalpha = 0;
1589                                 liquidcolor = '0 0 0';
1590                                 incontent = 0;
1591                                 break;
1592                 }
1593
1594                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1595                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1596                         contentfadetime = autocvar_hud_contents_fadeintime;
1597                         liquidalpha_prev = liquidalpha;
1598                         liquidcolor_prev = liquidcolor;
1599                 }
1600                 else
1601                         contentfadetime = autocvar_hud_contents_fadeouttime;
1602
1603                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1604                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1605
1606                 if(contentavgalpha)
1607                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1608
1609                 if(autocvar_hud_postprocessing)
1610                 {
1611                         if(autocvar_hud_contents_blur && contentavgalpha)
1612                         {
1613                                 content_blurpostprocess.x = 1;
1614                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1615                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1616                         }
1617                         else
1618                         {
1619                                 content_blurpostprocess.x = 0;
1620                                 content_blurpostprocess.y = 0;
1621                                 content_blurpostprocess.z = 0;
1622                         }
1623                 }
1624         }
1625
1626         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1627         {
1628                 splash_size.x = max(vid_conwidth, vid_conheight);
1629                 splash_size.y = max(vid_conwidth, vid_conheight);
1630                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1631                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1632
1633                 float myhealth_flash_temp;
1634                 myhealth = getstati(STAT_HEALTH);
1635
1636                 // fade out
1637                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1638                 // add new damage
1639                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1640
1641                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1642                 pain_threshold = autocvar_hud_damage_pain_threshold;
1643                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1644                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1645
1646                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1647                 {
1648                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1649                 }
1650
1651                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1652
1653                 if(myhealth_prev < 1)
1654                 {
1655                         if(myhealth >= 1)
1656                         {
1657                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1658                                 myhealth_flash_temp = 0;
1659                         }
1660                         else
1661                         {
1662                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1663                         }
1664                 }
1665
1666                 if(spectatee_status == -1 || intermission)
1667                 {
1668                         myhealth_flash = 0; // observing, or match ended
1669                         myhealth_flash_temp = 0;
1670                 }
1671
1672                 myhealth_prev = myhealth;
1673
1674                 // IDEA: change damage color/picture based on player model for robot/alien species?
1675                 // pro: matches model better
1676                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1677                 // maybe different reddish pics?
1678                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1679                 {
1680                         if(autocvar_cl_gentle_damage == 2)
1681                         {
1682                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1683                                 {
1684                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1685                                 }
1686                         }
1687                         else
1688                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1689
1690                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1691                 }
1692                 else
1693                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1694
1695                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1696                 {
1697                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1698                         {
1699                                 damage_blurpostprocess.x = 1;
1700                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1701                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1702                         }
1703                         else
1704                         {
1705                                 damage_blurpostprocess.x = 0;
1706                                 damage_blurpostprocess.y = 0;
1707                                 damage_blurpostprocess.z = 0;
1708                         }
1709                 }
1710         }
1711
1712         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1713         float e2 = (autocvar_hud_powerup != 0);
1714         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1715         {
1716                 // enable or disable rendering types if they are used or not
1717                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1718                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1719
1720                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1721                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1722                 {
1723                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1724                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1725                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1726                         {
1727                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1728                                 old_blurradius = blurradius;
1729                                 old_bluralpha = bluralpha;
1730                         }
1731                 }
1732                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1733                 {
1734                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1735                         old_blurradius = 0;
1736                         old_bluralpha = 0;
1737                 }
1738
1739                 // edge detection postprocess handling done second (used by hud_powerup)
1740                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1741                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1742                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1743
1744                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1745
1746                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1747                 {
1748                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1749                         {
1750                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1751                                 old_sharpen_intensity = sharpen_intensity;
1752                         }
1753                 }
1754                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1755                 {
1756                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1757                         old_sharpen_intensity = 0;
1758                 }
1759
1760                 if(cvar("r_glsl_postprocess") == 0)
1761                         cvar_set("r_glsl_postprocess", "2");
1762         }
1763         else if(cvar("r_glsl_postprocess") == 2)
1764                 cvar_set("r_glsl_postprocess", "0");
1765
1766         if(menu_visible)
1767                 menu_show();
1768
1769         /*if(gametype == MAPINFO_TYPE_CTF)
1770           {
1771           ctf_view();
1772           } else */
1773
1774         // draw 2D entities
1775         e = self;
1776         for(self = world; (self = nextent(self)); )
1777                 if(self.draw2d)
1778                         self.draw2d();
1779         self = e;
1780         Draw_ShowNames_All();
1781
1782         scoreboard_active = HUD_WouldDrawScoreboard();
1783
1784         UpdateDamage();
1785         UpdateCrosshair();
1786         UpdateHitsound();
1787
1788         if(NextFrameCommand)
1789         {
1790                 localcmd("\n", NextFrameCommand, "\n");
1791                 NextFrameCommand = string_null;
1792         }
1793
1794         // we must do this check AFTER a frame was rendered, or it won't work
1795         if(cs_project_is_b0rked == 0)
1796         {
1797                 string w0, h0;
1798                 w0 = ftos(autocvar_vid_conwidth);
1799                 h0 = ftos(autocvar_vid_conheight);
1800                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1801                 //setproperty(VF_FOV, '90 90 0');
1802                 setproperty(VF_ORIGIN, '0 0 0');
1803                 setproperty(VF_ANGLES, '0 0 0');
1804                 setproperty(VF_PERSPECTIVE, 1);
1805                 makevectors('0 0 0');
1806                 vector v1, v2;
1807                 cvar_set("vid_conwidth", "800");
1808                 cvar_set("vid_conheight", "600");
1809                 v1 = cs_project(v_forward);
1810                 cvar_set("vid_conwidth", "640");
1811                 cvar_set("vid_conheight", "480");
1812                 v2 = cs_project(v_forward);
1813                 if(v1 == v2)
1814                         cs_project_is_b0rked = 1;
1815                 else
1816                         cs_project_is_b0rked = -1;
1817                 cvar_set("vid_conwidth", w0);
1818                 cvar_set("vid_conheight", h0);
1819         }
1820
1821         if(autocvar__hud_configure)
1822                 HUD_Panel_Mouse();
1823         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
1824                 HUD_Minigame_Mouse();
1825         else
1826                 HUD_Radar_Mouse();
1827
1828     if(hud && !intermission)
1829     if(hud == HUD_BUMBLEBEE_GUN)
1830         CSQC_BUMBLE_GUN_HUD();
1831     else
1832                 VEH_ACTION(hud, VR_HUD);
1833
1834         cl_notice_run();
1835
1836         // let's reset the view back to normal for the end
1837         setproperty(VF_MIN, '0 0 0');
1838         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1839 }
1840
1841
1842 void CSQC_common_hud(void)
1843 {
1844         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1845                 Accuracy_LoadLevels();
1846
1847         HUD_Main(); // always run these functions for alpha checks
1848         HUD_DrawScoreboard();
1849
1850         // scoreboard/accuracy, map/gametype voting screen
1851         if (scoreboard_active || intermission == 2)
1852                 HUD_Reset();
1853 }
1854
1855
1856 // following vectors must be global to allow seamless switching between camera modes
1857 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1858 void CSQC_Demo_Camera()
1859 {
1860         float speed, attenuation, dimensions;
1861         vector tmp, delta;
1862
1863         if( autocvar_camera_reset || !camera_mode )
1864         {
1865                 camera_offset = '0 0 0';
1866                 current_angles = '0 0 0';
1867                 camera_direction = '0 0 0';
1868                 camera_offset.z += 30;
1869                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1870                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1871                 current_origin = view_origin;
1872                 current_camera_offset  = camera_offset;
1873                 cvar_set("camera_reset", "0");
1874                 camera_mode = CAMERA_CHASE;
1875         }
1876
1877         // Camera angles
1878         if( camera_roll )
1879                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1880
1881         if(autocvar_camera_look_player)
1882         {
1883                 vector dir;
1884                 float n;
1885
1886                 dir = normalize(view_origin - current_position);
1887                 n = mouse_angles.z;
1888                 mouse_angles = vectoangles(dir);
1889                 mouse_angles.x = mouse_angles.x * -1;
1890                 mouse_angles.z = n;
1891         }
1892         else
1893         {
1894                 tmp = getmousepos() * 0.1;
1895                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1896                 {
1897                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1898                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1899                 }
1900         }
1901
1902         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1903         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1904         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1905         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1906
1907         // Fix difference when angles don't have the same sign
1908         delta = '0 0 0';
1909         if(mouse_angles.y < -60 && current_angles.y > 60)
1910                 delta = '0 360 0';
1911         if(mouse_angles.y > 60 && current_angles.y < -60)
1912                 delta = '0 -360 0';
1913
1914         if(autocvar_camera_look_player)
1915                 attenuation = autocvar_camera_look_attenuation;
1916         else
1917                 attenuation = autocvar_camera_speed_attenuation;
1918
1919         attenuation = 1 / max(1, attenuation);
1920         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1921
1922         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1923         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1924         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1925         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1926
1927         // Camera position
1928         tmp = '0 0 0';
1929         dimensions = 0;
1930
1931         if( camera_direction.x )
1932         {
1933                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1934                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1935                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1936                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1937                 ++dimensions;
1938         }
1939
1940         if( camera_direction.y )
1941         {
1942                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1943                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1944                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1945                 ++dimensions;
1946         }
1947
1948         if( camera_direction.z )
1949         {
1950                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1951                 ++dimensions;
1952         }
1953
1954         if(autocvar_camera_free)
1955                 speed = autocvar_camera_speed_free;
1956         else
1957                 speed = autocvar_camera_speed_chase;
1958
1959         if(dimensions)
1960         {
1961                 speed = speed * sqrt(1 / dimensions);
1962                 camera_offset += tmp * speed;
1963         }
1964
1965         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1966
1967         // Camera modes
1968         if( autocvar_camera_free )
1969         {
1970                 if ( camera_mode == CAMERA_CHASE )
1971                 {
1972                         current_camera_offset = current_origin + current_camera_offset;
1973                         camera_offset = current_origin + camera_offset;
1974                 }
1975
1976                 camera_mode = CAMERA_FREE;
1977                 current_position = current_camera_offset;
1978         }
1979         else
1980         {
1981                 if ( camera_mode == CAMERA_FREE )
1982                 {
1983                         current_origin = view_origin;
1984                         camera_offset = camera_offset - current_origin;
1985                         current_camera_offset = current_camera_offset - current_origin;
1986                 }
1987
1988                 camera_mode = CAMERA_CHASE;
1989
1990                 if(autocvar_camera_chase_smoothly)
1991                         current_origin += (view_origin - current_origin) * attenuation;
1992                 else
1993                         current_origin = view_origin;
1994
1995                 current_position = current_origin + current_camera_offset;
1996         }
1997
1998         setproperty(VF_ANGLES, current_angles);
1999         setproperty(VF_ORIGIN, current_position);
2000 }