qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/_mod.qh"
   5 #include "mapvoting.qh"
   6 #include "shownames.qh"
   7 #include "hud/panel/scoreboard.qh"
   8 #include "hud/panel/quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include <common/animdecide.qh>
  13 #include <common/ent_cs.qh>
  14 #include <common/anim.qh>
  15 #include <common/constants.qh>
  16 #include <common/net_linked.qh>
  17 #include <common/debug.qh>
  18 #include <common/mapinfo.qh>
  19 #include <common/gamemodes/_mod.qh>
  20 #include <common/physics/player.qh>
  21 #include <common/stats.qh>
  22 #include <common/triggers/target/music.qh>
  23 #include <common/teams.qh>
  24
  25 #include <common/weapons/weapon/tuba.qh>
  26
  27 #include <common/vehicles/all.qh>
  28 #include <common/weapons/_all.qh>
  29 #include <common/viewloc.qh>
  30 #include <common/minigames/cl_minigames.qh>
  31 #include <common/minigames/cl_minigames_hud.qh>
  32
  33 #include <lib/csqcmodel/cl_player.qh>
  34 #include <lib/csqcmodel/cl_model.qh>
  35 #include "csqcmodel_hooks.qh"
  36
  37 #include <lib/warpzone/client.qh>
  38 #include <lib/warpzone/common.qh>
  39
  40 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  41
  42 float autocvar_cl_viewmodel_scale;
  43
  44 bool autocvar_cl_bobmodel;
  45 float autocvar_cl_bobmodel_speed;
  46 float autocvar_cl_bobmodel_side;
  47 float autocvar_cl_bobmodel_up;
  48
  49 float autocvar_cl_followmodel;
  50 float autocvar_cl_followmodel_speed = 0.3;
  51 float autocvar_cl_followmodel_limit = 135;
  52 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  53 float autocvar_cl_followmodel_highpass = 0.05;
  54 float autocvar_cl_followmodel_lowpass = 0.03;
  55 bool autocvar_cl_followmodel_velocity_absolute;
  56
  57 float autocvar_cl_leanmodel;
  58 float autocvar_cl_leanmodel_speed = 0.3;
  59 float autocvar_cl_leanmodel_limit = 30;
  60 float autocvar_cl_leanmodel_highpass1 = 0.2;
  61 float autocvar_cl_leanmodel_highpass = 0.2;
  62 float autocvar_cl_leanmodel_lowpass = 0.05;
  63
  64 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  65 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  66 { \
  67         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  68 } MACRO_END
  69
  70 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  71 { \
  72         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  73         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  74 } MACRO_END
  75
  76 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  77 { \
  78         float __f = 0; lowpass(value, frac, ref_store, __f); \
  79         ret = (value) - __f; \
  80 } MACRO_END
  81
  82 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  83 { \
  84         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  85         ret = (value) - __f; \
  86 } MACRO_END
  87
  88 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  89 { \
  90         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  91         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  92 } MACRO_END
  93
  94 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  95 { \
  96         highpass(value.x, frac, ref_store.x, ref_out.x); \
  97         highpass(value.y, frac, ref_store.y, ref_out.y); \
  98 } MACRO_END
  99
 100 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 101 { \
 102         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 103         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 104 } MACRO_END
 105
 106 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 107 { \
 108         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 109         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 110         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 111 } MACRO_END
 112
 113 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 114 { \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 } MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 137                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 138                 vel.x = view.velocity * forward;
 139                 vel.y = view.velocity * right * -1;
 140                 vel.z = view.velocity * up;
 141         }
 142
 143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 146
 147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 148         lowpass3(vel, frac, vel_average, gunorg);
 149
 150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 151
 152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 154         frac = avg_factor(autocvar_cl_followmodel_highpass);
 155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 158
 159         if (autocvar_cl_followmodel_velocity_absolute)
 160         {
 161                 vector fixed_gunorg;
 162                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 163                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 164                 fixed_gunorg.x = gunorg * forward;
 165                 fixed_gunorg.y = gunorg * right * -1;
 166                 fixed_gunorg.z = gunorg * up;
 167                 gunorg = fixed_gunorg;
 168         }
 169
 170         cl_followmodel_ofs = gunorg;
 171         cl_followmodel_time = time;
 172 }
 173
 174 vector leanmodel_ofs(entity view)
 175 {
 176         float frac;
 177         vector gunangles = '0 0 0';
 178         static vector gunangles_prev = '0 0 0';
 179         static vector gunangles_highpass = '0 0 0';
 180         static vector gunangles_adjustment_highpass;
 181         static vector gunangles_adjustment_lowpass;
 182
 183         if (view.csqcmodel_teleported)
 184                 gunangles_prev = view_angles;
 185
 186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 187         gunangles_highpass += gunangles_prev;
 188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 193         gunangles_prev = view_angles;
 194         gunangles_highpass -= gunangles_prev;
 195
 196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 206
 207         return gunangles;
 208 }
 209
 210 vector bobmodel_ofs(entity view)
 211 {
 212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 213         static bool oldonground;
 214         static float hitgroundtime;
 215         if (clonground)
 216         {
 217                 float f = time; // cl.movecmd[0].time
 218                 if (!oldonground)
 219                         hitgroundtime = f;
 220         }
 221         oldonground = clonground;
 222
 223         // calculate for swinging gun model
 224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 225         vector gunorg = '0 0 0';
 226         static float bobmodel_scale = 0;
 227         static float time_ofs = 0; // makes the effect always restart in the same way
 228         if (clonground)
 229         {
 230                 if (time - hitgroundtime > 0.05)
 231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 232         }
 233         else
 234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 235
 236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 237         if (bobmodel_scale && xyspeed)
 238         {
 239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 243         }
 244         else
 245                 time_ofs = time;
 246
 247         return gunorg;
 248 }
 249
 250 void viewmodel_animate(entity this)
 251 {
 252         if (autocvar_chase_active) return;
 253         if (STAT(HEALTH) <= 0) return;
 254
 255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 256
 257         if (autocvar_cl_followmodel)
 258         {
 259                 calc_followmodel_ofs(view);
 260                 this.origin += cl_followmodel_ofs;
 261         }
 262
 263         if (autocvar_cl_leanmodel)
 264                 this.angles += leanmodel_ofs(view);
 265
 266         // vertical view bobbing code
 267         // TODO: cl_bob
 268
 269         // horizontal view bobbing code
 270         // TODO: cl_bob2
 271
 272         // fall bobbing code
 273         // causes the view to swing down and back up when touching the ground
 274         // TODO: cl_bobfall
 275
 276         // gun model bobbing code
 277         if (autocvar_cl_bobmodel)
 278                 this.origin += bobmodel_ofs(view);
 279 }
 280
 281 .vector viewmodel_origin, viewmodel_angles;
 282 .float weapon_nextthink;
 283 .float weapon_eta_last;
 284 .float weapon_switchdelay;
 285
 286 .string name_last;
 287
 288 void viewmodel_draw(entity this)
 289 {
 290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 291                 return;
 292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 293         float a = this.alpha;
 294         static bool wasinvehicle;
 295         bool invehicle = player_localentnum > maxclients;
 296         if (invehicle) a = -1;
 297         else if (wasinvehicle) a = 1;
 298         wasinvehicle = invehicle;
 299         Weapon wep = this.activeweapon;
 300         int c = entcs_GetClientColors(current_player);
 301         vector g = weaponentity_glowmod(wep, NULL, c, this);
 302         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 303         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 304                 | EF_NODEPTHTEST)
 305                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 306         for (entity e = this; e; e = e.weaponchild)
 307         {
 308                 e.drawmask = mask;
 309                 e.alpha = a;
 310                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 311                 e.glowmod = g;
 312                 e.csqcmodel_effects = fx;
 313                 CSQCModel_Effects_Apply(e);
 314         }
 315         {
 316                 string name = wep.mdl;
 317                 string newname = wep.wr_viewmodel(wep, this);
 318                 if(newname)
 319                         name = newname;
 320                 bool swap = name != this.name_last;
 321                 // if (swap)
 322                 {
 323                         this.name_last = name;
 324                         CL_WeaponEntity_SetModel(this, name, swap);
 325                         this.viewmodel_origin = this.origin;
 326                         this.viewmodel_angles = this.angles;
 327                 }
 328                 anim_update(this);
 329                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 330                         anim_set(this, this.anim_idle, true, false, false);
 331         }
 332         float f = 0; // 0..1; 0: fully active
 333         float rate = STAT(WEAPONRATEFACTOR);
 334         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 335         if (eta <= 0) f = this.weapon_eta_last;
 336         else switch (this.state)
 337         {
 338                 case WS_RAISE:
 339                 {
 340                         f = eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_DROP:
 344                 {
 345                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 346                         break;
 347                 }
 348                 case WS_CLEAR:
 349                 {
 350                         f = 1;
 351                         break;
 352                 }
 353         }
 354         this.weapon_eta_last = f;
 355         this.origin = this.viewmodel_origin;
 356         this.angles = this.viewmodel_angles;
 357         this.angles_x = (-90 * f * f);
 358         viewmodel_animate(this);
 359         MUTATOR_CALLHOOK(DrawViewModel, this);
 360         setorigin(this, this.origin);
 361 }
 362
 363 STATIC_INIT(viewmodel) {
 364     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         viewmodels[slot] = new(viewmodel);
 366 }
 367
 368 void Porto_Draw(entity this);
 369 STATIC_INIT(Porto)
 370 {
 371         entity e = new_pure(porto);
 372         e.draw = Porto_Draw;
 373         IL_PUSH(g_drawables, e);
 374         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 375 }
 376
 377 const int polyline_length = 16;
 378 .vector polyline[polyline_length];
 379 void Porto_Draw(entity this)
 380 {
 381         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 382         {
 383                 entity wepent = viewmodels[slot];
 384
 385                 if (wepent.activeweapon != WEP_PORTO) continue;
 386                 if (spectatee_status) continue;
 387                 if (WEP_CVAR(porto, secondary)) continue;
 388                 if (intermission == 1) continue;
 389                 if (intermission == 2) continue;
 390                 if (STAT(HEALTH) <= 0) continue;
 391
 392                 vector pos = view_origin;
 393                 vector dir = view_forward;
 394                 if (wepent.angles_held_status)
 395                 {
 396                         makevectors(wepent.angles_held);
 397                         dir = v_forward;
 398                 }
 399
 400                 wepent.polyline[0] = pos;
 401
 402                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 403                 int n = 1 + 2;  // 2 lines == 3 points
 404                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 405                 {
 406                         traceline(pos, pos + 65536 * dir, true, this);
 407                         dir = reflect(dir, trace_plane_normal);
 408                         pos = trace_endpos;
 409                         wepent.polyline[++idx] = pos;
 410                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 411                         {
 412                                 n += 1;
 413                                 continue;
 414                         }
 415                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 416                         {
 417                                 n = max(2, idx);
 418                                 break;
 419                         }
 420                         // check size
 421                         {
 422                                 vector ang = vectoangles2(trace_plane_normal, dir);
 423                                 ang.x = -ang.x;
 424                                 makevectors(ang);
 425                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 426                                 {
 427                                         n = max(2, idx);
 428                                         break;
 429                                 }
 430                         }
 431                         portal_number += 1;
 432                         if (portal_number >= portal_max) break;
 433                         if (portal_number == 1) portal1_idx = idx;
 434                 }
 435                 for (int idx = 0; idx < n - 1; ++idx)
 436                 {
 437                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 438                         if (idx == 0) p -= view_up * 16;  // line from player
 439                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 440                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 441                 }
 442         }
 443 }
 444
 445 float drawtime;
 446 float avgspeed;
 447 vector GetCurrentFov(float fov)
 448 {
 449         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 450         float velocityzoom, curspeed;
 451         vector v;
 452
 453         zoomsensitivity = autocvar_cl_zoomsensitivity;
 454         zoomfactor = autocvar_cl_zoomfactor;
 455         if(zoomfactor < 1 || zoomfactor > 30)
 456                 zoomfactor = 2.5;
 457         zoomspeed = autocvar_cl_zoomspeed;
 458         if(zoomspeed >= 0)
 459         if(zoomspeed < 0.5 || zoomspeed > 16)
 460                         zoomspeed = 3.5;
 461
 462         zoomdir = button_zoom;
 463
 464         if(hud == HUD_NORMAL && !spectatee_status)
 465         {
 466                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 467                 {
 468                         entity wepent = viewmodels[slot];
 469                         if(wepent.switchweapon == wepent.activeweapon)
 470                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 471                                 zoomdir += button_attack2;
 472                 }
 473         }
 474         if(spectatee_status > 0 || isdemo())
 475         {
 476                 if(spectatorbutton_zoom)
 477                 {
 478                         if(zoomdir)
 479                                 zoomdir = 0;
 480                         else
 481                                 zoomdir = 1;
 482                 }
 483                 // fteqcc failed twice here already, don't optimize this
 484         }
 485
 486         if(zoomdir) { zoomin_effect = 0; }
 487
 488         if(camera_active)
 489         {
 490                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 491         }
 492         else if(autocvar_cl_spawnzoom && zoomin_effect)
 493         {
 494                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 495
 496                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 497                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 498                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 499         }
 500         else
 501         {
 502                 if(zoomspeed < 0) // instant zoom
 503                 {
 504                         if(zoomdir)
 505                                 current_viewzoom = 1 / zoomfactor;
 506                         else
 507                                 current_viewzoom = 1;
 508                 }
 509                 else
 510                 {
 511                         if(zoomdir)
 512                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 513                         else
 514                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 515                 }
 516         }
 517
 518         if(almost_equals(current_viewzoom, 1))
 519                 current_zoomfraction = 0;
 520         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 521                 current_zoomfraction = 1;
 522         else
 523                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 524
 525         if(zoomsensitivity < 1)
 526                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 527         else
 528                 setsensitivityscale(1);
 529
 530         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 531         {
 532                 if(intermission) { curspeed = 0; }
 533                 else
 534                 {
 535
 536                         makevectors(view_angles);
 537                         v = pmove_vel;
 538                         if(csqcplayer)
 539                                 v = csqcplayer.velocity;
 540
 541                         switch(autocvar_cl_velocityzoom_type)
 542                         {
 543                                 case 3: curspeed = max(0, v_forward * v); break;
 544                                 case 2: curspeed = (v_forward * v); break;
 545                                 case 1: default: curspeed = vlen(v); break;
 546                         }
 547                 }
 548
 549                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 550                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 551                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 552
 553                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 554         }
 555         else
 556                 velocityzoom = 1;
 557
 558         float frustumx, frustumy, fovx, fovy;
 559         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 560         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 561         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 562         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 563
 564         return '1 0 0' * fovx + '0 1 0' * fovy;
 565 }
 566
 567 vector GetViewLocationFOV(float fov)
 568 {
 569         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 570         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 571         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 572         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 573         return '1 0 0' * fovx + '0 1 0' * fovy;
 574 }
 575
 576 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 577 {
 578         float fovx, fovy;
 579         float width = (ov_worldmax.x - ov_worldmin.x);
 580         float height = (ov_worldmax.y - ov_worldmin.y);
 581         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 582         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 583         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 584         return '1 0 0' * fovx + '0 1 0' * fovy;
 585 }
 586
 587 // this function must match W_SetupShot!
 588 float zoomscript_caught;
 589
 590 vector wcross_origin;
 591 float wcross_scale_prev, wcross_alpha_prev;
 592 vector wcross_color_prev;
 593 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 594 vector wcross_color_goal_prev;
 595 float wcross_changedonetime;
 596
 597 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 598 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 599 float wcross_name_changestarttime, wcross_name_changedonetime;
 600 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 601
 602 float wcross_ring_prev;
 603
 604 entity trueaim;
 605 entity trueaim_rifle;
 606
 607 const float SHOTTYPE_HITTEAM = 1;
 608 const float SHOTTYPE_HITOBSTRUCTION = 2;
 609 const float SHOTTYPE_HITWORLD = 3;
 610 const float SHOTTYPE_HITENEMY = 4;
 611
 612 void TrueAim_Init()
 613 {
 614         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 615         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 616 }
 617
 618 float EnemyHitCheck()
 619 {
 620         float t, n;
 621         wcross_origin = project_3d_to_2d(trace_endpos);
 622         wcross_origin.z = 0;
 623         if(trace_ent)
 624                 n = trace_ent.entnum;
 625         else
 626                 n = trace_networkentity;
 627         if(n < 1)
 628                 return SHOTTYPE_HITWORLD;
 629         if(n > maxclients)
 630                 return SHOTTYPE_HITWORLD;
 631         t = entcs_GetTeam(n - 1);
 632         if(teamplay)
 633                 if(t == myteam)
 634                         return SHOTTYPE_HITTEAM;
 635         if(t == NUM_SPECTATOR)
 636                 return SHOTTYPE_HITWORLD;
 637         return SHOTTYPE_HITENEMY;
 638 }
 639
 640 float TrueAimCheck(entity wepent)
 641 {
 642         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 643         vector vecs, trueaimpoint, w_shotorg;
 644         vector mi, ma, dv;
 645         float shottype;
 646         entity ta;
 647         float mv;
 648
 649         mi = ma = '0 0 0';
 650         ta = trueaim;
 651         mv = MOVE_NOMONSTERS;
 652
 653         switch(wepent.activeweapon) // WEAPONTODO
 654         {
 655                 case WEP_TUBA: // no aim
 656                 case WEP_PORTO: // shoots from eye
 657                 case WEP_NEXBALL: // shoots from eye
 658                 case WEP_HOOK: // no trueaim
 659                 case WEP_MORTAR: // toss curve
 660                         return SHOTTYPE_HITWORLD;
 661                 case WEP_VORTEX:
 662                 case WEP_VAPORIZER:
 663                         mv = MOVE_NORMAL;
 664                         break;
 665                 case WEP_RIFLE:
 666                         ta = trueaim_rifle;
 667                         mv = MOVE_NORMAL;
 668                         if(zoomscript_caught)
 669                         {
 670                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 671                                 return EnemyHitCheck();
 672                         }
 673                         break;
 674                 case WEP_DEVASTATOR: // projectile has a size!
 675                         mi = '-3 -3 -3';
 676                         ma = '3 3 3';
 677                         break;
 678                 case WEP_FIREBALL: // projectile has a size!
 679                         mi = '-16 -16 -16';
 680                         ma = '16 16 16';
 681                         break;
 682                 case WEP_SEEKER: // projectile has a size!
 683                         mi = '-2 -2 -2';
 684                         ma = '2 2 2';
 685                         break;
 686                 case WEP_ELECTRO: // projectile has a size!
 687                         mi = '0 0 -3';
 688                         ma = '0 0 -3';
 689                         break;
 690         }
 691
 692         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 693
 694         vecs = decompressShotOrigin(STAT(SHOTORG));
 695
 696         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 697         trueaimpoint = trace_endpos;
 698
 699         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 700                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 701
 702         if(vecs.x > 0)
 703                 vecs.y = -vecs.y;
 704         else
 705                 vecs = '0 0 0';
 706
 707         dv = view_right * vecs.y + view_up * vecs.z;
 708         w_shotorg = traceorigin + dv;
 709
 710         // now move the vecs forward as much as requested if possible
 711         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 712         w_shotorg = trace_endpos - view_forward * nudge;
 713
 714         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 715         shottype = EnemyHitCheck();
 716         if(shottype != SHOTTYPE_HITWORLD)
 717                 return shottype;
 718
 719 #if 0
 720         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 721         // or rather, I know why, but see no fix
 722         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 723                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 724                 return SHOTTYPE_HITOBSTRUCTION;
 725 #endif
 726
 727         return SHOTTYPE_HITWORLD;
 728 }
 729
 730 void PostInit();
 731 void CSQC_Demo_Camera();
 732 float camera_mode;
 733 const float CAMERA_FREE = 1;
 734 const float CAMERA_CHASE = 2;
 735 float reticle_type;
 736 string NextFrameCommand;
 737
 738 vector freeze_org, freeze_ang;
 739 entity nightvision_noise, nightvision_noise2;
 740
 741 const float MAX_TIME_DIFF = 5;
 742 float pickup_crosshair_time, pickup_crosshair_size;
 743 float hitindication_crosshair_size;
 744 float use_vortex_chargepool;
 745
 746 float myhealth, myhealth_prev;
 747 float myhealth_flash;
 748
 749 float old_blurradius, old_bluralpha;
 750 float old_sharpen_intensity;
 751
 752 vector myhealth_gentlergb;
 753
 754 float contentavgalpha, liquidalpha_prev;
 755 vector liquidcolor_prev;
 756
 757 float eventchase_current_distance;
 758 float eventchase_running;
 759 bool WantEventchase(entity this)
 760 {
 761         if(autocvar_cl_orthoview)
 762                 return false;
 763         if(STAT(GAME_STOPPED) || intermission)
 764                 return true;
 765         if(this.viewloc)
 766                 return true;
 767         if(spectatee_status >= 0)
 768         {
 769                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 770                         return true;
 771                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 772                         return true;
 773                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 774                 {
 775                         if(autocvar_cl_eventchase_death == 2)
 776                         {
 777                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 778                                 if(this.velocity == '0 0 0' || eventchase_running)
 779                                         return true;
 780                         }
 781                         else return true;
 782                 }
 783         }
 784         return false;
 785 }
 786
 787 void HUD_Crosshair_Vehicle(entity this)
 788 {
 789         if(hud != HUD_BUMBLEBEE_GUN)
 790         {
 791                 Vehicle info = Vehicles_from(hud);
 792                 info.vr_crosshair(info, this);
 793         }
 794 }
 795
 796 vector damage_blurpostprocess, content_blurpostprocess;
 797
 798 float unaccounted_damage = 0;
 799 void UpdateDamage()
 800 {
 801         // accumulate damage with each stat update
 802         static float damage_total_prev = 0;
 803         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 804         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 805         damage_total_prev = damage_total;
 806
 807         static float damage_dealt_time_prev = 0;
 808         float damage_dealt_time = STAT(HIT_TIME);
 809         if (damage_dealt_time != damage_dealt_time_prev)
 810         {
 811                 unaccounted_damage += unaccounted_damage_new;
 812                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 813         }
 814         damage_dealt_time_prev = damage_dealt_time;
 815
 816         // prevent hitsound when switching spectatee
 817         static float spectatee_status_prev = 0;
 818         if (spectatee_status != spectatee_status_prev)
 819                 unaccounted_damage = 0;
 820         spectatee_status_prev = spectatee_status;
 821 }
 822
 823 void HitSound()
 824 {
 825         // varying sound pitch
 826
 827         bool have_arc = false;
 828         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 829         {
 830                 entity wepent = viewmodels[slot];
 831
 832                 if(wepent.activeweapon == WEP_ARC)
 833                         have_arc = true;
 834         }
 835
 836         static float hitsound_time_prev = 0;
 837         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 838         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 839         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 840         {
 841                 if (autocvar_cl_hitsound && unaccounted_damage)
 842                 {
 843                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 844                         float a = autocvar_cl_hitsound_max_pitch;
 845                         float b = autocvar_cl_hitsound_min_pitch;
 846                         float c = autocvar_cl_hitsound_nom_damage;
 847                         float d = unaccounted_damage;
 848                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 849
 850                         // if sound variation is disabled, set pitch_shift to 1
 851                         if (autocvar_cl_hitsound == 1)
 852                                 pitch_shift = 1;
 853
 854                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 855                         if (autocvar_cl_hitsound == 3)
 856                         {
 857                                 float mirror_value = (a-b)/2 + b;
 858                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 859                         }
 860
 861                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 862
 863                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 864                         // todo: normalize sound pressure levels? seems unnecessary
 865
 866                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 867                 }
 868                 unaccounted_damage = 0;
 869                 hitsound_time_prev = time;
 870         }
 871
 872         static float typehit_time_prev = 0;
 873         float typehit_time = STAT(TYPEHIT_TIME);
 874         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 875         {
 876                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 877                 typehit_time_prev = typehit_time;
 878         }
 879
 880         static float kill_time_prev = 0;
 881         float kill_time = STAT(KILL_TIME);
 882         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 883         {
 884                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 885                 kill_time_prev = kill_time;
 886         }
 887 }
 888
 889 vector crosshair_getcolor(entity this, float health_stat)
 890 {
 891         static float rainbow_last_flicker;
 892         static vector rainbow_prev_color;
 893         vector wcross_color = '0 0 0';
 894         switch(autocvar_crosshair_color_special)
 895         {
 896                 case 1: // crosshair_color_per_weapon
 897                 {
 898                         if(this != WEP_Null && hud == HUD_NORMAL)
 899                         {
 900                                 wcross_color = this.wpcolor;
 901                                 break;
 902                         }
 903                         else { goto normalcolor; }
 904                 }
 905
 906                 case 2: // crosshair_color_by_health
 907                 {
 908                         float hp = health_stat;
 909
 910                         //x = red
 911                         //y = green
 912                         //z = blue
 913
 914                         wcross_color.z = 0;
 915
 916                         if(hp > 200)
 917                         {
 918                                 wcross_color.x = 0;
 919                                 wcross_color.y = 1;
 920                         }
 921                         else if(hp > 150)
 922                         {
 923                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 924                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 925                         }
 926                         else if(hp > 100)
 927                         {
 928                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 929                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 930                                 wcross_color.z = 1 - (hp-100)*0.02;
 931                         }
 932                         else if(hp > 50)
 933                         {
 934                                 wcross_color.x = 1;
 935                                 wcross_color.y = 1;
 936                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 937                         }
 938                         else if(hp > 20)
 939                         {
 940                                 wcross_color.x = 1;
 941                                 wcross_color.y = (hp-20)*90/27/100;
 942                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 943                         }
 944                         else
 945                         {
 946                                 wcross_color.x = 1;
 947                                 wcross_color.y = 0;
 948                         }
 949                         break;
 950                 }
 951
 952                 case 3: // crosshair_color_rainbow
 953                 {
 954                         if(time >= rainbow_last_flicker)
 955                         {
 956                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 957                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 958                         }
 959                         wcross_color = rainbow_prev_color;
 960                         break;
 961                 }
 962 LABEL(normalcolor)
 963                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 964         }
 965
 966         return wcross_color;
 967 }
 968
 969 void HUD_Crosshair(entity this)
 970 {
 971         float f, i, j;
 972         vector v;
 973         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 974                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 975                 !HUD_MinigameMenu_IsOpened() )
 976         {
 977                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 978                         return;
 979
 980                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 981                         return;
 982
 983                 if (hud != HUD_NORMAL)
 984                 {
 985                         HUD_Crosshair_Vehicle(this);
 986                         return;
 987                 }
 988
 989                 string wcross_style;
 990                 float wcross_alpha, wcross_resolution;
 991                 wcross_style = autocvar_crosshair;
 992                 if (wcross_style == "0")
 993                         return;
 994                 wcross_resolution = autocvar_crosshair_size;
 995                 if (wcross_resolution == 0)
 996                         return;
 997                 wcross_alpha = autocvar_crosshair_alpha;
 998                 if (wcross_alpha == 0)
 999                         return;
1000
1001                 // TrueAim check
1002                 float shottype;
1003
1004                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1005                 wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1006                 wcross_origin.z = 0;
1007                 if(autocvar_crosshair_hittest)
1008                 {
1009                         vector wcross_oldorigin;
1010                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1011                         wcross_oldorigin = wcross_origin;
1012                         shottype = TrueAimCheck(thiswep);
1013                         if(shottype == SHOTTYPE_HITWORLD)
1014                         {
1015                                 v = wcross_origin - wcross_oldorigin;
1016                                 v.x /= vid_conwidth;
1017                                 v.y /= vid_conheight;
1018                                 if(vdist(v, >, 0.01))
1019                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1020                         }
1021                         if(!autocvar_crosshair_hittest_showimpact)
1022                                 wcross_origin = wcross_oldorigin;
1023                 }
1024                 else
1025                         shottype = SHOTTYPE_HITWORLD;
1026
1027                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1028                 string wcross_name = "";
1029                 float wcross_scale, wcross_blur;
1030
1031         entity e = WEP_Null;
1032                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1033                 {
1034                         entity wepent = viewmodels[0]; // TODO: unhardcode
1035                         e = wepent.switchingweapon;
1036                         if(e)
1037                         {
1038                                 if(autocvar_crosshair_per_weapon)
1039                                 {
1040                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1041                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1042                                         //if (wcross_resolution == 0)
1043                                                 //return;
1044
1045                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1046                                         wcross_resolution *= e.w_crosshair_size;
1047                                         wcross_name = e.w_crosshair;
1048                                 }
1049                         }
1050                 }
1051
1052                 if(wcross_name == "")
1053                         wcross_name = strcat("gfx/crosshair", wcross_style);
1054
1055                 // MAIN CROSSHAIR COLOR DECISION
1056                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1057
1058                 if(autocvar_crosshair_effect_scalefade)
1059                 {
1060                         wcross_scale = wcross_resolution;
1061                         wcross_resolution = 1;
1062                 }
1063                 else
1064                 {
1065                         wcross_scale = 1;
1066                 }
1067
1068                 if(autocvar_crosshair_pickup)
1069                 {
1070                         float stat_pickup_time = STAT(LAST_PICKUP);
1071
1072                         if(pickup_crosshair_time < stat_pickup_time)
1073                         {
1074                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1075                                         pickup_crosshair_size = 1;
1076
1077                                 pickup_crosshair_time = stat_pickup_time;
1078                         }
1079
1080                         if(pickup_crosshair_size > 0)
1081                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1082                         else
1083                                 pickup_crosshair_size = 0;
1084
1085                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1086                 }
1087
1088                 // todo: make crosshair hit indication dependent on damage dealt
1089                 if(autocvar_crosshair_hitindication)
1090                 {
1091                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1092
1093                         if(unaccounted_damage)
1094                         {
1095                                 hitindication_crosshair_size = 1;
1096                         }
1097
1098                         if(hitindication_crosshair_size > 0)
1099                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1100                         else
1101                                 hitindication_crosshair_size = 0;
1102
1103                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1104                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1105                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1106                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1107                 }
1108
1109                 if(shottype == SHOTTYPE_HITENEMY)
1110                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1111                 if(shottype == SHOTTYPE_HITTEAM)
1112                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1113
1114                 f = fabs(autocvar_crosshair_effect_time);
1115                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1116                 {
1117                         wcross_changedonetime = time + f;
1118                 }
1119                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1120                 {
1121                         wcross_name_changestarttime = time;
1122                         wcross_name_changedonetime = time + f;
1123                         if(wcross_name_goal_prev_prev)
1124                                 strunzone(wcross_name_goal_prev_prev);
1125                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1126                         wcross_name_goal_prev = strzone(wcross_name);
1127                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1128                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1129                         wcross_resolution_goal_prev = wcross_resolution;
1130                 }
1131
1132                 wcross_scale_goal_prev = wcross_scale;
1133                 wcross_alpha_goal_prev = wcross_alpha;
1134                 wcross_color_goal_prev = wcross_color;
1135
1136                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1137                 {
1138                         wcross_blur = 1;
1139                         wcross_alpha *= 0.75;
1140                 }
1141                 else
1142                         wcross_blur = 0;
1143                 // *_prev is at time-frametime
1144                 // * is at wcross_changedonetime+f
1145                 // what do we have at time?
1146                 if(time < wcross_changedonetime)
1147                 {
1148                         f = frametime / (wcross_changedonetime - time + frametime);
1149                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1150                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1151                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1152                 }
1153
1154                 wcross_scale_prev = wcross_scale;
1155                 wcross_alpha_prev = wcross_alpha;
1156                 wcross_color_prev = wcross_color;
1157
1158                 MUTATOR_CALLHOOK(UpdateCrosshair);
1159
1160                 wcross_scale *= 1 - autocvar__menu_alpha;
1161                 wcross_alpha *= 1 - autocvar__menu_alpha;
1162                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1163
1164                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1165                 {
1166                         // crosshair rings for weapon stats
1167                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1168                         {
1169                                 // declarations and stats
1170                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1171                                 string ring_image = string_null, ring_inner_image = string_null;
1172                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1173
1174                                 ring_scale = autocvar_crosshair_ring_size;
1175
1176                                 float weapon_clipload, weapon_clipsize;
1177                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1178                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1179
1180                                 float vortex_charge, vortex_chargepool;
1181                                 vortex_charge = STAT(VORTEX_CHARGE);
1182                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1183
1184                                 float arc_heat = STAT(ARC_HEAT);
1185
1186                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1187                                         vortex_charge_movingavg = vortex_charge;
1188
1189                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1190
1191                                 // handle the values
1192                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1193                                 {
1194                                         if (vortex_chargepool || use_vortex_chargepool) {
1195                                                 use_vortex_chargepool = 1;
1196                                                 ring_inner_value = vortex_chargepool;
1197                                         } else {
1198                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1199                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1200                                         }
1201
1202                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1203                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1204                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1205
1206                                         // draw the outer ring to show the current charge of the weapon
1207                                         ring_value = vortex_charge;
1208                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1209                                         ring_rgb = wcross_color;
1210                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1211                                 }
1212                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1213                                 {
1214                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1215                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1216                                         ring_rgb = wcross_color;
1217                                         ring_image = "gfx/crosshair_ring.tga";
1218                                 }
1219                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1220                                 {
1221                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1222                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1223                                         ring_rgb = wcross_color;
1224                                         ring_image = "gfx/crosshair_ring.tga";
1225                                 }
1226                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1227                                 {
1228                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1229                                         ring_scale = autocvar_crosshair_ring_reload_size;
1230                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1231                                         ring_rgb = wcross_color;
1232
1233                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1234                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1235                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1236                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1237                                         else
1238                                                 ring_image = "gfx/crosshair_ring.tga";
1239                                 }
1240                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1241                                 {
1242                                         ring_value = arc_heat;
1243                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1244                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1245                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1246                                         ring_image = "gfx/crosshair_ring.tga";
1247                                 }
1248
1249                                 // if in weapon switch animation, fade ring out/in
1250                                 if(autocvar_crosshair_effect_time > 0)
1251                                 {
1252                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1253                                         if (f >= 1)
1254                                         {
1255                                                 wcross_ring_prev = ((ring_image) ? true : false);
1256                                         }
1257
1258                                         if(wcross_ring_prev)
1259                                         {
1260                                                 if(f < 1)
1261                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1262                                         }
1263                                         else
1264                                         {
1265                                                 if(f < 1)
1266                                                         ring_alpha *= bound(0, f, 1);
1267                                         }
1268                                 }
1269
1270                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1271                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1272
1273                                 if (ring_value)
1274                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1275                         }
1276
1277 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1278                         MACRO_BEGIN { \
1279                                 if(wcross_blur > 0) \
1280                                 { \
1281                                         for(i = -2; i <= 2; ++i) \
1282                                         for(j = -2; j <= 2; ++j) \
1283                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1284                                 } \
1285                                 else \
1286                                 { \
1287                                         M(0,0,sz,wcross_name,wcross_alpha); \
1288                                 } \
1289                         } MACRO_END
1290
1291 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1292                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1293
1294 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1295                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1296
1297                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1298                         {
1299                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1300                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1301                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1302                                 f = 1 - f;
1303                         }
1304                         else
1305                         {
1306                                 f = 1;
1307                         }
1308                         wcross_name_alpha_goal_prev = f;
1309
1310                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1311                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1312
1313                         if(autocvar_crosshair_dot)
1314                         {
1315                                 vector wcross_color_old;
1316                                 wcross_color_old = wcross_color;
1317
1318                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1319                                         wcross_color = stov(autocvar_crosshair_dot_color);
1320
1321                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1322                                 // FIXME why don't we use wcross_alpha here?
1323                                 wcross_color = wcross_color_old;
1324                         }
1325                 }
1326         }
1327         else
1328         {
1329                 wcross_scale_prev = 0;
1330                 wcross_alpha_prev = 0;
1331                 wcross_scale_goal_prev = 0;
1332                 wcross_alpha_goal_prev = 0;
1333                 wcross_changedonetime = 0;
1334                 if(wcross_name_goal_prev)
1335                         strunzone(wcross_name_goal_prev);
1336                 wcross_name_goal_prev = string_null;
1337                 if(wcross_name_goal_prev_prev)
1338                         strunzone(wcross_name_goal_prev_prev);
1339                 wcross_name_goal_prev_prev = string_null;
1340                 wcross_name_changestarttime = 0;
1341                 wcross_name_changedonetime = 0;
1342                 wcross_name_alpha_goal_prev = 0;
1343                 wcross_name_alpha_goal_prev_prev = 0;
1344                 wcross_resolution_goal_prev = 0;
1345                 wcross_resolution_goal_prev_prev = 0;
1346         }
1347 }
1348
1349 void HUD_Draw(entity this)
1350 {
1351         // if we don't know gametype and scores yet avoid drawing the scoreboard
1352         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1353         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1354         // cl_deathscoreboard would show the scoreboard and so on
1355         if(!gametype)
1356                 return;
1357
1358         if(!intermission)
1359         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1360         {
1361                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1362         }
1363         else if(STAT(FROZEN))
1364         {
1365                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1366         }
1367         if(!intermission)
1368         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1369         {
1370                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1371                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1372         }
1373         else if(STAT(CAPTURE_PROGRESS))
1374         {
1375                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1376                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1377         }
1378         else if(STAT(REVIVE_PROGRESS))
1379         {
1380                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1381                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1382         }
1383
1384         if(autocvar_r_letterbox == 0)
1385                 if(autocvar_viewsize < 120)
1386                 {
1387                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1388                                 Accuracy_LoadLevels();
1389
1390                         HUD_Main();
1391                         HUD_Scale_Disable();
1392                 }
1393
1394         // crosshair goes VERY LAST
1395         UpdateDamage();
1396         HUD_Crosshair(this);
1397         HitSound();
1398 }
1399
1400 bool ov_enabled;
1401 float oldr_nearclip;
1402 float oldr_farclip_base;
1403 float oldr_farclip_world;
1404 float oldr_novis;
1405 float oldr_useportalculling;
1406 float oldr_useinfinitefarclip;
1407
1408 void cl_notice_run();
1409
1410 float prev_myteam;
1411 int lasthud;
1412 float vh_notice_time;
1413 void WaypointSprite_Load();
1414 void CSQC_UpdateView(entity this, float w, float h)
1415 {
1416     TC(int, w); TC(int, h);
1417         entity e;
1418         float fov;
1419         float f;
1420         vector vf_size, vf_min;
1421         float a;
1422
1423         execute_next_frame();
1424
1425         ++framecount;
1426
1427         stats_get();
1428         hud = STAT(HUD);
1429
1430         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1431                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1432
1433         lasthud = hud;
1434
1435         HUD_Scale_Disable();
1436
1437         if(autocvar__hud_showbinds_reload) // menu can set this one
1438         {
1439                 db_close(binddb);
1440                 binddb = db_create();
1441                 cvar_set("_hud_showbinds_reload", "0");
1442         }
1443
1444         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1445                 view_quality = getproperty(VF_MINFPS_QUALITY);
1446         else
1447                 view_quality = 1;
1448
1449         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1450         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1451
1452         vf_size = getpropertyvec(VF_SIZE);
1453         vf_min = getpropertyvec(VF_MIN);
1454         vid_width = vf_size.x;
1455         vid_height = vf_size.y;
1456
1457         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1458         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1459
1460         WaypointSprite_Load();
1461
1462         CSQCPlayer_SetCamera();
1463
1464         if(player_localentnum <= maxclients) // is it a client?
1465                 current_player = player_localentnum - 1;
1466         else // then player_localentnum is the vehicle I'm driving
1467                 current_player = player_localnum;
1468         myteam = entcs_GetTeam(current_player);
1469
1470         if(myteam != prev_myteam)
1471         {
1472                 myteamcolors = colormapPaletteColor(myteam, 1);
1473                 FOREACH(hud_panels, true, it.update_time = time);
1474                 prev_myteam = myteam;
1475         }
1476
1477         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1478
1479         float is_dead = (STAT(HEALTH) <= 0);
1480
1481         // FIXME do we need this hack?
1482         if(isdemo())
1483         {
1484                 // in demos, input_buttons do not work
1485                 button_zoom = (autocvar__togglezoom == "-");
1486         }
1487         else if(button_zoom
1488                 && autocvar_cl_unpress_zoom_on_death
1489                 && (spectatee_status >= 0)
1490                 && (is_dead || intermission))
1491         {
1492                 // no zoom while dead or in intermission please
1493                 localcmd("-zoom\n");
1494                 button_zoom = false;
1495         }
1496
1497         // event chase camera
1498         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1499         {
1500                 if(STAT(CAMERA_SPECTATOR))
1501                 {
1502                         if(spectatee_status > 0)
1503                         {
1504                                 if(!autocvar_chase_active)
1505                                 {
1506                                         cvar_set("chase_active", "-2");
1507                                         goto skip_eventchase_death;
1508                                 }
1509                         }
1510                         else if(autocvar_chase_active == -2)
1511                                 cvar_set("chase_active", "0");
1512
1513                         if(autocvar_chase_active == -2)
1514                                 goto skip_eventchase_death;
1515                 }
1516                 else if(autocvar_chase_active == -2)
1517                         cvar_set("chase_active", "0");
1518
1519                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1520
1521                 float vehicle_viewdist = 0;
1522                 vector vehicle_viewofs = '0 0 0';
1523
1524                 if(vehicle_chase)
1525                 {
1526                         if(hud != HUD_BUMBLEBEE_GUN)
1527                         {
1528                                 Vehicle info = Vehicles_from(hud);
1529                                 vehicle_viewdist = info.height;
1530                                 vehicle_viewofs = info.view_ofs;
1531                         }
1532                 }
1533
1534                 if(WantEventchase(this))
1535                 {
1536                         vector current_view_origin_override = '0 0 0';
1537                         vector view_offset_override = '0 0 0';
1538                         float chase_distance_override = 0;
1539                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1540                         if(custom_eventchase)
1541                         {
1542                                 current_view_origin_override = M_ARGV(0, vector);
1543                                 view_offset_override = M_ARGV(1, vector);
1544                                 chase_distance_override = M_ARGV(0, float);
1545                         }
1546                         eventchase_running = true;
1547
1548                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1549                         if(!local_player)
1550                                 local_player = this; // fall back!
1551
1552                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1553                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1554                         if (custom_eventchase)
1555                                 current_view_origin = current_view_origin_override;
1556
1557                         // detect maximum viewoffset and use it
1558                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1559                         if(vehicle_chase)
1560                         {
1561                                 if(vehicle_viewofs)
1562                                         view_offset = vehicle_viewofs;
1563                                 else
1564                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1565                         }
1566                         if (custom_eventchase)
1567                                 view_offset = view_offset_override;
1568
1569                         if(view_offset)
1570                         {
1571                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1572                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1573                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1574                         }
1575
1576                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1577                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1578                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1579                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1580
1581                         // make the camera smooth back
1582                         float chase_distance = autocvar_cl_eventchase_distance;
1583                         if(vehicle_chase)
1584                         {
1585                                 if(vehicle_viewofs)
1586                                         chase_distance = vehicle_viewdist;
1587                                 else
1588                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1589                         }
1590                         if (custom_eventchase)
1591                                 chase_distance = chase_distance_override;
1592
1593                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1594                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1595                         else if(eventchase_current_distance != chase_distance)
1596                                 eventchase_current_distance = chase_distance;
1597
1598                         makevectors(view_angles);
1599
1600                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1601                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1602
1603                         // If the boxtrace fails, revert back to line tracing.
1604                         if(!local_player.viewloc)
1605                         if(trace_startsolid)
1606                         {
1607                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1608                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1609                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1610                         }
1611                         else { setproperty(VF_ORIGIN, trace_endpos); }
1612
1613                         if(!local_player.viewloc)
1614                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1615                 }
1616                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1617                 {
1618                         eventchase_running = false;
1619                         cvar_set("chase_active", "0");
1620                         eventchase_current_distance = 0; // start from 0 next time
1621                 }
1622         }
1623         // workaround for camera stuck between player's legs when using chase_active 1
1624         // because the engine stops updating the chase_active camera when the game ends
1625         else if(intermission)
1626         {
1627                 cvar_settemp("chase_active", "-1");
1628                 eventchase_current_distance = 0;
1629         }
1630
1631         LABEL(skip_eventchase_death);
1632
1633         // do lockview after event chase camera so that it still applies whenever necessary.
1634         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1635         {
1636                 setproperty(VF_ORIGIN, freeze_org);
1637                 setproperty(VF_ANGLES, freeze_ang);
1638         }
1639         else
1640         {
1641                 freeze_org = getpropertyvec(VF_ORIGIN);
1642                 freeze_ang = getpropertyvec(VF_ANGLES);
1643         }
1644
1645         WarpZone_FixView();
1646         //WarpZone_FixPMove();
1647
1648         vector ov_org = '0 0 0';
1649         vector ov_mid = '0 0 0';
1650         vector ov_worldmin = '0 0 0';
1651         vector ov_worldmax = '0 0 0';
1652         if(autocvar_cl_orthoview)
1653         {
1654                 ov_worldmin = mi_picmin;
1655                 ov_worldmax = mi_picmax;
1656
1657                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1658                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1659                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1660
1661                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1662                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1663
1664                 float ov_nearest = vlen(ov_org - vec3(
1665                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1666                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1667                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1668                 ));
1669
1670                 float ov_furthest = 0;
1671                 float dist = 0;
1672
1673                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1674                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1675                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1676                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1677                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1678                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1679                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1680                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1681
1682                 if(!ov_enabled)
1683                 {
1684                         oldr_nearclip = cvar("r_nearclip");
1685                         oldr_farclip_base = cvar("r_farclip_base");
1686                         oldr_farclip_world = cvar("r_farclip_world");
1687                         oldr_novis = cvar("r_novis");
1688                         oldr_useportalculling = cvar("r_useportalculling");
1689                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1690                 }
1691
1692                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1693                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1694                 cvar_settemp("r_farclip_world", "0");
1695                 cvar_settemp("r_novis", "1");
1696                 cvar_settemp("r_useportalculling", "0");
1697                 cvar_settemp("r_useinfinitefarclip", "0");
1698
1699                 setproperty(VF_ORIGIN, ov_org);
1700                 setproperty(VF_ANGLES, '90 0 0');
1701
1702                 ov_enabled = true;
1703
1704                 #if 0
1705                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1706                         vtos(ov_org),
1707                         vtos(getpropertyvec(VF_ANGLES)),
1708                         ov_distance,
1709                         ov_nearest,
1710                         ov_furthest);
1711                 #endif
1712         }
1713         else
1714         {
1715                 if(ov_enabled)
1716                 {
1717                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1718                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1719                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1720                         cvar_set("r_novis", ftos(oldr_novis));
1721                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1722                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1723                 }
1724                 ov_enabled = false;
1725         }
1726
1727         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1728         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1729         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1730                 viewmodel_draw(viewmodels[slot]);
1731
1732         // Render the Scene
1733         view_origin = getpropertyvec(VF_ORIGIN);
1734         view_angles = getpropertyvec(VF_ANGLES);
1735         makevectors(view_angles);
1736         view_forward = v_forward;
1737         view_right = v_right;
1738         view_up = v_up;
1739
1740 #ifdef BLURTEST
1741         if(time > blurtest_time0 && time < blurtest_time1)
1742         {
1743                 float r, t;
1744
1745                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1746                 r = t * blurtest_radius;
1747                 f = 1 / (t ** blurtest_power) - 1;
1748
1749                 cvar_set("r_glsl_postprocess", "1");
1750                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1751         }
1752         else
1753         {
1754                 cvar_set("r_glsl_postprocess", "0");
1755                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1756         }
1757 #endif
1758
1759         TargetMusic_Advance();
1760         Fog_Force();
1761
1762         if(drawtime == 0)
1763                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1764         else
1765                 drawframetime = bound(0.000001, time - drawtime, 1);
1766         drawtime = time;
1767
1768         // watch for gametype changes here...
1769         // in ParseStuffCMD the cmd isn't executed yet :/
1770         // might even be better to add the gametype to TE_CSQC_INIT...?
1771         if(!postinit)
1772                 PostInit();
1773
1774         if(intermission && !intermission_time)
1775                 intermission_time = time;
1776
1777         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1778         {
1779                 if(calledhooks & HOOK_START)
1780                 {
1781                         localcmd("\ncl_hook_gameend\n");
1782                         calledhooks |= HOOK_END;
1783                 }
1784         }
1785
1786         Announcer();
1787
1788         fov = autocvar_fov;
1789         if(fov <= 59.5)
1790         {
1791                 if(!zoomscript_caught)
1792                 {
1793                         localcmd("+button9\n");
1794                         zoomscript_caught = 1;
1795                 }
1796         }
1797         else
1798         {
1799                 if(zoomscript_caught)
1800                 {
1801                         localcmd("-button9\n");
1802                         zoomscript_caught = 0;
1803                 }
1804         }
1805
1806         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1807
1808         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1809         {
1810                 entity wepent = viewmodels[slot];
1811
1812                 if(wepent.last_switchweapon != wepent.switchweapon)
1813                 {
1814                         weapontime = time;
1815                         wepent.last_switchweapon = wepent.switchweapon;
1816                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1817                         {
1818                                 localcmd("-zoom\n");
1819                                 button_zoom = false;
1820                         }
1821                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1822                         {
1823                                 localcmd("-fire\n");
1824                                 localcmd("-fire2\n");
1825                                 button_attack2 = false;
1826                         }
1827                 }
1828                 if(wepent.last_activeweapon != wepent.activeweapon)
1829                 {
1830                         wepent.last_activeweapon = wepent.activeweapon;
1831
1832                         e = wepent.activeweapon;
1833                         if(e.netname != "")
1834                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1835                         else if(slot == 0)
1836                                 localcmd("\ncl_hook_activeweapon none\n");
1837                 }
1838         }
1839
1840         // ALWAYS Clear Current Scene First
1841         clearscene();
1842
1843         setproperty(VF_ORIGIN, view_origin);
1844         setproperty(VF_ANGLES, view_angles);
1845
1846         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1847         setproperty(VF_SIZE, vf_size);
1848         setproperty(VF_MIN, vf_min);
1849
1850         // Assign Standard Viewflags
1851         // Draw the World (and sky)
1852         setproperty(VF_DRAWWORLD, 1);
1853
1854         // Set the console size vars
1855         vid_conwidth = autocvar_vid_conwidth;
1856         vid_conheight = autocvar_vid_conheight;
1857         vid_pixelheight = autocvar_vid_pixelheight;
1858
1859         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1860         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1861         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1862
1863         if(camera_active) // Camera for demo playback
1864         {
1865                 if(autocvar_camera_enable)
1866                         CSQC_Demo_Camera();
1867                 else
1868                 {
1869                         cvar_set("chase_active", ftos(chase_active_backup));
1870                         cvar_set("cl_demo_mousegrab", "0");
1871                         camera_active = false;
1872                 }
1873         }
1874         else
1875         {
1876 #ifdef CAMERATEST
1877                 if(autocvar_camera_enable)
1878 #else
1879                 if(autocvar_camera_enable && isdemo())
1880 #endif
1881                 {
1882                         // Enable required Darkplaces cvars
1883                         chase_active_backup = autocvar_chase_active;
1884                         cvar_set("chase_active", "2");
1885                         cvar_set("cl_demo_mousegrab", "1");
1886                         camera_active = true;
1887                         camera_mode = false;
1888                 }
1889         }
1890
1891         // Draw the Crosshair
1892         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1893
1894         // Draw the Engine Status Bar (the default Quake HUD)
1895         setproperty(VF_DRAWENGINESBAR, 0);
1896
1897         // Update the mouse position
1898         /*
1899            mousepos_x = vid_conwidth;
1900            mousepos_y = vid_conheight;
1901            mousepos = mousepos*0.5 + getmousepos();
1902          */
1903
1904         IL_EACH(g_drawables, it.draw, it.draw(it));
1905
1906         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1907         renderscene();
1908
1909         // now switch to 2D drawing mode by calling a 2D drawing function
1910         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1911         // next R_RenderScene call
1912         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1913
1914         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1915         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1916         {
1917                 // apply night vision effect
1918                 vector tc_00, tc_01, tc_10, tc_11;
1919                 vector rgb = '0 0 0';
1920
1921                 if(!nightvision_noise)
1922                 {
1923                         nightvision_noise = new(nightvision_noise);
1924                 }
1925                 if(!nightvision_noise2)
1926                 {
1927                         nightvision_noise2 = new(nightvision_noise2);
1928                 }
1929
1930                 // color tint in yellow
1931                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1932
1933                 // draw BG
1934                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1935                 rgb = '1 1 1';
1936                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1937                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1938                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1939                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1940                 tc_11 = tc_01 + tc_10 - tc_00;
1941                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1942                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1943                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1944                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1945                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1946                 R_EndPolygon();
1947
1948                 // draw FG
1949                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1950                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1951                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1952                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1953                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1954                 tc_11 = tc_01 + tc_10 - tc_00;
1955                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1956                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1957                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1958                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1959                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1960                 R_EndPolygon();
1961         }
1962
1963         if(autocvar_cl_reticle)
1964         {
1965                 string reticle_image = string_null;
1966                 bool wep_zoomed = false;
1967                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1968                 {
1969                         entity wepe = viewmodels[slot];
1970                         Weapon wep = wepe.activeweapon;
1971                         if(wep != WEP_Null && wep.wr_zoom)
1972                         {
1973                                 bool do_zoom = wep.wr_zoom(wep, NULL);
1974                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
1975                                         reticle_image = wep.w_reticle;
1976                                 wep_zoomed += do_zoom;
1977                         }
1978                 }
1979                 // Draw the aiming reticle for weapons that use it
1980                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1981                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1982                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1983                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1984                 {
1985                         // no zoom reticle while dead
1986                         reticle_type = 0;
1987                 }
1988                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
1989                 {
1990                         if(reticle_image) { reticle_type = 2; }
1991                         else { reticle_type = 0; }
1992                 }
1993                 else if(button_zoom || zoomscript_caught)
1994                 {
1995                         // normal zoom
1996                         reticle_type = 1;
1997                 }
1998
1999                 if(reticle_type)
2000                 {
2001                         if(autocvar_cl_reticle_stretch)
2002                         {
2003                                 reticle_size.x = vid_conwidth;
2004                                 reticle_size.y = vid_conheight;
2005                                 reticle_pos.x = 0;
2006                                 reticle_pos.y = 0;
2007                         }
2008                         else
2009                         {
2010                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2011                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2012                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2013                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2014                         }
2015
2016                         if(zoomscript_caught)
2017                                 f = 1;
2018                         else
2019                                 f = current_zoomfraction;
2020
2021                         if(f)
2022                         {
2023                                 switch(reticle_type)
2024                                 {
2025                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2026                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2027                                 }
2028                         }
2029                 }
2030         }
2031         else
2032         {
2033                 if(reticle_type != 0) { reticle_type = 0; }
2034         }
2035
2036
2037         // improved polyblend
2038         if(autocvar_hud_contents)
2039         {
2040                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2041                 vector liquidcolor;
2042
2043                 switch(pointcontents(view_origin))
2044                 {
2045                         case CONTENT_WATER:
2046                                 liquidalpha = autocvar_hud_contents_water_alpha;
2047                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2048                                 incontent = 1;
2049                                 break;
2050
2051                         case CONTENT_LAVA:
2052                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2053                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2054                                 incontent = 1;
2055                                 break;
2056
2057                         case CONTENT_SLIME:
2058                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2059                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2060                                 incontent = 1;
2061                                 break;
2062
2063                         default:
2064                                 liquidalpha = 0;
2065                                 liquidcolor = '0 0 0';
2066                                 incontent = 0;
2067                                 break;
2068                 }
2069
2070                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2071                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2072                         contentfadetime = autocvar_hud_contents_fadeintime;
2073                         liquidalpha_prev = liquidalpha;
2074                         liquidcolor_prev = liquidcolor;
2075                 }
2076                 else
2077                         contentfadetime = autocvar_hud_contents_fadeouttime;
2078
2079                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2080                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2081
2082                 if(contentavgalpha)
2083                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2084
2085                 if(autocvar_hud_postprocessing)
2086                 {
2087                         if(autocvar_hud_contents_blur && contentavgalpha)
2088                         {
2089                                 content_blurpostprocess.x = 1;
2090                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2091                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2092                         }
2093                         else
2094                         {
2095                                 content_blurpostprocess.x = 0;
2096                                 content_blurpostprocess.y = 0;
2097                                 content_blurpostprocess.z = 0;
2098                         }
2099                 }
2100         }
2101
2102         if(autocvar_hud_damage && !STAT(FROZEN))
2103         {
2104                 splash_size.x = max(vid_conwidth, vid_conheight);
2105                 splash_size.y = max(vid_conwidth, vid_conheight);
2106                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2107                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2108
2109                 float myhealth_flash_temp;
2110                 myhealth = STAT(HEALTH);
2111
2112                 // fade out
2113                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2114                 // add new damage
2115                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2116
2117                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2118                 pain_threshold = autocvar_hud_damage_pain_threshold;
2119                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2120                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2121
2122                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2123                 {
2124                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2125                 }
2126
2127                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2128
2129                 if(myhealth_prev < 1)
2130                 {
2131                         if(myhealth >= 1)
2132                         {
2133                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2134                                 myhealth_flash_temp = 0;
2135                         }
2136                         else
2137                         {
2138                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2139                         }
2140                 }
2141
2142                 if(spectatee_status == -1 || intermission)
2143                 {
2144                         myhealth_flash = 0; // observing, or match ended
2145                         myhealth_flash_temp = 0;
2146                 }
2147
2148                 myhealth_prev = myhealth;
2149
2150                 // IDEA: change damage color/picture based on player model for robot/alien species?
2151                 // pro: matches model better
2152                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2153                 // maybe different reddish pics?
2154                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2155                 {
2156                         if(autocvar_cl_gentle_damage == 2)
2157                         {
2158                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2159                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2160                         }
2161                         else
2162                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2163
2164                         if(myhealth_flash_temp > 0)
2165                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2166                 }
2167                 else if(myhealth_flash_temp > 0)
2168                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2169
2170                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2171                 {
2172                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2173                         {
2174                                 damage_blurpostprocess.x = 1;
2175                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2176                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2177                         }
2178                         else
2179                         {
2180                                 damage_blurpostprocess.x = 0;
2181                                 damage_blurpostprocess.y = 0;
2182                                 damage_blurpostprocess.z = 0;
2183                         }
2184                 }
2185         }
2186
2187         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2188         float e2 = (autocvar_hud_powerup != 0);
2189         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2190         {
2191                 // enable or disable rendering types if they are used or not
2192                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2193                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2194
2195                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2196                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2197                 {
2198                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2199                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2200                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2201                         {
2202                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2203                                 old_blurradius = blurradius;
2204                                 old_bluralpha = bluralpha;
2205                         }
2206                 }
2207                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2208                 {
2209                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2210                         old_blurradius = 0;
2211                         old_bluralpha = 0;
2212                 }
2213
2214                 // edge detection postprocess handling done second (used by hud_powerup)
2215                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2216                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2217                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2218
2219                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2220
2221                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2222                 {
2223                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2224                         {
2225                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2226                                 old_sharpen_intensity = sharpen_intensity;
2227                         }
2228                 }
2229                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2230                 {
2231                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2232                         old_sharpen_intensity = 0;
2233                 }
2234
2235                 if(cvar("r_glsl_postprocess") == 0)
2236                         cvar_set("r_glsl_postprocess", "2");
2237         }
2238         else if(cvar("r_glsl_postprocess") == 2)
2239                 cvar_set("r_glsl_postprocess", "0");
2240
2241         /*if(gametype == MAPINFO_TYPE_CTF)
2242           {
2243           ctf_view();
2244           } else */
2245
2246         // draw 2D entities
2247         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2248         Draw_ShowNames_All();
2249 #ifdef DEBUGDRAW
2250         Debug_Draw();
2251 #endif
2252
2253         scoreboard_active = Scoreboard_WouldDraw();
2254
2255         HUD_Draw(this); // this parameter for deep vehicle function
2256
2257         if(NextFrameCommand)
2258         {
2259                 localcmd("\n", NextFrameCommand, "\n");
2260                 NextFrameCommand = string_null;
2261         }
2262
2263         // we must do this check AFTER a frame was rendered, or it won't work
2264         if(cs_project_is_b0rked == 0)
2265         {
2266                 string w0, h0;
2267                 w0 = ftos(autocvar_vid_conwidth);
2268                 h0 = ftos(autocvar_vid_conheight);
2269                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2270                 //setproperty(VF_FOV, '90 90 0');
2271                 setproperty(VF_ORIGIN, '0 0 0');
2272                 setproperty(VF_ANGLES, '0 0 0');
2273                 setproperty(VF_PERSPECTIVE, 1);
2274                 makevectors('0 0 0');
2275                 vector v1, v2;
2276                 cvar_set("vid_conwidth", "800");
2277                 cvar_set("vid_conheight", "600");
2278                 v1 = cs_project(v_forward);
2279                 cvar_set("vid_conwidth", "640");
2280                 cvar_set("vid_conheight", "480");
2281                 v2 = cs_project(v_forward);
2282                 if(v1 == v2)
2283                         cs_project_is_b0rked = 1;
2284                 else
2285                         cs_project_is_b0rked = -1;
2286                 cvar_set("vid_conwidth", w0);
2287                 cvar_set("vid_conheight", h0);
2288         }
2289
2290         if(autocvar__hud_configure)
2291                 HUD_Panel_Mouse();
2292         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2293                 HUD_Minigame_Mouse();
2294         else if(QuickMenu_IsOpened())
2295                 QuickMenu_Mouse();
2296         else
2297                 HUD_Radar_Mouse();
2298
2299         cl_notice_run();
2300         unpause_update();
2301         Net_Flush();
2302
2303         // let's reset the view back to normal for the end
2304         setproperty(VF_MIN, '0 0 0');
2305         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2306
2307         IL_ENDFRAME();
2308 }
2309
2310
2311 // following vectors must be global to allow seamless switching between camera modes
2312 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2313 void CSQC_Demo_Camera()
2314 {
2315         float speed, attenuation, dimensions;
2316         vector tmp, delta;
2317
2318         if( autocvar_camera_reset || !camera_mode )
2319         {
2320                 camera_offset = '0 0 0';
2321                 current_angles = '0 0 0';
2322                 camera_direction = '0 0 0';
2323                 camera_offset.z += 30;
2324                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2325                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2326                 current_origin = view_origin;
2327                 current_camera_offset  = camera_offset;
2328                 cvar_set("camera_reset", "0");
2329                 camera_mode = CAMERA_CHASE;
2330         }
2331
2332         // Camera angles
2333         if( camera_roll )
2334                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2335
2336         if(autocvar_camera_look_player)
2337         {
2338                 vector dir;
2339                 float n;
2340
2341                 dir = normalize(view_origin - current_position);
2342                 n = mouse_angles.z;
2343                 mouse_angles = vectoangles(dir);
2344                 mouse_angles.x = mouse_angles.x * -1;
2345                 mouse_angles.z = n;
2346         }
2347         else
2348         {
2349                 tmp = getmousepos() * 0.1;
2350                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2351                 {
2352                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2353                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2354                 }
2355         }
2356
2357         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2358         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2359         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2360         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2361
2362         // Fix difference when angles don't have the same sign
2363         delta = '0 0 0';
2364         if(mouse_angles.y < -60 && current_angles.y > 60)
2365                 delta = '0 360 0';
2366         if(mouse_angles.y > 60 && current_angles.y < -60)
2367                 delta = '0 -360 0';
2368
2369         if(autocvar_camera_look_player)
2370                 attenuation = autocvar_camera_look_attenuation;
2371         else
2372                 attenuation = autocvar_camera_speed_attenuation;
2373
2374         attenuation = 1 / max(1, attenuation);
2375         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2376
2377         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2378         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2379         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2380         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2381
2382         // Camera position
2383         tmp = '0 0 0';
2384         dimensions = 0;
2385
2386         if( camera_direction.x )
2387         {
2388                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2389                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2390                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2391                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2392                 ++dimensions;
2393         }
2394
2395         if( camera_direction.y )
2396         {
2397                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2398                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2399                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2400                 ++dimensions;
2401         }
2402
2403         if( camera_direction.z )
2404         {
2405                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2406                 ++dimensions;
2407         }
2408
2409         if(autocvar_camera_free)
2410                 speed = autocvar_camera_speed_free;
2411         else
2412                 speed = autocvar_camera_speed_chase;
2413
2414         if(dimensions)
2415         {
2416                 speed = speed * sqrt(1 / dimensions);
2417                 camera_offset += tmp * speed;
2418         }
2419
2420         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2421
2422         // Camera modes
2423         if( autocvar_camera_free )
2424         {
2425                 if ( camera_mode == CAMERA_CHASE )
2426                 {
2427                         current_camera_offset = current_origin + current_camera_offset;
2428                         camera_offset = current_origin + camera_offset;
2429                 }
2430
2431                 camera_mode = CAMERA_FREE;
2432                 current_position = current_camera_offset;
2433         }
2434         else
2435         {
2436                 if ( camera_mode == CAMERA_FREE )
2437                 {
2438                         current_origin = view_origin;
2439                         camera_offset = camera_offset - current_origin;
2440                         current_camera_offset = current_camera_offset - current_origin;
2441                 }
2442
2443                 camera_mode = CAMERA_CHASE;
2444
2445                 if(autocvar_camera_chase_smoothly)
2446                         current_origin += (view_origin - current_origin) * attenuation;
2447                 else
2448                         current_origin = view_origin;
2449
2450                 current_position = current_origin + current_camera_offset;
2451         }
2452
2453         setproperty(VF_ANGLES, current_angles);
2454         setproperty(VF_ORIGIN, current_position);
2455 }