qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "announcer.qh"
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "scoreboard.qh"
   7 #include "shownames.qh"
   8 #include "quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include "../common/anim.qh"
  13 #include "../common/constants.qh"
  14 #include "../common/debug.qh"
  15 #include "../common/mapinfo.qh"
  16 #include <common/gamemodes/all.qh>
  17 #include "../common/physics/player.qh"
  18 #include "../common/stats.qh"
  19 #include "../common/triggers/target/music.qh"
  20 #include "../common/teams.qh"
  21
  22 #include <common/vehicles/all.qh>
  23 #include <common/weapons/all.qh>
  24 #include "../common/viewloc.qh"
  25 #include "../common/minigames/cl_minigames.qh"
  26 #include "../common/minigames/cl_minigames_hud.qh"
  27
  28 #include "../lib/csqcmodel/cl_player.qh"
  29
  30 #include "../lib/warpzone/client.qh"
  31 #include "../lib/warpzone/common.qh"
  32
  33 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  34
  35 float autocvar_cl_viewmodel_scale;
  36
  37 bool autocvar_cl_bobmodel;
  38 float autocvar_cl_bobmodel_speed;
  39 float autocvar_cl_bobmodel_side;
  40 float autocvar_cl_bobmodel_up;
  41
  42 float autocvar_cl_followmodel;
  43 float autocvar_cl_followmodel_speed = 0.3;
  44 float autocvar_cl_followmodel_limit = 135;
  45 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  46 float autocvar_cl_followmodel_highpass = 0.05;
  47 float autocvar_cl_followmodel_lowpass = 0.03;
  48 bool autocvar_cl_followmodel_velocity_absolute;
  49
  50 float autocvar_cl_leanmodel;
  51 float autocvar_cl_leanmodel_speed = 0.3;
  52 float autocvar_cl_leanmodel_limit = 30;
  53 float autocvar_cl_leanmodel_highpass1 = 0.2;
  54 float autocvar_cl_leanmodel_highpass = 0.2;
  55 float autocvar_cl_leanmodel_lowpass = 0.05;
  56
  57 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  58 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  59 { \
  60         ret = ref_store = ref_store * (1 - frac) + (value) * frac; \
  61 } MACRO_END
  62
  63 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  64 { \
  65         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  66         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  67 } MACRO_END
  68
  69 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  70 { \
  71         float __f = 0; lowpass(value, frac, ref_store, __f); \
  72         ret = (value) - __f; \
  73 } MACRO_END
  74
  75 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  76 { \
  77         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  78         ret = (value) - __f; \
  79 } MACRO_END
  80
  81 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  82 { \
  83         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  84         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  85 } MACRO_END
  86
  87 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  88 { \
  89         highpass(value.x, frac, ref_store.x, ref_out.x); \
  90         highpass(value.y, frac, ref_store.y, ref_out.y); \
  91 } MACRO_END
  92
  93 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
  94 { \
  95         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
  96         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
  97 } MACRO_END
  98
  99 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 100 { \
 101         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 102         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 103         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 104 } MACRO_END
 105
 106 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 107 { \
 108         highpass(value.x, frac, ref_store.x, ref_out.x); \
 109         highpass(value.y, frac, ref_store.y, ref_out.y); \
 110         highpass(value.z, frac, ref_store.z, ref_out.z); \
 111 } MACRO_END
 112
 113 void viewmodel_animate(entity this)
 114 {
 115         static float prevtime;
 116         float frametime = (time - prevtime);
 117         prevtime = time;
 118
 119         if (autocvar_chase_active) return;
 120         if (STAT(HEALTH) <= 0) return;
 121
 122         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 123
 124         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 125         static bool oldonground;
 126         static float hitgroundtime;
 127         if (clonground)
 128         {
 129                 float f = time; // cl.movecmd[0].time
 130                 if (!oldonground)
 131                         hitgroundtime = f;
 132         }
 133         oldonground = clonground;
 134
 135
 136         bool teleported = view.csqcmodel_teleported;
 137
 138         float frac;
 139         if(autocvar_cl_followmodel)
 140         {
 141                 vector gunorg = '0 0 0';
 142                 static vector vel_average;
 143                 static vector gunorg_prev = '0 0 0';
 144                 static vector gunorg_adjustment_highpass;
 145                 static vector gunorg_adjustment_lowpass;
 146
 147                 vector vel;
 148                 if(autocvar_cl_followmodel_velocity_absolute)
 149                         vel = view.velocity;
 150                 else
 151                 {
 152                         vector forward, right = '0 0 0', up = '0 0 0';
 153                         MAKEVECTORS(makevectors, view_angles, forward, right, up);
 154                         vel.x = view.velocity * forward;
 155                         vel.y = view.velocity * right * -1;
 156                         vel.z = view.velocity * up;
 157                 }
 158
 159                 vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 160                 vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 161                 vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 162
 163                 frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 164                 lowpass3(vel, frac, vel_average, gunorg);
 165
 166                 gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 167
 168                 // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 169                 // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 170                 frac = avg_factor(autocvar_cl_followmodel_highpass);
 171                 highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 172                 frac = avg_factor(autocvar_cl_followmodel_lowpass);
 173                 lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 174
 175                 if(autocvar_cl_followmodel_velocity_absolute)
 176                 {
 177                         vector fixed_gunorg;
 178                         vector forward, right = '0 0 0', up = '0 0 0';
 179                         MAKEVECTORS(makevectors, view_angles, forward, right, up);
 180                         fixed_gunorg.x = gunorg * forward;
 181                         fixed_gunorg.y = gunorg * right * -1;
 182                         fixed_gunorg.z = gunorg * up;
 183                         gunorg = fixed_gunorg;
 184                 }
 185
 186                 this.origin += gunorg;
 187         }
 188
 189         if(autocvar_cl_leanmodel)
 190         {
 191                 vector gunangles = '0 0 0';
 192                 static vector gunangles_prev = '0 0 0';
 193                 static vector gunangles_highpass = '0 0 0';
 194                 static vector gunangles_adjustment_highpass;
 195                 static vector gunangles_adjustment_lowpass;
 196
 197                 if (teleported)
 198                         gunangles_prev = view_angles;
 199
 200                 // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 201                 gunangles_highpass += gunangles_prev;
 202                 PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 203                 YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 204                 ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 205                 frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 206                 highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 207                 gunangles_prev = view_angles;
 208                 gunangles_highpass -= gunangles_prev;
 209
 210                 PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 211                 YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 212
 213                 // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 214                 frac = avg_factor(autocvar_cl_leanmodel_highpass);
 215                 highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 216                 frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 217                 lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 218
 219                 gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 220                 this.angles += gunangles;
 221         }
 222
 223         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 224
 225         // vertical view bobbing code
 226         // TODO: cl_bob
 227
 228         // horizontal view bobbing code
 229         // TODO: cl_bob2
 230
 231         // fall bobbing code
 232         // causes the view to swing down and back up when touching the ground
 233         // TODO: cl_bobfall
 234
 235         // gun model bobbing code
 236         if (autocvar_cl_bobmodel)
 237         {
 238                 // calculate for swinging gun model
 239                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 240                 static float bobmodel_scale = 0;
 241                 static float time_ofs = 0; // makes the effect always restart in the same way
 242                 if (clonground)
 243                 {
 244                         if (time - hitgroundtime > 0.05)
 245                                 bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 246                 }
 247                 else
 248                         bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 249                 if(bobmodel_scale && xyspeed)
 250                 {
 251                         float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 252                         float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 253                         vector gunorg = '0 0 0';
 254                         gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 255                         gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 256
 257                         this.origin += gunorg;
 258                 }
 259                 else
 260                         time_ofs = time;
 261         }
 262 }
 263
 264 .vector viewmodel_origin, viewmodel_angles;
 265 .float weapon_nextthink;
 266 .float weapon_eta_last;
 267 .float weapon_switchdelay;
 268
 269 void viewmodel_draw(entity this)
 270 {
 271         if(!activeweapon)
 272                 return;
 273         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 274         float a = this.alpha;
 275         static bool wasinvehicle;
 276         bool invehicle = player_localentnum > maxclients;
 277         if (invehicle) a = -1;
 278         else if (wasinvehicle) a = 1;
 279         wasinvehicle = invehicle;
 280         Weapon wep = activeweapon;
 281         int c = stof(getplayerkeyvalue(current_player, "colors"));
 282         vector g = weaponentity_glowmod(wep, c);
 283         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 284         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 285                 | EF_NODEPTHTEST)
 286                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 287         for (entity e = this; e; e = e.weaponchild)
 288         {
 289                 e.drawmask = mask;
 290                 e.alpha = a;
 291                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 292                 e.glowmod = g;
 293                 e.csqcmodel_effects = fx;
 294                 CSQCModel_Effects_Apply(e);
 295         }
 296         {
 297                 static string name_last;
 298                 string name = wep.mdl;
 299                 if (name != name_last)
 300                 {
 301                         name_last = name;
 302                         CL_WeaponEntity_SetModel(this, name);
 303                         this.viewmodel_origin = this.origin;
 304                         this.viewmodel_angles = this.angles;
 305                 }
 306                 anim_update(this);
 307                 if (!this.animstate_override)
 308                         anim_set(this, this.anim_idle, true, false, false);
 309         }
 310         float f = 0; // 0..1; 0: fully active
 311         float eta = (this.weapon_nextthink - time) / STAT(WEAPONRATEFACTOR);
 312         if (eta <= 0) f = this.weapon_eta_last;
 313         else switch (this.state)
 314         {
 315                 case WS_RAISE:
 316                 {
 317                         f = eta / max(eta, this.weapon_switchdelay);
 318                         break;
 319                 }
 320                 case WS_DROP:
 321                 {
 322                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 323                         break;
 324                 }
 325                 case WS_CLEAR:
 326                 {
 327                         f = 1;
 328                         break;
 329                 }
 330         }
 331         this.weapon_eta_last = f;
 332         this.origin = this.viewmodel_origin;
 333         this.angles = this.viewmodel_angles;
 334         this.angles_x = (-90 * f * f);
 335         viewmodel_animate(this);
 336         setorigin(this, this.origin);
 337 }
 338
 339 entity viewmodel;
 340 STATIC_INIT(viewmodel) {
 341     viewmodel = new(viewmodel);
 342 }
 343
 344 void Porto_Draw(entity this);
 345 STATIC_INIT(Porto)
 346 {
 347         entity e = new_pure(porto);
 348         e.draw = Porto_Draw;
 349         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 350 }
 351
 352 const int polyline_length = 16;
 353 vector polyline[polyline_length];
 354 void Porto_Draw(entity this)
 355 {
 356         if (activeweapon != WEP_PORTO) return;
 357         if (spectatee_status) return;
 358         if (WEP_CVAR(porto, secondary)) return;
 359         if (intermission == 1) return;
 360         if (intermission == 2) return;
 361         if (STAT(HEALTH) <= 0) return;
 362
 363         vector pos = view_origin;
 364         vector dir = view_forward;
 365         if (angles_held_status)
 366         {
 367                 makevectors(angles_held);
 368                 dir = v_forward;
 369         }
 370
 371         polyline[0] = pos;
 372
 373         int portal_number = 0, portal1_idx = 1, portal_max = 2;
 374         int n = 1 + 2;  // 2 lines == 3 points
 375         for (int idx = 0; idx < n && idx < polyline_length - 1; )
 376         {
 377                 traceline(pos, pos + 65536 * dir, true, this);
 378                 dir = reflect(dir, trace_plane_normal);
 379                 pos = trace_endpos;
 380                 polyline[++idx] = pos;
 381                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 382                 {
 383                         n += 1;
 384                         continue;
 385                 }
 386                 if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 387                 {
 388                         n = max(2, idx);
 389                         break;
 390                 }
 391                 // check size
 392                 {
 393                         vector ang = vectoangles2(trace_plane_normal, dir);
 394                         ang.x = -ang.x;
 395                         makevectors(ang);
 396                         if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 397                         {
 398                                 n = max(2, idx);
 399                                 break;
 400                         }
 401                 }
 402                 portal_number += 1;
 403                 if (portal_number >= portal_max) break;
 404                 if (portal_number == 1) portal1_idx = idx;
 405         }
 406         for (int idx = 0; idx < n - 1; ++idx)
 407         {
 408                 vector p = polyline[idx], q = polyline[idx + 1];
 409                 if (idx == 0) p -= view_up * 16;  // line from player
 410                 vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 411                 Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 412         }
 413 }
 414
 415 float drawtime;
 416 float avgspeed;
 417 vector GetCurrentFov(float fov)
 418 {
 419         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 420         float velocityzoom, curspeed;
 421         vector v;
 422
 423         zoomsensitivity = autocvar_cl_zoomsensitivity;
 424         zoomfactor = autocvar_cl_zoomfactor;
 425         if(zoomfactor < 1 || zoomfactor > 30)
 426                 zoomfactor = 2.5;
 427         zoomspeed = autocvar_cl_zoomspeed;
 428         if(zoomspeed >= 0)
 429         if(zoomspeed < 0.5 || zoomspeed > 16)
 430                         zoomspeed = 3.5;
 431
 432         zoomdir = button_zoom;
 433         if(hud == HUD_NORMAL)
 434         if(switchweapon == activeweapon)
 435         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 436                 zoomdir += button_attack2;
 437         if(spectatee_status > 0 || isdemo())
 438         {
 439                 if(spectatorbutton_zoom)
 440                 {
 441                         if(zoomdir)
 442                                 zoomdir = 0;
 443                         else
 444                                 zoomdir = 1;
 445                 }
 446                 // fteqcc failed twice here already, don't optimize this
 447         }
 448
 449         if(zoomdir) { zoomin_effect = 0; }
 450
 451         if(camera_active)
 452         {
 453                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 454         }
 455         else if(autocvar_cl_spawnzoom && zoomin_effect)
 456         {
 457                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 458
 459                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 460                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 461                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 462         }
 463         else
 464         {
 465                 if(zoomspeed < 0) // instant zoom
 466                 {
 467                         if(zoomdir)
 468                                 current_viewzoom = 1 / zoomfactor;
 469                         else
 470                                 current_viewzoom = 1;
 471                 }
 472                 else
 473                 {
 474                         if(zoomdir)
 475                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 476                         else
 477                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 478                 }
 479         }
 480
 481         if(almost_equals(current_viewzoom, 1))
 482                 current_zoomfraction = 0;
 483         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 484                 current_zoomfraction = 1;
 485         else
 486                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 487
 488         if(zoomsensitivity < 1)
 489                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 490         else
 491                 setsensitivityscale(1);
 492
 493         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 494         {
 495                 if(intermission) { curspeed = 0; }
 496                 else
 497                 {
 498
 499                         makevectors(view_angles);
 500                         v = pmove_vel;
 501                         if(csqcplayer)
 502                                 v = csqcplayer.velocity;
 503
 504                         switch(autocvar_cl_velocityzoom_type)
 505                         {
 506                                 case 3: curspeed = max(0, v_forward * v); break;
 507                                 case 2: curspeed = (v_forward * v); break;
 508                                 case 1: default: curspeed = vlen(v); break;
 509                         }
 510                 }
 511
 512                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 513                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 514                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 515
 516                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 517         }
 518         else
 519                 velocityzoom = 1;
 520
 521         float frustumx, frustumy, fovx, fovy;
 522         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 523         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 524         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 525         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 526
 527         return '1 0 0' * fovx + '0 1 0' * fovy;
 528 }
 529
 530 vector GetViewLocationFOV(float fov)
 531 {
 532         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 533         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 534         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 535         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 536         return '1 0 0' * fovx + '0 1 0' * fovy;
 537 }
 538
 539 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 540 {
 541         float fovx, fovy;
 542         float width = (ov_worldmax.x - ov_worldmin.x);
 543         float height = (ov_worldmax.y - ov_worldmin.y);
 544         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 545         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 546         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 547         return '1 0 0' * fovx + '0 1 0' * fovy;
 548 }
 549
 550 // this function must match W_SetupShot!
 551 float zoomscript_caught;
 552
 553 vector wcross_origin;
 554 float wcross_scale_prev, wcross_alpha_prev;
 555 vector wcross_color_prev;
 556 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 557 vector wcross_color_goal_prev;
 558 float wcross_changedonetime;
 559
 560 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 561 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 562 float wcross_name_changestarttime, wcross_name_changedonetime;
 563 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 564
 565 float wcross_ring_prev;
 566
 567 entity trueaim;
 568 entity trueaim_rifle;
 569
 570 const float SHOTTYPE_HITTEAM = 1;
 571 const float SHOTTYPE_HITOBSTRUCTION = 2;
 572 const float SHOTTYPE_HITWORLD = 3;
 573 const float SHOTTYPE_HITENEMY = 4;
 574
 575 void TrueAim_Init()
 576 {
 577         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 578         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 579 }
 580
 581 float EnemyHitCheck()
 582 {
 583         float t, n;
 584         wcross_origin = project_3d_to_2d(trace_endpos);
 585         wcross_origin.z = 0;
 586         if(trace_ent)
 587                 n = trace_ent.entnum;
 588         else
 589                 n = trace_networkentity;
 590         if(n < 1)
 591                 return SHOTTYPE_HITWORLD;
 592         if(n > maxclients)
 593                 return SHOTTYPE_HITWORLD;
 594         t = entcs_GetTeam(n - 1);
 595         if(teamplay)
 596                 if(t == myteam)
 597                         return SHOTTYPE_HITTEAM;
 598         if(t == NUM_SPECTATOR)
 599                 return SHOTTYPE_HITWORLD;
 600         return SHOTTYPE_HITENEMY;
 601 }
 602
 603 float TrueAimCheck()
 604 {
 605         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 606         vector vecs, trueaimpoint, w_shotorg;
 607         vector mi, ma, dv;
 608         float shottype;
 609         entity ta;
 610         float mv;
 611
 612         mi = ma = '0 0 0';
 613         ta = trueaim;
 614         mv = MOVE_NOMONSTERS;
 615
 616         switch(activeweapon) // WEAPONTODO
 617         {
 618                 case WEP_TUBA: // no aim
 619                 case WEP_PORTO: // shoots from eye
 620                 case WEP_NEXBALL: // shoots from eye
 621                 case WEP_HOOK: // no trueaim
 622                 case WEP_MORTAR: // toss curve
 623                         return SHOTTYPE_HITWORLD;
 624                 case WEP_VORTEX:
 625                 case WEP_VAPORIZER:
 626                         mv = MOVE_NORMAL;
 627                         break;
 628                 case WEP_RIFLE:
 629                         ta = trueaim_rifle;
 630                         mv = MOVE_NORMAL;
 631                         if(zoomscript_caught)
 632                         {
 633                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 634                                 return EnemyHitCheck();
 635                         }
 636                         break;
 637                 case WEP_DEVASTATOR: // projectile has a size!
 638                         mi = '-3 -3 -3';
 639                         ma = '3 3 3';
 640                         break;
 641                 case WEP_FIREBALL: // projectile has a size!
 642                         mi = '-16 -16 -16';
 643                         ma = '16 16 16';
 644                         break;
 645                 case WEP_SEEKER: // projectile has a size!
 646                         mi = '-2 -2 -2';
 647                         ma = '2 2 2';
 648                         break;
 649                 case WEP_ELECTRO: // projectile has a size!
 650                         mi = '0 0 -3';
 651                         ma = '0 0 -3';
 652                         break;
 653         }
 654
 655         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 656
 657         vecs = decompressShotOrigin(STAT(SHOTORG));
 658
 659         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 660         trueaimpoint = trace_endpos;
 661
 662         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 663                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 664
 665         if(vecs.x > 0)
 666                 vecs.y = -vecs.y;
 667         else
 668                 vecs = '0 0 0';
 669
 670         dv = view_right * vecs.y + view_up * vecs.z;
 671         w_shotorg = traceorigin + dv;
 672
 673         // now move the vecs forward as much as requested if possible
 674         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 675         w_shotorg = trace_endpos - view_forward * nudge;
 676
 677         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 678         shottype = EnemyHitCheck();
 679         if(shottype != SHOTTYPE_HITWORLD)
 680                 return shottype;
 681
 682 #if 0
 683         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 684         // or rather, I know why, but see no fix
 685         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 686                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 687                 return SHOTTYPE_HITOBSTRUCTION;
 688 #endif
 689
 690         return SHOTTYPE_HITWORLD;
 691 }
 692
 693 void PostInit();
 694 void CSQC_Demo_Camera();
 695 float HUD_WouldDrawScoreboard();
 696 float camera_mode;
 697 const float CAMERA_FREE = 1;
 698 const float CAMERA_CHASE = 2;
 699 float reticle_type;
 700 string reticle_image;
 701 string NextFrameCommand;
 702
 703 vector freeze_org, freeze_ang;
 704 entity nightvision_noise, nightvision_noise2;
 705
 706 const float MAX_TIME_DIFF = 5;
 707 float pickup_crosshair_time, pickup_crosshair_size;
 708 float hitindication_crosshair_size;
 709 float use_vortex_chargepool;
 710
 711 float myhealth, myhealth_prev;
 712 float myhealth_flash;
 713
 714 float old_blurradius, old_bluralpha;
 715 float old_sharpen_intensity;
 716
 717 vector myhealth_gentlergb;
 718
 719 float contentavgalpha, liquidalpha_prev;
 720 vector liquidcolor_prev;
 721
 722 float eventchase_current_distance;
 723 float eventchase_running;
 724 bool WantEventchase(entity this)
 725 {
 726         if(autocvar_cl_orthoview)
 727                 return false;
 728         if(intermission)
 729                 return true;
 730         if(this.viewloc)
 731                 return true;
 732         if(spectatee_status >= 0)
 733         {
 734                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 735                         return true;
 736                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 737                         return true;
 738                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
 739                         return true;
 740                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 741                 {
 742                         if(autocvar_cl_eventchase_death == 2)
 743                         {
 744                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 745                                 if(this.velocity == '0 0 0' || eventchase_running)
 746                                         return true;
 747                         }
 748                         else return true;
 749                 }
 750         }
 751         return false;
 752 }
 753
 754 void HUD_Crosshair_Vehicle()
 755 {
 756         if(hud != HUD_BUMBLEBEE_GUN)
 757         {
 758                 Vehicle info = Vehicles_from(hud);
 759                 info.vr_crosshair(info);
 760         }
 761 }
 762
 763 vector damage_blurpostprocess, content_blurpostprocess;
 764
 765 float unaccounted_damage = 0;
 766 void UpdateDamage()
 767 {
 768         // accumulate damage with each stat update
 769         static float damage_total_prev = 0;
 770         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 771         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 772         damage_total_prev = damage_total;
 773
 774         static float damage_dealt_time_prev = 0;
 775         float damage_dealt_time = STAT(HIT_TIME);
 776         if (damage_dealt_time != damage_dealt_time_prev)
 777         {
 778                 unaccounted_damage += unaccounted_damage_new;
 779                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 780         }
 781         damage_dealt_time_prev = damage_dealt_time;
 782
 783         // prevent hitsound when switching spectatee
 784         static float spectatee_status_prev = 0;
 785         if (spectatee_status != spectatee_status_prev)
 786                 unaccounted_damage = 0;
 787         spectatee_status_prev = spectatee_status;
 788 }
 789
 790 void HitSound()
 791 {
 792         // varying sound pitch
 793
 794         static float hitsound_time_prev = 0;
 795         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 796         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 797         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 798         {
 799                 if (autocvar_cl_hitsound && unaccounted_damage)
 800                 {
 801                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 802                         float a = autocvar_cl_hitsound_max_pitch;
 803                         float b = autocvar_cl_hitsound_min_pitch;
 804                         float c = autocvar_cl_hitsound_nom_damage;
 805                         float x = unaccounted_damage;
 806                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 807
 808                         // if sound variation is disabled, set pitch_shift to 1
 809                         if (autocvar_cl_hitsound == 1)
 810                                 pitch_shift = 1;
 811
 812                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 813                         if (autocvar_cl_hitsound == 3)
 814                         {
 815                                 float mirror_value = (a-b)/2 + b;
 816                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 817                         }
 818
 819                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 820
 821                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 822                         // todo: normalize sound pressure levels? seems unnecessary
 823
 824                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 825                 }
 826                 unaccounted_damage = 0;
 827                 hitsound_time_prev = time;
 828         }
 829
 830         static float typehit_time_prev = 0;
 831         float typehit_time = STAT(TYPEHIT_TIME);
 832         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 833         {
 834                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 835                 typehit_time_prev = typehit_time;
 836         }
 837 }
 838
 839 void HUD_Crosshair()
 840 {SELFPARAM();
 841         static float rainbow_last_flicker;
 842         static vector rainbow_prev_color;
 843         entity e = this;
 844         float f, i, j;
 845         vector v;
 846         if(!scoreboard_active && !camera_active && intermission != 2 &&
 847                 spectatee_status != -1 && !csqcplayer.viewloc &&
 848                 !HUD_MinigameMenu_IsOpened() )
 849         {
 850                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 851                         return;
 852
 853                 if (hud != HUD_NORMAL)
 854                 {
 855                         HUD_Crosshair_Vehicle();
 856                         return;
 857                 }
 858
 859                 string wcross_style;
 860                 float wcross_alpha, wcross_resolution;
 861                 wcross_style = autocvar_crosshair;
 862                 if (wcross_style == "0")
 863                         return;
 864                 wcross_resolution = autocvar_crosshair_size;
 865                 if (wcross_resolution == 0)
 866                         return;
 867                 wcross_alpha = autocvar_crosshair_alpha;
 868                 if (wcross_alpha == 0)
 869                         return;
 870
 871                 // TrueAim check
 872                 float shottype;
 873
 874                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 875                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 876                 wcross_origin.z = 0;
 877                 if(autocvar_crosshair_hittest)
 878                 {
 879                         vector wcross_oldorigin;
 880                         wcross_oldorigin = wcross_origin;
 881                         shottype = TrueAimCheck();
 882                         if(shottype == SHOTTYPE_HITWORLD)
 883                         {
 884                                 v = wcross_origin - wcross_oldorigin;
 885                                 v.x /= vid_conwidth;
 886                                 v.y /= vid_conheight;
 887                                 if(vlen(v) > 0.01)
 888                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 889                         }
 890                         if(!autocvar_crosshair_hittest_showimpact)
 891                                 wcross_origin = wcross_oldorigin;
 892                 }
 893                 else
 894                         shottype = SHOTTYPE_HITWORLD;
 895
 896                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 897                 string wcross_name = "";
 898                 float wcross_scale, wcross_blur;
 899
 900                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 901                 {
 902                         e = switchingweapon;
 903                         if(e)
 904                         {
 905                                 if(autocvar_crosshair_per_weapon)
 906                                 {
 907                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 908                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 909                                         //if (wcross_resolution == 0)
 910                                                 //return;
 911
 912                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 913                                         wcross_resolution *= e.w_crosshair_size;
 914                                         wcross_name = e.w_crosshair;
 915                                 }
 916                         }
 917                 }
 918
 919                 if(wcross_name == "")
 920                         wcross_name = strcat("gfx/crosshair", wcross_style);
 921
 922                 // MAIN CROSSHAIR COLOR DECISION
 923                 switch(autocvar_crosshair_color_special)
 924                 {
 925                         case 1: // crosshair_color_per_weapon
 926                         {
 927                                 if(e)
 928                                 {
 929                                         wcross_color = e.wpcolor;
 930                                         break;
 931                                 }
 932                                 else { goto normalcolor; }
 933                         }
 934
 935                         case 2: // crosshair_color_by_health
 936                         {
 937                                 float x = STAT(HEALTH);
 938
 939                                 //x = red
 940                                 //y = green
 941                                 //z = blue
 942
 943                                 wcross_color.z = 0;
 944
 945                                 if(x > 200)
 946                                 {
 947                                         wcross_color.x = 0;
 948                                         wcross_color.y = 1;
 949                                 }
 950                                 else if(x > 150)
 951                                 {
 952                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 953                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 954                                 }
 955                                 else if(x > 100)
 956                                 {
 957                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 958                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 959                                         wcross_color.z = 1 - (x-100)*0.02;
 960                                 }
 961                                 else if(x > 50)
 962                                 {
 963                                         wcross_color.x = 1;
 964                                         wcross_color.y = 1;
 965                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 966                                 }
 967                                 else if(x > 20)
 968                                 {
 969                                         wcross_color.x = 1;
 970                                         wcross_color.y = (x-20)*90/27/100;
 971                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 972                                 }
 973                                 else
 974                                 {
 975                                         wcross_color.x = 1;
 976                                         wcross_color.y = 0;
 977                                 }
 978                                 break;
 979                         }
 980
 981                         case 3: // crosshair_color_rainbow
 982                         {
 983                                 if(time >= rainbow_last_flicker)
 984                                 {
 985                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 986                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 987                                 }
 988                                 wcross_color = rainbow_prev_color;
 989                                 break;
 990                         }
 991                         :normalcolor
 992                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 993                 }
 994
 995                 if(autocvar_crosshair_effect_scalefade)
 996                 {
 997                         wcross_scale = wcross_resolution;
 998                         wcross_resolution = 1;
 999                 }
1000                 else
1001                 {
1002                         wcross_scale = 1;
1003                 }
1004
1005                 if(autocvar_crosshair_pickup)
1006                 {
1007                         float stat_pickup_time = STAT(LAST_PICKUP);
1008
1009                         if(pickup_crosshair_time < stat_pickup_time)
1010                         {
1011                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1012                                         pickup_crosshair_size = 1;
1013
1014                                 pickup_crosshair_time = stat_pickup_time;
1015                         }
1016
1017                         if(pickup_crosshair_size > 0)
1018                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1019                         else
1020                                 pickup_crosshair_size = 0;
1021
1022                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1023                 }
1024
1025                 // todo: make crosshair hit indication dependent on damage dealt
1026                 if(autocvar_crosshair_hitindication)
1027                 {
1028                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1029
1030                         if(unaccounted_damage)
1031                         {
1032                                 hitindication_crosshair_size = 1;
1033                         }
1034
1035                         if(hitindication_crosshair_size > 0)
1036                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1037                         else
1038                                 hitindication_crosshair_size = 0;
1039
1040                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1041                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1042                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1043                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1044                 }
1045
1046                 if(shottype == SHOTTYPE_HITENEMY)
1047                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1048                 if(shottype == SHOTTYPE_HITTEAM)
1049                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1050
1051                 f = fabs(autocvar_crosshair_effect_time);
1052                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1053                 {
1054                         wcross_changedonetime = time + f;
1055                 }
1056                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1057                 {
1058                         wcross_name_changestarttime = time;
1059                         wcross_name_changedonetime = time + f;
1060                         if(wcross_name_goal_prev_prev)
1061                                 strunzone(wcross_name_goal_prev_prev);
1062                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1063                         wcross_name_goal_prev = strzone(wcross_name);
1064                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1065                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1066                         wcross_resolution_goal_prev = wcross_resolution;
1067                 }
1068
1069                 wcross_scale_goal_prev = wcross_scale;
1070                 wcross_alpha_goal_prev = wcross_alpha;
1071                 wcross_color_goal_prev = wcross_color;
1072
1073                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1074                 {
1075                         wcross_blur = 1;
1076                         wcross_alpha *= 0.75;
1077                 }
1078                 else
1079                         wcross_blur = 0;
1080                 // *_prev is at time-frametime
1081                 // * is at wcross_changedonetime+f
1082                 // what do we have at time?
1083                 if(time < wcross_changedonetime)
1084                 {
1085                         f = frametime / (wcross_changedonetime - time + frametime);
1086                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1087                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1088                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1089                 }
1090
1091                 wcross_scale_prev = wcross_scale;
1092                 wcross_alpha_prev = wcross_alpha;
1093                 wcross_color_prev = wcross_color;
1094
1095                 MUTATOR_CALLHOOK(UpdateCrosshair);
1096
1097                 wcross_scale *= 1 - autocvar__menu_alpha;
1098                 wcross_alpha *= 1 - autocvar__menu_alpha;
1099                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1100
1101                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1102                 {
1103                         // crosshair rings for weapon stats
1104                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1105                         {
1106                                 // declarations and stats
1107                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1108                                 string ring_image = string_null, ring_inner_image = string_null;
1109                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1110
1111                                 ring_scale = autocvar_crosshair_ring_size;
1112
1113                                 float weapon_clipload, weapon_clipsize;
1114                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1115                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1116
1117                                 float ok_ammo_charge, ok_ammo_chargepool;
1118                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1119                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1120
1121                                 float vortex_charge, vortex_chargepool;
1122                                 vortex_charge = STAT(VORTEX_CHARGE);
1123                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1124
1125                                 float arc_heat = STAT(ARC_HEAT);
1126
1127                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1128                                         vortex_charge_movingavg = vortex_charge;
1129
1130
1131                                 // handle the values
1132                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1133                                 {
1134                                         if (vortex_chargepool || use_vortex_chargepool) {
1135                                                 use_vortex_chargepool = 1;
1136                                                 ring_inner_value = vortex_chargepool;
1137                                         } else {
1138                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1139                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1140                                         }
1141
1142                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1143                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1144                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1145
1146                                         // draw the outer ring to show the current charge of the weapon
1147                                         ring_value = vortex_charge;
1148                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1149                                         ring_rgb = wcross_color;
1150                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1151                                 }
1152                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1153                                 {
1154                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1155                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1156                                         ring_rgb = wcross_color;
1157                                         ring_image = "gfx/crosshair_ring.tga";
1158                                 }
1159                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1160                                 {
1161                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1162                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1163                                         ring_rgb = wcross_color;
1164                                         ring_image = "gfx/crosshair_ring.tga";
1165                                 }
1166                                 else if (ok_ammo_charge)
1167                                 {
1168                                         ring_value = ok_ammo_chargepool;
1169                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1170                                         ring_rgb = wcross_color;
1171                                         ring_image = "gfx/crosshair_ring.tga";
1172                                 }
1173                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1174                                 {
1175                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1176                                         ring_scale = autocvar_crosshair_ring_reload_size;
1177                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1178                                         ring_rgb = wcross_color;
1179
1180                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1181                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1182                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1183                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1184                                         else
1185                                                 ring_image = "gfx/crosshair_ring.tga";
1186                                 }
1187                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1188                                 {
1189                                         ring_value = arc_heat;
1190                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1191                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1192                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1193                                         ring_image = "gfx/crosshair_ring.tga";
1194                                 }
1195
1196                                 // if in weapon switch animation, fade ring out/in
1197                                 if(autocvar_crosshair_effect_time > 0)
1198                                 {
1199                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1200                                         if (f >= 1)
1201                                         {
1202                                                 wcross_ring_prev = ((ring_image) ? true : false);
1203                                         }
1204
1205                                         if(wcross_ring_prev)
1206                                         {
1207                                                 if(f < 1)
1208                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1209                                         }
1210                                         else
1211                                         {
1212                                                 if(f < 1)
1213                                                         ring_alpha *= bound(0, f, 1);
1214                                         }
1215                                 }
1216
1217                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1218                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1219
1220                                 if (ring_value)
1221                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1222                         }
1223
1224 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1225                         MACRO_BEGIN { \
1226                                 if(wcross_blur > 0) \
1227                                 { \
1228                                         for(i = -2; i <= 2; ++i) \
1229                                         for(j = -2; j <= 2; ++j) \
1230                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1231                                 } \
1232                                 else \
1233                                 { \
1234                                         M(0,0,sz,wcross_name,wcross_alpha); \
1235                                 } \
1236                         } MACRO_END
1237
1238 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1239                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1240
1241 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1242                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1243
1244                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1245                         {
1246                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1247                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1248                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1249                                 f = 1 - f;
1250                         }
1251                         else
1252                         {
1253                                 f = 1;
1254                         }
1255                         wcross_name_alpha_goal_prev = f;
1256
1257                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1258                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1259
1260                         if(autocvar_crosshair_dot)
1261                         {
1262                                 vector wcross_color_old;
1263                                 wcross_color_old = wcross_color;
1264
1265                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1266                                         wcross_color = stov(autocvar_crosshair_dot_color);
1267
1268                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1269                                 // FIXME why don't we use wcross_alpha here?
1270                                 wcross_color = wcross_color_old;
1271                         }
1272                 }
1273         }
1274         else
1275         {
1276                 wcross_scale_prev = 0;
1277                 wcross_alpha_prev = 0;
1278                 wcross_scale_goal_prev = 0;
1279                 wcross_alpha_goal_prev = 0;
1280                 wcross_changedonetime = 0;
1281                 if(wcross_name_goal_prev)
1282                         strunzone(wcross_name_goal_prev);
1283                 wcross_name_goal_prev = string_null;
1284                 if(wcross_name_goal_prev_prev)
1285                         strunzone(wcross_name_goal_prev_prev);
1286                 wcross_name_goal_prev_prev = string_null;
1287                 wcross_name_changestarttime = 0;
1288                 wcross_name_changedonetime = 0;
1289                 wcross_name_alpha_goal_prev = 0;
1290                 wcross_name_alpha_goal_prev_prev = 0;
1291                 wcross_resolution_goal_prev = 0;
1292                 wcross_resolution_goal_prev_prev = 0;
1293         }
1294 }
1295
1296 void HUD_Draw()
1297 {
1298         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1299         {
1300                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, MUTATOR_ARGV(0, vector), autocvar_hud_colorflash_alpha * MUTATOR_ARGV(0, float), DRAWFLAG_ADDITIVE);
1301         }
1302         else if(STAT(FROZEN))
1303         {
1304                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1305         }
1306         if(!intermission)
1307         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1308         {
1309                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1310                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1311         }
1312         else if(STAT(REVIVE_PROGRESS))
1313         {
1314                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1315                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1316         }
1317
1318         if(autocvar_r_letterbox == 0)
1319                 if(autocvar_viewsize < 120)
1320                 {
1321                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1322                                 Accuracy_LoadLevels();
1323
1324                         HUD_Main();
1325                         HUD_DrawScoreboard();
1326                 }
1327
1328         // crosshair goes VERY LAST
1329         UpdateDamage();
1330         HUD_Crosshair();
1331         HitSound();
1332 }
1333
1334 bool ov_enabled;
1335 float oldr_nearclip;
1336 float oldr_farclip_base;
1337 float oldr_farclip_world;
1338 float oldr_novis;
1339 float oldr_useportalculling;
1340 float oldr_useinfinitefarclip;
1341
1342 void cl_notice_run();
1343 float prev_myteam;
1344 int lasthud;
1345 float vh_notice_time;
1346 void WaypointSprite_Load();
1347 void CSQC_UpdateView(float w, float h)
1348 {SELFPARAM();
1349         entity e;
1350         float fov;
1351         float f;
1352         vector vf_size, vf_min;
1353         float a;
1354
1355         execute_next_frame();
1356
1357         ++framecount;
1358
1359         stats_get();
1360         hud = STAT(HUD);
1361
1362         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1363                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1364
1365         lasthud = hud;
1366
1367         if(autocvar__hud_showbinds_reload) // menu can set this one
1368         {
1369                 db_close(binddb);
1370                 binddb = db_create();
1371                 cvar_set("_hud_showbinds_reload", "0");
1372         }
1373
1374         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1375                 view_quality = getproperty(VF_MINFPS_QUALITY);
1376         else
1377                 view_quality = 1;
1378
1379         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1380         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1381
1382         vf_size = getpropertyvec(VF_SIZE);
1383         vf_min = getpropertyvec(VF_MIN);
1384         vid_width = vf_size.x;
1385         vid_height = vf_size.y;
1386
1387         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1388         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1389
1390         WaypointSprite_Load();
1391
1392         CSQCPlayer_SetCamera();
1393
1394         if(player_localentnum <= maxclients) // is it a client?
1395                 current_player = player_localentnum - 1;
1396         else // then player_localentnum is the vehicle I'm driving
1397                 current_player = player_localnum;
1398         myteam = entcs_GetTeam(current_player);
1399
1400         if(myteam != prev_myteam)
1401         {
1402                 myteamcolors = colormapPaletteColor(myteam, 1);
1403                 FOREACH(hud_panels, true, it.update_time = time);
1404                 prev_myteam = myteam;
1405         }
1406
1407         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1408
1409         float is_dead = (STAT(HEALTH) <= 0);
1410
1411         // FIXME do we need this hack?
1412         if(isdemo())
1413         {
1414                 // in demos, input_buttons do not work
1415                 button_zoom = (autocvar__togglezoom == "-");
1416         }
1417         else if(button_zoom
1418                 && autocvar_cl_unpress_zoom_on_death
1419                 && (spectatee_status >= 0)
1420                 && (is_dead || intermission))
1421         {
1422                 // no zoom while dead or in intermission please
1423                 localcmd("-zoom\n");
1424                 button_zoom = false;
1425         }
1426
1427         // event chase camera
1428         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1429         {
1430                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1431                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1432                 entity gen = world;
1433
1434                 float vehicle_viewdist = 0;
1435                 vector vehicle_viewofs = '0 0 0';
1436
1437                 if(vehicle_chase)
1438                 {
1439                         if(hud != HUD_BUMBLEBEE_GUN)
1440                         {
1441                                 Vehicle info = Vehicles_from(hud);
1442                                 vehicle_viewdist = info.height;
1443                                 vehicle_viewofs = info.view_ofs;
1444                         }
1445                 }
1446
1447                 if(ons_roundlost)
1448                 {
1449                         FOREACH_ENTITY_CLASS("onslaught_generator", it.health <= 0, {
1450                                 gen = it;
1451                                 break;
1452                         });
1453                         if(!gen)
1454                                 ons_roundlost = false; // don't enforce the 3rd person camera if there is no dead generator to show
1455                 }
1456                 if(WantEventchase(self) || (!autocvar_cl_orthoview && ons_roundlost))
1457                 {
1458                         eventchase_running = true;
1459
1460                         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1461                         if(!local_player)
1462                                 local_player = self; // fall back!
1463
1464                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1465                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1466                         if(ons_roundlost) { current_view_origin = gen.origin; }
1467
1468                         // detect maximum viewoffset and use it
1469                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1470                         if(vehicle_chase)
1471                         {
1472                                 if(vehicle_viewofs)
1473                                         view_offset = vehicle_viewofs;
1474                                 else
1475                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1476                         }
1477                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1478
1479                         if(view_offset)
1480                         {
1481                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1482                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1483                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1484                         }
1485
1486                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1487                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1488                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1489                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1490
1491                         // make the camera smooth back
1492                         float chase_distance = autocvar_cl_eventchase_distance;
1493                         if(vehicle_chase)
1494                         {
1495                                 if(vehicle_viewofs)
1496                                         chase_distance = vehicle_viewdist;
1497                                 else
1498                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1499                         }
1500                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1501
1502                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1503                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1504                         else if(eventchase_current_distance != chase_distance)
1505                                 eventchase_current_distance = chase_distance;
1506
1507                         makevectors(view_angles);
1508
1509                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1510                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1511
1512                         // If the boxtrace fails, revert back to line tracing.
1513                         if(!local_player.viewloc)
1514                         if(trace_startsolid)
1515                         {
1516                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1517                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1518                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1519                         }
1520                         else { setproperty(VF_ORIGIN, trace_endpos); }
1521
1522                         if(!local_player.viewloc)
1523                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1524                 }
1525                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1526                 {
1527                         eventchase_running = false;
1528                         cvar_set("chase_active", "0");
1529                         eventchase_current_distance = 0; // start from 0 next time
1530                 }
1531         }
1532         // workaround for camera stuck between player's legs when using chase_active 1
1533         // because the engine stops updating the chase_active camera when the game ends
1534         else if(intermission)
1535         {
1536                 cvar_settemp("chase_active", "-1");
1537                 eventchase_current_distance = 0;
1538         }
1539
1540         // do lockview after event chase camera so that it still applies whenever necessary.
1541         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1542         {
1543                 setproperty(VF_ORIGIN, freeze_org);
1544                 setproperty(VF_ANGLES, freeze_ang);
1545         }
1546         else
1547         {
1548                 freeze_org = getpropertyvec(VF_ORIGIN);
1549                 freeze_ang = getpropertyvec(VF_ANGLES);
1550         }
1551
1552         WarpZone_FixView();
1553         //WarpZone_FixPMove();
1554
1555         vector ov_org = '0 0 0';
1556         vector ov_mid = '0 0 0';
1557         vector ov_worldmin = '0 0 0';
1558         vector ov_worldmax = '0 0 0';
1559         if(autocvar_cl_orthoview)
1560         {
1561                 ov_worldmin = mi_picmin;
1562                 ov_worldmax = mi_picmax;
1563
1564                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1565                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1566                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1567
1568                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1569                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1570
1571                 float ov_nearest = vlen(ov_org - vec3(
1572                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1573                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1574                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1575                 ));
1576
1577                 float ov_furthest = 0;
1578                 float dist = 0;
1579
1580                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1581                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1582                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1583                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1584                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1585                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1586                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1587                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1588
1589                 if(!ov_enabled)
1590                 {
1591                         oldr_nearclip = cvar("r_nearclip");
1592                         oldr_farclip_base = cvar("r_farclip_base");
1593                         oldr_farclip_world = cvar("r_farclip_world");
1594                         oldr_novis = cvar("r_novis");
1595                         oldr_useportalculling = cvar("r_useportalculling");
1596                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1597                 }
1598
1599                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1600                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1601                 cvar_settemp("r_farclip_world", "0");
1602                 cvar_settemp("r_novis", "1");
1603                 cvar_settemp("r_useportalculling", "0");
1604                 cvar_settemp("r_useinfinitefarclip", "0");
1605
1606                 setproperty(VF_ORIGIN, ov_org);
1607                 setproperty(VF_ANGLES, '90 0 0');
1608
1609                 ov_enabled = true;
1610
1611                 #if 0
1612                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1613                         vtos(ov_org),
1614                         vtos(getpropertyvec(VF_ANGLES)),
1615                         ov_distance,
1616                         ov_nearest,
1617                         ov_furthest);
1618                 #endif
1619         }
1620         else
1621         {
1622                 if(ov_enabled)
1623                 {
1624                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1625                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1626                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1627                         cvar_set("r_novis", ftos(oldr_novis));
1628                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1629                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1630                 }
1631                 ov_enabled = false;
1632         }
1633
1634         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1635         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1636         viewmodel_draw(viewmodel);
1637
1638         // Render the Scene
1639         view_origin = getpropertyvec(VF_ORIGIN);
1640         view_angles = getpropertyvec(VF_ANGLES);
1641         makevectors(view_angles);
1642         view_forward = v_forward;
1643         view_right = v_right;
1644         view_up = v_up;
1645
1646 #ifdef BLURTEST
1647         if(time > blurtest_time0 && time < blurtest_time1)
1648         {
1649                 float r, t;
1650
1651                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1652                 r = t * blurtest_radius;
1653                 f = 1 / pow(t, blurtest_power) - 1;
1654
1655                 cvar_set("r_glsl_postprocess", "1");
1656                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1657         }
1658         else
1659         {
1660                 cvar_set("r_glsl_postprocess", "0");
1661                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1662         }
1663 #endif
1664
1665         TargetMusic_Advance();
1666         Fog_Force();
1667
1668         if(drawtime == 0)
1669                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1670         else
1671                 drawframetime = bound(0.000001, time - drawtime, 1);
1672         drawtime = time;
1673
1674         // watch for gametype changes here...
1675         // in ParseStuffCMD the cmd isn't executed yet :/
1676         // might even be better to add the gametype to TE_CSQC_INIT...?
1677         if(!postinit)
1678                 PostInit();
1679
1680         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1681         {
1682                 if(calledhooks & HOOK_START)
1683                 {
1684                         localcmd("\ncl_hook_gameend\n");
1685                         calledhooks |= HOOK_END;
1686                 }
1687         }
1688
1689         Announcer();
1690
1691         fov = autocvar_fov;
1692         if(fov <= 59.5)
1693         {
1694                 if(!zoomscript_caught)
1695                 {
1696                         localcmd("+button9\n");
1697                         zoomscript_caught = 1;
1698                 }
1699         }
1700         else
1701         {
1702                 if(zoomscript_caught)
1703                 {
1704                         localcmd("-button9\n");
1705                         zoomscript_caught = 0;
1706                 }
1707         }
1708
1709         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1710
1711         // currently switching-to weapon (for crosshair)
1712         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1713
1714         // actually active weapon (for zoom)
1715         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1716
1717         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1718
1719         f = (serverflags & SERVERFLAG_TEAMPLAY);
1720         if(f != teamplay)
1721         {
1722                 teamplay = f;
1723                 HUD_InitScores();
1724         }
1725
1726         if(last_switchweapon != switchweapon)
1727         {
1728                 weapontime = time;
1729                 last_switchweapon = switchweapon;
1730                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1731                 {
1732                         localcmd("-zoom\n");
1733                         button_zoom = false;
1734                 }
1735                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1736                 {
1737                         localcmd("-fire\n");
1738                         localcmd("-fire2\n");
1739                         button_attack2 = false;
1740                 }
1741         }
1742         if(last_activeweapon != activeweapon)
1743         {
1744                 last_activeweapon = activeweapon;
1745
1746                 e = activeweapon;
1747                 if(e.netname != "")
1748                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1749                 else
1750                         localcmd("\ncl_hook_activeweapon none\n");
1751         }
1752
1753         // ALWAYS Clear Current Scene First
1754         clearscene();
1755
1756         setproperty(VF_ORIGIN, view_origin);
1757         setproperty(VF_ANGLES, view_angles);
1758
1759         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1760         setproperty(VF_SIZE, vf_size);
1761         setproperty(VF_MIN, vf_min);
1762
1763         // Assign Standard Viewflags
1764         // Draw the World (and sky)
1765         setproperty(VF_DRAWWORLD, 1);
1766
1767         // Set the console size vars
1768         vid_conwidth = autocvar_vid_conwidth;
1769         vid_conheight = autocvar_vid_conheight;
1770         vid_pixelheight = autocvar_vid_pixelheight;
1771
1772         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1773         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1774         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1775
1776         // Camera for demo playback
1777         if(camera_active)
1778         {
1779                 if(autocvar_camera_enable)
1780                         CSQC_Demo_Camera();
1781                 else
1782                 {
1783                         cvar_set("chase_active", ftos(chase_active_backup));
1784                         cvar_set("cl_demo_mousegrab", "0");
1785                         camera_active = false;
1786                 }
1787         }
1788         else
1789         {
1790 #ifdef CAMERATEST
1791                 if(autocvar_camera_enable)
1792 #else
1793                 if(autocvar_camera_enable && isdemo())
1794 #endif
1795                 {
1796                         // Enable required Darkplaces cvars
1797                         chase_active_backup = autocvar_chase_active;
1798                         cvar_set("chase_active", "2");
1799                         cvar_set("cl_demo_mousegrab", "1");
1800                         camera_active = true;
1801                         camera_mode = false;
1802                 }
1803         }
1804
1805         // Draw the Crosshair
1806         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1807
1808         // Draw the Engine Status Bar (the default Quake HUD)
1809         setproperty(VF_DRAWENGINESBAR, 0);
1810
1811         // Update the mouse position
1812         /*
1813            mousepos_x = vid_conwidth;
1814            mousepos_y = vid_conheight;
1815            mousepos = mousepos*0.5 + getmousepos();
1816          */
1817
1818         FOREACH_ENTITY(it.draw, it.draw(it));
1819
1820         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1821         renderscene();
1822
1823         // now switch to 2D drawing mode by calling a 2D drawing function
1824         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1825         // next R_RenderScene call
1826         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1827
1828         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1829         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1830         {
1831                 // apply night vision effect
1832                 vector tc_00, tc_01, tc_10, tc_11;
1833                 vector rgb = '0 0 0';
1834
1835                 if(!nightvision_noise)
1836                 {
1837                         nightvision_noise = new(nightvision_noise);
1838                 }
1839                 if(!nightvision_noise2)
1840                 {
1841                         nightvision_noise2 = new(nightvision_noise2);
1842                 }
1843
1844                 // color tint in yellow
1845                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1846
1847                 // draw BG
1848                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1849                 rgb = '1 1 1';
1850                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1851                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1852                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1853                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1854                 tc_11 = tc_01 + tc_10 - tc_00;
1855                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1856                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1857                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1858                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1859                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1860                 R_EndPolygon();
1861
1862                 // draw FG
1863                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1864                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1865                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1866                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1867                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1868                 tc_11 = tc_01 + tc_10 - tc_00;
1869                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1870                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1871                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1872                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1873                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1874                 R_EndPolygon();
1875         }
1876
1877         if(autocvar_cl_reticle)
1878         {
1879                 Weapon wep = activeweapon;
1880                 // Draw the aiming reticle for weapons that use it
1881                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1882                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1883                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1884                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1885                 {
1886                         // no zoom reticle while dead
1887                         reticle_type = 0;
1888                 }
1889                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1890                 {
1891                         if(reticle_image != "") { reticle_type = 2; }
1892                         else { reticle_type = 0; }
1893                 }
1894                 else if(button_zoom || zoomscript_caught)
1895                 {
1896                         // normal zoom
1897                         reticle_type = 1;
1898                 }
1899
1900                 if(reticle_type)
1901                 {
1902                         if(autocvar_cl_reticle_stretch)
1903                         {
1904                                 reticle_size.x = vid_conwidth;
1905                                 reticle_size.y = vid_conheight;
1906                                 reticle_pos.x = 0;
1907                                 reticle_pos.y = 0;
1908                         }
1909                         else
1910                         {
1911                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1912                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1913                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1914                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1915                         }
1916
1917                         if(zoomscript_caught)
1918                                 f = 1;
1919                         else
1920                                 f = current_zoomfraction;
1921
1922                         if(f)
1923                         {
1924                                 switch(reticle_type)
1925                                 {
1926                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1927                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1928                                 }
1929                         }
1930                 }
1931         }
1932         else
1933         {
1934                 if(reticle_type != 0) { reticle_type = 0; }
1935         }
1936
1937
1938         // improved polyblend
1939         if(autocvar_hud_contents)
1940         {
1941                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1942                 vector liquidcolor;
1943
1944                 switch(pointcontents(view_origin))
1945                 {
1946                         case CONTENT_WATER:
1947                                 liquidalpha = autocvar_hud_contents_water_alpha;
1948                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1949                                 incontent = 1;
1950                                 break;
1951
1952                         case CONTENT_LAVA:
1953                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1954                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1955                                 incontent = 1;
1956                                 break;
1957
1958                         case CONTENT_SLIME:
1959                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1960                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1961                                 incontent = 1;
1962                                 break;
1963
1964                         default:
1965                                 liquidalpha = 0;
1966                                 liquidcolor = '0 0 0';
1967                                 incontent = 0;
1968                                 break;
1969                 }
1970
1971                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1972                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1973                         contentfadetime = autocvar_hud_contents_fadeintime;
1974                         liquidalpha_prev = liquidalpha;
1975                         liquidcolor_prev = liquidcolor;
1976                 }
1977                 else
1978                         contentfadetime = autocvar_hud_contents_fadeouttime;
1979
1980                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1981                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1982
1983                 if(contentavgalpha)
1984                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1985
1986                 if(autocvar_hud_postprocessing)
1987                 {
1988                         if(autocvar_hud_contents_blur && contentavgalpha)
1989                         {
1990                                 content_blurpostprocess.x = 1;
1991                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1992                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1993                         }
1994                         else
1995                         {
1996                                 content_blurpostprocess.x = 0;
1997                                 content_blurpostprocess.y = 0;
1998                                 content_blurpostprocess.z = 0;
1999                         }
2000                 }
2001         }
2002
2003         if(autocvar_hud_damage && !STAT(FROZEN))
2004         {
2005                 splash_size.x = max(vid_conwidth, vid_conheight);
2006                 splash_size.y = max(vid_conwidth, vid_conheight);
2007                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2008                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2009
2010                 float myhealth_flash_temp;
2011                 myhealth = STAT(HEALTH);
2012
2013                 // fade out
2014                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2015                 // add new damage
2016                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2017
2018                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2019                 pain_threshold = autocvar_hud_damage_pain_threshold;
2020                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2021                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2022
2023                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2024                 {
2025                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2026                 }
2027
2028                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2029
2030                 if(myhealth_prev < 1)
2031                 {
2032                         if(myhealth >= 1)
2033                         {
2034                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2035                                 myhealth_flash_temp = 0;
2036                         }
2037                         else
2038                         {
2039                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2040                         }
2041                 }
2042
2043                 if(spectatee_status == -1 || intermission)
2044                 {
2045                         myhealth_flash = 0; // observing, or match ended
2046                         myhealth_flash_temp = 0;
2047                 }
2048
2049                 myhealth_prev = myhealth;
2050
2051                 // IDEA: change damage color/picture based on player model for robot/alien species?
2052                 // pro: matches model better
2053                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2054                 // maybe different reddish pics?
2055                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2056                 {
2057                         if(autocvar_cl_gentle_damage == 2)
2058                         {
2059                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2060                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2061                         }
2062                         else
2063                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2064
2065                         if(myhealth_flash_temp > 0)
2066                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2067                 }
2068                 else if(myhealth_flash_temp > 0)
2069                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2070
2071                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2072                 {
2073                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2074                         {
2075                                 damage_blurpostprocess.x = 1;
2076                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2077                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2078                         }
2079                         else
2080                         {
2081                                 damage_blurpostprocess.x = 0;
2082                                 damage_blurpostprocess.y = 0;
2083                                 damage_blurpostprocess.z = 0;
2084                         }
2085                 }
2086         }
2087
2088         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2089         float e2 = (autocvar_hud_powerup != 0);
2090         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2091         {
2092                 // enable or disable rendering types if they are used or not
2093                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2094                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2095
2096                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2097                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2098                 {
2099                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2100                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2101                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2102                         {
2103                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2104                                 old_blurradius = blurradius;
2105                                 old_bluralpha = bluralpha;
2106                         }
2107                 }
2108                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2109                 {
2110                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2111                         old_blurradius = 0;
2112                         old_bluralpha = 0;
2113                 }
2114
2115                 // edge detection postprocess handling done second (used by hud_powerup)
2116                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2117                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2118                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2119
2120                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2121
2122                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2123                 {
2124                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2125                         {
2126                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2127                                 old_sharpen_intensity = sharpen_intensity;
2128                         }
2129                 }
2130                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2131                 {
2132                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2133                         old_sharpen_intensity = 0;
2134                 }
2135
2136                 if(cvar("r_glsl_postprocess") == 0)
2137                         cvar_set("r_glsl_postprocess", "2");
2138         }
2139         else if(cvar("r_glsl_postprocess") == 2)
2140                 cvar_set("r_glsl_postprocess", "0");
2141
2142         /*if(gametype == MAPINFO_TYPE_CTF)
2143           {
2144           ctf_view();
2145           } else */
2146
2147         // draw 2D entities
2148         FOREACH_ENTITY(it.draw2d, it.draw2d(it));
2149         Draw_ShowNames_All();
2150         Debug_Draw();
2151
2152         scoreboard_active = HUD_WouldDrawScoreboard();
2153
2154         HUD_Draw();
2155
2156         if(NextFrameCommand)
2157         {
2158                 localcmd("\n", NextFrameCommand, "\n");
2159                 NextFrameCommand = string_null;
2160         }
2161
2162         // we must do this check AFTER a frame was rendered, or it won't work
2163         if(cs_project_is_b0rked == 0)
2164         {
2165                 string w0, h0;
2166                 w0 = ftos(autocvar_vid_conwidth);
2167                 h0 = ftos(autocvar_vid_conheight);
2168                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2169                 //setproperty(VF_FOV, '90 90 0');
2170                 setproperty(VF_ORIGIN, '0 0 0');
2171                 setproperty(VF_ANGLES, '0 0 0');
2172                 setproperty(VF_PERSPECTIVE, 1);
2173                 makevectors('0 0 0');
2174                 vector v1, v2;
2175                 cvar_set("vid_conwidth", "800");
2176                 cvar_set("vid_conheight", "600");
2177                 v1 = cs_project(v_forward);
2178                 cvar_set("vid_conwidth", "640");
2179                 cvar_set("vid_conheight", "480");
2180                 v2 = cs_project(v_forward);
2181                 if(v1 == v2)
2182                         cs_project_is_b0rked = 1;
2183                 else
2184                         cs_project_is_b0rked = -1;
2185                 cvar_set("vid_conwidth", w0);
2186                 cvar_set("vid_conheight", h0);
2187         }
2188
2189         if(autocvar__hud_configure)
2190                 HUD_Panel_Mouse();
2191         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2192                 HUD_Minigame_Mouse();
2193         else if(QuickMenu_IsOpened())
2194                 QuickMenu_Mouse();
2195         else
2196                 HUD_Radar_Mouse();
2197
2198         cl_notice_run();
2199         unpause_update();
2200         Net_Flush();
2201
2202         // let's reset the view back to normal for the end
2203         setproperty(VF_MIN, '0 0 0');
2204         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2205 }
2206
2207
2208 // following vectors must be global to allow seamless switching between camera modes
2209 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2210 void CSQC_Demo_Camera()
2211 {
2212         float speed, attenuation, dimensions;
2213         vector tmp, delta;
2214
2215         if( autocvar_camera_reset || !camera_mode )
2216         {
2217                 camera_offset = '0 0 0';
2218                 current_angles = '0 0 0';
2219                 camera_direction = '0 0 0';
2220                 camera_offset.z += 30;
2221                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2222                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2223                 current_origin = view_origin;
2224                 current_camera_offset  = camera_offset;
2225                 cvar_set("camera_reset", "0");
2226                 camera_mode = CAMERA_CHASE;
2227         }
2228
2229         // Camera angles
2230         if( camera_roll )
2231                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2232
2233         if(autocvar_camera_look_player)
2234         {
2235                 vector dir;
2236                 float n;
2237
2238                 dir = normalize(view_origin - current_position);
2239                 n = mouse_angles.z;
2240                 mouse_angles = vectoangles(dir);
2241                 mouse_angles.x = mouse_angles.x * -1;
2242                 mouse_angles.z = n;
2243         }
2244         else
2245         {
2246                 tmp = getmousepos() * 0.1;
2247                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2248                 {
2249                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2250                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2251                 }
2252         }
2253
2254         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2255         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2256         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2257         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2258
2259         // Fix difference when angles don't have the same sign
2260         delta = '0 0 0';
2261         if(mouse_angles.y < -60 && current_angles.y > 60)
2262                 delta = '0 360 0';
2263         if(mouse_angles.y > 60 && current_angles.y < -60)
2264                 delta = '0 -360 0';
2265
2266         if(autocvar_camera_look_player)
2267                 attenuation = autocvar_camera_look_attenuation;
2268         else
2269                 attenuation = autocvar_camera_speed_attenuation;
2270
2271         attenuation = 1 / max(1, attenuation);
2272         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2273
2274         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2275         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2276         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2277         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2278
2279         // Camera position
2280         tmp = '0 0 0';
2281         dimensions = 0;
2282
2283         if( camera_direction.x )
2284         {
2285                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2286                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2287                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2288                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2289                 ++dimensions;
2290         }
2291
2292         if( camera_direction.y )
2293         {
2294                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2295                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2296                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2297                 ++dimensions;
2298         }
2299
2300         if( camera_direction.z )
2301         {
2302                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2303                 ++dimensions;
2304         }
2305
2306         if(autocvar_camera_free)
2307                 speed = autocvar_camera_speed_free;
2308         else
2309                 speed = autocvar_camera_speed_chase;
2310
2311         if(dimensions)
2312         {
2313                 speed = speed * sqrt(1 / dimensions);
2314                 camera_offset += tmp * speed;
2315         }
2316
2317         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2318
2319         // Camera modes
2320         if( autocvar_camera_free )
2321         {
2322                 if ( camera_mode == CAMERA_CHASE )
2323                 {
2324                         current_camera_offset = current_origin + current_camera_offset;
2325                         camera_offset = current_origin + camera_offset;
2326                 }
2327
2328                 camera_mode = CAMERA_FREE;
2329                 current_position = current_camera_offset;
2330         }
2331         else
2332         {
2333                 if ( camera_mode == CAMERA_FREE )
2334                 {
2335                         current_origin = view_origin;
2336                         camera_offset = camera_offset - current_origin;
2337                         current_camera_offset = current_camera_offset - current_origin;
2338                 }
2339
2340                 camera_mode = CAMERA_CHASE;
2341
2342                 if(autocvar_camera_chase_smoothly)
2343                         current_origin += (view_origin - current_origin) * attenuation;
2344                 else
2345                         current_origin = view_origin;
2346
2347                 current_position = current_origin + current_camera_offset;
2348         }
2349
2350         setproperty(VF_ANGLES, current_angles);
2351         setproperty(VF_ORIGIN, current_position);
2352 }