qcsrc/client/view.qc

   1 #include "_all.qh"
   2
   3 #include "announcer.qh"
   4 #include "hook.qh"
   5 #include "hud.qh"
   6 #include "hud_config.qh"
   7 #include "mapvoting.qh"
   8 #include "scoreboard.qh"
   9 #include "shownames.qh"
  10
  11 #include "mutators/events.qh"
  12
  13 #include "../common/constants.qh"
  14 #include "../common/mapinfo.qh"
  15 #include "../common/nades.qh"
  16 #include "../common/stats.qh"
  17 #include "../common/triggers/target/music.qh"
  18 #include "../common/teams.qh"
  19 #include "../common/util.qh"
  20
  21 #include "../common/weapons/all.qh"
  22
  23 #include "../csqcmodellib/cl_player.qh"
  24
  25 #include "../warpzonelib/client.qh"
  26 #include "../warpzonelib/common.qh"
  27
  28 entity porto;
  29 vector polyline[16];
  30 void Porto_Draw()
  31 {
  32         vector p, dir, ang, q, nextdir;
  33         float portal_number, portal1_idx;
  34
  35         if(activeweapon != WEP_PORTO.m_id || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  36                 return;
  37         if(g_balance_porto_secondary)
  38                 return;
  39         if(intermission == 1)
  40                 return;
  41         if(intermission == 2)
  42                 return;
  43         if (getstati(STAT_HEALTH) <= 0)
  44                 return;
  45
  46         dir = view_forward;
  47
  48         if(angles_held_status)
  49         {
  50                 makevectors(angles_held);
  51                 dir = v_forward;
  52         }
  53
  54         p = view_origin;
  55
  56         polyline[0] = p;
  57         int idx = 1;
  58         portal_number = 0;
  59         nextdir = dir;
  60
  61         for (;;)
  62         {
  63                 dir = nextdir;
  64                 traceline(p, p + 65536 * dir, true, porto);
  65                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  66                         return;
  67                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  68                 p = trace_endpos;
  69                 polyline[idx] = p;
  70                 ++idx;
  71                 if(idx >= 16)
  72                         return;
  73                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  74                         continue;
  75                 ++portal_number;
  76                 ang = vectoangles2(trace_plane_normal, dir);
  77                 ang.x = -ang.x;
  78                 makevectors(ang);
  79                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  80                         return;
  81                 if(portal_number == 1)
  82                 {
  83                         portal1_idx = idx;
  84                         if(portal_number >= 2)
  85                                 break;
  86                 }
  87         }
  88
  89         while(idx >= 2)
  90         {
  91                 p = polyline[idx-2];
  92                 q = polyline[idx-1];
  93                 if(idx == 2)
  94                         p = p - view_up * 16;
  95                 if(idx-1 >= portal1_idx)
  96                 {
  97                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
  98                 }
  99                 else
 100                 {
 101                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 102                 }
 103                 --idx;
 104         }
 105 }
 106
 107 void Porto_Init()
 108 {
 109         porto = spawn();
 110         porto.classname = "porto";
 111         porto.draw = Porto_Draw;
 112         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 113 }
 114
 115 float drawtime;
 116 float avgspeed;
 117 vector GetCurrentFov(float fov)
 118 {
 119         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 120         float velocityzoom, curspeed;
 121         vector v;
 122
 123         zoomsensitivity = autocvar_cl_zoomsensitivity;
 124         zoomfactor = autocvar_cl_zoomfactor;
 125         if(zoomfactor < 1 || zoomfactor > 30)
 126                 zoomfactor = 2.5;
 127         zoomspeed = autocvar_cl_zoomspeed;
 128         if(zoomspeed >= 0)
 129         if(zoomspeed < 0.5 || zoomspeed > 16)
 130                         zoomspeed = 3.5;
 131
 132         zoomdir = button_zoom;
 133         if(hud == HUD_NORMAL)
 134         if((activeweapon == WEP_VORTEX.m_id && vortex_scope) || (activeweapon == WEP_RIFLE.m_id && rifle_scope)) // do NOT use switchweapon here
 135                 zoomdir += button_attack2;
 136         if(spectatee_status > 0 || isdemo())
 137         {
 138                 if(spectatorbutton_zoom)
 139                 {
 140                         if(zoomdir)
 141                                 zoomdir = 0;
 142                         else
 143                                 zoomdir = 1;
 144                 }
 145                 // fteqcc failed twice here already, don't optimize this
 146         }
 147
 148         if(zoomdir) { zoomin_effect = 0; }
 149
 150         if(camera_active)
 151         {
 152                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 153         }
 154         else if(autocvar_cl_spawnzoom && zoomin_effect)
 155         {
 156                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 157
 158                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 159                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 160                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 161         }
 162         else
 163         {
 164                 if(zoomspeed < 0) // instant zoom
 165                 {
 166                         if(zoomdir)
 167                                 current_viewzoom = 1 / zoomfactor;
 168                         else
 169                                 current_viewzoom = 1;
 170                 }
 171                 else
 172                 {
 173                         if(zoomdir)
 174                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 175                         else
 176                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 177                 }
 178         }
 179
 180         if(almost_equals(current_viewzoom, 1))
 181                 current_zoomfraction = 0;
 182         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 183                 current_zoomfraction = 1;
 184         else
 185                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 186
 187         if(zoomsensitivity < 1)
 188                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 189         else
 190                 setsensitivityscale(1);
 191
 192         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 193         {
 194                 if(intermission) { curspeed = 0; }
 195                 else
 196                 {
 197
 198                         makevectors(view_angles);
 199                         v = pmove_vel;
 200                         if(csqcplayer)
 201                                 v = csqcplayer.velocity;
 202
 203                         switch(autocvar_cl_velocityzoom_type)
 204                         {
 205                                 case 3: curspeed = max(0, v_forward * v); break;
 206                                 case 2: curspeed = (v_forward * v); break;
 207                                 case 1: default: curspeed = vlen(v); break;
 208                         }
 209                 }
 210
 211                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 212                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 213                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 214
 215                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 216         }
 217         else
 218                 velocityzoom = 1;
 219
 220         float frustumx, frustumy, fovx, fovy;
 221         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 222         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 223         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 224         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 225
 226         return '1 0 0' * fovx + '0 1 0' * fovy;
 227 }
 228
 229 vector GetViewLocationFOV(float fov)
 230 {
 231         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 232         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 233         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 234         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 235         return '1 0 0' * fovx + '0 1 0' * fovy;
 236 }
 237
 238 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 239 {
 240         float fovx, fovy;
 241         float width = (ov_worldmax.x - ov_worldmin.x);
 242         float height = (ov_worldmax.y - ov_worldmin.y);
 243         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 244         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 245         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 246         return '1 0 0' * fovx + '0 1 0' * fovy;
 247 }
 248
 249 // this function must match W_SetupShot!
 250 float zoomscript_caught;
 251
 252 vector wcross_origin;
 253 float wcross_scale_prev, wcross_alpha_prev;
 254 vector wcross_color_prev;
 255 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 256 vector wcross_color_goal_prev;
 257 float wcross_changedonetime;
 258
 259 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 260 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 261 float wcross_name_changestarttime, wcross_name_changedonetime;
 262 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 263
 264 float wcross_ring_prev;
 265
 266 entity trueaim;
 267 entity trueaim_rifle;
 268
 269 const float SHOTTYPE_HITTEAM = 1;
 270 const float SHOTTYPE_HITOBSTRUCTION = 2;
 271 const float SHOTTYPE_HITWORLD = 3;
 272 const float SHOTTYPE_HITENEMY = 4;
 273
 274 void TrueAim_Init()
 275 {
 276         trueaim = spawn();
 277         trueaim.classname = "trueaim";
 278         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 279         trueaim_rifle = spawn();
 280         trueaim_rifle.classname = "trueaim_rifle";
 281         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 282 }
 283
 284 float EnemyHitCheck()
 285 {
 286         float t, n;
 287         wcross_origin = project_3d_to_2d(trace_endpos);
 288         wcross_origin.z = 0;
 289         if(trace_ent)
 290                 n = trace_ent.entnum;
 291         else
 292                 n = trace_networkentity;
 293         if(n < 1)
 294                 return SHOTTYPE_HITWORLD;
 295         if(n > maxclients)
 296                 return SHOTTYPE_HITWORLD;
 297         t = GetPlayerColor(n - 1);
 298         if(teamplay)
 299                 if(t == myteam)
 300                         return SHOTTYPE_HITTEAM;
 301         if(t == NUM_SPECTATOR)
 302                 return SHOTTYPE_HITWORLD;
 303         return SHOTTYPE_HITENEMY;
 304 }
 305
 306 float TrueAimCheck()
 307 {
 308         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 309         vector vecs, trueaimpoint, w_shotorg;
 310         vector mi, ma, dv;
 311         float shottype;
 312         entity ta;
 313         float mv;
 314
 315         mi = ma = '0 0 0';
 316         ta = trueaim;
 317         mv = MOVE_NOMONSTERS;
 318
 319         switch(activeweapon) // WEAPONTODO
 320         {
 321                 case WEP_TUBA.m_id: // no aim
 322                 case WEP_PORTO.m_id: // shoots from eye
 323                 case WEP_HOOK.m_id: // no trueaim
 324                 case WEP_MORTAR.m_id: // toss curve
 325                         return SHOTTYPE_HITWORLD;
 326                 case WEP_VORTEX.m_id:
 327                 case WEP_VAPORIZER.m_id:
 328                         mv = MOVE_NORMAL;
 329                         break;
 330                 case WEP_RIFLE.m_id:
 331                         ta = trueaim_rifle;
 332                         mv = MOVE_NORMAL;
 333                         if(zoomscript_caught)
 334                         {
 335                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 336                                 return EnemyHitCheck();
 337                         }
 338                         break;
 339                 case WEP_DEVASTATOR.m_id: // projectile has a size!
 340                         mi = '-3 -3 -3';
 341                         ma = '3 3 3';
 342                         break;
 343                 case WEP_FIREBALL.m_id: // projectile has a size!
 344                         mi = '-16 -16 -16';
 345                         ma = '16 16 16';
 346                         break;
 347                 case WEP_SEEKER.m_id: // projectile has a size!
 348                         mi = '-2 -2 -2';
 349                         ma = '2 2 2';
 350                         break;
 351                 case WEP_ELECTRO.m_id: // projectile has a size!
 352                         mi = '0 0 -3';
 353                         ma = '0 0 -3';
 354                         break;
 355         }
 356
 357         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 358
 359         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 360
 361         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 362         trueaimpoint = trace_endpos;
 363
 364         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 365                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 366
 367         if(vecs.x > 0)
 368                 vecs.y = -vecs.y;
 369         else
 370                 vecs = '0 0 0';
 371
 372         dv = view_right * vecs.y + view_up * vecs.z;
 373         w_shotorg = traceorigin + dv;
 374
 375         // now move the vecs forward as much as requested if possible
 376         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 377         w_shotorg = trace_endpos - view_forward * nudge;
 378
 379         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 380         shottype = EnemyHitCheck();
 381         if(shottype != SHOTTYPE_HITWORLD)
 382                 return shottype;
 383
 384 #if 0
 385         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 386         // or rather, I know why, but see no fix
 387         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 388                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 389                 return SHOTTYPE_HITOBSTRUCTION;
 390 #endif
 391
 392         return SHOTTYPE_HITWORLD;
 393 }
 394
 395 void CSQC_common_hud(void);
 396
 397 void PostInit(void);
 398 void CSQC_Demo_Camera();
 399 float HUD_WouldDrawScoreboard();
 400 float camera_mode;
 401 const float CAMERA_FREE = 1;
 402 const float CAMERA_CHASE = 2;
 403 float reticle_type;
 404 string reticle_image;
 405 string NextFrameCommand;
 406
 407 vector freeze_org, freeze_ang;
 408 entity nightvision_noise, nightvision_noise2;
 409
 410 const float MAX_TIME_DIFF = 5;
 411 float pickup_crosshair_time, pickup_crosshair_size;
 412 float hitindication_crosshair_size;
 413 float use_vortex_chargepool;
 414
 415 float myhealth, myhealth_prev;
 416 float myhealth_flash;
 417
 418 float old_blurradius, old_bluralpha;
 419 float old_sharpen_intensity;
 420
 421 vector myhealth_gentlergb;
 422
 423 float contentavgalpha, liquidalpha_prev;
 424 vector liquidcolor_prev;
 425
 426 float eventchase_current_distance;
 427 float eventchase_running;
 428 bool WantEventchase()
 429 {
 430         if(autocvar_cl_orthoview)
 431                 return false;
 432         if(intermission)
 433                 return true;
 434         if(self.viewloc)
 435                 return true;
 436         if(spectatee_status >= 0)
 437         {
 438                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 439                         return true;
 440                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO.m_id)))
 441                         return true;
 442                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 443                 {
 444                         if(autocvar_cl_eventchase_death == 2)
 445                         {
 446                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 447                                 if(self.velocity == '0 0 0' || eventchase_running)
 448                                         return true;
 449                         }
 450                         else return true;
 451                 }
 452         }
 453         return false;
 454 }
 455
 456 vector damage_blurpostprocess, content_blurpostprocess;
 457
 458 float checkfail[16];
 459
 460 float unaccounted_damage = 0;
 461 void UpdateDamage()
 462 {
 463         // accumulate damage with each stat update
 464         static float damage_total_prev = 0;
 465         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 466         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 467         damage_total_prev = damage_total;
 468
 469         static float damage_dealt_time_prev = 0;
 470         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 471         if (damage_dealt_time != damage_dealt_time_prev)
 472         {
 473                 unaccounted_damage += unaccounted_damage_new;
 474                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 475         }
 476         damage_dealt_time_prev = damage_dealt_time;
 477
 478         // prevent hitsound when switching spectatee
 479         static float spectatee_status_prev = 0;
 480         if (spectatee_status != spectatee_status_prev)
 481                 unaccounted_damage = 0;
 482         spectatee_status_prev = spectatee_status;
 483 }
 484
 485 void UpdateHitsound()
 486 {
 487         // varying sound pitch
 488
 489         static float hitsound_time_prev = 0;
 490         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 491         float arc_hack = activeweapon == WEP_ARC.m_id && autocvar_cl_hitsound >= 2;
 492         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 493         {
 494                 if (autocvar_cl_hitsound && unaccounted_damage)
 495                 {
 496                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 497                         float a = autocvar_cl_hitsound_max_pitch;
 498                         float b = autocvar_cl_hitsound_min_pitch;
 499                         float c = autocvar_cl_hitsound_nom_damage;
 500                         float x = unaccounted_damage;
 501                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 502
 503                         // if sound variation is disabled, set pitch_shift to 1
 504                         if (autocvar_cl_hitsound == 1)
 505                                 pitch_shift = 1;
 506
 507                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 508                         if (autocvar_cl_hitsound == 3)
 509                         {
 510                                 float mirror_value = (a-b)/2 + b;
 511                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 512                         }
 513
 514                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 515
 516                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 517                         // todo: normalize sound pressure levels? seems unnecessary
 518
 519                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 520                 }
 521                 unaccounted_damage = 0;
 522                 hitsound_time_prev = time;
 523         }
 524
 525         static float typehit_time_prev = 0;
 526         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 527         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 528         {
 529                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 530                 typehit_time_prev = typehit_time;
 531         }
 532 }
 533
 534 void UpdateCrosshair()
 535 {
 536         static float rainbow_last_flicker;
 537     static vector rainbow_prev_color;
 538         entity e = self;
 539         float f, i, j;
 540         vector v;
 541         if(getstati(STAT_FROZEN))
 542                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 543         else if (getstatf(STAT_HEALING_ORB)>time)
 544                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, NADE_TYPE_HEAL.m_color, autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
 545         if(!intermission)
 546         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 547         {
 548                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 549                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 550         }
 551         else if(getstatf(STAT_REVIVE_PROGRESS))
 552         {
 553                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 554                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 555         }
 556
 557         if(autocvar_r_letterbox == 0)
 558                 if(autocvar_viewsize < 120)
 559                         CSQC_common_hud();
 560
 561         // crosshair goes VERY LAST
 562         if(!scoreboard_active && !camera_active && intermission != 2 &&
 563                 spectatee_status != -1 && hud == HUD_NORMAL && !csqcplayer.viewloc &&
 564                 !HUD_MinigameMenu_IsOpened() )
 565         {
 566                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 567                         return;
 568
 569                 string wcross_style;
 570                 float wcross_alpha, wcross_resolution;
 571                 wcross_style = autocvar_crosshair;
 572                 if (wcross_style == "0")
 573                         return;
 574                 wcross_resolution = autocvar_crosshair_size;
 575                 if (wcross_resolution == 0)
 576                         return;
 577                 wcross_alpha = autocvar_crosshair_alpha;
 578                 if (wcross_alpha == 0)
 579                         return;
 580
 581                 // TrueAim check
 582                 float shottype;
 583
 584                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 585                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 586                 wcross_origin.z = 0;
 587                 if(autocvar_crosshair_hittest)
 588                 {
 589                         vector wcross_oldorigin;
 590                         wcross_oldorigin = wcross_origin;
 591                         shottype = TrueAimCheck();
 592                         if(shottype == SHOTTYPE_HITWORLD)
 593                         {
 594                                 v = wcross_origin - wcross_oldorigin;
 595                                 v.x /= vid_conwidth;
 596                                 v.y /= vid_conheight;
 597                                 if(vlen(v) > 0.01)
 598                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 599                         }
 600                         if(!autocvar_crosshair_hittest_showimpact)
 601                                 wcross_origin = wcross_oldorigin;
 602                 }
 603                 else
 604                         shottype = SHOTTYPE_HITWORLD;
 605
 606                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 607                 string wcross_name = "";
 608                 float wcross_scale, wcross_blur;
 609
 610                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 611                 {
 612                         e = get_weaponinfo(switchingweapon);
 613                         if(e)
 614                         {
 615                                 if(autocvar_crosshair_per_weapon)
 616                                 {
 617                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 618                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 619                                         //if (wcross_resolution == 0)
 620                                                 //return;
 621
 622                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 623                                         wcross_resolution *= e.w_crosshair_size;
 624                                         wcross_name = e.w_crosshair;
 625                                 }
 626                         }
 627                 }
 628
 629                 if(wcross_name == "")
 630                         wcross_name = strcat("gfx/crosshair", wcross_style);
 631
 632                 // MAIN CROSSHAIR COLOR DECISION
 633                 switch(autocvar_crosshair_color_special)
 634                 {
 635                         case 1: // crosshair_color_per_weapon
 636                         {
 637                                 if(e)
 638                                 {
 639                                         wcross_color = e.wpcolor;
 640                                         break;
 641                                 }
 642                                 else { goto normalcolor; }
 643                         }
 644
 645                         case 2: // crosshair_color_by_health
 646                         {
 647                                 float x = getstati(STAT_HEALTH);
 648
 649                                 //x = red
 650                                 //y = green
 651                                 //z = blue
 652
 653                                 wcross_color.z = 0;
 654
 655                                 if(x > 200)
 656                                 {
 657                                         wcross_color.x = 0;
 658                                         wcross_color.y = 1;
 659                                 }
 660                                 else if(x > 150)
 661                                 {
 662                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 663                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 664                                 }
 665                                 else if(x > 100)
 666                                 {
 667                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 668                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 669                                         wcross_color.z = 1 - (x-100)*0.02;
 670                                 }
 671                                 else if(x > 50)
 672                                 {
 673                                         wcross_color.x = 1;
 674                                         wcross_color.y = 1;
 675                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 676                                 }
 677                                 else if(x > 20)
 678                                 {
 679                                         wcross_color.x = 1;
 680                                         wcross_color.y = (x-20)*90/27/100;
 681                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 682                                 }
 683                                 else
 684                                 {
 685                                         wcross_color.x = 1;
 686                                         wcross_color.y = 0;
 687                                 }
 688                                 break;
 689                         }
 690
 691                         case 3: // crosshair_color_rainbow
 692                         {
 693                                 if(time >= rainbow_last_flicker)
 694                                 {
 695                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 696                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 697                                 }
 698                                 wcross_color = rainbow_prev_color;
 699                                 break;
 700                         }
 701                         :normalcolor
 702                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 703                 }
 704
 705                 if(autocvar_crosshair_effect_scalefade)
 706                 {
 707                         wcross_scale = wcross_resolution;
 708                         wcross_resolution = 1;
 709                 }
 710                 else
 711                 {
 712                         wcross_scale = 1;
 713                 }
 714
 715                 if(autocvar_crosshair_pickup)
 716                 {
 717                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 718
 719                         if(pickup_crosshair_time < stat_pickup_time)
 720                         {
 721                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 722                                         pickup_crosshair_size = 1;
 723
 724                                 pickup_crosshair_time = stat_pickup_time;
 725                         }
 726
 727                         if(pickup_crosshair_size > 0)
 728                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 729                         else
 730                                 pickup_crosshair_size = 0;
 731
 732                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 733                 }
 734
 735                 // todo: make crosshair hit indication dependent on damage dealt
 736                 if(autocvar_crosshair_hitindication)
 737                 {
 738                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 739
 740                         if(unaccounted_damage)
 741                         {
 742                                 hitindication_crosshair_size = 1;
 743                         }
 744
 745                         if(hitindication_crosshair_size > 0)
 746                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 747                         else
 748                                 hitindication_crosshair_size = 0;
 749
 750                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 751                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 752                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 753                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 754                 }
 755
 756                 if(shottype == SHOTTYPE_HITENEMY)
 757                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 758                 if(shottype == SHOTTYPE_HITTEAM)
 759                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 760
 761                 f = fabs(autocvar_crosshair_effect_time);
 762                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 763                 {
 764                         wcross_changedonetime = time + f;
 765                 }
 766                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 767                 {
 768                         wcross_name_changestarttime = time;
 769                         wcross_name_changedonetime = time + f;
 770                         if(wcross_name_goal_prev_prev)
 771                                 strunzone(wcross_name_goal_prev_prev);
 772                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 773                         wcross_name_goal_prev = strzone(wcross_name);
 774                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 775                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 776                         wcross_resolution_goal_prev = wcross_resolution;
 777                 }
 778
 779                 wcross_scale_goal_prev = wcross_scale;
 780                 wcross_alpha_goal_prev = wcross_alpha;
 781                 wcross_color_goal_prev = wcross_color;
 782
 783                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 784                 {
 785                         wcross_blur = 1;
 786                         wcross_alpha *= 0.75;
 787                 }
 788                 else
 789                         wcross_blur = 0;
 790                 // *_prev is at time-frametime
 791                 // * is at wcross_changedonetime+f
 792                 // what do we have at time?
 793                 if(time < wcross_changedonetime)
 794                 {
 795                         f = frametime / (wcross_changedonetime - time + frametime);
 796                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 797                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 798                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 799                 }
 800
 801                 wcross_scale_prev = wcross_scale;
 802                 wcross_alpha_prev = wcross_alpha;
 803                 wcross_color_prev = wcross_color;
 804
 805                 MUTATOR_CALLHOOK(UpdateCrosshair);
 806
 807                 wcross_scale *= 1 - autocvar__menu_alpha;
 808                 wcross_alpha *= 1 - autocvar__menu_alpha;
 809                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 810
 811                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 812                 {
 813                         // crosshair rings for weapon stats
 814                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 815                         {
 816                                 // declarations and stats
 817                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 818                                 string ring_image = string_null, ring_inner_image = string_null;
 819                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 820
 821                                 ring_scale = autocvar_crosshair_ring_size;
 822
 823                                 float weapon_clipload, weapon_clipsize;
 824                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 825                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 826
 827                                 float ok_ammo_charge, ok_ammo_chargepool;
 828                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 829                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 830
 831                                 float vortex_charge, vortex_chargepool;
 832                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 833                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 834
 835                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 836
 837                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 838                                         vortex_charge_movingavg = vortex_charge;
 839
 840
 841                                 // handle the values
 842                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX.m_id && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 843                                 {
 844                                         if (vortex_chargepool || use_vortex_chargepool) {
 845                                                 use_vortex_chargepool = 1;
 846                                                 ring_inner_value = vortex_chargepool;
 847                                         } else {
 848                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 849                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 850                                         }
 851
 852                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 853                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 854                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 855
 856                                         // draw the outer ring to show the current charge of the weapon
 857                                         ring_value = vortex_charge;
 858                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 859                                         ring_rgb = wcross_color;
 860                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 861                                 }
 862                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER.m_id && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 863                                 {
 864                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 865                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 866                                         ring_rgb = wcross_color;
 867                                         ring_image = "gfx/crosshair_ring.tga";
 868                                 }
 869                                 else if (activeweapon == WEP_HAGAR.m_id && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 870                                 {
 871                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 872                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 873                                         ring_rgb = wcross_color;
 874                                         ring_image = "gfx/crosshair_ring.tga";
 875                                 }
 876                                 else if (ok_ammo_charge)
 877                                 {
 878                                         ring_value = ok_ammo_chargepool;
 879                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 880                                         ring_rgb = wcross_color;
 881                                         ring_image = "gfx/crosshair_ring.tga";
 882                                 }
 883                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 884                                 {
 885                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 886                                         ring_scale = autocvar_crosshair_ring_reload_size;
 887                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 888                                         ring_rgb = wcross_color;
 889
 890                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 891                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 892                                         if ((activeweapon == WEP_RIFLE.m_id) && (weapon_clipsize == 80))
 893                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 894                                         else
 895                                                 ring_image = "gfx/crosshair_ring.tga";
 896                                 }
 897                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC.m_id )
 898                                 {
 899                                         ring_value = arc_heat;
 900                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 901                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 902                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 903                                         ring_image = "gfx/crosshair_ring.tga";
 904                                 }
 905
 906                                 // if in weapon switch animation, fade ring out/in
 907                                 if(autocvar_crosshair_effect_time > 0)
 908                                 {
 909                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 910                                         if (f >= 1)
 911                                         {
 912                                                 wcross_ring_prev = ((ring_image) ? true : false);
 913                                         }
 914
 915                                         if(wcross_ring_prev)
 916                                         {
 917                                                 if(f < 1)
 918                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 919                                         }
 920                                         else
 921                                         {
 922                                                 if(f < 1)
 923                                                         ring_alpha *= bound(0, f, 1);
 924                                         }
 925                                 }
 926
 927                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 928                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 929
 930                                 if (ring_value)
 931                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 932                         }
 933
 934 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 935                         do \
 936                         { \
 937                                 if(wcross_blur > 0) \
 938                                 { \
 939                                         for(i = -2; i <= 2; ++i) \
 940                                         for(j = -2; j <= 2; ++j) \
 941                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 942                                 } \
 943                                 else \
 944                                 { \
 945                                         M(0,0,sz,wcross_name,wcross_alpha); \
 946                                 } \
 947                         } \
 948                         while(0)
 949
 950 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 951                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 952
 953 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 954                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 955
 956                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 957                         {
 958                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 959                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 960                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 961                                 f = 1 - f;
 962                         }
 963                         else
 964                         {
 965                                 f = 1;
 966                         }
 967                         wcross_name_alpha_goal_prev = f;
 968
 969                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 970                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 971
 972                         if(autocvar_crosshair_dot)
 973                         {
 974                                 vector wcross_color_old;
 975                                 wcross_color_old = wcross_color;
 976
 977                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 978                                         wcross_color = stov(autocvar_crosshair_dot_color);
 979
 980                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 981                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 982                                 wcross_color = wcross_color_old;
 983                         }
 984                 }
 985         }
 986         else
 987         {
 988                 wcross_scale_prev = 0;
 989                 wcross_alpha_prev = 0;
 990                 wcross_scale_goal_prev = 0;
 991                 wcross_alpha_goal_prev = 0;
 992                 wcross_changedonetime = 0;
 993                 if(wcross_name_goal_prev)
 994                         strunzone(wcross_name_goal_prev);
 995                 wcross_name_goal_prev = string_null;
 996                 if(wcross_name_goal_prev_prev)
 997                         strunzone(wcross_name_goal_prev_prev);
 998                 wcross_name_goal_prev_prev = string_null;
 999                 wcross_name_changestarttime = 0;
1000                 wcross_name_changedonetime = 0;
1001                 wcross_name_alpha_goal_prev = 0;
1002                 wcross_name_alpha_goal_prev_prev = 0;
1003                 wcross_resolution_goal_prev = 0;
1004                 wcross_resolution_goal_prev_prev = 0;
1005         }
1006 }
1007
1008 const int BUTTON_3 = 4;
1009 const int BUTTON_4 = 8;
1010 float cl_notice_run();
1011 float prev_myteam;
1012 int lasthud;
1013 float vh_notice_time;
1014 void WaypointSprite_Load();
1015 void CSQC_UpdateView(float w, float h)
1016 {
1017         entity e;
1018         float fov;
1019         float f;
1020         int i;
1021         vector vf_size, vf_min;
1022         float a;
1023
1024         execute_next_frame();
1025
1026         ++framecount;
1027
1028         hud = getstati(STAT_HUD);
1029
1030         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1031                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1032
1033         lasthud = hud;
1034
1035         if(autocvar__hud_showbinds_reload) // menu can set this one
1036         {
1037                 db_close(binddb);
1038                 binddb = db_create();
1039                 cvar_set("_hud_showbinds_reload", "0");
1040         }
1041
1042         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1043                 view_quality = getproperty(VF_MINFPS_QUALITY);
1044         else
1045                 view_quality = 1;
1046
1047         button_attack2 = (input_buttons & BUTTON_3);
1048         button_zoom = (input_buttons & BUTTON_4);
1049
1050 #define CHECKFAIL_ASSERT(flag,func,parm,val) do {                                                                   \
1051         float checkfailv = (func)(parm);                                                                                \
1052         if (checkfailv != (val)) {                                                                                      \
1053                 if (!checkfail[(flag)])                                                                                     \
1054                 localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv));                           \
1055                 checkfail[(flag)] = 1;                                                                                      \
1056         }                                                                                                               \
1057 } while(0)
1058         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
1059         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
1060         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
1061         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1062         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
1063         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
1064         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1065
1066         vf_size = getpropertyvec(VF_SIZE);
1067         vf_min = getpropertyvec(VF_MIN);
1068         vid_width = vf_size.x;
1069         vid_height = vf_size.y;
1070
1071         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1072         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1073
1074         WaypointSprite_Load();
1075
1076         CSQCPlayer_SetCamera();
1077
1078         if(player_localentnum <= maxclients) // is it a client?
1079                 current_player = player_localentnum - 1;
1080         else // then player_localentnum is the vehicle I'm driving
1081                 current_player = player_localnum;
1082         myteam = GetPlayerColor(current_player);
1083
1084         if(myteam != prev_myteam)
1085         {
1086                 myteamcolors = colormapPaletteColor(myteam, 1);
1087                 for(i = 0; i < HUD_PANEL_NUM; ++i)
1088                         hud_panel[i].update_time = time;
1089                 prev_myteam = myteam;
1090         }
1091
1092         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1093
1094         float is_dead = (getstati(STAT_HEALTH) <= 0);
1095
1096         // FIXME do we need this hack?
1097         if(isdemo())
1098         {
1099                 // in demos, input_buttons do not work
1100                 button_zoom = (autocvar__togglezoom == "-");
1101         }
1102         else if(button_zoom
1103                 && autocvar_cl_unpress_zoom_on_death
1104                 && (spectatee_status >= 0)
1105                 && (is_dead || intermission))
1106         {
1107                 // no zoom while dead or in intermission please
1108                 localcmd("-zoom\n");
1109                 button_zoom = false;
1110         }
1111
1112         // event chase camera
1113         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1114         {
1115                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1116                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && getstati(STAT_ROUNDLOST));
1117                 entity gen = world;
1118
1119                 if(ons_roundlost)
1120                 {
1121                         entity e;
1122                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1123                         {
1124                                 if(e.health <= 0)
1125                                 {
1126                                         gen = e;
1127                                         break;
1128                                 }
1129                         }
1130                         if(!gen)
1131                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1132                 }
1133                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1134                 {
1135                         eventchase_running = true;
1136
1137                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1138                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1139                         if(ons_roundlost) { current_view_origin = gen.origin; }
1140
1141                         // detect maximum viewoffset and use it
1142                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1143                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1144                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1145
1146                         if(view_offset)
1147                         {
1148                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1149                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1150                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1151                         }
1152
1153                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1154                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1155                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1156                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1157
1158                         // make the camera smooth back
1159                         float chase_distance = autocvar_cl_eventchase_distance;
1160                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1161                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1162
1163                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1164                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1165                         else if(eventchase_current_distance != chase_distance)
1166                                 eventchase_current_distance = chase_distance;
1167
1168                         makevectors(view_angles);
1169
1170                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1171                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1172
1173                         // If the boxtrace fails, revert back to line tracing.
1174                         if(!self.viewloc)
1175                         if(trace_startsolid)
1176                         {
1177                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1178                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1179                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1180                         }
1181                         else { setproperty(VF_ORIGIN, trace_endpos); }
1182
1183                         if(!self.viewloc)
1184                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1185                 }
1186                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1187                 {
1188                         eventchase_running = false;
1189                         cvar_set("chase_active", "0");
1190                         eventchase_current_distance = 0; // start from 0 next time
1191                 }
1192         }
1193         // workaround for camera stuck between player's legs when using chase_active 1
1194         // because the engine stops updating the chase_active camera when the game ends
1195         else if(intermission)
1196         {
1197                 cvar_settemp("chase_active", "-1");
1198                 eventchase_current_distance = 0;
1199         }
1200
1201         // do lockview after event chase camera so that it still applies whenever necessary.
1202         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
1203         {
1204                 setproperty(VF_ORIGIN, freeze_org);
1205                 setproperty(VF_ANGLES, freeze_ang);
1206         }
1207         else
1208         {
1209                 freeze_org = getpropertyvec(VF_ORIGIN);
1210                 freeze_ang = getpropertyvec(VF_ANGLES);
1211         }
1212
1213         WarpZone_FixView();
1214         //WarpZone_FixPMove();
1215
1216         vector ov_org = '0 0 0';
1217         vector ov_mid = '0 0 0';
1218         vector ov_worldmin = '0 0 0';
1219         vector ov_worldmax = '0 0 0';
1220         if(autocvar_cl_orthoview)
1221         {
1222                 ov_worldmin = mi_picmin;
1223                 ov_worldmax = mi_picmax;
1224
1225                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1226                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1227                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1228
1229                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1230                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1231
1232                 float ov_nearest = vlen(ov_org - vec3(
1233                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1234                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1235                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1236                 ));
1237
1238                 float ov_furthest = 0;
1239                 float dist = 0;
1240
1241                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1242                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1243                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1244                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1245                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1246                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1247                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1248                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1249
1250                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1251                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1252                 cvar_settemp("r_farclip_world", "0");
1253                 cvar_settemp("r_novis", "1");
1254                 cvar_settemp("r_useportalculling", "0");
1255                 cvar_settemp("r_useinfinitefarclip", "0");
1256
1257                 setproperty(VF_ORIGIN, ov_org);
1258                 setproperty(VF_ANGLES, '90 0 0');
1259
1260                 #if 0
1261                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1262                         vtos(ov_org),
1263                         vtos(getpropertyvec(VF_ANGLES)),
1264                         ov_distance,
1265                         ov_nearest,
1266                         ov_furthest);
1267                 #endif
1268         }
1269
1270         // Render the Scene
1271         view_origin = getpropertyvec(VF_ORIGIN);
1272         view_angles = getpropertyvec(VF_ANGLES);
1273         makevectors(view_angles);
1274         view_forward = v_forward;
1275         view_right = v_right;
1276         view_up = v_up;
1277
1278 #ifdef BLURTEST
1279         if(time > blurtest_time0 && time < blurtest_time1)
1280         {
1281                 float r, t;
1282
1283                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1284                 r = t * blurtest_radius;
1285                 f = 1 / pow(t, blurtest_power) - 1;
1286
1287                 cvar_set("r_glsl_postprocess", "1");
1288                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1289         }
1290         else
1291         {
1292                 cvar_set("r_glsl_postprocess", "0");
1293                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1294         }
1295 #endif
1296
1297         TargetMusic_Advance();
1298         Fog_Force();
1299
1300         if(drawtime == 0)
1301                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1302         else
1303                 drawframetime = bound(0.000001, time - drawtime, 1);
1304         drawtime = time;
1305
1306         // watch for gametype changes here...
1307         // in ParseStuffCMD the cmd isn't executed yet :/
1308         // might even be better to add the gametype to TE_CSQC_INIT...?
1309         if(!postinit)
1310                 PostInit();
1311
1312         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1313         {
1314                 if(calledhooks & HOOK_START)
1315                 {
1316                         localcmd("\ncl_hook_gameend\n");
1317                         calledhooks |= HOOK_END;
1318                 }
1319         }
1320
1321         Announcer();
1322
1323         fov = autocvar_fov;
1324         if(fov <= 59.5)
1325         {
1326                 if(!zoomscript_caught)
1327                 {
1328                         localcmd("+button9\n");
1329                         zoomscript_caught = 1;
1330                 }
1331         }
1332         else
1333         {
1334                 if(zoomscript_caught)
1335                 {
1336                         localcmd("-button9\n");
1337                         zoomscript_caught = 0;
1338                 }
1339         }
1340
1341         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1342
1343         // next WANTED weapon (for HUD)
1344         switchweapon = getstati(STAT_SWITCHWEAPON);
1345
1346         // currently switching-to weapon (for crosshair)
1347         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1348
1349         // actually active weapon (for zoom)
1350         activeweapon = getstati(STAT_ACTIVEWEAPON);
1351
1352         f = (serverflags & SERVERFLAG_TEAMPLAY);
1353         if(f != teamplay)
1354         {
1355                 teamplay = f;
1356                 HUD_InitScores();
1357         }
1358
1359         if(last_switchweapon != switchweapon)
1360         {
1361                 weapontime = time;
1362                 last_switchweapon = switchweapon;
1363                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1364                 {
1365                         localcmd("-zoom\n");
1366                         button_zoom = false;
1367                 }
1368                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1369                 {
1370                         localcmd("-fire\n");
1371                         localcmd("-fire2\n");
1372                         button_attack2 = false;
1373                 }
1374         }
1375         if(last_activeweapon != activeweapon)
1376         {
1377                 last_activeweapon = activeweapon;
1378
1379                 e = get_weaponinfo(activeweapon);
1380                 if(e.netname != "")
1381                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1382                 else
1383                         localcmd("\ncl_hook_activeweapon none\n");
1384         }
1385
1386         // ALWAYS Clear Current Scene First
1387         clearscene();
1388
1389         setproperty(VF_ORIGIN, view_origin);
1390         setproperty(VF_ANGLES, view_angles);
1391
1392         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1393         setproperty(VF_SIZE, vf_size);
1394         setproperty(VF_MIN, vf_min);
1395
1396         // Assign Standard Viewflags
1397         // Draw the World (and sky)
1398         setproperty(VF_DRAWWORLD, 1);
1399
1400         // Set the console size vars
1401         vid_conwidth = autocvar_vid_conwidth;
1402         vid_conheight = autocvar_vid_conheight;
1403         vid_pixelheight = autocvar_vid_pixelheight;
1404
1405         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1406         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1407         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1408
1409         // Camera for demo playback
1410         if(camera_active)
1411         {
1412                 if(autocvar_camera_enable)
1413                         CSQC_Demo_Camera();
1414                 else
1415                 {
1416                         cvar_set("chase_active", ftos(chase_active_backup));
1417                         cvar_set("cl_demo_mousegrab", "0");
1418                         camera_active = false;
1419                 }
1420         }
1421         else
1422         {
1423 #ifdef CAMERATEST
1424                 if(autocvar_camera_enable)
1425 #else
1426                 if(autocvar_camera_enable && isdemo())
1427 #endif
1428                 {
1429                         // Enable required Darkplaces cvars
1430                         chase_active_backup = autocvar_chase_active;
1431                         cvar_set("chase_active", "2");
1432                         cvar_set("cl_demo_mousegrab", "1");
1433                         camera_active = true;
1434                         camera_mode = false;
1435                 }
1436         }
1437
1438         // Draw the Crosshair
1439         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1440
1441         // Draw the Engine Status Bar (the default Quake HUD)
1442         setproperty(VF_DRAWENGINESBAR, 0);
1443
1444         // Update the mouse position
1445         /*
1446            mousepos_x = vid_conwidth;
1447            mousepos_y = vid_conheight;
1448            mousepos = mousepos*0.5 + getmousepos();
1449          */
1450
1451         e = self;
1452         for(self = world; (self = nextent(self)); )
1453                 if(self.draw)
1454                         self.draw();
1455         self = e;
1456
1457         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1458         renderscene();
1459
1460         // now switch to 2D drawing mode by calling a 2D drawing function
1461         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1462         // next R_RenderScene call
1463         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1464
1465         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1466         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1467         {
1468                 // apply night vision effect
1469                 vector tc_00, tc_01, tc_10, tc_11;
1470                 vector rgb = '0 0 0';
1471
1472                 if(!nightvision_noise)
1473                 {
1474                         nightvision_noise = spawn();
1475                         nightvision_noise.classname = "nightvision_noise";
1476                 }
1477                 if(!nightvision_noise2)
1478                 {
1479                         nightvision_noise2 = spawn();
1480                         nightvision_noise2.classname = "nightvision_noise2";
1481                 }
1482
1483                 // color tint in yellow
1484                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1485
1486                 // draw BG
1487                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1488                 rgb = '1 1 1';
1489                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1490                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1491                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1492                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1493                 tc_11 = tc_01 + tc_10 - tc_00;
1494                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1495                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1496                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1497                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1498                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1499                 R_EndPolygon();
1500
1501                 // draw FG
1502                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1503                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1504                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1505                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1506                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1507                 tc_11 = tc_01 + tc_10 - tc_00;
1508                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1509                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1510                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1511                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1512                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1513                 R_EndPolygon();
1514         }
1515
1516         if(autocvar_cl_reticle)
1517         {
1518                 // Draw the aiming reticle for weapons that use it
1519                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1520                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1521                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1522                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1523                 {
1524                         // no zoom reticle while dead
1525                         reticle_type = 0;
1526                 }
1527                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
1528                 {
1529                         if(reticle_image != "") { reticle_type = 2; }
1530                         else { reticle_type = 0; }
1531                 }
1532                 else if(button_zoom || zoomscript_caught)
1533                 {
1534                         // normal zoom
1535                         reticle_type = 1;
1536                 }
1537
1538                 if(reticle_type)
1539                 {
1540                         if(autocvar_cl_reticle_stretch)
1541                         {
1542                                 reticle_size.x = vid_conwidth;
1543                                 reticle_size.y = vid_conheight;
1544                                 reticle_pos.x = 0;
1545                                 reticle_pos.y = 0;
1546                         }
1547                         else
1548                         {
1549                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1550                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1551                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1552                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1553                         }
1554
1555                         if(zoomscript_caught)
1556                                 f = 1;
1557                         else
1558                                 f = current_zoomfraction;
1559
1560                         if(f)
1561                         {
1562                                 switch(reticle_type)
1563                                 {
1564                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1565                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1566                                 }
1567                         }
1568                 }
1569         }
1570         else
1571         {
1572                 if(reticle_type != 0) { reticle_type = 0; }
1573         }
1574
1575
1576         // improved polyblend
1577         if(autocvar_hud_contents)
1578         {
1579                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1580                 vector liquidcolor;
1581
1582                 switch(pointcontents(view_origin))
1583                 {
1584                         case CONTENT_WATER:
1585                                 liquidalpha = autocvar_hud_contents_water_alpha;
1586                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1587                                 incontent = 1;
1588                                 break;
1589
1590                         case CONTENT_LAVA:
1591                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1592                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1593                                 incontent = 1;
1594                                 break;
1595
1596                         case CONTENT_SLIME:
1597                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1598                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1599                                 incontent = 1;
1600                                 break;
1601
1602                         default:
1603                                 liquidalpha = 0;
1604                                 liquidcolor = '0 0 0';
1605                                 incontent = 0;
1606                                 break;
1607                 }
1608
1609                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1610                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1611                         contentfadetime = autocvar_hud_contents_fadeintime;
1612                         liquidalpha_prev = liquidalpha;
1613                         liquidcolor_prev = liquidcolor;
1614                 }
1615                 else
1616                         contentfadetime = autocvar_hud_contents_fadeouttime;
1617
1618                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1619                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1620
1621                 if(contentavgalpha)
1622                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1623
1624                 if(autocvar_hud_postprocessing)
1625                 {
1626                         if(autocvar_hud_contents_blur && contentavgalpha)
1627                         {
1628                                 content_blurpostprocess.x = 1;
1629                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1630                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1631                         }
1632                         else
1633                         {
1634                                 content_blurpostprocess.x = 0;
1635                                 content_blurpostprocess.y = 0;
1636                                 content_blurpostprocess.z = 0;
1637                         }
1638                 }
1639         }
1640
1641         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1642         {
1643                 splash_size.x = max(vid_conwidth, vid_conheight);
1644                 splash_size.y = max(vid_conwidth, vid_conheight);
1645                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1646                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1647
1648                 float myhealth_flash_temp;
1649                 myhealth = getstati(STAT_HEALTH);
1650
1651                 // fade out
1652                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1653                 // add new damage
1654                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1655
1656                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1657                 pain_threshold = autocvar_hud_damage_pain_threshold;
1658                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1659                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1660
1661                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1662                 {
1663                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1664                 }
1665
1666                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1667
1668                 if(myhealth_prev < 1)
1669                 {
1670                         if(myhealth >= 1)
1671                         {
1672                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1673                                 myhealth_flash_temp = 0;
1674                         }
1675                         else
1676                         {
1677                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1678                         }
1679                 }
1680
1681                 if(spectatee_status == -1 || intermission)
1682                 {
1683                         myhealth_flash = 0; // observing, or match ended
1684                         myhealth_flash_temp = 0;
1685                 }
1686
1687                 myhealth_prev = myhealth;
1688
1689                 // IDEA: change damage color/picture based on player model for robot/alien species?
1690                 // pro: matches model better
1691                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1692                 // maybe different reddish pics?
1693                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1694                 {
1695                         if(autocvar_cl_gentle_damage == 2)
1696                         {
1697                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1698                                 {
1699                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1700                                 }
1701                         }
1702                         else
1703                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1704
1705                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1706                 }
1707                 else
1708                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1709
1710                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1711                 {
1712                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1713                         {
1714                                 damage_blurpostprocess.x = 1;
1715                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1716                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1717                         }
1718                         else
1719                         {
1720                                 damage_blurpostprocess.x = 0;
1721                                 damage_blurpostprocess.y = 0;
1722                                 damage_blurpostprocess.z = 0;
1723                         }
1724                 }
1725         }
1726
1727         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1728         float e2 = (autocvar_hud_powerup != 0);
1729         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1730         {
1731                 // enable or disable rendering types if they are used or not
1732                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1733                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1734
1735                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1736                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1737                 {
1738                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1739                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1740                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1741                         {
1742                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1743                                 old_blurradius = blurradius;
1744                                 old_bluralpha = bluralpha;
1745                         }
1746                 }
1747                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1748                 {
1749                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1750                         old_blurradius = 0;
1751                         old_bluralpha = 0;
1752                 }
1753
1754                 // edge detection postprocess handling done second (used by hud_powerup)
1755                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1756                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1757                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1758
1759                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1760
1761                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1762                 {
1763                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1764                         {
1765                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1766                                 old_sharpen_intensity = sharpen_intensity;
1767                         }
1768                 }
1769                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1770                 {
1771                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1772                         old_sharpen_intensity = 0;
1773                 }
1774
1775                 if(cvar("r_glsl_postprocess") == 0)
1776                         cvar_set("r_glsl_postprocess", "2");
1777         }
1778         else if(cvar("r_glsl_postprocess") == 2)
1779                 cvar_set("r_glsl_postprocess", "0");
1780
1781         if(menu_visible)
1782                 menu_show();
1783
1784         /*if(gametype == MAPINFO_TYPE_CTF)
1785           {
1786           ctf_view();
1787           } else */
1788
1789         // draw 2D entities
1790         e = self;
1791         for(self = world; (self = nextent(self)); )
1792                 if(self.draw2d)
1793                         self.draw2d();
1794         self = e;
1795         Draw_ShowNames_All();
1796
1797         scoreboard_active = HUD_WouldDrawScoreboard();
1798
1799         UpdateDamage();
1800         UpdateCrosshair();
1801         UpdateHitsound();
1802
1803         if(NextFrameCommand)
1804         {
1805                 localcmd("\n", NextFrameCommand, "\n");
1806                 NextFrameCommand = string_null;
1807         }
1808
1809         // we must do this check AFTER a frame was rendered, or it won't work
1810         if(cs_project_is_b0rked == 0)
1811         {
1812                 string w0, h0;
1813                 w0 = ftos(autocvar_vid_conwidth);
1814                 h0 = ftos(autocvar_vid_conheight);
1815                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1816                 //setproperty(VF_FOV, '90 90 0');
1817                 setproperty(VF_ORIGIN, '0 0 0');
1818                 setproperty(VF_ANGLES, '0 0 0');
1819                 setproperty(VF_PERSPECTIVE, 1);
1820                 makevectors('0 0 0');
1821                 vector v1, v2;
1822                 cvar_set("vid_conwidth", "800");
1823                 cvar_set("vid_conheight", "600");
1824                 v1 = cs_project(v_forward);
1825                 cvar_set("vid_conwidth", "640");
1826                 cvar_set("vid_conheight", "480");
1827                 v2 = cs_project(v_forward);
1828                 if(v1 == v2)
1829                         cs_project_is_b0rked = 1;
1830                 else
1831                         cs_project_is_b0rked = -1;
1832                 cvar_set("vid_conwidth", w0);
1833                 cvar_set("vid_conheight", h0);
1834         }
1835
1836         if(autocvar__hud_configure)
1837                 HUD_Panel_Mouse();
1838         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
1839                 HUD_Minigame_Mouse();
1840         else
1841                 HUD_Radar_Mouse();
1842
1843     if(hud && !intermission)
1844     if(hud == HUD_BUMBLEBEE_GUN)
1845         CSQC_BUMBLE_GUN_HUD();
1846     else
1847                 VEH_ACTION(hud, VR_HUD);
1848
1849         cl_notice_run();
1850
1851         // let's reset the view back to normal for the end
1852         setproperty(VF_MIN, '0 0 0');
1853         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1854 }
1855
1856
1857 void CSQC_common_hud(void)
1858 {
1859         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1860                 Accuracy_LoadLevels();
1861
1862         HUD_Main(); // always run these functions for alpha checks
1863         HUD_DrawScoreboard();
1864
1865         // scoreboard/accuracy, map/gametype voting screen
1866         if (scoreboard_active || intermission == 2)
1867                 HUD_Reset();
1868 }
1869
1870
1871 // following vectors must be global to allow seamless switching between camera modes
1872 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1873 void CSQC_Demo_Camera()
1874 {
1875         float speed, attenuation, dimensions;
1876         vector tmp, delta;
1877
1878         if( autocvar_camera_reset || !camera_mode )
1879         {
1880                 camera_offset = '0 0 0';
1881                 current_angles = '0 0 0';
1882                 camera_direction = '0 0 0';
1883                 camera_offset.z += 30;
1884                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1885                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1886                 current_origin = view_origin;
1887                 current_camera_offset  = camera_offset;
1888                 cvar_set("camera_reset", "0");
1889                 camera_mode = CAMERA_CHASE;
1890         }
1891
1892         // Camera angles
1893         if( camera_roll )
1894                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1895
1896         if(autocvar_camera_look_player)
1897         {
1898                 vector dir;
1899                 float n;
1900
1901                 dir = normalize(view_origin - current_position);
1902                 n = mouse_angles.z;
1903                 mouse_angles = vectoangles(dir);
1904                 mouse_angles.x = mouse_angles.x * -1;
1905                 mouse_angles.z = n;
1906         }
1907         else
1908         {
1909                 tmp = getmousepos() * 0.1;
1910                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1911                 {
1912                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1913                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1914                 }
1915         }
1916
1917         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1918         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1919         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1920         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1921
1922         // Fix difference when angles don't have the same sign
1923         delta = '0 0 0';
1924         if(mouse_angles.y < -60 && current_angles.y > 60)
1925                 delta = '0 360 0';
1926         if(mouse_angles.y > 60 && current_angles.y < -60)
1927                 delta = '0 -360 0';
1928
1929         if(autocvar_camera_look_player)
1930                 attenuation = autocvar_camera_look_attenuation;
1931         else
1932                 attenuation = autocvar_camera_speed_attenuation;
1933
1934         attenuation = 1 / max(1, attenuation);
1935         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1936
1937         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1938         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1939         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1940         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1941
1942         // Camera position
1943         tmp = '0 0 0';
1944         dimensions = 0;
1945
1946         if( camera_direction.x )
1947         {
1948                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1949                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1950                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1951                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1952                 ++dimensions;
1953         }
1954
1955         if( camera_direction.y )
1956         {
1957                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1958                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1959                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1960                 ++dimensions;
1961         }
1962
1963         if( camera_direction.z )
1964         {
1965                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1966                 ++dimensions;
1967         }
1968
1969         if(autocvar_camera_free)
1970                 speed = autocvar_camera_speed_free;
1971         else
1972                 speed = autocvar_camera_speed_chase;
1973
1974         if(dimensions)
1975         {
1976                 speed = speed * sqrt(1 / dimensions);
1977                 camera_offset += tmp * speed;
1978         }
1979
1980         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1981
1982         // Camera modes
1983         if( autocvar_camera_free )
1984         {
1985                 if ( camera_mode == CAMERA_CHASE )
1986                 {
1987                         current_camera_offset = current_origin + current_camera_offset;
1988                         camera_offset = current_origin + camera_offset;
1989                 }
1990
1991                 camera_mode = CAMERA_FREE;
1992                 current_position = current_camera_offset;
1993         }
1994         else
1995         {
1996                 if ( camera_mode == CAMERA_FREE )
1997                 {
1998                         current_origin = view_origin;
1999                         camera_offset = camera_offset - current_origin;
2000                         current_camera_offset = current_camera_offset - current_origin;
2001                 }
2002
2003                 camera_mode = CAMERA_CHASE;
2004
2005                 if(autocvar_camera_chase_smoothly)
2006                         current_origin += (view_origin - current_origin) * attenuation;
2007                 else
2008                         current_origin = view_origin;
2009
2010                 current_position = current_origin + current_camera_offset;
2011         }
2012
2013         setproperty(VF_ANGLES, current_angles);
2014         setproperty(VF_ORIGIN, current_position);
2015 }