qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hook.qh"
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "scoreboard.qh"
   7 #include "shownames.qh"
   8 #include "quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include "../common/anim.qh"
  13 #include "../common/constants.qh"
  14 #include "../common/debug.qh"
  15 #include "../common/mapinfo.qh"
  16 #include "../common/gamemodes/all.qh"
  17 #include "../common/nades/all.qh"
  18 #include "../common/stats.qh"
  19 #include "../common/triggers/target/music.qh"
  20 #include "../common/teams.qh"
  21
  22 #include "../common/vehicles/all.qh"
  23 #include "../common/weapons/all.qh"
  24 #include "../common/viewloc.qh"
  25 #include "../common/minigames/cl_minigames.qh"
  26 #include "../common/minigames/cl_minigames_hud.qh"
  27
  28 #include "../lib/csqcmodel/cl_player.qh"
  29
  30 #include "../lib/warpzone/client.qh"
  31 #include "../lib/warpzone/common.qh"
  32
  33 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  34
  35 float autocvar_cl_viewmodel_scale;
  36
  37 bool autocvar_cl_bobmodel;
  38 float autocvar_cl_bobmodel_speed;
  39 float autocvar_cl_bobmodel_side;
  40 float autocvar_cl_bobmodel_up;
  41
  42 float autocvar_cl_followmodel;
  43 float autocvar_cl_followmodel_side_speed;
  44 float autocvar_cl_followmodel_side_highpass;
  45 float autocvar_cl_followmodel_side_highpass1;
  46 float autocvar_cl_followmodel_side_limit;
  47 float autocvar_cl_followmodel_side_lowpass;
  48 float autocvar_cl_followmodel_up_speed;
  49 float autocvar_cl_followmodel_up_highpass;
  50 float autocvar_cl_followmodel_up_highpass1;
  51 float autocvar_cl_followmodel_up_limit;
  52 float autocvar_cl_followmodel_up_lowpass;
  53
  54 float autocvar_cl_leanmodel;
  55 float autocvar_cl_leanmodel_side_speed;
  56 float autocvar_cl_leanmodel_side_highpass;
  57 float autocvar_cl_leanmodel_side_highpass1;
  58 float autocvar_cl_leanmodel_side_lowpass;
  59 float autocvar_cl_leanmodel_side_limit;
  60 float autocvar_cl_leanmodel_up_speed;
  61 float autocvar_cl_leanmodel_up_highpass;
  62 float autocvar_cl_leanmodel_up_highpass1;
  63 float autocvar_cl_leanmodel_up_lowpass;
  64 float autocvar_cl_leanmodel_up_limit;
  65
  66 #define lowpass(value, frac, ref_store, ret) do \
  67 { \
  68         float __frac = bound(0, frac, 1); \
  69         ret = ref_store = ref_store * (1 - __frac) + (value) * __frac; \
  70 } while (0)
  71
  72 #define lowpass_limited(value, frac, limit, ref_store, ret) do \
  73 { \
  74         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  75         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  76 } while (0)
  77
  78 #define highpass(value, frac, ref_store, ret) do \
  79 { \
  80         float __f; lowpass(value, frac, ref_store, __f); \
  81         ret = (value) - __f; \
  82 } while (0)
  83
  84 #define highpass_limited(value, frac, limit, ref_store, ret) do \
  85 { \
  86         float __f; lowpass_limited(value, frac, limit, ref_store, __f); \
  87         ret = (value) - __f; \
  88 } while (0)
  89
  90 #define lowpass3(value, fracx, fracy, fracz, ref_store, ref_out) do \
  91 { \
  92         lowpass(value.x, fracx, ref_store.x, ref_out.x); \
  93         lowpass(value.y, fracy, ref_store.y, ref_out.y); \
  94         lowpass(value.z, fracz, ref_store.z, ref_out.z); \
  95 } while (0)
  96
  97 #define highpass3(value, fracx, fracy, fracz, ref_store, ref_out) do \
  98 { \
  99         highpass(value.x, fracx, ref_store.x, ref_out.x); \
 100         highpass(value.y, fracy, ref_store.y, ref_out.y); \
 101         highpass(value.z, fracz, ref_store.z, ref_out.z); \
 102 } while (0)
 103
 104 #define highpass3_limited(value, fracx, limitx, fracy, limity, fracz, limitz, ref_store, ref_out) do \
 105 { \
 106         highpass_limited(value.x, fracx, limitx, ref_store.x, ref_out.x); \
 107         highpass_limited(value.y, fracy, limity, ref_store.y, ref_out.y); \
 108         highpass_limited(value.z, fracz, limitz, ref_store.z, ref_out.z); \
 109 } while (0)
 110
 111 void viewmodel_animate(entity this)
 112 {
 113         static float prevtime;
 114         float frametime = (time - prevtime) * getstatf(STAT_MOVEVARS_TIMESCALE);
 115         prevtime = time;
 116
 117         if (autocvar_chase_active) return;
 118         if (getstati(STAT_HEALTH) <= 0) return;
 119
 120         vector gunorg = '0 0 0', gunangles = '0 0 0';
 121         static vector gunorg_prev = '0 0 0', gunangles_prev = '0 0 0';
 122
 123         bool teleported = false; // TODO: detect
 124
 125         // 1. if we teleported, clear the frametime... the lowpass will recover the previous value then
 126         if (teleported)
 127         {
 128                 // try to fix the first highpass; result is NOT
 129                 // perfect! TODO find a better fix
 130                 gunangles_prev = view_angles;
 131                 gunorg_prev = view_origin;
 132         }
 133
 134         static vector gunorg_highpass = '0 0 0';
 135
 136         // 2. for the gun origin, only keep the high frequency (non-DC) parts, which is "somewhat like velocity"
 137         gunorg_highpass += gunorg_prev;
 138         highpass3_limited(view_origin,
 139                 frametime * autocvar_cl_followmodel_side_highpass1, autocvar_cl_followmodel_side_limit,
 140                 frametime * autocvar_cl_followmodel_side_highpass1, autocvar_cl_followmodel_side_limit,
 141                 frametime * autocvar_cl_followmodel_up_highpass1, autocvar_cl_followmodel_up_limit,
 142                 gunorg_highpass, gunorg);
 143         gunorg_prev = view_origin;
 144         gunorg_highpass -= gunorg_prev;
 145
 146         static vector gunangles_highpass = '0 0 0';
 147
 148         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 149         gunangles_highpass += gunangles_prev;
 150         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 151         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 152         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 153         highpass3_limited(view_angles,
 154                 frametime * autocvar_cl_leanmodel_up_highpass1, autocvar_cl_leanmodel_up_limit,
 155                 frametime * autocvar_cl_leanmodel_side_highpass1, autocvar_cl_leanmodel_side_limit,
 156                 0, 0,
 157                 gunangles_highpass, gunangles);
 158         gunangles_prev = view_angles;
 159         gunangles_highpass -= gunangles_prev;
 160
 161         // 3. calculate the RAW adjustment vectors
 162         gunorg.x *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_side_speed : 0);
 163         gunorg.y *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_side_speed : 0);
 164         gunorg.z *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_up_speed : 0);
 165
 166         PITCH(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_up_speed : 0);
 167         YAW(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_side_speed : 0);
 168         ROLL(gunangles) = 0;
 169
 170         static vector gunorg_adjustment_highpass;
 171         static vector gunorg_adjustment_lowpass;
 172         static vector gunangles_adjustment_highpass;
 173         static vector gunangles_adjustment_lowpass;
 174
 175         // 4. perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 176         //    trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 177         highpass3(gunorg,
 178                 frametime * autocvar_cl_followmodel_side_highpass,
 179                 frametime * autocvar_cl_followmodel_side_highpass,
 180                 frametime * autocvar_cl_followmodel_up_highpass,
 181                 gunorg_adjustment_highpass, gunorg);
 182         lowpass3(gunorg,
 183                 frametime * autocvar_cl_followmodel_side_lowpass,
 184                 frametime * autocvar_cl_followmodel_side_lowpass,
 185                 frametime * autocvar_cl_followmodel_up_lowpass,
 186                 gunorg_adjustment_lowpass, gunorg);
 187         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 188         highpass3(gunangles,
 189                 frametime * autocvar_cl_leanmodel_up_highpass,
 190                 frametime * autocvar_cl_leanmodel_side_highpass,
 191                 0,
 192                 gunangles_adjustment_highpass, gunangles);
 193         lowpass3(gunangles,
 194                 frametime * autocvar_cl_leanmodel_up_lowpass,
 195                 frametime * autocvar_cl_leanmodel_side_lowpass,
 196                 0,
 197                 gunangles_adjustment_lowpass, gunangles);
 198         float xyspeed = bound(0, vlen(vec2(csqcplayer.velocity)), 400);
 199
 200         // vertical view bobbing code
 201         // TODO: cl_bob
 202
 203         // horizontal view bobbing code
 204         // TODO: cl_bob2
 205
 206         // fall bobbing code
 207         // causes the view to swing down and back up when touching the ground
 208         // TODO: cl_bobfall
 209
 210         // gun model bobbing code
 211         if (autocvar_cl_bobmodel)
 212         {
 213                 // calculate for swinging gun model
 214                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 215                 // Sajt: I tried to smooth out the transitions between bob and no bob, which works
 216                 // for the most part, but for some reason when you go through a message trigger or
 217                 // pick up an item or anything like that it will momentarily jolt the gun.
 218                 vector forward, right, up;
 219                 float bspeed;
 220                 float t = 1;
 221                 float s = time * autocvar_cl_bobmodel_speed;
 222                 // TODO
 223 //              if (clonground)
 224 //              {
 225 //                      if (time - hitgroundtime < 0.2)
 226 //                      {
 227 //                              // just hit the ground, speed the bob back up over the next 0.2 seconds
 228 //                              t = time - hitgroundtime;
 229 //                              t = bound(0, t, 0.2);
 230 //                              t *= 5;
 231 //                      }
 232 //              }
 233 //              else
 234 //              {
 235 //                      // recently left the ground, slow the bob down over the next 0.2 seconds
 236 //                      t = time - lastongroundtime;
 237 //                      t = 0.2 - bound(0, t, 0.2);
 238 //                      t *= 5;
 239 //              }
 240                 bspeed = xyspeed * 0.01;
 241                 MAKEVECTORS(makevectors, gunangles, forward, right, up);
 242                 float bobr = bspeed * autocvar_cl_bobmodel_side * autocvar_cl_viewmodel_scale * sin(s) * t;
 243                 gunorg += bobr * right;
 244                 float bobu = bspeed * autocvar_cl_bobmodel_up * autocvar_cl_viewmodel_scale * cos(s * 2) * t;
 245                 gunorg += bobu * up;
 246         }
 247         this.origin += view_forward * gunorg.x + view_right * gunorg.y + view_up * gunorg.z;
 248         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 249         this.angles += gunangles;
 250 }
 251
 252 .vector viewmodel_origin, viewmodel_angles;
 253
 254 void viewmodel_draw(entity this)
 255 {
 256         int mask = (intermission || (getstati(STAT_HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 257         float a = this.alpha;
 258         int c = stof(getplayerkeyvalue(current_player, "colors"));
 259         vector g = this.glowmod; // TODO: completely clientside: colormapPaletteColor(c & 0x0F, true) * 2;
 260         entity me = CSQCModel_server2csqc(player_localentnum);
 261         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 262                 | EF_NODEPTHTEST)
 263                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 264         for (entity e = this; e; e = e.weaponchild)
 265         {
 266                 e.drawmask = mask;
 267                 e.alpha = a;
 268                 e.colormap = c;
 269                 e.glowmod = g;
 270                 e.csqcmodel_effects = fx;
 271                 WITH(entity, self, e, CSQCModel_Effects_Apply());
 272         }
 273         {
 274                 static string name_last;
 275                 string name = Weapons_from(activeweapon).mdl;
 276                 if (name != name_last)
 277                 {
 278                         name_last = name;
 279                         CL_WeaponEntity_SetModel(this, name);
 280                         this.viewmodel_origin = this.origin;
 281                         this.viewmodel_angles = this.angles;
 282                 }
 283                 anim_update(this);
 284                 if (!this.animstate_override)
 285                         anim_set(this, this.anim_idle, true, false, false);
 286         }
 287         float eta = (getstatf(STAT_WEAPON_NEXTTHINK) - time); // TODO: / W_WeaponRateFactor();
 288         float f = 0; // 0..1; 0: fully active
 289         switch (this.state)
 290         {
 291                 case WS_RAISE:
 292                 {
 293                         // entity newwep = Weapons_from(activeweapon);
 294                         float delay = 0.2; // TODO: newwep.switchdelay_raise;
 295                         f = eta / max(eta, delay);
 296                         break;
 297                 }
 298                 case WS_DROP:
 299                 {
 300                         // entity oldwep = Weapons_from(activeweapon);
 301                         float delay = 0.2; // TODO: newwep.switchdelay_drop;
 302                         f = 1 - eta / max(eta, delay);
 303                         break;
 304                 }
 305                 case WS_CLEAR:
 306                 {
 307                         f = 1;
 308                         break;
 309                 }
 310         }
 311         this.origin = this.viewmodel_origin;
 312         this.angles = this.viewmodel_angles;
 313         this.angles_x = (-90 * f * f);
 314         viewmodel_animate(this);
 315         setorigin(this, this.origin);
 316 }
 317
 318 entity viewmodel;
 319 STATIC_INIT(viewmodel) {
 320     viewmodel = new(viewmodel);
 321         viewmodel.draw = viewmodel_draw;
 322 }
 323
 324 entity porto;
 325 vector polyline[16];
 326 void Porto_Draw(entity this)
 327 {
 328         vector p, dir, ang, q, nextdir;
 329         float portal_number, portal1_idx;
 330
 331         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
 332                 return;
 333         if(g_balance_porto_secondary)
 334                 return;
 335         if(intermission == 1)
 336                 return;
 337         if(intermission == 2)
 338                 return;
 339         if (getstati(STAT_HEALTH) <= 0)
 340                 return;
 341
 342         dir = view_forward;
 343
 344         if(angles_held_status)
 345         {
 346                 makevectors(angles_held);
 347                 dir = v_forward;
 348         }
 349
 350         p = view_origin;
 351
 352         polyline[0] = p;
 353         int idx = 1;
 354         portal_number = 0;
 355         nextdir = dir;
 356
 357         for (;;)
 358         {
 359                 dir = nextdir;
 360                 traceline(p, p + 65536 * dir, true, porto);
 361                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 362                         return;
 363                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
 364                 p = trace_endpos;
 365                 polyline[idx] = p;
 366                 ++idx;
 367                 if(idx >= 16)
 368                         return;
 369                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 370                         continue;
 371                 ++portal_number;
 372                 ang = vectoangles2(trace_plane_normal, dir);
 373                 ang.x = -ang.x;
 374                 makevectors(ang);
 375                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 376                         return;
 377                 if(portal_number == 1)
 378                 {
 379                         portal1_idx = idx;
 380                         if(portal_number >= 2)
 381                                 break;
 382                 }
 383         }
 384
 385         while(idx >= 2)
 386         {
 387                 p = polyline[idx-2];
 388                 q = polyline[idx-1];
 389                 if(idx == 2)
 390                         p = p - view_up * 16;
 391                 if(idx-1 >= portal1_idx)
 392                 {
 393                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 394                 }
 395                 else
 396                 {
 397                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 398                 }
 399                 --idx;
 400         }
 401 }
 402
 403 void Porto_Init()
 404 {
 405         porto = new(porto);
 406         make_pure(porto);
 407         porto.draw = Porto_Draw;
 408         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 409 }
 410
 411 float drawtime;
 412 float avgspeed;
 413 vector GetCurrentFov(float fov)
 414 {
 415         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 416         float velocityzoom, curspeed;
 417         vector v;
 418
 419         zoomsensitivity = autocvar_cl_zoomsensitivity;
 420         zoomfactor = autocvar_cl_zoomfactor;
 421         if(zoomfactor < 1 || zoomfactor > 30)
 422                 zoomfactor = 2.5;
 423         zoomspeed = autocvar_cl_zoomspeed;
 424         if(zoomspeed >= 0)
 425         if(zoomspeed < 0.5 || zoomspeed > 16)
 426                         zoomspeed = 3.5;
 427
 428         zoomdir = button_zoom;
 429         if(hud == HUD_NORMAL)
 430         if(switchweapon == activeweapon)
 431         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
 432                 zoomdir += button_attack2;
 433         if(spectatee_status > 0 || isdemo())
 434         {
 435                 if(spectatorbutton_zoom)
 436                 {
 437                         if(zoomdir)
 438                                 zoomdir = 0;
 439                         else
 440                                 zoomdir = 1;
 441                 }
 442                 // fteqcc failed twice here already, don't optimize this
 443         }
 444
 445         if(zoomdir) { zoomin_effect = 0; }
 446
 447         if(camera_active)
 448         {
 449                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 450         }
 451         else if(autocvar_cl_spawnzoom && zoomin_effect)
 452         {
 453                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 454
 455                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 456                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 457                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 458         }
 459         else
 460         {
 461                 if(zoomspeed < 0) // instant zoom
 462                 {
 463                         if(zoomdir)
 464                                 current_viewzoom = 1 / zoomfactor;
 465                         else
 466                                 current_viewzoom = 1;
 467                 }
 468                 else
 469                 {
 470                         if(zoomdir)
 471                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 472                         else
 473                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 474                 }
 475         }
 476
 477         if(almost_equals(current_viewzoom, 1))
 478                 current_zoomfraction = 0;
 479         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 480                 current_zoomfraction = 1;
 481         else
 482                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 483
 484         if(zoomsensitivity < 1)
 485                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 486         else
 487                 setsensitivityscale(1);
 488
 489         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 490         {
 491                 if(intermission) { curspeed = 0; }
 492                 else
 493                 {
 494
 495                         makevectors(view_angles);
 496                         v = pmove_vel;
 497                         if(csqcplayer)
 498                                 v = csqcplayer.velocity;
 499
 500                         switch(autocvar_cl_velocityzoom_type)
 501                         {
 502                                 case 3: curspeed = max(0, v_forward * v); break;
 503                                 case 2: curspeed = (v_forward * v); break;
 504                                 case 1: default: curspeed = vlen(v); break;
 505                         }
 506                 }
 507
 508                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 509                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 510                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 511
 512                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 513         }
 514         else
 515                 velocityzoom = 1;
 516
 517         float frustumx, frustumy, fovx, fovy;
 518         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 519         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 520         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 521         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 522
 523         return '1 0 0' * fovx + '0 1 0' * fovy;
 524 }
 525
 526 vector GetViewLocationFOV(float fov)
 527 {
 528         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 529         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 530         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 531         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 532         return '1 0 0' * fovx + '0 1 0' * fovy;
 533 }
 534
 535 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 536 {
 537         float fovx, fovy;
 538         float width = (ov_worldmax.x - ov_worldmin.x);
 539         float height = (ov_worldmax.y - ov_worldmin.y);
 540         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 541         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 542         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 543         return '1 0 0' * fovx + '0 1 0' * fovy;
 544 }
 545
 546 // this function must match W_SetupShot!
 547 float zoomscript_caught;
 548
 549 vector wcross_origin;
 550 float wcross_scale_prev, wcross_alpha_prev;
 551 vector wcross_color_prev;
 552 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 553 vector wcross_color_goal_prev;
 554 float wcross_changedonetime;
 555
 556 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 557 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 558 float wcross_name_changestarttime, wcross_name_changedonetime;
 559 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 560
 561 float wcross_ring_prev;
 562
 563 entity trueaim;
 564 entity trueaim_rifle;
 565
 566 const float SHOTTYPE_HITTEAM = 1;
 567 const float SHOTTYPE_HITOBSTRUCTION = 2;
 568 const float SHOTTYPE_HITWORLD = 3;
 569 const float SHOTTYPE_HITENEMY = 4;
 570
 571 void TrueAim_Init()
 572 {
 573         trueaim = new(trueaim);
 574         make_pure(trueaim);
 575         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 576         trueaim_rifle = new(trueaim_rifle);
 577         make_pure(trueaim_rifle);
 578         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 579 }
 580
 581 float EnemyHitCheck()
 582 {
 583         float t, n;
 584         wcross_origin = project_3d_to_2d(trace_endpos);
 585         wcross_origin.z = 0;
 586         if(trace_ent)
 587                 n = trace_ent.entnum;
 588         else
 589                 n = trace_networkentity;
 590         if(n < 1)
 591                 return SHOTTYPE_HITWORLD;
 592         if(n > maxclients)
 593                 return SHOTTYPE_HITWORLD;
 594         t = GetPlayerColor(n - 1);
 595         if(teamplay)
 596                 if(t == myteam)
 597                         return SHOTTYPE_HITTEAM;
 598         if(t == NUM_SPECTATOR)
 599                 return SHOTTYPE_HITWORLD;
 600         return SHOTTYPE_HITENEMY;
 601 }
 602
 603 float TrueAimCheck()
 604 {
 605         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 606         vector vecs, trueaimpoint, w_shotorg;
 607         vector mi, ma, dv;
 608         float shottype;
 609         entity ta;
 610         float mv;
 611
 612         mi = ma = '0 0 0';
 613         ta = trueaim;
 614         mv = MOVE_NOMONSTERS;
 615
 616         switch(activeweapon) // WEAPONTODO
 617         {
 618                 case WEP_TUBA.m_id: // no aim
 619                 case WEP_PORTO.m_id: // shoots from eye
 620                 case WEP_NEXBALL.m_id: // shoots from eye
 621                 case WEP_HOOK.m_id: // no trueaim
 622                 case WEP_MORTAR.m_id: // toss curve
 623                         return SHOTTYPE_HITWORLD;
 624                 case WEP_VORTEX.m_id:
 625                 case WEP_VAPORIZER.m_id:
 626                         mv = MOVE_NORMAL;
 627                         break;
 628                 case WEP_RIFLE.m_id:
 629                         ta = trueaim_rifle;
 630                         mv = MOVE_NORMAL;
 631                         if(zoomscript_caught)
 632                         {
 633                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 634                                 return EnemyHitCheck();
 635                         }
 636                         break;
 637                 case WEP_DEVASTATOR.m_id: // projectile has a size!
 638                         mi = '-3 -3 -3';
 639                         ma = '3 3 3';
 640                         break;
 641                 case WEP_FIREBALL.m_id: // projectile has a size!
 642                         mi = '-16 -16 -16';
 643                         ma = '16 16 16';
 644                         break;
 645                 case WEP_SEEKER.m_id: // projectile has a size!
 646                         mi = '-2 -2 -2';
 647                         ma = '2 2 2';
 648                         break;
 649                 case WEP_ELECTRO.m_id: // projectile has a size!
 650                         mi = '0 0 -3';
 651                         ma = '0 0 -3';
 652                         break;
 653         }
 654
 655         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 656
 657         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 658
 659         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 660         trueaimpoint = trace_endpos;
 661
 662         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 663                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 664
 665         if(vecs.x > 0)
 666                 vecs.y = -vecs.y;
 667         else
 668                 vecs = '0 0 0';
 669
 670         dv = view_right * vecs.y + view_up * vecs.z;
 671         w_shotorg = traceorigin + dv;
 672
 673         // now move the vecs forward as much as requested if possible
 674         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 675         w_shotorg = trace_endpos - view_forward * nudge;
 676
 677         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 678         shottype = EnemyHitCheck();
 679         if(shottype != SHOTTYPE_HITWORLD)
 680                 return shottype;
 681
 682 #if 0
 683         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 684         // or rather, I know why, but see no fix
 685         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 686                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 687                 return SHOTTYPE_HITOBSTRUCTION;
 688 #endif
 689
 690         return SHOTTYPE_HITWORLD;
 691 }
 692
 693 void PostInit();
 694 void CSQC_Demo_Camera();
 695 float HUD_WouldDrawScoreboard();
 696 float camera_mode;
 697 const float CAMERA_FREE = 1;
 698 const float CAMERA_CHASE = 2;
 699 float reticle_type;
 700 string reticle_image;
 701 string NextFrameCommand;
 702
 703 vector freeze_org, freeze_ang;
 704 entity nightvision_noise, nightvision_noise2;
 705
 706 const float MAX_TIME_DIFF = 5;
 707 float pickup_crosshair_time, pickup_crosshair_size;
 708 float hitindication_crosshair_size;
 709 float use_vortex_chargepool;
 710
 711 float myhealth, myhealth_prev;
 712 float myhealth_flash;
 713
 714 float old_blurradius, old_bluralpha;
 715 float old_sharpen_intensity;
 716
 717 vector myhealth_gentlergb;
 718
 719 float contentavgalpha, liquidalpha_prev;
 720 vector liquidcolor_prev;
 721
 722 float eventchase_current_distance;
 723 float eventchase_running;
 724 bool WantEventchase()
 725 {SELFPARAM();
 726         if(autocvar_cl_orthoview)
 727                 return false;
 728         if(intermission)
 729                 return true;
 730         if(self.viewloc)
 731                 return true;
 732         if(spectatee_status >= 0)
 733         {
 734                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 735                         return true;
 736                 if(MUTATOR_CALLHOOK(WantEventchase, self))
 737                         return true;
 738                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_NEXBALL.m_id)))
 739                         return true;
 740                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 741                 {
 742                         if(autocvar_cl_eventchase_death == 2)
 743                         {
 744                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 745                                 if(self.velocity == '0 0 0' || eventchase_running)
 746                                         return true;
 747                         }
 748                         else return true;
 749                 }
 750         }
 751         return false;
 752 }
 753
 754 void HUD_Crosshair_Vehicle()
 755 {
 756         if(hud != HUD_BUMBLEBEE_GUN)
 757         {
 758                 Vehicle info = get_vehicleinfo(hud);
 759                 info.vr_crosshair(info);
 760         }
 761 }
 762
 763 vector damage_blurpostprocess, content_blurpostprocess;
 764
 765 float unaccounted_damage = 0;
 766 void UpdateDamage()
 767 {
 768         // accumulate damage with each stat update
 769         static float damage_total_prev = 0;
 770         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 771         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 772         damage_total_prev = damage_total;
 773
 774         static float damage_dealt_time_prev = 0;
 775         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 776         if (damage_dealt_time != damage_dealt_time_prev)
 777         {
 778                 unaccounted_damage += unaccounted_damage_new;
 779                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 780         }
 781         damage_dealt_time_prev = damage_dealt_time;
 782
 783         // prevent hitsound when switching spectatee
 784         static float spectatee_status_prev = 0;
 785         if (spectatee_status != spectatee_status_prev)
 786                 unaccounted_damage = 0;
 787         spectatee_status_prev = spectatee_status;
 788 }
 789
 790 void HitSound()
 791 {
 792         // varying sound pitch
 793
 794         static float hitsound_time_prev = 0;
 795         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 796         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
 797         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 798         {
 799                 if (autocvar_cl_hitsound && unaccounted_damage)
 800                 {
 801                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 802                         float a = autocvar_cl_hitsound_max_pitch;
 803                         float b = autocvar_cl_hitsound_min_pitch;
 804                         float c = autocvar_cl_hitsound_nom_damage;
 805                         float x = unaccounted_damage;
 806                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 807
 808                         // if sound variation is disabled, set pitch_shift to 1
 809                         if (autocvar_cl_hitsound == 1)
 810                                 pitch_shift = 1;
 811
 812                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 813                         if (autocvar_cl_hitsound == 3)
 814                         {
 815                                 float mirror_value = (a-b)/2 + b;
 816                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 817                         }
 818
 819                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 820
 821                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 822                         // todo: normalize sound pressure levels? seems unnecessary
 823
 824                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 825                 }
 826                 unaccounted_damage = 0;
 827                 hitsound_time_prev = time;
 828         }
 829
 830         static float typehit_time_prev = 0;
 831         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 832         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 833         {
 834                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 835                 typehit_time_prev = typehit_time;
 836         }
 837 }
 838
 839 void HUD_Crosshair()
 840 {SELFPARAM();
 841         static float rainbow_last_flicker;
 842         static vector rainbow_prev_color;
 843         entity e = self;
 844         float f, i, j;
 845         vector v;
 846         if(!scoreboard_active && !camera_active && intermission != 2 &&
 847                 spectatee_status != -1 && !csqcplayer.viewloc &&
 848                 !HUD_MinigameMenu_IsOpened() )
 849         {
 850                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 851                         return;
 852
 853                 if (hud != HUD_NORMAL)
 854                 {
 855                         HUD_Crosshair_Vehicle();
 856                         return;
 857                 }
 858
 859                 string wcross_style;
 860                 float wcross_alpha, wcross_resolution;
 861                 wcross_style = autocvar_crosshair;
 862                 if (wcross_style == "0")
 863                         return;
 864                 wcross_resolution = autocvar_crosshair_size;
 865                 if (wcross_resolution == 0)
 866                         return;
 867                 wcross_alpha = autocvar_crosshair_alpha;
 868                 if (wcross_alpha == 0)
 869                         return;
 870
 871                 // TrueAim check
 872                 float shottype;
 873
 874                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 875                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 876                 wcross_origin.z = 0;
 877                 if(autocvar_crosshair_hittest)
 878                 {
 879                         vector wcross_oldorigin;
 880                         wcross_oldorigin = wcross_origin;
 881                         shottype = TrueAimCheck();
 882                         if(shottype == SHOTTYPE_HITWORLD)
 883                         {
 884                                 v = wcross_origin - wcross_oldorigin;
 885                                 v.x /= vid_conwidth;
 886                                 v.y /= vid_conheight;
 887                                 if(vlen(v) > 0.01)
 888                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 889                         }
 890                         if(!autocvar_crosshair_hittest_showimpact)
 891                                 wcross_origin = wcross_oldorigin;
 892                 }
 893                 else
 894                         shottype = SHOTTYPE_HITWORLD;
 895
 896                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 897                 string wcross_name = "";
 898                 float wcross_scale, wcross_blur;
 899
 900                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 901                 {
 902                         e = get_weaponinfo(switchingweapon);
 903                         if(e)
 904                         {
 905                                 if(autocvar_crosshair_per_weapon)
 906                                 {
 907                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 908                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 909                                         //if (wcross_resolution == 0)
 910                                                 //return;
 911
 912                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 913                                         wcross_resolution *= e.w_crosshair_size;
 914                                         wcross_name = e.w_crosshair;
 915                                 }
 916                         }
 917                 }
 918
 919                 if(wcross_name == "")
 920                         wcross_name = strcat("gfx/crosshair", wcross_style);
 921
 922                 // MAIN CROSSHAIR COLOR DECISION
 923                 switch(autocvar_crosshair_color_special)
 924                 {
 925                         case 1: // crosshair_color_per_weapon
 926                         {
 927                                 if(e)
 928                                 {
 929                                         wcross_color = e.wpcolor;
 930                                         break;
 931                                 }
 932                                 else { goto normalcolor; }
 933                         }
 934
 935                         case 2: // crosshair_color_by_health
 936                         {
 937                                 float x = getstati(STAT_HEALTH);
 938
 939                                 //x = red
 940                                 //y = green
 941                                 //z = blue
 942
 943                                 wcross_color.z = 0;
 944
 945                                 if(x > 200)
 946                                 {
 947                                         wcross_color.x = 0;
 948                                         wcross_color.y = 1;
 949                                 }
 950                                 else if(x > 150)
 951                                 {
 952                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 953                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 954                                 }
 955                                 else if(x > 100)
 956                                 {
 957                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 958                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 959                                         wcross_color.z = 1 - (x-100)*0.02;
 960                                 }
 961                                 else if(x > 50)
 962                                 {
 963                                         wcross_color.x = 1;
 964                                         wcross_color.y = 1;
 965                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 966                                 }
 967                                 else if(x > 20)
 968                                 {
 969                                         wcross_color.x = 1;
 970                                         wcross_color.y = (x-20)*90/27/100;
 971                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 972                                 }
 973                                 else
 974                                 {
 975                                         wcross_color.x = 1;
 976                                         wcross_color.y = 0;
 977                                 }
 978                                 break;
 979                         }
 980
 981                         case 3: // crosshair_color_rainbow
 982                         {
 983                                 if(time >= rainbow_last_flicker)
 984                                 {
 985                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 986                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 987                                 }
 988                                 wcross_color = rainbow_prev_color;
 989                                 break;
 990                         }
 991                         :normalcolor
 992                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 993                 }
 994
 995                 if(autocvar_crosshair_effect_scalefade)
 996                 {
 997                         wcross_scale = wcross_resolution;
 998                         wcross_resolution = 1;
 999                 }
1000                 else
1001                 {
1002                         wcross_scale = 1;
1003                 }
1004
1005                 if(autocvar_crosshair_pickup)
1006                 {
1007                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
1008
1009                         if(pickup_crosshair_time < stat_pickup_time)
1010                         {
1011                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1012                                         pickup_crosshair_size = 1;
1013
1014                                 pickup_crosshair_time = stat_pickup_time;
1015                         }
1016
1017                         if(pickup_crosshair_size > 0)
1018                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1019                         else
1020                                 pickup_crosshair_size = 0;
1021
1022                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1023                 }
1024
1025                 // todo: make crosshair hit indication dependent on damage dealt
1026                 if(autocvar_crosshair_hitindication)
1027                 {
1028                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1029
1030                         if(unaccounted_damage)
1031                         {
1032                                 hitindication_crosshair_size = 1;
1033                         }
1034
1035                         if(hitindication_crosshair_size > 0)
1036                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1037                         else
1038                                 hitindication_crosshair_size = 0;
1039
1040                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1041                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1042                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1043                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1044                 }
1045
1046                 if(shottype == SHOTTYPE_HITENEMY)
1047                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1048                 if(shottype == SHOTTYPE_HITTEAM)
1049                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1050
1051                 f = fabs(autocvar_crosshair_effect_time);
1052                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1053                 {
1054                         wcross_changedonetime = time + f;
1055                 }
1056                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1057                 {
1058                         wcross_name_changestarttime = time;
1059                         wcross_name_changedonetime = time + f;
1060                         if(wcross_name_goal_prev_prev)
1061                                 strunzone(wcross_name_goal_prev_prev);
1062                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1063                         wcross_name_goal_prev = strzone(wcross_name);
1064                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1065                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1066                         wcross_resolution_goal_prev = wcross_resolution;
1067                 }
1068
1069                 wcross_scale_goal_prev = wcross_scale;
1070                 wcross_alpha_goal_prev = wcross_alpha;
1071                 wcross_color_goal_prev = wcross_color;
1072
1073                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1074                 {
1075                         wcross_blur = 1;
1076                         wcross_alpha *= 0.75;
1077                 }
1078                 else
1079                         wcross_blur = 0;
1080                 // *_prev is at time-frametime
1081                 // * is at wcross_changedonetime+f
1082                 // what do we have at time?
1083                 if(time < wcross_changedonetime)
1084                 {
1085                         f = frametime / (wcross_changedonetime - time + frametime);
1086                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1087                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1088                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1089                 }
1090
1091                 wcross_scale_prev = wcross_scale;
1092                 wcross_alpha_prev = wcross_alpha;
1093                 wcross_color_prev = wcross_color;
1094
1095                 MUTATOR_CALLHOOK(UpdateCrosshair);
1096
1097                 wcross_scale *= 1 - autocvar__menu_alpha;
1098                 wcross_alpha *= 1 - autocvar__menu_alpha;
1099                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1100
1101                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1102                 {
1103                         // crosshair rings for weapon stats
1104                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1105                         {
1106                                 // declarations and stats
1107                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1108                                 string ring_image = string_null, ring_inner_image = string_null;
1109                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1110
1111                                 ring_scale = autocvar_crosshair_ring_size;
1112
1113                                 float weapon_clipload, weapon_clipsize;
1114                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
1115                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
1116
1117                                 float ok_ammo_charge, ok_ammo_chargepool;
1118                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
1119                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
1120
1121                                 float vortex_charge, vortex_chargepool;
1122                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
1123                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
1124
1125                                 float arc_heat = getstatf(STAT_ARC_HEAT);
1126
1127                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1128                                         vortex_charge_movingavg = vortex_charge;
1129
1130
1131                                 // handle the values
1132                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1133                                 {
1134                                         if (vortex_chargepool || use_vortex_chargepool) {
1135                                                 use_vortex_chargepool = 1;
1136                                                 ring_inner_value = vortex_chargepool;
1137                                         } else {
1138                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1139                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1140                                         }
1141
1142                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1143                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1144                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1145
1146                                         // draw the outer ring to show the current charge of the weapon
1147                                         ring_value = vortex_charge;
1148                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1149                                         ring_rgb = wcross_color;
1150                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1151                                 }
1152                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1153                                 {
1154                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1155                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1156                                         ring_rgb = wcross_color;
1157                                         ring_image = "gfx/crosshair_ring.tga";
1158                                 }
1159                                 else if (activeweapon == WEP_HAGAR.m_id && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1160                                 {
1161                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
1162                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1163                                         ring_rgb = wcross_color;
1164                                         ring_image = "gfx/crosshair_ring.tga";
1165                                 }
1166                                 else if (ok_ammo_charge)
1167                                 {
1168                                         ring_value = ok_ammo_chargepool;
1169                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1170                                         ring_rgb = wcross_color;
1171                                         ring_image = "gfx/crosshair_ring.tga";
1172                                 }
1173                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1174                                 {
1175                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1176                                         ring_scale = autocvar_crosshair_ring_reload_size;
1177                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1178                                         ring_rgb = wcross_color;
1179
1180                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1181                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1182                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
1183                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1184                                         else
1185                                                 ring_image = "gfx/crosshair_ring.tga";
1186                                 }
1187                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
1188                                 {
1189                                         ring_value = arc_heat;
1190                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1191                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1192                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1193                                         ring_image = "gfx/crosshair_ring.tga";
1194                                 }
1195
1196                                 // if in weapon switch animation, fade ring out/in
1197                                 if(autocvar_crosshair_effect_time > 0)
1198                                 {
1199                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1200                                         if (f >= 1)
1201                                         {
1202                                                 wcross_ring_prev = ((ring_image) ? true : false);
1203                                         }
1204
1205                                         if(wcross_ring_prev)
1206                                         {
1207                                                 if(f < 1)
1208                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1209                                         }
1210                                         else
1211                                         {
1212                                                 if(f < 1)
1213                                                         ring_alpha *= bound(0, f, 1);
1214                                         }
1215                                 }
1216
1217                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1218                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1219
1220                                 if (ring_value)
1221                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1222                         }
1223
1224 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1225                         do \
1226                         { \
1227                                 if(wcross_blur > 0) \
1228                                 { \
1229                                         for(i = -2; i <= 2; ++i) \
1230                                         for(j = -2; j <= 2; ++j) \
1231                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1232                                 } \
1233                                 else \
1234                                 { \
1235                                         M(0,0,sz,wcross_name,wcross_alpha); \
1236                                 } \
1237                         } \
1238                         while(0)
1239
1240 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1241                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1242
1243 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1244                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1245
1246                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1247                         {
1248                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1249                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1250                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1251                                 f = 1 - f;
1252                         }
1253                         else
1254                         {
1255                                 f = 1;
1256                         }
1257                         wcross_name_alpha_goal_prev = f;
1258
1259                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1260                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1261
1262                         if(autocvar_crosshair_dot)
1263                         {
1264                                 vector wcross_color_old;
1265                                 wcross_color_old = wcross_color;
1266
1267                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1268                                         wcross_color = stov(autocvar_crosshair_dot_color);
1269
1270                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1271                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
1272                                 wcross_color = wcross_color_old;
1273                         }
1274                 }
1275         }
1276         else
1277         {
1278                 wcross_scale_prev = 0;
1279                 wcross_alpha_prev = 0;
1280                 wcross_scale_goal_prev = 0;
1281                 wcross_alpha_goal_prev = 0;
1282                 wcross_changedonetime = 0;
1283                 if(wcross_name_goal_prev)
1284                         strunzone(wcross_name_goal_prev);
1285                 wcross_name_goal_prev = string_null;
1286                 if(wcross_name_goal_prev_prev)
1287                         strunzone(wcross_name_goal_prev_prev);
1288                 wcross_name_goal_prev_prev = string_null;
1289                 wcross_name_changestarttime = 0;
1290                 wcross_name_changedonetime = 0;
1291                 wcross_name_alpha_goal_prev = 0;
1292                 wcross_name_alpha_goal_prev_prev = 0;
1293                 wcross_resolution_goal_prev = 0;
1294                 wcross_resolution_goal_prev_prev = 0;
1295         }
1296 }
1297
1298 void HUD_Draw()
1299 {
1300         if(getstati(STAT_FROZEN))
1301                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1302         else if (getstatf(STAT_HEALING_ORB)>time)
1303                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, NADE_TYPE_HEAL.m_color, autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
1304         if(!intermission)
1305         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1306         {
1307                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1308                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1309         }
1310         else if(getstatf(STAT_REVIVE_PROGRESS))
1311         {
1312                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1313                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1314         }
1315
1316         if(autocvar_r_letterbox == 0)
1317                 if(autocvar_viewsize < 120)
1318                 {
1319                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1320                                 Accuracy_LoadLevels();
1321
1322                         HUD_Main();
1323                         HUD_DrawScoreboard();
1324                 }
1325
1326         // crosshair goes VERY LAST
1327         UpdateDamage();
1328         HUD_Crosshair();
1329         HitSound();
1330 }
1331
1332 bool ov_enabled;
1333 float oldr_nearclip;
1334 float oldr_farclip_base;
1335 float oldr_farclip_world;
1336 float oldr_novis;
1337 float oldr_useportalculling;
1338 float oldr_useinfinitefarclip;
1339
1340 const int BUTTON_3 = 4;
1341 const int BUTTON_4 = 8;
1342 float cl_notice_run();
1343 float prev_myteam;
1344 int lasthud;
1345 float vh_notice_time;
1346 void WaypointSprite_Load();
1347 void CSQC_UpdateView(float w, float h)
1348 {SELFPARAM();
1349         entity e;
1350         float fov;
1351         float f;
1352         vector vf_size, vf_min;
1353         float a;
1354
1355         execute_next_frame();
1356
1357         ++framecount;
1358
1359         hud = getstati(STAT_HUD);
1360
1361         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1362                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1363
1364         lasthud = hud;
1365
1366         if(autocvar__hud_showbinds_reload) // menu can set this one
1367         {
1368                 db_close(binddb);
1369                 binddb = db_create();
1370                 cvar_set("_hud_showbinds_reload", "0");
1371         }
1372
1373         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1374                 view_quality = getproperty(VF_MINFPS_QUALITY);
1375         else
1376                 view_quality = 1;
1377
1378         button_attack2 = (input_buttons & BUTTON_3);
1379         button_zoom = (input_buttons & BUTTON_4);
1380
1381         vf_size = getpropertyvec(VF_SIZE);
1382         vf_min = getpropertyvec(VF_MIN);
1383         vid_width = vf_size.x;
1384         vid_height = vf_size.y;
1385
1386         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1387         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1388
1389         WaypointSprite_Load();
1390
1391         CSQCPlayer_SetCamera();
1392
1393         if(player_localentnum <= maxclients) // is it a client?
1394                 current_player = player_localentnum - 1;
1395         else // then player_localentnum is the vehicle I'm driving
1396                 current_player = player_localnum;
1397         myteam = GetPlayerColor(current_player);
1398
1399         if(myteam != prev_myteam)
1400         {
1401                 myteamcolors = colormapPaletteColor(myteam, 1);
1402                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1403                 prev_myteam = myteam;
1404         }
1405
1406         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1407
1408         float is_dead = (getstati(STAT_HEALTH) <= 0);
1409
1410         // FIXME do we need this hack?
1411         if(isdemo())
1412         {
1413                 // in demos, input_buttons do not work
1414                 button_zoom = (autocvar__togglezoom == "-");
1415         }
1416         else if(button_zoom
1417                 && autocvar_cl_unpress_zoom_on_death
1418                 && (spectatee_status >= 0)
1419                 && (is_dead || intermission))
1420         {
1421                 // no zoom while dead or in intermission please
1422                 localcmd("-zoom\n");
1423                 button_zoom = false;
1424         }
1425
1426         // event chase camera
1427         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1428         {
1429                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1430                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && getstati(STAT_ROUNDLOST));
1431                 entity gen = world;
1432
1433                 if(ons_roundlost)
1434                 {
1435                         entity e;
1436                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1437                         {
1438                                 if(e.health <= 0)
1439                                 {
1440                                         gen = e;
1441                                         break;
1442                                 }
1443                         }
1444                         if(!gen)
1445                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1446                 }
1447                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1448                 {
1449                         eventchase_running = true;
1450
1451                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1452                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1453                         if(ons_roundlost) { current_view_origin = gen.origin; }
1454
1455                         // detect maximum viewoffset and use it
1456                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1457                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1458                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1459
1460                         if(view_offset)
1461                         {
1462                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1463                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1464                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1465                         }
1466
1467                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1468                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1469                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1470                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1471
1472                         // make the camera smooth back
1473                         float chase_distance = autocvar_cl_eventchase_distance;
1474                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1475                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1476
1477                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1478                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1479                         else if(eventchase_current_distance != chase_distance)
1480                                 eventchase_current_distance = chase_distance;
1481
1482                         makevectors(view_angles);
1483
1484                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1485                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1486
1487                         // If the boxtrace fails, revert back to line tracing.
1488                         if(!self.viewloc)
1489                         if(trace_startsolid)
1490                         {
1491                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1492                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1493                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1494                         }
1495                         else { setproperty(VF_ORIGIN, trace_endpos); }
1496
1497                         if(!self.viewloc)
1498                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1499                 }
1500                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1501                 {
1502                         eventchase_running = false;
1503                         cvar_set("chase_active", "0");
1504                         eventchase_current_distance = 0; // start from 0 next time
1505                 }
1506         }
1507         // workaround for camera stuck between player's legs when using chase_active 1
1508         // because the engine stops updating the chase_active camera when the game ends
1509         else if(intermission)
1510         {
1511                 cvar_settemp("chase_active", "-1");
1512                 eventchase_current_distance = 0;
1513         }
1514
1515         // do lockview after event chase camera so that it still applies whenever necessary.
1516         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1517         {
1518                 setproperty(VF_ORIGIN, freeze_org);
1519                 setproperty(VF_ANGLES, freeze_ang);
1520         }
1521         else
1522         {
1523                 freeze_org = getpropertyvec(VF_ORIGIN);
1524                 freeze_ang = getpropertyvec(VF_ANGLES);
1525         }
1526
1527         WarpZone_FixView();
1528         //WarpZone_FixPMove();
1529
1530         vector ov_org = '0 0 0';
1531         vector ov_mid = '0 0 0';
1532         vector ov_worldmin = '0 0 0';
1533         vector ov_worldmax = '0 0 0';
1534         if(autocvar_cl_orthoview)
1535         {
1536                 ov_worldmin = mi_picmin;
1537                 ov_worldmax = mi_picmax;
1538
1539                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1540                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1541                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1542
1543                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1544                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1545
1546                 float ov_nearest = vlen(ov_org - vec3(
1547                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1548                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1549                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1550                 ));
1551
1552                 float ov_furthest = 0;
1553                 float dist = 0;
1554
1555                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1556                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1557                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1558                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1559                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1560                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1561                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1562                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1563
1564                 if(!ov_enabled)
1565                 {
1566                         oldr_nearclip = cvar("r_nearclip");
1567                         oldr_farclip_base = cvar("r_farclip_base");
1568                         oldr_farclip_world = cvar("r_farclip_world");
1569                         oldr_novis = cvar("r_novis");
1570                         oldr_useportalculling = cvar("r_useportalculling");
1571                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1572                 }
1573
1574                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1575                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1576                 cvar_settemp("r_farclip_world", "0");
1577                 cvar_settemp("r_novis", "1");
1578                 cvar_settemp("r_useportalculling", "0");
1579                 cvar_settemp("r_useinfinitefarclip", "0");
1580
1581                 setproperty(VF_ORIGIN, ov_org);
1582                 setproperty(VF_ANGLES, '90 0 0');
1583
1584                 ov_enabled = true;
1585
1586                 #if 0
1587                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1588                         vtos(ov_org),
1589                         vtos(getpropertyvec(VF_ANGLES)),
1590                         ov_distance,
1591                         ov_nearest,
1592                         ov_furthest);
1593                 #endif
1594         }
1595         else
1596         {
1597                 if(ov_enabled)
1598                 {
1599                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1600                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1601                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1602                         cvar_set("r_novis", ftos(oldr_novis));
1603                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1604                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1605                 }
1606                 ov_enabled = false;
1607         }
1608
1609         // Render the Scene
1610         view_origin = getpropertyvec(VF_ORIGIN);
1611         view_angles = getpropertyvec(VF_ANGLES);
1612         makevectors(view_angles);
1613         view_forward = v_forward;
1614         view_right = v_right;
1615         view_up = v_up;
1616
1617 #ifdef BLURTEST
1618         if(time > blurtest_time0 && time < blurtest_time1)
1619         {
1620                 float r, t;
1621
1622                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1623                 r = t * blurtest_radius;
1624                 f = 1 / pow(t, blurtest_power) - 1;
1625
1626                 cvar_set("r_glsl_postprocess", "1");
1627                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1628         }
1629         else
1630         {
1631                 cvar_set("r_glsl_postprocess", "0");
1632                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1633         }
1634 #endif
1635
1636         TargetMusic_Advance();
1637         Fog_Force();
1638
1639         if(drawtime == 0)
1640                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1641         else
1642                 drawframetime = bound(0.000001, time - drawtime, 1);
1643         drawtime = time;
1644
1645         // watch for gametype changes here...
1646         // in ParseStuffCMD the cmd isn't executed yet :/
1647         // might even be better to add the gametype to TE_CSQC_INIT...?
1648         if(!postinit)
1649                 PostInit();
1650
1651         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1652         {
1653                 if(calledhooks & HOOK_START)
1654                 {
1655                         localcmd("\ncl_hook_gameend\n");
1656                         calledhooks |= HOOK_END;
1657                 }
1658         }
1659
1660         Announcer();
1661
1662         fov = autocvar_fov;
1663         if(fov <= 59.5)
1664         {
1665                 if(!zoomscript_caught)
1666                 {
1667                         localcmd("+button9\n");
1668                         zoomscript_caught = 1;
1669                 }
1670         }
1671         else
1672         {
1673                 if(zoomscript_caught)
1674                 {
1675                         localcmd("-button9\n");
1676                         zoomscript_caught = 0;
1677                 }
1678         }
1679
1680         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1681
1682         // next WANTED weapon (for HUD)
1683         switchweapon = getstati(STAT_SWITCHWEAPON);
1684
1685         // currently switching-to weapon (for crosshair)
1686         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1687
1688         // actually active weapon (for zoom)
1689         activeweapon = getstati(STAT_ACTIVEWEAPON);
1690
1691         f = (serverflags & SERVERFLAG_TEAMPLAY);
1692         if(f != teamplay)
1693         {
1694                 teamplay = f;
1695                 HUD_InitScores();
1696         }
1697
1698         if(last_switchweapon != switchweapon)
1699         {
1700                 weapontime = time;
1701                 last_switchweapon = switchweapon;
1702                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1703                 {
1704                         localcmd("-zoom\n");
1705                         button_zoom = false;
1706                 }
1707                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1708                 {
1709                         localcmd("-fire\n");
1710                         localcmd("-fire2\n");
1711                         button_attack2 = false;
1712                 }
1713         }
1714         if(last_activeweapon != activeweapon)
1715         {
1716                 last_activeweapon = activeweapon;
1717
1718                 e = get_weaponinfo(activeweapon);
1719                 if(e.netname != "")
1720                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1721                 else
1722                         localcmd("\ncl_hook_activeweapon none\n");
1723         }
1724
1725         // ALWAYS Clear Current Scene First
1726         clearscene();
1727
1728         setproperty(VF_ORIGIN, view_origin);
1729         setproperty(VF_ANGLES, view_angles);
1730
1731         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1732         setproperty(VF_SIZE, vf_size);
1733         setproperty(VF_MIN, vf_min);
1734
1735         // Assign Standard Viewflags
1736         // Draw the World (and sky)
1737         setproperty(VF_DRAWWORLD, 1);
1738
1739         // Set the console size vars
1740         vid_conwidth = autocvar_vid_conwidth;
1741         vid_conheight = autocvar_vid_conheight;
1742         vid_pixelheight = autocvar_vid_pixelheight;
1743
1744         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1745         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1746         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1747
1748         // Camera for demo playback
1749         if(camera_active)
1750         {
1751                 if(autocvar_camera_enable)
1752                         CSQC_Demo_Camera();
1753                 else
1754                 {
1755                         cvar_set("chase_active", ftos(chase_active_backup));
1756                         cvar_set("cl_demo_mousegrab", "0");
1757                         camera_active = false;
1758                 }
1759         }
1760         else
1761         {
1762 #ifdef CAMERATEST
1763                 if(autocvar_camera_enable)
1764 #else
1765                 if(autocvar_camera_enable && isdemo())
1766 #endif
1767                 {
1768                         // Enable required Darkplaces cvars
1769                         chase_active_backup = autocvar_chase_active;
1770                         cvar_set("chase_active", "2");
1771                         cvar_set("cl_demo_mousegrab", "1");
1772                         camera_active = true;
1773                         camera_mode = false;
1774                 }
1775         }
1776
1777         // Draw the Crosshair
1778         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1779
1780         // Draw the Engine Status Bar (the default Quake HUD)
1781         setproperty(VF_DRAWENGINESBAR, 0);
1782
1783         // Update the mouse position
1784         /*
1785            mousepos_x = vid_conwidth;
1786            mousepos_y = vid_conheight;
1787            mousepos = mousepos*0.5 + getmousepos();
1788          */
1789
1790         for(entity e = NULL; (e = nextent(e)); ) if (e.draw) {
1791                 WITH(entity, self, e, e.draw(e));
1792         }
1793
1794         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1795         renderscene();
1796
1797         // now switch to 2D drawing mode by calling a 2D drawing function
1798         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1799         // next R_RenderScene call
1800         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1801
1802         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1803         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1804         {
1805                 // apply night vision effect
1806                 vector tc_00, tc_01, tc_10, tc_11;
1807                 vector rgb = '0 0 0';
1808
1809                 if(!nightvision_noise)
1810                 {
1811                         nightvision_noise = new(nightvision_noise);
1812                 }
1813                 if(!nightvision_noise2)
1814                 {
1815                         nightvision_noise2 = new(nightvision_noise2);
1816                 }
1817
1818                 // color tint in yellow
1819                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1820
1821                 // draw BG
1822                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1823                 rgb = '1 1 1';
1824                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1825                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1826                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1827                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1828                 tc_11 = tc_01 + tc_10 - tc_00;
1829                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1830                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1831                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1832                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1833                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1834                 R_EndPolygon();
1835
1836                 // draw FG
1837                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1838                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1839                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1840                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1841                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1842                 tc_11 = tc_01 + tc_10 - tc_00;
1843                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1844                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1845                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1846                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1847                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1848                 R_EndPolygon();
1849         }
1850
1851         if(autocvar_cl_reticle)
1852         {
1853                 Weapon wep = get_weaponinfo(activeweapon);
1854                 // Draw the aiming reticle for weapons that use it
1855                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1856                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1857                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1858                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1859                 {
1860                         // no zoom reticle while dead
1861                         reticle_type = 0;
1862                 }
1863                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1864                 {
1865                         if(reticle_image != "") { reticle_type = 2; }
1866                         else { reticle_type = 0; }
1867                 }
1868                 else if(button_zoom || zoomscript_caught)
1869                 {
1870                         // normal zoom
1871                         reticle_type = 1;
1872                 }
1873
1874                 if(reticle_type)
1875                 {
1876                         if(autocvar_cl_reticle_stretch)
1877                         {
1878                                 reticle_size.x = vid_conwidth;
1879                                 reticle_size.y = vid_conheight;
1880                                 reticle_pos.x = 0;
1881                                 reticle_pos.y = 0;
1882                         }
1883                         else
1884                         {
1885                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1886                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1887                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1888                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1889                         }
1890
1891                         if(zoomscript_caught)
1892                                 f = 1;
1893                         else
1894                                 f = current_zoomfraction;
1895
1896                         if(f)
1897                         {
1898                                 switch(reticle_type)
1899                                 {
1900                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1901                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1902                                 }
1903                         }
1904                 }
1905         }
1906         else
1907         {
1908                 if(reticle_type != 0) { reticle_type = 0; }
1909         }
1910
1911
1912         // improved polyblend
1913         if(autocvar_hud_contents)
1914         {
1915                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1916                 vector liquidcolor;
1917
1918                 switch(pointcontents(view_origin))
1919                 {
1920                         case CONTENT_WATER:
1921                                 liquidalpha = autocvar_hud_contents_water_alpha;
1922                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1923                                 incontent = 1;
1924                                 break;
1925
1926                         case CONTENT_LAVA:
1927                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1928                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1929                                 incontent = 1;
1930                                 break;
1931
1932                         case CONTENT_SLIME:
1933                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1934                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1935                                 incontent = 1;
1936                                 break;
1937
1938                         default:
1939                                 liquidalpha = 0;
1940                                 liquidcolor = '0 0 0';
1941                                 incontent = 0;
1942                                 break;
1943                 }
1944
1945                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1946                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1947                         contentfadetime = autocvar_hud_contents_fadeintime;
1948                         liquidalpha_prev = liquidalpha;
1949                         liquidcolor_prev = liquidcolor;
1950                 }
1951                 else
1952                         contentfadetime = autocvar_hud_contents_fadeouttime;
1953
1954                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1955                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1956
1957                 if(contentavgalpha)
1958                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1959
1960                 if(autocvar_hud_postprocessing)
1961                 {
1962                         if(autocvar_hud_contents_blur && contentavgalpha)
1963                         {
1964                                 content_blurpostprocess.x = 1;
1965                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1966                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1967                         }
1968                         else
1969                         {
1970                                 content_blurpostprocess.x = 0;
1971                                 content_blurpostprocess.y = 0;
1972                                 content_blurpostprocess.z = 0;
1973                         }
1974                 }
1975         }
1976
1977         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1978         {
1979                 splash_size.x = max(vid_conwidth, vid_conheight);
1980                 splash_size.y = max(vid_conwidth, vid_conheight);
1981                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1982                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1983
1984                 float myhealth_flash_temp;
1985                 myhealth = getstati(STAT_HEALTH);
1986
1987                 // fade out
1988                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1989                 // add new damage
1990                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1991
1992                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1993                 pain_threshold = autocvar_hud_damage_pain_threshold;
1994                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1995                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1996
1997                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1998                 {
1999                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2000                 }
2001
2002                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2003
2004                 if(myhealth_prev < 1)
2005                 {
2006                         if(myhealth >= 1)
2007                         {
2008                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2009                                 myhealth_flash_temp = 0;
2010                         }
2011                         else
2012                         {
2013                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2014                         }
2015                 }
2016
2017                 if(spectatee_status == -1 || intermission)
2018                 {
2019                         myhealth_flash = 0; // observing, or match ended
2020                         myhealth_flash_temp = 0;
2021                 }
2022
2023                 myhealth_prev = myhealth;
2024
2025                 // IDEA: change damage color/picture based on player model for robot/alien species?
2026                 // pro: matches model better
2027                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2028                 // maybe different reddish pics?
2029                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2030                 {
2031                         if(autocvar_cl_gentle_damage == 2)
2032                         {
2033                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2034                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2035                         }
2036                         else
2037                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2038
2039                         if(myhealth_flash_temp > 0)
2040                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2041                 }
2042                 else if(myhealth_flash_temp > 0)
2043                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2044
2045                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2046                 {
2047                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2048                         {
2049                                 damage_blurpostprocess.x = 1;
2050                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2051                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2052                         }
2053                         else
2054                         {
2055                                 damage_blurpostprocess.x = 0;
2056                                 damage_blurpostprocess.y = 0;
2057                                 damage_blurpostprocess.z = 0;
2058                         }
2059                 }
2060         }
2061
2062         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2063         float e2 = (autocvar_hud_powerup != 0);
2064         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2065         {
2066                 // enable or disable rendering types if they are used or not
2067                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2068                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2069
2070                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2071                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2072                 {
2073                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2074                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2075                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2076                         {
2077                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2078                                 old_blurradius = blurradius;
2079                                 old_bluralpha = bluralpha;
2080                         }
2081                 }
2082                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2083                 {
2084                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2085                         old_blurradius = 0;
2086                         old_bluralpha = 0;
2087                 }
2088
2089                 // edge detection postprocess handling done second (used by hud_powerup)
2090                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
2091                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2092                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2093
2094                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2095
2096                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2097                 {
2098                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2099                         {
2100                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2101                                 old_sharpen_intensity = sharpen_intensity;
2102                         }
2103                 }
2104                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2105                 {
2106                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2107                         old_sharpen_intensity = 0;
2108                 }
2109
2110                 if(cvar("r_glsl_postprocess") == 0)
2111                         cvar_set("r_glsl_postprocess", "2");
2112         }
2113         else if(cvar("r_glsl_postprocess") == 2)
2114                 cvar_set("r_glsl_postprocess", "0");
2115
2116         /*if(gametype == MAPINFO_TYPE_CTF)
2117           {
2118           ctf_view();
2119           } else */
2120
2121         // draw 2D entities
2122         for (entity e = NULL; (e = nextent(e)); ) if (e.draw2d) {
2123                 WITH(entity, self, e, e.draw2d(e));
2124         }
2125         Draw_ShowNames_All();
2126         Debug_Draw();
2127
2128         scoreboard_active = HUD_WouldDrawScoreboard();
2129
2130         HUD_Draw();
2131
2132         if(NextFrameCommand)
2133         {
2134                 localcmd("\n", NextFrameCommand, "\n");
2135                 NextFrameCommand = string_null;
2136         }
2137
2138         // we must do this check AFTER a frame was rendered, or it won't work
2139         if(cs_project_is_b0rked == 0)
2140         {
2141                 string w0, h0;
2142                 w0 = ftos(autocvar_vid_conwidth);
2143                 h0 = ftos(autocvar_vid_conheight);
2144                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2145                 //setproperty(VF_FOV, '90 90 0');
2146                 setproperty(VF_ORIGIN, '0 0 0');
2147                 setproperty(VF_ANGLES, '0 0 0');
2148                 setproperty(VF_PERSPECTIVE, 1);
2149                 makevectors('0 0 0');
2150                 vector v1, v2;
2151                 cvar_set("vid_conwidth", "800");
2152                 cvar_set("vid_conheight", "600");
2153                 v1 = cs_project(v_forward);
2154                 cvar_set("vid_conwidth", "640");
2155                 cvar_set("vid_conheight", "480");
2156                 v2 = cs_project(v_forward);
2157                 if(v1 == v2)
2158                         cs_project_is_b0rked = 1;
2159                 else
2160                         cs_project_is_b0rked = -1;
2161                 cvar_set("vid_conwidth", w0);
2162                 cvar_set("vid_conheight", h0);
2163         }
2164
2165         if(autocvar__hud_configure)
2166                 HUD_Panel_Mouse();
2167         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2168                 HUD_Minigame_Mouse();
2169         else if(QuickMenu_IsOpened())
2170                 QuickMenu_Mouse();
2171         else
2172                 HUD_Radar_Mouse();
2173
2174         cl_notice_run();
2175
2176         // let's reset the view back to normal for the end
2177         setproperty(VF_MIN, '0 0 0');
2178         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2179 }
2180
2181
2182 // following vectors must be global to allow seamless switching between camera modes
2183 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2184 void CSQC_Demo_Camera()
2185 {
2186         float speed, attenuation, dimensions;
2187         vector tmp, delta;
2188
2189         if( autocvar_camera_reset || !camera_mode )
2190         {
2191                 camera_offset = '0 0 0';
2192                 current_angles = '0 0 0';
2193                 camera_direction = '0 0 0';
2194                 camera_offset.z += 30;
2195                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2196                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2197                 current_origin = view_origin;
2198                 current_camera_offset  = camera_offset;
2199                 cvar_set("camera_reset", "0");
2200                 camera_mode = CAMERA_CHASE;
2201         }
2202
2203         // Camera angles
2204         if( camera_roll )
2205                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2206
2207         if(autocvar_camera_look_player)
2208         {
2209                 vector dir;
2210                 float n;
2211
2212                 dir = normalize(view_origin - current_position);
2213                 n = mouse_angles.z;
2214                 mouse_angles = vectoangles(dir);
2215                 mouse_angles.x = mouse_angles.x * -1;
2216                 mouse_angles.z = n;
2217         }
2218         else
2219         {
2220                 tmp = getmousepos() * 0.1;
2221                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
2222                 {
2223                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2224                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2225                 }
2226         }
2227
2228         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2229         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2230         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2231         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2232
2233         // Fix difference when angles don't have the same sign
2234         delta = '0 0 0';
2235         if(mouse_angles.y < -60 && current_angles.y > 60)
2236                 delta = '0 360 0';
2237         if(mouse_angles.y > 60 && current_angles.y < -60)
2238                 delta = '0 -360 0';
2239
2240         if(autocvar_camera_look_player)
2241                 attenuation = autocvar_camera_look_attenuation;
2242         else
2243                 attenuation = autocvar_camera_speed_attenuation;
2244
2245         attenuation = 1 / max(1, attenuation);
2246         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2247
2248         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2249         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2250         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2251         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2252
2253         // Camera position
2254         tmp = '0 0 0';
2255         dimensions = 0;
2256
2257         if( camera_direction.x )
2258         {
2259                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2260                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2261                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2262                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2263                 ++dimensions;
2264         }
2265
2266         if( camera_direction.y )
2267         {
2268                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2269                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2270                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2271                 ++dimensions;
2272         }
2273
2274         if( camera_direction.z )
2275         {
2276                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2277                 ++dimensions;
2278         }
2279
2280         if(autocvar_camera_free)
2281                 speed = autocvar_camera_speed_free;
2282         else
2283                 speed = autocvar_camera_speed_chase;
2284
2285         if(dimensions)
2286         {
2287                 speed = speed * sqrt(1 / dimensions);
2288                 camera_offset += tmp * speed;
2289         }
2290
2291         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2292
2293         // Camera modes
2294         if( autocvar_camera_free )
2295         {
2296                 if ( camera_mode == CAMERA_CHASE )
2297                 {
2298                         current_camera_offset = current_origin + current_camera_offset;
2299                         camera_offset = current_origin + camera_offset;
2300                 }
2301
2302                 camera_mode = CAMERA_FREE;
2303                 current_position = current_camera_offset;
2304         }
2305         else
2306         {
2307                 if ( camera_mode == CAMERA_FREE )
2308                 {
2309                         current_origin = view_origin;
2310                         camera_offset = camera_offset - current_origin;
2311                         current_camera_offset = current_camera_offset - current_origin;
2312                 }
2313
2314                 camera_mode = CAMERA_CHASE;
2315
2316                 if(autocvar_camera_chase_smoothly)
2317                         current_origin += (view_origin - current_origin) * attenuation;
2318                 else
2319                         current_origin = view_origin;
2320
2321                 current_position = current_origin + current_camera_offset;
2322         }
2323
2324         setproperty(VF_ANGLES, current_angles);
2325         setproperty(VF_ORIGIN, current_position);
2326 }