qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/debug.qh>
  17 #include <common/mapinfo.qh>
  18 #include <common/gamemodes/_mod.qh>
  19 #include <common/physics/player.qh>
  20 #include <common/stats.qh>
  21 #include <common/triggers/target/music.qh>
  22 #include <common/teams.qh>
  23
  24 #include <common/vehicles/all.qh>
  25 #include <common/weapons/_all.qh>
  26 #include <common/viewloc.qh>
  27 #include <common/minigames/cl_minigames.qh>
  28 #include <common/minigames/cl_minigames_hud.qh>
  29
  30 #include <lib/csqcmodel/cl_player.qh>
  31 #include <lib/csqcmodel/cl_model.qh>
  32 #include "csqcmodel_hooks.qh"
  33
  34 #include <lib/warpzone/client.qh>
  35 #include <lib/warpzone/common.qh>
  36
  37 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  38
  39 float autocvar_cl_viewmodel_scale;
  40
  41 bool autocvar_cl_bobmodel;
  42 float autocvar_cl_bobmodel_speed;
  43 float autocvar_cl_bobmodel_side;
  44 float autocvar_cl_bobmodel_up;
  45
  46 float autocvar_cl_followmodel;
  47 float autocvar_cl_followmodel_speed = 0.3;
  48 float autocvar_cl_followmodel_limit = 135;
  49 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  50 float autocvar_cl_followmodel_highpass = 0.05;
  51 float autocvar_cl_followmodel_lowpass = 0.03;
  52 bool autocvar_cl_followmodel_velocity_absolute;
  53
  54 float autocvar_cl_leanmodel;
  55 float autocvar_cl_leanmodel_speed = 0.3;
  56 float autocvar_cl_leanmodel_limit = 30;
  57 float autocvar_cl_leanmodel_highpass1 = 0.2;
  58 float autocvar_cl_leanmodel_highpass = 0.2;
  59 float autocvar_cl_leanmodel_lowpass = 0.05;
  60
  61 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  62 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  63 { \
  64         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  65 } MACRO_END
  66
  67 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  68 { \
  69         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  70         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  71 } MACRO_END
  72
  73 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  74 { \
  75         float __f = 0; lowpass(value, frac, ref_store, __f); \
  76         ret = (value) - __f; \
  77 } MACRO_END
  78
  79 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  80 { \
  81         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  82         ret = (value) - __f; \
  83 } MACRO_END
  84
  85 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  86 { \
  87         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  88         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  89 } MACRO_END
  90
  91 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  92 { \
  93         highpass(value.x, frac, ref_store.x, ref_out.x); \
  94         highpass(value.y, frac, ref_store.y, ref_out.y); \
  95 } MACRO_END
  96
  97 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 100         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 101 } MACRO_END
 102
 103 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 104 { \
 105         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 106         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 107         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 108 } MACRO_END
 109
 110 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         highpass(value.x, frac, ref_store.x, ref_out.x); \
 113         highpass(value.y, frac, ref_store.y, ref_out.y); \
 114         highpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 void calc_followmodel_ofs(entity view)
 118 {
 119         if(cl_followmodel_time == time)
 120                 return; // cl_followmodel_ofs already calculated for this frame
 121
 122         float frac;
 123         vector gunorg = '0 0 0';
 124         static vector vel_average;
 125         static vector gunorg_prev = '0 0 0';
 126         static vector gunorg_adjustment_highpass;
 127         static vector gunorg_adjustment_lowpass;
 128
 129         vector vel;
 130         if (autocvar_cl_followmodel_velocity_absolute)
 131                 vel = view.velocity;
 132         else
 133         {
 134                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 135                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 136                 vel.x = view.velocity * forward;
 137                 vel.y = view.velocity * right * -1;
 138                 vel.z = view.velocity * up;
 139         }
 140
 141         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 142         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 143         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 144
 145         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 146         lowpass3(vel, frac, vel_average, gunorg);
 147
 148         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 149
 150         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 151         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 152         frac = avg_factor(autocvar_cl_followmodel_highpass);
 153         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 154         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 155         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 156
 157         if (autocvar_cl_followmodel_velocity_absolute)
 158         {
 159                 vector fixed_gunorg;
 160                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 161                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 162                 fixed_gunorg.x = gunorg * forward;
 163                 fixed_gunorg.y = gunorg * right * -1;
 164                 fixed_gunorg.z = gunorg * up;
 165                 gunorg = fixed_gunorg;
 166         }
 167
 168         cl_followmodel_ofs = gunorg;
 169         cl_followmodel_time = time;
 170 }
 171
 172 vector leanmodel_ofs(entity view)
 173 {
 174         float frac;
 175         vector gunangles = '0 0 0';
 176         static vector gunangles_prev = '0 0 0';
 177         static vector gunangles_highpass = '0 0 0';
 178         static vector gunangles_adjustment_highpass;
 179         static vector gunangles_adjustment_lowpass;
 180
 181         if (view.csqcmodel_teleported)
 182                 gunangles_prev = view_angles;
 183
 184         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 185         gunangles_highpass += gunangles_prev;
 186         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 187         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 188         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 189         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 190         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 191         gunangles_prev = view_angles;
 192         gunangles_highpass -= gunangles_prev;
 193
 194         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 195         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 196
 197         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 198         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 199         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 200         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 201         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 202
 203         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 204
 205         return gunangles;
 206 }
 207
 208 vector bobmodel_ofs(entity view)
 209 {
 210         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 211         static bool oldonground;
 212         static float hitgroundtime;
 213         if (clonground)
 214         {
 215                 float f = time; // cl.movecmd[0].time
 216                 if (!oldonground)
 217                         hitgroundtime = f;
 218         }
 219         oldonground = clonground;
 220
 221         // calculate for swinging gun model
 222         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 223         vector gunorg = '0 0 0';
 224         static float bobmodel_scale = 0;
 225         static float time_ofs = 0; // makes the effect always restart in the same way
 226         if (clonground)
 227         {
 228                 if (time - hitgroundtime > 0.05)
 229                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 230         }
 231         else
 232                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 233
 234         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 235         if (bobmodel_scale && xyspeed)
 236         {
 237                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 238                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 239                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 240                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 241         }
 242         else
 243                 time_ofs = time;
 244
 245         return gunorg;
 246 }
 247
 248 void viewmodel_animate(entity this)
 249 {
 250         if (autocvar_chase_active) return;
 251         if (STAT(HEALTH) <= 0) return;
 252
 253         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 254
 255         if (autocvar_cl_followmodel)
 256         {
 257                 calc_followmodel_ofs(view);
 258                 this.origin += cl_followmodel_ofs;
 259         }
 260
 261         if (autocvar_cl_leanmodel)
 262                 this.angles += leanmodel_ofs(view);
 263
 264         // vertical view bobbing code
 265         // TODO: cl_bob
 266
 267         // horizontal view bobbing code
 268         // TODO: cl_bob2
 269
 270         // fall bobbing code
 271         // causes the view to swing down and back up when touching the ground
 272         // TODO: cl_bobfall
 273
 274         // gun model bobbing code
 275         if (autocvar_cl_bobmodel)
 276                 this.origin += bobmodel_ofs(view);
 277 }
 278
 279 .vector viewmodel_origin, viewmodel_angles;
 280 .float weapon_nextthink;
 281 .float weapon_eta_last;
 282 .float weapon_switchdelay;
 283
 284 .string name_last;
 285
 286 void viewmodel_draw(entity this)
 287 {
 288         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 289                 return;
 290         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 291         float a = this.alpha;
 292         static bool wasinvehicle;
 293         bool invehicle = player_localentnum > maxclients;
 294         if (invehicle) a = -1;
 295         else if (wasinvehicle) a = 1;
 296         wasinvehicle = invehicle;
 297         Weapon wep = this.activeweapon;
 298         int c = entcs_GetClientColors(current_player);
 299         vector g = weaponentity_glowmod(wep, NULL, c, this);
 300         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 301         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 302                 | EF_NODEPTHTEST)
 303                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 304         for (entity e = this; e; e = e.weaponchild)
 305         {
 306                 e.drawmask = mask;
 307                 e.alpha = a;
 308                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 309                 e.glowmod = g;
 310                 e.csqcmodel_effects = fx;
 311                 CSQCModel_Effects_Apply(e);
 312         }
 313         {
 314                 string name = wep.mdl;
 315                 if(wep == WEP_TUBA)
 316                 {
 317                         name = (this.tuba_instrument == 0) ? "tuba" :
 318                            (this.tuba_instrument == 1) ? "akordeon" :
 319                                                      "kleinbottle";
 320                 }
 321                 bool swap = name != this.name_last;
 322                 // if (swap)
 323                 {
 324                         this.name_last = name;
 325                         CL_WeaponEntity_SetModel(this, name, swap);
 326                         this.viewmodel_origin = this.origin;
 327                         this.viewmodel_angles = this.angles;
 328                 }
 329                 anim_update(this);
 330                 if (!this.animstate_override && !this.animstate_looping)
 331                         anim_set(this, this.anim_idle, true, false, false);
 332         }
 333         float f = 0; // 0..1; 0: fully active
 334         float rate = STAT(WEAPONRATEFACTOR);
 335         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 336         if (eta <= 0) f = this.weapon_eta_last;
 337         else switch (this.state)
 338         {
 339                 case WS_RAISE:
 340                 {
 341                         f = eta / max(eta, this.weapon_switchdelay);
 342                         break;
 343                 }
 344                 case WS_DROP:
 345                 {
 346                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 347                         break;
 348                 }
 349                 case WS_CLEAR:
 350                 {
 351                         f = 1;
 352                         break;
 353                 }
 354         }
 355         this.weapon_eta_last = f;
 356         this.origin = this.viewmodel_origin;
 357         this.angles = this.viewmodel_angles;
 358         this.angles_x = (-90 * f * f);
 359         viewmodel_animate(this);
 360         setorigin(this, this.origin);
 361 }
 362
 363 STATIC_INIT(viewmodel) {
 364     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         viewmodels[slot] = new(viewmodel);
 366 }
 367
 368 void Porto_Draw(entity this);
 369 STATIC_INIT(Porto)
 370 {
 371         entity e = new_pure(porto);
 372         e.draw = Porto_Draw;
 373         IL_PUSH(g_drawables, e);
 374         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 375 }
 376
 377 const int polyline_length = 16;
 378 .vector polyline[polyline_length];
 379 void Porto_Draw(entity this)
 380 {
 381         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 382         {
 383                 entity wepent = viewmodels[slot];
 384
 385                 if (wepent.activeweapon != WEP_PORTO) continue;
 386                 if (spectatee_status) continue;
 387                 if (WEP_CVAR(porto, secondary)) continue;
 388                 if (intermission == 1) continue;
 389                 if (intermission == 2) continue;
 390                 if (STAT(HEALTH) <= 0) continue;
 391
 392                 vector pos = view_origin;
 393                 vector dir = view_forward;
 394                 if (wepent.angles_held_status)
 395                 {
 396                         makevectors(wepent.angles_held);
 397                         dir = v_forward;
 398                 }
 399
 400                 wepent.polyline[0] = pos;
 401
 402                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 403                 int n = 1 + 2;  // 2 lines == 3 points
 404                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 405                 {
 406                         traceline(pos, pos + 65536 * dir, true, this);
 407                         dir = reflect(dir, trace_plane_normal);
 408                         pos = trace_endpos;
 409                         wepent.polyline[++idx] = pos;
 410                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 411                         {
 412                                 n += 1;
 413                                 continue;
 414                         }
 415                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 416                         {
 417                                 n = max(2, idx);
 418                                 break;
 419                         }
 420                         // check size
 421                         {
 422                                 vector ang = vectoangles2(trace_plane_normal, dir);
 423                                 ang.x = -ang.x;
 424                                 makevectors(ang);
 425                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 426                                 {
 427                                         n = max(2, idx);
 428                                         break;
 429                                 }
 430                         }
 431                         portal_number += 1;
 432                         if (portal_number >= portal_max) break;
 433                         if (portal_number == 1) portal1_idx = idx;
 434                 }
 435                 for (int idx = 0; idx < n - 1; ++idx)
 436                 {
 437                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 438                         if (idx == 0) p -= view_up * 16;  // line from player
 439                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 440                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 441                 }
 442         }
 443 }
 444
 445 float drawtime;
 446 float avgspeed;
 447 vector GetCurrentFov(float fov)
 448 {
 449         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 450         float velocityzoom, curspeed;
 451         vector v;
 452
 453         zoomsensitivity = autocvar_cl_zoomsensitivity;
 454         zoomfactor = autocvar_cl_zoomfactor;
 455         if(zoomfactor < 1 || zoomfactor > 30)
 456                 zoomfactor = 2.5;
 457         zoomspeed = autocvar_cl_zoomspeed;
 458         if(zoomspeed >= 0)
 459         if(zoomspeed < 0.5 || zoomspeed > 16)
 460                         zoomspeed = 3.5;
 461
 462         zoomdir = button_zoom;
 463
 464         if(hud == HUD_NORMAL && !spectatee_status)
 465         {
 466                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 467                 {
 468                         entity wepent = viewmodels[slot];
 469                         if(wepent.switchweapon == wepent.activeweapon)
 470                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 471                                 zoomdir += button_attack2;
 472                 }
 473         }
 474         if(spectatee_status > 0 || isdemo())
 475         {
 476                 if(spectatorbutton_zoom)
 477                 {
 478                         if(zoomdir)
 479                                 zoomdir = 0;
 480                         else
 481                                 zoomdir = 1;
 482                 }
 483                 // fteqcc failed twice here already, don't optimize this
 484         }
 485
 486         if(zoomdir) { zoomin_effect = 0; }
 487
 488         if(camera_active)
 489         {
 490                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 491         }
 492         else if(autocvar_cl_spawnzoom && zoomin_effect)
 493         {
 494                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 495
 496                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 497                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 498                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 499         }
 500         else
 501         {
 502                 if(zoomspeed < 0) // instant zoom
 503                 {
 504                         if(zoomdir)
 505                                 current_viewzoom = 1 / zoomfactor;
 506                         else
 507                                 current_viewzoom = 1;
 508                 }
 509                 else
 510                 {
 511                         if(zoomdir)
 512                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 513                         else
 514                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 515                 }
 516         }
 517
 518         if(almost_equals(current_viewzoom, 1))
 519                 current_zoomfraction = 0;
 520         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 521                 current_zoomfraction = 1;
 522         else
 523                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 524
 525         if(zoomsensitivity < 1)
 526                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 527         else
 528                 setsensitivityscale(1);
 529
 530         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 531         {
 532                 if(intermission) { curspeed = 0; }
 533                 else
 534                 {
 535
 536                         makevectors(view_angles);
 537                         v = pmove_vel;
 538                         if(csqcplayer)
 539                                 v = csqcplayer.velocity;
 540
 541                         switch(autocvar_cl_velocityzoom_type)
 542                         {
 543                                 case 3: curspeed = max(0, v_forward * v); break;
 544                                 case 2: curspeed = (v_forward * v); break;
 545                                 case 1: default: curspeed = vlen(v); break;
 546                         }
 547                 }
 548
 549                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 550                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 551                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 552
 553                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 554         }
 555         else
 556                 velocityzoom = 1;
 557
 558         float frustumx, frustumy, fovx, fovy;
 559         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 560         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 561         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 562         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 563
 564         return '1 0 0' * fovx + '0 1 0' * fovy;
 565 }
 566
 567 vector GetViewLocationFOV(float fov)
 568 {
 569         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 570         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 571         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 572         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 573         return '1 0 0' * fovx + '0 1 0' * fovy;
 574 }
 575
 576 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 577 {
 578         float fovx, fovy;
 579         float width = (ov_worldmax.x - ov_worldmin.x);
 580         float height = (ov_worldmax.y - ov_worldmin.y);
 581         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 582         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 583         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 584         return '1 0 0' * fovx + '0 1 0' * fovy;
 585 }
 586
 587 // this function must match W_SetupShot!
 588 float zoomscript_caught;
 589
 590 vector wcross_origin;
 591 float wcross_scale_prev, wcross_alpha_prev;
 592 vector wcross_color_prev;
 593 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 594 vector wcross_color_goal_prev;
 595 float wcross_changedonetime;
 596
 597 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 598 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 599 float wcross_name_changestarttime, wcross_name_changedonetime;
 600 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 601
 602 float wcross_ring_prev;
 603
 604 entity trueaim;
 605 entity trueaim_rifle;
 606
 607 const float SHOTTYPE_HITTEAM = 1;
 608 const float SHOTTYPE_HITOBSTRUCTION = 2;
 609 const float SHOTTYPE_HITWORLD = 3;
 610 const float SHOTTYPE_HITENEMY = 4;
 611
 612 void TrueAim_Init()
 613 {
 614         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 615         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 616 }
 617
 618 float EnemyHitCheck()
 619 {
 620         float t, n;
 621         wcross_origin = project_3d_to_2d(trace_endpos);
 622         wcross_origin.z = 0;
 623         if(trace_ent)
 624                 n = trace_ent.entnum;
 625         else
 626                 n = trace_networkentity;
 627         if(n < 1)
 628                 return SHOTTYPE_HITWORLD;
 629         if(n > maxclients)
 630                 return SHOTTYPE_HITWORLD;
 631         t = entcs_GetTeam(n - 1);
 632         if(teamplay)
 633                 if(t == myteam)
 634                         return SHOTTYPE_HITTEAM;
 635         if(t == NUM_SPECTATOR)
 636                 return SHOTTYPE_HITWORLD;
 637         return SHOTTYPE_HITENEMY;
 638 }
 639
 640 float TrueAimCheck(entity wepent)
 641 {
 642         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 643         vector vecs, trueaimpoint, w_shotorg;
 644         vector mi, ma, dv;
 645         float shottype;
 646         entity ta;
 647         float mv;
 648
 649         mi = ma = '0 0 0';
 650         ta = trueaim;
 651         mv = MOVE_NOMONSTERS;
 652
 653         switch(wepent.activeweapon) // WEAPONTODO
 654         {
 655                 case WEP_TUBA: // no aim
 656                 case WEP_PORTO: // shoots from eye
 657                 case WEP_NEXBALL: // shoots from eye
 658                 case WEP_HOOK: // no trueaim
 659                 case WEP_MORTAR: // toss curve
 660                         return SHOTTYPE_HITWORLD;
 661                 case WEP_VORTEX:
 662                 case WEP_VAPORIZER:
 663                         mv = MOVE_NORMAL;
 664                         break;
 665                 case WEP_RIFLE:
 666                         ta = trueaim_rifle;
 667                         mv = MOVE_NORMAL;
 668                         if(zoomscript_caught)
 669                         {
 670                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 671                                 return EnemyHitCheck();
 672                         }
 673                         break;
 674                 case WEP_DEVASTATOR: // projectile has a size!
 675                         mi = '-3 -3 -3';
 676                         ma = '3 3 3';
 677                         break;
 678                 case WEP_FIREBALL: // projectile has a size!
 679                         mi = '-16 -16 -16';
 680                         ma = '16 16 16';
 681                         break;
 682                 case WEP_SEEKER: // projectile has a size!
 683                         mi = '-2 -2 -2';
 684                         ma = '2 2 2';
 685                         break;
 686                 case WEP_ELECTRO: // projectile has a size!
 687                         mi = '0 0 -3';
 688                         ma = '0 0 -3';
 689                         break;
 690         }
 691
 692         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 693
 694         vecs = decompressShotOrigin(STAT(SHOTORG));
 695
 696         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 697         trueaimpoint = trace_endpos;
 698
 699         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 700                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 701
 702         if(vecs.x > 0)
 703                 vecs.y = -vecs.y;
 704         else
 705                 vecs = '0 0 0';
 706
 707         dv = view_right * vecs.y + view_up * vecs.z;
 708         w_shotorg = traceorigin + dv;
 709
 710         // now move the vecs forward as much as requested if possible
 711         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 712         w_shotorg = trace_endpos - view_forward * nudge;
 713
 714         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 715         shottype = EnemyHitCheck();
 716         if(shottype != SHOTTYPE_HITWORLD)
 717                 return shottype;
 718
 719 #if 0
 720         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 721         // or rather, I know why, but see no fix
 722         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 723                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 724                 return SHOTTYPE_HITOBSTRUCTION;
 725 #endif
 726
 727         return SHOTTYPE_HITWORLD;
 728 }
 729
 730 void PostInit();
 731 void CSQC_Demo_Camera();
 732 float camera_mode;
 733 const float CAMERA_FREE = 1;
 734 const float CAMERA_CHASE = 2;
 735 float reticle_type;
 736 string NextFrameCommand;
 737
 738 vector freeze_org, freeze_ang;
 739 entity nightvision_noise, nightvision_noise2;
 740
 741 const float MAX_TIME_DIFF = 5;
 742 float pickup_crosshair_time, pickup_crosshair_size;
 743 float hitindication_crosshair_size;
 744 float use_vortex_chargepool;
 745
 746 float myhealth, myhealth_prev;
 747 float myhealth_flash;
 748
 749 float old_blurradius, old_bluralpha;
 750 float old_sharpen_intensity;
 751
 752 vector myhealth_gentlergb;
 753
 754 float contentavgalpha, liquidalpha_prev;
 755 vector liquidcolor_prev;
 756
 757 float eventchase_current_distance;
 758 float eventchase_running;
 759 bool WantEventchase(entity this)
 760 {
 761         if(autocvar_cl_orthoview)
 762                 return false;
 763         if(intermission)
 764                 return true;
 765         if(this.viewloc)
 766                 return true;
 767         if(spectatee_status >= 0)
 768         {
 769                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 770                         return true;
 771                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 772                         return true;
 773                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 774                 {
 775                         if(autocvar_cl_eventchase_death == 2)
 776                         {
 777                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 778                                 if(this.velocity == '0 0 0' || eventchase_running)
 779                                         return true;
 780                         }
 781                         else return true;
 782                 }
 783         }
 784         return false;
 785 }
 786
 787 void HUD_Crosshair_Vehicle(entity this)
 788 {
 789         if(hud != HUD_BUMBLEBEE_GUN)
 790         {
 791                 Vehicle info = Vehicles_from(hud);
 792                 info.vr_crosshair(info, this);
 793         }
 794 }
 795
 796 vector damage_blurpostprocess, content_blurpostprocess;
 797
 798 float unaccounted_damage = 0;
 799 void UpdateDamage()
 800 {
 801         // accumulate damage with each stat update
 802         static float damage_total_prev = 0;
 803         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 804         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 805         damage_total_prev = damage_total;
 806
 807         static float damage_dealt_time_prev = 0;
 808         float damage_dealt_time = STAT(HIT_TIME);
 809         if (damage_dealt_time != damage_dealt_time_prev)
 810         {
 811                 unaccounted_damage += unaccounted_damage_new;
 812                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 813         }
 814         damage_dealt_time_prev = damage_dealt_time;
 815
 816         // prevent hitsound when switching spectatee
 817         static float spectatee_status_prev = 0;
 818         if (spectatee_status != spectatee_status_prev)
 819                 unaccounted_damage = 0;
 820         spectatee_status_prev = spectatee_status;
 821 }
 822
 823 void HitSound()
 824 {
 825         // varying sound pitch
 826
 827         bool have_arc = false;
 828         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 829         {
 830                 entity wepent = viewmodels[slot];
 831
 832                 if(wepent.activeweapon == WEP_ARC)
 833                         have_arc = true;
 834         }
 835
 836         static float hitsound_time_prev = 0;
 837         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 838         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 839         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 840         {
 841                 if (autocvar_cl_hitsound && unaccounted_damage)
 842                 {
 843                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 844                         float a = autocvar_cl_hitsound_max_pitch;
 845                         float b = autocvar_cl_hitsound_min_pitch;
 846                         float c = autocvar_cl_hitsound_nom_damage;
 847                         float x = unaccounted_damage;
 848                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 849
 850                         // if sound variation is disabled, set pitch_shift to 1
 851                         if (autocvar_cl_hitsound == 1)
 852                                 pitch_shift = 1;
 853
 854                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 855                         if (autocvar_cl_hitsound == 3)
 856                         {
 857                                 float mirror_value = (a-b)/2 + b;
 858                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 859                         }
 860
 861                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 862
 863                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 864                         // todo: normalize sound pressure levels? seems unnecessary
 865
 866                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 867                 }
 868                 unaccounted_damage = 0;
 869                 hitsound_time_prev = time;
 870         }
 871
 872         static float typehit_time_prev = 0;
 873         float typehit_time = STAT(TYPEHIT_TIME);
 874         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 875         {
 876                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 877                 typehit_time_prev = typehit_time;
 878         }
 879 }
 880
 881 vector crosshair_getcolor(entity this, float health_stat)
 882 {
 883         static float rainbow_last_flicker;
 884         static vector rainbow_prev_color;
 885         vector wcross_color = '0 0 0';
 886         switch(autocvar_crosshair_color_special)
 887         {
 888                 case 1: // crosshair_color_per_weapon
 889                 {
 890                         if(this != WEP_Null && hud == HUD_NORMAL)
 891                         {
 892                                 wcross_color = this.wpcolor;
 893                                 break;
 894                         }
 895                         else { goto normalcolor; }
 896                 }
 897
 898                 case 2: // crosshair_color_by_health
 899                 {
 900                         float x = health_stat;
 901
 902                         //x = red
 903                         //y = green
 904                         //z = blue
 905
 906                         wcross_color.z = 0;
 907
 908                         if(x > 200)
 909                         {
 910                                 wcross_color.x = 0;
 911                                 wcross_color.y = 1;
 912                         }
 913                         else if(x > 150)
 914                         {
 915                                 wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 916                                 wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 917                         }
 918                         else if(x > 100)
 919                         {
 920                                 wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 921                                 wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 922                                 wcross_color.z = 1 - (x-100)*0.02;
 923                         }
 924                         else if(x > 50)
 925                         {
 926                                 wcross_color.x = 1;
 927                                 wcross_color.y = 1;
 928                                 wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 929                         }
 930                         else if(x > 20)
 931                         {
 932                                 wcross_color.x = 1;
 933                                 wcross_color.y = (x-20)*90/27/100;
 934                                 wcross_color.z = (x-20)*90/27/100 * 0.2;
 935                         }
 936                         else
 937                         {
 938                                 wcross_color.x = 1;
 939                                 wcross_color.y = 0;
 940                         }
 941                         break;
 942                 }
 943
 944                 case 3: // crosshair_color_rainbow
 945                 {
 946                         if(time >= rainbow_last_flicker)
 947                         {
 948                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 949                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 950                         }
 951                         wcross_color = rainbow_prev_color;
 952                         break;
 953                 }
 954 LABEL(normalcolor)
 955                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 956         }
 957
 958         return wcross_color;
 959 }
 960
 961 void HUD_Crosshair(entity this)
 962 {
 963         float f, i, j;
 964         vector v;
 965         if(!scoreboard_active && !camera_active && intermission != 2 &&
 966                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 967                 !HUD_MinigameMenu_IsOpened() )
 968         {
 969                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 970                         return;
 971
 972                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 973                         return;
 974
 975                 if (hud != HUD_NORMAL)
 976                 {
 977                         HUD_Crosshair_Vehicle(this);
 978                         return;
 979                 }
 980
 981                 string wcross_style;
 982                 float wcross_alpha, wcross_resolution;
 983                 wcross_style = autocvar_crosshair;
 984                 if (wcross_style == "0")
 985                         return;
 986                 wcross_resolution = autocvar_crosshair_size;
 987                 if (wcross_resolution == 0)
 988                         return;
 989                 wcross_alpha = autocvar_crosshair_alpha;
 990                 if (wcross_alpha == 0)
 991                         return;
 992
 993                 // TrueAim check
 994                 float shottype;
 995
 996                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 997                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 998                 wcross_origin.z = 0;
 999                 if(autocvar_crosshair_hittest)
1000                 {
1001                         vector wcross_oldorigin;
1002                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1003                         wcross_oldorigin = wcross_origin;
1004                         shottype = TrueAimCheck(thiswep);
1005                         if(shottype == SHOTTYPE_HITWORLD)
1006                         {
1007                                 v = wcross_origin - wcross_oldorigin;
1008                                 v.x /= vid_conwidth;
1009                                 v.y /= vid_conheight;
1010                                 if(vdist(v, >, 0.01))
1011                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1012                         }
1013                         if(!autocvar_crosshair_hittest_showimpact)
1014                                 wcross_origin = wcross_oldorigin;
1015                 }
1016                 else
1017                         shottype = SHOTTYPE_HITWORLD;
1018
1019                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1020                 string wcross_name = "";
1021                 float wcross_scale, wcross_blur;
1022
1023         entity e = WEP_Null;
1024                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1025                 {
1026                         entity wepent = viewmodels[0]; // TODO: unhardcode
1027                         e = wepent.switchingweapon;
1028                         if(e)
1029                         {
1030                                 if(autocvar_crosshair_per_weapon)
1031                                 {
1032                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1033                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1034                                         //if (wcross_resolution == 0)
1035                                                 //return;
1036
1037                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1038                                         wcross_resolution *= e.w_crosshair_size;
1039                                         wcross_name = e.w_crosshair;
1040                                 }
1041                         }
1042                 }
1043
1044                 if(wcross_name == "")
1045                         wcross_name = strcat("gfx/crosshair", wcross_style);
1046
1047                 // MAIN CROSSHAIR COLOR DECISION
1048                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1049
1050                 if(autocvar_crosshair_effect_scalefade)
1051                 {
1052                         wcross_scale = wcross_resolution;
1053                         wcross_resolution = 1;
1054                 }
1055                 else
1056                 {
1057                         wcross_scale = 1;
1058                 }
1059
1060                 if(autocvar_crosshair_pickup)
1061                 {
1062                         float stat_pickup_time = STAT(LAST_PICKUP);
1063
1064                         if(pickup_crosshair_time < stat_pickup_time)
1065                         {
1066                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1067                                         pickup_crosshair_size = 1;
1068
1069                                 pickup_crosshair_time = stat_pickup_time;
1070                         }
1071
1072                         if(pickup_crosshair_size > 0)
1073                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1074                         else
1075                                 pickup_crosshair_size = 0;
1076
1077                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1078                 }
1079
1080                 // todo: make crosshair hit indication dependent on damage dealt
1081                 if(autocvar_crosshair_hitindication)
1082                 {
1083                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1084
1085                         if(unaccounted_damage)
1086                         {
1087                                 hitindication_crosshair_size = 1;
1088                         }
1089
1090                         if(hitindication_crosshair_size > 0)
1091                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1092                         else
1093                                 hitindication_crosshair_size = 0;
1094
1095                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1096                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1097                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1098                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1099                 }
1100
1101                 if(shottype == SHOTTYPE_HITENEMY)
1102                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1103                 if(shottype == SHOTTYPE_HITTEAM)
1104                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1105
1106                 f = fabs(autocvar_crosshair_effect_time);
1107                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1108                 {
1109                         wcross_changedonetime = time + f;
1110                 }
1111                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1112                 {
1113                         wcross_name_changestarttime = time;
1114                         wcross_name_changedonetime = time + f;
1115                         if(wcross_name_goal_prev_prev)
1116                                 strunzone(wcross_name_goal_prev_prev);
1117                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1118                         wcross_name_goal_prev = strzone(wcross_name);
1119                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1120                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1121                         wcross_resolution_goal_prev = wcross_resolution;
1122                 }
1123
1124                 wcross_scale_goal_prev = wcross_scale;
1125                 wcross_alpha_goal_prev = wcross_alpha;
1126                 wcross_color_goal_prev = wcross_color;
1127
1128                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1129                 {
1130                         wcross_blur = 1;
1131                         wcross_alpha *= 0.75;
1132                 }
1133                 else
1134                         wcross_blur = 0;
1135                 // *_prev is at time-frametime
1136                 // * is at wcross_changedonetime+f
1137                 // what do we have at time?
1138                 if(time < wcross_changedonetime)
1139                 {
1140                         f = frametime / (wcross_changedonetime - time + frametime);
1141                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1142                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1143                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1144                 }
1145
1146                 wcross_scale_prev = wcross_scale;
1147                 wcross_alpha_prev = wcross_alpha;
1148                 wcross_color_prev = wcross_color;
1149
1150                 MUTATOR_CALLHOOK(UpdateCrosshair);
1151
1152                 wcross_scale *= 1 - autocvar__menu_alpha;
1153                 wcross_alpha *= 1 - autocvar__menu_alpha;
1154                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1155
1156                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1157                 {
1158                         // crosshair rings for weapon stats
1159                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1160                         {
1161                                 // declarations and stats
1162                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1163                                 string ring_image = string_null, ring_inner_image = string_null;
1164                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1165
1166                                 ring_scale = autocvar_crosshair_ring_size;
1167
1168                                 float weapon_clipload, weapon_clipsize;
1169                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1170                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1171
1172                                 float vortex_charge, vortex_chargepool;
1173                                 vortex_charge = STAT(VORTEX_CHARGE);
1174                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1175
1176                                 float arc_heat = STAT(ARC_HEAT);
1177
1178                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1179                                         vortex_charge_movingavg = vortex_charge;
1180
1181                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1182
1183                                 // handle the values
1184                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1185                                 {
1186                                         if (vortex_chargepool || use_vortex_chargepool) {
1187                                                 use_vortex_chargepool = 1;
1188                                                 ring_inner_value = vortex_chargepool;
1189                                         } else {
1190                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1191                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1192                                         }
1193
1194                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1195                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1196                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1197
1198                                         // draw the outer ring to show the current charge of the weapon
1199                                         ring_value = vortex_charge;
1200                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1201                                         ring_rgb = wcross_color;
1202                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1203                                 }
1204                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1205                                 {
1206                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1207                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1208                                         ring_rgb = wcross_color;
1209                                         ring_image = "gfx/crosshair_ring.tga";
1210                                 }
1211                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1212                                 {
1213                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1214                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1215                                         ring_rgb = wcross_color;
1216                                         ring_image = "gfx/crosshair_ring.tga";
1217                                 }
1218                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1219                                 {
1220                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1221                                         ring_scale = autocvar_crosshair_ring_reload_size;
1222                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1223                                         ring_rgb = wcross_color;
1224
1225                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1226                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1227                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1228                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1229                                         else
1230                                                 ring_image = "gfx/crosshair_ring.tga";
1231                                 }
1232                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1233                                 {
1234                                         ring_value = arc_heat;
1235                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1236                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1237                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1238                                         ring_image = "gfx/crosshair_ring.tga";
1239                                 }
1240
1241                                 // if in weapon switch animation, fade ring out/in
1242                                 if(autocvar_crosshair_effect_time > 0)
1243                                 {
1244                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1245                                         if (f >= 1)
1246                                         {
1247                                                 wcross_ring_prev = ((ring_image) ? true : false);
1248                                         }
1249
1250                                         if(wcross_ring_prev)
1251                                         {
1252                                                 if(f < 1)
1253                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1254                                         }
1255                                         else
1256                                         {
1257                                                 if(f < 1)
1258                                                         ring_alpha *= bound(0, f, 1);
1259                                         }
1260                                 }
1261
1262                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1263                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1264
1265                                 if (ring_value)
1266                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1267                         }
1268
1269 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1270                         MACRO_BEGIN { \
1271                                 if(wcross_blur > 0) \
1272                                 { \
1273                                         for(i = -2; i <= 2; ++i) \
1274                                         for(j = -2; j <= 2; ++j) \
1275                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1276                                 } \
1277                                 else \
1278                                 { \
1279                                         M(0,0,sz,wcross_name,wcross_alpha); \
1280                                 } \
1281                         } MACRO_END
1282
1283 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1284                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1285
1286 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1287                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1288
1289                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1290                         {
1291                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1292                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1293                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1294                                 f = 1 - f;
1295                         }
1296                         else
1297                         {
1298                                 f = 1;
1299                         }
1300                         wcross_name_alpha_goal_prev = f;
1301
1302                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1303                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1304
1305                         if(autocvar_crosshair_dot)
1306                         {
1307                                 vector wcross_color_old;
1308                                 wcross_color_old = wcross_color;
1309
1310                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1311                                         wcross_color = stov(autocvar_crosshair_dot_color);
1312
1313                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1314                                 // FIXME why don't we use wcross_alpha here?
1315                                 wcross_color = wcross_color_old;
1316                         }
1317                 }
1318         }
1319         else
1320         {
1321                 wcross_scale_prev = 0;
1322                 wcross_alpha_prev = 0;
1323                 wcross_scale_goal_prev = 0;
1324                 wcross_alpha_goal_prev = 0;
1325                 wcross_changedonetime = 0;
1326                 if(wcross_name_goal_prev)
1327                         strunzone(wcross_name_goal_prev);
1328                 wcross_name_goal_prev = string_null;
1329                 if(wcross_name_goal_prev_prev)
1330                         strunzone(wcross_name_goal_prev_prev);
1331                 wcross_name_goal_prev_prev = string_null;
1332                 wcross_name_changestarttime = 0;
1333                 wcross_name_changedonetime = 0;
1334                 wcross_name_alpha_goal_prev = 0;
1335                 wcross_name_alpha_goal_prev_prev = 0;
1336                 wcross_resolution_goal_prev = 0;
1337                 wcross_resolution_goal_prev_prev = 0;
1338         }
1339 }
1340
1341 void HUD_Draw(entity this)
1342 {
1343         // if we don't know gametype and scores yet avoid drawing the scoreboard
1344         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1345         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1346         // cl_deathscoreboard would show the scoreboard and so on
1347         if(!gametype)
1348                 return;
1349
1350         if(!intermission)
1351         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1352         {
1353                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1354         }
1355         else if(STAT(FROZEN))
1356         {
1357                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1358         }
1359         if(!intermission)
1360         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1361         {
1362                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1363                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1364         }
1365         else if(STAT(CAPTURE_PROGRESS))
1366         {
1367                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1368                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1369         }
1370         else if(STAT(REVIVE_PROGRESS))
1371         {
1372                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1373                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1374         }
1375
1376         if(autocvar_r_letterbox == 0)
1377                 if(autocvar_viewsize < 120)
1378                 {
1379                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1380                                 Accuracy_LoadLevels();
1381
1382                         HUD_Main();
1383                         HUD_Scale_Disable();
1384                 }
1385
1386         // crosshair goes VERY LAST
1387         UpdateDamage();
1388         HUD_Crosshair(this);
1389         HitSound();
1390 }
1391
1392 bool ov_enabled;
1393 float oldr_nearclip;
1394 float oldr_farclip_base;
1395 float oldr_farclip_world;
1396 float oldr_novis;
1397 float oldr_useportalculling;
1398 float oldr_useinfinitefarclip;
1399
1400 void cl_notice_run();
1401
1402 float prev_myteam;
1403 int lasthud;
1404 float vh_notice_time;
1405 void WaypointSprite_Load();
1406 void CSQC_UpdateView(entity this, float w, float h)
1407 {
1408     TC(int, w); TC(int, h);
1409         entity e;
1410         float fov;
1411         float f;
1412         vector vf_size, vf_min;
1413         float a;
1414
1415         execute_next_frame();
1416
1417         ++framecount;
1418
1419         stats_get();
1420         hud = STAT(HUD);
1421
1422         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1423                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1424
1425         lasthud = hud;
1426
1427         HUD_Scale_Disable();
1428
1429         if(autocvar__hud_showbinds_reload) // menu can set this one
1430         {
1431                 db_close(binddb);
1432                 binddb = db_create();
1433                 cvar_set("_hud_showbinds_reload", "0");
1434         }
1435
1436         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1437                 view_quality = getproperty(VF_MINFPS_QUALITY);
1438         else
1439                 view_quality = 1;
1440
1441         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1442         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1443
1444         vf_size = getpropertyvec(VF_SIZE);
1445         vf_min = getpropertyvec(VF_MIN);
1446         vid_width = vf_size.x;
1447         vid_height = vf_size.y;
1448
1449         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1450         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1451
1452         WaypointSprite_Load();
1453
1454         CSQCPlayer_SetCamera();
1455
1456         if(player_localentnum <= maxclients) // is it a client?
1457                 current_player = player_localentnum - 1;
1458         else // then player_localentnum is the vehicle I'm driving
1459                 current_player = player_localnum;
1460         myteam = entcs_GetTeam(current_player);
1461
1462         if(myteam != prev_myteam)
1463         {
1464                 myteamcolors = colormapPaletteColor(myteam, 1);
1465                 FOREACH(hud_panels, true, it.update_time = time);
1466                 prev_myteam = myteam;
1467         }
1468
1469         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1470
1471         float is_dead = (STAT(HEALTH) <= 0);
1472
1473         // FIXME do we need this hack?
1474         if(isdemo())
1475         {
1476                 // in demos, input_buttons do not work
1477                 button_zoom = (autocvar__togglezoom == "-");
1478         }
1479         else if(button_zoom
1480                 && autocvar_cl_unpress_zoom_on_death
1481                 && (spectatee_status >= 0)
1482                 && (is_dead || intermission))
1483         {
1484                 // no zoom while dead or in intermission please
1485                 localcmd("-zoom\n");
1486                 button_zoom = false;
1487         }
1488
1489         // event chase camera
1490         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1491         {
1492                 if(STAT(CAMERA_SPECTATOR))
1493                 {
1494                         if(spectatee_status > 0)
1495                         {
1496                                 if(!autocvar_chase_active)
1497                                 {
1498                                         cvar_set("chase_active", "-2");
1499                                         goto skip_eventchase_death;
1500                                 }
1501                         }
1502                         else if(autocvar_chase_active == -2)
1503                                 cvar_set("chase_active", "0");
1504
1505                         if(autocvar_chase_active == -2)
1506                                 goto skip_eventchase_death;
1507                 }
1508                 else if(autocvar_chase_active == -2)
1509                         cvar_set("chase_active", "0");
1510
1511                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1512
1513                 float vehicle_viewdist = 0;
1514                 vector vehicle_viewofs = '0 0 0';
1515
1516                 if(vehicle_chase)
1517                 {
1518                         if(hud != HUD_BUMBLEBEE_GUN)
1519                         {
1520                                 Vehicle info = Vehicles_from(hud);
1521                                 vehicle_viewdist = info.height;
1522                                 vehicle_viewofs = info.view_ofs;
1523                         }
1524                 }
1525
1526                 if(WantEventchase(this))
1527                 {
1528                         vector current_view_origin_override = '0 0 0';
1529                         vector view_offset_override = '0 0 0';
1530                         float chase_distance_override = 0;
1531                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1532                         if(custom_eventchase)
1533                         {
1534                                 current_view_origin_override = M_ARGV(0, vector);
1535                                 view_offset_override = M_ARGV(1, vector);
1536                                 chase_distance_override = M_ARGV(0, float);
1537                         }
1538                         eventchase_running = true;
1539
1540                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1541                         if(!local_player)
1542                                 local_player = this; // fall back!
1543
1544                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1545                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1546                         if (custom_eventchase)
1547                                 current_view_origin = current_view_origin_override;
1548
1549                         // detect maximum viewoffset and use it
1550                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1551                         if(vehicle_chase)
1552                         {
1553                                 if(vehicle_viewofs)
1554                                         view_offset = vehicle_viewofs;
1555                                 else
1556                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1557                         }
1558                         if (custom_eventchase)
1559                                 view_offset = view_offset_override;
1560
1561                         if(view_offset)
1562                         {
1563                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1564                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1565                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1566                         }
1567
1568                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1569                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1570                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1571                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1572
1573                         // make the camera smooth back
1574                         float chase_distance = autocvar_cl_eventchase_distance;
1575                         if(vehicle_chase)
1576                         {
1577                                 if(vehicle_viewofs)
1578                                         chase_distance = vehicle_viewdist;
1579                                 else
1580                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1581                         }
1582                         if (custom_eventchase)
1583                                 chase_distance = chase_distance_override;
1584
1585                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1586                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1587                         else if(eventchase_current_distance != chase_distance)
1588                                 eventchase_current_distance = chase_distance;
1589
1590                         makevectors(view_angles);
1591
1592                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1593                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1594
1595                         // If the boxtrace fails, revert back to line tracing.
1596                         if(!local_player.viewloc)
1597                         if(trace_startsolid)
1598                         {
1599                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1600                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1601                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1602                         }
1603                         else { setproperty(VF_ORIGIN, trace_endpos); }
1604
1605                         if(!local_player.viewloc)
1606                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1607                 }
1608                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1609                 {
1610                         eventchase_running = false;
1611                         cvar_set("chase_active", "0");
1612                         eventchase_current_distance = 0; // start from 0 next time
1613                 }
1614         }
1615         // workaround for camera stuck between player's legs when using chase_active 1
1616         // because the engine stops updating the chase_active camera when the game ends
1617         else if(intermission)
1618         {
1619                 cvar_settemp("chase_active", "-1");
1620                 eventchase_current_distance = 0;
1621         }
1622
1623         LABEL(skip_eventchase_death);
1624
1625         // do lockview after event chase camera so that it still applies whenever necessary.
1626         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1627         {
1628                 setproperty(VF_ORIGIN, freeze_org);
1629                 setproperty(VF_ANGLES, freeze_ang);
1630         }
1631         else
1632         {
1633                 freeze_org = getpropertyvec(VF_ORIGIN);
1634                 freeze_ang = getpropertyvec(VF_ANGLES);
1635         }
1636
1637         WarpZone_FixView();
1638         //WarpZone_FixPMove();
1639
1640         vector ov_org = '0 0 0';
1641         vector ov_mid = '0 0 0';
1642         vector ov_worldmin = '0 0 0';
1643         vector ov_worldmax = '0 0 0';
1644         if(autocvar_cl_orthoview)
1645         {
1646                 ov_worldmin = mi_picmin;
1647                 ov_worldmax = mi_picmax;
1648
1649                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1650                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1651                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1652
1653                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1654                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1655
1656                 float ov_nearest = vlen(ov_org - vec3(
1657                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1658                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1659                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1660                 ));
1661
1662                 float ov_furthest = 0;
1663                 float dist = 0;
1664
1665                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1666                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1667                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1668                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1669                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1670                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1671                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1672                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1673
1674                 if(!ov_enabled)
1675                 {
1676                         oldr_nearclip = cvar("r_nearclip");
1677                         oldr_farclip_base = cvar("r_farclip_base");
1678                         oldr_farclip_world = cvar("r_farclip_world");
1679                         oldr_novis = cvar("r_novis");
1680                         oldr_useportalculling = cvar("r_useportalculling");
1681                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1682                 }
1683
1684                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1685                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1686                 cvar_settemp("r_farclip_world", "0");
1687                 cvar_settemp("r_novis", "1");
1688                 cvar_settemp("r_useportalculling", "0");
1689                 cvar_settemp("r_useinfinitefarclip", "0");
1690
1691                 setproperty(VF_ORIGIN, ov_org);
1692                 setproperty(VF_ANGLES, '90 0 0');
1693
1694                 ov_enabled = true;
1695
1696                 #if 0
1697                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1698                         vtos(ov_org),
1699                         vtos(getpropertyvec(VF_ANGLES)),
1700                         ov_distance,
1701                         ov_nearest,
1702                         ov_furthest);
1703                 #endif
1704         }
1705         else
1706         {
1707                 if(ov_enabled)
1708                 {
1709                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1710                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1711                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1712                         cvar_set("r_novis", ftos(oldr_novis));
1713                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1714                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1715                 }
1716                 ov_enabled = false;
1717         }
1718
1719         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1720         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1721         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1722                 viewmodel_draw(viewmodels[slot]);
1723
1724         // Render the Scene
1725         view_origin = getpropertyvec(VF_ORIGIN);
1726         view_angles = getpropertyvec(VF_ANGLES);
1727         makevectors(view_angles);
1728         view_forward = v_forward;
1729         view_right = v_right;
1730         view_up = v_up;
1731
1732 #ifdef BLURTEST
1733         if(time > blurtest_time0 && time < blurtest_time1)
1734         {
1735                 float r, t;
1736
1737                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1738                 r = t * blurtest_radius;
1739                 f = 1 / pow(t, blurtest_power) - 1;
1740
1741                 cvar_set("r_glsl_postprocess", "1");
1742                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1743         }
1744         else
1745         {
1746                 cvar_set("r_glsl_postprocess", "0");
1747                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1748         }
1749 #endif
1750
1751         TargetMusic_Advance();
1752         Fog_Force();
1753
1754         if(drawtime == 0)
1755                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1756         else
1757                 drawframetime = bound(0.000001, time - drawtime, 1);
1758         drawtime = time;
1759
1760         // watch for gametype changes here...
1761         // in ParseStuffCMD the cmd isn't executed yet :/
1762         // might even be better to add the gametype to TE_CSQC_INIT...?
1763         if(!postinit)
1764                 PostInit();
1765
1766         if(intermission && !gameover_time)
1767                 gameover_time = time;
1768
1769         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1770         {
1771                 if(calledhooks & HOOK_START)
1772                 {
1773                         localcmd("\ncl_hook_gameend\n");
1774                         calledhooks |= HOOK_END;
1775                 }
1776         }
1777
1778         Announcer();
1779
1780         fov = autocvar_fov;
1781         if(fov <= 59.5)
1782         {
1783                 if(!zoomscript_caught)
1784                 {
1785                         localcmd("+button9\n");
1786                         zoomscript_caught = 1;
1787                 }
1788         }
1789         else
1790         {
1791                 if(zoomscript_caught)
1792                 {
1793                         localcmd("-button9\n");
1794                         zoomscript_caught = 0;
1795                 }
1796         }
1797
1798         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1799
1800         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1801         {
1802                 entity wepent = viewmodels[slot];
1803
1804                 if(wepent.last_switchweapon != wepent.switchweapon)
1805                 {
1806                         weapontime = time;
1807                         wepent.last_switchweapon = wepent.switchweapon;
1808                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1809                         {
1810                                 localcmd("-zoom\n");
1811                                 button_zoom = false;
1812                         }
1813                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1814                         {
1815                                 localcmd("-fire\n");
1816                                 localcmd("-fire2\n");
1817                                 button_attack2 = false;
1818                         }
1819                 }
1820                 if(wepent.last_activeweapon != wepent.activeweapon)
1821                 {
1822                         wepent.last_activeweapon = wepent.activeweapon;
1823
1824                         e = wepent.activeweapon;
1825                         if(e.netname != "")
1826                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1827                         else if(slot == 0)
1828                                 localcmd("\ncl_hook_activeweapon none\n");
1829                 }
1830         }
1831
1832         // ALWAYS Clear Current Scene First
1833         clearscene();
1834
1835         setproperty(VF_ORIGIN, view_origin);
1836         setproperty(VF_ANGLES, view_angles);
1837
1838         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1839         setproperty(VF_SIZE, vf_size);
1840         setproperty(VF_MIN, vf_min);
1841
1842         // Assign Standard Viewflags
1843         // Draw the World (and sky)
1844         setproperty(VF_DRAWWORLD, 1);
1845
1846         // Set the console size vars
1847         vid_conwidth = autocvar_vid_conwidth;
1848         vid_conheight = autocvar_vid_conheight;
1849         vid_pixelheight = autocvar_vid_pixelheight;
1850
1851         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1852         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1853         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1854
1855         if(camera_active) // Camera for demo playback
1856         {
1857                 if(autocvar_camera_enable)
1858                         CSQC_Demo_Camera();
1859                 else
1860                 {
1861                         cvar_set("chase_active", ftos(chase_active_backup));
1862                         cvar_set("cl_demo_mousegrab", "0");
1863                         camera_active = false;
1864                 }
1865         }
1866         else
1867         {
1868 #ifdef CAMERATEST
1869                 if(autocvar_camera_enable)
1870 #else
1871                 if(autocvar_camera_enable && isdemo())
1872 #endif
1873                 {
1874                         // Enable required Darkplaces cvars
1875                         chase_active_backup = autocvar_chase_active;
1876                         cvar_set("chase_active", "2");
1877                         cvar_set("cl_demo_mousegrab", "1");
1878                         camera_active = true;
1879                         camera_mode = false;
1880                 }
1881         }
1882
1883         // Draw the Crosshair
1884         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1885
1886         // Draw the Engine Status Bar (the default Quake HUD)
1887         setproperty(VF_DRAWENGINESBAR, 0);
1888
1889         // Update the mouse position
1890         /*
1891            mousepos_x = vid_conwidth;
1892            mousepos_y = vid_conheight;
1893            mousepos = mousepos*0.5 + getmousepos();
1894          */
1895
1896         IL_EACH(g_drawables, it.draw, it.draw(it));
1897
1898         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1899         renderscene();
1900
1901         // now switch to 2D drawing mode by calling a 2D drawing function
1902         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1903         // next R_RenderScene call
1904         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1905
1906         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1907         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1908         {
1909                 // apply night vision effect
1910                 vector tc_00, tc_01, tc_10, tc_11;
1911                 vector rgb = '0 0 0';
1912
1913                 if(!nightvision_noise)
1914                 {
1915                         nightvision_noise = new(nightvision_noise);
1916                 }
1917                 if(!nightvision_noise2)
1918                 {
1919                         nightvision_noise2 = new(nightvision_noise2);
1920                 }
1921
1922                 // color tint in yellow
1923                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1924
1925                 // draw BG
1926                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1927                 rgb = '1 1 1';
1928                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1929                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1930                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1931                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1932                 tc_11 = tc_01 + tc_10 - tc_00;
1933                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1934                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1935                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1936                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1937                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1938                 R_EndPolygon();
1939
1940                 // draw FG
1941                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1942                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1943                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1944                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1945                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1946                 tc_11 = tc_01 + tc_10 - tc_00;
1947                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1948                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1949                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1950                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1951                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1952                 R_EndPolygon();
1953         }
1954
1955         if(autocvar_cl_reticle)
1956         {
1957                 string reticle_image = "";
1958                 bool wep_zoomed = false;
1959                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1960                 {
1961                         entity wepe = viewmodels[slot];
1962                         Weapon wep = wepe.activeweapon;
1963                         if(wep != WEP_Null && wep.wr_zoom)
1964                         {
1965                                 bool do_zoom = wep.wr_zoom(wep, NULL);
1966                                 if(wep.w_reticle && wep.w_reticle != "")
1967                                         reticle_image = wep.w_reticle;
1968                                 wep_zoomed += do_zoom;
1969                         }
1970                 }
1971                 // Draw the aiming reticle for weapons that use it
1972                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1973                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1974                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1975                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1976                 {
1977                         // no zoom reticle while dead
1978                         reticle_type = 0;
1979                 }
1980                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
1981                 {
1982                         if(reticle_image && reticle_image != "") { reticle_type = 2; }
1983                         else { reticle_type = 0; }
1984                 }
1985                 else if(button_zoom || zoomscript_caught)
1986                 {
1987                         // normal zoom
1988                         reticle_type = 1;
1989                 }
1990
1991                 if(reticle_type)
1992                 {
1993                         if(autocvar_cl_reticle_stretch)
1994                         {
1995                                 reticle_size.x = vid_conwidth;
1996                                 reticle_size.y = vid_conheight;
1997                                 reticle_pos.x = 0;
1998                                 reticle_pos.y = 0;
1999                         }
2000                         else
2001                         {
2002                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2003                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2004                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2005                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2006                         }
2007
2008                         if(zoomscript_caught)
2009                                 f = 1;
2010                         else
2011                                 f = current_zoomfraction;
2012
2013                         if(f)
2014                         {
2015                                 switch(reticle_type)
2016                                 {
2017                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2018                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2019                                 }
2020                         }
2021                 }
2022         }
2023         else
2024         {
2025                 if(reticle_type != 0) { reticle_type = 0; }
2026         }
2027
2028
2029         // improved polyblend
2030         if(autocvar_hud_contents)
2031         {
2032                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2033                 vector liquidcolor;
2034
2035                 switch(pointcontents(view_origin))
2036                 {
2037                         case CONTENT_WATER:
2038                                 liquidalpha = autocvar_hud_contents_water_alpha;
2039                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2040                                 incontent = 1;
2041                                 break;
2042
2043                         case CONTENT_LAVA:
2044                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2045                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2046                                 incontent = 1;
2047                                 break;
2048
2049                         case CONTENT_SLIME:
2050                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2051                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2052                                 incontent = 1;
2053                                 break;
2054
2055                         default:
2056                                 liquidalpha = 0;
2057                                 liquidcolor = '0 0 0';
2058                                 incontent = 0;
2059                                 break;
2060                 }
2061
2062                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2063                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2064                         contentfadetime = autocvar_hud_contents_fadeintime;
2065                         liquidalpha_prev = liquidalpha;
2066                         liquidcolor_prev = liquidcolor;
2067                 }
2068                 else
2069                         contentfadetime = autocvar_hud_contents_fadeouttime;
2070
2071                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2072                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2073
2074                 if(contentavgalpha)
2075                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2076
2077                 if(autocvar_hud_postprocessing)
2078                 {
2079                         if(autocvar_hud_contents_blur && contentavgalpha)
2080                         {
2081                                 content_blurpostprocess.x = 1;
2082                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2083                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2084                         }
2085                         else
2086                         {
2087                                 content_blurpostprocess.x = 0;
2088                                 content_blurpostprocess.y = 0;
2089                                 content_blurpostprocess.z = 0;
2090                         }
2091                 }
2092         }
2093
2094         if(autocvar_hud_damage && !STAT(FROZEN))
2095         {
2096                 splash_size.x = max(vid_conwidth, vid_conheight);
2097                 splash_size.y = max(vid_conwidth, vid_conheight);
2098                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2099                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2100
2101                 float myhealth_flash_temp;
2102                 myhealth = STAT(HEALTH);
2103
2104                 // fade out
2105                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2106                 // add new damage
2107                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2108
2109                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2110                 pain_threshold = autocvar_hud_damage_pain_threshold;
2111                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2112                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2113
2114                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2115                 {
2116                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2117                 }
2118
2119                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2120
2121                 if(myhealth_prev < 1)
2122                 {
2123                         if(myhealth >= 1)
2124                         {
2125                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2126                                 myhealth_flash_temp = 0;
2127                         }
2128                         else
2129                         {
2130                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2131                         }
2132                 }
2133
2134                 if(spectatee_status == -1 || intermission)
2135                 {
2136                         myhealth_flash = 0; // observing, or match ended
2137                         myhealth_flash_temp = 0;
2138                 }
2139
2140                 myhealth_prev = myhealth;
2141
2142                 // IDEA: change damage color/picture based on player model for robot/alien species?
2143                 // pro: matches model better
2144                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2145                 // maybe different reddish pics?
2146                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2147                 {
2148                         if(autocvar_cl_gentle_damage == 2)
2149                         {
2150                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2151                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2152                         }
2153                         else
2154                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2155
2156                         if(myhealth_flash_temp > 0)
2157                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2158                 }
2159                 else if(myhealth_flash_temp > 0)
2160                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2161
2162                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2163                 {
2164                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2165                         {
2166                                 damage_blurpostprocess.x = 1;
2167                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2168                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2169                         }
2170                         else
2171                         {
2172                                 damage_blurpostprocess.x = 0;
2173                                 damage_blurpostprocess.y = 0;
2174                                 damage_blurpostprocess.z = 0;
2175                         }
2176                 }
2177         }
2178
2179         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2180         float e2 = (autocvar_hud_powerup != 0);
2181         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2182         {
2183                 // enable or disable rendering types if they are used or not
2184                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2185                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2186
2187                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2188                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2189                 {
2190                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2191                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2192                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2193                         {
2194                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2195                                 old_blurradius = blurradius;
2196                                 old_bluralpha = bluralpha;
2197                         }
2198                 }
2199                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2200                 {
2201                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2202                         old_blurradius = 0;
2203                         old_bluralpha = 0;
2204                 }
2205
2206                 // edge detection postprocess handling done second (used by hud_powerup)
2207                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2208                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2209                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2210
2211                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2212
2213                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2214                 {
2215                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2216                         {
2217                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2218                                 old_sharpen_intensity = sharpen_intensity;
2219                         }
2220                 }
2221                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2222                 {
2223                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2224                         old_sharpen_intensity = 0;
2225                 }
2226
2227                 if(cvar("r_glsl_postprocess") == 0)
2228                         cvar_set("r_glsl_postprocess", "2");
2229         }
2230         else if(cvar("r_glsl_postprocess") == 2)
2231                 cvar_set("r_glsl_postprocess", "0");
2232
2233         /*if(gametype == MAPINFO_TYPE_CTF)
2234           {
2235           ctf_view();
2236           } else */
2237
2238         // draw 2D entities
2239         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2240         Draw_ShowNames_All();
2241         Debug_Draw();
2242
2243         scoreboard_active = Scoreboard_WouldDraw();
2244
2245         HUD_Draw(this); // this parameter for deep vehicle function
2246
2247         if(NextFrameCommand)
2248         {
2249                 localcmd("\n", NextFrameCommand, "\n");
2250                 NextFrameCommand = string_null;
2251         }
2252
2253         // we must do this check AFTER a frame was rendered, or it won't work
2254         if(cs_project_is_b0rked == 0)
2255         {
2256                 string w0, h0;
2257                 w0 = ftos(autocvar_vid_conwidth);
2258                 h0 = ftos(autocvar_vid_conheight);
2259                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2260                 //setproperty(VF_FOV, '90 90 0');
2261                 setproperty(VF_ORIGIN, '0 0 0');
2262                 setproperty(VF_ANGLES, '0 0 0');
2263                 setproperty(VF_PERSPECTIVE, 1);
2264                 makevectors('0 0 0');
2265                 vector v1, v2;
2266                 cvar_set("vid_conwidth", "800");
2267                 cvar_set("vid_conheight", "600");
2268                 v1 = cs_project(v_forward);
2269                 cvar_set("vid_conwidth", "640");
2270                 cvar_set("vid_conheight", "480");
2271                 v2 = cs_project(v_forward);
2272                 if(v1 == v2)
2273                         cs_project_is_b0rked = 1;
2274                 else
2275                         cs_project_is_b0rked = -1;
2276                 cvar_set("vid_conwidth", w0);
2277                 cvar_set("vid_conheight", h0);
2278         }
2279
2280         if(autocvar__hud_configure)
2281                 HUD_Panel_Mouse();
2282         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2283                 HUD_Minigame_Mouse();
2284         else if(QuickMenu_IsOpened())
2285                 QuickMenu_Mouse();
2286         else
2287                 HUD_Radar_Mouse();
2288
2289         cl_notice_run();
2290         unpause_update();
2291         Net_Flush();
2292
2293         // let's reset the view back to normal for the end
2294         setproperty(VF_MIN, '0 0 0');
2295         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2296
2297         IL_ENDFRAME();
2298 }
2299
2300
2301 // following vectors must be global to allow seamless switching between camera modes
2302 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2303 void CSQC_Demo_Camera()
2304 {
2305         float speed, attenuation, dimensions;
2306         vector tmp, delta;
2307
2308         if( autocvar_camera_reset || !camera_mode )
2309         {
2310                 camera_offset = '0 0 0';
2311                 current_angles = '0 0 0';
2312                 camera_direction = '0 0 0';
2313                 camera_offset.z += 30;
2314                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2315                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2316                 current_origin = view_origin;
2317                 current_camera_offset  = camera_offset;
2318                 cvar_set("camera_reset", "0");
2319                 camera_mode = CAMERA_CHASE;
2320         }
2321
2322         // Camera angles
2323         if( camera_roll )
2324                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2325
2326         if(autocvar_camera_look_player)
2327         {
2328                 vector dir;
2329                 float n;
2330
2331                 dir = normalize(view_origin - current_position);
2332                 n = mouse_angles.z;
2333                 mouse_angles = vectoangles(dir);
2334                 mouse_angles.x = mouse_angles.x * -1;
2335                 mouse_angles.z = n;
2336         }
2337         else
2338         {
2339                 tmp = getmousepos() * 0.1;
2340                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2341                 {
2342                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2343                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2344                 }
2345         }
2346
2347         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2348         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2349         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2350         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2351
2352         // Fix difference when angles don't have the same sign
2353         delta = '0 0 0';
2354         if(mouse_angles.y < -60 && current_angles.y > 60)
2355                 delta = '0 360 0';
2356         if(mouse_angles.y > 60 && current_angles.y < -60)
2357                 delta = '0 -360 0';
2358
2359         if(autocvar_camera_look_player)
2360                 attenuation = autocvar_camera_look_attenuation;
2361         else
2362                 attenuation = autocvar_camera_speed_attenuation;
2363
2364         attenuation = 1 / max(1, attenuation);
2365         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2366
2367         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2368         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2369         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2370         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2371
2372         // Camera position
2373         tmp = '0 0 0';
2374         dimensions = 0;
2375
2376         if( camera_direction.x )
2377         {
2378                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2379                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2380                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2381                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2382                 ++dimensions;
2383         }
2384
2385         if( camera_direction.y )
2386         {
2387                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2388                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2389                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2390                 ++dimensions;
2391         }
2392
2393         if( camera_direction.z )
2394         {
2395                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2396                 ++dimensions;
2397         }
2398
2399         if(autocvar_camera_free)
2400                 speed = autocvar_camera_speed_free;
2401         else
2402                 speed = autocvar_camera_speed_chase;
2403
2404         if(dimensions)
2405         {
2406                 speed = speed * sqrt(1 / dimensions);
2407                 camera_offset += tmp * speed;
2408         }
2409
2410         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2411
2412         // Camera modes
2413         if( autocvar_camera_free )
2414         {
2415                 if ( camera_mode == CAMERA_CHASE )
2416                 {
2417                         current_camera_offset = current_origin + current_camera_offset;
2418                         camera_offset = current_origin + camera_offset;
2419                 }
2420
2421                 camera_mode = CAMERA_FREE;
2422                 current_position = current_camera_offset;
2423         }
2424         else
2425         {
2426                 if ( camera_mode == CAMERA_FREE )
2427                 {
2428                         current_origin = view_origin;
2429                         camera_offset = camera_offset - current_origin;
2430                         current_camera_offset = current_camera_offset - current_origin;
2431                 }
2432
2433                 camera_mode = CAMERA_CHASE;
2434
2435                 if(autocvar_camera_chase_smoothly)
2436                         current_origin += (view_origin - current_origin) * attenuation;
2437                 else
2438                         current_origin = view_origin;
2439
2440                 current_position = current_origin + current_camera_offset;
2441         }
2442
2443         setproperty(VF_ANGLES, current_angles);
2444         setproperty(VF_ORIGIN, current_position);
2445 }