qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "main.qh"
   8 #include "mapvoting.qh"
   9 #include "shownames.qh"
  10 #include "hud/panel/scoreboard.qh"
  11 #include "hud/panel/quickmenu.qh"
  12
  13 #include <client/mutators/_mod.qh>
  14
  15 #include <common/animdecide.qh>
  16 #include <common/deathtypes/all.qh>
  17 #include <common/ent_cs.qh>
  18 #include <common/anim.qh>
  19 #include <common/constants.qh>
  20 #include <common/net_linked.qh>
  21 #include <common/net_notice.qh>
  22 #include <common/debug.qh>
  23 #include <common/mapinfo.qh>
  24 #include <common/gamemodes/_mod.qh>
  25 #include <common/physics/player.qh>
  26 #include <common/stats.qh>
  27 #include <common/mapobjects/target/music.qh>
  28 #include <common/teams.qh>
  29 #include <common/wepent.qh>
  30
  31 #include <common/weapons/weapon/tuba.qh>
  32
  33 #include <common/vehicles/all.qh>
  34 #include <common/weapons/_all.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha = 1;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  81 MACRO_END
  82
  83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  84         float __f = 0; lowpass(value, frac, ref_store, __f); \
  85         ret = (value) - __f; \
  86 MACRO_END
  87
  88 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  90         ret = (value) - __f; \
  91 MACRO_END
  92
  93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99         highpass(value.x, frac, ref_store.x, ref_out.x); \
 100         highpass(value.y, frac, ref_store.y, ref_out.y); \
 101 MACRO_END
 102
 103 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 104         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 105         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 106 MACRO_END
 107
 108 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 112 MACRO_END
 113
 114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 vector forward, right, up;
 137                 MAKE_VECTORS(view_angles, forward, right, up);
 138                 vel.x = view.velocity * forward;
 139                 vel.y = view.velocity * right * -1;
 140                 vel.z = view.velocity * up;
 141         }
 142
 143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 146
 147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 148         lowpass3(vel, frac, vel_average, gunorg);
 149
 150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 151
 152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 154         frac = avg_factor(autocvar_cl_followmodel_highpass);
 155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 158
 159         if (autocvar_cl_followmodel_velocity_absolute)
 160         {
 161                 vector fixed_gunorg;
 162                 vector forward, right, up;
 163                 MAKE_VECTORS(view_angles, forward, right, up);
 164                 fixed_gunorg.x = gunorg * forward;
 165                 fixed_gunorg.y = gunorg * right * -1;
 166                 fixed_gunorg.z = gunorg * up;
 167                 gunorg = fixed_gunorg;
 168         }
 169
 170         cl_followmodel_ofs = gunorg;
 171         cl_followmodel_time = time;
 172 }
 173
 174 vector leanmodel_ofs(entity view)
 175 {
 176         float frac;
 177         vector gunangles = '0 0 0';
 178         static vector gunangles_prev = '0 0 0';
 179         static vector gunangles_highpass = '0 0 0';
 180         static vector gunangles_adjustment_highpass;
 181         static vector gunangles_adjustment_lowpass;
 182
 183         if (view.csqcmodel_teleported)
 184                 gunangles_prev = view_angles;
 185
 186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 187         gunangles_highpass += gunangles_prev;
 188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 193         gunangles_prev = view_angles;
 194         gunangles_highpass -= gunangles_prev;
 195
 196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 206
 207         return gunangles;
 208 }
 209
 210 vector bobmodel_ofs(entity view)
 211 {
 212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 213         static bool oldonground;
 214         static float hitgroundtime;
 215         if (clonground)
 216         {
 217                 float f = time; // cl.movecmd[0].time
 218                 if (!oldonground)
 219                         hitgroundtime = f;
 220         }
 221         oldonground = clonground;
 222
 223         // calculate for swinging gun model
 224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 225         vector gunorg = '0 0 0';
 226         static float bobmodel_scale = 0;
 227         static float time_ofs = 0; // makes the effect always restart in the same way
 228         if (clonground)
 229         {
 230                 if (time - hitgroundtime > 0.05)
 231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 232         }
 233         else
 234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 235
 236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 237         if (bobmodel_scale && xyspeed)
 238         {
 239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 243         }
 244         else
 245                 time_ofs = time;
 246
 247         return gunorg;
 248 }
 249
 250 void viewmodel_animate(entity this)
 251 {
 252         if (autocvar_chase_active) return;
 253         if (STAT(HEALTH) <= 0) return;
 254
 255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 256
 257         if (autocvar_cl_followmodel)
 258         {
 259                 calc_followmodel_ofs(view);
 260                 this.origin += cl_followmodel_ofs;
 261         }
 262
 263         if (autocvar_cl_leanmodel)
 264                 this.angles += leanmodel_ofs(view);
 265
 266         // vertical view bobbing code
 267         // TODO: cl_bob
 268
 269         // horizontal view bobbing code
 270         // TODO: cl_bob2
 271
 272         // fall bobbing code
 273         // causes the view to swing down and back up when touching the ground
 274         // TODO: cl_bobfall
 275
 276         // gun model bobbing code
 277         if (autocvar_cl_bobmodel)
 278                 this.origin += bobmodel_ofs(view);
 279 }
 280
 281 .vector viewmodel_origin, viewmodel_angles;
 282 .float weapon_nextthink;
 283 .float weapon_eta_last;
 284 .float weapon_switchdelay;
 285
 286 .string name_last;
 287
 288 void viewmodel_draw(entity this)
 289 {
 290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 291                 return;
 292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 293         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 294         int wepskin = this.m_skin;
 295         bool invehicle = player_localentnum > maxclients;
 296         if (invehicle) a = -1;
 297         Weapon wep = this.activeweapon;
 298         int c = entcs_GetClientColors(current_player);
 299         vector g = weaponentity_glowmod(wep, NULL, c, this);
 300         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 301         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 302                 | EF_NODEPTHTEST)
 303                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 304         for (entity e = this; e; e = e.weaponchild)
 305         {
 306                 e.drawmask = mask;
 307                 e.alpha = a;
 308                 e.skin = wepskin;
 309                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 310                 e.glowmod = g;
 311                 e.csqcmodel_effects = fx;
 312                 CSQCModel_Effects_Apply(e);
 313         }
 314         if(a >= 0)
 315         {
 316                 string name = wep.mdl;
 317                 string newname = wep.wr_viewmodel(wep, this);
 318                 if(newname)
 319                         name = newname;
 320                 bool swap = name != this.name_last;
 321                 // if (swap)
 322                 {
 323                         this.name_last = name;
 324                         CL_WeaponEntity_SetModel(this, name, swap);
 325                         this.viewmodel_origin = this.origin;
 326                         this.viewmodel_angles = this.angles;
 327                 }
 328                 anim_update(this);
 329                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 330                         anim_set(this, this.anim_idle, true, false, false);
 331         }
 332         float f = 0; // 0..1; 0: fully active
 333         float rate = STAT(WEAPONRATEFACTOR);
 334         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 335         if (eta <= 0) f = this.weapon_eta_last;
 336         else switch (this.state)
 337         {
 338                 case WS_RAISE:
 339                 {
 340                         f = eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_DROP:
 344                 {
 345                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 346                         break;
 347                 }
 348                 case WS_CLEAR:
 349                 {
 350                         f = 1;
 351                         break;
 352                 }
 353         }
 354         this.weapon_eta_last = f;
 355         this.origin = this.viewmodel_origin;
 356         this.angles = this.viewmodel_angles;
 357         this.angles_x = (-90 * f * f);
 358         viewmodel_animate(this);
 359         MUTATOR_CALLHOOK(DrawViewModel, this);
 360         setorigin(this, this.origin);
 361 }
 362
 363 STATIC_INIT(viewmodel) {
 364     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         viewmodels[slot] = new(viewmodel);
 366 }
 367
 368 float showfps_prevfps;
 369 float showfps_prevfps_time;
 370 int showfps_framecounter;
 371
 372 void fpscounter_update()
 373 {
 374         if(!STAT(SHOWFPS))
 375                 return;
 376
 377         float currentTime = gettime(GETTIME_REALTIME);
 378         showfps_framecounter += 1;
 379         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 380         {
 381                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 382                 showfps_framecounter = 0;
 383                 showfps_prevfps_time = currentTime;
 384
 385                 int channel = MSG_C2S;
 386                 WriteHeader(channel, fpsreport);
 387                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 388         }
 389 }
 390
 391 STATIC_INIT(fpscounter_init)
 392 {
 393         float currentTime = gettime(GETTIME_REALTIME);
 394         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 395 }
 396
 397 float avgspeed;
 398 vector GetCurrentFov(float fov)
 399 {
 400         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 401         float velocityzoom, curspeed;
 402         vector v;
 403
 404         zoomsensitivity = autocvar_cl_zoomsensitivity;
 405         zoomfactor = autocvar_cl_zoomfactor;
 406         if(zoomfactor < 1 || zoomfactor > 30)
 407                 zoomfactor = 2.5;
 408         zoomspeed = autocvar_cl_zoomspeed;
 409         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 410                 zoomspeed = 3.5;
 411
 412         zoomdir = button_zoom;
 413
 414         if(hud == HUD_NORMAL && !spectatee_status)
 415         {
 416                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 417                 {
 418                         entity wepent = viewmodels[slot];
 419                         if(wepent.switchweapon != wepent.activeweapon)
 420                                 continue;
 421                         Weapon wep = wepent.activeweapon;
 422                         if(wep != WEP_Null && wep.wr_zoomdir)
 423                         {
 424                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 425                                 zoomdir += do_zoom;
 426                         }
 427                 }
 428         }
 429         if(spectatee_status > 0 || isdemo())
 430         {
 431                 if(spectatorbutton_zoom)
 432                 {
 433                         if(zoomdir)
 434                                 zoomdir = 0;
 435                         else
 436                                 zoomdir = 1;
 437                 }
 438                 // fteqcc failed twice here already, don't optimize this
 439         }
 440
 441         if(zoomdir) { zoomin_effect = 0; }
 442
 443         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 444         {
 445                 current_viewzoom = 1;
 446         }
 447         else if (camera_active)
 448         {
 449                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 450         }
 451         else if(autocvar_cl_spawnzoom && zoomin_effect)
 452         {
 453                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 454
 455                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 456                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 457                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 458         }
 459         else
 460         {
 461                 if(zoomspeed < 0) // instant zoom
 462                 {
 463                         if(zoomdir)
 464                                 current_viewzoom = 1 / zoomfactor;
 465                         else
 466                                 current_viewzoom = 1;
 467                 }
 468                 else
 469                 {
 470                         if(zoomdir)
 471                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 472                         else
 473                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 474                 }
 475         }
 476
 477         if(almost_equals(current_viewzoom, 1))
 478                 current_zoomfraction = 0;
 479         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 480                 current_zoomfraction = 1;
 481         else
 482                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 483
 484         if(zoomsensitivity < 1)
 485                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 486         else
 487                 setsensitivityscale(1);
 488
 489         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type && !autocvar_cl_lockview) // _type = 0 disables velocity zoom too
 490         {
 491                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 492                         curspeed = 0;
 493                 else
 494                 {
 495                         vector forward, right, up;
 496                         MAKE_VECTORS(view_angles, forward, right, up);
 497                         v = pmove_vel;
 498                         if(csqcplayer)
 499                                 v = csqcplayer.velocity;
 500
 501                         switch(autocvar_cl_velocityzoom_type)
 502                         {
 503                                 case 3: curspeed = max(0, forward * v); break;
 504                                 case 2: curspeed = (forward * v); break;
 505                                 case 1: default: curspeed = vlen(v); break;
 506                         }
 507                 }
 508
 509                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 510                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 511                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 512
 513                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 514         }
 515         else
 516                 velocityzoom = 1;
 517
 518         float frustumx, frustumy, fovx, fovy;
 519         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 520         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 521         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 522         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 523
 524         return '1 0 0' * fovx + '0 1 0' * fovy;
 525 }
 526
 527 vector GetViewLocationFOV(float fov)
 528 {
 529         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 530         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 531         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 532         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 533         return '1 0 0' * fovx + '0 1 0' * fovy;
 534 }
 535
 536 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 537 {
 538         float fovx, fovy;
 539         float width = (ov_worldmax.x - ov_worldmin.x);
 540         float height = (ov_worldmax.y - ov_worldmin.y);
 541         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 542         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 543         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 544         return '1 0 0' * fovx + '0 1 0' * fovy;
 545 }
 546
 547 // this function must match W_SetupShot!
 548
 549 bool minigame_wasactive;
 550
 551 float camera_mode;
 552 const float CAMERA_FREE = 1;
 553 const float CAMERA_CHASE = 2;
 554 string NextFrameCommand;
 555
 556 vector freeze_org, freeze_ang;
 557 entity nightvision_noise, nightvision_noise2;
 558
 559 float myhealth, myhealth_prev;
 560 float myhealth_flash;
 561
 562 float old_blurradius, old_bluralpha;
 563 float old_sharpen_intensity;
 564
 565 vector myhealth_gentlergb;
 566
 567 float contentavgalpha, liquidalpha_prev;
 568 vector liquidcolor_prev;
 569
 570 float eventchase_current_distance;
 571 float eventchase_running;
 572 int WantEventchase(entity this, bool want_vehiclechase)
 573 {
 574         if(autocvar_cl_orthoview)
 575                 return 0;
 576         if(STAT(GAME_STOPPED) || intermission)
 577                 return 1;
 578         if(this.viewloc)
 579                 return 1;
 580         if(spectatee_status >= 0)
 581         {
 582                 if(want_vehiclechase)
 583                         return 1;
 584                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 585                         return 1;
 586                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 587                         return 1;
 588                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 589                 {
 590                         if(autocvar_cl_eventchase_death == 2)
 591                         {
 592                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 593                                 if(this.velocity == '0 0 0' || eventchase_running)
 594                                         return 1;
 595                         }
 596                         else return 1;
 597                 }
 598                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 599                 {
 600                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 601                                 return 1;
 602                         else if (eventchase_running)
 603                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 604                 }
 605         }
 606         return 0;
 607 }
 608
 609 void View_EventChase(entity this)
 610 {
 611         // event chase camera
 612         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
 613         {
 614                 if(STAT(CAMERA_SPECTATOR))
 615                 {
 616                         if(spectatee_status > 0)
 617                         {
 618                                 if(!autocvar_chase_active)
 619                                 {
 620                                         cvar_set("chase_active", "-2");
 621                                         return;
 622                                 }
 623                         }
 624                         else if(autocvar_chase_active == -2)
 625                                 cvar_set("chase_active", "0");
 626
 627                         if(autocvar_chase_active == -2)
 628                                 return;
 629                 }
 630                 else if(autocvar_chase_active == -2)
 631                         cvar_set("chase_active", "0");
 632
 633                 bool vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
 634
 635                 float vehicle_viewdist = 0;
 636                 vector vehicle_viewofs = '0 0 0';
 637
 638                 if(vehicle_chase)
 639                 {
 640                         if(hud != HUD_BUMBLEBEE_GUN)
 641                         {
 642                                 Vehicle info = REGISTRY_GET(Vehicles, hud);
 643                                 vehicle_viewdist = info.height;
 644                                 vehicle_viewofs = info.view_ofs;
 645                                 if(vehicle_viewdist < 0) // when set below 0, this vehicle doesn't use third person view (gunner slots)
 646                                         vehicle_chase = false;
 647                         }
 648                         else
 649                                 vehicle_chase = false;
 650                 }
 651
 652                 int eventchase = WantEventchase(this, vehicle_chase);
 653                 if (eventchase)
 654                 {
 655                         vector current_view_origin_override = '0 0 0';
 656                         vector view_offset_override = '0 0 0';
 657                         float chase_distance_override = 0;
 658                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
 659                         if(custom_eventchase)
 660                         {
 661                                 current_view_origin_override = M_ARGV(0, vector);
 662                                 view_offset_override = M_ARGV(1, vector);
 663                                 chase_distance_override = M_ARGV(0, float);
 664                         }
 665                         eventchase_running = true;
 666
 667                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
 668                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
 669                         if (custom_eventchase)
 670                                 current_view_origin = current_view_origin_override;
 671
 672                         // detect maximum viewoffset and use it
 673                         vector view_offset = autocvar_cl_eventchase_viewoffset;
 674                         if(vehicle_chase)
 675                         {
 676                                 if(vehicle_viewofs)
 677                                         view_offset = vehicle_viewofs;
 678                                 else
 679                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
 680                         }
 681                         if (custom_eventchase)
 682                                 view_offset = view_offset_override;
 683
 684                         if(view_offset)
 685                         {
 686                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
 687                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
 688                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
 689                         }
 690
 691                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
 692                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
 693                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
 694                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
 695
 696                         // make the camera smooth back
 697                         float chase_distance = autocvar_cl_eventchase_distance;
 698                         if(vehicle_chase)
 699                         {
 700                                 if(vehicle_viewofs)
 701                                         chase_distance = vehicle_viewdist;
 702                                 else
 703                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
 704                         }
 705                         if (custom_eventchase)
 706                                 chase_distance = chase_distance_override;
 707
 708                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
 709                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
 710                         else if(eventchase_current_distance != chase_distance)
 711                                 eventchase_current_distance = chase_distance;
 712
 713                         vector forward, right, up;
 714                         MAKE_VECTORS(view_angles, forward, right, up);
 715
 716                         vector eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 717                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
 718
 719                         // If the boxtrace fails, revert back to line tracing.
 720                         if(!this.viewloc)
 721                         if(trace_startsolid)
 722                         {
 723                                 eventchase_target_origin = (current_view_origin - (forward * eventchase_current_distance));
 724                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
 725                                 setproperty(VF_ORIGIN, (trace_endpos - (forward * autocvar_cl_eventchase_mins.z)));
 726                         }
 727                         else { setproperty(VF_ORIGIN, trace_endpos); }
 728
 729                         if(!this.viewloc)
 730                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
 731                 }
 732
 733                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
 734                 {
 735                         eventchase_running = false;
 736                         cvar_set("chase_active", "0");
 737                         eventchase_current_distance = 0; // start from 0 next time
 738                 }
 739         }
 740         // workaround for camera stuck between player's legs when using chase_active 1
 741         // because the engine stops updating the chase_active camera when the game ends
 742         else if(intermission)
 743         {
 744                 cvar_settemp("chase_active", "-1");
 745                 eventchase_current_distance = 0;
 746         }
 747 }
 748
 749 vector damage_blurpostprocess, content_blurpostprocess;
 750
 751 void UpdateDamage()
 752 {
 753         // accumulate damage with each stat update
 754         static float damage_total_prev = 0;
 755         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 756         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 757         damage_total_prev = damage_total;
 758
 759         static float damage_dealt_time_prev = 0;
 760         float damage_dealt_time = STAT(HIT_TIME);
 761         if (damage_dealt_time != damage_dealt_time_prev)
 762         {
 763                 unaccounted_damage += unaccounted_damage_new;
 764                 //LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 765         }
 766         damage_dealt_time_prev = damage_dealt_time;
 767
 768         // prevent hitsound when switching spectatee
 769         static float spectatee_status_prev = 0;
 770         if (spectatee_status != spectatee_status_prev)
 771                 unaccounted_damage = 0;
 772         spectatee_status_prev = spectatee_status;
 773 }
 774
 775 void HitSound()
 776 {
 777         // varying sound pitch
 778
 779         bool have_arc = false;
 780         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 781         {
 782                 entity wepent = viewmodels[slot];
 783
 784                 if(wepent.activeweapon == WEP_ARC)
 785                         have_arc = true;
 786         }
 787
 788         static float hitsound_time_prev = 0;
 789         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 790         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 791         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 792         {
 793                 if (autocvar_cl_hitsound && unaccounted_damage)
 794                 {
 795                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 796                         float a = autocvar_cl_hitsound_max_pitch;
 797                         float b = autocvar_cl_hitsound_min_pitch;
 798                         float c = autocvar_cl_hitsound_nom_damage;
 799                         float d = unaccounted_damage;
 800                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 801
 802                         // if sound variation is disabled, set pitch_shift to 1
 803                         if (autocvar_cl_hitsound == 1)
 804                                 pitch_shift = 1;
 805
 806                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 807                         if (autocvar_cl_hitsound == 3)
 808                         {
 809                                 float mirror_value = (a-b)/2 + b;
 810                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 811                         }
 812
 813                         //LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 814
 815                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 816                         // todo: normalize sound pressure levels? seems unnecessary
 817
 818                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 819                 }
 820                 unaccounted_damage = 0;
 821                 hitsound_time_prev = time;
 822         }
 823
 824         static float typehit_time_prev = 0;
 825         float typehit_time = STAT(TYPEHIT_TIME);
 826         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 827         {
 828                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 829                 typehit_time_prev = typehit_time;
 830         }
 831
 832         static float kill_time_prev = 0;
 833         float kill_time = STAT(KILL_TIME);
 834         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 835         {
 836                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 837                 kill_time_prev = kill_time;
 838         }
 839 }
 840
 841 const int MAX_SPECIALCOMMAND = 15;
 842 vector specialcommand_slots[MAX_SPECIALCOMMAND];
 843 vector specialcommand_colors[MAX_SPECIALCOMMAND];
 844 const float SPECIALCOMMAND_SPEED = 150;
 845 const float SPECIALCOMMAND_TURNSPEED = 2;
 846 const float SPECIALCOMMAND_SIZE = 0.025;
 847 const float SPECIALCOMMAND_CHANCE = 0.35;
 848 float sc_spawntime, sc_changetime;
 849 vector sc_color = '1 1 1';
 850 void SpecialCommand()
 851 {
 852         if(!STAT(MOVEVARS_SPECIALCOMMAND))
 853                 return;
 854
 855         if(time >= sc_changetime)
 856         {
 857                 sc_changetime = time + 1;
 858                 sc_color = randomvec() * 1.5;
 859                 sc_color.x = bound(0.2, sc_color.x, 0.75);
 860                 sc_color.y = bound(0.2, sc_color.y, 0.75);
 861                 sc_color.z = bound(0.2, sc_color.z, 0.75);
 862         }
 863         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
 864
 865         if(!precache_pic("gfx/smile"))
 866                 return; // damn party poopers
 867
 868         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
 869         {
 870                 vector slot = specialcommand_slots[j];
 871                 if(slot.y)
 872                         slot.y += SPECIALCOMMAND_SPEED * frametime;
 873                 //if(slot.z)
 874                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
 875                 if(slot.y >= vid_conheight)
 876                         slot = '0 0 0';
 877
 878                 if(slot == '0 0 0')
 879                 {
 880                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
 881                         {
 882                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
 883                                 slot.y = 1; // start it off 0 so we can use it
 884                                 slot.z = floor(random() * REGISTRY_MAX(Weapons));
 885                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
 886                                 vector newcolor = randomvec() * 2;
 887                                 newcolor.x = bound(0.4, newcolor.x, 1);
 888                                 newcolor.y = bound(0.4, newcolor.y, 1);
 889                                 newcolor.z = bound(0.4, newcolor.z, 1);
 890                                 specialcommand_colors[j] = newcolor;
 891                         }
 892                 }
 893                 else
 894                 {
 895                         vector splash_size = '0 0 0';
 896                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
 897                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
 898                         entity wep = REGISTRY_GET(Weapons, slot.z);
 899                         if(wep == WEP_Null)
 900                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
 901                         else
 902                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
 903                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
 904                 }
 905
 906                 specialcommand_slots[j] = slot;
 907         }
 908 }
 909
 910 void HUD_Draw(entity this)
 911 {
 912         // if we don't know gametype and scores yet avoid drawing the scoreboard
 913         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
 914         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
 915         // cl_deathscoreboard would show the scoreboard and so on
 916         if(!gametype)
 917                 return;
 918
 919         Hud_Dynamic_Frame();
 920
 921         if(!intermission)
 922         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
 923         {
 924                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
 925         }
 926         else if(STAT(FROZEN))
 927         {
 928                 vector col = '0.25 0.90 1';
 929                 if(STAT(REVIVE_PROGRESS))
 930                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
 931                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 932         }
 933
 934         HUD_Scale_Enable();
 935         if(!intermission)
 936         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 937         {
 938                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
 939                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 940                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 941         }
 942         else if(STAT(CAPTURE_PROGRESS))
 943         {
 944                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 945                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 946         }
 947         else if(STAT(REVIVE_PROGRESS))
 948         {
 949                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 950                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
 951         }
 952         HUD_Scale_Disable();
 953
 954         if(autocvar_r_letterbox == 0)
 955                 if(autocvar_viewsize < 120)
 956                 {
 957                         if(!MUTATOR_CALLHOOK(DrawScoreboardAccuracy))
 958                                 Accuracy_LoadLevels();
 959
 960                         HUD_Main();
 961                         HUD_Scale_Disable();
 962                 }
 963
 964         // crosshair goes VERY LAST
 965         SpecialCommand();
 966         UpdateDamage();
 967         HUD_Crosshair(this);
 968         HitSound();
 969 }
 970
 971 void ViewLocation_Mouse()
 972 {
 973         if(spectatee_status)
 974                 return; // don't draw it as spectator!
 975
 976         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
 977         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
 978         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
 979
 980         //float cursor_alpha = 1 - autocvar__menu_alpha;
 981         //cursor_type = CURSOR_NORMAL;
 982         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
 983 }
 984
 985 void HUD_Cursor_Show()
 986 {
 987         float cursor_alpha = 1 - autocvar__menu_alpha;
 988         if(cursor_type == CURSOR_NORMAL)
 989                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
 990         else if(cursor_type == CURSOR_MOVE)
 991                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
 992         else if(cursor_type == CURSOR_RESIZE)
 993                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
 994         else if(cursor_type == CURSOR_RESIZE2)
 995                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
 996 }
 997
 998 void HUD_Mouse(entity player)
 999 {
1000         if(autocvar__menu_alpha == 1)
1001                 return;
1002
1003         if(!cursor_active)
1004         {
1005                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1006                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1007                 return;
1008         }
1009
1010         if (cursor_active == -1) // starting to display the cursor
1011         {
1012                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1013                 // in the first frame mousepos is the mouse position of the last time
1014                 // the cursor was displayed, thus we ignore it to avoid a glictch
1015                 cursor_active = 1;
1016                 return;
1017         }
1018
1019         if(!autocvar_hud_cursormode)
1020                 update_mousepos();
1021
1022         cursor_type = CURSOR_NORMAL;
1023         if(autocvar__hud_configure)
1024                 HUD_Panel_Mouse();
1025         else
1026         {
1027                 if (HUD_MinigameMenu_IsOpened())
1028                         HUD_Minigame_Mouse();
1029                 if (QuickMenu_IsOpened())
1030                         QuickMenu_Mouse();
1031                 if (HUD_Radar_Clickable())
1032                         HUD_Radar_Mouse();
1033         }
1034
1035         prevMouseClicked = mouseClicked;
1036
1037         HUD_Cursor_Show();
1038 }
1039
1040 void View_NightVision()
1041 {
1042         if(!(autocvar_r_fakelight >= 2 || autocvar_r_fullbright) || (serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1043                 return;
1044
1045         // apply night vision effect
1046         vector tc_00, tc_01, tc_10, tc_11;
1047         vector rgb = '0 0 0';
1048         float a;
1049
1050         if(!nightvision_noise)
1051         {
1052                 nightvision_noise = new(nightvision_noise);
1053         }
1054         if(!nightvision_noise2)
1055         {
1056                 nightvision_noise2 = new(nightvision_noise2);
1057         }
1058
1059         // color tint in yellow
1060         drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1061
1062         // draw BG
1063         a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1064         rgb = '1 1 1';
1065         tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1066         tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1067         tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1068         //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1069         tc_11 = tc_01 + tc_10 - tc_00;
1070         R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE, true);
1071         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1072         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1073         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1074         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1075         R_EndPolygon();
1076
1077         // draw FG
1078         a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1079         rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1080         tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1081         tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1082         tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1083         tc_11 = tc_01 + tc_10 - tc_00;
1084         R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE, true);
1085         R_PolygonVertex('0 0 0', tc_00, rgb, a);
1086         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1087         R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1088         R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1089         R_EndPolygon();
1090 }
1091
1092 // visual overlay while in liquids
1093 // provides some effects to the postprocessing function
1094 void HUD_Contents()
1095 {
1096         if(!autocvar_hud_contents || MUTATOR_CALLHOOK(HUD_Contents))
1097                 return;
1098
1099         // improved polyblend
1100         float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1101         vector liquidcolor;
1102
1103         switch(pointcontents(view_origin))
1104         {
1105                 case CONTENT_WATER:
1106                         liquidalpha = autocvar_hud_contents_water_alpha;
1107                         liquidcolor = stov(autocvar_hud_contents_water_color);
1108                         incontent = 1;
1109                         break;
1110
1111                 case CONTENT_LAVA:
1112                         liquidalpha = autocvar_hud_contents_lava_alpha;
1113                         liquidcolor = stov(autocvar_hud_contents_lava_color);
1114                         incontent = 1;
1115                         break;
1116
1117                 case CONTENT_SLIME:
1118                         liquidalpha = autocvar_hud_contents_slime_alpha;
1119                         liquidcolor = stov(autocvar_hud_contents_slime_color);
1120                         incontent = 1;
1121                         break;
1122
1123                 default:
1124                         liquidalpha = 0;
1125                         liquidcolor = '0 0 0';
1126                         incontent = 0;
1127                         break;
1128         }
1129
1130         if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1131         { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1132                 contentfadetime = autocvar_hud_contents_fadeintime;
1133                 liquidalpha_prev = liquidalpha;
1134                 liquidcolor_prev = liquidcolor;
1135         }
1136         else
1137                 contentfadetime = autocvar_hud_contents_fadeouttime;
1138
1139         contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1140         contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1141
1142         if(contentavgalpha)
1143                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1144
1145         if(autocvar_hud_postprocessing)
1146         {
1147                 if(autocvar_hud_contents_blur && contentavgalpha)
1148                 {
1149                         content_blurpostprocess.x = 1;
1150                         content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1151                         content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1152                 }
1153                 else
1154                 {
1155                         content_blurpostprocess.x = 0;
1156                         content_blurpostprocess.y = 0;
1157                         content_blurpostprocess.z = 0;
1158                 }
1159         }
1160 }
1161
1162 // visual pain effects on the screen
1163 // provides some effects to the postprocessing function
1164 void HUD_Damage()
1165 {
1166         if(!autocvar_hud_damage || STAT(FROZEN))
1167                 return;
1168
1169         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1170         splash_size.x = max(vid_conwidth, vid_conheight);
1171         splash_size.y = max(vid_conwidth, vid_conheight);
1172         splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1173         splash_pos.y = (vid_conheight - splash_size.y) / 2;
1174
1175         float myhealth_flash_temp;
1176         myhealth = STAT(HEALTH);
1177
1178         // fade out
1179         myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1180         // add new damage
1181         myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1182
1183         float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1184         pain_threshold = autocvar_hud_damage_pain_threshold;
1185         pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1186         pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1187
1188         if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1189         {
1190                 pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1191         }
1192
1193         myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1194
1195         if(myhealth_prev < 1)
1196         {
1197                 if(myhealth >= 1)
1198                 {
1199                         myhealth_flash = 0; // just spawned, clear the flash immediately
1200                         myhealth_flash_temp = 0;
1201                 }
1202                 else
1203                 {
1204                         myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1205                 }
1206         }
1207
1208         if(spectatee_status == -1 || intermission)
1209         {
1210                 myhealth_flash = 0; // observing, or match ended
1211                 myhealth_flash_temp = 0;
1212         }
1213
1214         myhealth_prev = myhealth;
1215
1216         // IDEA: change damage color/picture based on player model for robot/alien species?
1217         // pro: matches model better
1218         // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1219         // maybe different reddish pics?
1220         if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1221         {
1222                 if(autocvar_cl_gentle_damage == 2)
1223                 {
1224                         if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1225                                 myhealth_gentlergb = randomvec();
1226                 }
1227                 else
1228                         myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1229
1230                 if(myhealth_flash_temp > 0)
1231                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1232         }
1233         else if(myhealth_flash_temp > 0)
1234                 drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1235
1236         if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1237         {
1238                 if(autocvar_hud_damage_blur && myhealth_flash_temp)
1239                 {
1240                         damage_blurpostprocess.x = 1;
1241                         damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1242                         damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1243                 }
1244                 else
1245                 {
1246                         damage_blurpostprocess.x = 0;
1247                         damage_blurpostprocess.y = 0;
1248                         damage_blurpostprocess.z = 0;
1249                 }
1250         }
1251 }
1252
1253 void View_PostProcessing()
1254 {
1255         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1256         float e2 = (autocvar_hud_powerup != 0);
1257         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1258         {
1259                 // enable or disable rendering types if they are used or not
1260                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1261                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1262
1263                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1264                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1265                 {
1266                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1267                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1268                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1269                         {
1270                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1271                                 old_blurradius = blurradius;
1272                                 old_bluralpha = bluralpha;
1273                         }
1274                 }
1275                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1276                 {
1277                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1278                         old_blurradius = 0;
1279                         old_bluralpha = 0;
1280                 }
1281
1282                 // edge detection postprocess handling done second (used by hud_powerup)
1283                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
1284                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1285                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1286
1287                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1288
1289                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1290                 {
1291                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1292                         {
1293                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1294                                 old_sharpen_intensity = sharpen_intensity;
1295                         }
1296                 }
1297                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1298                 {
1299                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1300                         old_sharpen_intensity = 0;
1301                 }
1302
1303                 if(cvar("r_glsl_postprocess") == 0)
1304                         cvar_set("r_glsl_postprocess", "2");
1305         }
1306         else if(cvar("r_glsl_postprocess") == 2)
1307                 cvar_set("r_glsl_postprocess", "0");
1308 }
1309
1310 void View_Lock()
1311 {
1312         int lock_type = (!autocvar_hud_cursormode && ((autocvar__hud_configure && spectatee_status <= 0) || intermission > 1 || QuickMenu_IsOpened()));
1313         if (lock_type == 0)
1314                 lock_type = autocvar_cl_lockview;
1315
1316         // lock_type 1: lock origin and angles
1317         // lock_type 2: lock only origin
1318         if(lock_type >= 1)
1319                 setproperty(VF_ORIGIN, freeze_org);
1320         else
1321                 freeze_org = getpropertyvec(VF_ORIGIN);
1322         if(lock_type == 1)
1323                 setproperty(VF_ANGLES, freeze_ang);
1324         else
1325                 freeze_ang = getpropertyvec(VF_ANGLES);
1326 }
1327
1328 void View_DemoCamera()
1329 {
1330         if(camera_active) // Camera for demo playback
1331         {
1332                 if(autocvar_camera_enable)
1333                         CSQC_Demo_Camera();
1334                 else
1335                 {
1336                         cvar_set("chase_active", ftos(chase_active_backup));
1337                         cvar_set("cl_demo_mousegrab", "0");
1338                         camera_active = false;
1339                 }
1340         }
1341         else
1342         {
1343 #ifdef CAMERATEST
1344                 if(autocvar_camera_enable)
1345 #else
1346                 if(autocvar_camera_enable && isdemo())
1347 #endif
1348                 {
1349                         // Enable required Darkplaces cvars
1350                         chase_active_backup = autocvar_chase_active;
1351                         cvar_set("chase_active", "2");
1352                         cvar_set("cl_demo_mousegrab", "1");
1353                         camera_active = true;
1354                         camera_mode = false;
1355                 }
1356         }
1357 }
1358
1359 #ifdef BLURTEST
1360 void View_BlurTest()
1361 {
1362         if(time > blurtest_time0 && time < blurtest_time1)
1363         {
1364                 float t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1365                 float r = t * blurtest_radius;
1366                 float f = 1 / (t ** blurtest_power) - 1;
1367
1368                 cvar_set("r_glsl_postprocess", "1");
1369                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1370         }
1371         else
1372         {
1373                 cvar_set("r_glsl_postprocess", "0");
1374                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1375         }
1376 }
1377 #endif
1378
1379 void View_CheckButtonStatus()
1380 {
1381         float is_dead = (STAT(HEALTH) <= 0);
1382
1383         // FIXME do we need this hack?
1384         if(isdemo())
1385         {
1386                 // in demos, input_buttons do not work
1387                 button_zoom = (autocvar__togglezoom == "-");
1388         }
1389         else if(button_zoom
1390                 && autocvar_cl_unpress_zoom_on_death
1391                 && (spectatee_status >= 0)
1392                 && (is_dead || intermission))
1393         {
1394                 // no zoom while dead or in intermission please
1395                 localcmd("-zoom\n");
1396                 button_zoom = false;
1397         }
1398
1399         if(autocvar_fov <= 59.5)
1400         {
1401                 if(!zoomscript_caught)
1402                 {
1403                         localcmd("+button9\n");
1404                         zoomscript_caught = 1;
1405                 }
1406         }
1407         else
1408         {
1409                 if(zoomscript_caught)
1410                 {
1411                         localcmd("-button9\n");
1412                         zoomscript_caught = 0;
1413                 }
1414         }
1415
1416         if(active_minigame && HUD_MinigameMenu_IsOpened())
1417         {
1418                 if(!minigame_wasactive)
1419                 {
1420                         localcmd("+button12\n");
1421                         minigame_wasactive = true;
1422                 }
1423         }
1424         else if(minigame_wasactive)
1425         {
1426                 localcmd("-button12\n");
1427                 minigame_wasactive = false;
1428         }
1429
1430         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1431         {
1432                 entity wepent = viewmodels[slot];
1433
1434                 if(wepent.last_switchweapon != wepent.switchweapon)
1435                 {
1436                         weapontime = time;
1437                         wepent.last_switchweapon = wepent.switchweapon;
1438                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1439                         {
1440                                 localcmd("-zoom\n");
1441                                 button_zoom = false;
1442                         }
1443                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1444                         {
1445                                 localcmd("-fire\n");
1446                                 localcmd("-fire2\n");
1447                                 button_attack2 = false;
1448                         }
1449                 }
1450                 if(wepent.last_activeweapon != wepent.activeweapon)
1451                 {
1452                         wepent.last_activeweapon = wepent.activeweapon;
1453
1454                         entity e = wepent.activeweapon;
1455                         if(e.netname != "")
1456                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1457                         else if(slot == 0)
1458                                 localcmd("\ncl_hook_activeweapon none\n");
1459                 }
1460         }
1461 }
1462
1463 bool ov_enabled;
1464 float oldr_nearclip;
1465 float oldr_farclip_base;
1466 float oldr_farclip_world;
1467 float oldr_novis;
1468 float oldr_useportalculling;
1469 float oldr_useinfinitefarclip;
1470 vector ov_org = '0 0 0';
1471 vector ov_mid = '0 0 0';
1472 vector ov_worldmin = '0 0 0';
1473 vector ov_worldmax = '0 0 0';
1474
1475 void View_Ortho()
1476 {
1477         ov_org = '0 0 0';
1478         ov_mid = '0 0 0';
1479         ov_worldmin = '0 0 0';
1480         ov_worldmax = '0 0 0';
1481         if(autocvar_cl_orthoview)
1482         {
1483                 ov_worldmin = mi_picmin;
1484                 ov_worldmax = mi_picmax;
1485
1486                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1487                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1488                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1489
1490                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1491                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1492
1493                 float ov_nearest = vlen(ov_org - vec3(
1494                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1495                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1496                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1497                 ));
1498
1499                 float ov_furthest = 0;
1500                 float dist = 0;
1501
1502                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1503                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1504                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1505                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1506                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1507                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1508                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1509                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1510
1511                 if(!ov_enabled)
1512                 {
1513                         oldr_nearclip = cvar("r_nearclip");
1514                         oldr_farclip_base = cvar("r_farclip_base");
1515                         oldr_farclip_world = cvar("r_farclip_world");
1516                         oldr_novis = cvar("r_novis");
1517                         oldr_useportalculling = cvar("r_useportalculling");
1518                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1519                 }
1520
1521                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1522                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1523                 cvar_settemp("r_farclip_world", "0");
1524                 cvar_settemp("r_novis", "1");
1525                 cvar_settemp("r_useportalculling", "0");
1526                 cvar_settemp("r_useinfinitefarclip", "0");
1527
1528                 setproperty(VF_ORIGIN, ov_org);
1529                 setproperty(VF_ANGLES, '90 0 0');
1530
1531                 ov_enabled = true;
1532
1533                 #if 0
1534                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1535                         vtos(ov_org),
1536                         vtos(getpropertyvec(VF_ANGLES)),
1537                         ov_distance,
1538                         ov_nearest,
1539                         ov_furthest);
1540                 #endif
1541         }
1542         else
1543         {
1544                 if(ov_enabled)
1545                 {
1546                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1547                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1548                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1549                         cvar_set("r_novis", ftos(oldr_novis));
1550                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1551                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1552                 }
1553                 ov_enabled = false;
1554         }
1555 }
1556
1557 void View_UpdateFov()
1558 {
1559         vector fov;
1560         if(autocvar_cl_orthoview)
1561                 fov = GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org);
1562         else if(csqcplayer.viewloc)
1563                 fov = GetViewLocationFOV(110); // enforce 110 fov, so things don't look odd
1564         else
1565                 fov = GetCurrentFov(autocvar_fov);
1566
1567         setproperty(VF_FOV, fov);
1568 }
1569
1570 void CSQC_UpdateView(entity this, float w, float h)
1571 {
1572         TC(int, w); TC(int, h);
1573
1574         execute_next_frame();
1575
1576         ++framecount;
1577
1578         stats_get();
1579         hud = STAT(HUD);
1580
1581         ReplicateVars(false);
1582         if (ReplicateVars_NOT_SENDING())
1583                 ReplicateVars_DELAY(0.8 + random() * 0.4); // no need to check cvars every frame
1584
1585         HUD_Scale_Disable();
1586
1587         if(autocvar__hud_showbinds_reload) // menu can set this one
1588         {
1589                 db_close(binddb);
1590                 binddb = db_create();
1591                 cvar_set("_hud_showbinds_reload", "0");
1592         }
1593
1594         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1595                 view_quality = getproperty(VF_MINFPS_QUALITY);
1596         else
1597                 view_quality = 1;
1598
1599         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1600         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1601
1602         vector vf_size = getpropertyvec(VF_SIZE);
1603         vector vf_min = getpropertyvec(VF_MIN);
1604         vid_width = vf_size.x;
1605         vid_height = vf_size.y;
1606
1607         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1608
1609         WaypointSprite_Load();
1610
1611         CSQCPlayer_SetCamera();
1612
1613         if(player_localentnum <= maxclients) // is it a client?
1614                 current_player = player_localentnum - 1;
1615         else // then player_localentnum is the vehicle I'm driving
1616                 current_player = player_localnum;
1617         myteam = entcs_GetTeam(current_player);
1618
1619         // abused multiple places below
1620         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1621         if(!local_player)
1622                 local_player = this; // fall back!
1623
1624         View_EventChase(local_player);
1625
1626         // do lockview after event chase camera so that it still applies whenever necessary.
1627         View_Lock();
1628
1629         WarpZone_FixView();
1630         //WarpZone_FixPMove();
1631
1632         View_Ortho();
1633
1634         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1635         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1636         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1637                 viewmodel_draw(viewmodels[slot]);
1638
1639         // Render the Scene
1640         view_origin = getpropertyvec(VF_ORIGIN);
1641         view_angles = getpropertyvec(VF_ANGLES);
1642         MAKE_VECTORS(view_angles, view_forward, view_right, view_up);
1643
1644 #ifdef BLURTEST
1645         View_BlurTest();
1646 #endif
1647
1648         TargetMusic_Advance();
1649         Fog_Force();
1650         fpscounter_update();
1651
1652         if(drawtime == 0)
1653                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1654         else
1655                 drawframetime = bound(0.000001, time - drawtime, 1);
1656         drawtime = time;
1657
1658         // watch for gametype changes here...
1659         // in ParseStuffCMD the cmd isn't executed yet :/
1660         // might even be better to add the gametype to TE_CSQC_INIT...?
1661         if(!postinit)
1662                 PostInit();
1663
1664         if(intermission && !intermission_time)
1665                 intermission_time = time;
1666
1667         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1668         {
1669                 if(calledhooks & HOOK_START)
1670                 {
1671                         localcmd("\ncl_hook_gameend\n");
1672                         calledhooks |= HOOK_END;
1673                 }
1674         }
1675
1676         Announcer();
1677
1678         View_CheckButtonStatus();
1679
1680         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1681
1682         // ALWAYS Clear Current Scene First
1683         clearscene();
1684
1685         setproperty(VF_ORIGIN, view_origin);
1686         setproperty(VF_ANGLES, view_angles);
1687
1688         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1689         setproperty(VF_SIZE, vf_size);
1690         setproperty(VF_MIN, vf_min);
1691
1692         // Assign Standard Viewflags
1693         // Draw the World (and sky)
1694         setproperty(VF_DRAWWORLD, 1);
1695
1696         // Set the console size vars
1697         vid_conwidth = autocvar_vid_conwidth;
1698         vid_conheight = autocvar_vid_conheight;
1699         vid_pixelheight = autocvar_vid_pixelheight;
1700
1701         View_UpdateFov();
1702
1703         View_DemoCamera();
1704
1705         // Draw the Crosshair
1706         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1707
1708         // Draw the Engine Status Bar (the default Quake HUD)
1709         setproperty(VF_DRAWENGINESBAR, 0);
1710
1711         // Update the mouse position
1712         /*
1713            mousepos_x = vid_conwidth;
1714            mousepos_y = vid_conheight;
1715            mousepos = mousepos*0.5 + getmousepos();
1716          */
1717
1718         IL_EACH(g_drawables, it.draw, it.draw(it));
1719
1720         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
1721         renderscene();
1722
1723         // Now the the scene has been rendered, begin with the 2D drawing functions
1724
1725         View_NightVision();
1726         DrawReticle(local_player);
1727         HUD_Contents();
1728         HUD_Damage();
1729         View_PostProcessing();
1730
1731         // draw 2D entities
1732         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
1733         Draw_ShowNames_All();
1734 #if ENABLE_DEBUGDRAW
1735         Debug_Draw();
1736 #endif
1737
1738         scoreboard_active = Scoreboard_WouldDraw();
1739
1740         HUD_Draw(this); // this parameter for deep vehicle function
1741
1742         if(NextFrameCommand)
1743         {
1744                 localcmd("\n", NextFrameCommand, "\n");
1745                 NextFrameCommand = string_null;
1746         }
1747
1748         // we must do this check AFTER a frame was rendered, or it won't work
1749         if(cs_project_is_b0rked == 0)
1750         {
1751                 string w0, h0;
1752                 w0 = ftos(autocvar_vid_conwidth);
1753                 h0 = ftos(autocvar_vid_conheight);
1754                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1755                 //setproperty(VF_FOV, '90 90 0');
1756                 setproperty(VF_ORIGIN, '0 0 0');
1757                 setproperty(VF_ANGLES, '0 0 0');
1758                 setproperty(VF_PERSPECTIVE, 1);
1759                 vector forward, right, up;
1760                 MAKE_VECTORS('0 0 0', forward, right, up);
1761                 vector v1, v2;
1762                 cvar_set("vid_conwidth", "800");
1763                 cvar_set("vid_conheight", "600");
1764                 v1 = cs_project(forward);
1765                 cvar_set("vid_conwidth", "640");
1766                 cvar_set("vid_conheight", "480");
1767                 v2 = cs_project(forward);
1768                 if(v1 == v2)
1769                         cs_project_is_b0rked = 1;
1770                 else
1771                         cs_project_is_b0rked = -1;
1772                 cvar_set("vid_conwidth", w0);
1773                 cvar_set("vid_conheight", h0);
1774         }
1775
1776         HUD_Mouse(local_player);
1777
1778         cl_notice_run();
1779         unpause_update();
1780         Net_Flush();
1781
1782         // let's reset the view back to normal for the end
1783         setproperty(VF_MIN, '0 0 0');
1784         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1785
1786         IL_ENDFRAME();
1787 }
1788
1789
1790 // following vectors must be global to allow seamless switching between camera modes
1791 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1792 void CSQC_Demo_Camera()
1793 {
1794         float speed, attenuation, dimensions;
1795         vector tmp, delta;
1796
1797         if( autocvar_camera_reset || !camera_mode )
1798         {
1799                 camera_offset = '0 0 0';
1800                 current_angles = '0 0 0';
1801                 camera_direction = '0 0 0';
1802                 camera_offset.z += 30;
1803                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1804                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1805                 current_origin = view_origin;
1806                 current_camera_offset  = camera_offset;
1807                 cvar_set("camera_reset", "0");
1808                 camera_mode = CAMERA_CHASE;
1809         }
1810
1811         // Camera angles
1812         if( camera_roll )
1813                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1814
1815         if(autocvar_camera_look_player)
1816         {
1817                 vector dir;
1818                 float n;
1819
1820                 dir = normalize(view_origin - current_position);
1821                 n = mouse_angles.z;
1822                 mouse_angles = vectoangles(dir);
1823                 mouse_angles.x = mouse_angles.x * -1;
1824                 mouse_angles.z = n;
1825         }
1826         else
1827         {
1828                 tmp = getmousepos() * 0.1;
1829                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
1830                 {
1831                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1832                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1833                 }
1834         }
1835
1836         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1837         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1838         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1839         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1840
1841         // Fix difference when angles don't have the same sign
1842         delta = '0 0 0';
1843         if(mouse_angles.y < -60 && current_angles.y > 60)
1844                 delta = '0 360 0';
1845         if(mouse_angles.y > 60 && current_angles.y < -60)
1846                 delta = '0 -360 0';
1847
1848         if(autocvar_camera_look_player)
1849                 attenuation = autocvar_camera_look_attenuation;
1850         else
1851                 attenuation = autocvar_camera_speed_attenuation;
1852
1853         attenuation = 1 / max(1, attenuation);
1854         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1855
1856         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1857         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1858         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1859         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1860
1861         // Camera position
1862         tmp = '0 0 0';
1863         dimensions = 0;
1864
1865         if( camera_direction.x )
1866         {
1867                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1868                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1869                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1870                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1871                 ++dimensions;
1872         }
1873
1874         if( camera_direction.y )
1875         {
1876                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1877                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1878                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1879                 ++dimensions;
1880         }
1881
1882         if( camera_direction.z )
1883         {
1884                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1885                 ++dimensions;
1886         }
1887
1888         if(autocvar_camera_free)
1889                 speed = autocvar_camera_speed_free;
1890         else
1891                 speed = autocvar_camera_speed_chase;
1892
1893         if(dimensions)
1894         {
1895                 speed = speed * sqrt(1 / dimensions);
1896                 camera_offset += tmp * speed;
1897         }
1898
1899         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1900
1901         // Camera modes
1902         if( autocvar_camera_free )
1903         {
1904                 if ( camera_mode == CAMERA_CHASE )
1905                 {
1906                         current_camera_offset = current_origin + current_camera_offset;
1907                         camera_offset = current_origin + camera_offset;
1908                 }
1909
1910                 camera_mode = CAMERA_FREE;
1911                 current_position = current_camera_offset;
1912         }
1913         else
1914         {
1915                 if ( camera_mode == CAMERA_FREE )
1916                 {
1917                         current_origin = view_origin;
1918                         camera_offset = camera_offset - current_origin;
1919                         current_camera_offset = current_camera_offset - current_origin;
1920                 }
1921
1922                 camera_mode = CAMERA_CHASE;
1923
1924                 if(autocvar_camera_chase_smoothly)
1925                         current_origin += (view_origin - current_origin) * attenuation;
1926                 else
1927                         current_origin = view_origin;
1928
1929                 current_position = current_origin + current_camera_offset;
1930         }
1931
1932         setproperty(VF_ANGLES, current_angles);
1933         setproperty(VF_ORIGIN, current_position);
1934 }