qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51
  52 bool autocvar_cl_bobmodel;
  53 float autocvar_cl_bobmodel_speed;
  54 float autocvar_cl_bobmodel_side;
  55 float autocvar_cl_bobmodel_up;
  56
  57 float autocvar_cl_followmodel;
  58 float autocvar_cl_followmodel_speed = 0.3;
  59 float autocvar_cl_followmodel_limit = 135;
  60 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  61 float autocvar_cl_followmodel_highpass = 0.05;
  62 float autocvar_cl_followmodel_lowpass = 0.03;
  63 bool autocvar_cl_followmodel_velocity_absolute;
  64
  65 float autocvar_cl_leanmodel;
  66 float autocvar_cl_leanmodel_speed = 0.3;
  67 float autocvar_cl_leanmodel_limit = 30;
  68 float autocvar_cl_leanmodel_highpass1 = 0.2;
  69 float autocvar_cl_leanmodel_highpass = 0.2;
  70 float autocvar_cl_leanmodel_lowpass = 0.05;
  71
  72 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  73
  74 #define lowpass(value, frac, ref_store, ret) \
  75         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  76
  77 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  78 { \
  79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  81 } MACRO_END
  82
  83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  84 { \
  85         float __f = 0; lowpass(value, frac, ref_store, __f); \
  86         ret = (value) - __f; \
  87 } MACRO_END
  88
  89 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  90 { \
  91         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  92         ret = (value) - __f; \
  93 } MACRO_END
  94
  95 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  96 { \
  97         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  98         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  99 } MACRO_END
 100
 101 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
 102 { \
 103         highpass(value.x, frac, ref_store.x, ref_out.x); \
 104         highpass(value.y, frac, ref_store.y, ref_out.y); \
 105 } MACRO_END
 106
 107 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 108 { \
 109         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 110         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 111 } MACRO_END
 112
 113 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 114 { \
 115         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 116         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 117         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 118 } MACRO_END
 119
 120 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 121 { \
 122         highpass(value.x, frac, ref_store.x, ref_out.x); \
 123         highpass(value.y, frac, ref_store.y, ref_out.y); \
 124         highpass(value.z, frac, ref_store.z, ref_out.z); \
 125 } MACRO_END
 126
 127 void calc_followmodel_ofs(entity view)
 128 {
 129         if(cl_followmodel_time == time)
 130                 return; // cl_followmodel_ofs already calculated for this frame
 131
 132         float frac;
 133         vector gunorg = '0 0 0';
 134         static vector vel_average;
 135         static vector gunorg_adjustment_highpass;
 136         static vector gunorg_adjustment_lowpass;
 137
 138         vector vel;
 139         if (autocvar_cl_followmodel_velocity_absolute)
 140                 vel = view.velocity;
 141         else
 142         {
 143                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 144                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 145                 vel.x = view.velocity * forward;
 146                 vel.y = view.velocity * right * -1;
 147                 vel.z = view.velocity * up;
 148         }
 149
 150         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 151         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 152         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 153
 154         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 155         lowpass3(vel, frac, vel_average, gunorg);
 156
 157         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 158
 159         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 160         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 161         frac = avg_factor(autocvar_cl_followmodel_highpass);
 162         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 163         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 164         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 165
 166         if (autocvar_cl_followmodel_velocity_absolute)
 167         {
 168                 vector fixed_gunorg;
 169                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 170                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 171                 fixed_gunorg.x = gunorg * forward;
 172                 fixed_gunorg.y = gunorg * right * -1;
 173                 fixed_gunorg.z = gunorg * up;
 174                 gunorg = fixed_gunorg;
 175         }
 176
 177         cl_followmodel_ofs = gunorg;
 178         cl_followmodel_time = time;
 179 }
 180
 181 vector leanmodel_ofs(entity view)
 182 {
 183         float frac;
 184         vector gunangles = '0 0 0';
 185         static vector gunangles_prev = '0 0 0';
 186         static vector gunangles_highpass = '0 0 0';
 187         static vector gunangles_adjustment_highpass;
 188         static vector gunangles_adjustment_lowpass;
 189
 190         if (view.csqcmodel_teleported)
 191                 gunangles_prev = view_angles;
 192
 193         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 194         gunangles_highpass += gunangles_prev;
 195         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 196         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 197         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 198         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 199         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 200         gunangles_prev = view_angles;
 201         gunangles_highpass -= gunangles_prev;
 202
 203         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 204         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 205
 206         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 207         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 208         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 209         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 210         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 211
 212         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 213
 214         return gunangles;
 215 }
 216
 217 vector bobmodel_ofs(entity view)
 218 {
 219         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 220         static bool oldonground;
 221         static float hitgroundtime;
 222         if (clonground)
 223         {
 224                 float f = time; // cl.movecmd[0].time
 225                 if (!oldonground)
 226                         hitgroundtime = f;
 227         }
 228         oldonground = clonground;
 229
 230         // calculate for swinging gun model
 231         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 232         vector gunorg = '0 0 0';
 233         static float bobmodel_scale = 0;
 234         static float time_ofs = 0; // makes the effect always restart in the same way
 235         if (clonground)
 236         {
 237                 if (time - hitgroundtime > 0.05)
 238                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 239         }
 240         else
 241                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 242
 243         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 244         if (bobmodel_scale && xyspeed)
 245         {
 246                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 247                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 248                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 249                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 250         }
 251         else
 252                 time_ofs = time;
 253
 254         return gunorg;
 255 }
 256
 257 void viewmodel_animate(entity this)
 258 {
 259         if (autocvar_chase_active) return;
 260         if (STAT(HEALTH) <= 0) return;
 261
 262         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 263
 264         if (autocvar_cl_followmodel)
 265         {
 266                 calc_followmodel_ofs(view);
 267                 this.origin += cl_followmodel_ofs;
 268         }
 269
 270         if (autocvar_cl_leanmodel)
 271                 this.angles += leanmodel_ofs(view);
 272
 273         // vertical view bobbing code
 274         // TODO: cl_bob
 275
 276         // horizontal view bobbing code
 277         // TODO: cl_bob2
 278
 279         // fall bobbing code
 280         // causes the view to swing down and back up when touching the ground
 281         // TODO: cl_bobfall
 282
 283         // gun model bobbing code
 284         if (autocvar_cl_bobmodel)
 285                 this.origin += bobmodel_ofs(view);
 286 }
 287
 288 .vector viewmodel_origin, viewmodel_angles;
 289 .float weapon_nextthink;
 290 .float weapon_eta_last;
 291 .float weapon_switchdelay;
 292
 293 .string name_last;
 294
 295 void viewmodel_draw(entity this)
 296 {
 297         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 298                 return;
 299         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 300         float a = this.alpha;
 301         static bool wasinvehicle;
 302         bool invehicle = player_localentnum > maxclients;
 303         if (invehicle) a = -1;
 304         else if (wasinvehicle) a = 1;
 305         wasinvehicle = invehicle;
 306         Weapon wep = this.activeweapon;
 307         int c = entcs_GetClientColors(current_player);
 308         vector g = weaponentity_glowmod(wep, NULL, c, this);
 309         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 310         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 311                 | EF_NODEPTHTEST)
 312                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 313         for (entity e = this; e; e = e.weaponchild)
 314         {
 315                 e.drawmask = mask;
 316                 e.alpha = a;
 317                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 318                 e.glowmod = g;
 319                 e.csqcmodel_effects = fx;
 320                 CSQCModel_Effects_Apply(e);
 321         }
 322         if(a >= 0)
 323         {
 324                 string name = wep.mdl;
 325                 string newname = wep.wr_viewmodel(wep, this);
 326                 if(newname)
 327                         name = newname;
 328                 bool swap = name != this.name_last;
 329                 // if (swap)
 330                 {
 331                         this.name_last = name;
 332                         CL_WeaponEntity_SetModel(this, name, swap);
 333                         this.viewmodel_origin = this.origin;
 334                         this.viewmodel_angles = this.angles;
 335                 }
 336                 anim_update(this);
 337                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 338                         anim_set(this, this.anim_idle, true, false, false);
 339         }
 340         float f = 0; // 0..1; 0: fully active
 341         float rate = STAT(WEAPONRATEFACTOR);
 342         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 343         if (eta <= 0) f = this.weapon_eta_last;
 344         else switch (this.state)
 345         {
 346                 case WS_RAISE:
 347                 {
 348                         f = eta / max(eta, this.weapon_switchdelay);
 349                         break;
 350                 }
 351                 case WS_DROP:
 352                 {
 353                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 354                         break;
 355                 }
 356                 case WS_CLEAR:
 357                 {
 358                         f = 1;
 359                         break;
 360                 }
 361         }
 362         this.weapon_eta_last = f;
 363         this.origin = this.viewmodel_origin;
 364         this.angles = this.viewmodel_angles;
 365         this.angles_x = (-90 * f * f);
 366         viewmodel_animate(this);
 367         MUTATOR_CALLHOOK(DrawViewModel, this);
 368         setorigin(this, this.origin);
 369 }
 370
 371 STATIC_INIT(viewmodel) {
 372     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 373         viewmodels[slot] = new(viewmodel);
 374 }
 375
 376 float showfps_prevfps;
 377 float showfps_prevfps_time;
 378 int showfps_framecounter;
 379
 380 void fpscounter_update()
 381 {
 382         if(!STAT(SHOWFPS))
 383                 return;
 384
 385         float currentTime = gettime(GETTIME_REALTIME);
 386         showfps_framecounter += 1;
 387         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 388         {
 389                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 390                 showfps_framecounter = 0;
 391                 showfps_prevfps_time = currentTime;
 392
 393                 int channel = MSG_C2S;
 394                 WriteHeader(channel, fpsreport);
 395                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 396         }
 397 }
 398
 399 STATIC_INIT(fpscounter_init)
 400 {
 401         float currentTime = gettime(GETTIME_REALTIME);
 402         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 403 }
 404
 405 STATIC_INIT(Porto)
 406 {
 407         entity e = new_pure(porto);
 408         e.draw = Porto_Draw;
 409         IL_PUSH(g_drawables, e);
 410         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 411 }
 412
 413 const int polyline_length = 16;
 414 .vector polyline[polyline_length];
 415 void Porto_Draw(entity this)
 416 {
 417         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 418         {
 419                 entity wepent = viewmodels[slot];
 420
 421                 if (wepent.activeweapon != WEP_PORTO) continue;
 422                 if (spectatee_status) continue;
 423                 if (WEP_CVAR(porto, secondary)) continue;
 424                 if (intermission == 1) continue;
 425                 if (intermission == 2) continue;
 426                 if (STAT(HEALTH) <= 0) continue;
 427
 428                 vector pos = view_origin;
 429                 vector dir = view_forward;
 430                 if (wepent.angles_held_status)
 431                 {
 432                         makevectors(wepent.angles_held);
 433                         dir = v_forward;
 434                 }
 435
 436                 wepent.polyline[0] = pos;
 437
 438                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 439                 int n = 1 + 2;  // 2 lines == 3 points
 440                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 441                 {
 442                         traceline(pos, pos + 65536 * dir, true, this);
 443                         dir = reflect(dir, trace_plane_normal);
 444                         pos = trace_endpos;
 445                         wepent.polyline[++idx] = pos;
 446                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 447                         {
 448                                 n += 1;
 449                                 continue;
 450                         }
 451                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 452                         {
 453                                 n = max(2, idx);
 454                                 break;
 455                         }
 456                         // check size
 457                         {
 458                                 vector ang = vectoangles2(trace_plane_normal, dir);
 459                                 ang.x = -ang.x;
 460                                 makevectors(ang);
 461                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 462                                 {
 463                                         n = max(2, idx);
 464                                         break;
 465                                 }
 466                         }
 467                         portal_number += 1;
 468                         if (portal_number >= portal_max) break;
 469                         if (portal_number == 1) portal1_idx = idx;
 470                 }
 471                 for (int idx = 0; idx < n - 1; ++idx)
 472                 {
 473                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 474                         if (idx == 0) p -= view_up * 16;  // line from player
 475                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 476                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 477                 }
 478         }
 479 }
 480
 481 float drawtime;
 482 float avgspeed;
 483 vector GetCurrentFov(float fov)
 484 {
 485         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 486         float velocityzoom, curspeed;
 487         vector v;
 488
 489         zoomsensitivity = autocvar_cl_zoomsensitivity;
 490         zoomfactor = autocvar_cl_zoomfactor;
 491         if(zoomfactor < 1 || zoomfactor > 30)
 492                 zoomfactor = 2.5;
 493         zoomspeed = autocvar_cl_zoomspeed;
 494         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 495                 zoomspeed = 3.5;
 496
 497         zoomdir = button_zoom;
 498
 499         if(hud == HUD_NORMAL && !spectatee_status)
 500         {
 501                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 502                 {
 503                         entity wepent = viewmodels[slot];
 504                         if(wepent.switchweapon != wepent.activeweapon)
 505                                 continue;
 506                         Weapon wep = wepent.activeweapon;
 507                         if(wep != WEP_Null && wep.wr_zoomdir)
 508                         {
 509                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 510                                 zoomdir += do_zoom;
 511                         }
 512                 }
 513         }
 514         if(spectatee_status > 0 || isdemo())
 515         {
 516                 if(spectatorbutton_zoom)
 517                 {
 518                         if(zoomdir)
 519                                 zoomdir = 0;
 520                         else
 521                                 zoomdir = 1;
 522                 }
 523                 // fteqcc failed twice here already, don't optimize this
 524         }
 525
 526         if(zoomdir) { zoomin_effect = 0; }
 527
 528         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 529         {
 530                 current_viewzoom = 1;
 531         }
 532         else if (camera_active)
 533         {
 534                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 535         }
 536         else if(autocvar_cl_spawnzoom && zoomin_effect)
 537         {
 538                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 539
 540                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 541                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 542                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 543         }
 544         else
 545         {
 546                 if(zoomspeed < 0) // instant zoom
 547                 {
 548                         if(zoomdir)
 549                                 current_viewzoom = 1 / zoomfactor;
 550                         else
 551                                 current_viewzoom = 1;
 552                 }
 553                 else
 554                 {
 555                         if(zoomdir)
 556                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 557                         else
 558                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 559                 }
 560         }
 561
 562         if(almost_equals(current_viewzoom, 1))
 563                 current_zoomfraction = 0;
 564         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 565                 current_zoomfraction = 1;
 566         else
 567                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 568
 569         if(zoomsensitivity < 1)
 570                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 571         else
 572                 setsensitivityscale(1);
 573
 574         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 575         {
 576                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 577                         curspeed = 0;
 578                 else
 579                 {
 580                         makevectors(view_angles);
 581                         v = pmove_vel;
 582                         if(csqcplayer)
 583                                 v = csqcplayer.velocity;
 584
 585                         switch(autocvar_cl_velocityzoom_type)
 586                         {
 587                                 case 3: curspeed = max(0, v_forward * v); break;
 588                                 case 2: curspeed = (v_forward * v); break;
 589                                 case 1: default: curspeed = vlen(v); break;
 590                         }
 591                 }
 592
 593                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 594                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 595                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 596
 597                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 598         }
 599         else
 600                 velocityzoom = 1;
 601
 602         float frustumx, frustumy, fovx, fovy;
 603         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 604         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 605         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 606         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 607
 608         return '1 0 0' * fovx + '0 1 0' * fovy;
 609 }
 610
 611 vector GetViewLocationFOV(float fov)
 612 {
 613         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 614         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 615         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 616         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 617         return '1 0 0' * fovx + '0 1 0' * fovy;
 618 }
 619
 620 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 621 {
 622         float fovx, fovy;
 623         float width = (ov_worldmax.x - ov_worldmin.x);
 624         float height = (ov_worldmax.y - ov_worldmin.y);
 625         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 626         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 627         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 628         return '1 0 0' * fovx + '0 1 0' * fovy;
 629 }
 630
 631 // this function must match W_SetupShot!
 632 float zoomscript_caught;
 633
 634 vector wcross_origin;
 635 float wcross_scale_prev, wcross_alpha_prev;
 636 vector wcross_color_prev;
 637 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 638 vector wcross_color_goal_prev;
 639 float wcross_changedonetime;
 640
 641 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 642 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 643 float wcross_name_changestarttime, wcross_name_changedonetime;
 644 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 645
 646 float wcross_ring_prev;
 647
 648 entity trueaim;
 649 entity trueaim_rifle;
 650
 651 const float SHOTTYPE_HITTEAM = 1;
 652 const float SHOTTYPE_HITOBSTRUCTION = 2;
 653 const float SHOTTYPE_HITWORLD = 3;
 654 const float SHOTTYPE_HITENEMY = 4;
 655
 656 void TrueAim_Init()
 657 {
 658         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 659         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 660 }
 661
 662 float EnemyHitCheck()
 663 {
 664         float t, n;
 665         wcross_origin = project_3d_to_2d(trace_endpos);
 666         wcross_origin.z = 0;
 667         if(trace_ent)
 668                 n = trace_ent.entnum;
 669         else
 670                 n = trace_networkentity;
 671         if(n < 1)
 672                 return SHOTTYPE_HITWORLD;
 673         if(n > maxclients)
 674                 return SHOTTYPE_HITWORLD;
 675         t = entcs_GetTeam(n - 1);
 676         if(teamplay)
 677                 if(t == myteam)
 678                         return SHOTTYPE_HITTEAM;
 679         if(t == NUM_SPECTATOR)
 680                 return SHOTTYPE_HITWORLD;
 681         return SHOTTYPE_HITENEMY;
 682 }
 683
 684 float TrueAimCheck(entity wepent)
 685 {
 686         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 687         vector vecs, trueaimpoint, w_shotorg;
 688         vector mi, ma, dv;
 689         float shottype;
 690         entity ta;
 691         float mv;
 692
 693         mi = ma = '0 0 0';
 694         ta = trueaim;
 695         mv = MOVE_NOMONSTERS;
 696
 697         switch(wepent.activeweapon) // WEAPONTODO
 698         {
 699                 case WEP_TUBA: // no aim
 700                 case WEP_PORTO: // shoots from eye
 701                 case WEP_NEXBALL: // shoots from eye
 702                 case WEP_HOOK: // no trueaim
 703                 case WEP_MORTAR: // toss curve
 704                         return SHOTTYPE_HITWORLD;
 705                 case WEP_VORTEX:
 706                 case WEP_OVERKILL_NEX:
 707                 case WEP_VAPORIZER:
 708                         mv = MOVE_NORMAL;
 709                         break;
 710                 case WEP_RIFLE:
 711                         ta = trueaim_rifle;
 712                         mv = MOVE_NORMAL;
 713                         if(zoomscript_caught)
 714                         {
 715                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 716                                 return EnemyHitCheck();
 717                         }
 718                         break;
 719                 case WEP_DEVASTATOR: // projectile has a size!
 720                         mi = '-3 -3 -3';
 721                         ma = '3 3 3';
 722                         break;
 723                 case WEP_FIREBALL: // projectile has a size!
 724                         mi = '-16 -16 -16';
 725                         ma = '16 16 16';
 726                         break;
 727                 case WEP_SEEKER: // projectile has a size!
 728                         mi = '-2 -2 -2';
 729                         ma = '2 2 2';
 730                         break;
 731                 case WEP_ELECTRO: // projectile has a size!
 732                         mi = '0 0 -3';
 733                         ma = '0 0 -3';
 734                         break;
 735         }
 736
 737         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 738
 739         vecs = decompressShotOrigin(STAT(SHOTORG));
 740
 741         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 742         trueaimpoint = trace_endpos;
 743
 744         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 745                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 746
 747         if(vecs.x > 0)
 748                 vecs.y = -vecs.y;
 749         else
 750                 vecs = '0 0 0';
 751
 752         dv = view_right * vecs.y + view_up * vecs.z;
 753         w_shotorg = traceorigin + dv;
 754
 755         // now move the vecs forward as much as requested if possible
 756         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 757         w_shotorg = trace_endpos - view_forward * nudge;
 758
 759         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 760         shottype = EnemyHitCheck();
 761         if(shottype != SHOTTYPE_HITWORLD)
 762                 return shottype;
 763
 764 #if 0
 765         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 766         // or rather, I know why, but see no fix
 767         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 768                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 769                 return SHOTTYPE_HITOBSTRUCTION;
 770 #endif
 771
 772         return SHOTTYPE_HITWORLD;
 773 }
 774
 775 float camera_mode;
 776 const float CAMERA_FREE = 1;
 777 const float CAMERA_CHASE = 2;
 778 float reticle_type;
 779 string NextFrameCommand;
 780
 781 vector freeze_org, freeze_ang;
 782 entity nightvision_noise, nightvision_noise2;
 783
 784 const float MAX_TIME_DIFF = 5;
 785 float pickup_crosshair_time, pickup_crosshair_size;
 786 float hitindication_crosshair_size;
 787 float use_vortex_chargepool;
 788
 789 float myhealth, myhealth_prev;
 790 float myhealth_flash;
 791
 792 float old_blurradius, old_bluralpha;
 793 float old_sharpen_intensity;
 794
 795 vector myhealth_gentlergb;
 796
 797 float contentavgalpha, liquidalpha_prev;
 798 vector liquidcolor_prev;
 799
 800 float eventchase_current_distance;
 801 float eventchase_running;
 802 bool WantEventchase(entity this)
 803 {
 804         if(autocvar_cl_orthoview)
 805                 return false;
 806         if(STAT(GAME_STOPPED) || intermission)
 807                 return true;
 808         if(this.viewloc)
 809                 return true;
 810         if(spectatee_status >= 0)
 811         {
 812                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 813                         return true;
 814                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 815                         return true;
 816                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 817                         return true;
 818                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 819                 {
 820                         if(autocvar_cl_eventchase_death == 2)
 821                         {
 822                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 823                                 if(this.velocity == '0 0 0' || eventchase_running)
 824                                         return true;
 825                         }
 826                         else return true;
 827                 }
 828         }
 829         return false;
 830 }
 831
 832 void HUD_Crosshair_Vehicle(entity this)
 833 {
 834         if(hud != HUD_BUMBLEBEE_GUN)
 835         {
 836                 Vehicle info = Vehicles_from(hud);
 837                 info.vr_crosshair(info, this);
 838         }
 839 }
 840
 841 vector damage_blurpostprocess, content_blurpostprocess;
 842
 843 float unaccounted_damage = 0;
 844 void UpdateDamage()
 845 {
 846         // accumulate damage with each stat update
 847         static float damage_total_prev = 0;
 848         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 849         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 850         damage_total_prev = damage_total;
 851
 852         static float damage_dealt_time_prev = 0;
 853         float damage_dealt_time = STAT(HIT_TIME);
 854         if (damage_dealt_time != damage_dealt_time_prev)
 855         {
 856                 unaccounted_damage += unaccounted_damage_new;
 857                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 858         }
 859         damage_dealt_time_prev = damage_dealt_time;
 860
 861         // prevent hitsound when switching spectatee
 862         static float spectatee_status_prev = 0;
 863         if (spectatee_status != spectatee_status_prev)
 864                 unaccounted_damage = 0;
 865         spectatee_status_prev = spectatee_status;
 866 }
 867
 868 void HitSound()
 869 {
 870         // varying sound pitch
 871
 872         bool have_arc = false;
 873         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 874         {
 875                 entity wepent = viewmodels[slot];
 876
 877                 if(wepent.activeweapon == WEP_ARC)
 878                         have_arc = true;
 879         }
 880
 881         static float hitsound_time_prev = 0;
 882         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 883         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 884         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 885         {
 886                 if (autocvar_cl_hitsound && unaccounted_damage)
 887                 {
 888                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 889                         float a = autocvar_cl_hitsound_max_pitch;
 890                         float b = autocvar_cl_hitsound_min_pitch;
 891                         float c = autocvar_cl_hitsound_nom_damage;
 892                         float d = unaccounted_damage;
 893                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 894
 895                         // if sound variation is disabled, set pitch_shift to 1
 896                         if (autocvar_cl_hitsound == 1)
 897                                 pitch_shift = 1;
 898
 899                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 900                         if (autocvar_cl_hitsound == 3)
 901                         {
 902                                 float mirror_value = (a-b)/2 + b;
 903                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 904                         }
 905
 906                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 907
 908                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 909                         // todo: normalize sound pressure levels? seems unnecessary
 910
 911                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 912                 }
 913                 unaccounted_damage = 0;
 914                 hitsound_time_prev = time;
 915         }
 916
 917         static float typehit_time_prev = 0;
 918         float typehit_time = STAT(TYPEHIT_TIME);
 919         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 920         {
 921                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 922                 typehit_time_prev = typehit_time;
 923         }
 924
 925         static float kill_time_prev = 0;
 926         float kill_time = STAT(KILL_TIME);
 927         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 928         {
 929                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 930                 kill_time_prev = kill_time;
 931         }
 932 }
 933
 934 vector crosshair_getcolor(entity this, float health_stat)
 935 {
 936         static float rainbow_last_flicker;
 937         static vector rainbow_prev_color;
 938         vector wcross_color = '0 0 0';
 939         switch(autocvar_crosshair_color_special)
 940         {
 941                 case 1: // crosshair_color_per_weapon
 942                 {
 943                         if(this != WEP_Null && hud == HUD_NORMAL)
 944                         {
 945                                 wcross_color = this.wpcolor;
 946                                 break;
 947                         }
 948                         else { goto normalcolor; }
 949                 }
 950
 951                 case 2: // crosshair_color_by_health
 952                 {
 953                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 954                         float hp = floor(v.x + 1);
 955
 956                         //x = red
 957                         //y = green
 958                         //z = blue
 959
 960                         wcross_color.z = 0;
 961
 962                         if(hp > 200)
 963                         {
 964                                 wcross_color.x = 0;
 965                                 wcross_color.y = 1;
 966                         }
 967                         else if(hp > 150)
 968                         {
 969                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 970                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 971                         }
 972                         else if(hp > 100)
 973                         {
 974                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 975                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 976                                 wcross_color.z = 1 - (hp-100)*0.02;
 977                         }
 978                         else if(hp > 50)
 979                         {
 980                                 wcross_color.x = 1;
 981                                 wcross_color.y = 1;
 982                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 983                         }
 984                         else if(hp > 20)
 985                         {
 986                                 wcross_color.x = 1;
 987                                 wcross_color.y = (hp-20)*90/27/100;
 988                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 989                         }
 990                         else
 991                         {
 992                                 wcross_color.x = 1;
 993                                 wcross_color.y = 0;
 994                         }
 995                         break;
 996                 }
 997
 998                 case 3: // crosshair_color_rainbow
 999                 {
1000                         if(time >= rainbow_last_flicker)
1001                         {
1002                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1003                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1004                         }
1005                         wcross_color = rainbow_prev_color;
1006                         break;
1007                 }
1008 LABEL(normalcolor)
1009                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1010         }
1011
1012         return wcross_color;
1013 }
1014
1015 void HUD_Crosshair(entity this)
1016 {
1017         float f, i, j;
1018         vector v;
1019         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
1020                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
1021                 !HUD_MinigameMenu_IsOpened() )
1022         {
1023                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1024                         return;
1025
1026                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
1027                         return;
1028
1029                 if (hud != HUD_NORMAL)
1030                 {
1031                         HUD_Crosshair_Vehicle(this);
1032                         return;
1033                 }
1034
1035                 string wcross_style;
1036                 float wcross_alpha, wcross_resolution;
1037                 wcross_style = autocvar_crosshair;
1038                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1039                         wcross_style = autocvar_crosshair_2d;
1040                 if (wcross_style == "0")
1041                         return;
1042                 wcross_resolution = autocvar_crosshair_size;
1043                 if (wcross_resolution == 0)
1044                         return;
1045                 wcross_alpha = autocvar_crosshair_alpha;
1046                 if (wcross_alpha == 0)
1047                         return;
1048
1049                 // TrueAim check
1050                 float shottype;
1051
1052                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1053                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1054                         wcross_origin = viewloc_mousepos;
1055                 else
1056                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1057                 wcross_origin.z = 0;
1058                 if(autocvar_crosshair_hittest)
1059                 {
1060                         vector wcross_oldorigin;
1061                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1062                         wcross_oldorigin = wcross_origin;
1063                         shottype = TrueAimCheck(thiswep);
1064                         if(shottype == SHOTTYPE_HITWORLD)
1065                         {
1066                                 v = wcross_origin - wcross_oldorigin;
1067                                 v.x /= vid_conwidth;
1068                                 v.y /= vid_conheight;
1069                                 if(vdist(v, >, 0.01))
1070                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1071                         }
1072                         if(!autocvar_crosshair_hittest_showimpact)
1073                                 wcross_origin = wcross_oldorigin;
1074                 }
1075                 else
1076                         shottype = SHOTTYPE_HITWORLD;
1077
1078                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1079                 string wcross_name = "";
1080                 float wcross_scale, wcross_blur;
1081
1082         entity e = WEP_Null;
1083                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1084                 {
1085                         entity wepent = viewmodels[0]; // TODO: unhardcode
1086                         e = wepent.switchingweapon;
1087                         if(e)
1088                         {
1089                                 if(autocvar_crosshair_per_weapon)
1090                                 {
1091                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1092                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1093                                         //if (wcross_resolution == 0)
1094                                                 //return;
1095
1096                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1097                                         wcross_resolution *= e.w_crosshair_size;
1098                                         wcross_name = e.w_crosshair;
1099                                 }
1100                         }
1101                 }
1102
1103                 if(wcross_name == "")
1104                         wcross_name = strcat("gfx/crosshair", wcross_style);
1105
1106                 // MAIN CROSSHAIR COLOR DECISION
1107                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1108
1109                 if(autocvar_crosshair_effect_scalefade)
1110                 {
1111                         wcross_scale = wcross_resolution;
1112                         wcross_resolution = 1;
1113                 }
1114                 else
1115                 {
1116                         wcross_scale = 1;
1117                 }
1118
1119                 if(autocvar_crosshair_pickup)
1120                 {
1121                         float stat_pickup_time = STAT(LAST_PICKUP);
1122
1123                         if(pickup_crosshair_time < stat_pickup_time)
1124                         {
1125                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1126                                         pickup_crosshair_size = 1;
1127
1128                                 pickup_crosshair_time = stat_pickup_time;
1129                         }
1130
1131                         if(pickup_crosshair_size > 0)
1132                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1133                         else
1134                                 pickup_crosshair_size = 0;
1135
1136                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1137                 }
1138
1139                 // todo: make crosshair hit indication dependent on damage dealt
1140                 if(autocvar_crosshair_hitindication)
1141                 {
1142                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1143
1144                         if(unaccounted_damage)
1145                         {
1146                                 hitindication_crosshair_size = 1;
1147                         }
1148
1149                         if(hitindication_crosshair_size > 0)
1150                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1151                         else
1152                                 hitindication_crosshair_size = 0;
1153
1154                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1155                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1156                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1157                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1158                 }
1159
1160                 if(shottype == SHOTTYPE_HITENEMY)
1161                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1162                 if(shottype == SHOTTYPE_HITTEAM)
1163                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1164
1165                 f = fabs(autocvar_crosshair_effect_time);
1166                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1167                 {
1168                         wcross_changedonetime = time + f;
1169                 }
1170                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1171                 {
1172                         wcross_name_changestarttime = time;
1173                         wcross_name_changedonetime = time + f;
1174                         if(wcross_name_goal_prev_prev)
1175                                 strunzone(wcross_name_goal_prev_prev);
1176                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1177                         wcross_name_goal_prev = strzone(wcross_name);
1178                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1179                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1180                         wcross_resolution_goal_prev = wcross_resolution;
1181                 }
1182
1183                 wcross_scale_goal_prev = wcross_scale;
1184                 wcross_alpha_goal_prev = wcross_alpha;
1185                 wcross_color_goal_prev = wcross_color;
1186
1187                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1188                 {
1189                         wcross_blur = 1;
1190                         wcross_alpha *= 0.75;
1191                 }
1192                 else
1193                         wcross_blur = 0;
1194                 // *_prev is at time-frametime
1195                 // * is at wcross_changedonetime+f
1196                 // what do we have at time?
1197                 if(time < wcross_changedonetime)
1198                 {
1199                         f = frametime / (wcross_changedonetime - time + frametime);
1200                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1201                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1202                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1203                 }
1204
1205                 wcross_scale_prev = wcross_scale;
1206                 wcross_alpha_prev = wcross_alpha;
1207                 wcross_color_prev = wcross_color;
1208
1209                 MUTATOR_CALLHOOK(UpdateCrosshair);
1210
1211                 wcross_scale *= 1 - autocvar__menu_alpha;
1212                 wcross_alpha *= 1 - autocvar__menu_alpha;
1213                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1214
1215                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1216                 {
1217                         // crosshair rings for weapon stats
1218                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1219                         {
1220                                 // declarations and stats
1221                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1222                                 string ring_image = string_null, ring_inner_image = string_null;
1223                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1224
1225                                 ring_scale = autocvar_crosshair_ring_size;
1226
1227                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1228
1229                                 int weapon_clipload = wepent.clip_load;
1230                                 int weapon_clipsize = wepent.clip_size;
1231
1232                                 float arc_heat = wepent.arc_heat_percent;
1233                                 float vcharge = wepent.vortex_charge;
1234                                 float vchargepool = wepent.vortex_chargepool_ammo;
1235                                 float oknex_charge_ = wepent.oknex_charge;
1236                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1237
1238                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1239                                         vortex_charge_movingavg = vcharge;
1240
1241                                 // handle the values
1242                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1243                                 {
1244                                         if (vchargepool || use_vortex_chargepool) {
1245                                                 use_vortex_chargepool = 1;
1246                                                 ring_inner_value = vchargepool;
1247                                         } else {
1248                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1249                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1250                                         }
1251
1252                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1253                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1254                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1255
1256                                         // draw the outer ring to show the current charge of the weapon
1257                                         ring_value = vcharge;
1258                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1259                                         ring_rgb = wcross_color;
1260                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1261                                 }
1262                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1263                                 {
1264                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1265                                                 use_vortex_chargepool = 1;
1266                                                 ring_inner_value = oknex_chargepool_;
1267                                         } else {
1268                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1269                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1270                                         }
1271
1272                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1273                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1274                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1275
1276                                         // draw the outer ring to show the current charge of the weapon
1277                                         ring_value = oknex_charge_;
1278                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1279                                         ring_rgb = wcross_color;
1280                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1281                                 }
1282                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1283                                 {
1284                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1285                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1286                                         ring_rgb = wcross_color;
1287                                         ring_image = "gfx/crosshair_ring.tga";
1288                                 }
1289                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1290                                 {
1291                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1292                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1293                                         ring_rgb = wcross_color;
1294                                         ring_image = "gfx/crosshair_ring.tga";
1295                                 }
1296                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1297                                 {
1298                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1299                                         ring_scale = autocvar_crosshair_ring_reload_size;
1300                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1301                                         ring_rgb = wcross_color;
1302
1303                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1304                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1305                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1306                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1307                                         else
1308                                                 ring_image = "gfx/crosshair_ring.tga";
1309                                 }
1310                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1311                                 {
1312                                         ring_value = arc_heat;
1313                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1314                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1315                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1316                                         ring_image = "gfx/crosshair_ring.tga";
1317                                 }
1318
1319                                 // if in weapon switch animation, fade ring out/in
1320                                 if(autocvar_crosshair_effect_time > 0)
1321                                 {
1322                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1323                                         if (f >= 1)
1324                                         {
1325                                                 wcross_ring_prev = ((ring_image) ? true : false);
1326                                         }
1327
1328                                         if(wcross_ring_prev)
1329                                         {
1330                                                 if(f < 1)
1331                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1332                                         }
1333                                         else
1334                                         {
1335                                                 if(f < 1)
1336                                                         ring_alpha *= bound(0, f, 1);
1337                                         }
1338                                 }
1339
1340                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1341                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1342
1343                                 if (ring_value)
1344                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1345                         }
1346
1347 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1348                         MACRO_BEGIN { \
1349                                 if(wcross_blur > 0) \
1350                                 { \
1351                                         for(i = -2; i <= 2; ++i) \
1352                                         for(j = -2; j <= 2; ++j) \
1353                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1354                                 } \
1355                                 else \
1356                                 { \
1357                                         M(0,0,sz,wcross_name,wcross_alpha); \
1358                                 } \
1359                         } MACRO_END
1360
1361 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1362                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1363
1364 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1365                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1366
1367                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1368                         {
1369                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1370                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1371                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1372                                 f = 1 - f;
1373                         }
1374                         else
1375                         {
1376                                 f = 1;
1377                         }
1378                         wcross_name_alpha_goal_prev = f;
1379
1380                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1381                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1382
1383                         if(autocvar_crosshair_dot)
1384                         {
1385                                 vector wcross_color_old;
1386                                 wcross_color_old = wcross_color;
1387
1388                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1389                                         wcross_color = stov(autocvar_crosshair_dot_color);
1390
1391                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1392                                 // FIXME why don't we use wcross_alpha here?
1393                                 wcross_color = wcross_color_old;
1394                         }
1395                 }
1396         }
1397         else
1398         {
1399                 wcross_scale_prev = 0;
1400                 wcross_alpha_prev = 0;
1401                 wcross_scale_goal_prev = 0;
1402                 wcross_alpha_goal_prev = 0;
1403                 wcross_changedonetime = 0;
1404                 strfree(wcross_name_goal_prev);
1405                 strfree(wcross_name_goal_prev_prev);
1406                 wcross_name_changestarttime = 0;
1407                 wcross_name_changedonetime = 0;
1408                 wcross_name_alpha_goal_prev = 0;
1409                 wcross_name_alpha_goal_prev_prev = 0;
1410                 wcross_resolution_goal_prev = 0;
1411                 wcross_resolution_goal_prev_prev = 0;
1412         }
1413 }
1414
1415 const int MAX_SPECIALCOMMAND = 15;
1416 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1417 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1418 const float SPECIALCOMMAND_SPEED = 150;
1419 const float SPECIALCOMMAND_TURNSPEED = 2;
1420 const float SPECIALCOMMAND_SIZE = 0.025;
1421 const float SPECIALCOMMAND_CHANCE = 0.35;
1422 float sc_spawntime, sc_changetime;
1423 vector sc_color = '1 1 1';
1424 void SpecialCommand()
1425 {
1426         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1427                 return;
1428
1429         if(time >= sc_changetime)
1430         {
1431                 sc_changetime = time + 1;
1432                 sc_color = randomvec() * 1.5;
1433                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1434                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1435                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1436         }
1437         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1438
1439         if(!precache_pic("gfx/smile"))
1440                 return; // damn party poopers
1441
1442         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1443         {
1444                 vector slot = specialcommand_slots[j];
1445                 if(slot.y)
1446                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1447                 //if(slot.z)
1448                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1449                 if(slot.y >= vid_conheight)
1450                         slot = '0 0 0';
1451
1452                 if(slot == '0 0 0')
1453                 {
1454                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1455                         {
1456                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1457                                 slot.y = 1; // start it off 0 so we can use it
1458                                 slot.z = floor(random() * Weapons_MAX);
1459                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1460                                 vector newcolor = randomvec() * 2;
1461                                 newcolor.x = bound(0.4, newcolor.x, 1);
1462                                 newcolor.y = bound(0.4, newcolor.y, 1);
1463                                 newcolor.z = bound(0.4, newcolor.z, 1);
1464                                 specialcommand_colors[j] = newcolor;
1465                         }
1466                 }
1467                 else
1468                 {
1469                         vector splash_size = '0 0 0';
1470                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1471                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1472                         entity wep = Weapons_from(slot.z);
1473                         if(wep == WEP_Null)
1474                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1475                         else
1476                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1477                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1478                 }
1479
1480                 specialcommand_slots[j] = slot;
1481         }
1482 }
1483
1484 void HUD_Draw(entity this)
1485 {
1486         // if we don't know gametype and scores yet avoid drawing the scoreboard
1487         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1488         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1489         // cl_deathscoreboard would show the scoreboard and so on
1490         if(!gametype)
1491                 return;
1492
1493         Hud_Dynamic_Frame();
1494
1495         if(!intermission)
1496         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1497         {
1498                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1499         }
1500         else if(STAT(FROZEN))
1501         {
1502                 vector col = '0.25 0.90 1';
1503                 if(STAT(REVIVE_PROGRESS))
1504                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1505                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1506         }
1507
1508         HUD_Scale_Enable();
1509         if(!intermission)
1510         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1511         {
1512                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1513                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1514                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1515         }
1516         else if(STAT(CAPTURE_PROGRESS))
1517         {
1518                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1519                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1520         }
1521         else if(STAT(REVIVE_PROGRESS))
1522         {
1523                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1524                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1525         }
1526         HUD_Scale_Disable();
1527
1528         if(autocvar_r_letterbox == 0)
1529                 if(autocvar_viewsize < 120)
1530                 {
1531                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1532                                 Accuracy_LoadLevels();
1533
1534                         HUD_Main();
1535                         HUD_Scale_Disable();
1536                 }
1537
1538         // crosshair goes VERY LAST
1539         SpecialCommand();
1540         UpdateDamage();
1541         HUD_Crosshair(this);
1542         HitSound();
1543 }
1544
1545 void ViewLocation_Mouse()
1546 {
1547         if(spectatee_status)
1548                 return; // don't draw it as spectator!
1549
1550         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1551         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1552         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1553
1554         //float cursor_alpha = 1 - autocvar__menu_alpha;
1555         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1556 }
1557
1558 bool ov_enabled;
1559 float oldr_nearclip;
1560 float oldr_farclip_base;
1561 float oldr_farclip_world;
1562 float oldr_novis;
1563 float oldr_useportalculling;
1564 float oldr_useinfinitefarclip;
1565
1566 float prev_myteam;
1567 int lasthud;
1568 float vh_notice_time;
1569 void CSQC_UpdateView(entity this, float w, float h)
1570 {
1571         TC(int, w); TC(int, h);
1572         entity e;
1573         float fov;
1574         float f;
1575         vector vf_size, vf_min;
1576         float a;
1577
1578         execute_next_frame();
1579
1580         ++framecount;
1581
1582         stats_get();
1583         hud = STAT(HUD);
1584
1585         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1586                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1587
1588         lasthud = hud;
1589
1590         HUD_Scale_Disable();
1591
1592         if(autocvar__hud_showbinds_reload) // menu can set this one
1593         {
1594                 db_close(binddb);
1595                 binddb = db_create();
1596                 cvar_set("_hud_showbinds_reload", "0");
1597         }
1598
1599         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1600                 view_quality = getproperty(VF_MINFPS_QUALITY);
1601         else
1602                 view_quality = 1;
1603
1604         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1605         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1606
1607         vf_size = getpropertyvec(VF_SIZE);
1608         vf_min = getpropertyvec(VF_MIN);
1609         vid_width = vf_size.x;
1610         vid_height = vf_size.y;
1611
1612         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1613         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1614
1615         WaypointSprite_Load();
1616
1617         CSQCPlayer_SetCamera();
1618
1619         if(player_localentnum <= maxclients) // is it a client?
1620                 current_player = player_localentnum - 1;
1621         else // then player_localentnum is the vehicle I'm driving
1622                 current_player = player_localnum;
1623         myteam = entcs_GetTeam(current_player);
1624
1625         if(myteam != prev_myteam)
1626         {
1627                 myteamcolors = colormapPaletteColor(myteam, 1);
1628                 FOREACH(hud_panels, true, it.update_time = time);
1629                 prev_myteam = myteam;
1630         }
1631
1632         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1633
1634         float is_dead = (STAT(HEALTH) <= 0);
1635
1636         // FIXME do we need this hack?
1637         if(isdemo())
1638         {
1639                 // in demos, input_buttons do not work
1640                 button_zoom = (autocvar__togglezoom == "-");
1641         }
1642         else if(button_zoom
1643                 && autocvar_cl_unpress_zoom_on_death
1644                 && (spectatee_status >= 0)
1645                 && (is_dead || intermission))
1646         {
1647                 // no zoom while dead or in intermission please
1648                 localcmd("-zoom\n");
1649                 button_zoom = false;
1650         }
1651
1652         // abused multiple places below
1653         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1654         if(!local_player)
1655                 local_player = this; // fall back!
1656
1657         // event chase camera
1658         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1659         {
1660                 if(STAT(CAMERA_SPECTATOR))
1661                 {
1662                         if(spectatee_status > 0)
1663                         {
1664                                 if(!autocvar_chase_active)
1665                                 {
1666                                         cvar_set("chase_active", "-2");
1667                                         goto skip_eventchase_death;
1668                                 }
1669                         }
1670                         else if(autocvar_chase_active == -2)
1671                                 cvar_set("chase_active", "0");
1672
1673                         if(autocvar_chase_active == -2)
1674                                 goto skip_eventchase_death;
1675                 }
1676                 else if(autocvar_chase_active == -2)
1677                         cvar_set("chase_active", "0");
1678
1679                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1680
1681                 float vehicle_viewdist = 0;
1682                 vector vehicle_viewofs = '0 0 0';
1683
1684                 if(vehicle_chase)
1685                 {
1686                         if(hud != HUD_BUMBLEBEE_GUN)
1687                         {
1688                                 Vehicle info = Vehicles_from(hud);
1689                                 vehicle_viewdist = info.height;
1690                                 vehicle_viewofs = info.view_ofs;
1691                         }
1692                 }
1693
1694                 if(WantEventchase(this))
1695                 {
1696                         vector current_view_origin_override = '0 0 0';
1697                         vector view_offset_override = '0 0 0';
1698                         float chase_distance_override = 0;
1699                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1700                         if(custom_eventchase)
1701                         {
1702                                 current_view_origin_override = M_ARGV(0, vector);
1703                                 view_offset_override = M_ARGV(1, vector);
1704                                 chase_distance_override = M_ARGV(0, float);
1705                         }
1706                         eventchase_running = true;
1707
1708                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1709                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1710                         if (custom_eventchase)
1711                                 current_view_origin = current_view_origin_override;
1712
1713                         // detect maximum viewoffset and use it
1714                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1715                         if(vehicle_chase)
1716                         {
1717                                 if(vehicle_viewofs)
1718                                         view_offset = vehicle_viewofs;
1719                                 else
1720                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1721                         }
1722                         if (custom_eventchase)
1723                                 view_offset = view_offset_override;
1724
1725                         if(view_offset)
1726                         {
1727                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1728                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1729                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1730                         }
1731
1732                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1733                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1734                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1735                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1736
1737                         // make the camera smooth back
1738                         float chase_distance = autocvar_cl_eventchase_distance;
1739                         if(vehicle_chase)
1740                         {
1741                                 if(vehicle_viewofs)
1742                                         chase_distance = vehicle_viewdist;
1743                                 else
1744                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1745                         }
1746                         if (custom_eventchase)
1747                                 chase_distance = chase_distance_override;
1748
1749                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1750                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1751                         else if(eventchase_current_distance != chase_distance)
1752                                 eventchase_current_distance = chase_distance;
1753
1754                         makevectors(view_angles);
1755
1756                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1757                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1758
1759                         // If the boxtrace fails, revert back to line tracing.
1760                         if(!local_player.viewloc)
1761                         if(trace_startsolid)
1762                         {
1763                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1764                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1765                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1766                         }
1767                         else { setproperty(VF_ORIGIN, trace_endpos); }
1768
1769                         if(!local_player.viewloc)
1770                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1771                 }
1772                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1773                 {
1774                         eventchase_running = false;
1775                         cvar_set("chase_active", "0");
1776                         eventchase_current_distance = 0; // start from 0 next time
1777                 }
1778         }
1779         // workaround for camera stuck between player's legs when using chase_active 1
1780         // because the engine stops updating the chase_active camera when the game ends
1781         else if(intermission)
1782         {
1783                 cvar_settemp("chase_active", "-1");
1784                 eventchase_current_distance = 0;
1785         }
1786
1787         LABEL(skip_eventchase_death);
1788
1789         // do lockview after event chase camera so that it still applies whenever necessary.
1790         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1791         {
1792                 setproperty(VF_ORIGIN, freeze_org);
1793                 setproperty(VF_ANGLES, freeze_ang);
1794         }
1795         else
1796         {
1797                 freeze_org = getpropertyvec(VF_ORIGIN);
1798                 freeze_ang = getpropertyvec(VF_ANGLES);
1799         }
1800
1801         WarpZone_FixView();
1802         //WarpZone_FixPMove();
1803
1804         vector ov_org = '0 0 0';
1805         vector ov_mid = '0 0 0';
1806         vector ov_worldmin = '0 0 0';
1807         vector ov_worldmax = '0 0 0';
1808         if(autocvar_cl_orthoview)
1809         {
1810                 ov_worldmin = mi_picmin;
1811                 ov_worldmax = mi_picmax;
1812
1813                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1814                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1815                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1816
1817                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1818                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1819
1820                 float ov_nearest = vlen(ov_org - vec3(
1821                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1822                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1823                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1824                 ));
1825
1826                 float ov_furthest = 0;
1827                 float dist = 0;
1828
1829                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1830                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1831                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1832                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1833                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1834                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1835                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1836                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1837
1838                 if(!ov_enabled)
1839                 {
1840                         oldr_nearclip = cvar("r_nearclip");
1841                         oldr_farclip_base = cvar("r_farclip_base");
1842                         oldr_farclip_world = cvar("r_farclip_world");
1843                         oldr_novis = cvar("r_novis");
1844                         oldr_useportalculling = cvar("r_useportalculling");
1845                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1846                 }
1847
1848                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1849                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1850                 cvar_settemp("r_farclip_world", "0");
1851                 cvar_settemp("r_novis", "1");
1852                 cvar_settemp("r_useportalculling", "0");
1853                 cvar_settemp("r_useinfinitefarclip", "0");
1854
1855                 setproperty(VF_ORIGIN, ov_org);
1856                 setproperty(VF_ANGLES, '90 0 0');
1857
1858                 ov_enabled = true;
1859
1860                 #if 0
1861                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1862                         vtos(ov_org),
1863                         vtos(getpropertyvec(VF_ANGLES)),
1864                         ov_distance,
1865                         ov_nearest,
1866                         ov_furthest);
1867                 #endif
1868         }
1869         else
1870         {
1871                 if(ov_enabled)
1872                 {
1873                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1874                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1875                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1876                         cvar_set("r_novis", ftos(oldr_novis));
1877                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1878                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1879                 }
1880                 ov_enabled = false;
1881         }
1882
1883         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1884         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1885         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1886                 viewmodel_draw(viewmodels[slot]);
1887
1888         // Render the Scene
1889         view_origin = getpropertyvec(VF_ORIGIN);
1890         view_angles = getpropertyvec(VF_ANGLES);
1891         makevectors(view_angles);
1892         view_forward = v_forward;
1893         view_right = v_right;
1894         view_up = v_up;
1895
1896 #ifdef BLURTEST
1897         if(time > blurtest_time0 && time < blurtest_time1)
1898         {
1899                 float r, t;
1900
1901                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1902                 r = t * blurtest_radius;
1903                 f = 1 / (t ** blurtest_power) - 1;
1904
1905                 cvar_set("r_glsl_postprocess", "1");
1906                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1907         }
1908         else
1909         {
1910                 cvar_set("r_glsl_postprocess", "0");
1911                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1912         }
1913 #endif
1914
1915         TargetMusic_Advance();
1916         Fog_Force();
1917         fpscounter_update();
1918
1919         if(drawtime == 0)
1920                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1921         else
1922                 drawframetime = bound(0.000001, time - drawtime, 1);
1923         drawtime = time;
1924
1925         // watch for gametype changes here...
1926         // in ParseStuffCMD the cmd isn't executed yet :/
1927         // might even be better to add the gametype to TE_CSQC_INIT...?
1928         if(!postinit)
1929                 PostInit();
1930
1931         if(intermission && !intermission_time)
1932                 intermission_time = time;
1933
1934         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1935         {
1936                 if(calledhooks & HOOK_START)
1937                 {
1938                         localcmd("\ncl_hook_gameend\n");
1939                         calledhooks |= HOOK_END;
1940                 }
1941         }
1942
1943         Announcer();
1944
1945         fov = autocvar_fov;
1946         if(fov <= 59.5)
1947         {
1948                 if(!zoomscript_caught)
1949                 {
1950                         localcmd("+button9\n");
1951                         zoomscript_caught = 1;
1952                 }
1953         }
1954         else
1955         {
1956                 if(zoomscript_caught)
1957                 {
1958                         localcmd("-button9\n");
1959                         zoomscript_caught = 0;
1960                 }
1961         }
1962
1963         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1964
1965         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1966         {
1967                 entity wepent = viewmodels[slot];
1968
1969                 if(wepent.last_switchweapon != wepent.switchweapon)
1970                 {
1971                         weapontime = time;
1972                         wepent.last_switchweapon = wepent.switchweapon;
1973                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1974                         {
1975                                 localcmd("-zoom\n");
1976                                 button_zoom = false;
1977                         }
1978                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1979                         {
1980                                 localcmd("-fire\n");
1981                                 localcmd("-fire2\n");
1982                                 button_attack2 = false;
1983                         }
1984                 }
1985                 if(wepent.last_activeweapon != wepent.activeweapon)
1986                 {
1987                         wepent.last_activeweapon = wepent.activeweapon;
1988
1989                         e = wepent.activeweapon;
1990                         if(e.netname != "")
1991                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1992                         else if(slot == 0)
1993                                 localcmd("\ncl_hook_activeweapon none\n");
1994                 }
1995         }
1996
1997         // ALWAYS Clear Current Scene First
1998         clearscene();
1999
2000         setproperty(VF_ORIGIN, view_origin);
2001         setproperty(VF_ANGLES, view_angles);
2002
2003         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2004         setproperty(VF_SIZE, vf_size);
2005         setproperty(VF_MIN, vf_min);
2006
2007         // Assign Standard Viewflags
2008         // Draw the World (and sky)
2009         setproperty(VF_DRAWWORLD, 1);
2010
2011         // Set the console size vars
2012         vid_conwidth = autocvar_vid_conwidth;
2013         vid_conheight = autocvar_vid_conheight;
2014         vid_pixelheight = autocvar_vid_pixelheight;
2015
2016         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2017         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2018         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2019
2020         if(camera_active) // Camera for demo playback
2021         {
2022                 if(autocvar_camera_enable)
2023                         CSQC_Demo_Camera();
2024                 else
2025                 {
2026                         cvar_set("chase_active", ftos(chase_active_backup));
2027                         cvar_set("cl_demo_mousegrab", "0");
2028                         camera_active = false;
2029                 }
2030         }
2031         else
2032         {
2033 #ifdef CAMERATEST
2034                 if(autocvar_camera_enable)
2035 #else
2036                 if(autocvar_camera_enable && isdemo())
2037 #endif
2038                 {
2039                         // Enable required Darkplaces cvars
2040                         chase_active_backup = autocvar_chase_active;
2041                         cvar_set("chase_active", "2");
2042                         cvar_set("cl_demo_mousegrab", "1");
2043                         camera_active = true;
2044                         camera_mode = false;
2045                 }
2046         }
2047
2048         // Draw the Crosshair
2049         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2050
2051         // Draw the Engine Status Bar (the default Quake HUD)
2052         setproperty(VF_DRAWENGINESBAR, 0);
2053
2054         // Update the mouse position
2055         /*
2056            mousepos_x = vid_conwidth;
2057            mousepos_y = vid_conheight;
2058            mousepos = mousepos*0.5 + getmousepos();
2059          */
2060
2061         IL_EACH(g_drawables, it.draw, it.draw(it));
2062
2063         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2064         renderscene();
2065
2066         // now switch to 2D drawing mode by calling a 2D drawing function
2067         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2068         // next R_RenderScene call
2069         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2070
2071         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2072         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2073         {
2074                 // apply night vision effect
2075                 vector tc_00, tc_01, tc_10, tc_11;
2076                 vector rgb = '0 0 0';
2077
2078                 if(!nightvision_noise)
2079                 {
2080                         nightvision_noise = new(nightvision_noise);
2081                 }
2082                 if(!nightvision_noise2)
2083                 {
2084                         nightvision_noise2 = new(nightvision_noise2);
2085                 }
2086
2087                 // color tint in yellow
2088                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2089
2090                 // draw BG
2091                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2092                 rgb = '1 1 1';
2093                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2094                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2095                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2096                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2097                 tc_11 = tc_01 + tc_10 - tc_00;
2098                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2099                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2100                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2101                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2102                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2103                 R_EndPolygon();
2104
2105                 // draw FG
2106                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2107                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2108                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2109                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2110                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2111                 tc_11 = tc_01 + tc_10 - tc_00;
2112                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2113                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2114                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2115                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2116                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2117                 R_EndPolygon();
2118         }
2119
2120         if(autocvar_cl_reticle)
2121         {
2122                 string reticle_image = string_null;
2123                 bool wep_zoomed = false;
2124                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2125                 {
2126                         entity wepe = viewmodels[slot];
2127                         Weapon wep = wepe.activeweapon;
2128                         if(wep != WEP_Null && wep.wr_zoom)
2129                         {
2130                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2131                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2132                                         reticle_image = wep.w_reticle;
2133                                 wep_zoomed += do_zoom;
2134                         }
2135                 }
2136                 // Draw the aiming reticle for weapons that use it
2137                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2138                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2139                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2140                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2141                 {
2142                         // no zoom reticle while dead
2143                         reticle_type = 0;
2144                 }
2145                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2146                 {
2147                         if(reticle_image) { reticle_type = 2; }
2148                         else { reticle_type = 0; }
2149                 }
2150                 else if(button_zoom || zoomscript_caught)
2151                 {
2152                         // normal zoom
2153                         reticle_type = 1;
2154                 }
2155
2156                 if(reticle_type)
2157                 {
2158                         if(autocvar_cl_reticle_stretch)
2159                         {
2160                                 reticle_size.x = vid_conwidth;
2161                                 reticle_size.y = vid_conheight;
2162                                 reticle_pos.x = 0;
2163                                 reticle_pos.y = 0;
2164                         }
2165                         else
2166                         {
2167                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2168                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2169                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2170                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2171                         }
2172
2173                         if(zoomscript_caught)
2174                                 f = 1;
2175                         else
2176                                 f = current_zoomfraction;
2177
2178                         if(f)
2179                         {
2180                                 switch(reticle_type)
2181                                 {
2182                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2183                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2184                                 }
2185                         }
2186                 }
2187         }
2188         else
2189         {
2190                 if(reticle_type != 0) { reticle_type = 0; }
2191         }
2192
2193
2194         // improved polyblend
2195         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2196         {
2197                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2198                 vector liquidcolor;
2199
2200                 switch(pointcontents(view_origin))
2201                 {
2202                         case CONTENT_WATER:
2203                                 liquidalpha = autocvar_hud_contents_water_alpha;
2204                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2205                                 incontent = 1;
2206                                 break;
2207
2208                         case CONTENT_LAVA:
2209                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2210                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2211                                 incontent = 1;
2212                                 break;
2213
2214                         case CONTENT_SLIME:
2215                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2216                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2217                                 incontent = 1;
2218                                 break;
2219
2220                         default:
2221                                 liquidalpha = 0;
2222                                 liquidcolor = '0 0 0';
2223                                 incontent = 0;
2224                                 break;
2225                 }
2226
2227                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2228                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2229                         contentfadetime = autocvar_hud_contents_fadeintime;
2230                         liquidalpha_prev = liquidalpha;
2231                         liquidcolor_prev = liquidcolor;
2232                 }
2233                 else
2234                         contentfadetime = autocvar_hud_contents_fadeouttime;
2235
2236                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2237                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2238
2239                 if(contentavgalpha)
2240                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2241
2242                 if(autocvar_hud_postprocessing)
2243                 {
2244                         if(autocvar_hud_contents_blur && contentavgalpha)
2245                         {
2246                                 content_blurpostprocess.x = 1;
2247                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2248                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2249                         }
2250                         else
2251                         {
2252                                 content_blurpostprocess.x = 0;
2253                                 content_blurpostprocess.y = 0;
2254                                 content_blurpostprocess.z = 0;
2255                         }
2256                 }
2257         }
2258
2259         if(autocvar_hud_damage && !STAT(FROZEN))
2260         {
2261                 splash_size.x = max(vid_conwidth, vid_conheight);
2262                 splash_size.y = max(vid_conwidth, vid_conheight);
2263                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2264                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2265
2266                 float myhealth_flash_temp;
2267                 myhealth = STAT(HEALTH);
2268
2269                 // fade out
2270                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2271                 // add new damage
2272                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2273
2274                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2275                 pain_threshold = autocvar_hud_damage_pain_threshold;
2276                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2277                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2278
2279                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2280                 {
2281                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2282                 }
2283
2284                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2285
2286                 if(myhealth_prev < 1)
2287                 {
2288                         if(myhealth >= 1)
2289                         {
2290                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2291                                 myhealth_flash_temp = 0;
2292                         }
2293                         else
2294                         {
2295                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2296                         }
2297                 }
2298
2299                 if(spectatee_status == -1 || intermission)
2300                 {
2301                         myhealth_flash = 0; // observing, or match ended
2302                         myhealth_flash_temp = 0;
2303                 }
2304
2305                 myhealth_prev = myhealth;
2306
2307                 // IDEA: change damage color/picture based on player model for robot/alien species?
2308                 // pro: matches model better
2309                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2310                 // maybe different reddish pics?
2311                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2312                 {
2313                         if(autocvar_cl_gentle_damage == 2)
2314                         {
2315                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2316                                         myhealth_gentlergb = randomvec();
2317                         }
2318                         else
2319                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2320
2321                         if(myhealth_flash_temp > 0)
2322                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2323                 }
2324                 else if(myhealth_flash_temp > 0)
2325                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2326
2327                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2328                 {
2329                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2330                         {
2331                                 damage_blurpostprocess.x = 1;
2332                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2333                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2334                         }
2335                         else
2336                         {
2337                                 damage_blurpostprocess.x = 0;
2338                                 damage_blurpostprocess.y = 0;
2339                                 damage_blurpostprocess.z = 0;
2340                         }
2341                 }
2342         }
2343
2344         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2345         float e2 = (autocvar_hud_powerup != 0);
2346         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2347         {
2348                 // enable or disable rendering types if they are used or not
2349                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2350                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2351
2352                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2353                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2354                 {
2355                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2356                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2357                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2358                         {
2359                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2360                                 old_blurradius = blurradius;
2361                                 old_bluralpha = bluralpha;
2362                         }
2363                 }
2364                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2365                 {
2366                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2367                         old_blurradius = 0;
2368                         old_bluralpha = 0;
2369                 }
2370
2371                 // edge detection postprocess handling done second (used by hud_powerup)
2372                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2373                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2374                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2375
2376                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2377
2378                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2379                 {
2380                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2381                         {
2382                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2383                                 old_sharpen_intensity = sharpen_intensity;
2384                         }
2385                 }
2386                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2387                 {
2388                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2389                         old_sharpen_intensity = 0;
2390                 }
2391
2392                 if(cvar("r_glsl_postprocess") == 0)
2393                         cvar_set("r_glsl_postprocess", "2");
2394         }
2395         else if(cvar("r_glsl_postprocess") == 2)
2396                 cvar_set("r_glsl_postprocess", "0");
2397
2398         /*if(gametype == MAPINFO_TYPE_CTF)
2399           {
2400           ctf_view();
2401           } else */
2402
2403         // draw 2D entities
2404         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2405         Draw_ShowNames_All();
2406 #if ENABLE_DEBUGDRAW
2407         Debug_Draw();
2408 #endif
2409
2410         scoreboard_active = Scoreboard_WouldDraw();
2411
2412         HUD_Draw(this); // this parameter for deep vehicle function
2413
2414         if(NextFrameCommand)
2415         {
2416                 localcmd("\n", NextFrameCommand, "\n");
2417                 NextFrameCommand = string_null;
2418         }
2419
2420         // we must do this check AFTER a frame was rendered, or it won't work
2421         if(cs_project_is_b0rked == 0)
2422         {
2423                 string w0, h0;
2424                 w0 = ftos(autocvar_vid_conwidth);
2425                 h0 = ftos(autocvar_vid_conheight);
2426                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2427                 //setproperty(VF_FOV, '90 90 0');
2428                 setproperty(VF_ORIGIN, '0 0 0');
2429                 setproperty(VF_ANGLES, '0 0 0');
2430                 setproperty(VF_PERSPECTIVE, 1);
2431                 makevectors('0 0 0');
2432                 vector v1, v2;
2433                 cvar_set("vid_conwidth", "800");
2434                 cvar_set("vid_conheight", "600");
2435                 v1 = cs_project(v_forward);
2436                 cvar_set("vid_conwidth", "640");
2437                 cvar_set("vid_conheight", "480");
2438                 v2 = cs_project(v_forward);
2439                 if(v1 == v2)
2440                         cs_project_is_b0rked = 1;
2441                 else
2442                         cs_project_is_b0rked = -1;
2443                 cvar_set("vid_conwidth", w0);
2444                 cvar_set("vid_conheight", h0);
2445         }
2446
2447         if(autocvar__hud_configure)
2448                 HUD_Panel_Mouse();
2449         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2450                 HUD_Minigame_Mouse();
2451         else if(QuickMenu_IsOpened())
2452                 QuickMenu_Mouse();
2453         else if(local_player.viewloc && (local_player.viewloc.spawnflags & VIEWLOC_FREEAIM))
2454                 ViewLocation_Mouse(); // NOTE: doesn't use cursormode
2455         else
2456                 HUD_Radar_Mouse();
2457
2458         cl_notice_run();
2459         unpause_update();
2460         Net_Flush();
2461
2462         // let's reset the view back to normal for the end
2463         setproperty(VF_MIN, '0 0 0');
2464         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2465
2466         IL_ENDFRAME();
2467 }
2468
2469
2470 // following vectors must be global to allow seamless switching between camera modes
2471 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2472 void CSQC_Demo_Camera()
2473 {
2474         float speed, attenuation, dimensions;
2475         vector tmp, delta;
2476
2477         if( autocvar_camera_reset || !camera_mode )
2478         {
2479                 camera_offset = '0 0 0';
2480                 current_angles = '0 0 0';
2481                 camera_direction = '0 0 0';
2482                 camera_offset.z += 30;
2483                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2484                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2485                 current_origin = view_origin;
2486                 current_camera_offset  = camera_offset;
2487                 cvar_set("camera_reset", "0");
2488                 camera_mode = CAMERA_CHASE;
2489         }
2490
2491         // Camera angles
2492         if( camera_roll )
2493                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2494
2495         if(autocvar_camera_look_player)
2496         {
2497                 vector dir;
2498                 float n;
2499
2500                 dir = normalize(view_origin - current_position);
2501                 n = mouse_angles.z;
2502                 mouse_angles = vectoangles(dir);
2503                 mouse_angles.x = mouse_angles.x * -1;
2504                 mouse_angles.z = n;
2505         }
2506         else
2507         {
2508                 tmp = getmousepos() * 0.1;
2509                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2510                 {
2511                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2512                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2513                 }
2514         }
2515
2516         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2517         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2518         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2519         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2520
2521         // Fix difference when angles don't have the same sign
2522         delta = '0 0 0';
2523         if(mouse_angles.y < -60 && current_angles.y > 60)
2524                 delta = '0 360 0';
2525         if(mouse_angles.y > 60 && current_angles.y < -60)
2526                 delta = '0 -360 0';
2527
2528         if(autocvar_camera_look_player)
2529                 attenuation = autocvar_camera_look_attenuation;
2530         else
2531                 attenuation = autocvar_camera_speed_attenuation;
2532
2533         attenuation = 1 / max(1, attenuation);
2534         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2535
2536         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2537         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2538         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2539         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2540
2541         // Camera position
2542         tmp = '0 0 0';
2543         dimensions = 0;
2544
2545         if( camera_direction.x )
2546         {
2547                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2548                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2549                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2550                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2551                 ++dimensions;
2552         }
2553
2554         if( camera_direction.y )
2555         {
2556                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2557                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2558                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2559                 ++dimensions;
2560         }
2561
2562         if( camera_direction.z )
2563         {
2564                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2565                 ++dimensions;
2566         }
2567
2568         if(autocvar_camera_free)
2569                 speed = autocvar_camera_speed_free;
2570         else
2571                 speed = autocvar_camera_speed_chase;
2572
2573         if(dimensions)
2574         {
2575                 speed = speed * sqrt(1 / dimensions);
2576                 camera_offset += tmp * speed;
2577         }
2578
2579         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2580
2581         // Camera modes
2582         if( autocvar_camera_free )
2583         {
2584                 if ( camera_mode == CAMERA_CHASE )
2585                 {
2586                         current_camera_offset = current_origin + current_camera_offset;
2587                         camera_offset = current_origin + camera_offset;
2588                 }
2589
2590                 camera_mode = CAMERA_FREE;
2591                 current_position = current_camera_offset;
2592         }
2593         else
2594         {
2595                 if ( camera_mode == CAMERA_FREE )
2596                 {
2597                         current_origin = view_origin;
2598                         camera_offset = camera_offset - current_origin;
2599                         current_camera_offset = current_camera_offset - current_origin;
2600                 }
2601
2602                 camera_mode = CAMERA_CHASE;
2603
2604                 if(autocvar_camera_chase_smoothly)
2605                         current_origin += (view_origin - current_origin) * attenuation;
2606                 else
2607                         current_origin = view_origin;
2608
2609                 current_position = current_origin + current_camera_offset;
2610         }
2611
2612         setproperty(VF_ANGLES, current_angles);
2613         setproperty(VF_ORIGIN, current_position);
2614 }