qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hud/all.qh"
   4 #include "mapvoting.qh"
   5 #include "scoreboard.qh"
   6 #include "shownames.qh"
   7 #include "quickmenu.qh"
   8
   9 #include "mutators/events.qh"
  10
  11 #include "../common/anim.qh"
  12 #include "../common/constants.qh"
  13 #include "../common/debug.qh"
  14 #include "../common/mapinfo.qh"
  15 #include <common/gamemodes/all.qh>
  16 #include "../common/physics/player.qh"
  17 #include "../common/stats.qh"
  18 #include "../common/triggers/target/music.qh"
  19 #include "../common/teams.qh"
  20
  21 #include <common/vehicles/all.qh>
  22 #include <common/weapons/all.qh>
  23 #include "../common/viewloc.qh"
  24 #include "../common/minigames/cl_minigames.qh"
  25 #include "../common/minigames/cl_minigames_hud.qh"
  26
  27 #include "../lib/csqcmodel/cl_player.qh"
  28
  29 #include "../lib/warpzone/client.qh"
  30 #include "../lib/warpzone/common.qh"
  31
  32 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  33
  34 float autocvar_cl_viewmodel_scale;
  35
  36 bool autocvar_cl_bobmodel;
  37 float autocvar_cl_bobmodel_speed;
  38 float autocvar_cl_bobmodel_side;
  39 float autocvar_cl_bobmodel_up;
  40
  41 float autocvar_cl_followmodel;
  42 float autocvar_cl_followmodel_side_speed;
  43 float autocvar_cl_followmodel_side_highpass;
  44 float autocvar_cl_followmodel_side_highpass1;
  45 float autocvar_cl_followmodel_side_limit;
  46 float autocvar_cl_followmodel_side_lowpass;
  47 float autocvar_cl_followmodel_up_speed;
  48 float autocvar_cl_followmodel_up_highpass;
  49 float autocvar_cl_followmodel_up_highpass1;
  50 float autocvar_cl_followmodel_up_limit;
  51 float autocvar_cl_followmodel_up_lowpass;
  52
  53 float autocvar_cl_leanmodel;
  54 float autocvar_cl_leanmodel_side_speed;
  55 float autocvar_cl_leanmodel_side_highpass;
  56 float autocvar_cl_leanmodel_side_highpass1;
  57 float autocvar_cl_leanmodel_side_lowpass;
  58 float autocvar_cl_leanmodel_side_limit;
  59 float autocvar_cl_leanmodel_up_speed;
  60 float autocvar_cl_leanmodel_up_highpass;
  61 float autocvar_cl_leanmodel_up_highpass1;
  62 float autocvar_cl_leanmodel_up_lowpass;
  63 float autocvar_cl_leanmodel_up_limit;
  64
  65 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  66 { \
  67         float __frac = bound(0, frac, 1); \
  68         ret = ref_store = ref_store * (1 - __frac) + (value) * __frac; \
  69 } MACRO_END
  70
  71 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  72 { \
  73         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  74         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  75 } MACRO_END
  76
  77 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  78 { \
  79         float __f = 0; lowpass(value, frac, ref_store, __f); \
  80         ret = (value) - __f; \
  81 } MACRO_END
  82
  83 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  84 { \
  85         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  86         ret = (value) - __f; \
  87 } MACRO_END
  88
  89 #define lowpass3(value, fracx, fracy, fracz, ref_store, ref_out) MACRO_BEGIN \
  90 { \
  91         lowpass(value.x, fracx, ref_store.x, ref_out.x); \
  92         lowpass(value.y, fracy, ref_store.y, ref_out.y); \
  93         lowpass(value.z, fracz, ref_store.z, ref_out.z); \
  94 } MACRO_END
  95
  96 #define highpass3(value, fracx, fracy, fracz, ref_store, ref_out) MACRO_BEGIN \
  97 { \
  98         highpass(value.x, fracx, ref_store.x, ref_out.x); \
  99         highpass(value.y, fracy, ref_store.y, ref_out.y); \
 100         highpass(value.z, fracz, ref_store.z, ref_out.z); \
 101 } MACRO_END
 102
 103 #define highpass3_limited(value, fracx, limitx, fracy, limity, fracz, limitz, ref_store, ref_out) MACRO_BEGIN \
 104 { \
 105         highpass_limited(value.x, fracx, limitx, ref_store.x, ref_out.x); \
 106         highpass_limited(value.y, fracy, limity, ref_store.y, ref_out.y); \
 107         highpass_limited(value.z, fracz, limitz, ref_store.z, ref_out.z); \
 108 } MACRO_END
 109
 110 void viewmodel_animate(entity this)
 111 {
 112         static float prevtime;
 113         float frametime = (time - prevtime) * STAT(MOVEVARS_TIMESCALE);
 114         prevtime = time;
 115
 116         if (autocvar_chase_active) return;
 117         if (STAT(HEALTH) <= 0) return;
 118
 119         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 120
 121         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 122         static bool oldonground;
 123         static float hitgroundtime;
 124         static float lastongroundtime;
 125         if (clonground)
 126         {
 127                 float f = time; // cl.movecmd[0].time
 128                 if (!oldonground)
 129                         hitgroundtime = f;
 130                 lastongroundtime = f;
 131         }
 132         oldonground = clonground;
 133
 134         vector gunorg = '0 0 0', gunangles = '0 0 0';
 135         static vector gunorg_prev = '0 0 0', gunangles_prev = '0 0 0';
 136
 137         bool teleported = view.csqcmodel_teleported;
 138
 139         // 1. if we teleported, clear the frametime... the lowpass will recover the previous value then
 140         if (teleported)
 141         {
 142                 // try to fix the first highpass; result is NOT
 143                 // perfect! TODO find a better fix
 144                 gunangles_prev = view_angles;
 145                 gunorg_prev = view_origin;
 146         }
 147
 148         static vector gunorg_highpass = '0 0 0';
 149
 150         // 2. for the gun origin, only keep the high frequency (non-DC) parts, which is "somewhat like velocity"
 151         gunorg_highpass += gunorg_prev;
 152         highpass3_limited(view_origin,
 153                 frametime * autocvar_cl_followmodel_side_highpass1, autocvar_cl_followmodel_side_limit,
 154                 frametime * autocvar_cl_followmodel_side_highpass1, autocvar_cl_followmodel_side_limit,
 155                 frametime * autocvar_cl_followmodel_up_highpass1, autocvar_cl_followmodel_up_limit,
 156                 gunorg_highpass, gunorg);
 157         gunorg_prev = view_origin;
 158         gunorg_highpass -= gunorg_prev;
 159
 160         static vector gunangles_highpass = '0 0 0';
 161
 162         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 163         gunangles_highpass += gunangles_prev;
 164         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 165         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 166         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 167         highpass3_limited(view_angles,
 168                 frametime * autocvar_cl_leanmodel_up_highpass1, autocvar_cl_leanmodel_up_limit,
 169                 frametime * autocvar_cl_leanmodel_side_highpass1, autocvar_cl_leanmodel_side_limit,
 170                 0, 0,
 171                 gunangles_highpass, gunangles);
 172         gunangles_prev = view_angles;
 173         gunangles_highpass -= gunangles_prev;
 174
 175         // 3. calculate the RAW adjustment vectors
 176         gunorg.x *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_side_speed : 0);
 177         gunorg.y *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_side_speed : 0);
 178         gunorg.z *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_up_speed : 0);
 179
 180         PITCH(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_up_speed : 0);
 181         YAW(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_side_speed : 0);
 182         ROLL(gunangles) = 0;
 183
 184         static vector gunorg_adjustment_highpass;
 185         static vector gunorg_adjustment_lowpass;
 186         static vector gunangles_adjustment_highpass;
 187         static vector gunangles_adjustment_lowpass;
 188
 189         // 4. perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 190         //    trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 191         highpass3(gunorg,
 192                 frametime * autocvar_cl_followmodel_side_highpass,
 193                 frametime * autocvar_cl_followmodel_side_highpass,
 194                 frametime * autocvar_cl_followmodel_up_highpass,
 195                 gunorg_adjustment_highpass, gunorg);
 196         lowpass3(gunorg,
 197                 frametime * autocvar_cl_followmodel_side_lowpass,
 198                 frametime * autocvar_cl_followmodel_side_lowpass,
 199                 frametime * autocvar_cl_followmodel_up_lowpass,
 200                 gunorg_adjustment_lowpass, gunorg);
 201         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 202         highpass3(gunangles,
 203                 frametime * autocvar_cl_leanmodel_up_highpass,
 204                 frametime * autocvar_cl_leanmodel_side_highpass,
 205                 0,
 206                 gunangles_adjustment_highpass, gunangles);
 207         lowpass3(gunangles,
 208                 frametime * autocvar_cl_leanmodel_up_lowpass,
 209                 frametime * autocvar_cl_leanmodel_side_lowpass,
 210                 0,
 211                 gunangles_adjustment_lowpass, gunangles);
 212         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 213
 214         // vertical view bobbing code
 215         // TODO: cl_bob
 216
 217         // horizontal view bobbing code
 218         // TODO: cl_bob2
 219
 220         // fall bobbing code
 221         // causes the view to swing down and back up when touching the ground
 222         // TODO: cl_bobfall
 223
 224         // gun model bobbing code
 225         if (autocvar_cl_bobmodel)
 226         {
 227                 // calculate for swinging gun model
 228                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 229                 // Sajt: I tried to smooth out the transitions between bob and no bob, which works
 230                 // for the most part, but for some reason when you go through a message trigger or
 231                 // pick up an item or anything like that it will momentarily jolt the gun.
 232                 vector forward, right = '0 0 0', up = '0 0 0';
 233                 float bspeed;
 234                 float t = 1;
 235                 float s = time * autocvar_cl_bobmodel_speed;
 236                 if (clonground)
 237                 {
 238                         if (time - hitgroundtime < 0.2)
 239                         {
 240                                 // just hit the ground, speed the bob back up over the next 0.2 seconds
 241                                 t = time - hitgroundtime;
 242                                 t = bound(0, t, 0.2);
 243                                 t *= 5;
 244                         }
 245                 }
 246                 else
 247                 {
 248                         // recently left the ground, slow the bob down over the next 0.2 seconds
 249                         t = time - lastongroundtime;
 250                         t = 0.2 - bound(0, t, 0.2);
 251                         t *= 5;
 252                 }
 253                 bspeed = xyspeed * 0.01;
 254                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 255                 float bobr = bspeed * autocvar_cl_bobmodel_side * autocvar_cl_viewmodel_scale * sin(s) * t;
 256                 gunorg += bobr * right;
 257                 float bobu = bspeed * autocvar_cl_bobmodel_up * autocvar_cl_viewmodel_scale * cos(s * 2) * t;
 258                 gunorg += bobu * up;
 259         }
 260         vector v = rotate(gunorg, YAW(view_angles) * DEG2RAD); // rotate world coordinates to relative ones
 261         v.z = gunorg.z;
 262         this.origin += v;
 263         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 264         this.angles += gunangles;
 265 }
 266
 267 .vector viewmodel_origin, viewmodel_angles;
 268 .float weapon_nextthink;
 269 .float weapon_eta_last;
 270 .float weapon_switchdelay;
 271
 272 void viewmodel_draw(entity this)
 273 {
 274         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 275         float a = this.alpha;
 276         static bool wasinvehicle;
 277         bool invehicle = player_localentnum > maxclients;
 278         if (invehicle) a = -1;
 279         else if (wasinvehicle) a = 1;
 280         wasinvehicle = invehicle;
 281         int c = stof(getplayerkeyvalue(current_player, "colors"));
 282         vector g;
 283         Weapon wep = activeweapon;
 284         if (!(g = wep.wr_glow(wep))) g = colormapPaletteColor(c & 0x0F, true) * 2;
 285         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 286         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 287                 | EF_NODEPTHTEST)
 288                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 289         for (entity e = this; e; e = e.weaponchild)
 290         {
 291                 e.drawmask = mask;
 292                 e.alpha = a;
 293                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 294                 e.glowmod = g;
 295                 e.csqcmodel_effects = fx;
 296                 WITH(entity, self, e, CSQCModel_Effects_Apply());
 297         }
 298         {
 299                 static string name_last;
 300                 string name = wep.mdl;
 301                 if (name != name_last)
 302                 {
 303                         name_last = name;
 304                         CL_WeaponEntity_SetModel(this, name);
 305                         this.viewmodel_origin = this.origin;
 306                         this.viewmodel_angles = this.angles;
 307                 }
 308                 anim_update(this);
 309                 if (!this.animstate_override)
 310                         anim_set(this, this.anim_idle, true, false, false);
 311         }
 312         float f = 0; // 0..1; 0: fully active
 313         float eta = (this.weapon_nextthink - time) / STAT(WEAPONRATEFACTOR);
 314         if (eta <= 0) f = this.weapon_eta_last;
 315         else switch (this.state)
 316         {
 317                 case WS_RAISE:
 318                 {
 319                         f = eta / max(eta, this.weapon_switchdelay);
 320                         break;
 321                 }
 322                 case WS_DROP:
 323                 {
 324                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 325                         break;
 326                 }
 327                 case WS_CLEAR:
 328                 {
 329                         f = 1;
 330                         break;
 331                 }
 332         }
 333         this.weapon_eta_last = f;
 334         this.origin = this.viewmodel_origin;
 335         this.angles = this.viewmodel_angles;
 336         this.angles_x = (-90 * f * f);
 337         viewmodel_animate(this);
 338         setorigin(this, this.origin);
 339 }
 340
 341 entity viewmodel;
 342 STATIC_INIT(viewmodel) {
 343     viewmodel = new(viewmodel);
 344     make_pure(viewmodel);
 345         viewmodel.draw = viewmodel_draw;
 346 }
 347
 348 entity porto;
 349 vector polyline[16];
 350 void Porto_Draw(entity this)
 351 {
 352         vector p, dir, ang, q, nextdir;
 353         float portal_number, portal1_idx;
 354
 355         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
 356                 return;
 357         if(WEP_CVAR(porto, secondary))
 358                 return;
 359         if(intermission == 1)
 360                 return;
 361         if(intermission == 2)
 362                 return;
 363         if (STAT(HEALTH) <= 0)
 364                 return;
 365
 366         dir = view_forward;
 367
 368         if(angles_held_status)
 369         {
 370                 makevectors(angles_held);
 371                 dir = v_forward;
 372         }
 373
 374         p = view_origin;
 375
 376         polyline[0] = p;
 377         int idx = 1;
 378         portal_number = 0;
 379         nextdir = dir;
 380
 381         for (;;)
 382         {
 383                 dir = nextdir;
 384                 traceline(p, p + 65536 * dir, true, porto);
 385                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 386                         return;
 387                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
 388                 p = trace_endpos;
 389                 polyline[idx] = p;
 390                 ++idx;
 391                 if(idx >= 16)
 392                         return;
 393                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 394                         continue;
 395                 ++portal_number;
 396                 ang = vectoangles2(trace_plane_normal, dir);
 397                 ang.x = -ang.x;
 398                 makevectors(ang);
 399                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 400                         return;
 401                 if(portal_number == 1)
 402                 {
 403                         portal1_idx = idx;
 404                         if(portal_number >= 2)
 405                                 break;
 406                 }
 407         }
 408
 409         while(idx >= 2)
 410         {
 411                 p = polyline[idx-2];
 412                 q = polyline[idx-1];
 413                 if(idx == 2)
 414                         p = p - view_up * 16;
 415                 if(idx-1 >= portal1_idx)
 416                 {
 417                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 418                 }
 419                 else
 420                 {
 421                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 422                 }
 423                 --idx;
 424         }
 425 }
 426
 427 void Porto_Init()
 428 {
 429         porto = new(porto);
 430         make_pure(porto);
 431         porto.draw = Porto_Draw;
 432         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 433 }
 434
 435 float drawtime;
 436 float avgspeed;
 437 vector GetCurrentFov(float fov)
 438 {
 439         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 440         float velocityzoom, curspeed;
 441         vector v;
 442
 443         zoomsensitivity = autocvar_cl_zoomsensitivity;
 444         zoomfactor = autocvar_cl_zoomfactor;
 445         if(zoomfactor < 1 || zoomfactor > 30)
 446                 zoomfactor = 2.5;
 447         zoomspeed = autocvar_cl_zoomspeed;
 448         if(zoomspeed >= 0)
 449         if(zoomspeed < 0.5 || zoomspeed > 16)
 450                         zoomspeed = 3.5;
 451
 452         zoomdir = button_zoom;
 453         if(hud == HUD_NORMAL)
 454         if(switchweapon == activeweapon)
 455         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 456                 zoomdir += button_attack2;
 457         if(spectatee_status > 0 || isdemo())
 458         {
 459                 if(spectatorbutton_zoom)
 460                 {
 461                         if(zoomdir)
 462                                 zoomdir = 0;
 463                         else
 464                                 zoomdir = 1;
 465                 }
 466                 // fteqcc failed twice here already, don't optimize this
 467         }
 468
 469         if(zoomdir) { zoomin_effect = 0; }
 470
 471         if(camera_active)
 472         {
 473                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 474         }
 475         else if(autocvar_cl_spawnzoom && zoomin_effect)
 476         {
 477                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 478
 479                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 480                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 481                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 482         }
 483         else
 484         {
 485                 if(zoomspeed < 0) // instant zoom
 486                 {
 487                         if(zoomdir)
 488                                 current_viewzoom = 1 / zoomfactor;
 489                         else
 490                                 current_viewzoom = 1;
 491                 }
 492                 else
 493                 {
 494                         if(zoomdir)
 495                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 496                         else
 497                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 498                 }
 499         }
 500
 501         if(almost_equals(current_viewzoom, 1))
 502                 current_zoomfraction = 0;
 503         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 504                 current_zoomfraction = 1;
 505         else
 506                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 507
 508         if(zoomsensitivity < 1)
 509                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 510         else
 511                 setsensitivityscale(1);
 512
 513         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 514         {
 515                 if(intermission) { curspeed = 0; }
 516                 else
 517                 {
 518
 519                         makevectors(view_angles);
 520                         v = pmove_vel;
 521                         if(csqcplayer)
 522                                 v = csqcplayer.velocity;
 523
 524                         switch(autocvar_cl_velocityzoom_type)
 525                         {
 526                                 case 3: curspeed = max(0, v_forward * v); break;
 527                                 case 2: curspeed = (v_forward * v); break;
 528                                 case 1: default: curspeed = vlen(v); break;
 529                         }
 530                 }
 531
 532                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 533                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 534                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 535
 536                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 537         }
 538         else
 539                 velocityzoom = 1;
 540
 541         float frustumx, frustumy, fovx, fovy;
 542         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 543         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 544         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 545         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 546
 547         return '1 0 0' * fovx + '0 1 0' * fovy;
 548 }
 549
 550 vector GetViewLocationFOV(float fov)
 551 {
 552         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 553         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 554         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 555         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 556         return '1 0 0' * fovx + '0 1 0' * fovy;
 557 }
 558
 559 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 560 {
 561         float fovx, fovy;
 562         float width = (ov_worldmax.x - ov_worldmin.x);
 563         float height = (ov_worldmax.y - ov_worldmin.y);
 564         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 565         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 566         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 567         return '1 0 0' * fovx + '0 1 0' * fovy;
 568 }
 569
 570 // this function must match W_SetupShot!
 571 float zoomscript_caught;
 572
 573 vector wcross_origin;
 574 float wcross_scale_prev, wcross_alpha_prev;
 575 vector wcross_color_prev;
 576 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 577 vector wcross_color_goal_prev;
 578 float wcross_changedonetime;
 579
 580 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 581 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 582 float wcross_name_changestarttime, wcross_name_changedonetime;
 583 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 584
 585 float wcross_ring_prev;
 586
 587 entity trueaim;
 588 entity trueaim_rifle;
 589
 590 const float SHOTTYPE_HITTEAM = 1;
 591 const float SHOTTYPE_HITOBSTRUCTION = 2;
 592 const float SHOTTYPE_HITWORLD = 3;
 593 const float SHOTTYPE_HITENEMY = 4;
 594
 595 void TrueAim_Init()
 596 {
 597         trueaim = new(trueaim);
 598         make_pure(trueaim);
 599         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 600         trueaim_rifle = new(trueaim_rifle);
 601         make_pure(trueaim_rifle);
 602         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 603 }
 604
 605 float EnemyHitCheck()
 606 {
 607         float t, n;
 608         wcross_origin = project_3d_to_2d(trace_endpos);
 609         wcross_origin.z = 0;
 610         if(trace_ent)
 611                 n = trace_ent.entnum;
 612         else
 613                 n = trace_networkentity;
 614         if(n < 1)
 615                 return SHOTTYPE_HITWORLD;
 616         if(n > maxclients)
 617                 return SHOTTYPE_HITWORLD;
 618         t = entcs_GetTeam(n - 1);
 619         if(teamplay)
 620                 if(t == myteam)
 621                         return SHOTTYPE_HITTEAM;
 622         if(t == NUM_SPECTATOR)
 623                 return SHOTTYPE_HITWORLD;
 624         return SHOTTYPE_HITENEMY;
 625 }
 626
 627 float TrueAimCheck()
 628 {
 629         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 630         vector vecs, trueaimpoint, w_shotorg;
 631         vector mi, ma, dv;
 632         float shottype;
 633         entity ta;
 634         float mv;
 635
 636         mi = ma = '0 0 0';
 637         ta = trueaim;
 638         mv = MOVE_NOMONSTERS;
 639
 640         switch(activeweapon) // WEAPONTODO
 641         {
 642                 case WEP_TUBA: // no aim
 643                 case WEP_PORTO: // shoots from eye
 644                 case WEP_NEXBALL: // shoots from eye
 645                 case WEP_HOOK: // no trueaim
 646                 case WEP_MORTAR: // toss curve
 647                         return SHOTTYPE_HITWORLD;
 648                 case WEP_VORTEX:
 649                 case WEP_VAPORIZER:
 650                         mv = MOVE_NORMAL;
 651                         break;
 652                 case WEP_RIFLE:
 653                         ta = trueaim_rifle;
 654                         mv = MOVE_NORMAL;
 655                         if(zoomscript_caught)
 656                         {
 657                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 658                                 return EnemyHitCheck();
 659                         }
 660                         break;
 661                 case WEP_DEVASTATOR: // projectile has a size!
 662                         mi = '-3 -3 -3';
 663                         ma = '3 3 3';
 664                         break;
 665                 case WEP_FIREBALL: // projectile has a size!
 666                         mi = '-16 -16 -16';
 667                         ma = '16 16 16';
 668                         break;
 669                 case WEP_SEEKER: // projectile has a size!
 670                         mi = '-2 -2 -2';
 671                         ma = '2 2 2';
 672                         break;
 673                 case WEP_ELECTRO: // projectile has a size!
 674                         mi = '0 0 -3';
 675                         ma = '0 0 -3';
 676                         break;
 677         }
 678
 679         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 680
 681         vecs = decompressShotOrigin(STAT(SHOTORG));
 682
 683         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 684         trueaimpoint = trace_endpos;
 685
 686         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 687                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 688
 689         if(vecs.x > 0)
 690                 vecs.y = -vecs.y;
 691         else
 692                 vecs = '0 0 0';
 693
 694         dv = view_right * vecs.y + view_up * vecs.z;
 695         w_shotorg = traceorigin + dv;
 696
 697         // now move the vecs forward as much as requested if possible
 698         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 699         w_shotorg = trace_endpos - view_forward * nudge;
 700
 701         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 702         shottype = EnemyHitCheck();
 703         if(shottype != SHOTTYPE_HITWORLD)
 704                 return shottype;
 705
 706 #if 0
 707         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 708         // or rather, I know why, but see no fix
 709         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 710                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 711                 return SHOTTYPE_HITOBSTRUCTION;
 712 #endif
 713
 714         return SHOTTYPE_HITWORLD;
 715 }
 716
 717 void PostInit();
 718 void CSQC_Demo_Camera();
 719 float HUD_WouldDrawScoreboard();
 720 float camera_mode;
 721 const float CAMERA_FREE = 1;
 722 const float CAMERA_CHASE = 2;
 723 float reticle_type;
 724 string reticle_image;
 725 string NextFrameCommand;
 726
 727 vector freeze_org, freeze_ang;
 728 entity nightvision_noise, nightvision_noise2;
 729
 730 const float MAX_TIME_DIFF = 5;
 731 float pickup_crosshair_time, pickup_crosshair_size;
 732 float hitindication_crosshair_size;
 733 float use_vortex_chargepool;
 734
 735 float myhealth, myhealth_prev;
 736 float myhealth_flash;
 737
 738 float old_blurradius, old_bluralpha;
 739 float old_sharpen_intensity;
 740
 741 vector myhealth_gentlergb;
 742
 743 float contentavgalpha, liquidalpha_prev;
 744 vector liquidcolor_prev;
 745
 746 float eventchase_current_distance;
 747 float eventchase_running;
 748 bool WantEventchase()
 749 {SELFPARAM();
 750         if(autocvar_cl_orthoview)
 751                 return false;
 752         if(intermission)
 753                 return true;
 754         if(self.viewloc)
 755                 return true;
 756         if(spectatee_status >= 0)
 757         {
 758                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 759                         return true;
 760                 if(MUTATOR_CALLHOOK(WantEventchase, self))
 761                         return true;
 762                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
 763                         return true;
 764                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 765                 {
 766                         if(autocvar_cl_eventchase_death == 2)
 767                         {
 768                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 769                                 if(self.velocity == '0 0 0' || eventchase_running)
 770                                         return true;
 771                         }
 772                         else return true;
 773                 }
 774         }
 775         return false;
 776 }
 777
 778 void HUD_Crosshair_Vehicle()
 779 {
 780         if(hud != HUD_BUMBLEBEE_GUN)
 781         {
 782                 Vehicle info = Vehicles_from(hud);
 783                 info.vr_crosshair(info);
 784         }
 785 }
 786
 787 vector damage_blurpostprocess, content_blurpostprocess;
 788
 789 float unaccounted_damage = 0;
 790 void UpdateDamage()
 791 {
 792         // accumulate damage with each stat update
 793         static float damage_total_prev = 0;
 794         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 795         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 796         damage_total_prev = damage_total;
 797
 798         static float damage_dealt_time_prev = 0;
 799         float damage_dealt_time = STAT(HIT_TIME);
 800         if (damage_dealt_time != damage_dealt_time_prev)
 801         {
 802                 unaccounted_damage += unaccounted_damage_new;
 803                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 804         }
 805         damage_dealt_time_prev = damage_dealt_time;
 806
 807         // prevent hitsound when switching spectatee
 808         static float spectatee_status_prev = 0;
 809         if (spectatee_status != spectatee_status_prev)
 810                 unaccounted_damage = 0;
 811         spectatee_status_prev = spectatee_status;
 812 }
 813
 814 void HitSound()
 815 {
 816         // varying sound pitch
 817
 818         static float hitsound_time_prev = 0;
 819         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 820         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 821         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 822         {
 823                 if (autocvar_cl_hitsound && unaccounted_damage)
 824                 {
 825                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 826                         float a = autocvar_cl_hitsound_max_pitch;
 827                         float b = autocvar_cl_hitsound_min_pitch;
 828                         float c = autocvar_cl_hitsound_nom_damage;
 829                         float x = unaccounted_damage;
 830                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 831
 832                         // if sound variation is disabled, set pitch_shift to 1
 833                         if (autocvar_cl_hitsound == 1)
 834                                 pitch_shift = 1;
 835
 836                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 837                         if (autocvar_cl_hitsound == 3)
 838                         {
 839                                 float mirror_value = (a-b)/2 + b;
 840                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 841                         }
 842
 843                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 844
 845                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 846                         // todo: normalize sound pressure levels? seems unnecessary
 847
 848                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 849                 }
 850                 unaccounted_damage = 0;
 851                 hitsound_time_prev = time;
 852         }
 853
 854         static float typehit_time_prev = 0;
 855         float typehit_time = STAT(TYPEHIT_TIME);
 856         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 857         {
 858                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 859                 typehit_time_prev = typehit_time;
 860         }
 861 }
 862
 863 void HUD_Crosshair()
 864 {SELFPARAM();
 865         static float rainbow_last_flicker;
 866         static vector rainbow_prev_color;
 867         entity e = self;
 868         float f, i, j;
 869         vector v;
 870         if(!scoreboard_active && !camera_active && intermission != 2 &&
 871                 spectatee_status != -1 && !csqcplayer.viewloc &&
 872                 !HUD_MinigameMenu_IsOpened() )
 873         {
 874                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 875                         return;
 876
 877                 if (hud != HUD_NORMAL)
 878                 {
 879                         HUD_Crosshair_Vehicle();
 880                         return;
 881                 }
 882
 883                 string wcross_style;
 884                 float wcross_alpha, wcross_resolution;
 885                 wcross_style = autocvar_crosshair;
 886                 if (wcross_style == "0")
 887                         return;
 888                 wcross_resolution = autocvar_crosshair_size;
 889                 if (wcross_resolution == 0)
 890                         return;
 891                 wcross_alpha = autocvar_crosshair_alpha;
 892                 if (wcross_alpha == 0)
 893                         return;
 894
 895                 // TrueAim check
 896                 float shottype;
 897
 898                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 899                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 900                 wcross_origin.z = 0;
 901                 if(autocvar_crosshair_hittest)
 902                 {
 903                         vector wcross_oldorigin;
 904                         wcross_oldorigin = wcross_origin;
 905                         shottype = TrueAimCheck();
 906                         if(shottype == SHOTTYPE_HITWORLD)
 907                         {
 908                                 v = wcross_origin - wcross_oldorigin;
 909                                 v.x /= vid_conwidth;
 910                                 v.y /= vid_conheight;
 911                                 if(vlen(v) > 0.01)
 912                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 913                         }
 914                         if(!autocvar_crosshair_hittest_showimpact)
 915                                 wcross_origin = wcross_oldorigin;
 916                 }
 917                 else
 918                         shottype = SHOTTYPE_HITWORLD;
 919
 920                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 921                 string wcross_name = "";
 922                 float wcross_scale, wcross_blur;
 923
 924                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 925                 {
 926                         e = switchingweapon;
 927                         if(e)
 928                         {
 929                                 if(autocvar_crosshair_per_weapon)
 930                                 {
 931                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 932                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 933                                         //if (wcross_resolution == 0)
 934                                                 //return;
 935
 936                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 937                                         wcross_resolution *= e.w_crosshair_size;
 938                                         wcross_name = e.w_crosshair;
 939                                 }
 940                         }
 941                 }
 942
 943                 if(wcross_name == "")
 944                         wcross_name = strcat("gfx/crosshair", wcross_style);
 945
 946                 // MAIN CROSSHAIR COLOR DECISION
 947                 switch(autocvar_crosshair_color_special)
 948                 {
 949                         case 1: // crosshair_color_per_weapon
 950                         {
 951                                 if(e)
 952                                 {
 953                                         wcross_color = e.wpcolor;
 954                                         break;
 955                                 }
 956                                 else { goto normalcolor; }
 957                         }
 958
 959                         case 2: // crosshair_color_by_health
 960                         {
 961                                 float x = STAT(HEALTH);
 962
 963                                 //x = red
 964                                 //y = green
 965                                 //z = blue
 966
 967                                 wcross_color.z = 0;
 968
 969                                 if(x > 200)
 970                                 {
 971                                         wcross_color.x = 0;
 972                                         wcross_color.y = 1;
 973                                 }
 974                                 else if(x > 150)
 975                                 {
 976                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 977                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 978                                 }
 979                                 else if(x > 100)
 980                                 {
 981                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 982                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 983                                         wcross_color.z = 1 - (x-100)*0.02;
 984                                 }
 985                                 else if(x > 50)
 986                                 {
 987                                         wcross_color.x = 1;
 988                                         wcross_color.y = 1;
 989                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 990                                 }
 991                                 else if(x > 20)
 992                                 {
 993                                         wcross_color.x = 1;
 994                                         wcross_color.y = (x-20)*90/27/100;
 995                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 996                                 }
 997                                 else
 998                                 {
 999                                         wcross_color.x = 1;
1000                                         wcross_color.y = 0;
1001                                 }
1002                                 break;
1003                         }
1004
1005                         case 3: // crosshair_color_rainbow
1006                         {
1007                                 if(time >= rainbow_last_flicker)
1008                                 {
1009                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1010                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1011                                 }
1012                                 wcross_color = rainbow_prev_color;
1013                                 break;
1014                         }
1015                         :normalcolor
1016                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
1017                 }
1018
1019                 if(autocvar_crosshair_effect_scalefade)
1020                 {
1021                         wcross_scale = wcross_resolution;
1022                         wcross_resolution = 1;
1023                 }
1024                 else
1025                 {
1026                         wcross_scale = 1;
1027                 }
1028
1029                 if(autocvar_crosshair_pickup)
1030                 {
1031                         float stat_pickup_time = STAT(LAST_PICKUP);
1032
1033                         if(pickup_crosshair_time < stat_pickup_time)
1034                         {
1035                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1036                                         pickup_crosshair_size = 1;
1037
1038                                 pickup_crosshair_time = stat_pickup_time;
1039                         }
1040
1041                         if(pickup_crosshair_size > 0)
1042                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1043                         else
1044                                 pickup_crosshair_size = 0;
1045
1046                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1047                 }
1048
1049                 // todo: make crosshair hit indication dependent on damage dealt
1050                 if(autocvar_crosshair_hitindication)
1051                 {
1052                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1053
1054                         if(unaccounted_damage)
1055                         {
1056                                 hitindication_crosshair_size = 1;
1057                         }
1058
1059                         if(hitindication_crosshair_size > 0)
1060                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1061                         else
1062                                 hitindication_crosshair_size = 0;
1063
1064                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1065                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1066                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1067                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1068                 }
1069
1070                 if(shottype == SHOTTYPE_HITENEMY)
1071                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1072                 if(shottype == SHOTTYPE_HITTEAM)
1073                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1074
1075                 f = fabs(autocvar_crosshair_effect_time);
1076                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1077                 {
1078                         wcross_changedonetime = time + f;
1079                 }
1080                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1081                 {
1082                         wcross_name_changestarttime = time;
1083                         wcross_name_changedonetime = time + f;
1084                         if(wcross_name_goal_prev_prev)
1085                                 strunzone(wcross_name_goal_prev_prev);
1086                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1087                         wcross_name_goal_prev = strzone(wcross_name);
1088                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1089                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1090                         wcross_resolution_goal_prev = wcross_resolution;
1091                 }
1092
1093                 wcross_scale_goal_prev = wcross_scale;
1094                 wcross_alpha_goal_prev = wcross_alpha;
1095                 wcross_color_goal_prev = wcross_color;
1096
1097                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1098                 {
1099                         wcross_blur = 1;
1100                         wcross_alpha *= 0.75;
1101                 }
1102                 else
1103                         wcross_blur = 0;
1104                 // *_prev is at time-frametime
1105                 // * is at wcross_changedonetime+f
1106                 // what do we have at time?
1107                 if(time < wcross_changedonetime)
1108                 {
1109                         f = frametime / (wcross_changedonetime - time + frametime);
1110                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1111                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1112                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1113                 }
1114
1115                 wcross_scale_prev = wcross_scale;
1116                 wcross_alpha_prev = wcross_alpha;
1117                 wcross_color_prev = wcross_color;
1118
1119                 MUTATOR_CALLHOOK(UpdateCrosshair);
1120
1121                 wcross_scale *= 1 - autocvar__menu_alpha;
1122                 wcross_alpha *= 1 - autocvar__menu_alpha;
1123                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1124
1125                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1126                 {
1127                         // crosshair rings for weapon stats
1128                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1129                         {
1130                                 // declarations and stats
1131                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1132                                 string ring_image = string_null, ring_inner_image = string_null;
1133                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1134
1135                                 ring_scale = autocvar_crosshair_ring_size;
1136
1137                                 float weapon_clipload, weapon_clipsize;
1138                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1139                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1140
1141                                 float ok_ammo_charge, ok_ammo_chargepool;
1142                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1143                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1144
1145                                 float vortex_charge, vortex_chargepool;
1146                                 vortex_charge = STAT(VORTEX_CHARGE);
1147                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1148
1149                                 float arc_heat = STAT(ARC_HEAT);
1150
1151                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1152                                         vortex_charge_movingavg = vortex_charge;
1153
1154
1155                                 // handle the values
1156                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1157                                 {
1158                                         if (vortex_chargepool || use_vortex_chargepool) {
1159                                                 use_vortex_chargepool = 1;
1160                                                 ring_inner_value = vortex_chargepool;
1161                                         } else {
1162                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1163                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1164                                         }
1165
1166                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1167                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1168                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1169
1170                                         // draw the outer ring to show the current charge of the weapon
1171                                         ring_value = vortex_charge;
1172                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1173                                         ring_rgb = wcross_color;
1174                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1175                                 }
1176                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1177                                 {
1178                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1179                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1180                                         ring_rgb = wcross_color;
1181                                         ring_image = "gfx/crosshair_ring.tga";
1182                                 }
1183                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1184                                 {
1185                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1186                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1187                                         ring_rgb = wcross_color;
1188                                         ring_image = "gfx/crosshair_ring.tga";
1189                                 }
1190                                 else if (ok_ammo_charge)
1191                                 {
1192                                         ring_value = ok_ammo_chargepool;
1193                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1194                                         ring_rgb = wcross_color;
1195                                         ring_image = "gfx/crosshair_ring.tga";
1196                                 }
1197                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1198                                 {
1199                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1200                                         ring_scale = autocvar_crosshair_ring_reload_size;
1201                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1202                                         ring_rgb = wcross_color;
1203
1204                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1205                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1206                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1207                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1208                                         else
1209                                                 ring_image = "gfx/crosshair_ring.tga";
1210                                 }
1211                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1212                                 {
1213                                         ring_value = arc_heat;
1214                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1215                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1216                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1217                                         ring_image = "gfx/crosshair_ring.tga";
1218                                 }
1219
1220                                 // if in weapon switch animation, fade ring out/in
1221                                 if(autocvar_crosshair_effect_time > 0)
1222                                 {
1223                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1224                                         if (f >= 1)
1225                                         {
1226                                                 wcross_ring_prev = ((ring_image) ? true : false);
1227                                         }
1228
1229                                         if(wcross_ring_prev)
1230                                         {
1231                                                 if(f < 1)
1232                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1233                                         }
1234                                         else
1235                                         {
1236                                                 if(f < 1)
1237                                                         ring_alpha *= bound(0, f, 1);
1238                                         }
1239                                 }
1240
1241                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1242                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1243
1244                                 if (ring_value)
1245                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1246                         }
1247
1248 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1249                         MACRO_BEGIN { \
1250                                 if(wcross_blur > 0) \
1251                                 { \
1252                                         for(i = -2; i <= 2; ++i) \
1253                                         for(j = -2; j <= 2; ++j) \
1254                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1255                                 } \
1256                                 else \
1257                                 { \
1258                                         M(0,0,sz,wcross_name,wcross_alpha); \
1259                                 } \
1260                         } MACRO_END
1261
1262 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1263                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1264
1265 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1266                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1267
1268                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1269                         {
1270                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1271                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1272                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1273                                 f = 1 - f;
1274                         }
1275                         else
1276                         {
1277                                 f = 1;
1278                         }
1279                         wcross_name_alpha_goal_prev = f;
1280
1281                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1282                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1283
1284                         if(autocvar_crosshair_dot)
1285                         {
1286                                 vector wcross_color_old;
1287                                 wcross_color_old = wcross_color;
1288
1289                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1290                                         wcross_color = stov(autocvar_crosshair_dot_color);
1291
1292                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1293                                 // FIXME why don't we use wcross_alpha here?
1294                                 wcross_color = wcross_color_old;
1295                         }
1296                 }
1297         }
1298         else
1299         {
1300                 wcross_scale_prev = 0;
1301                 wcross_alpha_prev = 0;
1302                 wcross_scale_goal_prev = 0;
1303                 wcross_alpha_goal_prev = 0;
1304                 wcross_changedonetime = 0;
1305                 if(wcross_name_goal_prev)
1306                         strunzone(wcross_name_goal_prev);
1307                 wcross_name_goal_prev = string_null;
1308                 if(wcross_name_goal_prev_prev)
1309                         strunzone(wcross_name_goal_prev_prev);
1310                 wcross_name_goal_prev_prev = string_null;
1311                 wcross_name_changestarttime = 0;
1312                 wcross_name_changedonetime = 0;
1313                 wcross_name_alpha_goal_prev = 0;
1314                 wcross_name_alpha_goal_prev_prev = 0;
1315                 wcross_resolution_goal_prev = 0;
1316                 wcross_resolution_goal_prev_prev = 0;
1317         }
1318 }
1319
1320 void HUD_Draw()
1321 {
1322         vector rgb = '0 0 0';
1323         float a = 1;
1324         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1325         {
1326                 rgb = MUTATOR_ARGV(0, vector);
1327                 a = MUTATOR_ARGV(0, float);
1328         }
1329         else if(STAT(FROZEN))
1330         {
1331                 rgb = ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1');
1332         }
1333         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, rgb, autocvar_hud_colorflash_alpha * a, DRAWFLAG_ADDITIVE);
1334         if(!intermission)
1335         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1336         {
1337                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1338                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1339         }
1340         else if(STAT(REVIVE_PROGRESS))
1341         {
1342                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1343                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1344         }
1345
1346         if(autocvar_r_letterbox == 0)
1347                 if(autocvar_viewsize < 120)
1348                 {
1349                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1350                                 Accuracy_LoadLevels();
1351
1352                         HUD_Main();
1353                         HUD_DrawScoreboard();
1354                 }
1355
1356         // crosshair goes VERY LAST
1357         UpdateDamage();
1358         HUD_Crosshair();
1359         HitSound();
1360 }
1361
1362 bool ov_enabled;
1363 float oldr_nearclip;
1364 float oldr_farclip_base;
1365 float oldr_farclip_world;
1366 float oldr_novis;
1367 float oldr_useportalculling;
1368 float oldr_useinfinitefarclip;
1369
1370 void cl_notice_run();
1371 float prev_myteam;
1372 int lasthud;
1373 float vh_notice_time;
1374 void WaypointSprite_Load();
1375 void CSQC_UpdateView(float w, float h)
1376 {SELFPARAM();
1377         entity e;
1378         float fov;
1379         float f;
1380         vector vf_size, vf_min;
1381         float a;
1382
1383         execute_next_frame();
1384
1385         ++framecount;
1386
1387         stats_get();
1388         hud = STAT(HUD);
1389
1390         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1391                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1392
1393         lasthud = hud;
1394
1395         if(autocvar__hud_showbinds_reload) // menu can set this one
1396         {
1397                 db_close(binddb);
1398                 binddb = db_create();
1399                 cvar_set("_hud_showbinds_reload", "0");
1400         }
1401
1402         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1403                 view_quality = getproperty(VF_MINFPS_QUALITY);
1404         else
1405                 view_quality = 1;
1406
1407         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(self);
1408         button_zoom = PHYS_INPUT_BUTTON_ZOOM(self);
1409
1410         vf_size = getpropertyvec(VF_SIZE);
1411         vf_min = getpropertyvec(VF_MIN);
1412         vid_width = vf_size.x;
1413         vid_height = vf_size.y;
1414
1415         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1416         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1417
1418         WaypointSprite_Load();
1419
1420         CSQCPlayer_SetCamera();
1421
1422         if(player_localentnum <= maxclients) // is it a client?
1423                 current_player = player_localentnum - 1;
1424         else // then player_localentnum is the vehicle I'm driving
1425                 current_player = player_localnum;
1426         myteam = entcs_GetTeam(current_player);
1427
1428         if(myteam != prev_myteam)
1429         {
1430                 myteamcolors = colormapPaletteColor(myteam, 1);
1431                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1432                 prev_myteam = myteam;
1433         }
1434
1435         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1436
1437         float is_dead = (STAT(HEALTH) <= 0);
1438
1439         // FIXME do we need this hack?
1440         if(isdemo())
1441         {
1442                 // in demos, input_buttons do not work
1443                 button_zoom = (autocvar__togglezoom == "-");
1444         }
1445         else if(button_zoom
1446                 && autocvar_cl_unpress_zoom_on_death
1447                 && (spectatee_status >= 0)
1448                 && (is_dead || intermission))
1449         {
1450                 // no zoom while dead or in intermission please
1451                 localcmd("-zoom\n");
1452                 button_zoom = false;
1453         }
1454
1455         // event chase camera
1456         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1457         {
1458                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1459                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1460                 entity gen = world;
1461
1462                 float vehicle_viewdist = 0;
1463                 vector vehicle_viewofs = '0 0 0';
1464
1465                 if(vehicle_chase)
1466                 {
1467                         if(hud != HUD_BUMBLEBEE_GUN)
1468                         {
1469                                 Vehicle info = Vehicles_from(hud);
1470                                 vehicle_viewdist = info.height;
1471                                 vehicle_viewofs = info.view_ofs;
1472                         }
1473                 }
1474
1475                 if(ons_roundlost)
1476                 {
1477                         FOREACH_ENTITY_CLASS("onslaught_generator", it.health <= 0, LAMBDA(
1478                                 gen = it;
1479                                 break;
1480                         ));
1481                         if(!gen)
1482                                 ons_roundlost = false; // don't enforce the 3rd person camera if there is no dead generator to show
1483                 }
1484                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1485                 {
1486                         eventchase_running = true;
1487
1488                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1489                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1490                         if(ons_roundlost) { current_view_origin = gen.origin; }
1491
1492                         // detect maximum viewoffset and use it
1493                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1494                         if(vehicle_chase)
1495                         {
1496                                 if(vehicle_viewofs)
1497                                         view_offset = vehicle_viewofs;
1498                                 else
1499                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1500                         }
1501                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1502
1503                         if(view_offset)
1504                         {
1505                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1506                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1507                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1508                         }
1509
1510                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1511                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1512                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1513                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1514
1515                         // make the camera smooth back
1516                         float chase_distance = autocvar_cl_eventchase_distance;
1517                         if(vehicle_chase)
1518                         {
1519                                 if(vehicle_viewofs)
1520                                         chase_distance = vehicle_viewdist;
1521                                 else
1522                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1523                         }
1524                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1525
1526                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1527                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1528                         else if(eventchase_current_distance != chase_distance)
1529                                 eventchase_current_distance = chase_distance;
1530
1531                         makevectors(view_angles);
1532
1533                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1534                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1535
1536                         // If the boxtrace fails, revert back to line tracing.
1537                         if(!self.viewloc)
1538                         if(trace_startsolid)
1539                         {
1540                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1541                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1542                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1543                         }
1544                         else { setproperty(VF_ORIGIN, trace_endpos); }
1545
1546                         if(!self.viewloc)
1547                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1548                 }
1549                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1550                 {
1551                         eventchase_running = false;
1552                         cvar_set("chase_active", "0");
1553                         eventchase_current_distance = 0; // start from 0 next time
1554                 }
1555         }
1556         // workaround for camera stuck between player's legs when using chase_active 1
1557         // because the engine stops updating the chase_active camera when the game ends
1558         else if(intermission)
1559         {
1560                 cvar_settemp("chase_active", "-1");
1561                 eventchase_current_distance = 0;
1562         }
1563
1564         // do lockview after event chase camera so that it still applies whenever necessary.
1565         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1566         {
1567                 setproperty(VF_ORIGIN, freeze_org);
1568                 setproperty(VF_ANGLES, freeze_ang);
1569         }
1570         else
1571         {
1572                 freeze_org = getpropertyvec(VF_ORIGIN);
1573                 freeze_ang = getpropertyvec(VF_ANGLES);
1574         }
1575
1576         WarpZone_FixView();
1577         //WarpZone_FixPMove();
1578
1579         vector ov_org = '0 0 0';
1580         vector ov_mid = '0 0 0';
1581         vector ov_worldmin = '0 0 0';
1582         vector ov_worldmax = '0 0 0';
1583         if(autocvar_cl_orthoview)
1584         {
1585                 ov_worldmin = mi_picmin;
1586                 ov_worldmax = mi_picmax;
1587
1588                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1589                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1590                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1591
1592                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1593                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1594
1595                 float ov_nearest = vlen(ov_org - vec3(
1596                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1597                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1598                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1599                 ));
1600
1601                 float ov_furthest = 0;
1602                 float dist = 0;
1603
1604                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1605                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1606                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1607                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1608                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1609                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1610                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1611                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1612
1613                 if(!ov_enabled)
1614                 {
1615                         oldr_nearclip = cvar("r_nearclip");
1616                         oldr_farclip_base = cvar("r_farclip_base");
1617                         oldr_farclip_world = cvar("r_farclip_world");
1618                         oldr_novis = cvar("r_novis");
1619                         oldr_useportalculling = cvar("r_useportalculling");
1620                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1621                 }
1622
1623                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1624                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1625                 cvar_settemp("r_farclip_world", "0");
1626                 cvar_settemp("r_novis", "1");
1627                 cvar_settemp("r_useportalculling", "0");
1628                 cvar_settemp("r_useinfinitefarclip", "0");
1629
1630                 setproperty(VF_ORIGIN, ov_org);
1631                 setproperty(VF_ANGLES, '90 0 0');
1632
1633                 ov_enabled = true;
1634
1635                 #if 0
1636                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1637                         vtos(ov_org),
1638                         vtos(getpropertyvec(VF_ANGLES)),
1639                         ov_distance,
1640                         ov_nearest,
1641                         ov_furthest);
1642                 #endif
1643         }
1644         else
1645         {
1646                 if(ov_enabled)
1647                 {
1648                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1649                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1650                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1651                         cvar_set("r_novis", ftos(oldr_novis));
1652                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1653                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1654                 }
1655                 ov_enabled = false;
1656         }
1657
1658         // Render the Scene
1659         view_origin = getpropertyvec(VF_ORIGIN);
1660         view_angles = getpropertyvec(VF_ANGLES);
1661         makevectors(view_angles);
1662         view_forward = v_forward;
1663         view_right = v_right;
1664         view_up = v_up;
1665
1666 #ifdef BLURTEST
1667         if(time > blurtest_time0 && time < blurtest_time1)
1668         {
1669                 float r, t;
1670
1671                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1672                 r = t * blurtest_radius;
1673                 f = 1 / pow(t, blurtest_power) - 1;
1674
1675                 cvar_set("r_glsl_postprocess", "1");
1676                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1677         }
1678         else
1679         {
1680                 cvar_set("r_glsl_postprocess", "0");
1681                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1682         }
1683 #endif
1684
1685         TargetMusic_Advance();
1686         Fog_Force();
1687
1688         if(drawtime == 0)
1689                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1690         else
1691                 drawframetime = bound(0.000001, time - drawtime, 1);
1692         drawtime = time;
1693
1694         // watch for gametype changes here...
1695         // in ParseStuffCMD the cmd isn't executed yet :/
1696         // might even be better to add the gametype to TE_CSQC_INIT...?
1697         if(!postinit)
1698                 PostInit();
1699
1700         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1701         {
1702                 if(calledhooks & HOOK_START)
1703                 {
1704                         localcmd("\ncl_hook_gameend\n");
1705                         calledhooks |= HOOK_END;
1706                 }
1707         }
1708
1709         Announcer();
1710
1711         fov = autocvar_fov;
1712         if(fov <= 59.5)
1713         {
1714                 if(!zoomscript_caught)
1715                 {
1716                         localcmd("+button9\n");
1717                         zoomscript_caught = 1;
1718                 }
1719         }
1720         else
1721         {
1722                 if(zoomscript_caught)
1723                 {
1724                         localcmd("-button9\n");
1725                         zoomscript_caught = 0;
1726                 }
1727         }
1728
1729         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1730
1731         // currently switching-to weapon (for crosshair)
1732         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1733
1734         // actually active weapon (for zoom)
1735         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1736
1737         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1738
1739         f = (serverflags & SERVERFLAG_TEAMPLAY);
1740         if(f != teamplay)
1741         {
1742                 teamplay = f;
1743                 HUD_InitScores();
1744         }
1745
1746         if(last_switchweapon != switchweapon)
1747         {
1748                 weapontime = time;
1749                 last_switchweapon = switchweapon;
1750                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1751                 {
1752                         localcmd("-zoom\n");
1753                         button_zoom = false;
1754                 }
1755                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1756                 {
1757                         localcmd("-fire\n");
1758                         localcmd("-fire2\n");
1759                         button_attack2 = false;
1760                 }
1761         }
1762         if(last_activeweapon != activeweapon)
1763         {
1764                 last_activeweapon = activeweapon;
1765
1766                 e = activeweapon;
1767                 if(e.netname != "")
1768                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1769                 else
1770                         localcmd("\ncl_hook_activeweapon none\n");
1771         }
1772
1773         // ALWAYS Clear Current Scene First
1774         clearscene();
1775
1776         setproperty(VF_ORIGIN, view_origin);
1777         setproperty(VF_ANGLES, view_angles);
1778
1779         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1780         setproperty(VF_SIZE, vf_size);
1781         setproperty(VF_MIN, vf_min);
1782
1783         // Assign Standard Viewflags
1784         // Draw the World (and sky)
1785         setproperty(VF_DRAWWORLD, 1);
1786
1787         // Set the console size vars
1788         vid_conwidth = autocvar_vid_conwidth;
1789         vid_conheight = autocvar_vid_conheight;
1790         vid_pixelheight = autocvar_vid_pixelheight;
1791
1792         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1793         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1794         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1795
1796         // Camera for demo playback
1797         if(camera_active)
1798         {
1799                 if(autocvar_camera_enable)
1800                         CSQC_Demo_Camera();
1801                 else
1802                 {
1803                         cvar_set("chase_active", ftos(chase_active_backup));
1804                         cvar_set("cl_demo_mousegrab", "0");
1805                         camera_active = false;
1806                 }
1807         }
1808         else
1809         {
1810 #ifdef CAMERATEST
1811                 if(autocvar_camera_enable)
1812 #else
1813                 if(autocvar_camera_enable && isdemo())
1814 #endif
1815                 {
1816                         // Enable required Darkplaces cvars
1817                         chase_active_backup = autocvar_chase_active;
1818                         cvar_set("chase_active", "2");
1819                         cvar_set("cl_demo_mousegrab", "1");
1820                         camera_active = true;
1821                         camera_mode = false;
1822                 }
1823         }
1824
1825         // Draw the Crosshair
1826         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1827
1828         // Draw the Engine Status Bar (the default Quake HUD)
1829         setproperty(VF_DRAWENGINESBAR, 0);
1830
1831         // Update the mouse position
1832         /*
1833            mousepos_x = vid_conwidth;
1834            mousepos_y = vid_conheight;
1835            mousepos = mousepos*0.5 + getmousepos();
1836          */
1837
1838         FOREACH_ENTITY(it.draw, LAMBDA(WITH(entity, self, it, it.draw(it))));
1839
1840         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1841         renderscene();
1842
1843         // now switch to 2D drawing mode by calling a 2D drawing function
1844         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1845         // next R_RenderScene call
1846         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1847
1848         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1849         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1850         {
1851                 // apply night vision effect
1852                 vector tc_00, tc_01, tc_10, tc_11;
1853                 vector rgb = '0 0 0';
1854
1855                 if(!nightvision_noise)
1856                 {
1857                         nightvision_noise = new(nightvision_noise);
1858                 }
1859                 if(!nightvision_noise2)
1860                 {
1861                         nightvision_noise2 = new(nightvision_noise2);
1862                 }
1863
1864                 // color tint in yellow
1865                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1866
1867                 // draw BG
1868                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1869                 rgb = '1 1 1';
1870                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1871                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1872                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1873                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1874                 tc_11 = tc_01 + tc_10 - tc_00;
1875                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1876                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1877                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1878                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1879                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1880                 R_EndPolygon();
1881
1882                 // draw FG
1883                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1884                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1885                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1886                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1887                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1888                 tc_11 = tc_01 + tc_10 - tc_00;
1889                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1890                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1891                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1892                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1893                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1894                 R_EndPolygon();
1895         }
1896
1897         if(autocvar_cl_reticle)
1898         {
1899                 Weapon wep = activeweapon;
1900                 // Draw the aiming reticle for weapons that use it
1901                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1902                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1903                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1904                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1905                 {
1906                         // no zoom reticle while dead
1907                         reticle_type = 0;
1908                 }
1909                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1910                 {
1911                         if(reticle_image != "") { reticle_type = 2; }
1912                         else { reticle_type = 0; }
1913                 }
1914                 else if(button_zoom || zoomscript_caught)
1915                 {
1916                         // normal zoom
1917                         reticle_type = 1;
1918                 }
1919
1920                 if(reticle_type)
1921                 {
1922                         if(autocvar_cl_reticle_stretch)
1923                         {
1924                                 reticle_size.x = vid_conwidth;
1925                                 reticle_size.y = vid_conheight;
1926                                 reticle_pos.x = 0;
1927                                 reticle_pos.y = 0;
1928                         }
1929                         else
1930                         {
1931                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1932                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1933                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1934                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1935                         }
1936
1937                         if(zoomscript_caught)
1938                                 f = 1;
1939                         else
1940                                 f = current_zoomfraction;
1941
1942                         if(f)
1943                         {
1944                                 switch(reticle_type)
1945                                 {
1946                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1947                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1948                                 }
1949                         }
1950                 }
1951         }
1952         else
1953         {
1954                 if(reticle_type != 0) { reticle_type = 0; }
1955         }
1956
1957
1958         // improved polyblend
1959         if(autocvar_hud_contents)
1960         {
1961                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1962                 vector liquidcolor;
1963
1964                 switch(pointcontents(view_origin))
1965                 {
1966                         case CONTENT_WATER:
1967                                 liquidalpha = autocvar_hud_contents_water_alpha;
1968                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1969                                 incontent = 1;
1970                                 break;
1971
1972                         case CONTENT_LAVA:
1973                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1974                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1975                                 incontent = 1;
1976                                 break;
1977
1978                         case CONTENT_SLIME:
1979                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1980                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1981                                 incontent = 1;
1982                                 break;
1983
1984                         default:
1985                                 liquidalpha = 0;
1986                                 liquidcolor = '0 0 0';
1987                                 incontent = 0;
1988                                 break;
1989                 }
1990
1991                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1992                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1993                         contentfadetime = autocvar_hud_contents_fadeintime;
1994                         liquidalpha_prev = liquidalpha;
1995                         liquidcolor_prev = liquidcolor;
1996                 }
1997                 else
1998                         contentfadetime = autocvar_hud_contents_fadeouttime;
1999
2000                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2001                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2002
2003                 if(contentavgalpha)
2004                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2005
2006                 if(autocvar_hud_postprocessing)
2007                 {
2008                         if(autocvar_hud_contents_blur && contentavgalpha)
2009                         {
2010                                 content_blurpostprocess.x = 1;
2011                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2012                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2013                         }
2014                         else
2015                         {
2016                                 content_blurpostprocess.x = 0;
2017                                 content_blurpostprocess.y = 0;
2018                                 content_blurpostprocess.z = 0;
2019                         }
2020                 }
2021         }
2022
2023         if(autocvar_hud_damage && !STAT(FROZEN))
2024         {
2025                 splash_size.x = max(vid_conwidth, vid_conheight);
2026                 splash_size.y = max(vid_conwidth, vid_conheight);
2027                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2028                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2029
2030                 float myhealth_flash_temp;
2031                 myhealth = STAT(HEALTH);
2032
2033                 // fade out
2034                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2035                 // add new damage
2036                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2037
2038                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2039                 pain_threshold = autocvar_hud_damage_pain_threshold;
2040                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2041                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2042
2043                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2044                 {
2045                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2046                 }
2047
2048                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2049
2050                 if(myhealth_prev < 1)
2051                 {
2052                         if(myhealth >= 1)
2053                         {
2054                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2055                                 myhealth_flash_temp = 0;
2056                         }
2057                         else
2058                         {
2059                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2060                         }
2061                 }
2062
2063                 if(spectatee_status == -1 || intermission)
2064                 {
2065                         myhealth_flash = 0; // observing, or match ended
2066                         myhealth_flash_temp = 0;
2067                 }
2068
2069                 myhealth_prev = myhealth;
2070
2071                 // IDEA: change damage color/picture based on player model for robot/alien species?
2072                 // pro: matches model better
2073                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2074                 // maybe different reddish pics?
2075                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2076                 {
2077                         if(autocvar_cl_gentle_damage == 2)
2078                         {
2079                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2080                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2081                         }
2082                         else
2083                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2084
2085                         if(myhealth_flash_temp > 0)
2086                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2087                 }
2088                 else if(myhealth_flash_temp > 0)
2089                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2090
2091                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2092                 {
2093                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2094                         {
2095                                 damage_blurpostprocess.x = 1;
2096                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2097                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2098                         }
2099                         else
2100                         {
2101                                 damage_blurpostprocess.x = 0;
2102                                 damage_blurpostprocess.y = 0;
2103                                 damage_blurpostprocess.z = 0;
2104                         }
2105                 }
2106         }
2107
2108         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2109         float e2 = (autocvar_hud_powerup != 0);
2110         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2111         {
2112                 // enable or disable rendering types if they are used or not
2113                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2114                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2115
2116                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2117                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2118                 {
2119                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2120                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2121                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2122                         {
2123                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2124                                 old_blurradius = blurradius;
2125                                 old_bluralpha = bluralpha;
2126                         }
2127                 }
2128                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2129                 {
2130                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2131                         old_blurradius = 0;
2132                         old_bluralpha = 0;
2133                 }
2134
2135                 // edge detection postprocess handling done second (used by hud_powerup)
2136                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2137                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2138                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2139
2140                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2141
2142                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2143                 {
2144                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2145                         {
2146                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2147                                 old_sharpen_intensity = sharpen_intensity;
2148                         }
2149                 }
2150                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2151                 {
2152                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2153                         old_sharpen_intensity = 0;
2154                 }
2155
2156                 if(cvar("r_glsl_postprocess") == 0)
2157                         cvar_set("r_glsl_postprocess", "2");
2158         }
2159         else if(cvar("r_glsl_postprocess") == 2)
2160                 cvar_set("r_glsl_postprocess", "0");
2161
2162         /*if(gametype == MAPINFO_TYPE_CTF)
2163           {
2164           ctf_view();
2165           } else */
2166
2167         // draw 2D entities
2168         FOREACH_ENTITY(it.draw2d, LAMBDA(WITH(entity, self, it, it.draw2d(it))));
2169         Draw_ShowNames_All();
2170         Debug_Draw();
2171
2172         scoreboard_active = HUD_WouldDrawScoreboard();
2173
2174         HUD_Draw();
2175
2176         if(NextFrameCommand)
2177         {
2178                 localcmd("\n", NextFrameCommand, "\n");
2179                 NextFrameCommand = string_null;
2180         }
2181
2182         // we must do this check AFTER a frame was rendered, or it won't work
2183         if(cs_project_is_b0rked == 0)
2184         {
2185                 string w0, h0;
2186                 w0 = ftos(autocvar_vid_conwidth);
2187                 h0 = ftos(autocvar_vid_conheight);
2188                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2189                 //setproperty(VF_FOV, '90 90 0');
2190                 setproperty(VF_ORIGIN, '0 0 0');
2191                 setproperty(VF_ANGLES, '0 0 0');
2192                 setproperty(VF_PERSPECTIVE, 1);
2193                 makevectors('0 0 0');
2194                 vector v1, v2;
2195                 cvar_set("vid_conwidth", "800");
2196                 cvar_set("vid_conheight", "600");
2197                 v1 = cs_project(v_forward);
2198                 cvar_set("vid_conwidth", "640");
2199                 cvar_set("vid_conheight", "480");
2200                 v2 = cs_project(v_forward);
2201                 if(v1 == v2)
2202                         cs_project_is_b0rked = 1;
2203                 else
2204                         cs_project_is_b0rked = -1;
2205                 cvar_set("vid_conwidth", w0);
2206                 cvar_set("vid_conheight", h0);
2207         }
2208
2209         if(autocvar__hud_configure)
2210                 HUD_Panel_Mouse();
2211         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2212                 HUD_Minigame_Mouse();
2213         else if(QuickMenu_IsOpened())
2214                 QuickMenu_Mouse();
2215         else
2216                 HUD_Radar_Mouse();
2217
2218         cl_notice_run();
2219         unpause_update();
2220         Net_Flush();
2221
2222         // let's reset the view back to normal for the end
2223         setproperty(VF_MIN, '0 0 0');
2224         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2225 }
2226
2227
2228 // following vectors must be global to allow seamless switching between camera modes
2229 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2230 void CSQC_Demo_Camera()
2231 {
2232         float speed, attenuation, dimensions;
2233         vector tmp, delta;
2234
2235         if( autocvar_camera_reset || !camera_mode )
2236         {
2237                 camera_offset = '0 0 0';
2238                 current_angles = '0 0 0';
2239                 camera_direction = '0 0 0';
2240                 camera_offset.z += 30;
2241                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2242                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2243                 current_origin = view_origin;
2244                 current_camera_offset  = camera_offset;
2245                 cvar_set("camera_reset", "0");
2246                 camera_mode = CAMERA_CHASE;
2247         }
2248
2249         // Camera angles
2250         if( camera_roll )
2251                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2252
2253         if(autocvar_camera_look_player)
2254         {
2255                 vector dir;
2256                 float n;
2257
2258                 dir = normalize(view_origin - current_position);
2259                 n = mouse_angles.z;
2260                 mouse_angles = vectoangles(dir);
2261                 mouse_angles.x = mouse_angles.x * -1;
2262                 mouse_angles.z = n;
2263         }
2264         else
2265         {
2266                 tmp = getmousepos() * 0.1;
2267                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2268                 {
2269                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2270                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2271                 }
2272         }
2273
2274         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2275         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2276         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2277         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2278
2279         // Fix difference when angles don't have the same sign
2280         delta = '0 0 0';
2281         if(mouse_angles.y < -60 && current_angles.y > 60)
2282                 delta = '0 360 0';
2283         if(mouse_angles.y > 60 && current_angles.y < -60)
2284                 delta = '0 -360 0';
2285
2286         if(autocvar_camera_look_player)
2287                 attenuation = autocvar_camera_look_attenuation;
2288         else
2289                 attenuation = autocvar_camera_speed_attenuation;
2290
2291         attenuation = 1 / max(1, attenuation);
2292         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2293
2294         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2295         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2296         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2297         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2298
2299         // Camera position
2300         tmp = '0 0 0';
2301         dimensions = 0;
2302
2303         if( camera_direction.x )
2304         {
2305                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2306                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2307                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2308                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2309                 ++dimensions;
2310         }
2311
2312         if( camera_direction.y )
2313         {
2314                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2315                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2316                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2317                 ++dimensions;
2318         }
2319
2320         if( camera_direction.z )
2321         {
2322                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2323                 ++dimensions;
2324         }
2325
2326         if(autocvar_camera_free)
2327                 speed = autocvar_camera_speed_free;
2328         else
2329                 speed = autocvar_camera_speed_chase;
2330
2331         if(dimensions)
2332         {
2333                 speed = speed * sqrt(1 / dimensions);
2334                 camera_offset += tmp * speed;
2335         }
2336
2337         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2338
2339         // Camera modes
2340         if( autocvar_camera_free )
2341         {
2342                 if ( camera_mode == CAMERA_CHASE )
2343                 {
2344                         current_camera_offset = current_origin + current_camera_offset;
2345                         camera_offset = current_origin + camera_offset;
2346                 }
2347
2348                 camera_mode = CAMERA_FREE;
2349                 current_position = current_camera_offset;
2350         }
2351         else
2352         {
2353                 if ( camera_mode == CAMERA_FREE )
2354                 {
2355                         current_origin = view_origin;
2356                         camera_offset = camera_offset - current_origin;
2357                         current_camera_offset = current_camera_offset - current_origin;
2358                 }
2359
2360                 camera_mode = CAMERA_CHASE;
2361
2362                 if(autocvar_camera_chase_smoothly)
2363                         current_origin += (view_origin - current_origin) * attenuation;
2364                 else
2365                         current_origin = view_origin;
2366
2367                 current_position = current_origin + current_camera_offset;
2368         }
2369
2370         setproperty(VF_ANGLES, current_angles);
2371         setproperty(VF_ORIGIN, current_position);
2372 }