qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79 { \
  80         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  81         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  82 } MACRO_END
  83
  84 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  85 { \
  86         float __f = 0; lowpass(value, frac, ref_store, __f); \
  87         ret = (value) - __f; \
  88 } MACRO_END
  89
  90 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  91 { \
  92         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  93         ret = (value) - __f; \
  94 } MACRO_END
  95
  96 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  97 { \
  98         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  99         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 100 } MACRO_END
 101
 102 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
 103 { \
 104         highpass(value.x, frac, ref_store.x, ref_out.x); \
 105         highpass(value.y, frac, ref_store.y, ref_out.y); \
 106 } MACRO_END
 107
 108 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 109 { \
 110         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 111         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 112 } MACRO_END
 113
 114 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115 { \
 116         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 117         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 118         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 119 } MACRO_END
 120
 121 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 122 { \
 123         highpass(value.x, frac, ref_store.x, ref_out.x); \
 124         highpass(value.y, frac, ref_store.y, ref_out.y); \
 125         highpass(value.z, frac, ref_store.z, ref_out.z); \
 126 } MACRO_END
 127
 128 void calc_followmodel_ofs(entity view)
 129 {
 130         if(cl_followmodel_time == time)
 131                 return; // cl_followmodel_ofs already calculated for this frame
 132
 133         float frac;
 134         vector gunorg = '0 0 0';
 135         static vector vel_average;
 136         static vector gunorg_adjustment_highpass;
 137         static vector gunorg_adjustment_lowpass;
 138
 139         vector vel;
 140         if (autocvar_cl_followmodel_velocity_absolute)
 141                 vel = view.velocity;
 142         else
 143         {
 144                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 145                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 146                 vel.x = view.velocity * forward;
 147                 vel.y = view.velocity * right * -1;
 148                 vel.z = view.velocity * up;
 149         }
 150
 151         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 152         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 153         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 154
 155         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 156         lowpass3(vel, frac, vel_average, gunorg);
 157
 158         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 159
 160         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 161         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 162         frac = avg_factor(autocvar_cl_followmodel_highpass);
 163         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 164         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 165         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 166
 167         if (autocvar_cl_followmodel_velocity_absolute)
 168         {
 169                 vector fixed_gunorg;
 170                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 171                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 172                 fixed_gunorg.x = gunorg * forward;
 173                 fixed_gunorg.y = gunorg * right * -1;
 174                 fixed_gunorg.z = gunorg * up;
 175                 gunorg = fixed_gunorg;
 176         }
 177
 178         cl_followmodel_ofs = gunorg;
 179         cl_followmodel_time = time;
 180 }
 181
 182 vector leanmodel_ofs(entity view)
 183 {
 184         float frac;
 185         vector gunangles = '0 0 0';
 186         static vector gunangles_prev = '0 0 0';
 187         static vector gunangles_highpass = '0 0 0';
 188         static vector gunangles_adjustment_highpass;
 189         static vector gunangles_adjustment_lowpass;
 190
 191         if (view.csqcmodel_teleported)
 192                 gunangles_prev = view_angles;
 193
 194         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 195         gunangles_highpass += gunangles_prev;
 196         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 197         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 198         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 199         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 200         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 201         gunangles_prev = view_angles;
 202         gunangles_highpass -= gunangles_prev;
 203
 204         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 205         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 206
 207         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 208         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 209         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 210         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 211         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 212
 213         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 214
 215         return gunangles;
 216 }
 217
 218 vector bobmodel_ofs(entity view)
 219 {
 220         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 221         static bool oldonground;
 222         static float hitgroundtime;
 223         if (clonground)
 224         {
 225                 float f = time; // cl.movecmd[0].time
 226                 if (!oldonground)
 227                         hitgroundtime = f;
 228         }
 229         oldonground = clonground;
 230
 231         // calculate for swinging gun model
 232         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 233         vector gunorg = '0 0 0';
 234         static float bobmodel_scale = 0;
 235         static float time_ofs = 0; // makes the effect always restart in the same way
 236         if (clonground)
 237         {
 238                 if (time - hitgroundtime > 0.05)
 239                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 240         }
 241         else
 242                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 243
 244         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 245         if (bobmodel_scale && xyspeed)
 246         {
 247                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 248                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 249                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 250                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 251         }
 252         else
 253                 time_ofs = time;
 254
 255         return gunorg;
 256 }
 257
 258 void viewmodel_animate(entity this)
 259 {
 260         if (autocvar_chase_active) return;
 261         if (STAT(HEALTH) <= 0) return;
 262
 263         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 264
 265         if (autocvar_cl_followmodel)
 266         {
 267                 calc_followmodel_ofs(view);
 268                 this.origin += cl_followmodel_ofs;
 269         }
 270
 271         if (autocvar_cl_leanmodel)
 272                 this.angles += leanmodel_ofs(view);
 273
 274         // vertical view bobbing code
 275         // TODO: cl_bob
 276
 277         // horizontal view bobbing code
 278         // TODO: cl_bob2
 279
 280         // fall bobbing code
 281         // causes the view to swing down and back up when touching the ground
 282         // TODO: cl_bobfall
 283
 284         // gun model bobbing code
 285         if (autocvar_cl_bobmodel)
 286                 this.origin += bobmodel_ofs(view);
 287 }
 288
 289 .vector viewmodel_origin, viewmodel_angles;
 290 .float weapon_nextthink;
 291 .float weapon_eta_last;
 292 .float weapon_switchdelay;
 293
 294 .string name_last;
 295
 296 void viewmodel_draw(entity this)
 297 {
 298         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 299                 return;
 300         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 301         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 302         bool invehicle = player_localentnum > maxclients;
 303         if (invehicle) a = -1;
 304         Weapon wep = this.activeweapon;
 305         int c = entcs_GetClientColors(current_player);
 306         vector g = weaponentity_glowmod(wep, NULL, c, this);
 307         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 308         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 309                 | EF_NODEPTHTEST)
 310                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 311         for (entity e = this; e; e = e.weaponchild)
 312         {
 313                 e.drawmask = mask;
 314                 e.alpha = a;
 315                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 316                 e.glowmod = g;
 317                 e.csqcmodel_effects = fx;
 318                 CSQCModel_Effects_Apply(e);
 319         }
 320         if(a >= 0)
 321         {
 322                 string name = wep.mdl;
 323                 string newname = wep.wr_viewmodel(wep, this);
 324                 if(newname)
 325                         name = newname;
 326                 bool swap = name != this.name_last;
 327                 // if (swap)
 328                 {
 329                         this.name_last = name;
 330                         CL_WeaponEntity_SetModel(this, name, swap);
 331                         this.viewmodel_origin = this.origin;
 332                         this.viewmodel_angles = this.angles;
 333                 }
 334                 anim_update(this);
 335                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 336                         anim_set(this, this.anim_idle, true, false, false);
 337         }
 338         float f = 0; // 0..1; 0: fully active
 339         float rate = STAT(WEAPONRATEFACTOR);
 340         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 341         if (eta <= 0) f = this.weapon_eta_last;
 342         else switch (this.state)
 343         {
 344                 case WS_RAISE:
 345                 {
 346                         f = eta / max(eta, this.weapon_switchdelay);
 347                         break;
 348                 }
 349                 case WS_DROP:
 350                 {
 351                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 352                         break;
 353                 }
 354                 case WS_CLEAR:
 355                 {
 356                         f = 1;
 357                         break;
 358                 }
 359         }
 360         this.weapon_eta_last = f;
 361         this.origin = this.viewmodel_origin;
 362         this.angles = this.viewmodel_angles;
 363         this.angles_x = (-90 * f * f);
 364         viewmodel_animate(this);
 365         MUTATOR_CALLHOOK(DrawViewModel, this);
 366         setorigin(this, this.origin);
 367 }
 368
 369 STATIC_INIT(viewmodel) {
 370     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 371         viewmodels[slot] = new(viewmodel);
 372 }
 373
 374 float showfps_prevfps;
 375 float showfps_prevfps_time;
 376 int showfps_framecounter;
 377
 378 void fpscounter_update()
 379 {
 380         if(!STAT(SHOWFPS))
 381                 return;
 382
 383         float currentTime = gettime(GETTIME_REALTIME);
 384         showfps_framecounter += 1;
 385         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 386         {
 387                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 388                 showfps_framecounter = 0;
 389                 showfps_prevfps_time = currentTime;
 390
 391                 int channel = MSG_C2S;
 392                 WriteHeader(channel, fpsreport);
 393                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 394         }
 395 }
 396
 397 STATIC_INIT(fpscounter_init)
 398 {
 399         float currentTime = gettime(GETTIME_REALTIME);
 400         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 401 }
 402
 403 STATIC_INIT(Porto)
 404 {
 405         entity e = new_pure(porto);
 406         e.draw = Porto_Draw;
 407         IL_PUSH(g_drawables, e);
 408         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 409 }
 410
 411 const int polyline_length = 16;
 412 .vector polyline[polyline_length];
 413 void Porto_Draw(entity this)
 414 {
 415         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 416         {
 417                 entity wepent = viewmodels[slot];
 418
 419                 if (wepent.activeweapon != WEP_PORTO) continue;
 420                 if (spectatee_status) continue;
 421                 if (WEP_CVAR(porto, secondary)) continue;
 422                 if (intermission == 1) continue;
 423                 if (intermission == 2) continue;
 424                 if (STAT(HEALTH) <= 0) continue;
 425
 426                 vector pos = view_origin;
 427                 vector dir = view_forward;
 428                 makevectors(((autocvar_chase_active) ? warpzone_save_view_angles : view_angles));
 429                 pos += v_right * -wepent.movedir.y
 430                         +  v_up * wepent.movedir.z;
 431
 432                 if (wepent.angles_held_status)
 433                 {
 434                         makevectors(wepent.angles_held);
 435                         dir = v_forward;
 436                 }
 437
 438                 wepent.polyline[0] = pos;
 439
 440                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 441                 int n = 1 + 2;  // 2 lines == 3 points
 442                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 443                 {
 444                         traceline(pos, pos + 65536 * dir, true, this);
 445                         dir = reflect(dir, trace_plane_normal);
 446                         pos = trace_endpos;
 447                         wepent.polyline[++idx] = pos;
 448                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 449                         {
 450                                 n += 1;
 451                                 continue;
 452                         }
 453                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 454                         {
 455                                 n = max(2, idx);
 456                                 break;
 457                         }
 458                         // check size
 459                         {
 460                                 vector ang = vectoangles2(trace_plane_normal, dir);
 461                                 ang.x = -ang.x;
 462                                 makevectors(ang);
 463                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 464                                 {
 465                                         n = max(2, idx);
 466                                         break;
 467                                 }
 468                         }
 469                         portal_number += 1;
 470                         if (portal_number >= portal_max) break;
 471                         if (portal_number == 1) portal1_idx = idx;
 472                 }
 473                 for (int idx = 0; idx < n - 1; ++idx)
 474                 {
 475                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 476                         if (idx == 0) p -= view_up * 16;  // line from player
 477                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 478                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 479                 }
 480         }
 481 }
 482
 483 float drawtime;
 484 float avgspeed;
 485 vector GetCurrentFov(float fov)
 486 {
 487         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 488         float velocityzoom, curspeed;
 489         vector v;
 490
 491         zoomsensitivity = autocvar_cl_zoomsensitivity;
 492         zoomfactor = autocvar_cl_zoomfactor;
 493         if(zoomfactor < 1 || zoomfactor > 30)
 494                 zoomfactor = 2.5;
 495         zoomspeed = autocvar_cl_zoomspeed;
 496         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 497                 zoomspeed = 3.5;
 498
 499         zoomdir = button_zoom;
 500
 501         if(hud == HUD_NORMAL && !spectatee_status)
 502         {
 503                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 504                 {
 505                         entity wepent = viewmodels[slot];
 506                         if(wepent.switchweapon != wepent.activeweapon)
 507                                 continue;
 508                         Weapon wep = wepent.activeweapon;
 509                         if(wep != WEP_Null && wep.wr_zoomdir)
 510                         {
 511                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 512                                 zoomdir += do_zoom;
 513                         }
 514                 }
 515         }
 516         if(spectatee_status > 0 || isdemo())
 517         {
 518                 if(spectatorbutton_zoom)
 519                 {
 520                         if(zoomdir)
 521                                 zoomdir = 0;
 522                         else
 523                                 zoomdir = 1;
 524                 }
 525                 // fteqcc failed twice here already, don't optimize this
 526         }
 527
 528         if(zoomdir) { zoomin_effect = 0; }
 529
 530         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 531         {
 532                 current_viewzoom = 1;
 533         }
 534         else if (camera_active)
 535         {
 536                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 537         }
 538         else if(autocvar_cl_spawnzoom && zoomin_effect)
 539         {
 540                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 541
 542                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 543                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 544                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 545         }
 546         else
 547         {
 548                 if(zoomspeed < 0) // instant zoom
 549                 {
 550                         if(zoomdir)
 551                                 current_viewzoom = 1 / zoomfactor;
 552                         else
 553                                 current_viewzoom = 1;
 554                 }
 555                 else
 556                 {
 557                         if(zoomdir)
 558                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 559                         else
 560                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 561                 }
 562         }
 563
 564         if(almost_equals(current_viewzoom, 1))
 565                 current_zoomfraction = 0;
 566         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 567                 current_zoomfraction = 1;
 568         else
 569                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 570
 571         if(zoomsensitivity < 1)
 572                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 573         else
 574                 setsensitivityscale(1);
 575
 576         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 577         {
 578                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 579                         curspeed = 0;
 580                 else
 581                 {
 582                         makevectors(view_angles);
 583                         v = pmove_vel;
 584                         if(csqcplayer)
 585                                 v = csqcplayer.velocity;
 586
 587                         switch(autocvar_cl_velocityzoom_type)
 588                         {
 589                                 case 3: curspeed = max(0, v_forward * v); break;
 590                                 case 2: curspeed = (v_forward * v); break;
 591                                 case 1: default: curspeed = vlen(v); break;
 592                         }
 593                 }
 594
 595                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 596                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 597                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 598
 599                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 600         }
 601         else
 602                 velocityzoom = 1;
 603
 604         float frustumx, frustumy, fovx, fovy;
 605         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 606         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 607         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 608         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 609
 610         return '1 0 0' * fovx + '0 1 0' * fovy;
 611 }
 612
 613 vector GetViewLocationFOV(float fov)
 614 {
 615         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 616         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 617         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 618         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 619         return '1 0 0' * fovx + '0 1 0' * fovy;
 620 }
 621
 622 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 623 {
 624         float fovx, fovy;
 625         float width = (ov_worldmax.x - ov_worldmin.x);
 626         float height = (ov_worldmax.y - ov_worldmin.y);
 627         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 628         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 629         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 630         return '1 0 0' * fovx + '0 1 0' * fovy;
 631 }
 632
 633 // this function must match W_SetupShot!
 634 float zoomscript_caught;
 635
 636 vector wcross_origin;
 637 float wcross_scale_prev, wcross_alpha_prev;
 638 vector wcross_color_prev;
 639 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 640 vector wcross_color_goal_prev;
 641 float wcross_changedonetime;
 642
 643 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 644 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 645 float wcross_name_changestarttime, wcross_name_changedonetime;
 646 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 647
 648 float wcross_ring_prev;
 649
 650 entity trueaim;
 651 entity trueaim_rifle;
 652
 653 const float SHOTTYPE_HITTEAM = 1;
 654 const float SHOTTYPE_HITOBSTRUCTION = 2;
 655 const float SHOTTYPE_HITWORLD = 3;
 656 const float SHOTTYPE_HITENEMY = 4;
 657
 658 void TrueAim_Init()
 659 {
 660         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 661         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 662 }
 663
 664 float EnemyHitCheck()
 665 {
 666         float t, n;
 667         wcross_origin = project_3d_to_2d(trace_endpos);
 668         wcross_origin.z = 0;
 669         if(trace_ent)
 670                 n = trace_ent.entnum;
 671         else
 672                 n = trace_networkentity;
 673         if(n < 1)
 674                 return SHOTTYPE_HITWORLD;
 675         if(n > maxclients)
 676                 return SHOTTYPE_HITWORLD;
 677         t = entcs_GetTeam(n - 1);
 678         if(teamplay)
 679                 if(t == myteam)
 680                         return SHOTTYPE_HITTEAM;
 681         if(t == NUM_SPECTATOR)
 682                 return SHOTTYPE_HITWORLD;
 683         return SHOTTYPE_HITENEMY;
 684 }
 685
 686 float TrueAimCheck(entity wepent)
 687 {
 688         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 689         vector vecs, trueaimpoint, w_shotorg;
 690         vector mi, ma, dv;
 691         float shottype;
 692         entity ta;
 693         float mv;
 694
 695         mi = ma = '0 0 0';
 696         ta = trueaim;
 697         mv = MOVE_NOMONSTERS;
 698
 699         switch(wepent.activeweapon) // WEAPONTODO
 700         {
 701                 case WEP_TUBA: // no aim
 702                 case WEP_PORTO: // shoots from eye
 703                 case WEP_NEXBALL: // shoots from eye
 704                 case WEP_HOOK: // no trueaim
 705                 case WEP_MORTAR: // toss curve
 706                         return SHOTTYPE_HITWORLD;
 707                 case WEP_VORTEX:
 708                 case WEP_OVERKILL_NEX:
 709                 case WEP_VAPORIZER:
 710                         mv = MOVE_NORMAL;
 711                         break;
 712                 case WEP_RIFLE:
 713                         ta = trueaim_rifle;
 714                         mv = MOVE_NORMAL;
 715                         if(zoomscript_caught)
 716                         {
 717                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 718                                 return EnemyHitCheck();
 719                         }
 720                         break;
 721                 case WEP_DEVASTATOR: // projectile has a size!
 722                         mi = '-3 -3 -3';
 723                         ma = '3 3 3';
 724                         break;
 725                 case WEP_FIREBALL: // projectile has a size!
 726                         mi = '-16 -16 -16';
 727                         ma = '16 16 16';
 728                         break;
 729                 case WEP_SEEKER: // projectile has a size!
 730                         mi = '-2 -2 -2';
 731                         ma = '2 2 2';
 732                         break;
 733                 case WEP_ELECTRO: // projectile has a size!
 734                         mi = '0 0 -3';
 735                         ma = '0 0 -3';
 736                         break;
 737         }
 738
 739         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 740
 741         vecs = decompressShotOrigin(STAT(SHOTORG));
 742
 743         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 744         trueaimpoint = trace_endpos;
 745
 746         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 747                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 748
 749         if(vecs.x > 0)
 750                 vecs.y = -vecs.y;
 751         else
 752                 vecs = '0 0 0';
 753
 754         dv = view_right * vecs.y + view_up * vecs.z;
 755         w_shotorg = traceorigin + dv;
 756
 757         // now move the vecs forward as much as requested if possible
 758         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 759         w_shotorg = trace_endpos - view_forward * nudge;
 760
 761         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 762         shottype = EnemyHitCheck();
 763         if(shottype != SHOTTYPE_HITWORLD)
 764                 return shottype;
 765
 766 #if 0
 767         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 768         // or rather, I know why, but see no fix
 769         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 770                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 771                 return SHOTTYPE_HITOBSTRUCTION;
 772 #endif
 773
 774         return SHOTTYPE_HITWORLD;
 775 }
 776
 777 float camera_mode;
 778 const float CAMERA_FREE = 1;
 779 const float CAMERA_CHASE = 2;
 780 float reticle_type;
 781 string NextFrameCommand;
 782
 783 vector freeze_org, freeze_ang;
 784 entity nightvision_noise, nightvision_noise2;
 785
 786 const float MAX_TIME_DIFF = 5;
 787 float pickup_crosshair_time, pickup_crosshair_size;
 788 float hitindication_crosshair_size;
 789 float use_vortex_chargepool;
 790
 791 float myhealth, myhealth_prev;
 792 float myhealth_flash;
 793
 794 float old_blurradius, old_bluralpha;
 795 float old_sharpen_intensity;
 796
 797 vector myhealth_gentlergb;
 798
 799 float contentavgalpha, liquidalpha_prev;
 800 vector liquidcolor_prev;
 801
 802 float eventchase_current_distance;
 803 float eventchase_running;
 804 bool WantEventchase(entity this)
 805 {
 806         if(autocvar_cl_orthoview)
 807                 return false;
 808         if(STAT(GAME_STOPPED) || intermission)
 809                 return true;
 810         if(this.viewloc)
 811                 return true;
 812         if(spectatee_status >= 0)
 813         {
 814                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 815                         return true;
 816                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 817                         return true;
 818                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 819                         return true;
 820                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 821                 {
 822                         if(autocvar_cl_eventchase_death == 2)
 823                         {
 824                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 825                                 if(this.velocity == '0 0 0' || eventchase_running)
 826                                         return true;
 827                         }
 828                         else return true;
 829                 }
 830         }
 831         return false;
 832 }
 833
 834 void HUD_Crosshair_Vehicle(entity this)
 835 {
 836         if(hud != HUD_BUMBLEBEE_GUN)
 837         {
 838                 Vehicle info = Vehicles_from(hud);
 839                 info.vr_crosshair(info, this);
 840         }
 841 }
 842
 843 vector damage_blurpostprocess, content_blurpostprocess;
 844
 845 float unaccounted_damage = 0;
 846 void UpdateDamage()
 847 {
 848         // accumulate damage with each stat update
 849         static float damage_total_prev = 0;
 850         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 851         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 852         damage_total_prev = damage_total;
 853
 854         static float damage_dealt_time_prev = 0;
 855         float damage_dealt_time = STAT(HIT_TIME);
 856         if (damage_dealt_time != damage_dealt_time_prev)
 857         {
 858                 unaccounted_damage += unaccounted_damage_new;
 859                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 860         }
 861         damage_dealt_time_prev = damage_dealt_time;
 862
 863         // prevent hitsound when switching spectatee
 864         static float spectatee_status_prev = 0;
 865         if (spectatee_status != spectatee_status_prev)
 866                 unaccounted_damage = 0;
 867         spectatee_status_prev = spectatee_status;
 868 }
 869
 870 void HitSound()
 871 {
 872         // varying sound pitch
 873
 874         bool have_arc = false;
 875         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 876         {
 877                 entity wepent = viewmodels[slot];
 878
 879                 if(wepent.activeweapon == WEP_ARC)
 880                         have_arc = true;
 881         }
 882
 883         static float hitsound_time_prev = 0;
 884         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 885         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 886         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 887         {
 888                 if (autocvar_cl_hitsound && unaccounted_damage)
 889                 {
 890                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 891                         float a = autocvar_cl_hitsound_max_pitch;
 892                         float b = autocvar_cl_hitsound_min_pitch;
 893                         float c = autocvar_cl_hitsound_nom_damage;
 894                         float d = unaccounted_damage;
 895                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 896
 897                         // if sound variation is disabled, set pitch_shift to 1
 898                         if (autocvar_cl_hitsound == 1)
 899                                 pitch_shift = 1;
 900
 901                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 902                         if (autocvar_cl_hitsound == 3)
 903                         {
 904                                 float mirror_value = (a-b)/2 + b;
 905                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 906                         }
 907
 908                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 909
 910                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 911                         // todo: normalize sound pressure levels? seems unnecessary
 912
 913                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 914                 }
 915                 unaccounted_damage = 0;
 916                 hitsound_time_prev = time;
 917         }
 918
 919         static float typehit_time_prev = 0;
 920         float typehit_time = STAT(TYPEHIT_TIME);
 921         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 922         {
 923                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 924                 typehit_time_prev = typehit_time;
 925         }
 926
 927         static float kill_time_prev = 0;
 928         float kill_time = STAT(KILL_TIME);
 929         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 930         {
 931                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 932                 kill_time_prev = kill_time;
 933         }
 934 }
 935
 936 vector crosshair_getcolor(entity this, float health_stat)
 937 {
 938         static float rainbow_last_flicker;
 939         static vector rainbow_prev_color;
 940         vector wcross_color = '0 0 0';
 941         switch(autocvar_crosshair_color_special)
 942         {
 943                 case 1: // crosshair_color_per_weapon
 944                 {
 945                         if(this != WEP_Null && hud == HUD_NORMAL)
 946                         {
 947                                 wcross_color = this.wpcolor;
 948                                 break;
 949                         }
 950                         else { goto normalcolor; }
 951                 }
 952
 953                 case 2: // crosshair_color_by_health
 954                 {
 955                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 956                         float hp = floor(v.x + 1);
 957
 958                         //x = red
 959                         //y = green
 960                         //z = blue
 961
 962                         wcross_color.z = 0;
 963
 964                         if(hp > 200)
 965                         {
 966                                 wcross_color.x = 0;
 967                                 wcross_color.y = 1;
 968                         }
 969                         else if(hp > 150)
 970                         {
 971                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 972                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 973                         }
 974                         else if(hp > 100)
 975                         {
 976                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 977                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 978                                 wcross_color.z = 1 - (hp-100)*0.02;
 979                         }
 980                         else if(hp > 50)
 981                         {
 982                                 wcross_color.x = 1;
 983                                 wcross_color.y = 1;
 984                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 985                         }
 986                         else if(hp > 20)
 987                         {
 988                                 wcross_color.x = 1;
 989                                 wcross_color.y = (hp-20)*90/27/100;
 990                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 991                         }
 992                         else
 993                         {
 994                                 wcross_color.x = 1;
 995                                 wcross_color.y = 0;
 996                         }
 997                         break;
 998                 }
 999
1000                 case 3: // crosshair_color_rainbow
1001                 {
1002                         if(time >= rainbow_last_flicker)
1003                         {
1004                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1005                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1006                         }
1007                         wcross_color = rainbow_prev_color;
1008                         break;
1009                 }
1010 LABEL(normalcolor)
1011                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1012         }
1013
1014         return wcross_color;
1015 }
1016
1017 void HUD_Crosshair(entity this)
1018 {
1019         float f, i, j;
1020         vector v;
1021         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
1022                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
1023                 !HUD_MinigameMenu_IsOpened() )
1024         {
1025                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1026                         return;
1027
1028                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
1029                         return;
1030
1031                 if (hud != HUD_NORMAL)
1032                 {
1033                         HUD_Crosshair_Vehicle(this);
1034                         return;
1035                 }
1036
1037                 string wcross_style;
1038                 float wcross_alpha, wcross_resolution;
1039                 wcross_style = autocvar_crosshair;
1040                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1041                         wcross_style = autocvar_crosshair_2d;
1042                 if (wcross_style == "0")
1043                         return;
1044                 wcross_resolution = autocvar_crosshair_size;
1045                 if (wcross_resolution == 0)
1046                         return;
1047                 wcross_alpha = autocvar_crosshair_alpha;
1048                 if (wcross_alpha == 0)
1049                         return;
1050
1051                 // TrueAim check
1052                 float shottype;
1053
1054                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1055                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1056                         wcross_origin = viewloc_mousepos;
1057                 else
1058                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1059                 wcross_origin.z = 0;
1060                 if(autocvar_crosshair_hittest)
1061                 {
1062                         vector wcross_oldorigin;
1063                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1064                         wcross_oldorigin = wcross_origin;
1065                         shottype = TrueAimCheck(thiswep);
1066                         if(shottype == SHOTTYPE_HITWORLD)
1067                         {
1068                                 v = wcross_origin - wcross_oldorigin;
1069                                 v.x /= vid_conwidth;
1070                                 v.y /= vid_conheight;
1071                                 if(vdist(v, >, 0.01))
1072                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1073                         }
1074                         if(!autocvar_crosshair_hittest_showimpact)
1075                                 wcross_origin = wcross_oldorigin;
1076                 }
1077                 else
1078                         shottype = SHOTTYPE_HITWORLD;
1079
1080                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1081                 string wcross_name = "";
1082                 float wcross_scale, wcross_blur;
1083
1084         entity e = WEP_Null;
1085                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1086                 {
1087                         entity wepent = viewmodels[0]; // TODO: unhardcode
1088                         e = wepent.switchingweapon;
1089                         if(e)
1090                         {
1091                                 if(autocvar_crosshair_per_weapon)
1092                                 {
1093                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1094                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1095                                         //if (wcross_resolution == 0)
1096                                                 //return;
1097
1098                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1099                                         wcross_resolution *= e.w_crosshair_size;
1100                                         wcross_name = e.w_crosshair;
1101                                 }
1102                         }
1103                 }
1104
1105                 if(wcross_name == "")
1106                         wcross_name = strcat("gfx/crosshair", wcross_style);
1107
1108                 // MAIN CROSSHAIR COLOR DECISION
1109                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1110
1111                 if(autocvar_crosshair_effect_scalefade)
1112                 {
1113                         wcross_scale = wcross_resolution;
1114                         wcross_resolution = 1;
1115                 }
1116                 else
1117                 {
1118                         wcross_scale = 1;
1119                 }
1120
1121                 if(autocvar_crosshair_pickup)
1122                 {
1123                         float stat_pickup_time = STAT(LAST_PICKUP);
1124
1125                         if(pickup_crosshair_time < stat_pickup_time)
1126                         {
1127                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1128                                         pickup_crosshair_size = 1;
1129
1130                                 pickup_crosshair_time = stat_pickup_time;
1131                         }
1132
1133                         if(pickup_crosshair_size > 0)
1134                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1135                         else
1136                                 pickup_crosshair_size = 0;
1137
1138                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1139                 }
1140
1141                 // todo: make crosshair hit indication dependent on damage dealt
1142                 if(autocvar_crosshair_hitindication)
1143                 {
1144                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1145
1146                         if(unaccounted_damage)
1147                         {
1148                                 hitindication_crosshair_size = 1;
1149                         }
1150
1151                         if(hitindication_crosshair_size > 0)
1152                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1153                         else
1154                                 hitindication_crosshair_size = 0;
1155
1156                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1157                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1158                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1159                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1160                 }
1161
1162                 if(shottype == SHOTTYPE_HITENEMY)
1163                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1164                 if(shottype == SHOTTYPE_HITTEAM)
1165                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1166
1167                 f = fabs(autocvar_crosshair_effect_time);
1168                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1169                 {
1170                         wcross_changedonetime = time + f;
1171                 }
1172                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1173                 {
1174                         wcross_name_changestarttime = time;
1175                         wcross_name_changedonetime = time + f;
1176                         if(wcross_name_goal_prev_prev)
1177                                 strunzone(wcross_name_goal_prev_prev);
1178                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1179                         wcross_name_goal_prev = strzone(wcross_name);
1180                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1181                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1182                         wcross_resolution_goal_prev = wcross_resolution;
1183                 }
1184
1185                 wcross_scale_goal_prev = wcross_scale;
1186                 wcross_alpha_goal_prev = wcross_alpha;
1187                 wcross_color_goal_prev = wcross_color;
1188
1189                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1190                 {
1191                         wcross_blur = 1;
1192                         wcross_alpha *= 0.75;
1193                 }
1194                 else
1195                         wcross_blur = 0;
1196                 // *_prev is at time-frametime
1197                 // * is at wcross_changedonetime+f
1198                 // what do we have at time?
1199                 if(time < wcross_changedonetime)
1200                 {
1201                         f = frametime / (wcross_changedonetime - time + frametime);
1202                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1203                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1204                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1205                 }
1206
1207                 wcross_scale_prev = wcross_scale;
1208                 wcross_alpha_prev = wcross_alpha;
1209                 wcross_color_prev = wcross_color;
1210
1211                 MUTATOR_CALLHOOK(UpdateCrosshair);
1212
1213                 wcross_scale *= 1 - autocvar__menu_alpha;
1214                 wcross_alpha *= 1 - autocvar__menu_alpha;
1215                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1216
1217                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1218                 {
1219                         // crosshair rings for weapon stats
1220                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1221                         {
1222                                 // declarations and stats
1223                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1224                                 string ring_image = string_null, ring_inner_image = string_null;
1225                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1226
1227                                 ring_scale = autocvar_crosshair_ring_size;
1228
1229                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1230
1231                                 int weapon_clipload = wepent.clip_load;
1232                                 int weapon_clipsize = wepent.clip_size;
1233
1234                                 float arc_heat = wepent.arc_heat_percent;
1235                                 float vcharge = wepent.vortex_charge;
1236                                 float vchargepool = wepent.vortex_chargepool_ammo;
1237                                 float oknex_charge_ = wepent.oknex_charge;
1238                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1239
1240                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1241                                         vortex_charge_movingavg = vcharge;
1242
1243                                 // handle the values
1244                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1245                                 {
1246                                         if (vchargepool || use_vortex_chargepool) {
1247                                                 use_vortex_chargepool = 1;
1248                                                 ring_inner_value = vchargepool;
1249                                         } else {
1250                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1251                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1252                                         }
1253
1254                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1255                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1256                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1257
1258                                         // draw the outer ring to show the current charge of the weapon
1259                                         ring_value = vcharge;
1260                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1261                                         ring_rgb = wcross_color;
1262                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1263                                 }
1264                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1265                                 {
1266                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1267                                                 use_vortex_chargepool = 1;
1268                                                 ring_inner_value = oknex_chargepool_;
1269                                         } else {
1270                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1271                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1272                                         }
1273
1274                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1275                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1276                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1277
1278                                         // draw the outer ring to show the current charge of the weapon
1279                                         ring_value = oknex_charge_;
1280                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1281                                         ring_rgb = wcross_color;
1282                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1283                                 }
1284                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1285                                 {
1286                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1287                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1288                                         ring_rgb = wcross_color;
1289                                         ring_image = "gfx/crosshair_ring.tga";
1290                                 }
1291                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1292                                 {
1293                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1294                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1295                                         ring_rgb = wcross_color;
1296                                         ring_image = "gfx/crosshair_ring.tga";
1297                                 }
1298                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1299                                 {
1300                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1301                                         ring_scale = autocvar_crosshair_ring_reload_size;
1302                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1303                                         ring_rgb = wcross_color;
1304
1305                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1306                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1307                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1308                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1309                                         else
1310                                                 ring_image = "gfx/crosshair_ring.tga";
1311                                 }
1312                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1313                                 {
1314                                         ring_value = arc_heat;
1315                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1316                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1317                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1318                                         ring_image = "gfx/crosshair_ring.tga";
1319                                 }
1320
1321                                 // if in weapon switch animation, fade ring out/in
1322                                 if(autocvar_crosshair_effect_time > 0)
1323                                 {
1324                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1325                                         if (f >= 1)
1326                                         {
1327                                                 wcross_ring_prev = ((ring_image) ? true : false);
1328                                         }
1329
1330                                         if(wcross_ring_prev)
1331                                         {
1332                                                 if(f < 1)
1333                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1334                                         }
1335                                         else
1336                                         {
1337                                                 if(f < 1)
1338                                                         ring_alpha *= bound(0, f, 1);
1339                                         }
1340                                 }
1341
1342                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1343                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1344
1345                                 if (ring_value)
1346                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1347                         }
1348
1349 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1350                         MACRO_BEGIN { \
1351                                 if(wcross_blur > 0) \
1352                                 { \
1353                                         for(i = -2; i <= 2; ++i) \
1354                                         for(j = -2; j <= 2; ++j) \
1355                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1356                                 } \
1357                                 else \
1358                                 { \
1359                                         M(0,0,sz,wcross_name,wcross_alpha); \
1360                                 } \
1361                         } MACRO_END
1362
1363 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1364                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1365
1366 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1367                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1368
1369                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1370                         {
1371                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1372                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1373                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1374                                 f = 1 - f;
1375                         }
1376                         else
1377                         {
1378                                 f = 1;
1379                         }
1380                         wcross_name_alpha_goal_prev = f;
1381
1382                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1383                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1384
1385                         if(autocvar_crosshair_dot)
1386                         {
1387                                 vector wcross_color_old;
1388                                 wcross_color_old = wcross_color;
1389
1390                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1391                                         wcross_color = stov(autocvar_crosshair_dot_color);
1392
1393                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1394                                 // FIXME why don't we use wcross_alpha here?
1395                                 wcross_color = wcross_color_old;
1396                         }
1397                 }
1398         }
1399         else
1400         {
1401                 wcross_scale_prev = 0;
1402                 wcross_alpha_prev = 0;
1403                 wcross_scale_goal_prev = 0;
1404                 wcross_alpha_goal_prev = 0;
1405                 wcross_changedonetime = 0;
1406                 strfree(wcross_name_goal_prev);
1407                 strfree(wcross_name_goal_prev_prev);
1408                 wcross_name_changestarttime = 0;
1409                 wcross_name_changedonetime = 0;
1410                 wcross_name_alpha_goal_prev = 0;
1411                 wcross_name_alpha_goal_prev_prev = 0;
1412                 wcross_resolution_goal_prev = 0;
1413                 wcross_resolution_goal_prev_prev = 0;
1414         }
1415 }
1416
1417 const int MAX_SPECIALCOMMAND = 15;
1418 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1419 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1420 const float SPECIALCOMMAND_SPEED = 150;
1421 const float SPECIALCOMMAND_TURNSPEED = 2;
1422 const float SPECIALCOMMAND_SIZE = 0.025;
1423 const float SPECIALCOMMAND_CHANCE = 0.35;
1424 float sc_spawntime, sc_changetime;
1425 vector sc_color = '1 1 1';
1426 void SpecialCommand()
1427 {
1428         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1429                 return;
1430
1431         if(time >= sc_changetime)
1432         {
1433                 sc_changetime = time + 1;
1434                 sc_color = randomvec() * 1.5;
1435                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1436                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1437                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1438         }
1439         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1440
1441         if(!precache_pic("gfx/smile"))
1442                 return; // damn party poopers
1443
1444         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1445         {
1446                 vector slot = specialcommand_slots[j];
1447                 if(slot.y)
1448                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1449                 //if(slot.z)
1450                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1451                 if(slot.y >= vid_conheight)
1452                         slot = '0 0 0';
1453
1454                 if(slot == '0 0 0')
1455                 {
1456                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1457                         {
1458                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1459                                 slot.y = 1; // start it off 0 so we can use it
1460                                 slot.z = floor(random() * Weapons_MAX);
1461                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1462                                 vector newcolor = randomvec() * 2;
1463                                 newcolor.x = bound(0.4, newcolor.x, 1);
1464                                 newcolor.y = bound(0.4, newcolor.y, 1);
1465                                 newcolor.z = bound(0.4, newcolor.z, 1);
1466                                 specialcommand_colors[j] = newcolor;
1467                         }
1468                 }
1469                 else
1470                 {
1471                         vector splash_size = '0 0 0';
1472                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1473                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1474                         entity wep = Weapons_from(slot.z);
1475                         if(wep == WEP_Null)
1476                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1477                         else
1478                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1479                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1480                 }
1481
1482                 specialcommand_slots[j] = slot;
1483         }
1484 }
1485
1486 void HUD_Draw(entity this)
1487 {
1488         // if we don't know gametype and scores yet avoid drawing the scoreboard
1489         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1490         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1491         // cl_deathscoreboard would show the scoreboard and so on
1492         if(!gametype)
1493                 return;
1494
1495         Hud_Dynamic_Frame();
1496
1497         if(!intermission)
1498         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1499         {
1500                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1501         }
1502         else if(STAT(FROZEN))
1503         {
1504                 vector col = '0.25 0.90 1';
1505                 if(STAT(REVIVE_PROGRESS))
1506                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1507                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1508         }
1509
1510         HUD_Scale_Enable();
1511         if(!intermission)
1512         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1513         {
1514                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1515                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1516                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1517         }
1518         else if(STAT(CAPTURE_PROGRESS))
1519         {
1520                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1521                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1522         }
1523         else if(STAT(REVIVE_PROGRESS))
1524         {
1525                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1526                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1527         }
1528         HUD_Scale_Disable();
1529
1530         if(autocvar_r_letterbox == 0)
1531                 if(autocvar_viewsize < 120)
1532                 {
1533                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1534                                 Accuracy_LoadLevels();
1535
1536                         HUD_Main();
1537                         HUD_Scale_Disable();
1538                 }
1539
1540         // crosshair goes VERY LAST
1541         SpecialCommand();
1542         UpdateDamage();
1543         HUD_Crosshair(this);
1544         HitSound();
1545 }
1546
1547 void ViewLocation_Mouse()
1548 {
1549         if(spectatee_status)
1550                 return; // don't draw it as spectator!
1551
1552         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1553         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1554         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1555
1556         //float cursor_alpha = 1 - autocvar__menu_alpha;
1557         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1558 }
1559
1560 bool ov_enabled;
1561 float oldr_nearclip;
1562 float oldr_farclip_base;
1563 float oldr_farclip_world;
1564 float oldr_novis;
1565 float oldr_useportalculling;
1566 float oldr_useinfinitefarclip;
1567
1568 float prev_myteam;
1569 int lasthud;
1570 float vh_notice_time;
1571 void CSQC_UpdateView(entity this, float w, float h)
1572 {
1573         TC(int, w); TC(int, h);
1574         entity e;
1575         float fov;
1576         float f;
1577         vector vf_size, vf_min;
1578         float a;
1579
1580         execute_next_frame();
1581
1582         ++framecount;
1583
1584         stats_get();
1585         hud = STAT(HUD);
1586
1587         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1588                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1589
1590         lasthud = hud;
1591
1592         HUD_Scale_Disable();
1593
1594         if(autocvar__hud_showbinds_reload) // menu can set this one
1595         {
1596                 db_close(binddb);
1597                 binddb = db_create();
1598                 cvar_set("_hud_showbinds_reload", "0");
1599         }
1600
1601         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1602                 view_quality = getproperty(VF_MINFPS_QUALITY);
1603         else
1604                 view_quality = 1;
1605
1606         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1607         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1608
1609         vf_size = getpropertyvec(VF_SIZE);
1610         vf_min = getpropertyvec(VF_MIN);
1611         vid_width = vf_size.x;
1612         vid_height = vf_size.y;
1613
1614         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1615         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1616
1617         WaypointSprite_Load();
1618
1619         CSQCPlayer_SetCamera();
1620
1621         if(player_localentnum <= maxclients) // is it a client?
1622                 current_player = player_localentnum - 1;
1623         else // then player_localentnum is the vehicle I'm driving
1624                 current_player = player_localnum;
1625         myteam = entcs_GetTeam(current_player);
1626
1627         if(myteam != prev_myteam)
1628         {
1629                 myteamcolors = colormapPaletteColor(myteam, 1);
1630                 FOREACH(hud_panels, true, it.update_time = time);
1631                 prev_myteam = myteam;
1632         }
1633
1634         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1635
1636         float is_dead = (STAT(HEALTH) <= 0);
1637
1638         // FIXME do we need this hack?
1639         if(isdemo())
1640         {
1641                 // in demos, input_buttons do not work
1642                 button_zoom = (autocvar__togglezoom == "-");
1643         }
1644         else if(button_zoom
1645                 && autocvar_cl_unpress_zoom_on_death
1646                 && (spectatee_status >= 0)
1647                 && (is_dead || intermission))
1648         {
1649                 // no zoom while dead or in intermission please
1650                 localcmd("-zoom\n");
1651                 button_zoom = false;
1652         }
1653
1654         // abused multiple places below
1655         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1656         if(!local_player)
1657                 local_player = this; // fall back!
1658
1659         // event chase camera
1660         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1661         {
1662                 if(STAT(CAMERA_SPECTATOR))
1663                 {
1664                         if(spectatee_status > 0)
1665                         {
1666                                 if(!autocvar_chase_active)
1667                                 {
1668                                         cvar_set("chase_active", "-2");
1669                                         goto skip_eventchase_death;
1670                                 }
1671                         }
1672                         else if(autocvar_chase_active == -2)
1673                                 cvar_set("chase_active", "0");
1674
1675                         if(autocvar_chase_active == -2)
1676                                 goto skip_eventchase_death;
1677                 }
1678                 else if(autocvar_chase_active == -2)
1679                         cvar_set("chase_active", "0");
1680
1681                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1682
1683                 float vehicle_viewdist = 0;
1684                 vector vehicle_viewofs = '0 0 0';
1685
1686                 if(vehicle_chase)
1687                 {
1688                         if(hud != HUD_BUMBLEBEE_GUN)
1689                         {
1690                                 Vehicle info = Vehicles_from(hud);
1691                                 vehicle_viewdist = info.height;
1692                                 vehicle_viewofs = info.view_ofs;
1693                         }
1694                 }
1695
1696                 if(WantEventchase(this))
1697                 {
1698                         vector current_view_origin_override = '0 0 0';
1699                         vector view_offset_override = '0 0 0';
1700                         float chase_distance_override = 0;
1701                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1702                         if(custom_eventchase)
1703                         {
1704                                 current_view_origin_override = M_ARGV(0, vector);
1705                                 view_offset_override = M_ARGV(1, vector);
1706                                 chase_distance_override = M_ARGV(0, float);
1707                         }
1708                         eventchase_running = true;
1709
1710                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1711                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1712                         if (custom_eventchase)
1713                                 current_view_origin = current_view_origin_override;
1714
1715                         // detect maximum viewoffset and use it
1716                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1717                         if(vehicle_chase)
1718                         {
1719                                 if(vehicle_viewofs)
1720                                         view_offset = vehicle_viewofs;
1721                                 else
1722                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1723                         }
1724                         if (custom_eventchase)
1725                                 view_offset = view_offset_override;
1726
1727                         if(view_offset)
1728                         {
1729                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1730                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1731                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1732                         }
1733
1734                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1735                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1736                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1737                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1738
1739                         // make the camera smooth back
1740                         float chase_distance = autocvar_cl_eventchase_distance;
1741                         if(vehicle_chase)
1742                         {
1743                                 if(vehicle_viewofs)
1744                                         chase_distance = vehicle_viewdist;
1745                                 else
1746                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1747                         }
1748                         if (custom_eventchase)
1749                                 chase_distance = chase_distance_override;
1750
1751                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1752                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1753                         else if(eventchase_current_distance != chase_distance)
1754                                 eventchase_current_distance = chase_distance;
1755
1756                         makevectors(view_angles);
1757
1758                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1759                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1760
1761                         // If the boxtrace fails, revert back to line tracing.
1762                         if(!local_player.viewloc)
1763                         if(trace_startsolid)
1764                         {
1765                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1766                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1767                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1768                         }
1769                         else { setproperty(VF_ORIGIN, trace_endpos); }
1770
1771                         if(!local_player.viewloc)
1772                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1773                 }
1774                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1775                 {
1776                         eventchase_running = false;
1777                         cvar_set("chase_active", "0");
1778                         eventchase_current_distance = 0; // start from 0 next time
1779                 }
1780         }
1781         // workaround for camera stuck between player's legs when using chase_active 1
1782         // because the engine stops updating the chase_active camera when the game ends
1783         else if(intermission)
1784         {
1785                 cvar_settemp("chase_active", "-1");
1786                 eventchase_current_distance = 0;
1787         }
1788
1789         LABEL(skip_eventchase_death);
1790
1791         // do lockview after event chase camera so that it still applies whenever necessary.
1792         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1793         {
1794                 setproperty(VF_ORIGIN, freeze_org);
1795                 setproperty(VF_ANGLES, freeze_ang);
1796         }
1797         else
1798         {
1799                 freeze_org = getpropertyvec(VF_ORIGIN);
1800                 freeze_ang = getpropertyvec(VF_ANGLES);
1801         }
1802
1803         WarpZone_FixView();
1804         //WarpZone_FixPMove();
1805
1806         vector ov_org = '0 0 0';
1807         vector ov_mid = '0 0 0';
1808         vector ov_worldmin = '0 0 0';
1809         vector ov_worldmax = '0 0 0';
1810         if(autocvar_cl_orthoview)
1811         {
1812                 ov_worldmin = mi_picmin;
1813                 ov_worldmax = mi_picmax;
1814
1815                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1816                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1817                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1818
1819                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1820                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1821
1822                 float ov_nearest = vlen(ov_org - vec3(
1823                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1824                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1825                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1826                 ));
1827
1828                 float ov_furthest = 0;
1829                 float dist = 0;
1830
1831                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1832                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1833                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1834                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1835                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1836                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1837                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1838                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1839
1840                 if(!ov_enabled)
1841                 {
1842                         oldr_nearclip = cvar("r_nearclip");
1843                         oldr_farclip_base = cvar("r_farclip_base");
1844                         oldr_farclip_world = cvar("r_farclip_world");
1845                         oldr_novis = cvar("r_novis");
1846                         oldr_useportalculling = cvar("r_useportalculling");
1847                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1848                 }
1849
1850                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1851                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1852                 cvar_settemp("r_farclip_world", "0");
1853                 cvar_settemp("r_novis", "1");
1854                 cvar_settemp("r_useportalculling", "0");
1855                 cvar_settemp("r_useinfinitefarclip", "0");
1856
1857                 setproperty(VF_ORIGIN, ov_org);
1858                 setproperty(VF_ANGLES, '90 0 0');
1859
1860                 ov_enabled = true;
1861
1862                 #if 0
1863                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1864                         vtos(ov_org),
1865                         vtos(getpropertyvec(VF_ANGLES)),
1866                         ov_distance,
1867                         ov_nearest,
1868                         ov_furthest);
1869                 #endif
1870         }
1871         else
1872         {
1873                 if(ov_enabled)
1874                 {
1875                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1876                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1877                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1878                         cvar_set("r_novis", ftos(oldr_novis));
1879                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1880                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1881                 }
1882                 ov_enabled = false;
1883         }
1884
1885         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1886         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1887         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1888                 viewmodel_draw(viewmodels[slot]);
1889
1890         // Render the Scene
1891         view_origin = getpropertyvec(VF_ORIGIN);
1892         view_angles = getpropertyvec(VF_ANGLES);
1893         makevectors(view_angles);
1894         view_forward = v_forward;
1895         view_right = v_right;
1896         view_up = v_up;
1897
1898 #ifdef BLURTEST
1899         if(time > blurtest_time0 && time < blurtest_time1)
1900         {
1901                 float r, t;
1902
1903                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1904                 r = t * blurtest_radius;
1905                 f = 1 / (t ** blurtest_power) - 1;
1906
1907                 cvar_set("r_glsl_postprocess", "1");
1908                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1909         }
1910         else
1911         {
1912                 cvar_set("r_glsl_postprocess", "0");
1913                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1914         }
1915 #endif
1916
1917         TargetMusic_Advance();
1918         Fog_Force();
1919         fpscounter_update();
1920
1921         if(drawtime == 0)
1922                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1923         else
1924                 drawframetime = bound(0.000001, time - drawtime, 1);
1925         drawtime = time;
1926
1927         // watch for gametype changes here...
1928         // in ParseStuffCMD the cmd isn't executed yet :/
1929         // might even be better to add the gametype to TE_CSQC_INIT...?
1930         if(!postinit)
1931                 PostInit();
1932
1933         if(intermission && !intermission_time)
1934                 intermission_time = time;
1935
1936         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1937         {
1938                 if(calledhooks & HOOK_START)
1939                 {
1940                         localcmd("\ncl_hook_gameend\n");
1941                         calledhooks |= HOOK_END;
1942                 }
1943         }
1944
1945         Announcer();
1946
1947         fov = autocvar_fov;
1948         if(fov <= 59.5)
1949         {
1950                 if(!zoomscript_caught)
1951                 {
1952                         localcmd("+button9\n");
1953                         zoomscript_caught = 1;
1954                 }
1955         }
1956         else
1957         {
1958                 if(zoomscript_caught)
1959                 {
1960                         localcmd("-button9\n");
1961                         zoomscript_caught = 0;
1962                 }
1963         }
1964
1965         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1966
1967         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1968         {
1969                 entity wepent = viewmodels[slot];
1970
1971                 if(wepent.last_switchweapon != wepent.switchweapon)
1972                 {
1973                         weapontime = time;
1974                         wepent.last_switchweapon = wepent.switchweapon;
1975                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1976                         {
1977                                 localcmd("-zoom\n");
1978                                 button_zoom = false;
1979                         }
1980                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1981                         {
1982                                 localcmd("-fire\n");
1983                                 localcmd("-fire2\n");
1984                                 button_attack2 = false;
1985                         }
1986                 }
1987                 if(wepent.last_activeweapon != wepent.activeweapon)
1988                 {
1989                         wepent.last_activeweapon = wepent.activeweapon;
1990
1991                         e = wepent.activeweapon;
1992                         if(e.netname != "")
1993                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1994                         else if(slot == 0)
1995                                 localcmd("\ncl_hook_activeweapon none\n");
1996                 }
1997         }
1998
1999         // ALWAYS Clear Current Scene First
2000         clearscene();
2001
2002         setproperty(VF_ORIGIN, view_origin);
2003         setproperty(VF_ANGLES, view_angles);
2004
2005         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2006         setproperty(VF_SIZE, vf_size);
2007         setproperty(VF_MIN, vf_min);
2008
2009         // Assign Standard Viewflags
2010         // Draw the World (and sky)
2011         setproperty(VF_DRAWWORLD, 1);
2012
2013         // Set the console size vars
2014         vid_conwidth = autocvar_vid_conwidth;
2015         vid_conheight = autocvar_vid_conheight;
2016         vid_pixelheight = autocvar_vid_pixelheight;
2017
2018         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2019         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2020         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2021
2022         if(camera_active) // Camera for demo playback
2023         {
2024                 if(autocvar_camera_enable)
2025                         CSQC_Demo_Camera();
2026                 else
2027                 {
2028                         cvar_set("chase_active", ftos(chase_active_backup));
2029                         cvar_set("cl_demo_mousegrab", "0");
2030                         camera_active = false;
2031                 }
2032         }
2033         else
2034         {
2035 #ifdef CAMERATEST
2036                 if(autocvar_camera_enable)
2037 #else
2038                 if(autocvar_camera_enable && isdemo())
2039 #endif
2040                 {
2041                         // Enable required Darkplaces cvars
2042                         chase_active_backup = autocvar_chase_active;
2043                         cvar_set("chase_active", "2");
2044                         cvar_set("cl_demo_mousegrab", "1");
2045                         camera_active = true;
2046                         camera_mode = false;
2047                 }
2048         }
2049
2050         // Draw the Crosshair
2051         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2052
2053         // Draw the Engine Status Bar (the default Quake HUD)
2054         setproperty(VF_DRAWENGINESBAR, 0);
2055
2056         // Update the mouse position
2057         /*
2058            mousepos_x = vid_conwidth;
2059            mousepos_y = vid_conheight;
2060            mousepos = mousepos*0.5 + getmousepos();
2061          */
2062
2063         IL_EACH(g_drawables, it.draw, it.draw(it));
2064
2065         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2066         renderscene();
2067
2068         // now switch to 2D drawing mode by calling a 2D drawing function
2069         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2070         // next R_RenderScene call
2071         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2072
2073         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2074         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2075         {
2076                 // apply night vision effect
2077                 vector tc_00, tc_01, tc_10, tc_11;
2078                 vector rgb = '0 0 0';
2079
2080                 if(!nightvision_noise)
2081                 {
2082                         nightvision_noise = new(nightvision_noise);
2083                 }
2084                 if(!nightvision_noise2)
2085                 {
2086                         nightvision_noise2 = new(nightvision_noise2);
2087                 }
2088
2089                 // color tint in yellow
2090                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2091
2092                 // draw BG
2093                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2094                 rgb = '1 1 1';
2095                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2096                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2097                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2098                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2099                 tc_11 = tc_01 + tc_10 - tc_00;
2100                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2101                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2102                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2103                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2104                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2105                 R_EndPolygon();
2106
2107                 // draw FG
2108                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2109                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2110                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2111                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2112                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2113                 tc_11 = tc_01 + tc_10 - tc_00;
2114                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2115                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2116                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2117                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2118                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2119                 R_EndPolygon();
2120         }
2121
2122         if(autocvar_cl_reticle)
2123         {
2124                 string reticle_image = string_null;
2125                 bool wep_zoomed = false;
2126                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2127                 {
2128                         entity wepe = viewmodels[slot];
2129                         Weapon wep = wepe.activeweapon;
2130                         if(wep != WEP_Null && wep.wr_zoom)
2131                         {
2132                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2133                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2134                                         reticle_image = wep.w_reticle;
2135                                 wep_zoomed += do_zoom;
2136                         }
2137                 }
2138                 // Draw the aiming reticle for weapons that use it
2139                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2140                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2141                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2142                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2143                 {
2144                         // no zoom reticle while dead
2145                         reticle_type = 0;
2146                 }
2147                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2148                 {
2149                         if(reticle_image) { reticle_type = 2; }
2150                         else { reticle_type = 0; }
2151                 }
2152                 else if(button_zoom || zoomscript_caught)
2153                 {
2154                         // normal zoom
2155                         reticle_type = 1;
2156                 }
2157
2158                 if(reticle_type)
2159                 {
2160                         if(autocvar_cl_reticle_stretch)
2161                         {
2162                                 reticle_size.x = vid_conwidth;
2163                                 reticle_size.y = vid_conheight;
2164                                 reticle_pos.x = 0;
2165                                 reticle_pos.y = 0;
2166                         }
2167                         else
2168                         {
2169                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2170                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2171                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2172                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2173                         }
2174
2175                         if(zoomscript_caught)
2176                                 f = 1;
2177                         else
2178                                 f = current_zoomfraction;
2179
2180                         if(f)
2181                         {
2182                                 switch(reticle_type)
2183                                 {
2184                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2185                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2186                                 }
2187                         }
2188                 }
2189         }
2190         else
2191         {
2192                 if(reticle_type != 0) { reticle_type = 0; }
2193         }
2194
2195
2196         // improved polyblend
2197         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2198         {
2199                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2200                 vector liquidcolor;
2201
2202                 switch(pointcontents(view_origin))
2203                 {
2204                         case CONTENT_WATER:
2205                                 liquidalpha = autocvar_hud_contents_water_alpha;
2206                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2207                                 incontent = 1;
2208                                 break;
2209
2210                         case CONTENT_LAVA:
2211                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2212                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2213                                 incontent = 1;
2214                                 break;
2215
2216                         case CONTENT_SLIME:
2217                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2218                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2219                                 incontent = 1;
2220                                 break;
2221
2222                         default:
2223                                 liquidalpha = 0;
2224                                 liquidcolor = '0 0 0';
2225                                 incontent = 0;
2226                                 break;
2227                 }
2228
2229                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2230                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2231                         contentfadetime = autocvar_hud_contents_fadeintime;
2232                         liquidalpha_prev = liquidalpha;
2233                         liquidcolor_prev = liquidcolor;
2234                 }
2235                 else
2236                         contentfadetime = autocvar_hud_contents_fadeouttime;
2237
2238                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2239                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2240
2241                 if(contentavgalpha)
2242                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2243
2244                 if(autocvar_hud_postprocessing)
2245                 {
2246                         if(autocvar_hud_contents_blur && contentavgalpha)
2247                         {
2248                                 content_blurpostprocess.x = 1;
2249                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2250                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2251                         }
2252                         else
2253                         {
2254                                 content_blurpostprocess.x = 0;
2255                                 content_blurpostprocess.y = 0;
2256                                 content_blurpostprocess.z = 0;
2257                         }
2258                 }
2259         }
2260
2261         if(autocvar_hud_damage && !STAT(FROZEN))
2262         {
2263                 splash_size.x = max(vid_conwidth, vid_conheight);
2264                 splash_size.y = max(vid_conwidth, vid_conheight);
2265                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2266                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2267
2268                 float myhealth_flash_temp;
2269                 myhealth = STAT(HEALTH);
2270
2271                 // fade out
2272                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2273                 // add new damage
2274                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2275
2276                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2277                 pain_threshold = autocvar_hud_damage_pain_threshold;
2278                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2279                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2280
2281                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2282                 {
2283                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2284                 }
2285
2286                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2287
2288                 if(myhealth_prev < 1)
2289                 {
2290                         if(myhealth >= 1)
2291                         {
2292                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2293                                 myhealth_flash_temp = 0;
2294                         }
2295                         else
2296                         {
2297                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2298                         }
2299                 }
2300
2301                 if(spectatee_status == -1 || intermission)
2302                 {
2303                         myhealth_flash = 0; // observing, or match ended
2304                         myhealth_flash_temp = 0;
2305                 }
2306
2307                 myhealth_prev = myhealth;
2308
2309                 // IDEA: change damage color/picture based on player model for robot/alien species?
2310                 // pro: matches model better
2311                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2312                 // maybe different reddish pics?
2313                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2314                 {
2315                         if(autocvar_cl_gentle_damage == 2)
2316                         {
2317                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2318                                         myhealth_gentlergb = randomvec();
2319                         }
2320                         else
2321                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2322
2323                         if(myhealth_flash_temp > 0)
2324                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2325                 }
2326                 else if(myhealth_flash_temp > 0)
2327                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2328
2329                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2330                 {
2331                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2332                         {
2333                                 damage_blurpostprocess.x = 1;
2334                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2335                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2336                         }
2337                         else
2338                         {
2339                                 damage_blurpostprocess.x = 0;
2340                                 damage_blurpostprocess.y = 0;
2341                                 damage_blurpostprocess.z = 0;
2342                         }
2343                 }
2344         }
2345
2346         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2347         float e2 = (autocvar_hud_powerup != 0);
2348         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2349         {
2350                 // enable or disable rendering types if they are used or not
2351                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2352                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2353
2354                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2355                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2356                 {
2357                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2358                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2359                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2360                         {
2361                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2362                                 old_blurradius = blurradius;
2363                                 old_bluralpha = bluralpha;
2364                         }
2365                 }
2366                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2367                 {
2368                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2369                         old_blurradius = 0;
2370                         old_bluralpha = 0;
2371                 }
2372
2373                 // edge detection postprocess handling done second (used by hud_powerup)
2374                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2375                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2376                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2377
2378                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2379
2380                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2381                 {
2382                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2383                         {
2384                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2385                                 old_sharpen_intensity = sharpen_intensity;
2386                         }
2387                 }
2388                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2389                 {
2390                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2391                         old_sharpen_intensity = 0;
2392                 }
2393
2394                 if(cvar("r_glsl_postprocess") == 0)
2395                         cvar_set("r_glsl_postprocess", "2");
2396         }
2397         else if(cvar("r_glsl_postprocess") == 2)
2398                 cvar_set("r_glsl_postprocess", "0");
2399
2400         /*if(gametype == MAPINFO_TYPE_CTF)
2401           {
2402           ctf_view();
2403           } else */
2404
2405         // draw 2D entities
2406         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2407         Draw_ShowNames_All();
2408 #if ENABLE_DEBUGDRAW
2409         Debug_Draw();
2410 #endif
2411
2412         scoreboard_active = Scoreboard_WouldDraw();
2413
2414         HUD_Draw(this); // this parameter for deep vehicle function
2415
2416         if(NextFrameCommand)
2417         {
2418                 localcmd("\n", NextFrameCommand, "\n");
2419                 NextFrameCommand = string_null;
2420         }
2421
2422         // we must do this check AFTER a frame was rendered, or it won't work
2423         if(cs_project_is_b0rked == 0)
2424         {
2425                 string w0, h0;
2426                 w0 = ftos(autocvar_vid_conwidth);
2427                 h0 = ftos(autocvar_vid_conheight);
2428                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2429                 //setproperty(VF_FOV, '90 90 0');
2430                 setproperty(VF_ORIGIN, '0 0 0');
2431                 setproperty(VF_ANGLES, '0 0 0');
2432                 setproperty(VF_PERSPECTIVE, 1);
2433                 makevectors('0 0 0');
2434                 vector v1, v2;
2435                 cvar_set("vid_conwidth", "800");
2436                 cvar_set("vid_conheight", "600");
2437                 v1 = cs_project(v_forward);
2438                 cvar_set("vid_conwidth", "640");
2439                 cvar_set("vid_conheight", "480");
2440                 v2 = cs_project(v_forward);
2441                 if(v1 == v2)
2442                         cs_project_is_b0rked = 1;
2443                 else
2444                         cs_project_is_b0rked = -1;
2445                 cvar_set("vid_conwidth", w0);
2446                 cvar_set("vid_conheight", h0);
2447         }
2448
2449         if(autocvar__hud_configure)
2450                 HUD_Panel_Mouse();
2451         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2452                 HUD_Minigame_Mouse();
2453         else if(QuickMenu_IsOpened())
2454                 QuickMenu_Mouse();
2455         else if(local_player.viewloc && (local_player.viewloc.spawnflags & VIEWLOC_FREEAIM))
2456                 ViewLocation_Mouse(); // NOTE: doesn't use cursormode
2457         else
2458                 HUD_Radar_Mouse();
2459
2460         cl_notice_run();
2461         unpause_update();
2462         Net_Flush();
2463
2464         // let's reset the view back to normal for the end
2465         setproperty(VF_MIN, '0 0 0');
2466         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2467
2468         IL_ENDFRAME();
2469 }
2470
2471
2472 // following vectors must be global to allow seamless switching between camera modes
2473 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2474 void CSQC_Demo_Camera()
2475 {
2476         float speed, attenuation, dimensions;
2477         vector tmp, delta;
2478
2479         if( autocvar_camera_reset || !camera_mode )
2480         {
2481                 camera_offset = '0 0 0';
2482                 current_angles = '0 0 0';
2483                 camera_direction = '0 0 0';
2484                 camera_offset.z += 30;
2485                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2486                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2487                 current_origin = view_origin;
2488                 current_camera_offset  = camera_offset;
2489                 cvar_set("camera_reset", "0");
2490                 camera_mode = CAMERA_CHASE;
2491         }
2492
2493         // Camera angles
2494         if( camera_roll )
2495                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2496
2497         if(autocvar_camera_look_player)
2498         {
2499                 vector dir;
2500                 float n;
2501
2502                 dir = normalize(view_origin - current_position);
2503                 n = mouse_angles.z;
2504                 mouse_angles = vectoangles(dir);
2505                 mouse_angles.x = mouse_angles.x * -1;
2506                 mouse_angles.z = n;
2507         }
2508         else
2509         {
2510                 tmp = getmousepos() * 0.1;
2511                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2512                 {
2513                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2514                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2515                 }
2516         }
2517
2518         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2519         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2520         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2521         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2522
2523         // Fix difference when angles don't have the same sign
2524         delta = '0 0 0';
2525         if(mouse_angles.y < -60 && current_angles.y > 60)
2526                 delta = '0 360 0';
2527         if(mouse_angles.y > 60 && current_angles.y < -60)
2528                 delta = '0 -360 0';
2529
2530         if(autocvar_camera_look_player)
2531                 attenuation = autocvar_camera_look_attenuation;
2532         else
2533                 attenuation = autocvar_camera_speed_attenuation;
2534
2535         attenuation = 1 / max(1, attenuation);
2536         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2537
2538         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2539         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2540         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2541         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2542
2543         // Camera position
2544         tmp = '0 0 0';
2545         dimensions = 0;
2546
2547         if( camera_direction.x )
2548         {
2549                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2550                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2551                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2552                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2553                 ++dimensions;
2554         }
2555
2556         if( camera_direction.y )
2557         {
2558                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2559                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2560                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2561                 ++dimensions;
2562         }
2563
2564         if( camera_direction.z )
2565         {
2566                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2567                 ++dimensions;
2568         }
2569
2570         if(autocvar_camera_free)
2571                 speed = autocvar_camera_speed_free;
2572         else
2573                 speed = autocvar_camera_speed_chase;
2574
2575         if(dimensions)
2576         {
2577                 speed = speed * sqrt(1 / dimensions);
2578                 camera_offset += tmp * speed;
2579         }
2580
2581         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2582
2583         // Camera modes
2584         if( autocvar_camera_free )
2585         {
2586                 if ( camera_mode == CAMERA_CHASE )
2587                 {
2588                         current_camera_offset = current_origin + current_camera_offset;
2589                         camera_offset = current_origin + camera_offset;
2590                 }
2591
2592                 camera_mode = CAMERA_FREE;
2593                 current_position = current_camera_offset;
2594         }
2595         else
2596         {
2597                 if ( camera_mode == CAMERA_FREE )
2598                 {
2599                         current_origin = view_origin;
2600                         camera_offset = camera_offset - current_origin;
2601                         current_camera_offset = current_camera_offset - current_origin;
2602                 }
2603
2604                 camera_mode = CAMERA_CHASE;
2605
2606                 if(autocvar_camera_chase_smoothly)
2607                         current_origin += (view_origin - current_origin) * attenuation;
2608                 else
2609                         current_origin = view_origin;
2610
2611                 current_position = current_origin + current_camera_offset;
2612         }
2613
2614         setproperty(VF_ANGLES, current_angles);
2615         setproperty(VF_ORIGIN, current_position);
2616 }