qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/net_linked.qh>
  17 #include <common/debug.qh>
  18 #include <common/mapinfo.qh>
  19 #include <common/gamemodes/_mod.qh>
  20 #include <common/physics/player.qh>
  21 #include <common/stats.qh>
  22 #include <common/triggers/target/music.qh>
  23 #include <common/teams.qh>
  24
  25 #include <common/weapons/weapon/tuba.qh>
  26
  27 #include <common/vehicles/all.qh>
  28 #include <common/weapons/_all.qh>
  29 #include <common/viewloc.qh>
  30 #include <common/minigames/cl_minigames.qh>
  31 #include <common/minigames/cl_minigames_hud.qh>
  32
  33 #include <lib/csqcmodel/cl_player.qh>
  34 #include <lib/csqcmodel/cl_model.qh>
  35 #include "csqcmodel_hooks.qh"
  36
  37 #include <lib/warpzone/client.qh>
  38 #include <lib/warpzone/common.qh>
  39
  40 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  41
  42 float autocvar_cl_viewmodel_scale;
  43
  44 bool autocvar_cl_bobmodel;
  45 float autocvar_cl_bobmodel_speed;
  46 float autocvar_cl_bobmodel_side;
  47 float autocvar_cl_bobmodel_up;
  48
  49 float autocvar_cl_followmodel;
  50 float autocvar_cl_followmodel_speed = 0.3;
  51 float autocvar_cl_followmodel_limit = 135;
  52 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  53 float autocvar_cl_followmodel_highpass = 0.05;
  54 float autocvar_cl_followmodel_lowpass = 0.03;
  55 bool autocvar_cl_followmodel_velocity_absolute;
  56
  57 float autocvar_cl_leanmodel;
  58 float autocvar_cl_leanmodel_speed = 0.3;
  59 float autocvar_cl_leanmodel_limit = 30;
  60 float autocvar_cl_leanmodel_highpass1 = 0.2;
  61 float autocvar_cl_leanmodel_highpass = 0.2;
  62 float autocvar_cl_leanmodel_lowpass = 0.05;
  63
  64 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  65
  66 #define lowpass(value, frac, ref_store, ret) \
  67         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  68
  69 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  70 { \
  71         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  72         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  73 } MACRO_END
  74
  75 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  76 { \
  77         float __f = 0; lowpass(value, frac, ref_store, __f); \
  78         ret = (value) - __f; \
  79 } MACRO_END
  80
  81 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  82 { \
  83         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  84         ret = (value) - __f; \
  85 } MACRO_END
  86
  87 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  88 { \
  89         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  90         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  91 } MACRO_END
  92
  93 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94 { \
  95         highpass(value.x, frac, ref_store.x, ref_out.x); \
  96         highpass(value.y, frac, ref_store.y, ref_out.y); \
  97 } MACRO_END
  98
  99 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 100 { \
 101         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 102         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 103 } MACRO_END
 104
 105 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 106 { \
 107         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 108         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 109         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 110 } MACRO_END
 111
 112 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 113 { \
 114         highpass(value.x, frac, ref_store.x, ref_out.x); \
 115         highpass(value.y, frac, ref_store.y, ref_out.y); \
 116         highpass(value.z, frac, ref_store.z, ref_out.z); \
 117 } MACRO_END
 118
 119 void calc_followmodel_ofs(entity view)
 120 {
 121         if(cl_followmodel_time == time)
 122                 return; // cl_followmodel_ofs already calculated for this frame
 123
 124         float frac;
 125         vector gunorg = '0 0 0';
 126         static vector vel_average;
 127         static vector gunorg_adjustment_highpass;
 128         static vector gunorg_adjustment_lowpass;
 129
 130         vector vel;
 131         if (autocvar_cl_followmodel_velocity_absolute)
 132                 vel = view.velocity;
 133         else
 134         {
 135                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 136                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 137                 vel.x = view.velocity * forward;
 138                 vel.y = view.velocity * right * -1;
 139                 vel.z = view.velocity * up;
 140         }
 141
 142         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 143         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 144         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 145
 146         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 147         lowpass3(vel, frac, vel_average, gunorg);
 148
 149         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 150
 151         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 152         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 153         frac = avg_factor(autocvar_cl_followmodel_highpass);
 154         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 155         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 156         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 157
 158         if (autocvar_cl_followmodel_velocity_absolute)
 159         {
 160                 vector fixed_gunorg;
 161                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 162                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 163                 fixed_gunorg.x = gunorg * forward;
 164                 fixed_gunorg.y = gunorg * right * -1;
 165                 fixed_gunorg.z = gunorg * up;
 166                 gunorg = fixed_gunorg;
 167         }
 168
 169         cl_followmodel_ofs = gunorg;
 170         cl_followmodel_time = time;
 171 }
 172
 173 vector leanmodel_ofs(entity view)
 174 {
 175         float frac;
 176         vector gunangles = '0 0 0';
 177         static vector gunangles_prev = '0 0 0';
 178         static vector gunangles_highpass = '0 0 0';
 179         static vector gunangles_adjustment_highpass;
 180         static vector gunangles_adjustment_lowpass;
 181
 182         if (view.csqcmodel_teleported)
 183                 gunangles_prev = view_angles;
 184
 185         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 186         gunangles_highpass += gunangles_prev;
 187         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 188         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 189         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 190         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 191         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 192         gunangles_prev = view_angles;
 193         gunangles_highpass -= gunangles_prev;
 194
 195         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 196         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 197
 198         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 199         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 200         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 201         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 202         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 203
 204         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 205
 206         return gunangles;
 207 }
 208
 209 vector bobmodel_ofs(entity view)
 210 {
 211         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 212         static bool oldonground;
 213         static float hitgroundtime;
 214         if (clonground)
 215         {
 216                 float f = time; // cl.movecmd[0].time
 217                 if (!oldonground)
 218                         hitgroundtime = f;
 219         }
 220         oldonground = clonground;
 221
 222         // calculate for swinging gun model
 223         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 224         vector gunorg = '0 0 0';
 225         static float bobmodel_scale = 0;
 226         static float time_ofs = 0; // makes the effect always restart in the same way
 227         if (clonground)
 228         {
 229                 if (time - hitgroundtime > 0.05)
 230                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 231         }
 232         else
 233                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 234
 235         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 236         if (bobmodel_scale && xyspeed)
 237         {
 238                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 239                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 240                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 241                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 242         }
 243         else
 244                 time_ofs = time;
 245
 246         return gunorg;
 247 }
 248
 249 void viewmodel_animate(entity this)
 250 {
 251         if (autocvar_chase_active) return;
 252         if (STAT(HEALTH) <= 0) return;
 253
 254         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 255
 256         if (autocvar_cl_followmodel)
 257         {
 258                 calc_followmodel_ofs(view);
 259                 this.origin += cl_followmodel_ofs;
 260         }
 261
 262         if (autocvar_cl_leanmodel)
 263                 this.angles += leanmodel_ofs(view);
 264
 265         // vertical view bobbing code
 266         // TODO: cl_bob
 267
 268         // horizontal view bobbing code
 269         // TODO: cl_bob2
 270
 271         // fall bobbing code
 272         // causes the view to swing down and back up when touching the ground
 273         // TODO: cl_bobfall
 274
 275         // gun model bobbing code
 276         if (autocvar_cl_bobmodel)
 277                 this.origin += bobmodel_ofs(view);
 278 }
 279
 280 .vector viewmodel_origin, viewmodel_angles;
 281 .float weapon_nextthink;
 282 .float weapon_eta_last;
 283 .float weapon_switchdelay;
 284
 285 .string name_last;
 286
 287 void viewmodel_draw(entity this)
 288 {
 289         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 290                 return;
 291         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 292         float a = this.alpha;
 293         static bool wasinvehicle;
 294         bool invehicle = player_localentnum > maxclients;
 295         if (invehicle) a = -1;
 296         else if (wasinvehicle) a = 1;
 297         wasinvehicle = invehicle;
 298         Weapon wep = this.activeweapon;
 299         int c = entcs_GetClientColors(current_player);
 300         vector g = weaponentity_glowmod(wep, NULL, c, this);
 301         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 302         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 303                 | EF_NODEPTHTEST)
 304                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 305         for (entity e = this; e; e = e.weaponchild)
 306         {
 307                 e.drawmask = mask;
 308                 e.alpha = a;
 309                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 310                 e.glowmod = g;
 311                 e.csqcmodel_effects = fx;
 312                 CSQCModel_Effects_Apply(e);
 313         }
 314         {
 315                 string name = wep.mdl;
 316                 string newname = wep.wr_viewmodel(wep, this);
 317                 if(newname)
 318                         name = newname;
 319                 bool swap = name != this.name_last;
 320                 // if (swap)
 321                 {
 322                         this.name_last = name;
 323                         CL_WeaponEntity_SetModel(this, name, swap);
 324                         this.viewmodel_origin = this.origin;
 325                         this.viewmodel_angles = this.angles;
 326                 }
 327                 anim_update(this);
 328                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 329                         anim_set(this, this.anim_idle, true, false, false);
 330         }
 331         float f = 0; // 0..1; 0: fully active
 332         float rate = STAT(WEAPONRATEFACTOR);
 333         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 334         if (eta <= 0) f = this.weapon_eta_last;
 335         else switch (this.state)
 336         {
 337                 case WS_RAISE:
 338                 {
 339                         f = eta / max(eta, this.weapon_switchdelay);
 340                         break;
 341                 }
 342                 case WS_DROP:
 343                 {
 344                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 345                         break;
 346                 }
 347                 case WS_CLEAR:
 348                 {
 349                         f = 1;
 350                         break;
 351                 }
 352         }
 353         this.weapon_eta_last = f;
 354         this.origin = this.viewmodel_origin;
 355         this.angles = this.viewmodel_angles;
 356         this.angles_x = (-90 * f * f);
 357         viewmodel_animate(this);
 358         MUTATOR_CALLHOOK(DrawViewModel, this);
 359         setorigin(this, this.origin);
 360 }
 361
 362 STATIC_INIT(viewmodel) {
 363     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 364         viewmodels[slot] = new(viewmodel);
 365 }
 366
 367 void Porto_Draw(entity this);
 368 STATIC_INIT(Porto)
 369 {
 370         entity e = new_pure(porto);
 371         e.draw = Porto_Draw;
 372         IL_PUSH(g_drawables, e);
 373         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 374 }
 375
 376 const int polyline_length = 16;
 377 .vector polyline[polyline_length];
 378 void Porto_Draw(entity this)
 379 {
 380         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 381         {
 382                 entity wepent = viewmodels[slot];
 383
 384                 if (wepent.activeweapon != WEP_PORTO) continue;
 385                 if (spectatee_status) continue;
 386                 if (WEP_CVAR(porto, secondary)) continue;
 387                 if (intermission == 1) continue;
 388                 if (intermission == 2) continue;
 389                 if (STAT(HEALTH) <= 0) continue;
 390
 391                 vector pos = view_origin;
 392                 vector dir = view_forward;
 393                 if (wepent.angles_held_status)
 394                 {
 395                         makevectors(wepent.angles_held);
 396                         dir = v_forward;
 397                 }
 398
 399                 wepent.polyline[0] = pos;
 400
 401                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 402                 int n = 1 + 2;  // 2 lines == 3 points
 403                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 404                 {
 405                         traceline(pos, pos + 65536 * dir, true, this);
 406                         dir = reflect(dir, trace_plane_normal);
 407                         pos = trace_endpos;
 408                         wepent.polyline[++idx] = pos;
 409                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 410                         {
 411                                 n += 1;
 412                                 continue;
 413                         }
 414                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 415                         {
 416                                 n = max(2, idx);
 417                                 break;
 418                         }
 419                         // check size
 420                         {
 421                                 vector ang = vectoangles2(trace_plane_normal, dir);
 422                                 ang.x = -ang.x;
 423                                 makevectors(ang);
 424                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 425                                 {
 426                                         n = max(2, idx);
 427                                         break;
 428                                 }
 429                         }
 430                         portal_number += 1;
 431                         if (portal_number >= portal_max) break;
 432                         if (portal_number == 1) portal1_idx = idx;
 433                 }
 434                 for (int idx = 0; idx < n - 1; ++idx)
 435                 {
 436                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 437                         if (idx == 0) p -= view_up * 16;  // line from player
 438                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 439                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 440                 }
 441         }
 442 }
 443
 444 float drawtime;
 445 float avgspeed;
 446 vector GetCurrentFov(float fov)
 447 {
 448         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 449         float velocityzoom, curspeed;
 450         vector v;
 451
 452         zoomsensitivity = autocvar_cl_zoomsensitivity;
 453         zoomfactor = autocvar_cl_zoomfactor;
 454         if(zoomfactor < 1 || zoomfactor > 30)
 455                 zoomfactor = 2.5;
 456         zoomspeed = autocvar_cl_zoomspeed;
 457         if(zoomspeed >= 0)
 458         if(zoomspeed < 0.5 || zoomspeed > 16)
 459                         zoomspeed = 3.5;
 460
 461         zoomdir = button_zoom;
 462
 463         if(hud == HUD_NORMAL && !spectatee_status)
 464         {
 465                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 466                 {
 467                         entity wepent = viewmodels[slot];
 468                         if(wepent.switchweapon == wepent.activeweapon)
 469                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 470                                 zoomdir += button_attack2;
 471                 }
 472         }
 473         if(spectatee_status > 0 || isdemo())
 474         {
 475                 if(spectatorbutton_zoom)
 476                 {
 477                         if(zoomdir)
 478                                 zoomdir = 0;
 479                         else
 480                                 zoomdir = 1;
 481                 }
 482                 // fteqcc failed twice here already, don't optimize this
 483         }
 484
 485         if(zoomdir) { zoomin_effect = 0; }
 486
 487         if(camera_active)
 488         {
 489                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 490         }
 491         else if(autocvar_cl_spawnzoom && zoomin_effect)
 492         {
 493                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 494
 495                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 496                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 497                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 498         }
 499         else
 500         {
 501                 if(zoomspeed < 0) // instant zoom
 502                 {
 503                         if(zoomdir)
 504                                 current_viewzoom = 1 / zoomfactor;
 505                         else
 506                                 current_viewzoom = 1;
 507                 }
 508                 else
 509                 {
 510                         if(zoomdir)
 511                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 512                         else
 513                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 514                 }
 515         }
 516
 517         if(almost_equals(current_viewzoom, 1))
 518                 current_zoomfraction = 0;
 519         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 520                 current_zoomfraction = 1;
 521         else
 522                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 523
 524         if(zoomsensitivity < 1)
 525                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 526         else
 527                 setsensitivityscale(1);
 528
 529         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 530         {
 531                 if(intermission) { curspeed = 0; }
 532                 else
 533                 {
 534
 535                         makevectors(view_angles);
 536                         v = pmove_vel;
 537                         if(csqcplayer)
 538                                 v = csqcplayer.velocity;
 539
 540                         switch(autocvar_cl_velocityzoom_type)
 541                         {
 542                                 case 3: curspeed = max(0, v_forward * v); break;
 543                                 case 2: curspeed = (v_forward * v); break;
 544                                 case 1: default: curspeed = vlen(v); break;
 545                         }
 546                 }
 547
 548                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 549                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 550                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 551
 552                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 553         }
 554         else
 555                 velocityzoom = 1;
 556
 557         float frustumx, frustumy, fovx, fovy;
 558         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 559         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 560         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 561         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 562
 563         return '1 0 0' * fovx + '0 1 0' * fovy;
 564 }
 565
 566 vector GetViewLocationFOV(float fov)
 567 {
 568         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 569         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 570         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 571         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 572         return '1 0 0' * fovx + '0 1 0' * fovy;
 573 }
 574
 575 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 576 {
 577         float fovx, fovy;
 578         float width = (ov_worldmax.x - ov_worldmin.x);
 579         float height = (ov_worldmax.y - ov_worldmin.y);
 580         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 581         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 582         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 583         return '1 0 0' * fovx + '0 1 0' * fovy;
 584 }
 585
 586 // this function must match W_SetupShot!
 587 float zoomscript_caught;
 588
 589 vector wcross_origin;
 590 float wcross_scale_prev, wcross_alpha_prev;
 591 vector wcross_color_prev;
 592 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 593 vector wcross_color_goal_prev;
 594 float wcross_changedonetime;
 595
 596 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 597 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 598 float wcross_name_changestarttime, wcross_name_changedonetime;
 599 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 600
 601 float wcross_ring_prev;
 602
 603 entity trueaim;
 604 entity trueaim_rifle;
 605
 606 const float SHOTTYPE_HITTEAM = 1;
 607 const float SHOTTYPE_HITOBSTRUCTION = 2;
 608 const float SHOTTYPE_HITWORLD = 3;
 609 const float SHOTTYPE_HITENEMY = 4;
 610
 611 void TrueAim_Init()
 612 {
 613         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 614         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 615 }
 616
 617 float EnemyHitCheck()
 618 {
 619         float t, n;
 620         wcross_origin = project_3d_to_2d(trace_endpos);
 621         wcross_origin.z = 0;
 622         if(trace_ent)
 623                 n = trace_ent.entnum;
 624         else
 625                 n = trace_networkentity;
 626         if(n < 1)
 627                 return SHOTTYPE_HITWORLD;
 628         if(n > maxclients)
 629                 return SHOTTYPE_HITWORLD;
 630         t = entcs_GetTeam(n - 1);
 631         if(teamplay)
 632                 if(t == myteam)
 633                         return SHOTTYPE_HITTEAM;
 634         if(t == NUM_SPECTATOR)
 635                 return SHOTTYPE_HITWORLD;
 636         return SHOTTYPE_HITENEMY;
 637 }
 638
 639 float TrueAimCheck(entity wepent)
 640 {
 641         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 642         vector vecs, trueaimpoint, w_shotorg;
 643         vector mi, ma, dv;
 644         float shottype;
 645         entity ta;
 646         float mv;
 647
 648         mi = ma = '0 0 0';
 649         ta = trueaim;
 650         mv = MOVE_NOMONSTERS;
 651
 652         switch(wepent.activeweapon) // WEAPONTODO
 653         {
 654                 case WEP_TUBA: // no aim
 655                 case WEP_PORTO: // shoots from eye
 656                 case WEP_NEXBALL: // shoots from eye
 657                 case WEP_HOOK: // no trueaim
 658                 case WEP_MORTAR: // toss curve
 659                         return SHOTTYPE_HITWORLD;
 660                 case WEP_VORTEX:
 661                 case WEP_VAPORIZER:
 662                         mv = MOVE_NORMAL;
 663                         break;
 664                 case WEP_RIFLE:
 665                         ta = trueaim_rifle;
 666                         mv = MOVE_NORMAL;
 667                         if(zoomscript_caught)
 668                         {
 669                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 670                                 return EnemyHitCheck();
 671                         }
 672                         break;
 673                 case WEP_DEVASTATOR: // projectile has a size!
 674                         mi = '-3 -3 -3';
 675                         ma = '3 3 3';
 676                         break;
 677                 case WEP_FIREBALL: // projectile has a size!
 678                         mi = '-16 -16 -16';
 679                         ma = '16 16 16';
 680                         break;
 681                 case WEP_SEEKER: // projectile has a size!
 682                         mi = '-2 -2 -2';
 683                         ma = '2 2 2';
 684                         break;
 685                 case WEP_ELECTRO: // projectile has a size!
 686                         mi = '0 0 -3';
 687                         ma = '0 0 -3';
 688                         break;
 689         }
 690
 691         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 692
 693         vecs = decompressShotOrigin(STAT(SHOTORG));
 694
 695         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 696         trueaimpoint = trace_endpos;
 697
 698         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 699                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 700
 701         if(vecs.x > 0)
 702                 vecs.y = -vecs.y;
 703         else
 704                 vecs = '0 0 0';
 705
 706         dv = view_right * vecs.y + view_up * vecs.z;
 707         w_shotorg = traceorigin + dv;
 708
 709         // now move the vecs forward as much as requested if possible
 710         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 711         w_shotorg = trace_endpos - view_forward * nudge;
 712
 713         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 714         shottype = EnemyHitCheck();
 715         if(shottype != SHOTTYPE_HITWORLD)
 716                 return shottype;
 717
 718 #if 0
 719         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 720         // or rather, I know why, but see no fix
 721         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 722                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 723                 return SHOTTYPE_HITOBSTRUCTION;
 724 #endif
 725
 726         return SHOTTYPE_HITWORLD;
 727 }
 728
 729 void PostInit();
 730 void CSQC_Demo_Camera();
 731 float camera_mode;
 732 const float CAMERA_FREE = 1;
 733 const float CAMERA_CHASE = 2;
 734 float reticle_type;
 735 string NextFrameCommand;
 736
 737 vector freeze_org, freeze_ang;
 738 entity nightvision_noise, nightvision_noise2;
 739
 740 const float MAX_TIME_DIFF = 5;
 741 float pickup_crosshair_time, pickup_crosshair_size;
 742 float hitindication_crosshair_size;
 743 float use_vortex_chargepool;
 744
 745 float myhealth, myhealth_prev;
 746 float myhealth_flash;
 747
 748 float old_blurradius, old_bluralpha;
 749 float old_sharpen_intensity;
 750
 751 vector myhealth_gentlergb;
 752
 753 float contentavgalpha, liquidalpha_prev;
 754 vector liquidcolor_prev;
 755
 756 float eventchase_current_distance;
 757 float eventchase_running;
 758 bool WantEventchase(entity this)
 759 {
 760         if(autocvar_cl_orthoview)
 761                 return false;
 762         if(STAT(GAME_STOPPED) || intermission)
 763                 return true;
 764         if(this.viewloc)
 765                 return true;
 766         if(spectatee_status >= 0)
 767         {
 768                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 769                         return true;
 770                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 771                         return true;
 772                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 773                         return true;
 774                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 775                 {
 776                         if(autocvar_cl_eventchase_death == 2)
 777                         {
 778                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 779                                 if(this.velocity == '0 0 0' || eventchase_running)
 780                                         return true;
 781                         }
 782                         else return true;
 783                 }
 784         }
 785         return false;
 786 }
 787
 788 void HUD_Crosshair_Vehicle(entity this)
 789 {
 790         if(hud != HUD_BUMBLEBEE_GUN)
 791         {
 792                 Vehicle info = Vehicles_from(hud);
 793                 info.vr_crosshair(info, this);
 794         }
 795 }
 796
 797 vector damage_blurpostprocess, content_blurpostprocess;
 798
 799 float unaccounted_damage = 0;
 800 void UpdateDamage()
 801 {
 802         // accumulate damage with each stat update
 803         static float damage_total_prev = 0;
 804         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 805         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 806         damage_total_prev = damage_total;
 807
 808         static float damage_dealt_time_prev = 0;
 809         float damage_dealt_time = STAT(HIT_TIME);
 810         if (damage_dealt_time != damage_dealt_time_prev)
 811         {
 812                 unaccounted_damage += unaccounted_damage_new;
 813                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 814         }
 815         damage_dealt_time_prev = damage_dealt_time;
 816
 817         // prevent hitsound when switching spectatee
 818         static float spectatee_status_prev = 0;
 819         if (spectatee_status != spectatee_status_prev)
 820                 unaccounted_damage = 0;
 821         spectatee_status_prev = spectatee_status;
 822 }
 823
 824 void HitSound()
 825 {
 826         // varying sound pitch
 827
 828         bool have_arc = false;
 829         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 830         {
 831                 entity wepent = viewmodels[slot];
 832
 833                 if(wepent.activeweapon == WEP_ARC)
 834                         have_arc = true;
 835         }
 836
 837         static float hitsound_time_prev = 0;
 838         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 839         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 840         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 841         {
 842                 if (autocvar_cl_hitsound && unaccounted_damage)
 843                 {
 844                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 845                         float a = autocvar_cl_hitsound_max_pitch;
 846                         float b = autocvar_cl_hitsound_min_pitch;
 847                         float c = autocvar_cl_hitsound_nom_damage;
 848                         float d = unaccounted_damage;
 849                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 850
 851                         // if sound variation is disabled, set pitch_shift to 1
 852                         if (autocvar_cl_hitsound == 1)
 853                                 pitch_shift = 1;
 854
 855                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 856                         if (autocvar_cl_hitsound == 3)
 857                         {
 858                                 float mirror_value = (a-b)/2 + b;
 859                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 860                         }
 861
 862                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 863
 864                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 865                         // todo: normalize sound pressure levels? seems unnecessary
 866
 867                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 868                 }
 869                 unaccounted_damage = 0;
 870                 hitsound_time_prev = time;
 871         }
 872
 873         static float typehit_time_prev = 0;
 874         float typehit_time = STAT(TYPEHIT_TIME);
 875         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 876         {
 877                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 878                 typehit_time_prev = typehit_time;
 879         }
 880
 881         static float kill_time_prev = 0;
 882         float kill_time = STAT(KILL_TIME);
 883         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 884         {
 885                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 886                 kill_time_prev = kill_time;
 887         }
 888 }
 889
 890 vector crosshair_getcolor(entity this, float health_stat)
 891 {
 892         static float rainbow_last_flicker;
 893         static vector rainbow_prev_color;
 894         vector wcross_color = '0 0 0';
 895         switch(autocvar_crosshair_color_special)
 896         {
 897                 case 1: // crosshair_color_per_weapon
 898                 {
 899                         if(this != WEP_Null && hud == HUD_NORMAL)
 900                         {
 901                                 wcross_color = this.wpcolor;
 902                                 break;
 903                         }
 904                         else { goto normalcolor; }
 905                 }
 906
 907                 case 2: // crosshair_color_by_health
 908                 {
 909                         float hp = health_stat;
 910
 911                         //x = red
 912                         //y = green
 913                         //z = blue
 914
 915                         wcross_color.z = 0;
 916
 917                         if(hp > 200)
 918                         {
 919                                 wcross_color.x = 0;
 920                                 wcross_color.y = 1;
 921                         }
 922                         else if(hp > 150)
 923                         {
 924                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 925                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 926                         }
 927                         else if(hp > 100)
 928                         {
 929                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 930                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 931                                 wcross_color.z = 1 - (hp-100)*0.02;
 932                         }
 933                         else if(hp > 50)
 934                         {
 935                                 wcross_color.x = 1;
 936                                 wcross_color.y = 1;
 937                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 938                         }
 939                         else if(hp > 20)
 940                         {
 941                                 wcross_color.x = 1;
 942                                 wcross_color.y = (hp-20)*90/27/100;
 943                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 944                         }
 945                         else
 946                         {
 947                                 wcross_color.x = 1;
 948                                 wcross_color.y = 0;
 949                         }
 950                         break;
 951                 }
 952
 953                 case 3: // crosshair_color_rainbow
 954                 {
 955                         if(time >= rainbow_last_flicker)
 956                         {
 957                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 958                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 959                         }
 960                         wcross_color = rainbow_prev_color;
 961                         break;
 962                 }
 963 LABEL(normalcolor)
 964                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 965         }
 966
 967         return wcross_color;
 968 }
 969
 970 void HUD_Crosshair(entity this)
 971 {
 972         float f, i, j;
 973         vector v;
 974         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 975                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 976                 !HUD_MinigameMenu_IsOpened() )
 977         {
 978                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 979                         return;
 980
 981                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 982                         return;
 983
 984                 if (hud != HUD_NORMAL)
 985                 {
 986                         HUD_Crosshair_Vehicle(this);
 987                         return;
 988                 }
 989
 990                 string wcross_style;
 991                 float wcross_alpha, wcross_resolution;
 992                 wcross_style = autocvar_crosshair;
 993                 if (wcross_style == "0")
 994                         return;
 995                 wcross_resolution = autocvar_crosshair_size;
 996                 if (wcross_resolution == 0)
 997                         return;
 998                 wcross_alpha = autocvar_crosshair_alpha;
 999                 if (wcross_alpha == 0)
1000                         return;
1001
1002                 // TrueAim check
1003                 float shottype;
1004
1005                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1006                 wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1007                 wcross_origin.z = 0;
1008                 if(autocvar_crosshair_hittest)
1009                 {
1010                         vector wcross_oldorigin;
1011                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1012                         wcross_oldorigin = wcross_origin;
1013                         shottype = TrueAimCheck(thiswep);
1014                         if(shottype == SHOTTYPE_HITWORLD)
1015                         {
1016                                 v = wcross_origin - wcross_oldorigin;
1017                                 v.x /= vid_conwidth;
1018                                 v.y /= vid_conheight;
1019                                 if(vdist(v, >, 0.01))
1020                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1021                         }
1022                         if(!autocvar_crosshair_hittest_showimpact)
1023                                 wcross_origin = wcross_oldorigin;
1024                 }
1025                 else
1026                         shottype = SHOTTYPE_HITWORLD;
1027
1028                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1029                 string wcross_name = "";
1030                 float wcross_scale, wcross_blur;
1031
1032         entity e = WEP_Null;
1033                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1034                 {
1035                         entity wepent = viewmodels[0]; // TODO: unhardcode
1036                         e = wepent.switchingweapon;
1037                         if(e)
1038                         {
1039                                 if(autocvar_crosshair_per_weapon)
1040                                 {
1041                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1042                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1043                                         //if (wcross_resolution == 0)
1044                                                 //return;
1045
1046                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1047                                         wcross_resolution *= e.w_crosshair_size;
1048                                         wcross_name = e.w_crosshair;
1049                                 }
1050                         }
1051                 }
1052
1053                 if(wcross_name == "")
1054                         wcross_name = strcat("gfx/crosshair", wcross_style);
1055
1056                 // MAIN CROSSHAIR COLOR DECISION
1057                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1058
1059                 if(autocvar_crosshair_effect_scalefade)
1060                 {
1061                         wcross_scale = wcross_resolution;
1062                         wcross_resolution = 1;
1063                 }
1064                 else
1065                 {
1066                         wcross_scale = 1;
1067                 }
1068
1069                 if(autocvar_crosshair_pickup)
1070                 {
1071                         float stat_pickup_time = STAT(LAST_PICKUP);
1072
1073                         if(pickup_crosshair_time < stat_pickup_time)
1074                         {
1075                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1076                                         pickup_crosshair_size = 1;
1077
1078                                 pickup_crosshair_time = stat_pickup_time;
1079                         }
1080
1081                         if(pickup_crosshair_size > 0)
1082                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1083                         else
1084                                 pickup_crosshair_size = 0;
1085
1086                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1087                 }
1088
1089                 // todo: make crosshair hit indication dependent on damage dealt
1090                 if(autocvar_crosshair_hitindication)
1091                 {
1092                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1093
1094                         if(unaccounted_damage)
1095                         {
1096                                 hitindication_crosshair_size = 1;
1097                         }
1098
1099                         if(hitindication_crosshair_size > 0)
1100                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1101                         else
1102                                 hitindication_crosshair_size = 0;
1103
1104                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1105                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1106                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1107                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1108                 }
1109
1110                 if(shottype == SHOTTYPE_HITENEMY)
1111                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1112                 if(shottype == SHOTTYPE_HITTEAM)
1113                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1114
1115                 f = fabs(autocvar_crosshair_effect_time);
1116                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1117                 {
1118                         wcross_changedonetime = time + f;
1119                 }
1120                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1121                 {
1122                         wcross_name_changestarttime = time;
1123                         wcross_name_changedonetime = time + f;
1124                         if(wcross_name_goal_prev_prev)
1125                                 strunzone(wcross_name_goal_prev_prev);
1126                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1127                         wcross_name_goal_prev = strzone(wcross_name);
1128                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1129                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1130                         wcross_resolution_goal_prev = wcross_resolution;
1131                 }
1132
1133                 wcross_scale_goal_prev = wcross_scale;
1134                 wcross_alpha_goal_prev = wcross_alpha;
1135                 wcross_color_goal_prev = wcross_color;
1136
1137                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1138                 {
1139                         wcross_blur = 1;
1140                         wcross_alpha *= 0.75;
1141                 }
1142                 else
1143                         wcross_blur = 0;
1144                 // *_prev is at time-frametime
1145                 // * is at wcross_changedonetime+f
1146                 // what do we have at time?
1147                 if(time < wcross_changedonetime)
1148                 {
1149                         f = frametime / (wcross_changedonetime - time + frametime);
1150                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1151                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1152                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1153                 }
1154
1155                 wcross_scale_prev = wcross_scale;
1156                 wcross_alpha_prev = wcross_alpha;
1157                 wcross_color_prev = wcross_color;
1158
1159                 MUTATOR_CALLHOOK(UpdateCrosshair);
1160
1161                 wcross_scale *= 1 - autocvar__menu_alpha;
1162                 wcross_alpha *= 1 - autocvar__menu_alpha;
1163                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1164
1165                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1166                 {
1167                         // crosshair rings for weapon stats
1168                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1169                         {
1170                                 // declarations and stats
1171                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1172                                 string ring_image = string_null, ring_inner_image = string_null;
1173                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1174
1175                                 ring_scale = autocvar_crosshair_ring_size;
1176
1177                                 float weapon_clipload, weapon_clipsize;
1178                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1179                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1180
1181                                 float vortex_charge, vortex_chargepool;
1182                                 vortex_charge = STAT(VORTEX_CHARGE);
1183                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1184
1185                                 float arc_heat = STAT(ARC_HEAT);
1186
1187                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1188                                         vortex_charge_movingavg = vortex_charge;
1189
1190                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1191
1192                                 // handle the values
1193                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1194                                 {
1195                                         if (vortex_chargepool || use_vortex_chargepool) {
1196                                                 use_vortex_chargepool = 1;
1197                                                 ring_inner_value = vortex_chargepool;
1198                                         } else {
1199                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1200                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1201                                         }
1202
1203                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1204                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1205                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1206
1207                                         // draw the outer ring to show the current charge of the weapon
1208                                         ring_value = vortex_charge;
1209                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1210                                         ring_rgb = wcross_color;
1211                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1212                                 }
1213                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1214                                 {
1215                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1216                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1217                                         ring_rgb = wcross_color;
1218                                         ring_image = "gfx/crosshair_ring.tga";
1219                                 }
1220                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1221                                 {
1222                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1223                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1224                                         ring_rgb = wcross_color;
1225                                         ring_image = "gfx/crosshair_ring.tga";
1226                                 }
1227                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1228                                 {
1229                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1230                                         ring_scale = autocvar_crosshair_ring_reload_size;
1231                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1232                                         ring_rgb = wcross_color;
1233
1234                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1235                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1236                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1237                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1238                                         else
1239                                                 ring_image = "gfx/crosshair_ring.tga";
1240                                 }
1241                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1242                                 {
1243                                         ring_value = arc_heat;
1244                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1245                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1246                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1247                                         ring_image = "gfx/crosshair_ring.tga";
1248                                 }
1249
1250                                 // if in weapon switch animation, fade ring out/in
1251                                 if(autocvar_crosshair_effect_time > 0)
1252                                 {
1253                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1254                                         if (f >= 1)
1255                                         {
1256                                                 wcross_ring_prev = ((ring_image) ? true : false);
1257                                         }
1258
1259                                         if(wcross_ring_prev)
1260                                         {
1261                                                 if(f < 1)
1262                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1263                                         }
1264                                         else
1265                                         {
1266                                                 if(f < 1)
1267                                                         ring_alpha *= bound(0, f, 1);
1268                                         }
1269                                 }
1270
1271                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1272                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1273
1274                                 if (ring_value)
1275                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1276                         }
1277
1278 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1279                         MACRO_BEGIN { \
1280                                 if(wcross_blur > 0) \
1281                                 { \
1282                                         for(i = -2; i <= 2; ++i) \
1283                                         for(j = -2; j <= 2; ++j) \
1284                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1285                                 } \
1286                                 else \
1287                                 { \
1288                                         M(0,0,sz,wcross_name,wcross_alpha); \
1289                                 } \
1290                         } MACRO_END
1291
1292 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1293                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1294
1295 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1296                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1297
1298                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1299                         {
1300                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1301                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1302                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1303                                 f = 1 - f;
1304                         }
1305                         else
1306                         {
1307                                 f = 1;
1308                         }
1309                         wcross_name_alpha_goal_prev = f;
1310
1311                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1312                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1313
1314                         if(autocvar_crosshair_dot)
1315                         {
1316                                 vector wcross_color_old;
1317                                 wcross_color_old = wcross_color;
1318
1319                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1320                                         wcross_color = stov(autocvar_crosshair_dot_color);
1321
1322                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1323                                 // FIXME why don't we use wcross_alpha here?
1324                                 wcross_color = wcross_color_old;
1325                         }
1326                 }
1327         }
1328         else
1329         {
1330                 wcross_scale_prev = 0;
1331                 wcross_alpha_prev = 0;
1332                 wcross_scale_goal_prev = 0;
1333                 wcross_alpha_goal_prev = 0;
1334                 wcross_changedonetime = 0;
1335                 if(wcross_name_goal_prev)
1336                         strunzone(wcross_name_goal_prev);
1337                 wcross_name_goal_prev = string_null;
1338                 if(wcross_name_goal_prev_prev)
1339                         strunzone(wcross_name_goal_prev_prev);
1340                 wcross_name_goal_prev_prev = string_null;
1341                 wcross_name_changestarttime = 0;
1342                 wcross_name_changedonetime = 0;
1343                 wcross_name_alpha_goal_prev = 0;
1344                 wcross_name_alpha_goal_prev_prev = 0;
1345                 wcross_resolution_goal_prev = 0;
1346                 wcross_resolution_goal_prev_prev = 0;
1347         }
1348 }
1349
1350 const int MAX_SPECIALCOMMAND = 15;
1351 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1352 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1353 const float SPECIALCOMMAND_SPEED = 150;
1354 const float SPECIALCOMMAND_TURNSPEED = 2;
1355 const float SPECIALCOMMAND_SIZE = 0.025;
1356 const float SPECIALCOMMAND_CHANCE = 0.35;
1357 float sc_spawntime, sc_changetime;
1358 vector sc_color = '1 1 1';
1359 void SpecialCommand()
1360 {
1361         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1362                 return;
1363
1364         if(time >= sc_changetime)
1365         {
1366                 sc_changetime = time + 1;
1367                 sc_color = randomvec() * 1.5;
1368                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1369                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1370                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1371         }
1372         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1373
1374         if(!precache_pic("gfx/smile"))
1375                 return; // damn party poopers
1376
1377         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1378         {
1379                 vector slot = specialcommand_slots[j];
1380                 if(slot.y)
1381                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1382                 if(slot.z)
1383                         slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1384                 if(slot.y >= vid_conheight)
1385                         slot = '0 0 0';
1386
1387                 if(slot == '0 0 0')
1388                 {
1389                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1390                         {
1391                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1392                                 slot.y = 1; // start it off 0 so we can use it
1393                                 slot.z = random();
1394                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1395                                 vector newcolor = randomvec() * 2;
1396                                 newcolor.x = bound(0.4, newcolor.x, 1);
1397                                 newcolor.y = bound(0.4, newcolor.y, 1);
1398                                 newcolor.z = bound(0.4, newcolor.z, 1);
1399                                 specialcommand_colors[j] = newcolor;
1400                         }
1401                 }
1402                 else
1403                 {
1404                         vector splash_size = '0 0 0';
1405                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1406                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1407                         drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1408                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1409                 }
1410
1411                 specialcommand_slots[j] = slot;
1412         }
1413 }
1414
1415 void HUD_Draw(entity this)
1416 {
1417         // if we don't know gametype and scores yet avoid drawing the scoreboard
1418         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1419         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1420         // cl_deathscoreboard would show the scoreboard and so on
1421         if(!gametype)
1422                 return;
1423
1424         Hud_Dynamic_Frame();
1425
1426         if(!intermission)
1427         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1428         {
1429                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1430         }
1431         else if(STAT(FROZEN))
1432         {
1433                 vector col = '0.25 0.90 1';
1434                 if(STAT(REVIVE_PROGRESS))
1435                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1436                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1437         }
1438
1439         HUD_Scale_Enable();
1440         if(!intermission)
1441         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1442         {
1443                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1444                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1445                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1446         }
1447         else if(STAT(CAPTURE_PROGRESS))
1448         {
1449                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1450                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1451         }
1452         else if(STAT(REVIVE_PROGRESS))
1453         {
1454                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1455                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1456         }
1457         HUD_Scale_Disable();
1458
1459         if(autocvar_r_letterbox == 0)
1460                 if(autocvar_viewsize < 120)
1461                 {
1462                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1463                                 Accuracy_LoadLevels();
1464
1465                         HUD_Main();
1466                         HUD_Scale_Disable();
1467                 }
1468
1469         // crosshair goes VERY LAST
1470         SpecialCommand();
1471         UpdateDamage();
1472         HUD_Crosshair(this);
1473         HitSound();
1474 }
1475
1476 bool ov_enabled;
1477 float oldr_nearclip;
1478 float oldr_farclip_base;
1479 float oldr_farclip_world;
1480 float oldr_novis;
1481 float oldr_useportalculling;
1482 float oldr_useinfinitefarclip;
1483
1484 void cl_notice_run();
1485
1486 float prev_myteam;
1487 int lasthud;
1488 float vh_notice_time;
1489 void WaypointSprite_Load();
1490 void CSQC_UpdateView(entity this, float w, float h)
1491 {
1492     TC(int, w); TC(int, h);
1493         entity e;
1494         float fov;
1495         float f;
1496         vector vf_size, vf_min;
1497         float a;
1498
1499         execute_next_frame();
1500
1501         ++framecount;
1502
1503         stats_get();
1504         hud = STAT(HUD);
1505
1506         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1507                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1508
1509         lasthud = hud;
1510
1511         HUD_Scale_Disable();
1512
1513         if(autocvar__hud_showbinds_reload) // menu can set this one
1514         {
1515                 db_close(binddb);
1516                 binddb = db_create();
1517                 cvar_set("_hud_showbinds_reload", "0");
1518         }
1519
1520         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1521                 view_quality = getproperty(VF_MINFPS_QUALITY);
1522         else
1523                 view_quality = 1;
1524
1525         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1526         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1527
1528         vf_size = getpropertyvec(VF_SIZE);
1529         vf_min = getpropertyvec(VF_MIN);
1530         vid_width = vf_size.x;
1531         vid_height = vf_size.y;
1532
1533         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1534         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1535
1536         WaypointSprite_Load();
1537
1538         CSQCPlayer_SetCamera();
1539
1540         if(player_localentnum <= maxclients) // is it a client?
1541                 current_player = player_localentnum - 1;
1542         else // then player_localentnum is the vehicle I'm driving
1543                 current_player = player_localnum;
1544         myteam = entcs_GetTeam(current_player);
1545
1546         if(myteam != prev_myteam)
1547         {
1548                 myteamcolors = colormapPaletteColor(myteam, 1);
1549                 FOREACH(hud_panels, true, it.update_time = time);
1550                 prev_myteam = myteam;
1551         }
1552
1553         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1554
1555         float is_dead = (STAT(HEALTH) <= 0);
1556
1557         // FIXME do we need this hack?
1558         if(isdemo())
1559         {
1560                 // in demos, input_buttons do not work
1561                 button_zoom = (autocvar__togglezoom == "-");
1562         }
1563         else if(button_zoom
1564                 && autocvar_cl_unpress_zoom_on_death
1565                 && (spectatee_status >= 0)
1566                 && (is_dead || intermission))
1567         {
1568                 // no zoom while dead or in intermission please
1569                 localcmd("-zoom\n");
1570                 button_zoom = false;
1571         }
1572
1573         // event chase camera
1574         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1575         {
1576                 if(STAT(CAMERA_SPECTATOR))
1577                 {
1578                         if(spectatee_status > 0)
1579                         {
1580                                 if(!autocvar_chase_active)
1581                                 {
1582                                         cvar_set("chase_active", "-2");
1583                                         goto skip_eventchase_death;
1584                                 }
1585                         }
1586                         else if(autocvar_chase_active == -2)
1587                                 cvar_set("chase_active", "0");
1588
1589                         if(autocvar_chase_active == -2)
1590                                 goto skip_eventchase_death;
1591                 }
1592                 else if(autocvar_chase_active == -2)
1593                         cvar_set("chase_active", "0");
1594
1595                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1596
1597                 float vehicle_viewdist = 0;
1598                 vector vehicle_viewofs = '0 0 0';
1599
1600                 if(vehicle_chase)
1601                 {
1602                         if(hud != HUD_BUMBLEBEE_GUN)
1603                         {
1604                                 Vehicle info = Vehicles_from(hud);
1605                                 vehicle_viewdist = info.height;
1606                                 vehicle_viewofs = info.view_ofs;
1607                         }
1608                 }
1609
1610                 if(WantEventchase(this))
1611                 {
1612                         vector current_view_origin_override = '0 0 0';
1613                         vector view_offset_override = '0 0 0';
1614                         float chase_distance_override = 0;
1615                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1616                         if(custom_eventchase)
1617                         {
1618                                 current_view_origin_override = M_ARGV(0, vector);
1619                                 view_offset_override = M_ARGV(1, vector);
1620                                 chase_distance_override = M_ARGV(0, float);
1621                         }
1622                         eventchase_running = true;
1623
1624                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1625                         if(!local_player)
1626                                 local_player = this; // fall back!
1627
1628                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1629                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1630                         if (custom_eventchase)
1631                                 current_view_origin = current_view_origin_override;
1632
1633                         // detect maximum viewoffset and use it
1634                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1635                         if(vehicle_chase)
1636                         {
1637                                 if(vehicle_viewofs)
1638                                         view_offset = vehicle_viewofs;
1639                                 else
1640                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1641                         }
1642                         if (custom_eventchase)
1643                                 view_offset = view_offset_override;
1644
1645                         if(view_offset)
1646                         {
1647                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1648                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1649                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1650                         }
1651
1652                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1653                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1654                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1655                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1656
1657                         // make the camera smooth back
1658                         float chase_distance = autocvar_cl_eventchase_distance;
1659                         if(vehicle_chase)
1660                         {
1661                                 if(vehicle_viewofs)
1662                                         chase_distance = vehicle_viewdist;
1663                                 else
1664                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1665                         }
1666                         if (custom_eventchase)
1667                                 chase_distance = chase_distance_override;
1668
1669                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1670                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1671                         else if(eventchase_current_distance != chase_distance)
1672                                 eventchase_current_distance = chase_distance;
1673
1674                         makevectors(view_angles);
1675
1676                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1677                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1678
1679                         // If the boxtrace fails, revert back to line tracing.
1680                         if(!local_player.viewloc)
1681                         if(trace_startsolid)
1682                         {
1683                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1684                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1685                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1686                         }
1687                         else { setproperty(VF_ORIGIN, trace_endpos); }
1688
1689                         if(!local_player.viewloc)
1690                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1691                 }
1692                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1693                 {
1694                         eventchase_running = false;
1695                         cvar_set("chase_active", "0");
1696                         eventchase_current_distance = 0; // start from 0 next time
1697                 }
1698         }
1699         // workaround for camera stuck between player's legs when using chase_active 1
1700         // because the engine stops updating the chase_active camera when the game ends
1701         else if(intermission)
1702         {
1703                 cvar_settemp("chase_active", "-1");
1704                 eventchase_current_distance = 0;
1705         }
1706
1707         LABEL(skip_eventchase_death);
1708
1709         // do lockview after event chase camera so that it still applies whenever necessary.
1710         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1711         {
1712                 setproperty(VF_ORIGIN, freeze_org);
1713                 setproperty(VF_ANGLES, freeze_ang);
1714         }
1715         else
1716         {
1717                 freeze_org = getpropertyvec(VF_ORIGIN);
1718                 freeze_ang = getpropertyvec(VF_ANGLES);
1719         }
1720
1721         WarpZone_FixView();
1722         //WarpZone_FixPMove();
1723
1724         vector ov_org = '0 0 0';
1725         vector ov_mid = '0 0 0';
1726         vector ov_worldmin = '0 0 0';
1727         vector ov_worldmax = '0 0 0';
1728         if(autocvar_cl_orthoview)
1729         {
1730                 ov_worldmin = mi_picmin;
1731                 ov_worldmax = mi_picmax;
1732
1733                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1734                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1735                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1736
1737                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1738                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1739
1740                 float ov_nearest = vlen(ov_org - vec3(
1741                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1742                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1743                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1744                 ));
1745
1746                 float ov_furthest = 0;
1747                 float dist = 0;
1748
1749                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1750                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1751                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1752                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1753                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1754                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1755                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1756                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1757
1758                 if(!ov_enabled)
1759                 {
1760                         oldr_nearclip = cvar("r_nearclip");
1761                         oldr_farclip_base = cvar("r_farclip_base");
1762                         oldr_farclip_world = cvar("r_farclip_world");
1763                         oldr_novis = cvar("r_novis");
1764                         oldr_useportalculling = cvar("r_useportalculling");
1765                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1766                 }
1767
1768                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1769                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1770                 cvar_settemp("r_farclip_world", "0");
1771                 cvar_settemp("r_novis", "1");
1772                 cvar_settemp("r_useportalculling", "0");
1773                 cvar_settemp("r_useinfinitefarclip", "0");
1774
1775                 setproperty(VF_ORIGIN, ov_org);
1776                 setproperty(VF_ANGLES, '90 0 0');
1777
1778                 ov_enabled = true;
1779
1780                 #if 0
1781                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1782                         vtos(ov_org),
1783                         vtos(getpropertyvec(VF_ANGLES)),
1784                         ov_distance,
1785                         ov_nearest,
1786                         ov_furthest);
1787                 #endif
1788         }
1789         else
1790         {
1791                 if(ov_enabled)
1792                 {
1793                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1794                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1795                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1796                         cvar_set("r_novis", ftos(oldr_novis));
1797                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1798                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1799                 }
1800                 ov_enabled = false;
1801         }
1802
1803         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1804         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1805         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1806                 viewmodel_draw(viewmodels[slot]);
1807
1808         // Render the Scene
1809         view_origin = getpropertyvec(VF_ORIGIN);
1810         view_angles = getpropertyvec(VF_ANGLES);
1811         makevectors(view_angles);
1812         view_forward = v_forward;
1813         view_right = v_right;
1814         view_up = v_up;
1815
1816 #ifdef BLURTEST
1817         if(time > blurtest_time0 && time < blurtest_time1)
1818         {
1819                 float r, t;
1820
1821                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1822                 r = t * blurtest_radius;
1823                 f = 1 / (t ** blurtest_power) - 1;
1824
1825                 cvar_set("r_glsl_postprocess", "1");
1826                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1827         }
1828         else
1829         {
1830                 cvar_set("r_glsl_postprocess", "0");
1831                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1832         }
1833 #endif
1834
1835         TargetMusic_Advance();
1836         Fog_Force();
1837
1838         if(drawtime == 0)
1839                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1840         else
1841                 drawframetime = bound(0.000001, time - drawtime, 1);
1842         drawtime = time;
1843
1844         // watch for gametype changes here...
1845         // in ParseStuffCMD the cmd isn't executed yet :/
1846         // might even be better to add the gametype to TE_CSQC_INIT...?
1847         if(!postinit)
1848                 PostInit();
1849
1850         if(intermission && !intermission_time)
1851                 intermission_time = time;
1852
1853         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1854         {
1855                 if(calledhooks & HOOK_START)
1856                 {
1857                         localcmd("\ncl_hook_gameend\n");
1858                         calledhooks |= HOOK_END;
1859                 }
1860         }
1861
1862         Announcer();
1863
1864         fov = autocvar_fov;
1865         if(fov <= 59.5)
1866         {
1867                 if(!zoomscript_caught)
1868                 {
1869                         localcmd("+button9\n");
1870                         zoomscript_caught = 1;
1871                 }
1872         }
1873         else
1874         {
1875                 if(zoomscript_caught)
1876                 {
1877                         localcmd("-button9\n");
1878                         zoomscript_caught = 0;
1879                 }
1880         }
1881
1882         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1883
1884         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1885         {
1886                 entity wepent = viewmodels[slot];
1887
1888                 if(wepent.last_switchweapon != wepent.switchweapon)
1889                 {
1890                         weapontime = time;
1891                         wepent.last_switchweapon = wepent.switchweapon;
1892                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1893                         {
1894                                 localcmd("-zoom\n");
1895                                 button_zoom = false;
1896                         }
1897                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1898                         {
1899                                 localcmd("-fire\n");
1900                                 localcmd("-fire2\n");
1901                                 button_attack2 = false;
1902                         }
1903                 }
1904                 if(wepent.last_activeweapon != wepent.activeweapon)
1905                 {
1906                         wepent.last_activeweapon = wepent.activeweapon;
1907
1908                         e = wepent.activeweapon;
1909                         if(e.netname != "")
1910                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1911                         else if(slot == 0)
1912                                 localcmd("\ncl_hook_activeweapon none\n");
1913                 }
1914         }
1915
1916         // ALWAYS Clear Current Scene First
1917         clearscene();
1918
1919         setproperty(VF_ORIGIN, view_origin);
1920         setproperty(VF_ANGLES, view_angles);
1921
1922         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1923         setproperty(VF_SIZE, vf_size);
1924         setproperty(VF_MIN, vf_min);
1925
1926         // Assign Standard Viewflags
1927         // Draw the World (and sky)
1928         setproperty(VF_DRAWWORLD, 1);
1929
1930         // Set the console size vars
1931         vid_conwidth = autocvar_vid_conwidth;
1932         vid_conheight = autocvar_vid_conheight;
1933         vid_pixelheight = autocvar_vid_pixelheight;
1934
1935         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1936         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1937         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1938
1939         if(camera_active) // Camera for demo playback
1940         {
1941                 if(autocvar_camera_enable)
1942                         CSQC_Demo_Camera();
1943                 else
1944                 {
1945                         cvar_set("chase_active", ftos(chase_active_backup));
1946                         cvar_set("cl_demo_mousegrab", "0");
1947                         camera_active = false;
1948                 }
1949         }
1950         else
1951         {
1952 #ifdef CAMERATEST
1953                 if(autocvar_camera_enable)
1954 #else
1955                 if(autocvar_camera_enable && isdemo())
1956 #endif
1957                 {
1958                         // Enable required Darkplaces cvars
1959                         chase_active_backup = autocvar_chase_active;
1960                         cvar_set("chase_active", "2");
1961                         cvar_set("cl_demo_mousegrab", "1");
1962                         camera_active = true;
1963                         camera_mode = false;
1964                 }
1965         }
1966
1967         // Draw the Crosshair
1968         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1969
1970         // Draw the Engine Status Bar (the default Quake HUD)
1971         setproperty(VF_DRAWENGINESBAR, 0);
1972
1973         // Update the mouse position
1974         /*
1975            mousepos_x = vid_conwidth;
1976            mousepos_y = vid_conheight;
1977            mousepos = mousepos*0.5 + getmousepos();
1978          */
1979
1980         IL_EACH(g_drawables, it.draw, it.draw(it));
1981
1982         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1983         renderscene();
1984
1985         // now switch to 2D drawing mode by calling a 2D drawing function
1986         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1987         // next R_RenderScene call
1988         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1989
1990         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1991         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1992         {
1993                 // apply night vision effect
1994                 vector tc_00, tc_01, tc_10, tc_11;
1995                 vector rgb = '0 0 0';
1996
1997                 if(!nightvision_noise)
1998                 {
1999                         nightvision_noise = new(nightvision_noise);
2000                 }
2001                 if(!nightvision_noise2)
2002                 {
2003                         nightvision_noise2 = new(nightvision_noise2);
2004                 }
2005
2006                 // color tint in yellow
2007                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2008
2009                 // draw BG
2010                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2011                 rgb = '1 1 1';
2012                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2013                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2014                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2015                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2016                 tc_11 = tc_01 + tc_10 - tc_00;
2017                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2018                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2019                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2020                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2021                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2022                 R_EndPolygon();
2023
2024                 // draw FG
2025                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2026                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2027                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2028                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2029                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2030                 tc_11 = tc_01 + tc_10 - tc_00;
2031                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2032                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2033                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2034                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2035                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2036                 R_EndPolygon();
2037         }
2038
2039         if(autocvar_cl_reticle)
2040         {
2041                 string reticle_image = string_null;
2042                 bool wep_zoomed = false;
2043                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2044                 {
2045                         entity wepe = viewmodels[slot];
2046                         Weapon wep = wepe.activeweapon;
2047                         if(wep != WEP_Null && wep.wr_zoom)
2048                         {
2049                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2050                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2051                                         reticle_image = wep.w_reticle;
2052                                 wep_zoomed += do_zoom;
2053                         }
2054                 }
2055                 // Draw the aiming reticle for weapons that use it
2056                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2057                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2058                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2059                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
2060                 {
2061                         // no zoom reticle while dead
2062                         reticle_type = 0;
2063                 }
2064                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2065                 {
2066                         if(reticle_image) { reticle_type = 2; }
2067                         else { reticle_type = 0; }
2068                 }
2069                 else if(button_zoom || zoomscript_caught)
2070                 {
2071                         // normal zoom
2072                         reticle_type = 1;
2073                 }
2074
2075                 if(reticle_type)
2076                 {
2077                         if(autocvar_cl_reticle_stretch)
2078                         {
2079                                 reticle_size.x = vid_conwidth;
2080                                 reticle_size.y = vid_conheight;
2081                                 reticle_pos.x = 0;
2082                                 reticle_pos.y = 0;
2083                         }
2084                         else
2085                         {
2086                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2087                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2088                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2089                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2090                         }
2091
2092                         if(zoomscript_caught)
2093                                 f = 1;
2094                         else
2095                                 f = current_zoomfraction;
2096
2097                         if(f)
2098                         {
2099                                 switch(reticle_type)
2100                                 {
2101                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2102                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2103                                 }
2104                         }
2105                 }
2106         }
2107         else
2108         {
2109                 if(reticle_type != 0) { reticle_type = 0; }
2110         }
2111
2112
2113         // improved polyblend
2114         if(autocvar_hud_contents)
2115         {
2116                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2117                 vector liquidcolor;
2118
2119                 switch(pointcontents(view_origin))
2120                 {
2121                         case CONTENT_WATER:
2122                                 liquidalpha = autocvar_hud_contents_water_alpha;
2123                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2124                                 incontent = 1;
2125                                 break;
2126
2127                         case CONTENT_LAVA:
2128                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2129                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2130                                 incontent = 1;
2131                                 break;
2132
2133                         case CONTENT_SLIME:
2134                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2135                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2136                                 incontent = 1;
2137                                 break;
2138
2139                         default:
2140                                 liquidalpha = 0;
2141                                 liquidcolor = '0 0 0';
2142                                 incontent = 0;
2143                                 break;
2144                 }
2145
2146                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2147                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2148                         contentfadetime = autocvar_hud_contents_fadeintime;
2149                         liquidalpha_prev = liquidalpha;
2150                         liquidcolor_prev = liquidcolor;
2151                 }
2152                 else
2153                         contentfadetime = autocvar_hud_contents_fadeouttime;
2154
2155                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2156                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2157
2158                 if(contentavgalpha)
2159                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2160
2161                 if(autocvar_hud_postprocessing)
2162                 {
2163                         if(autocvar_hud_contents_blur && contentavgalpha)
2164                         {
2165                                 content_blurpostprocess.x = 1;
2166                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2167                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2168                         }
2169                         else
2170                         {
2171                                 content_blurpostprocess.x = 0;
2172                                 content_blurpostprocess.y = 0;
2173                                 content_blurpostprocess.z = 0;
2174                         }
2175                 }
2176         }
2177
2178         if(autocvar_hud_damage && !STAT(FROZEN))
2179         {
2180                 splash_size.x = max(vid_conwidth, vid_conheight);
2181                 splash_size.y = max(vid_conwidth, vid_conheight);
2182                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2183                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2184
2185                 float myhealth_flash_temp;
2186                 myhealth = STAT(HEALTH);
2187
2188                 // fade out
2189                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2190                 // add new damage
2191                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2192
2193                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2194                 pain_threshold = autocvar_hud_damage_pain_threshold;
2195                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2196                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2197
2198                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2199                 {
2200                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2201                 }
2202
2203                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2204
2205                 if(myhealth_prev < 1)
2206                 {
2207                         if(myhealth >= 1)
2208                         {
2209                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2210                                 myhealth_flash_temp = 0;
2211                         }
2212                         else
2213                         {
2214                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2215                         }
2216                 }
2217
2218                 if(spectatee_status == -1 || intermission)
2219                 {
2220                         myhealth_flash = 0; // observing, or match ended
2221                         myhealth_flash_temp = 0;
2222                 }
2223
2224                 myhealth_prev = myhealth;
2225
2226                 // IDEA: change damage color/picture based on player model for robot/alien species?
2227                 // pro: matches model better
2228                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2229                 // maybe different reddish pics?
2230                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2231                 {
2232                         if(autocvar_cl_gentle_damage == 2)
2233                         {
2234                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2235                                         myhealth_gentlergb = randomvec();
2236                         }
2237                         else
2238                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2239
2240                         if(myhealth_flash_temp > 0)
2241                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2242                 }
2243                 else if(myhealth_flash_temp > 0)
2244                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2245
2246                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2247                 {
2248                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2249                         {
2250                                 damage_blurpostprocess.x = 1;
2251                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2252                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2253                         }
2254                         else
2255                         {
2256                                 damage_blurpostprocess.x = 0;
2257                                 damage_blurpostprocess.y = 0;
2258                                 damage_blurpostprocess.z = 0;
2259                         }
2260                 }
2261         }
2262
2263         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2264         float e2 = (autocvar_hud_powerup != 0);
2265         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2266         {
2267                 // enable or disable rendering types if they are used or not
2268                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2269                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2270
2271                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2272                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2273                 {
2274                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2275                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2276                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2277                         {
2278                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2279                                 old_blurradius = blurradius;
2280                                 old_bluralpha = bluralpha;
2281                         }
2282                 }
2283                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2284                 {
2285                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2286                         old_blurradius = 0;
2287                         old_bluralpha = 0;
2288                 }
2289
2290                 // edge detection postprocess handling done second (used by hud_powerup)
2291                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2292                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2293                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2294
2295                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2296
2297                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2298                 {
2299                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2300                         {
2301                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2302                                 old_sharpen_intensity = sharpen_intensity;
2303                         }
2304                 }
2305                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2306                 {
2307                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2308                         old_sharpen_intensity = 0;
2309                 }
2310
2311                 if(cvar("r_glsl_postprocess") == 0)
2312                         cvar_set("r_glsl_postprocess", "2");
2313         }
2314         else if(cvar("r_glsl_postprocess") == 2)
2315                 cvar_set("r_glsl_postprocess", "0");
2316
2317         /*if(gametype == MAPINFO_TYPE_CTF)
2318           {
2319           ctf_view();
2320           } else */
2321
2322         // draw 2D entities
2323         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2324         Draw_ShowNames_All();
2325 #if ENABLE_DEBUGDRAW
2326         Debug_Draw();
2327 #endif
2328
2329         scoreboard_active = Scoreboard_WouldDraw();
2330
2331         HUD_Draw(this); // this parameter for deep vehicle function
2332
2333         if(NextFrameCommand)
2334         {
2335                 localcmd("\n", NextFrameCommand, "\n");
2336                 NextFrameCommand = string_null;
2337         }
2338
2339         // we must do this check AFTER a frame was rendered, or it won't work
2340         if(cs_project_is_b0rked == 0)
2341         {
2342                 string w0, h0;
2343                 w0 = ftos(autocvar_vid_conwidth);
2344                 h0 = ftos(autocvar_vid_conheight);
2345                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2346                 //setproperty(VF_FOV, '90 90 0');
2347                 setproperty(VF_ORIGIN, '0 0 0');
2348                 setproperty(VF_ANGLES, '0 0 0');
2349                 setproperty(VF_PERSPECTIVE, 1);
2350                 makevectors('0 0 0');
2351                 vector v1, v2;
2352                 cvar_set("vid_conwidth", "800");
2353                 cvar_set("vid_conheight", "600");
2354                 v1 = cs_project(v_forward);
2355                 cvar_set("vid_conwidth", "640");
2356                 cvar_set("vid_conheight", "480");
2357                 v2 = cs_project(v_forward);
2358                 if(v1 == v2)
2359                         cs_project_is_b0rked = 1;
2360                 else
2361                         cs_project_is_b0rked = -1;
2362                 cvar_set("vid_conwidth", w0);
2363                 cvar_set("vid_conheight", h0);
2364         }
2365
2366         if(autocvar__hud_configure)
2367                 HUD_Panel_Mouse();
2368         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2369                 HUD_Minigame_Mouse();
2370         else if(QuickMenu_IsOpened())
2371                 QuickMenu_Mouse();
2372         else
2373                 HUD_Radar_Mouse();
2374
2375         cl_notice_run();
2376         unpause_update();
2377         Net_Flush();
2378
2379         // let's reset the view back to normal for the end
2380         setproperty(VF_MIN, '0 0 0');
2381         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2382
2383         IL_ENDFRAME();
2384 }
2385
2386
2387 // following vectors must be global to allow seamless switching between camera modes
2388 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2389 void CSQC_Demo_Camera()
2390 {
2391         float speed, attenuation, dimensions;
2392         vector tmp, delta;
2393
2394         if( autocvar_camera_reset || !camera_mode )
2395         {
2396                 camera_offset = '0 0 0';
2397                 current_angles = '0 0 0';
2398                 camera_direction = '0 0 0';
2399                 camera_offset.z += 30;
2400                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2401                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2402                 current_origin = view_origin;
2403                 current_camera_offset  = camera_offset;
2404                 cvar_set("camera_reset", "0");
2405                 camera_mode = CAMERA_CHASE;
2406         }
2407
2408         // Camera angles
2409         if( camera_roll )
2410                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2411
2412         if(autocvar_camera_look_player)
2413         {
2414                 vector dir;
2415                 float n;
2416
2417                 dir = normalize(view_origin - current_position);
2418                 n = mouse_angles.z;
2419                 mouse_angles = vectoangles(dir);
2420                 mouse_angles.x = mouse_angles.x * -1;
2421                 mouse_angles.z = n;
2422         }
2423         else
2424         {
2425                 tmp = getmousepos() * 0.1;
2426                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2427                 {
2428                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2429                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2430                 }
2431         }
2432
2433         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2434         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2435         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2436         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2437
2438         // Fix difference when angles don't have the same sign
2439         delta = '0 0 0';
2440         if(mouse_angles.y < -60 && current_angles.y > 60)
2441                 delta = '0 360 0';
2442         if(mouse_angles.y > 60 && current_angles.y < -60)
2443                 delta = '0 -360 0';
2444
2445         if(autocvar_camera_look_player)
2446                 attenuation = autocvar_camera_look_attenuation;
2447         else
2448                 attenuation = autocvar_camera_speed_attenuation;
2449
2450         attenuation = 1 / max(1, attenuation);
2451         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2452
2453         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2454         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2455         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2456         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2457
2458         // Camera position
2459         tmp = '0 0 0';
2460         dimensions = 0;
2461
2462         if( camera_direction.x )
2463         {
2464                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2465                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2466                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2467                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2468                 ++dimensions;
2469         }
2470
2471         if( camera_direction.y )
2472         {
2473                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2474                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2475                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2476                 ++dimensions;
2477         }
2478
2479         if( camera_direction.z )
2480         {
2481                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2482                 ++dimensions;
2483         }
2484
2485         if(autocvar_camera_free)
2486                 speed = autocvar_camera_speed_free;
2487         else
2488                 speed = autocvar_camera_speed_chase;
2489
2490         if(dimensions)
2491         {
2492                 speed = speed * sqrt(1 / dimensions);
2493                 camera_offset += tmp * speed;
2494         }
2495
2496         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2497
2498         // Camera modes
2499         if( autocvar_camera_free )
2500         {
2501                 if ( camera_mode == CAMERA_CHASE )
2502                 {
2503                         current_camera_offset = current_origin + current_camera_offset;
2504                         camera_offset = current_origin + camera_offset;
2505                 }
2506
2507                 camera_mode = CAMERA_FREE;
2508                 current_position = current_camera_offset;
2509         }
2510         else
2511         {
2512                 if ( camera_mode == CAMERA_FREE )
2513                 {
2514                         current_origin = view_origin;
2515                         camera_offset = camera_offset - current_origin;
2516                         current_camera_offset = current_camera_offset - current_origin;
2517                 }
2518
2519                 camera_mode = CAMERA_CHASE;
2520
2521                 if(autocvar_camera_chase_smoothly)
2522                         current_origin += (view_origin - current_origin) * attenuation;
2523                 else
2524                         current_origin = view_origin;
2525
2526                 current_position = current_origin + current_camera_offset;
2527         }
2528
2529         setproperty(VF_ANGLES, current_angles);
2530         setproperty(VF_ORIGIN, current_position);
2531 }