qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  81 MACRO_END
  82
  83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  84         float __f = 0; lowpass(value, frac, ref_store, __f); \
  85         ret = (value) - __f; \
  86 MACRO_END
  87
  88 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  90         ret = (value) - __f; \
  91 MACRO_END
  92
  93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99         highpass(value.x, frac, ref_store.x, ref_out.x); \
 100         highpass(value.y, frac, ref_store.y, ref_out.y); \
 101 MACRO_END
 102
 103 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 104         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 105         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 106 MACRO_END
 107
 108 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 112 MACRO_END
 113
 114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 137                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 138                 vel.x = view.velocity * forward;
 139                 vel.y = view.velocity * right * -1;
 140                 vel.z = view.velocity * up;
 141         }
 142
 143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 146
 147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 148         lowpass3(vel, frac, vel_average, gunorg);
 149
 150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 151
 152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 154         frac = avg_factor(autocvar_cl_followmodel_highpass);
 155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 158
 159         if (autocvar_cl_followmodel_velocity_absolute)
 160         {
 161                 vector fixed_gunorg;
 162                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 163                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 164                 fixed_gunorg.x = gunorg * forward;
 165                 fixed_gunorg.y = gunorg * right * -1;
 166                 fixed_gunorg.z = gunorg * up;
 167                 gunorg = fixed_gunorg;
 168         }
 169
 170         cl_followmodel_ofs = gunorg;
 171         cl_followmodel_time = time;
 172 }
 173
 174 vector leanmodel_ofs(entity view)
 175 {
 176         float frac;
 177         vector gunangles = '0 0 0';
 178         static vector gunangles_prev = '0 0 0';
 179         static vector gunangles_highpass = '0 0 0';
 180         static vector gunangles_adjustment_highpass;
 181         static vector gunangles_adjustment_lowpass;
 182
 183         if (view.csqcmodel_teleported)
 184                 gunangles_prev = view_angles;
 185
 186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 187         gunangles_highpass += gunangles_prev;
 188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 193         gunangles_prev = view_angles;
 194         gunangles_highpass -= gunangles_prev;
 195
 196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 206
 207         return gunangles;
 208 }
 209
 210 vector bobmodel_ofs(entity view)
 211 {
 212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 213         static bool oldonground;
 214         static float hitgroundtime;
 215         if (clonground)
 216         {
 217                 float f = time; // cl.movecmd[0].time
 218                 if (!oldonground)
 219                         hitgroundtime = f;
 220         }
 221         oldonground = clonground;
 222
 223         // calculate for swinging gun model
 224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 225         vector gunorg = '0 0 0';
 226         static float bobmodel_scale = 0;
 227         static float time_ofs = 0; // makes the effect always restart in the same way
 228         if (clonground)
 229         {
 230                 if (time - hitgroundtime > 0.05)
 231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 232         }
 233         else
 234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 235
 236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 237         if (bobmodel_scale && xyspeed)
 238         {
 239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 243         }
 244         else
 245                 time_ofs = time;
 246
 247         return gunorg;
 248 }
 249
 250 void viewmodel_animate(entity this)
 251 {
 252         if (autocvar_chase_active) return;
 253         if (STAT(HEALTH) <= 0) return;
 254
 255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 256
 257         if (autocvar_cl_followmodel)
 258         {
 259                 calc_followmodel_ofs(view);
 260                 this.origin += cl_followmodel_ofs;
 261         }
 262
 263         if (autocvar_cl_leanmodel)
 264                 this.angles += leanmodel_ofs(view);
 265
 266         // vertical view bobbing code
 267         // TODO: cl_bob
 268
 269         // horizontal view bobbing code
 270         // TODO: cl_bob2
 271
 272         // fall bobbing code
 273         // causes the view to swing down and back up when touching the ground
 274         // TODO: cl_bobfall
 275
 276         // gun model bobbing code
 277         if (autocvar_cl_bobmodel)
 278                 this.origin += bobmodel_ofs(view);
 279 }
 280
 281 .vector viewmodel_origin, viewmodel_angles;
 282 .float weapon_nextthink;
 283 .float weapon_eta_last;
 284 .float weapon_switchdelay;
 285
 286 .string name_last;
 287
 288 void viewmodel_draw(entity this)
 289 {
 290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 291                 return;
 292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 293         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 294         int wepskin = this.m_skin;
 295         bool invehicle = player_localentnum > maxclients;
 296         if (invehicle) a = -1;
 297         Weapon wep = this.activeweapon;
 298         int c = entcs_GetClientColors(current_player);
 299         vector g = weaponentity_glowmod(wep, NULL, c, this);
 300         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 301         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 302                 | EF_NODEPTHTEST)
 303                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 304         for (entity e = this; e; e = e.weaponchild)
 305         {
 306                 e.drawmask = mask;
 307                 e.alpha = a;
 308                 e.skin = wepskin;
 309                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 310                 e.glowmod = g;
 311                 e.csqcmodel_effects = fx;
 312                 CSQCModel_Effects_Apply(e);
 313         }
 314         if(a >= 0)
 315         {
 316                 string name = wep.mdl;
 317                 string newname = wep.wr_viewmodel(wep, this);
 318                 if(newname)
 319                         name = newname;
 320                 bool swap = name != this.name_last;
 321                 // if (swap)
 322                 {
 323                         this.name_last = name;
 324                         CL_WeaponEntity_SetModel(this, name, swap);
 325                         this.viewmodel_origin = this.origin;
 326                         this.viewmodel_angles = this.angles;
 327                 }
 328                 anim_update(this);
 329                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 330                         anim_set(this, this.anim_idle, true, false, false);
 331         }
 332         float f = 0; // 0..1; 0: fully active
 333         float rate = STAT(WEAPONRATEFACTOR);
 334         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 335         if (eta <= 0) f = this.weapon_eta_last;
 336         else switch (this.state)
 337         {
 338                 case WS_RAISE:
 339                 {
 340                         f = eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_DROP:
 344                 {
 345                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 346                         break;
 347                 }
 348                 case WS_CLEAR:
 349                 {
 350                         f = 1;
 351                         break;
 352                 }
 353         }
 354         this.weapon_eta_last = f;
 355         this.origin = this.viewmodel_origin;
 356         this.angles = this.viewmodel_angles;
 357         this.angles_x = (-90 * f * f);
 358         viewmodel_animate(this);
 359         MUTATOR_CALLHOOK(DrawViewModel, this);
 360         setorigin(this, this.origin);
 361 }
 362
 363 STATIC_INIT(viewmodel) {
 364     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         viewmodels[slot] = new(viewmodel);
 366 }
 367
 368 float showfps_prevfps;
 369 float showfps_prevfps_time;
 370 int showfps_framecounter;
 371
 372 void fpscounter_update()
 373 {
 374         if(!STAT(SHOWFPS))
 375                 return;
 376
 377         float currentTime = gettime(GETTIME_REALTIME);
 378         showfps_framecounter += 1;
 379         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 380         {
 381                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 382                 showfps_framecounter = 0;
 383                 showfps_prevfps_time = currentTime;
 384
 385                 int channel = MSG_C2S;
 386                 WriteHeader(channel, fpsreport);
 387                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 388         }
 389 }
 390
 391 STATIC_INIT(fpscounter_init)
 392 {
 393         float currentTime = gettime(GETTIME_REALTIME);
 394         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 395 }
 396
 397 float avgspeed;
 398 vector GetCurrentFov(float fov)
 399 {
 400         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 401         float velocityzoom, curspeed;
 402         vector v;
 403
 404         zoomsensitivity = autocvar_cl_zoomsensitivity;
 405         zoomfactor = autocvar_cl_zoomfactor;
 406         if(zoomfactor < 1 || zoomfactor > 30)
 407                 zoomfactor = 2.5;
 408         zoomspeed = autocvar_cl_zoomspeed;
 409         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 410                 zoomspeed = 3.5;
 411
 412         zoomdir = button_zoom;
 413
 414         if(hud == HUD_NORMAL && !spectatee_status)
 415         {
 416                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 417                 {
 418                         entity wepent = viewmodels[slot];
 419                         if(wepent.switchweapon != wepent.activeweapon)
 420                                 continue;
 421                         Weapon wep = wepent.activeweapon;
 422                         if(wep != WEP_Null && wep.wr_zoomdir)
 423                         {
 424                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 425                                 zoomdir += do_zoom;
 426                         }
 427                 }
 428         }
 429         if(spectatee_status > 0 || isdemo())
 430         {
 431                 if(spectatorbutton_zoom)
 432                 {
 433                         if(zoomdir)
 434                                 zoomdir = 0;
 435                         else
 436                                 zoomdir = 1;
 437                 }
 438                 // fteqcc failed twice here already, don't optimize this
 439         }
 440
 441         if(zoomdir) { zoomin_effect = 0; }
 442
 443         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 444         {
 445                 current_viewzoom = 1;
 446         }
 447         else if (camera_active)
 448         {
 449                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 450         }
 451         else if(autocvar_cl_spawnzoom && zoomin_effect)
 452         {
 453                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 454
 455                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 456                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 457                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 458         }
 459         else
 460         {
 461                 if(zoomspeed < 0) // instant zoom
 462                 {
 463                         if(zoomdir)
 464                                 current_viewzoom = 1 / zoomfactor;
 465                         else
 466                                 current_viewzoom = 1;
 467                 }
 468                 else
 469                 {
 470                         if(zoomdir)
 471                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 472                         else
 473                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 474                 }
 475         }
 476
 477         if(almost_equals(current_viewzoom, 1))
 478                 current_zoomfraction = 0;
 479         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 480                 current_zoomfraction = 1;
 481         else
 482                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 483
 484         if(zoomsensitivity < 1)
 485                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 486         else
 487                 setsensitivityscale(1);
 488
 489         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 490         {
 491                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 492                         curspeed = 0;
 493                 else
 494                 {
 495                         makevectors(view_angles);
 496                         v = pmove_vel;
 497                         if(csqcplayer)
 498                                 v = csqcplayer.velocity;
 499
 500                         switch(autocvar_cl_velocityzoom_type)
 501                         {
 502                                 case 3: curspeed = max(0, v_forward * v); break;
 503                                 case 2: curspeed = (v_forward * v); break;
 504                                 case 1: default: curspeed = vlen(v); break;
 505                         }
 506                 }
 507
 508                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 509                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 510                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 511
 512                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 513         }
 514         else
 515                 velocityzoom = 1;
 516
 517         float frustumx, frustumy, fovx, fovy;
 518         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 519         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 520         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 521         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 522
 523         return '1 0 0' * fovx + '0 1 0' * fovy;
 524 }
 525
 526 vector GetViewLocationFOV(float fov)
 527 {
 528         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 529         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 530         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 531         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 532         return '1 0 0' * fovx + '0 1 0' * fovy;
 533 }
 534
 535 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 536 {
 537         float fovx, fovy;
 538         float width = (ov_worldmax.x - ov_worldmin.x);
 539         float height = (ov_worldmax.y - ov_worldmin.y);
 540         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 541         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 542         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 543         return '1 0 0' * fovx + '0 1 0' * fovy;
 544 }
 545
 546 // this function must match W_SetupShot!
 547 float zoomscript_caught;
 548
 549 bool minigame_wasactive;
 550
 551 vector wcross_origin;
 552 float wcross_scale_prev, wcross_alpha_prev;
 553 vector wcross_color_prev;
 554 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 555 vector wcross_color_goal_prev;
 556 float wcross_changedonetime;
 557
 558 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 559 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 560 float wcross_name_changestarttime, wcross_name_changedonetime;
 561 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 562
 563 float wcross_ring_prev;
 564
 565 entity trueaim;
 566 entity trueaim_rifle;
 567
 568 const float SHOTTYPE_HITTEAM = 1;
 569 const float SHOTTYPE_HITOBSTRUCTION = 2;
 570 const float SHOTTYPE_HITWORLD = 3;
 571 const float SHOTTYPE_HITENEMY = 4;
 572
 573 void TrueAim_Init()
 574 {
 575         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 576         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 577 }
 578
 579 float EnemyHitCheck()
 580 {
 581         float t, n;
 582         wcross_origin = project_3d_to_2d(trace_endpos);
 583         wcross_origin.z = 0;
 584         if(trace_ent)
 585                 n = trace_ent.entnum;
 586         else
 587                 n = trace_networkentity;
 588         if(n < 1)
 589                 return SHOTTYPE_HITWORLD;
 590         if(n > maxclients)
 591                 return SHOTTYPE_HITWORLD;
 592         t = entcs_GetTeam(n - 1);
 593         if(teamplay)
 594                 if(t == myteam)
 595                         return SHOTTYPE_HITTEAM;
 596         if(t == NUM_SPECTATOR)
 597                 return SHOTTYPE_HITWORLD;
 598         return SHOTTYPE_HITENEMY;
 599 }
 600
 601 float TrueAimCheck(entity wepent)
 602 {
 603         if(wepent.activeweapon.spawnflags & WEP_FLAG_NOTRUEAIM)
 604                 return SHOTTYPE_HITWORLD;
 605
 606         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 607         vector vecs, trueaimpoint, w_shotorg;
 608         vector mi, ma, dv;
 609         float shottype;
 610         entity ta;
 611         float mv;
 612
 613         mi = ma = '0 0 0';
 614         ta = trueaim;
 615         mv = MOVE_NOMONSTERS;
 616
 617         switch(wepent.activeweapon) // WEAPONTODO
 618         {
 619                 case WEP_VORTEX:
 620                 case WEP_OVERKILL_NEX:
 621                 case WEP_VAPORIZER:
 622                         mv = MOVE_NORMAL;
 623                         break;
 624                 case WEP_RIFLE:
 625                         ta = trueaim_rifle;
 626                         mv = MOVE_NORMAL;
 627                         if(zoomscript_caught)
 628                         {
 629                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 630                                 return EnemyHitCheck();
 631                         }
 632                         break;
 633                 case WEP_DEVASTATOR: // projectile has a size!
 634                         mi = '-3 -3 -3';
 635                         ma = '3 3 3';
 636                         break;
 637                 case WEP_FIREBALL: // projectile has a size!
 638                         mi = '-16 -16 -16';
 639                         ma = '16 16 16';
 640                         break;
 641                 case WEP_SEEKER: // projectile has a size!
 642                         mi = '-2 -2 -2';
 643                         ma = '2 2 2';
 644                         break;
 645                 case WEP_ELECTRO: // projectile has a size!
 646                         mi = '0 0 -3';
 647                         ma = '0 0 -3';
 648                         break;
 649         }
 650
 651         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 652
 653         vecs = decompressShotOrigin(STAT(SHOTORG));
 654
 655         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 656         trueaimpoint = trace_endpos;
 657
 658         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 659                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 660
 661         if(vecs.x > 0)
 662                 vecs.y = -vecs.y;
 663         else
 664                 vecs = '0 0 0';
 665
 666         dv = view_right * vecs.y + view_up * vecs.z;
 667         w_shotorg = traceorigin + dv;
 668
 669         // now move the vecs forward as much as requested if possible
 670         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 671         w_shotorg = trace_endpos - view_forward * nudge;
 672
 673         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 674         shottype = EnemyHitCheck();
 675         if(shottype != SHOTTYPE_HITWORLD)
 676                 return shottype;
 677
 678 #if 0
 679         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 680         // or rather, I know why, but see no fix
 681         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 682                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 683                 return SHOTTYPE_HITOBSTRUCTION;
 684 #endif
 685
 686         return SHOTTYPE_HITWORLD;
 687 }
 688
 689 float camera_mode;
 690 const float CAMERA_FREE = 1;
 691 const float CAMERA_CHASE = 2;
 692 float reticle_type;
 693 string NextFrameCommand;
 694
 695 vector freeze_org, freeze_ang;
 696 entity nightvision_noise, nightvision_noise2;
 697
 698 const float MAX_TIME_DIFF = 5;
 699 float pickup_crosshair_time, pickup_crosshair_size;
 700 float hitindication_crosshair_size;
 701 float use_vortex_chargepool;
 702
 703 float myhealth, myhealth_prev;
 704 float myhealth_flash;
 705
 706 float old_blurradius, old_bluralpha;
 707 float old_sharpen_intensity;
 708
 709 vector myhealth_gentlergb;
 710
 711 float contentavgalpha, liquidalpha_prev;
 712 vector liquidcolor_prev;
 713
 714 float eventchase_current_distance;
 715 float eventchase_running;
 716 int WantEventchase(entity this)
 717 {
 718         if(autocvar_cl_orthoview)
 719                 return 0;
 720         if(STAT(GAME_STOPPED) || intermission)
 721                 return 1;
 722         if(this.viewloc)
 723                 return 1;
 724         if(spectatee_status >= 0)
 725         {
 726                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 727                         return 1;
 728                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 729                         return 1;
 730                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 731                         return 1;
 732                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 733                 {
 734                         if(autocvar_cl_eventchase_death == 2)
 735                         {
 736                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 737                                 if(this.velocity == '0 0 0' || eventchase_running)
 738                                         return 1;
 739                         }
 740                         else return 1;
 741                 }
 742                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 743                 {
 744                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 745                                 return 1;
 746                         else if (eventchase_running)
 747                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 748                 }
 749         }
 750         return 0;
 751 }
 752
 753 void HUD_Crosshair_Vehicle(entity this)
 754 {
 755         if(hud != HUD_BUMBLEBEE_GUN)
 756         {
 757                 Vehicle info = Vehicles_from(hud);
 758                 info.vr_crosshair(info, this);
 759         }
 760 }
 761
 762 vector damage_blurpostprocess, content_blurpostprocess;
 763
 764 float unaccounted_damage = 0;
 765 void UpdateDamage()
 766 {
 767         // accumulate damage with each stat update
 768         static float damage_total_prev = 0;
 769         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 770         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 771         damage_total_prev = damage_total;
 772
 773         static float damage_dealt_time_prev = 0;
 774         float damage_dealt_time = STAT(HIT_TIME);
 775         if (damage_dealt_time != damage_dealt_time_prev)
 776         {
 777                 unaccounted_damage += unaccounted_damage_new;
 778                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 779         }
 780         damage_dealt_time_prev = damage_dealt_time;
 781
 782         // prevent hitsound when switching spectatee
 783         static float spectatee_status_prev = 0;
 784         if (spectatee_status != spectatee_status_prev)
 785                 unaccounted_damage = 0;
 786         spectatee_status_prev = spectatee_status;
 787 }
 788
 789 void HitSound()
 790 {
 791         // varying sound pitch
 792
 793         bool have_arc = false;
 794         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 795         {
 796                 entity wepent = viewmodels[slot];
 797
 798                 if(wepent.activeweapon == WEP_ARC)
 799                         have_arc = true;
 800         }
 801
 802         static float hitsound_time_prev = 0;
 803         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 804         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 805         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 806         {
 807                 if (autocvar_cl_hitsound && unaccounted_damage)
 808                 {
 809                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 810                         float a = autocvar_cl_hitsound_max_pitch;
 811                         float b = autocvar_cl_hitsound_min_pitch;
 812                         float c = autocvar_cl_hitsound_nom_damage;
 813                         float d = unaccounted_damage;
 814                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 815
 816                         // if sound variation is disabled, set pitch_shift to 1
 817                         if (autocvar_cl_hitsound == 1)
 818                                 pitch_shift = 1;
 819
 820                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 821                         if (autocvar_cl_hitsound == 3)
 822                         {
 823                                 float mirror_value = (a-b)/2 + b;
 824                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 825                         }
 826
 827                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 828
 829                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 830                         // todo: normalize sound pressure levels? seems unnecessary
 831
 832                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 833                 }
 834                 unaccounted_damage = 0;
 835                 hitsound_time_prev = time;
 836         }
 837
 838         static float typehit_time_prev = 0;
 839         float typehit_time = STAT(TYPEHIT_TIME);
 840         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 841         {
 842                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 843                 typehit_time_prev = typehit_time;
 844         }
 845
 846         static float kill_time_prev = 0;
 847         float kill_time = STAT(KILL_TIME);
 848         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 849         {
 850                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 851                 kill_time_prev = kill_time;
 852         }
 853 }
 854
 855 vector crosshair_getcolor(entity this, float health_stat)
 856 {
 857         static float rainbow_last_flicker;
 858         static vector rainbow_prev_color;
 859         vector wcross_color = '0 0 0';
 860         switch(autocvar_crosshair_color_special)
 861         {
 862                 case 1: // crosshair_color_per_weapon
 863                 {
 864                         if(this != WEP_Null && hud == HUD_NORMAL)
 865                         {
 866                                 wcross_color = this.wpcolor;
 867                                 break;
 868                         }
 869                         else { goto normalcolor; }
 870                 }
 871
 872                 case 2: // crosshair_color_by_health
 873                 {
 874                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 875                         float hp = floor(v.x + 1);
 876
 877                         //x = red
 878                         //y = green
 879                         //z = blue
 880
 881                         wcross_color.z = 0;
 882
 883                         if(hp > 200)
 884                         {
 885                                 wcross_color.x = 0;
 886                                 wcross_color.y = 1;
 887                         }
 888                         else if(hp > 150)
 889                         {
 890                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 891                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 892                         }
 893                         else if(hp > 100)
 894                         {
 895                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 896                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 897                                 wcross_color.z = 1 - (hp-100)*0.02;
 898                         }
 899                         else if(hp > 50)
 900                         {
 901                                 wcross_color.x = 1;
 902                                 wcross_color.y = 1;
 903                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 904                         }
 905                         else if(hp > 20)
 906                         {
 907                                 wcross_color.x = 1;
 908                                 wcross_color.y = (hp-20)*90/27/100;
 909                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 910                         }
 911                         else
 912                         {
 913                                 wcross_color.x = 1;
 914                                 wcross_color.y = 0;
 915                         }
 916                         break;
 917                 }
 918
 919                 case 3: // crosshair_color_rainbow
 920                 {
 921                         if(time >= rainbow_last_flicker)
 922                         {
 923                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 924                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 925                         }
 926                         wcross_color = rainbow_prev_color;
 927                         break;
 928                 }
 929 LABEL(normalcolor)
 930                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 931         }
 932
 933         return wcross_color;
 934 }
 935
 936 void HUD_Crosshair(entity this)
 937 {
 938         float f, i, j;
 939         vector v;
 940         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 941                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 942                 !HUD_MinigameMenu_IsOpened() )
 943         {
 944                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 945                         return;
 946
 947                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 948                         return;
 949
 950                 if (hud != HUD_NORMAL)
 951                 {
 952                         HUD_Crosshair_Vehicle(this);
 953                         return;
 954                 }
 955
 956                 string wcross_style;
 957                 float wcross_alpha, wcross_resolution;
 958                 wcross_style = autocvar_crosshair;
 959                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
 960                         wcross_style = autocvar_crosshair_2d;
 961                 if (wcross_style == "0")
 962                         return;
 963                 wcross_resolution = autocvar_crosshair_size;
 964                 if (wcross_resolution == 0)
 965                         return;
 966                 wcross_alpha = autocvar_crosshair_alpha;
 967                 if (wcross_alpha == 0)
 968                         return;
 969
 970                 // TrueAim check
 971                 float shottype;
 972
 973                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 974                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
 975                         wcross_origin = viewloc_mousepos;
 976                 else if(autocvar_chase_active > 0 && autocvar_crosshair_chase)
 977                 {
 978                         vector player_org = ((csqcplayer) ? csqcplayer.origin + csqcplayer.view_ofs : view_origin);
 979                         if(csqcplayer && crosshair_chase_playeralpha && crosshair_chase_playeralpha < 1)
 980                         {
 981                                 traceline(view_origin, view_origin + max_shot_distance * view_forward, MOVE_NORMAL, NULL);
 982                                 if(trace_ent == csqcplayer)
 983                                         csqcplayer.alpha = crosshair_chase_playeralpha;
 984                                 else
 985                                         csqcplayer.alpha = csqcplayer.m_alpha;
 986                         }
 987                         traceline(player_org, player_org + max_shot_distance * view_forward, MOVE_WORLDONLY, NULL);
 988                         wcross_origin = project_3d_to_2d(trace_endpos);
 989                 }
 990                 else
 991                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
 992                 wcross_origin.z = 0;
 993                 if(autocvar_crosshair_hittest)
 994                 {
 995                         vector wcross_oldorigin;
 996                         entity thiswep = viewmodels[0]; // TODO: unhardcode
 997                         wcross_oldorigin = wcross_origin;
 998                         shottype = TrueAimCheck(thiswep);
 999                         if(shottype == SHOTTYPE_HITWORLD)
1000                         {
1001                                 v = wcross_origin - wcross_oldorigin;
1002                                 v.x /= vid_conwidth;
1003                                 v.y /= vid_conheight;
1004                                 if(vdist(v, >, 0.01))
1005                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1006                         }
1007                         if(!autocvar_crosshair_hittest_showimpact)
1008                                 wcross_origin = wcross_oldorigin;
1009                 }
1010                 else
1011                         shottype = SHOTTYPE_HITWORLD;
1012
1013                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1014                 string wcross_name = "";
1015                 float wcross_scale, wcross_blur;
1016
1017         entity e = WEP_Null;
1018                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1019                 {
1020                         entity wepent = viewmodels[0]; // TODO: unhardcode
1021                         e = wepent.switchingweapon;
1022                         if(e)
1023                         {
1024                                 if(autocvar_crosshair_per_weapon)
1025                                 {
1026                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1027                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1028                                         //if (wcross_resolution == 0)
1029                                                 //return;
1030
1031                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1032                                         wcross_resolution *= e.w_crosshair_size;
1033                                         wcross_name = e.w_crosshair;
1034                                 }
1035                         }
1036                 }
1037
1038                 if(wcross_name == "")
1039                         wcross_name = strcat("gfx/crosshair", wcross_style);
1040
1041                 // MAIN CROSSHAIR COLOR DECISION
1042                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1043
1044                 if(autocvar_crosshair_effect_scalefade)
1045                 {
1046                         wcross_scale = wcross_resolution;
1047                         wcross_resolution = 1;
1048                 }
1049                 else
1050                 {
1051                         wcross_scale = 1;
1052                 }
1053
1054                 if(autocvar_crosshair_pickup)
1055                 {
1056                         float stat_pickup_time = STAT(LAST_PICKUP);
1057
1058                         if(pickup_crosshair_time < stat_pickup_time)
1059                         {
1060                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1061                                         pickup_crosshair_size = 1;
1062
1063                                 pickup_crosshair_time = stat_pickup_time;
1064                         }
1065
1066                         if(pickup_crosshair_size > 0)
1067                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1068                         else
1069                                 pickup_crosshair_size = 0;
1070
1071                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1072                 }
1073
1074                 // todo: make crosshair hit indication dependent on damage dealt
1075                 if(autocvar_crosshair_hitindication)
1076                 {
1077                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1078
1079                         if(unaccounted_damage)
1080                         {
1081                                 hitindication_crosshair_size = 1;
1082                         }
1083
1084                         if(hitindication_crosshair_size > 0)
1085                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1086                         else
1087                                 hitindication_crosshair_size = 0;
1088
1089                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1090                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1091                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1092                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1093                 }
1094
1095                 if(shottype == SHOTTYPE_HITENEMY)
1096                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1097                 if(shottype == SHOTTYPE_HITTEAM)
1098                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1099
1100                 f = fabs(autocvar_crosshair_effect_time);
1101                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1102                 {
1103                         wcross_changedonetime = time + f;
1104                 }
1105                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1106                 {
1107                         wcross_name_changestarttime = time;
1108                         wcross_name_changedonetime = time + f;
1109                         if(wcross_name_goal_prev_prev)
1110                                 strunzone(wcross_name_goal_prev_prev);
1111                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1112                         wcross_name_goal_prev = strzone(wcross_name);
1113                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1114                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1115                         wcross_resolution_goal_prev = wcross_resolution;
1116                 }
1117
1118                 wcross_scale_goal_prev = wcross_scale;
1119                 wcross_alpha_goal_prev = wcross_alpha;
1120                 wcross_color_goal_prev = wcross_color;
1121
1122                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1123                 {
1124                         wcross_blur = 1;
1125                         wcross_alpha *= 0.75;
1126                 }
1127                 else
1128                         wcross_blur = 0;
1129                 // *_prev is at time-frametime
1130                 // * is at wcross_changedonetime+f
1131                 // what do we have at time?
1132                 if(time < wcross_changedonetime)
1133                 {
1134                         f = frametime / (wcross_changedonetime - time + frametime);
1135                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1136                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1137                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1138                 }
1139
1140                 wcross_scale_prev = wcross_scale;
1141                 wcross_alpha_prev = wcross_alpha;
1142                 wcross_color_prev = wcross_color;
1143
1144                 MUTATOR_CALLHOOK(UpdateCrosshair);
1145
1146                 wcross_scale *= 1 - autocvar__menu_alpha;
1147                 wcross_alpha *= 1 - autocvar__menu_alpha;
1148                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1149
1150                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1151                 {
1152                         // crosshair rings for weapon stats
1153                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1154                         {
1155                                 // declarations and stats
1156                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1157                                 string ring_image = string_null, ring_inner_image = string_null;
1158                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1159
1160                                 ring_scale = autocvar_crosshair_ring_size;
1161
1162                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1163
1164                                 int weapon_clipload = wepent.clip_load;
1165                                 int weapon_clipsize = wepent.clip_size;
1166
1167                                 float arc_heat = wepent.arc_heat_percent;
1168                                 float vcharge = wepent.vortex_charge;
1169                                 float vchargepool = wepent.vortex_chargepool_ammo;
1170                                 float oknex_charge_ = wepent.oknex_charge;
1171                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1172
1173                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1174                                         vortex_charge_movingavg = vcharge;
1175
1176                                 // handle the values
1177                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1178                                 {
1179                                         if (vchargepool || use_vortex_chargepool) {
1180                                                 use_vortex_chargepool = 1;
1181                                                 ring_inner_value = vchargepool;
1182                                         } else {
1183                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1184                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1185                                         }
1186
1187                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1188                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1189                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1190
1191                                         // draw the outer ring to show the current charge of the weapon
1192                                         ring_value = vcharge;
1193                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1194                                         ring_rgb = wcross_color;
1195                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1196                                 }
1197                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1198                                 {
1199                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1200                                                 use_vortex_chargepool = 1;
1201                                                 ring_inner_value = oknex_chargepool_;
1202                                         } else {
1203                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1204                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1205                                         }
1206
1207                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1208                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1209                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1210
1211                                         // draw the outer ring to show the current charge of the weapon
1212                                         ring_value = oknex_charge_;
1213                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1214                                         ring_rgb = wcross_color;
1215                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1216                                 }
1217                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1218                                 {
1219                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1220                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1221                                         ring_rgb = wcross_color;
1222                                         ring_image = "gfx/crosshair_ring.tga";
1223                                 }
1224                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1225                                 {
1226                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1227                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1228                                         ring_rgb = wcross_color;
1229                                         ring_image = "gfx/crosshair_ring.tga";
1230                                 }
1231                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1232                                 {
1233                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1234                                         ring_scale = autocvar_crosshair_ring_reload_size;
1235                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1236                                         ring_rgb = wcross_color;
1237
1238                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1239                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1240                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1241                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1242                                         else
1243                                                 ring_image = "gfx/crosshair_ring.tga";
1244                                 }
1245                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1246                                 {
1247                                         ring_value = arc_heat;
1248                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1249                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1250                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1251                                         ring_image = "gfx/crosshair_ring.tga";
1252                                 }
1253
1254                                 // if in weapon switch animation, fade ring out/in
1255                                 if(autocvar_crosshair_effect_time > 0)
1256                                 {
1257                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1258                                         if (f >= 1)
1259                                         {
1260                                                 wcross_ring_prev = ((ring_image) ? true : false);
1261                                         }
1262
1263                                         if(wcross_ring_prev)
1264                                         {
1265                                                 if(f < 1)
1266                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1267                                         }
1268                                         else
1269                                         {
1270                                                 if(f < 1)
1271                                                         ring_alpha *= bound(0, f, 1);
1272                                         }
1273                                 }
1274
1275                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1276                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1277
1278                                 if (ring_value)
1279                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1280                         }
1281
1282 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1283                         MACRO_BEGIN \
1284                                 vector scaled_sz = sz * wcross_size; \
1285                                 if(wcross_blur > 0) \
1286                                 { \
1287                                         for(i = -2; i <= 2; ++i) \
1288                                         for(j = -2; j <= 2; ++j) \
1289                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
1290                                 } \
1291                                 else \
1292                                 { \
1293                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
1294                                 } \
1295                         MACRO_END
1296
1297 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
1298                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1299
1300 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1301                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1302
1303                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1304                         {
1305                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1306                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1307                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1308                                 f = 1 - f;
1309                         }
1310                         else
1311                         {
1312                                 f = 1;
1313                         }
1314                         wcross_name_alpha_goal_prev = f;
1315
1316                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1317                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1318
1319                         if(autocvar_crosshair_dot)
1320                         {
1321                                 vector wcross_color_old;
1322                                 wcross_color_old = wcross_color;
1323
1324                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1325                                         wcross_color = stov(autocvar_crosshair_dot_color);
1326
1327                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1328                                 // FIXME why don't we use wcross_alpha here?
1329                                 wcross_color = wcross_color_old;
1330                         }
1331                 }
1332         }
1333         else
1334         {
1335                 wcross_scale_prev = 0;
1336                 wcross_alpha_prev = 0;
1337                 wcross_scale_goal_prev = 0;
1338                 wcross_alpha_goal_prev = 0;
1339                 wcross_changedonetime = 0;
1340                 strfree(wcross_name_goal_prev);
1341                 strfree(wcross_name_goal_prev_prev);
1342                 wcross_name_changestarttime = 0;
1343                 wcross_name_changedonetime = 0;
1344                 wcross_name_alpha_goal_prev = 0;
1345                 wcross_name_alpha_goal_prev_prev = 0;
1346                 wcross_resolution_goal_prev = 0;
1347                 wcross_resolution_goal_prev_prev = 0;
1348         }
1349 }
1350
1351 const int MAX_SPECIALCOMMAND = 15;
1352 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1353 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1354 const float SPECIALCOMMAND_SPEED = 150;
1355 const float SPECIALCOMMAND_TURNSPEED = 2;
1356 const float SPECIALCOMMAND_SIZE = 0.025;
1357 const float SPECIALCOMMAND_CHANCE = 0.35;
1358 float sc_spawntime, sc_changetime;
1359 vector sc_color = '1 1 1';
1360 void SpecialCommand()
1361 {
1362         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1363                 return;
1364
1365         if(time >= sc_changetime)
1366         {
1367                 sc_changetime = time + 1;
1368                 sc_color = randomvec() * 1.5;
1369                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1370                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1371                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1372         }
1373         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1374
1375         if(!precache_pic("gfx/smile"))
1376                 return; // damn party poopers
1377
1378         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1379         {
1380                 vector slot = specialcommand_slots[j];
1381                 if(slot.y)
1382                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1383                 //if(slot.z)
1384                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1385                 if(slot.y >= vid_conheight)
1386                         slot = '0 0 0';
1387
1388                 if(slot == '0 0 0')
1389                 {
1390                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1391                         {
1392                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1393                                 slot.y = 1; // start it off 0 so we can use it
1394                                 slot.z = floor(random() * Weapons_MAX);
1395                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1396                                 vector newcolor = randomvec() * 2;
1397                                 newcolor.x = bound(0.4, newcolor.x, 1);
1398                                 newcolor.y = bound(0.4, newcolor.y, 1);
1399                                 newcolor.z = bound(0.4, newcolor.z, 1);
1400                                 specialcommand_colors[j] = newcolor;
1401                         }
1402                 }
1403                 else
1404                 {
1405                         vector splash_size = '0 0 0';
1406                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1407                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1408                         entity wep = Weapons_from(slot.z);
1409                         if(wep == WEP_Null)
1410                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1411                         else
1412                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1413                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1414                 }
1415
1416                 specialcommand_slots[j] = slot;
1417         }
1418 }
1419
1420 void HUD_Draw(entity this)
1421 {
1422         // if we don't know gametype and scores yet avoid drawing the scoreboard
1423         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1424         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1425         // cl_deathscoreboard would show the scoreboard and so on
1426         if(!gametype)
1427                 return;
1428
1429         Hud_Dynamic_Frame();
1430
1431         if(!intermission)
1432         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1433         {
1434                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1435         }
1436         else if(STAT(FROZEN))
1437         {
1438                 vector col = '0.25 0.90 1';
1439                 if(STAT(REVIVE_PROGRESS))
1440                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1441                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1442         }
1443
1444         HUD_Scale_Enable();
1445         if(!intermission)
1446         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1447         {
1448                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1449                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1450                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1451         }
1452         else if(STAT(CAPTURE_PROGRESS))
1453         {
1454                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1455                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1456         }
1457         else if(STAT(REVIVE_PROGRESS))
1458         {
1459                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1460                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1461         }
1462         HUD_Scale_Disable();
1463
1464         if(autocvar_r_letterbox == 0)
1465                 if(autocvar_viewsize < 120)
1466                 {
1467                         if(!(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))
1468                                 Accuracy_LoadLevels();
1469
1470                         HUD_Main();
1471                         HUD_Scale_Disable();
1472                 }
1473
1474         // crosshair goes VERY LAST
1475         SpecialCommand();
1476         UpdateDamage();
1477         HUD_Crosshair(this);
1478         HitSound();
1479 }
1480
1481 void ViewLocation_Mouse()
1482 {
1483         if(spectatee_status)
1484                 return; // don't draw it as spectator!
1485
1486         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1487         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1488         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1489
1490         //float cursor_alpha = 1 - autocvar__menu_alpha;
1491         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1492 }
1493
1494 void HUD_Cursor_Show()
1495 {
1496         float cursor_alpha = 1 - autocvar__menu_alpha;
1497         if(cursor_type == CURSOR_NORMAL)
1498                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1499         else if(cursor_type == CURSOR_MOVE)
1500                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1501         else if(cursor_type == CURSOR_RESIZE)
1502                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1503         else if(cursor_type == CURSOR_RESIZE2)
1504                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1505 }
1506
1507 void HUD_Mouse(entity player)
1508 {
1509         if(autocvar__menu_alpha == 1)
1510                 return;
1511
1512         if(!cursor_active)
1513         {
1514                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1515                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1516                 return;
1517         }
1518
1519         if (cursor_active == -1) // starting to display the cursor
1520         {
1521                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1522                 // in the first frame mousepos is the mouse position of the last time
1523                 // the cursor was displayed, thus we ignore it to avoid a glictch
1524                 cursor_active = 1;
1525                 return;
1526         }
1527
1528         if(!autocvar_hud_cursormode)
1529                 update_mousepos();
1530
1531         if(autocvar__hud_configure)
1532                 HUD_Panel_Mouse();
1533         else
1534         {
1535                 if (HUD_MinigameMenu_IsOpened())
1536                         HUD_Minigame_Mouse();
1537                 if (QuickMenu_IsOpened())
1538                         QuickMenu_Mouse();
1539                 if (HUD_Radar_Clickable())
1540                         HUD_Radar_Mouse();
1541         }
1542
1543         prevMouseClicked = mouseClicked;
1544
1545         HUD_Cursor_Show();
1546 }
1547
1548 bool ov_enabled;
1549 float oldr_nearclip;
1550 float oldr_farclip_base;
1551 float oldr_farclip_world;
1552 float oldr_novis;
1553 float oldr_useportalculling;
1554 float oldr_useinfinitefarclip;
1555
1556 float prev_myteam;
1557 int lasthud;
1558 float vh_notice_time;
1559 void CSQC_UpdateView(entity this, float w, float h)
1560 {
1561         TC(int, w); TC(int, h);
1562         entity e;
1563         float fov;
1564         float f;
1565         vector vf_size, vf_min;
1566         float a;
1567
1568         execute_next_frame();
1569
1570         ++framecount;
1571
1572         stats_get();
1573         hud = STAT(HUD);
1574
1575         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1576                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1577
1578         lasthud = hud;
1579
1580         ReplicateVars(false);
1581         if (ReplicateVars_NOT_SENDING())
1582                 ReplicateVars_DELAY(0.8 + random() * 0.4); // no need to check cvars every frame
1583
1584         HUD_Scale_Disable();
1585
1586         if(autocvar__hud_showbinds_reload) // menu can set this one
1587         {
1588                 db_close(binddb);
1589                 binddb = db_create();
1590                 cvar_set("_hud_showbinds_reload", "0");
1591         }
1592
1593         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1594                 view_quality = getproperty(VF_MINFPS_QUALITY);
1595         else
1596                 view_quality = 1;
1597
1598         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1599         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1600
1601         vf_size = getpropertyvec(VF_SIZE);
1602         vf_min = getpropertyvec(VF_MIN);
1603         vid_width = vf_size.x;
1604         vid_height = vf_size.y;
1605
1606         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1607         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1608
1609         WaypointSprite_Load();
1610
1611         CSQCPlayer_SetCamera();
1612
1613         if(player_localentnum <= maxclients) // is it a client?
1614                 current_player = player_localentnum - 1;
1615         else // then player_localentnum is the vehicle I'm driving
1616                 current_player = player_localnum;
1617         myteam = entcs_GetTeam(current_player);
1618
1619         if(myteam != prev_myteam)
1620         {
1621                 myteamcolors = colormapPaletteColor(myteam, 1);
1622                 FOREACH(hud_panels, true, it.update_time = time);
1623                 prev_myteam = myteam;
1624         }
1625
1626         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1627
1628         float is_dead = (STAT(HEALTH) <= 0);
1629
1630         // FIXME do we need this hack?
1631         if(isdemo())
1632         {
1633                 // in demos, input_buttons do not work
1634                 button_zoom = (autocvar__togglezoom == "-");
1635         }
1636         else if(button_zoom
1637                 && autocvar_cl_unpress_zoom_on_death
1638                 && (spectatee_status >= 0)
1639                 && (is_dead || intermission))
1640         {
1641                 // no zoom while dead or in intermission please
1642                 localcmd("-zoom\n");
1643                 button_zoom = false;
1644         }
1645
1646         // abused multiple places below
1647         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1648         if(!local_player)
1649                 local_player = this; // fall back!
1650
1651         // event chase camera
1652         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1653         {
1654                 if(STAT(CAMERA_SPECTATOR))
1655                 {
1656                         if(spectatee_status > 0)
1657                         {
1658                                 if(!autocvar_chase_active)
1659                                 {
1660                                         cvar_set("chase_active", "-2");
1661                                         goto skip_eventchase_death;
1662                                 }
1663                         }
1664                         else if(autocvar_chase_active == -2)
1665                                 cvar_set("chase_active", "0");
1666
1667                         if(autocvar_chase_active == -2)
1668                                 goto skip_eventchase_death;
1669                 }
1670                 else if(autocvar_chase_active == -2)
1671                         cvar_set("chase_active", "0");
1672
1673                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1674
1675                 float vehicle_viewdist = 0;
1676                 vector vehicle_viewofs = '0 0 0';
1677
1678                 if(vehicle_chase)
1679                 {
1680                         if(hud != HUD_BUMBLEBEE_GUN)
1681                         {
1682                                 Vehicle info = Vehicles_from(hud);
1683                                 vehicle_viewdist = info.height;
1684                                 vehicle_viewofs = info.view_ofs;
1685                         }
1686                 }
1687
1688                 int eventchase = WantEventchase(this);
1689                 if (eventchase)
1690                 {
1691                         vector current_view_origin_override = '0 0 0';
1692                         vector view_offset_override = '0 0 0';
1693                         float chase_distance_override = 0;
1694                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1695                         if(custom_eventchase)
1696                         {
1697                                 current_view_origin_override = M_ARGV(0, vector);
1698                                 view_offset_override = M_ARGV(1, vector);
1699                                 chase_distance_override = M_ARGV(0, float);
1700                         }
1701                         eventchase_running = true;
1702
1703                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1704                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1705                         if (custom_eventchase)
1706                                 current_view_origin = current_view_origin_override;
1707
1708                         // detect maximum viewoffset and use it
1709                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1710                         if(vehicle_chase)
1711                         {
1712                                 if(vehicle_viewofs)
1713                                         view_offset = vehicle_viewofs;
1714                                 else
1715                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1716                         }
1717                         if (custom_eventchase)
1718                                 view_offset = view_offset_override;
1719
1720                         if(view_offset)
1721                         {
1722                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1723                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1724                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1725                         }
1726
1727                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1728                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1729                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1730                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1731
1732                         // make the camera smooth back
1733                         float chase_distance = autocvar_cl_eventchase_distance;
1734                         if(vehicle_chase)
1735                         {
1736                                 if(vehicle_viewofs)
1737                                         chase_distance = vehicle_viewdist;
1738                                 else
1739                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1740                         }
1741                         if (custom_eventchase)
1742                                 chase_distance = chase_distance_override;
1743
1744                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1745                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1746                         else if(eventchase_current_distance != chase_distance)
1747                                 eventchase_current_distance = chase_distance;
1748
1749                         makevectors(view_angles);
1750
1751                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1752                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1753
1754                         // If the boxtrace fails, revert back to line tracing.
1755                         if(!local_player.viewloc)
1756                         if(trace_startsolid)
1757                         {
1758                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1759                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1760                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1761                         }
1762                         else { setproperty(VF_ORIGIN, trace_endpos); }
1763
1764                         if(!local_player.viewloc)
1765                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1766                 }
1767
1768                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1769                 {
1770                         eventchase_running = false;
1771                         cvar_set("chase_active", "0");
1772                         eventchase_current_distance = 0; // start from 0 next time
1773                 }
1774         }
1775         // workaround for camera stuck between player's legs when using chase_active 1
1776         // because the engine stops updating the chase_active camera when the game ends
1777         else if(intermission)
1778         {
1779                 cvar_settemp("chase_active", "-1");
1780                 eventchase_current_distance = 0;
1781         }
1782
1783         LABEL(skip_eventchase_death);
1784
1785         // do lockview after event chase camera so that it still applies whenever necessary.
1786         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1787         {
1788                 setproperty(VF_ORIGIN, freeze_org);
1789                 setproperty(VF_ANGLES, freeze_ang);
1790         }
1791         else
1792         {
1793                 freeze_org = getpropertyvec(VF_ORIGIN);
1794                 freeze_ang = getpropertyvec(VF_ANGLES);
1795         }
1796
1797         WarpZone_FixView();
1798         //WarpZone_FixPMove();
1799
1800         vector ov_org = '0 0 0';
1801         vector ov_mid = '0 0 0';
1802         vector ov_worldmin = '0 0 0';
1803         vector ov_worldmax = '0 0 0';
1804         if(autocvar_cl_orthoview)
1805         {
1806                 ov_worldmin = mi_picmin;
1807                 ov_worldmax = mi_picmax;
1808
1809                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1810                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1811                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1812
1813                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1814                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1815
1816                 float ov_nearest = vlen(ov_org - vec3(
1817                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1818                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1819                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1820                 ));
1821
1822                 float ov_furthest = 0;
1823                 float dist = 0;
1824
1825                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1826                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1827                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1828                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1829                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1830                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1831                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1832                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1833
1834                 if(!ov_enabled)
1835                 {
1836                         oldr_nearclip = cvar("r_nearclip");
1837                         oldr_farclip_base = cvar("r_farclip_base");
1838                         oldr_farclip_world = cvar("r_farclip_world");
1839                         oldr_novis = cvar("r_novis");
1840                         oldr_useportalculling = cvar("r_useportalculling");
1841                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1842                 }
1843
1844                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1845                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1846                 cvar_settemp("r_farclip_world", "0");
1847                 cvar_settemp("r_novis", "1");
1848                 cvar_settemp("r_useportalculling", "0");
1849                 cvar_settemp("r_useinfinitefarclip", "0");
1850
1851                 setproperty(VF_ORIGIN, ov_org);
1852                 setproperty(VF_ANGLES, '90 0 0');
1853
1854                 ov_enabled = true;
1855
1856                 #if 0
1857                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1858                         vtos(ov_org),
1859                         vtos(getpropertyvec(VF_ANGLES)),
1860                         ov_distance,
1861                         ov_nearest,
1862                         ov_furthest);
1863                 #endif
1864         }
1865         else
1866         {
1867                 if(ov_enabled)
1868                 {
1869                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1870                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1871                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1872                         cvar_set("r_novis", ftos(oldr_novis));
1873                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1874                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1875                 }
1876                 ov_enabled = false;
1877         }
1878
1879         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1880         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1881         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1882                 viewmodel_draw(viewmodels[slot]);
1883
1884         // Render the Scene
1885         view_origin = getpropertyvec(VF_ORIGIN);
1886         view_angles = getpropertyvec(VF_ANGLES);
1887         MAKEVECTORS(makevectors, view_angles, view_forward, view_right, view_up);
1888
1889 #ifdef BLURTEST
1890         if(time > blurtest_time0 && time < blurtest_time1)
1891         {
1892                 float r, t;
1893
1894                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1895                 r = t * blurtest_radius;
1896                 f = 1 / (t ** blurtest_power) - 1;
1897
1898                 cvar_set("r_glsl_postprocess", "1");
1899                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1900         }
1901         else
1902         {
1903                 cvar_set("r_glsl_postprocess", "0");
1904                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1905         }
1906 #endif
1907
1908         TargetMusic_Advance();
1909         Fog_Force();
1910         fpscounter_update();
1911
1912         if(drawtime == 0)
1913                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1914         else
1915                 drawframetime = bound(0.000001, time - drawtime, 1);
1916         drawtime = time;
1917
1918         // watch for gametype changes here...
1919         // in ParseStuffCMD the cmd isn't executed yet :/
1920         // might even be better to add the gametype to TE_CSQC_INIT...?
1921         if(!postinit)
1922                 PostInit();
1923
1924         if(intermission && !intermission_time)
1925                 intermission_time = time;
1926
1927         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1928         {
1929                 if(calledhooks & HOOK_START)
1930                 {
1931                         localcmd("\ncl_hook_gameend\n");
1932                         calledhooks |= HOOK_END;
1933                 }
1934         }
1935
1936         Announcer();
1937
1938         fov = autocvar_fov;
1939         if(fov <= 59.5)
1940         {
1941                 if(!zoomscript_caught)
1942                 {
1943                         localcmd("+button9\n");
1944                         zoomscript_caught = 1;
1945                 }
1946         }
1947         else
1948         {
1949                 if(zoomscript_caught)
1950                 {
1951                         localcmd("-button9\n");
1952                         zoomscript_caught = 0;
1953                 }
1954         }
1955
1956         if(active_minigame && HUD_MinigameMenu_IsOpened())
1957         {
1958                 if(!minigame_wasactive)
1959                 {
1960                         localcmd("+button12\n");
1961                         minigame_wasactive = true;
1962                 }
1963         }
1964         else if(minigame_wasactive)
1965         {
1966                 localcmd("-button12\n");
1967                 minigame_wasactive = false;
1968         }
1969
1970         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1971
1972         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1973         {
1974                 entity wepent = viewmodels[slot];
1975
1976                 if(wepent.last_switchweapon != wepent.switchweapon)
1977                 {
1978                         weapontime = time;
1979                         wepent.last_switchweapon = wepent.switchweapon;
1980                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1981                         {
1982                                 localcmd("-zoom\n");
1983                                 button_zoom = false;
1984                         }
1985                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1986                         {
1987                                 localcmd("-fire\n");
1988                                 localcmd("-fire2\n");
1989                                 button_attack2 = false;
1990                         }
1991                 }
1992                 if(wepent.last_activeweapon != wepent.activeweapon)
1993                 {
1994                         wepent.last_activeweapon = wepent.activeweapon;
1995
1996                         e = wepent.activeweapon;
1997                         if(e.netname != "")
1998                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1999                         else if(slot == 0)
2000                                 localcmd("\ncl_hook_activeweapon none\n");
2001                 }
2002         }
2003
2004         // ALWAYS Clear Current Scene First
2005         clearscene();
2006
2007         setproperty(VF_ORIGIN, view_origin);
2008         setproperty(VF_ANGLES, view_angles);
2009
2010         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2011         setproperty(VF_SIZE, vf_size);
2012         setproperty(VF_MIN, vf_min);
2013
2014         // Assign Standard Viewflags
2015         // Draw the World (and sky)
2016         setproperty(VF_DRAWWORLD, 1);
2017
2018         // Set the console size vars
2019         vid_conwidth = autocvar_vid_conwidth;
2020         vid_conheight = autocvar_vid_conheight;
2021         vid_pixelheight = autocvar_vid_pixelheight;
2022
2023         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2024         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2025         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2026
2027         if(camera_active) // Camera for demo playback
2028         {
2029                 if(autocvar_camera_enable)
2030                         CSQC_Demo_Camera();
2031                 else
2032                 {
2033                         cvar_set("chase_active", ftos(chase_active_backup));
2034                         cvar_set("cl_demo_mousegrab", "0");
2035                         camera_active = false;
2036                 }
2037         }
2038         else
2039         {
2040 #ifdef CAMERATEST
2041                 if(autocvar_camera_enable)
2042 #else
2043                 if(autocvar_camera_enable && isdemo())
2044 #endif
2045                 {
2046                         // Enable required Darkplaces cvars
2047                         chase_active_backup = autocvar_chase_active;
2048                         cvar_set("chase_active", "2");
2049                         cvar_set("cl_demo_mousegrab", "1");
2050                         camera_active = true;
2051                         camera_mode = false;
2052                 }
2053         }
2054
2055         // Draw the Crosshair
2056         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2057
2058         // Draw the Engine Status Bar (the default Quake HUD)
2059         setproperty(VF_DRAWENGINESBAR, 0);
2060
2061         // Update the mouse position
2062         /*
2063            mousepos_x = vid_conwidth;
2064            mousepos_y = vid_conheight;
2065            mousepos = mousepos*0.5 + getmousepos();
2066          */
2067
2068         IL_EACH(g_drawables, it.draw, it.draw(it));
2069
2070         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2071         renderscene();
2072
2073         // now switch to 2D drawing mode by calling a 2D drawing function
2074         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2075         // next R_RenderScene call
2076         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2077
2078         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2079         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2080         {
2081                 // apply night vision effect
2082                 vector tc_00, tc_01, tc_10, tc_11;
2083                 vector rgb = '0 0 0';
2084
2085                 if(!nightvision_noise)
2086                 {
2087                         nightvision_noise = new(nightvision_noise);
2088                 }
2089                 if(!nightvision_noise2)
2090                 {
2091                         nightvision_noise2 = new(nightvision_noise2);
2092                 }
2093
2094                 // color tint in yellow
2095                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2096
2097                 // draw BG
2098                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2099                 rgb = '1 1 1';
2100                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2101                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2102                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2103                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2104                 tc_11 = tc_01 + tc_10 - tc_00;
2105                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2106                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2107                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2108                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2109                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2110                 R_EndPolygon();
2111
2112                 // draw FG
2113                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2114                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2115                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2116                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2117                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2118                 tc_11 = tc_01 + tc_10 - tc_00;
2119                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2120                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2121                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2122                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2123                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2124                 R_EndPolygon();
2125         }
2126
2127         if(autocvar_cl_reticle && !MUTATOR_CALLHOOK(DrawReticle))
2128         {
2129                 string reticle_image = string_null;
2130                 bool wep_zoomed = false;
2131                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2132                 {
2133                         entity wepe = viewmodels[slot];
2134                         Weapon wep = wepe.activeweapon;
2135                         if(wep != WEP_Null && wep.wr_zoom)
2136                         {
2137                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2138                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2139                                         reticle_image = wep.w_reticle;
2140                                 wep_zoomed += do_zoom;
2141                         }
2142                 }
2143                 // Draw the aiming reticle for weapons that use it
2144                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2145                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2146                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2147                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2148                 {
2149                         // no zoom reticle while dead
2150                         reticle_type = 0;
2151                 }
2152                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2153                 {
2154                         if(reticle_image) { reticle_type = 2; }
2155                         else { reticle_type = 0; }
2156                 }
2157                 else if(button_zoom || zoomscript_caught)
2158                 {
2159                         // normal zoom
2160                         reticle_type = 1;
2161                 }
2162
2163                 if(reticle_type)
2164                 {
2165                         if(autocvar_cl_reticle_stretch)
2166                         {
2167                                 reticle_size.x = vid_conwidth;
2168                                 reticle_size.y = vid_conheight;
2169                                 reticle_pos.x = 0;
2170                                 reticle_pos.y = 0;
2171                         }
2172                         else
2173                         {
2174                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2175                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2176                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2177                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2178                         }
2179
2180                         if(zoomscript_caught)
2181                                 f = 1;
2182                         else
2183                                 f = current_zoomfraction;
2184
2185                         if(f)
2186                         {
2187                                 switch(reticle_type)
2188                                 {
2189                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2190                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2191                                 }
2192                         }
2193                 }
2194         }
2195         else
2196         {
2197                 if(reticle_type != 0) { reticle_type = 0; }
2198         }
2199
2200
2201         // improved polyblend
2202         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2203         {
2204                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2205                 vector liquidcolor;
2206
2207                 switch(pointcontents(view_origin))
2208                 {
2209                         case CONTENT_WATER:
2210                                 liquidalpha = autocvar_hud_contents_water_alpha;
2211                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2212                                 incontent = 1;
2213                                 break;
2214
2215                         case CONTENT_LAVA:
2216                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2217                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2218                                 incontent = 1;
2219                                 break;
2220
2221                         case CONTENT_SLIME:
2222                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2223                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2224                                 incontent = 1;
2225                                 break;
2226
2227                         default:
2228                                 liquidalpha = 0;
2229                                 liquidcolor = '0 0 0';
2230                                 incontent = 0;
2231                                 break;
2232                 }
2233
2234                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2235                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2236                         contentfadetime = autocvar_hud_contents_fadeintime;
2237                         liquidalpha_prev = liquidalpha;
2238                         liquidcolor_prev = liquidcolor;
2239                 }
2240                 else
2241                         contentfadetime = autocvar_hud_contents_fadeouttime;
2242
2243                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2244                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2245
2246                 if(contentavgalpha)
2247                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2248
2249                 if(autocvar_hud_postprocessing)
2250                 {
2251                         if(autocvar_hud_contents_blur && contentavgalpha)
2252                         {
2253                                 content_blurpostprocess.x = 1;
2254                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2255                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2256                         }
2257                         else
2258                         {
2259                                 content_blurpostprocess.x = 0;
2260                                 content_blurpostprocess.y = 0;
2261                                 content_blurpostprocess.z = 0;
2262                         }
2263                 }
2264         }
2265
2266         if(autocvar_hud_damage && !STAT(FROZEN))
2267         {
2268                 splash_size.x = max(vid_conwidth, vid_conheight);
2269                 splash_size.y = max(vid_conwidth, vid_conheight);
2270                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2271                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2272
2273                 float myhealth_flash_temp;
2274                 myhealth = STAT(HEALTH);
2275
2276                 // fade out
2277                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2278                 // add new damage
2279                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2280
2281                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2282                 pain_threshold = autocvar_hud_damage_pain_threshold;
2283                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2284                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2285
2286                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2287                 {
2288                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2289                 }
2290
2291                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2292
2293                 if(myhealth_prev < 1)
2294                 {
2295                         if(myhealth >= 1)
2296                         {
2297                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2298                                 myhealth_flash_temp = 0;
2299                         }
2300                         else
2301                         {
2302                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2303                         }
2304                 }
2305
2306                 if(spectatee_status == -1 || intermission)
2307                 {
2308                         myhealth_flash = 0; // observing, or match ended
2309                         myhealth_flash_temp = 0;
2310                 }
2311
2312                 myhealth_prev = myhealth;
2313
2314                 // IDEA: change damage color/picture based on player model for robot/alien species?
2315                 // pro: matches model better
2316                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2317                 // maybe different reddish pics?
2318                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2319                 {
2320                         if(autocvar_cl_gentle_damage == 2)
2321                         {
2322                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2323                                         myhealth_gentlergb = randomvec();
2324                         }
2325                         else
2326                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2327
2328                         if(myhealth_flash_temp > 0)
2329                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2330                 }
2331                 else if(myhealth_flash_temp > 0)
2332                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2333
2334                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2335                 {
2336                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2337                         {
2338                                 damage_blurpostprocess.x = 1;
2339                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2340                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2341                         }
2342                         else
2343                         {
2344                                 damage_blurpostprocess.x = 0;
2345                                 damage_blurpostprocess.y = 0;
2346                                 damage_blurpostprocess.z = 0;
2347                         }
2348                 }
2349         }
2350
2351         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2352         float e2 = (autocvar_hud_powerup != 0);
2353         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2354         {
2355                 // enable or disable rendering types if they are used or not
2356                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2357                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2358
2359                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2360                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2361                 {
2362                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2363                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2364                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2365                         {
2366                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2367                                 old_blurradius = blurradius;
2368                                 old_bluralpha = bluralpha;
2369                         }
2370                 }
2371                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2372                 {
2373                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2374                         old_blurradius = 0;
2375                         old_bluralpha = 0;
2376                 }
2377
2378                 // edge detection postprocess handling done second (used by hud_powerup)
2379                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2380                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2381                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2382
2383                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2384
2385                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2386                 {
2387                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2388                         {
2389                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2390                                 old_sharpen_intensity = sharpen_intensity;
2391                         }
2392                 }
2393                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2394                 {
2395                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2396                         old_sharpen_intensity = 0;
2397                 }
2398
2399                 if(cvar("r_glsl_postprocess") == 0)
2400                         cvar_set("r_glsl_postprocess", "2");
2401         }
2402         else if(cvar("r_glsl_postprocess") == 2)
2403                 cvar_set("r_glsl_postprocess", "0");
2404
2405         /*if(ISGAMETYPE(CTF))
2406           {
2407           ctf_view();
2408           } else */
2409
2410         // draw 2D entities
2411         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2412         Draw_ShowNames_All();
2413 #if ENABLE_DEBUGDRAW
2414         Debug_Draw();
2415 #endif
2416
2417         scoreboard_active = Scoreboard_WouldDraw();
2418
2419         HUD_Draw(this); // this parameter for deep vehicle function
2420
2421         if(NextFrameCommand)
2422         {
2423                 localcmd("\n", NextFrameCommand, "\n");
2424                 NextFrameCommand = string_null;
2425         }
2426
2427         // we must do this check AFTER a frame was rendered, or it won't work
2428         if(cs_project_is_b0rked == 0)
2429         {
2430                 string w0, h0;
2431                 w0 = ftos(autocvar_vid_conwidth);
2432                 h0 = ftos(autocvar_vid_conheight);
2433                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2434                 //setproperty(VF_FOV, '90 90 0');
2435                 setproperty(VF_ORIGIN, '0 0 0');
2436                 setproperty(VF_ANGLES, '0 0 0');
2437                 setproperty(VF_PERSPECTIVE, 1);
2438                 makevectors('0 0 0');
2439                 vector v1, v2;
2440                 cvar_set("vid_conwidth", "800");
2441                 cvar_set("vid_conheight", "600");
2442                 v1 = cs_project(v_forward);
2443                 cvar_set("vid_conwidth", "640");
2444                 cvar_set("vid_conheight", "480");
2445                 v2 = cs_project(v_forward);
2446                 if(v1 == v2)
2447                         cs_project_is_b0rked = 1;
2448                 else
2449                         cs_project_is_b0rked = -1;
2450                 cvar_set("vid_conwidth", w0);
2451                 cvar_set("vid_conheight", h0);
2452         }
2453
2454         HUD_Mouse(local_player);
2455
2456         cl_notice_run();
2457         unpause_update();
2458         Net_Flush();
2459
2460         // let's reset the view back to normal for the end
2461         setproperty(VF_MIN, '0 0 0');
2462         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2463
2464         IL_ENDFRAME();
2465 }
2466
2467
2468 // following vectors must be global to allow seamless switching between camera modes
2469 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2470 void CSQC_Demo_Camera()
2471 {
2472         float speed, attenuation, dimensions;
2473         vector tmp, delta;
2474
2475         if( autocvar_camera_reset || !camera_mode )
2476         {
2477                 camera_offset = '0 0 0';
2478                 current_angles = '0 0 0';
2479                 camera_direction = '0 0 0';
2480                 camera_offset.z += 30;
2481                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2482                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2483                 current_origin = view_origin;
2484                 current_camera_offset  = camera_offset;
2485                 cvar_set("camera_reset", "0");
2486                 camera_mode = CAMERA_CHASE;
2487         }
2488
2489         // Camera angles
2490         if( camera_roll )
2491                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2492
2493         if(autocvar_camera_look_player)
2494         {
2495                 vector dir;
2496                 float n;
2497
2498                 dir = normalize(view_origin - current_position);
2499                 n = mouse_angles.z;
2500                 mouse_angles = vectoangles(dir);
2501                 mouse_angles.x = mouse_angles.x * -1;
2502                 mouse_angles.z = n;
2503         }
2504         else
2505         {
2506                 tmp = getmousepos() * 0.1;
2507                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2508                 {
2509                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2510                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2511                 }
2512         }
2513
2514         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2515         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2516         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2517         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2518
2519         // Fix difference when angles don't have the same sign
2520         delta = '0 0 0';
2521         if(mouse_angles.y < -60 && current_angles.y > 60)
2522                 delta = '0 360 0';
2523         if(mouse_angles.y > 60 && current_angles.y < -60)
2524                 delta = '0 -360 0';
2525
2526         if(autocvar_camera_look_player)
2527                 attenuation = autocvar_camera_look_attenuation;
2528         else
2529                 attenuation = autocvar_camera_speed_attenuation;
2530
2531         attenuation = 1 / max(1, attenuation);
2532         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2533
2534         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2535         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2536         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2537         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2538
2539         // Camera position
2540         tmp = '0 0 0';
2541         dimensions = 0;
2542
2543         if( camera_direction.x )
2544         {
2545                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2546                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2547                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2548                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2549                 ++dimensions;
2550         }
2551
2552         if( camera_direction.y )
2553         {
2554                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2555                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2556                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2557                 ++dimensions;
2558         }
2559
2560         if( camera_direction.z )
2561         {
2562                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2563                 ++dimensions;
2564         }
2565
2566         if(autocvar_camera_free)
2567                 speed = autocvar_camera_speed_free;
2568         else
2569                 speed = autocvar_camera_speed_chase;
2570
2571         if(dimensions)
2572         {
2573                 speed = speed * sqrt(1 / dimensions);
2574                 camera_offset += tmp * speed;
2575         }
2576
2577         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2578
2579         // Camera modes
2580         if( autocvar_camera_free )
2581         {
2582                 if ( camera_mode == CAMERA_CHASE )
2583                 {
2584                         current_camera_offset = current_origin + current_camera_offset;
2585                         camera_offset = current_origin + camera_offset;
2586                 }
2587
2588                 camera_mode = CAMERA_FREE;
2589                 current_position = current_camera_offset;
2590         }
2591         else
2592         {
2593                 if ( camera_mode == CAMERA_FREE )
2594                 {
2595                         current_origin = view_origin;
2596                         camera_offset = camera_offset - current_origin;
2597                         current_camera_offset = current_camera_offset - current_origin;
2598                 }
2599
2600                 camera_mode = CAMERA_CHASE;
2601
2602                 if(autocvar_camera_chase_smoothly)
2603                         current_origin += (view_origin - current_origin) * attenuation;
2604                 else
2605                         current_origin = view_origin;
2606
2607                 current_position = current_origin + current_camera_offset;
2608         }
2609
2610         setproperty(VF_ANGLES, current_angles);
2611         setproperty(VF_ORIGIN, current_position);
2612 }