qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79 { \
  80         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  81         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  82 } MACRO_END
  83
  84 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  85 { \
  86         float __f = 0; lowpass(value, frac, ref_store, __f); \
  87         ret = (value) - __f; \
  88 } MACRO_END
  89
  90 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  91 { \
  92         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  93         ret = (value) - __f; \
  94 } MACRO_END
  95
  96 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  97 { \
  98         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  99         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 100 } MACRO_END
 101
 102 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
 103 { \
 104         highpass(value.x, frac, ref_store.x, ref_out.x); \
 105         highpass(value.y, frac, ref_store.y, ref_out.y); \
 106 } MACRO_END
 107
 108 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 109 { \
 110         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 111         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 112 } MACRO_END
 113
 114 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115 { \
 116         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 117         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 118         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 119 } MACRO_END
 120
 121 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 122 { \
 123         highpass(value.x, frac, ref_store.x, ref_out.x); \
 124         highpass(value.y, frac, ref_store.y, ref_out.y); \
 125         highpass(value.z, frac, ref_store.z, ref_out.z); \
 126 } MACRO_END
 127
 128 void calc_followmodel_ofs(entity view)
 129 {
 130         if(cl_followmodel_time == time)
 131                 return; // cl_followmodel_ofs already calculated for this frame
 132
 133         float frac;
 134         vector gunorg = '0 0 0';
 135         static vector vel_average;
 136         static vector gunorg_adjustment_highpass;
 137         static vector gunorg_adjustment_lowpass;
 138
 139         vector vel;
 140         if (autocvar_cl_followmodel_velocity_absolute)
 141                 vel = view.velocity;
 142         else
 143         {
 144                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 145                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 146                 vel.x = view.velocity * forward;
 147                 vel.y = view.velocity * right * -1;
 148                 vel.z = view.velocity * up;
 149         }
 150
 151         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 152         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 153         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 154
 155         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 156         lowpass3(vel, frac, vel_average, gunorg);
 157
 158         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 159
 160         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 161         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 162         frac = avg_factor(autocvar_cl_followmodel_highpass);
 163         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 164         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 165         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 166
 167         if (autocvar_cl_followmodel_velocity_absolute)
 168         {
 169                 vector fixed_gunorg;
 170                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 171                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 172                 fixed_gunorg.x = gunorg * forward;
 173                 fixed_gunorg.y = gunorg * right * -1;
 174                 fixed_gunorg.z = gunorg * up;
 175                 gunorg = fixed_gunorg;
 176         }
 177
 178         cl_followmodel_ofs = gunorg;
 179         cl_followmodel_time = time;
 180 }
 181
 182 vector leanmodel_ofs(entity view)
 183 {
 184         float frac;
 185         vector gunangles = '0 0 0';
 186         static vector gunangles_prev = '0 0 0';
 187         static vector gunangles_highpass = '0 0 0';
 188         static vector gunangles_adjustment_highpass;
 189         static vector gunangles_adjustment_lowpass;
 190
 191         if (view.csqcmodel_teleported)
 192                 gunangles_prev = view_angles;
 193
 194         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 195         gunangles_highpass += gunangles_prev;
 196         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 197         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 198         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 199         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 200         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 201         gunangles_prev = view_angles;
 202         gunangles_highpass -= gunangles_prev;
 203
 204         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 205         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 206
 207         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 208         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 209         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 210         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 211         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 212
 213         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 214
 215         return gunangles;
 216 }
 217
 218 vector bobmodel_ofs(entity view)
 219 {
 220         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 221         static bool oldonground;
 222         static float hitgroundtime;
 223         if (clonground)
 224         {
 225                 float f = time; // cl.movecmd[0].time
 226                 if (!oldonground)
 227                         hitgroundtime = f;
 228         }
 229         oldonground = clonground;
 230
 231         // calculate for swinging gun model
 232         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 233         vector gunorg = '0 0 0';
 234         static float bobmodel_scale = 0;
 235         static float time_ofs = 0; // makes the effect always restart in the same way
 236         if (clonground)
 237         {
 238                 if (time - hitgroundtime > 0.05)
 239                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 240         }
 241         else
 242                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 243
 244         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 245         if (bobmodel_scale && xyspeed)
 246         {
 247                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 248                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 249                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 250                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 251         }
 252         else
 253                 time_ofs = time;
 254
 255         return gunorg;
 256 }
 257
 258 void viewmodel_animate(entity this)
 259 {
 260         if (autocvar_chase_active) return;
 261         if (STAT(HEALTH) <= 0) return;
 262
 263         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 264
 265         if (autocvar_cl_followmodel)
 266         {
 267                 calc_followmodel_ofs(view);
 268                 this.origin += cl_followmodel_ofs;
 269         }
 270
 271         if (autocvar_cl_leanmodel)
 272                 this.angles += leanmodel_ofs(view);
 273
 274         // vertical view bobbing code
 275         // TODO: cl_bob
 276
 277         // horizontal view bobbing code
 278         // TODO: cl_bob2
 279
 280         // fall bobbing code
 281         // causes the view to swing down and back up when touching the ground
 282         // TODO: cl_bobfall
 283
 284         // gun model bobbing code
 285         if (autocvar_cl_bobmodel)
 286                 this.origin += bobmodel_ofs(view);
 287 }
 288
 289 .vector viewmodel_origin, viewmodel_angles;
 290 .float weapon_nextthink;
 291 .float weapon_eta_last;
 292 .float weapon_switchdelay;
 293
 294 .string name_last;
 295
 296 void viewmodel_draw(entity this)
 297 {
 298         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 299                 return;
 300         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 301         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 302         bool invehicle = player_localentnum > maxclients;
 303         if (invehicle) a = -1;
 304         Weapon wep = this.activeweapon;
 305         int c = entcs_GetClientColors(current_player);
 306         vector g = weaponentity_glowmod(wep, NULL, c, this);
 307         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 308         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 309                 | EF_NODEPTHTEST)
 310                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 311         for (entity e = this; e; e = e.weaponchild)
 312         {
 313                 e.drawmask = mask;
 314                 e.alpha = a;
 315                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 316                 e.glowmod = g;
 317                 e.csqcmodel_effects = fx;
 318                 CSQCModel_Effects_Apply(e);
 319         }
 320         if(a >= 0)
 321         {
 322                 string name = wep.mdl;
 323                 string newname = wep.wr_viewmodel(wep, this);
 324                 if(newname)
 325                         name = newname;
 326                 bool swap = name != this.name_last;
 327                 // if (swap)
 328                 {
 329                         this.name_last = name;
 330                         CL_WeaponEntity_SetModel(this, name, swap);
 331                         this.viewmodel_origin = this.origin;
 332                         this.viewmodel_angles = this.angles;
 333                 }
 334                 anim_update(this);
 335                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 336                         anim_set(this, this.anim_idle, true, false, false);
 337         }
 338         float f = 0; // 0..1; 0: fully active
 339         float rate = STAT(WEAPONRATEFACTOR);
 340         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 341         if (eta <= 0) f = this.weapon_eta_last;
 342         else switch (this.state)
 343         {
 344                 case WS_RAISE:
 345                 {
 346                         f = eta / max(eta, this.weapon_switchdelay);
 347                         break;
 348                 }
 349                 case WS_DROP:
 350                 {
 351                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 352                         break;
 353                 }
 354                 case WS_CLEAR:
 355                 {
 356                         f = 1;
 357                         break;
 358                 }
 359         }
 360         this.weapon_eta_last = f;
 361         this.origin = this.viewmodel_origin;
 362         this.angles = this.viewmodel_angles;
 363         this.angles_x = (-90 * f * f);
 364         viewmodel_animate(this);
 365         MUTATOR_CALLHOOK(DrawViewModel, this);
 366         setorigin(this, this.origin);
 367 }
 368
 369 STATIC_INIT(viewmodel) {
 370     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 371         viewmodels[slot] = new(viewmodel);
 372 }
 373
 374 float showfps_prevfps;
 375 float showfps_prevfps_time;
 376 int showfps_framecounter;
 377
 378 void fpscounter_update()
 379 {
 380         if(!STAT(SHOWFPS))
 381                 return;
 382
 383         float currentTime = gettime(GETTIME_REALTIME);
 384         showfps_framecounter += 1;
 385         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 386         {
 387                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 388                 showfps_framecounter = 0;
 389                 showfps_prevfps_time = currentTime;
 390
 391                 int channel = MSG_C2S;
 392                 WriteHeader(channel, fpsreport);
 393                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 394         }
 395 }
 396
 397 STATIC_INIT(fpscounter_init)
 398 {
 399         float currentTime = gettime(GETTIME_REALTIME);
 400         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 401 }
 402
 403 STATIC_INIT(Porto)
 404 {
 405         entity e = new_pure(porto);
 406         e.draw = Porto_Draw;
 407         IL_PUSH(g_drawables, e);
 408         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 409 }
 410
 411 const int polyline_length = 16;
 412 .vector polyline[polyline_length];
 413 void Porto_Draw(entity this)
 414 {
 415         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 416         {
 417                 entity wepent = viewmodels[slot];
 418
 419                 if (wepent.activeweapon != WEP_PORTO) continue;
 420                 if (spectatee_status) continue;
 421                 if (WEP_CVAR(porto, secondary)) continue;
 422                 if (intermission == 1) continue;
 423                 if (intermission == 2) continue;
 424                 if (STAT(HEALTH) <= 0) continue;
 425
 426                 vector pos = view_origin;
 427                 vector dir = view_forward;
 428                 makevectors(((autocvar_chase_active) ? warpzone_save_view_angles : view_angles));
 429                 pos += v_right * -wepent.movedir.y
 430                         +  v_up * wepent.movedir.z;
 431
 432                 if (wepent.angles_held_status)
 433                 {
 434                         makevectors(wepent.angles_held);
 435                         dir = v_forward;
 436                 }
 437
 438                 wepent.polyline[0] = pos;
 439
 440                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 441                 int n = 1 + 2;  // 2 lines == 3 points
 442                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 443                 {
 444                         traceline(pos, pos + 65536 * dir, true, this);
 445                         dir = reflect(dir, trace_plane_normal);
 446                         pos = trace_endpos;
 447                         wepent.polyline[++idx] = pos;
 448                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 449                         {
 450                                 n += 1;
 451                                 continue;
 452                         }
 453                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 454                         {
 455                                 n = max(2, idx);
 456                                 break;
 457                         }
 458                         // check size
 459                         {
 460                                 vector ang = vectoangles2(trace_plane_normal, dir);
 461                                 ang.x = -ang.x;
 462                                 makevectors(ang);
 463                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 464                                 {
 465                                         n = max(2, idx);
 466                                         break;
 467                                 }
 468                         }
 469                         portal_number += 1;
 470                         if (portal_number >= portal_max) break;
 471                         if (portal_number == 1) portal1_idx = idx;
 472                 }
 473                 for (int idx = 0; idx < n - 1; ++idx)
 474                 {
 475                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 476                         if (idx == 0) p -= view_up * 16;  // line from player
 477                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 478                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 479                 }
 480         }
 481 }
 482
 483 float drawtime;
 484 float avgspeed;
 485 vector GetCurrentFov(float fov)
 486 {
 487         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 488         float velocityzoom, curspeed;
 489         vector v;
 490
 491         zoomsensitivity = autocvar_cl_zoomsensitivity;
 492         zoomfactor = autocvar_cl_zoomfactor;
 493         if(zoomfactor < 1 || zoomfactor > 30)
 494                 zoomfactor = 2.5;
 495         zoomspeed = autocvar_cl_zoomspeed;
 496         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 497                 zoomspeed = 3.5;
 498
 499         zoomdir = button_zoom;
 500
 501         if(hud == HUD_NORMAL && !spectatee_status)
 502         {
 503                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 504                 {
 505                         entity wepent = viewmodels[slot];
 506                         if(wepent.switchweapon != wepent.activeweapon)
 507                                 continue;
 508                         Weapon wep = wepent.activeweapon;
 509                         if(wep != WEP_Null && wep.wr_zoomdir)
 510                         {
 511                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 512                                 zoomdir += do_zoom;
 513                         }
 514                 }
 515         }
 516         if(spectatee_status > 0 || isdemo())
 517         {
 518                 if(spectatorbutton_zoom)
 519                 {
 520                         if(zoomdir)
 521                                 zoomdir = 0;
 522                         else
 523                                 zoomdir = 1;
 524                 }
 525                 // fteqcc failed twice here already, don't optimize this
 526         }
 527
 528         if(zoomdir) { zoomin_effect = 0; }
 529
 530         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 531         {
 532                 current_viewzoom = 1;
 533         }
 534         else if (camera_active)
 535         {
 536                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 537         }
 538         else if(autocvar_cl_spawnzoom && zoomin_effect)
 539         {
 540                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 541
 542                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 543                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 544                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 545         }
 546         else
 547         {
 548                 if(zoomspeed < 0) // instant zoom
 549                 {
 550                         if(zoomdir)
 551                                 current_viewzoom = 1 / zoomfactor;
 552                         else
 553                                 current_viewzoom = 1;
 554                 }
 555                 else
 556                 {
 557                         if(zoomdir)
 558                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 559                         else
 560                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 561                 }
 562         }
 563
 564         if(almost_equals(current_viewzoom, 1))
 565                 current_zoomfraction = 0;
 566         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 567                 current_zoomfraction = 1;
 568         else
 569                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 570
 571         if(zoomsensitivity < 1)
 572                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 573         else
 574                 setsensitivityscale(1);
 575
 576         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 577         {
 578                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 579                         curspeed = 0;
 580                 else
 581                 {
 582                         makevectors(view_angles);
 583                         v = pmove_vel;
 584                         if(csqcplayer)
 585                                 v = csqcplayer.velocity;
 586
 587                         switch(autocvar_cl_velocityzoom_type)
 588                         {
 589                                 case 3: curspeed = max(0, v_forward * v); break;
 590                                 case 2: curspeed = (v_forward * v); break;
 591                                 case 1: default: curspeed = vlen(v); break;
 592                         }
 593                 }
 594
 595                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 596                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 597                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 598
 599                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 600         }
 601         else
 602                 velocityzoom = 1;
 603
 604         float frustumx, frustumy, fovx, fovy;
 605         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 606         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 607         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 608         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 609
 610         return '1 0 0' * fovx + '0 1 0' * fovy;
 611 }
 612
 613 vector GetViewLocationFOV(float fov)
 614 {
 615         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 616         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 617         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 618         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 619         return '1 0 0' * fovx + '0 1 0' * fovy;
 620 }
 621
 622 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 623 {
 624         float fovx, fovy;
 625         float width = (ov_worldmax.x - ov_worldmin.x);
 626         float height = (ov_worldmax.y - ov_worldmin.y);
 627         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 628         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 629         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 630         return '1 0 0' * fovx + '0 1 0' * fovy;
 631 }
 632
 633 // this function must match W_SetupShot!
 634 float zoomscript_caught;
 635
 636 vector wcross_origin;
 637 float wcross_scale_prev, wcross_alpha_prev;
 638 vector wcross_color_prev;
 639 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 640 vector wcross_color_goal_prev;
 641 float wcross_changedonetime;
 642
 643 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 644 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 645 float wcross_name_changestarttime, wcross_name_changedonetime;
 646 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 647
 648 float wcross_ring_prev;
 649
 650 entity trueaim;
 651 entity trueaim_rifle;
 652
 653 const float SHOTTYPE_HITTEAM = 1;
 654 const float SHOTTYPE_HITOBSTRUCTION = 2;
 655 const float SHOTTYPE_HITWORLD = 3;
 656 const float SHOTTYPE_HITENEMY = 4;
 657
 658 void TrueAim_Init()
 659 {
 660         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 661         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 662 }
 663
 664 float EnemyHitCheck()
 665 {
 666         float t, n;
 667         wcross_origin = project_3d_to_2d(trace_endpos);
 668         wcross_origin.z = 0;
 669         if(trace_ent)
 670                 n = trace_ent.entnum;
 671         else
 672                 n = trace_networkentity;
 673         if(n < 1)
 674                 return SHOTTYPE_HITWORLD;
 675         if(n > maxclients)
 676                 return SHOTTYPE_HITWORLD;
 677         t = entcs_GetTeam(n - 1);
 678         if(teamplay)
 679                 if(t == myteam)
 680                         return SHOTTYPE_HITTEAM;
 681         if(t == NUM_SPECTATOR)
 682                 return SHOTTYPE_HITWORLD;
 683         return SHOTTYPE_HITENEMY;
 684 }
 685
 686 float TrueAimCheck(entity wepent)
 687 {
 688         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 689         vector vecs, trueaimpoint, w_shotorg;
 690         vector mi, ma, dv;
 691         float shottype;
 692         entity ta;
 693         float mv;
 694
 695         mi = ma = '0 0 0';
 696         ta = trueaim;
 697         mv = MOVE_NOMONSTERS;
 698
 699         switch(wepent.activeweapon) // WEAPONTODO
 700         {
 701                 case WEP_TUBA: // no aim
 702                 case WEP_PORTO: // shoots from eye
 703                 case WEP_NEXBALL: // shoots from eye
 704                 case WEP_HOOK: // no trueaim
 705                 case WEP_MORTAR: // toss curve
 706                         return SHOTTYPE_HITWORLD;
 707                 case WEP_VORTEX:
 708                 case WEP_OVERKILL_NEX:
 709                 case WEP_VAPORIZER:
 710                         mv = MOVE_NORMAL;
 711                         break;
 712                 case WEP_RIFLE:
 713                         ta = trueaim_rifle;
 714                         mv = MOVE_NORMAL;
 715                         if(zoomscript_caught)
 716                         {
 717                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 718                                 return EnemyHitCheck();
 719                         }
 720                         break;
 721                 case WEP_DEVASTATOR: // projectile has a size!
 722                         mi = '-3 -3 -3';
 723                         ma = '3 3 3';
 724                         break;
 725                 case WEP_FIREBALL: // projectile has a size!
 726                         mi = '-16 -16 -16';
 727                         ma = '16 16 16';
 728                         break;
 729                 case WEP_SEEKER: // projectile has a size!
 730                         mi = '-2 -2 -2';
 731                         ma = '2 2 2';
 732                         break;
 733                 case WEP_ELECTRO: // projectile has a size!
 734                         mi = '0 0 -3';
 735                         ma = '0 0 -3';
 736                         break;
 737         }
 738
 739         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 740
 741         vecs = decompressShotOrigin(STAT(SHOTORG));
 742
 743         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 744         trueaimpoint = trace_endpos;
 745
 746         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 747                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 748
 749         if(vecs.x > 0)
 750                 vecs.y = -vecs.y;
 751         else
 752                 vecs = '0 0 0';
 753
 754         dv = view_right * vecs.y + view_up * vecs.z;
 755         w_shotorg = traceorigin + dv;
 756
 757         // now move the vecs forward as much as requested if possible
 758         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 759         w_shotorg = trace_endpos - view_forward * nudge;
 760
 761         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 762         shottype = EnemyHitCheck();
 763         if(shottype != SHOTTYPE_HITWORLD)
 764                 return shottype;
 765
 766 #if 0
 767         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 768         // or rather, I know why, but see no fix
 769         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 770                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 771                 return SHOTTYPE_HITOBSTRUCTION;
 772 #endif
 773
 774         return SHOTTYPE_HITWORLD;
 775 }
 776
 777 float camera_mode;
 778 const float CAMERA_FREE = 1;
 779 const float CAMERA_CHASE = 2;
 780 float reticle_type;
 781 string NextFrameCommand;
 782
 783 vector freeze_org, freeze_ang;
 784 entity nightvision_noise, nightvision_noise2;
 785
 786 const float MAX_TIME_DIFF = 5;
 787 float pickup_crosshair_time, pickup_crosshair_size;
 788 float hitindication_crosshair_size;
 789 float use_vortex_chargepool;
 790
 791 float myhealth, myhealth_prev;
 792 float myhealth_flash;
 793
 794 float old_blurradius, old_bluralpha;
 795 float old_sharpen_intensity;
 796
 797 vector myhealth_gentlergb;
 798
 799 float contentavgalpha, liquidalpha_prev;
 800 vector liquidcolor_prev;
 801
 802 float eventchase_current_distance;
 803 float eventchase_running;
 804 bool WantEventchase(entity this)
 805 {
 806         if(autocvar_cl_orthoview)
 807                 return false;
 808         if(STAT(GAME_STOPPED) || intermission)
 809                 return true;
 810         if(this.viewloc)
 811                 return true;
 812         if(spectatee_status >= 0)
 813         {
 814                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 815                         return true;
 816                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 817                         return true;
 818                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 819                         return true;
 820                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 821                 {
 822                         if(autocvar_cl_eventchase_death == 2)
 823                         {
 824                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 825                                 if(this.velocity == '0 0 0' || eventchase_running)
 826                                         return true;
 827                         }
 828                         else return true;
 829                 }
 830                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change
 831                         && time <= spectatee_status_changed_time + 0.5)
 832                         return true;
 833         }
 834         return false;
 835 }
 836
 837 void HUD_Crosshair_Vehicle(entity this)
 838 {
 839         if(hud != HUD_BUMBLEBEE_GUN)
 840         {
 841                 Vehicle info = Vehicles_from(hud);
 842                 info.vr_crosshair(info, this);
 843         }
 844 }
 845
 846 vector damage_blurpostprocess, content_blurpostprocess;
 847
 848 float unaccounted_damage = 0;
 849 void UpdateDamage()
 850 {
 851         // accumulate damage with each stat update
 852         static float damage_total_prev = 0;
 853         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 854         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 855         damage_total_prev = damage_total;
 856
 857         static float damage_dealt_time_prev = 0;
 858         float damage_dealt_time = STAT(HIT_TIME);
 859         if (damage_dealt_time != damage_dealt_time_prev)
 860         {
 861                 unaccounted_damage += unaccounted_damage_new;
 862                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 863         }
 864         damage_dealt_time_prev = damage_dealt_time;
 865
 866         // prevent hitsound when switching spectatee
 867         static float spectatee_status_prev = 0;
 868         if (spectatee_status != spectatee_status_prev)
 869                 unaccounted_damage = 0;
 870         spectatee_status_prev = spectatee_status;
 871 }
 872
 873 void HitSound()
 874 {
 875         // varying sound pitch
 876
 877         bool have_arc = false;
 878         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 879         {
 880                 entity wepent = viewmodels[slot];
 881
 882                 if(wepent.activeweapon == WEP_ARC)
 883                         have_arc = true;
 884         }
 885
 886         static float hitsound_time_prev = 0;
 887         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 888         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 889         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 890         {
 891                 if (autocvar_cl_hitsound && unaccounted_damage)
 892                 {
 893                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 894                         float a = autocvar_cl_hitsound_max_pitch;
 895                         float b = autocvar_cl_hitsound_min_pitch;
 896                         float c = autocvar_cl_hitsound_nom_damage;
 897                         float d = unaccounted_damage;
 898                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 899
 900                         // if sound variation is disabled, set pitch_shift to 1
 901                         if (autocvar_cl_hitsound == 1)
 902                                 pitch_shift = 1;
 903
 904                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 905                         if (autocvar_cl_hitsound == 3)
 906                         {
 907                                 float mirror_value = (a-b)/2 + b;
 908                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 909                         }
 910
 911                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 912
 913                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 914                         // todo: normalize sound pressure levels? seems unnecessary
 915
 916                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 917                 }
 918                 unaccounted_damage = 0;
 919                 hitsound_time_prev = time;
 920         }
 921
 922         static float typehit_time_prev = 0;
 923         float typehit_time = STAT(TYPEHIT_TIME);
 924         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 925         {
 926                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 927                 typehit_time_prev = typehit_time;
 928         }
 929
 930         static float kill_time_prev = 0;
 931         float kill_time = STAT(KILL_TIME);
 932         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 933         {
 934                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 935                 kill_time_prev = kill_time;
 936         }
 937 }
 938
 939 vector crosshair_getcolor(entity this, float health_stat)
 940 {
 941         static float rainbow_last_flicker;
 942         static vector rainbow_prev_color;
 943         vector wcross_color = '0 0 0';
 944         switch(autocvar_crosshair_color_special)
 945         {
 946                 case 1: // crosshair_color_per_weapon
 947                 {
 948                         if(this != WEP_Null && hud == HUD_NORMAL)
 949                         {
 950                                 wcross_color = this.wpcolor;
 951                                 break;
 952                         }
 953                         else { goto normalcolor; }
 954                 }
 955
 956                 case 2: // crosshair_color_by_health
 957                 {
 958                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 959                         float hp = floor(v.x + 1);
 960
 961                         //x = red
 962                         //y = green
 963                         //z = blue
 964
 965                         wcross_color.z = 0;
 966
 967                         if(hp > 200)
 968                         {
 969                                 wcross_color.x = 0;
 970                                 wcross_color.y = 1;
 971                         }
 972                         else if(hp > 150)
 973                         {
 974                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 975                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 976                         }
 977                         else if(hp > 100)
 978                         {
 979                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 980                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 981                                 wcross_color.z = 1 - (hp-100)*0.02;
 982                         }
 983                         else if(hp > 50)
 984                         {
 985                                 wcross_color.x = 1;
 986                                 wcross_color.y = 1;
 987                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 988                         }
 989                         else if(hp > 20)
 990                         {
 991                                 wcross_color.x = 1;
 992                                 wcross_color.y = (hp-20)*90/27/100;
 993                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 994                         }
 995                         else
 996                         {
 997                                 wcross_color.x = 1;
 998                                 wcross_color.y = 0;
 999                         }
1000                         break;
1001                 }
1002
1003                 case 3: // crosshair_color_rainbow
1004                 {
1005                         if(time >= rainbow_last_flicker)
1006                         {
1007                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1008                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1009                         }
1010                         wcross_color = rainbow_prev_color;
1011                         break;
1012                 }
1013 LABEL(normalcolor)
1014                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1015         }
1016
1017         return wcross_color;
1018 }
1019
1020 void HUD_Crosshair(entity this)
1021 {
1022         float f, i, j;
1023         vector v;
1024         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
1025                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
1026                 !HUD_MinigameMenu_IsOpened() )
1027         {
1028                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1029                         return;
1030
1031                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
1032                         return;
1033
1034                 if (hud != HUD_NORMAL)
1035                 {
1036                         HUD_Crosshair_Vehicle(this);
1037                         return;
1038                 }
1039
1040                 string wcross_style;
1041                 float wcross_alpha, wcross_resolution;
1042                 wcross_style = autocvar_crosshair;
1043                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1044                         wcross_style = autocvar_crosshair_2d;
1045                 if (wcross_style == "0")
1046                         return;
1047                 wcross_resolution = autocvar_crosshair_size;
1048                 if (wcross_resolution == 0)
1049                         return;
1050                 wcross_alpha = autocvar_crosshair_alpha;
1051                 if (wcross_alpha == 0)
1052                         return;
1053
1054                 // TrueAim check
1055                 float shottype;
1056
1057                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1058                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1059                         wcross_origin = viewloc_mousepos;
1060                 else
1061                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1062                 wcross_origin.z = 0;
1063                 if(autocvar_crosshair_hittest)
1064                 {
1065                         vector wcross_oldorigin;
1066                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1067                         wcross_oldorigin = wcross_origin;
1068                         shottype = TrueAimCheck(thiswep);
1069                         if(shottype == SHOTTYPE_HITWORLD)
1070                         {
1071                                 v = wcross_origin - wcross_oldorigin;
1072                                 v.x /= vid_conwidth;
1073                                 v.y /= vid_conheight;
1074                                 if(vdist(v, >, 0.01))
1075                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1076                         }
1077                         if(!autocvar_crosshair_hittest_showimpact)
1078                                 wcross_origin = wcross_oldorigin;
1079                 }
1080                 else
1081                         shottype = SHOTTYPE_HITWORLD;
1082
1083                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1084                 string wcross_name = "";
1085                 float wcross_scale, wcross_blur;
1086
1087         entity e = WEP_Null;
1088                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1089                 {
1090                         entity wepent = viewmodels[0]; // TODO: unhardcode
1091                         e = wepent.switchingweapon;
1092                         if(e)
1093                         {
1094                                 if(autocvar_crosshair_per_weapon)
1095                                 {
1096                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1097                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1098                                         //if (wcross_resolution == 0)
1099                                                 //return;
1100
1101                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1102                                         wcross_resolution *= e.w_crosshair_size;
1103                                         wcross_name = e.w_crosshair;
1104                                 }
1105                         }
1106                 }
1107
1108                 if(wcross_name == "")
1109                         wcross_name = strcat("gfx/crosshair", wcross_style);
1110
1111                 // MAIN CROSSHAIR COLOR DECISION
1112                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1113
1114                 if(autocvar_crosshair_effect_scalefade)
1115                 {
1116                         wcross_scale = wcross_resolution;
1117                         wcross_resolution = 1;
1118                 }
1119                 else
1120                 {
1121                         wcross_scale = 1;
1122                 }
1123
1124                 if(autocvar_crosshair_pickup)
1125                 {
1126                         float stat_pickup_time = STAT(LAST_PICKUP);
1127
1128                         if(pickup_crosshair_time < stat_pickup_time)
1129                         {
1130                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1131                                         pickup_crosshair_size = 1;
1132
1133                                 pickup_crosshair_time = stat_pickup_time;
1134                         }
1135
1136                         if(pickup_crosshair_size > 0)
1137                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1138                         else
1139                                 pickup_crosshair_size = 0;
1140
1141                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1142                 }
1143
1144                 // todo: make crosshair hit indication dependent on damage dealt
1145                 if(autocvar_crosshair_hitindication)
1146                 {
1147                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1148
1149                         if(unaccounted_damage)
1150                         {
1151                                 hitindication_crosshair_size = 1;
1152                         }
1153
1154                         if(hitindication_crosshair_size > 0)
1155                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1156                         else
1157                                 hitindication_crosshair_size = 0;
1158
1159                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1160                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1161                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1162                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1163                 }
1164
1165                 if(shottype == SHOTTYPE_HITENEMY)
1166                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1167                 if(shottype == SHOTTYPE_HITTEAM)
1168                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1169
1170                 f = fabs(autocvar_crosshair_effect_time);
1171                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1172                 {
1173                         wcross_changedonetime = time + f;
1174                 }
1175                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1176                 {
1177                         wcross_name_changestarttime = time;
1178                         wcross_name_changedonetime = time + f;
1179                         if(wcross_name_goal_prev_prev)
1180                                 strunzone(wcross_name_goal_prev_prev);
1181                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1182                         wcross_name_goal_prev = strzone(wcross_name);
1183                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1184                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1185                         wcross_resolution_goal_prev = wcross_resolution;
1186                 }
1187
1188                 wcross_scale_goal_prev = wcross_scale;
1189                 wcross_alpha_goal_prev = wcross_alpha;
1190                 wcross_color_goal_prev = wcross_color;
1191
1192                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1193                 {
1194                         wcross_blur = 1;
1195                         wcross_alpha *= 0.75;
1196                 }
1197                 else
1198                         wcross_blur = 0;
1199                 // *_prev is at time-frametime
1200                 // * is at wcross_changedonetime+f
1201                 // what do we have at time?
1202                 if(time < wcross_changedonetime)
1203                 {
1204                         f = frametime / (wcross_changedonetime - time + frametime);
1205                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1206                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1207                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1208                 }
1209
1210                 wcross_scale_prev = wcross_scale;
1211                 wcross_alpha_prev = wcross_alpha;
1212                 wcross_color_prev = wcross_color;
1213
1214                 MUTATOR_CALLHOOK(UpdateCrosshair);
1215
1216                 wcross_scale *= 1 - autocvar__menu_alpha;
1217                 wcross_alpha *= 1 - autocvar__menu_alpha;
1218                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1219
1220                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1221                 {
1222                         // crosshair rings for weapon stats
1223                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1224                         {
1225                                 // declarations and stats
1226                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1227                                 string ring_image = string_null, ring_inner_image = string_null;
1228                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1229
1230                                 ring_scale = autocvar_crosshair_ring_size;
1231
1232                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1233
1234                                 int weapon_clipload = wepent.clip_load;
1235                                 int weapon_clipsize = wepent.clip_size;
1236
1237                                 float arc_heat = wepent.arc_heat_percent;
1238                                 float vcharge = wepent.vortex_charge;
1239                                 float vchargepool = wepent.vortex_chargepool_ammo;
1240                                 float oknex_charge_ = wepent.oknex_charge;
1241                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1242
1243                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1244                                         vortex_charge_movingavg = vcharge;
1245
1246                                 // handle the values
1247                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1248                                 {
1249                                         if (vchargepool || use_vortex_chargepool) {
1250                                                 use_vortex_chargepool = 1;
1251                                                 ring_inner_value = vchargepool;
1252                                         } else {
1253                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1254                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1255                                         }
1256
1257                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1258                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1259                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1260
1261                                         // draw the outer ring to show the current charge of the weapon
1262                                         ring_value = vcharge;
1263                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1264                                         ring_rgb = wcross_color;
1265                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1266                                 }
1267                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1268                                 {
1269                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1270                                                 use_vortex_chargepool = 1;
1271                                                 ring_inner_value = oknex_chargepool_;
1272                                         } else {
1273                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1274                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1275                                         }
1276
1277                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1278                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1279                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1280
1281                                         // draw the outer ring to show the current charge of the weapon
1282                                         ring_value = oknex_charge_;
1283                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1284                                         ring_rgb = wcross_color;
1285                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1286                                 }
1287                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1288                                 {
1289                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1290                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1291                                         ring_rgb = wcross_color;
1292                                         ring_image = "gfx/crosshair_ring.tga";
1293                                 }
1294                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1295                                 {
1296                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1297                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1298                                         ring_rgb = wcross_color;
1299                                         ring_image = "gfx/crosshair_ring.tga";
1300                                 }
1301                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1302                                 {
1303                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1304                                         ring_scale = autocvar_crosshair_ring_reload_size;
1305                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1306                                         ring_rgb = wcross_color;
1307
1308                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1309                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1310                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1311                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1312                                         else
1313                                                 ring_image = "gfx/crosshair_ring.tga";
1314                                 }
1315                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1316                                 {
1317                                         ring_value = arc_heat;
1318                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1319                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1320                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1321                                         ring_image = "gfx/crosshair_ring.tga";
1322                                 }
1323
1324                                 // if in weapon switch animation, fade ring out/in
1325                                 if(autocvar_crosshair_effect_time > 0)
1326                                 {
1327                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1328                                         if (f >= 1)
1329                                         {
1330                                                 wcross_ring_prev = ((ring_image) ? true : false);
1331                                         }
1332
1333                                         if(wcross_ring_prev)
1334                                         {
1335                                                 if(f < 1)
1336                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1337                                         }
1338                                         else
1339                                         {
1340                                                 if(f < 1)
1341                                                         ring_alpha *= bound(0, f, 1);
1342                                         }
1343                                 }
1344
1345                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1346                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1347
1348                                 if (ring_value)
1349                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1350                         }
1351
1352 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1353                         MACRO_BEGIN { \
1354                                 if(wcross_blur > 0) \
1355                                 { \
1356                                         for(i = -2; i <= 2; ++i) \
1357                                         for(j = -2; j <= 2; ++j) \
1358                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1359                                 } \
1360                                 else \
1361                                 { \
1362                                         M(0,0,sz,wcross_name,wcross_alpha); \
1363                                 } \
1364                         } MACRO_END
1365
1366 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1367                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1368
1369 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1370                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1371
1372                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1373                         {
1374                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1375                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1376                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1377                                 f = 1 - f;
1378                         }
1379                         else
1380                         {
1381                                 f = 1;
1382                         }
1383                         wcross_name_alpha_goal_prev = f;
1384
1385                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1386                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1387
1388                         if(autocvar_crosshair_dot)
1389                         {
1390                                 vector wcross_color_old;
1391                                 wcross_color_old = wcross_color;
1392
1393                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1394                                         wcross_color = stov(autocvar_crosshair_dot_color);
1395
1396                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1397                                 // FIXME why don't we use wcross_alpha here?
1398                                 wcross_color = wcross_color_old;
1399                         }
1400                 }
1401         }
1402         else
1403         {
1404                 wcross_scale_prev = 0;
1405                 wcross_alpha_prev = 0;
1406                 wcross_scale_goal_prev = 0;
1407                 wcross_alpha_goal_prev = 0;
1408                 wcross_changedonetime = 0;
1409                 strfree(wcross_name_goal_prev);
1410                 strfree(wcross_name_goal_prev_prev);
1411                 wcross_name_changestarttime = 0;
1412                 wcross_name_changedonetime = 0;
1413                 wcross_name_alpha_goal_prev = 0;
1414                 wcross_name_alpha_goal_prev_prev = 0;
1415                 wcross_resolution_goal_prev = 0;
1416                 wcross_resolution_goal_prev_prev = 0;
1417         }
1418 }
1419
1420 const int MAX_SPECIALCOMMAND = 15;
1421 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1422 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1423 const float SPECIALCOMMAND_SPEED = 150;
1424 const float SPECIALCOMMAND_TURNSPEED = 2;
1425 const float SPECIALCOMMAND_SIZE = 0.025;
1426 const float SPECIALCOMMAND_CHANCE = 0.35;
1427 float sc_spawntime, sc_changetime;
1428 vector sc_color = '1 1 1';
1429 void SpecialCommand()
1430 {
1431         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1432                 return;
1433
1434         if(time >= sc_changetime)
1435         {
1436                 sc_changetime = time + 1;
1437                 sc_color = randomvec() * 1.5;
1438                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1439                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1440                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1441         }
1442         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1443
1444         if(!precache_pic("gfx/smile"))
1445                 return; // damn party poopers
1446
1447         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1448         {
1449                 vector slot = specialcommand_slots[j];
1450                 if(slot.y)
1451                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1452                 //if(slot.z)
1453                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1454                 if(slot.y >= vid_conheight)
1455                         slot = '0 0 0';
1456
1457                 if(slot == '0 0 0')
1458                 {
1459                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1460                         {
1461                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1462                                 slot.y = 1; // start it off 0 so we can use it
1463                                 slot.z = floor(random() * Weapons_MAX);
1464                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1465                                 vector newcolor = randomvec() * 2;
1466                                 newcolor.x = bound(0.4, newcolor.x, 1);
1467                                 newcolor.y = bound(0.4, newcolor.y, 1);
1468                                 newcolor.z = bound(0.4, newcolor.z, 1);
1469                                 specialcommand_colors[j] = newcolor;
1470                         }
1471                 }
1472                 else
1473                 {
1474                         vector splash_size = '0 0 0';
1475                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1476                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1477                         entity wep = Weapons_from(slot.z);
1478                         if(wep == WEP_Null)
1479                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1480                         else
1481                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1482                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1483                 }
1484
1485                 specialcommand_slots[j] = slot;
1486         }
1487 }
1488
1489 void HUD_Draw(entity this)
1490 {
1491         // if we don't know gametype and scores yet avoid drawing the scoreboard
1492         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1493         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1494         // cl_deathscoreboard would show the scoreboard and so on
1495         if(!gametype)
1496                 return;
1497
1498         Hud_Dynamic_Frame();
1499
1500         if(!intermission)
1501         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1502         {
1503                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1504         }
1505         else if(STAT(FROZEN))
1506         {
1507                 vector col = '0.25 0.90 1';
1508                 if(STAT(REVIVE_PROGRESS))
1509                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1510                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1511         }
1512
1513         HUD_Scale_Enable();
1514         if(!intermission)
1515         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1516         {
1517                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1518                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1519                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1520         }
1521         else if(STAT(CAPTURE_PROGRESS))
1522         {
1523                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1524                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1525         }
1526         else if(STAT(REVIVE_PROGRESS))
1527         {
1528                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1529                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1530         }
1531         HUD_Scale_Disable();
1532
1533         if(autocvar_r_letterbox == 0)
1534                 if(autocvar_viewsize < 120)
1535                 {
1536                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1537                                 Accuracy_LoadLevels();
1538
1539                         HUD_Main();
1540                         HUD_Scale_Disable();
1541                 }
1542
1543         // crosshair goes VERY LAST
1544         SpecialCommand();
1545         UpdateDamage();
1546         HUD_Crosshair(this);
1547         HitSound();
1548 }
1549
1550 void ViewLocation_Mouse()
1551 {
1552         if(spectatee_status)
1553                 return; // don't draw it as spectator!
1554
1555         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1556         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1557         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1558
1559         //float cursor_alpha = 1 - autocvar__menu_alpha;
1560         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1561 }
1562
1563 bool ov_enabled;
1564 float oldr_nearclip;
1565 float oldr_farclip_base;
1566 float oldr_farclip_world;
1567 float oldr_novis;
1568 float oldr_useportalculling;
1569 float oldr_useinfinitefarclip;
1570
1571 float prev_myteam;
1572 int lasthud;
1573 float vh_notice_time;
1574 void CSQC_UpdateView(entity this, float w, float h)
1575 {
1576         TC(int, w); TC(int, h);
1577         entity e;
1578         float fov;
1579         float f;
1580         vector vf_size, vf_min;
1581         float a;
1582
1583         execute_next_frame();
1584
1585         ++framecount;
1586
1587         stats_get();
1588         hud = STAT(HUD);
1589
1590         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1591                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1592
1593         lasthud = hud;
1594
1595         HUD_Scale_Disable();
1596
1597         if(autocvar__hud_showbinds_reload) // menu can set this one
1598         {
1599                 db_close(binddb);
1600                 binddb = db_create();
1601                 cvar_set("_hud_showbinds_reload", "0");
1602         }
1603
1604         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1605                 view_quality = getproperty(VF_MINFPS_QUALITY);
1606         else
1607                 view_quality = 1;
1608
1609         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1610         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1611
1612         vf_size = getpropertyvec(VF_SIZE);
1613         vf_min = getpropertyvec(VF_MIN);
1614         vid_width = vf_size.x;
1615         vid_height = vf_size.y;
1616
1617         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1618         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1619
1620         WaypointSprite_Load();
1621
1622         CSQCPlayer_SetCamera();
1623
1624         if(player_localentnum <= maxclients) // is it a client?
1625                 current_player = player_localentnum - 1;
1626         else // then player_localentnum is the vehicle I'm driving
1627                 current_player = player_localnum;
1628         myteam = entcs_GetTeam(current_player);
1629
1630         if(myteam != prev_myteam)
1631         {
1632                 myteamcolors = colormapPaletteColor(myteam, 1);
1633                 FOREACH(hud_panels, true, it.update_time = time);
1634                 prev_myteam = myteam;
1635         }
1636
1637         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1638
1639         float is_dead = (STAT(HEALTH) <= 0);
1640
1641         // FIXME do we need this hack?
1642         if(isdemo())
1643         {
1644                 // in demos, input_buttons do not work
1645                 button_zoom = (autocvar__togglezoom == "-");
1646         }
1647         else if(button_zoom
1648                 && autocvar_cl_unpress_zoom_on_death
1649                 && (spectatee_status >= 0)
1650                 && (is_dead || intermission))
1651         {
1652                 // no zoom while dead or in intermission please
1653                 localcmd("-zoom\n");
1654                 button_zoom = false;
1655         }
1656
1657         // abused multiple places below
1658         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1659         if(!local_player)
1660                 local_player = this; // fall back!
1661
1662         // event chase camera
1663         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1664         {
1665                 if(STAT(CAMERA_SPECTATOR))
1666                 {
1667                         if(spectatee_status > 0)
1668                         {
1669                                 if(!autocvar_chase_active)
1670                                 {
1671                                         cvar_set("chase_active", "-2");
1672                                         goto skip_eventchase_death;
1673                                 }
1674                         }
1675                         else if(autocvar_chase_active == -2)
1676                                 cvar_set("chase_active", "0");
1677
1678                         if(autocvar_chase_active == -2)
1679                                 goto skip_eventchase_death;
1680                 }
1681                 else if(autocvar_chase_active == -2)
1682                         cvar_set("chase_active", "0");
1683
1684                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1685
1686                 float vehicle_viewdist = 0;
1687                 vector vehicle_viewofs = '0 0 0';
1688
1689                 if(vehicle_chase)
1690                 {
1691                         if(hud != HUD_BUMBLEBEE_GUN)
1692                         {
1693                                 Vehicle info = Vehicles_from(hud);
1694                                 vehicle_viewdist = info.height;
1695                                 vehicle_viewofs = info.view_ofs;
1696                         }
1697                 }
1698
1699                 if(WantEventchase(this))
1700                 {
1701                         vector current_view_origin_override = '0 0 0';
1702                         vector view_offset_override = '0 0 0';
1703                         float chase_distance_override = 0;
1704                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1705                         if(custom_eventchase)
1706                         {
1707                                 current_view_origin_override = M_ARGV(0, vector);
1708                                 view_offset_override = M_ARGV(1, vector);
1709                                 chase_distance_override = M_ARGV(0, float);
1710                         }
1711                         eventchase_running = true;
1712
1713                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1714                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1715                         if (custom_eventchase)
1716                                 current_view_origin = current_view_origin_override;
1717
1718                         // detect maximum viewoffset and use it
1719                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1720                         if(vehicle_chase)
1721                         {
1722                                 if(vehicle_viewofs)
1723                                         view_offset = vehicle_viewofs;
1724                                 else
1725                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1726                         }
1727                         if (custom_eventchase)
1728                                 view_offset = view_offset_override;
1729
1730                         if(view_offset)
1731                         {
1732                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1733                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1734                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1735                         }
1736
1737                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1738                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1739                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1740                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1741
1742                         // make the camera smooth back
1743                         float chase_distance = autocvar_cl_eventchase_distance;
1744                         if(vehicle_chase)
1745                         {
1746                                 if(vehicle_viewofs)
1747                                         chase_distance = vehicle_viewdist;
1748                                 else
1749                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1750                         }
1751                         if (custom_eventchase)
1752                                 chase_distance = chase_distance_override;
1753
1754                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1755                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1756                         else if(eventchase_current_distance != chase_distance)
1757                                 eventchase_current_distance = chase_distance;
1758
1759                         makevectors(view_angles);
1760
1761                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1762                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1763
1764                         // If the boxtrace fails, revert back to line tracing.
1765                         if(!local_player.viewloc)
1766                         if(trace_startsolid)
1767                         {
1768                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1769                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1770                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1771                         }
1772                         else { setproperty(VF_ORIGIN, trace_endpos); }
1773
1774                         if(!local_player.viewloc)
1775                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1776                 }
1777                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1778                 {
1779                         eventchase_running = false;
1780                         cvar_set("chase_active", "0");
1781                         eventchase_current_distance = 0; // start from 0 next time
1782                 }
1783         }
1784         // workaround for camera stuck between player's legs when using chase_active 1
1785         // because the engine stops updating the chase_active camera when the game ends
1786         else if(intermission)
1787         {
1788                 cvar_settemp("chase_active", "-1");
1789                 eventchase_current_distance = 0;
1790         }
1791
1792         LABEL(skip_eventchase_death);
1793
1794         // do lockview after event chase camera so that it still applies whenever necessary.
1795         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1796         {
1797                 setproperty(VF_ORIGIN, freeze_org);
1798                 setproperty(VF_ANGLES, freeze_ang);
1799         }
1800         else
1801         {
1802                 freeze_org = getpropertyvec(VF_ORIGIN);
1803                 freeze_ang = getpropertyvec(VF_ANGLES);
1804         }
1805
1806         WarpZone_FixView();
1807         //WarpZone_FixPMove();
1808
1809         vector ov_org = '0 0 0';
1810         vector ov_mid = '0 0 0';
1811         vector ov_worldmin = '0 0 0';
1812         vector ov_worldmax = '0 0 0';
1813         if(autocvar_cl_orthoview)
1814         {
1815                 ov_worldmin = mi_picmin;
1816                 ov_worldmax = mi_picmax;
1817
1818                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1819                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1820                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1821
1822                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1823                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1824
1825                 float ov_nearest = vlen(ov_org - vec3(
1826                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1827                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1828                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1829                 ));
1830
1831                 float ov_furthest = 0;
1832                 float dist = 0;
1833
1834                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1835                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1836                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1837                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1838                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1839                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1840                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1841                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1842
1843                 if(!ov_enabled)
1844                 {
1845                         oldr_nearclip = cvar("r_nearclip");
1846                         oldr_farclip_base = cvar("r_farclip_base");
1847                         oldr_farclip_world = cvar("r_farclip_world");
1848                         oldr_novis = cvar("r_novis");
1849                         oldr_useportalculling = cvar("r_useportalculling");
1850                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1851                 }
1852
1853                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1854                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1855                 cvar_settemp("r_farclip_world", "0");
1856                 cvar_settemp("r_novis", "1");
1857                 cvar_settemp("r_useportalculling", "0");
1858                 cvar_settemp("r_useinfinitefarclip", "0");
1859
1860                 setproperty(VF_ORIGIN, ov_org);
1861                 setproperty(VF_ANGLES, '90 0 0');
1862
1863                 ov_enabled = true;
1864
1865                 #if 0
1866                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1867                         vtos(ov_org),
1868                         vtos(getpropertyvec(VF_ANGLES)),
1869                         ov_distance,
1870                         ov_nearest,
1871                         ov_furthest);
1872                 #endif
1873         }
1874         else
1875         {
1876                 if(ov_enabled)
1877                 {
1878                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1879                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1880                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1881                         cvar_set("r_novis", ftos(oldr_novis));
1882                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1883                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1884                 }
1885                 ov_enabled = false;
1886         }
1887
1888         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1889         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1890         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1891                 viewmodel_draw(viewmodels[slot]);
1892
1893         // Render the Scene
1894         view_origin = getpropertyvec(VF_ORIGIN);
1895         view_angles = getpropertyvec(VF_ANGLES);
1896         makevectors(view_angles);
1897         view_forward = v_forward;
1898         view_right = v_right;
1899         view_up = v_up;
1900
1901 #ifdef BLURTEST
1902         if(time > blurtest_time0 && time < blurtest_time1)
1903         {
1904                 float r, t;
1905
1906                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1907                 r = t * blurtest_radius;
1908                 f = 1 / (t ** blurtest_power) - 1;
1909
1910                 cvar_set("r_glsl_postprocess", "1");
1911                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1912         }
1913         else
1914         {
1915                 cvar_set("r_glsl_postprocess", "0");
1916                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1917         }
1918 #endif
1919
1920         TargetMusic_Advance();
1921         Fog_Force();
1922         fpscounter_update();
1923
1924         if(drawtime == 0)
1925                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1926         else
1927                 drawframetime = bound(0.000001, time - drawtime, 1);
1928         drawtime = time;
1929
1930         // watch for gametype changes here...
1931         // in ParseStuffCMD the cmd isn't executed yet :/
1932         // might even be better to add the gametype to TE_CSQC_INIT...?
1933         if(!postinit)
1934                 PostInit();
1935
1936         if(intermission && !intermission_time)
1937                 intermission_time = time;
1938
1939         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1940         {
1941                 if(calledhooks & HOOK_START)
1942                 {
1943                         localcmd("\ncl_hook_gameend\n");
1944                         calledhooks |= HOOK_END;
1945                 }
1946         }
1947
1948         Announcer();
1949
1950         fov = autocvar_fov;
1951         if(fov <= 59.5)
1952         {
1953                 if(!zoomscript_caught)
1954                 {
1955                         localcmd("+button9\n");
1956                         zoomscript_caught = 1;
1957                 }
1958         }
1959         else
1960         {
1961                 if(zoomscript_caught)
1962                 {
1963                         localcmd("-button9\n");
1964                         zoomscript_caught = 0;
1965                 }
1966         }
1967
1968         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1969
1970         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1971         {
1972                 entity wepent = viewmodels[slot];
1973
1974                 if(wepent.last_switchweapon != wepent.switchweapon)
1975                 {
1976                         weapontime = time;
1977                         wepent.last_switchweapon = wepent.switchweapon;
1978                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1979                         {
1980                                 localcmd("-zoom\n");
1981                                 button_zoom = false;
1982                         }
1983                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1984                         {
1985                                 localcmd("-fire\n");
1986                                 localcmd("-fire2\n");
1987                                 button_attack2 = false;
1988                         }
1989                 }
1990                 if(wepent.last_activeweapon != wepent.activeweapon)
1991                 {
1992                         wepent.last_activeweapon = wepent.activeweapon;
1993
1994                         e = wepent.activeweapon;
1995                         if(e.netname != "")
1996                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1997                         else if(slot == 0)
1998                                 localcmd("\ncl_hook_activeweapon none\n");
1999                 }
2000         }
2001
2002         // ALWAYS Clear Current Scene First
2003         clearscene();
2004
2005         setproperty(VF_ORIGIN, view_origin);
2006         setproperty(VF_ANGLES, view_angles);
2007
2008         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2009         setproperty(VF_SIZE, vf_size);
2010         setproperty(VF_MIN, vf_min);
2011
2012         // Assign Standard Viewflags
2013         // Draw the World (and sky)
2014         setproperty(VF_DRAWWORLD, 1);
2015
2016         // Set the console size vars
2017         vid_conwidth = autocvar_vid_conwidth;
2018         vid_conheight = autocvar_vid_conheight;
2019         vid_pixelheight = autocvar_vid_pixelheight;
2020
2021         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2022         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2023         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2024
2025         if(camera_active) // Camera for demo playback
2026         {
2027                 if(autocvar_camera_enable)
2028                         CSQC_Demo_Camera();
2029                 else
2030                 {
2031                         cvar_set("chase_active", ftos(chase_active_backup));
2032                         cvar_set("cl_demo_mousegrab", "0");
2033                         camera_active = false;
2034                 }
2035         }
2036         else
2037         {
2038 #ifdef CAMERATEST
2039                 if(autocvar_camera_enable)
2040 #else
2041                 if(autocvar_camera_enable && isdemo())
2042 #endif
2043                 {
2044                         // Enable required Darkplaces cvars
2045                         chase_active_backup = autocvar_chase_active;
2046                         cvar_set("chase_active", "2");
2047                         cvar_set("cl_demo_mousegrab", "1");
2048                         camera_active = true;
2049                         camera_mode = false;
2050                 }
2051         }
2052
2053         // Draw the Crosshair
2054         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2055
2056         // Draw the Engine Status Bar (the default Quake HUD)
2057         setproperty(VF_DRAWENGINESBAR, 0);
2058
2059         // Update the mouse position
2060         /*
2061            mousepos_x = vid_conwidth;
2062            mousepos_y = vid_conheight;
2063            mousepos = mousepos*0.5 + getmousepos();
2064          */
2065
2066         IL_EACH(g_drawables, it.draw, it.draw(it));
2067
2068         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2069         renderscene();
2070
2071         // now switch to 2D drawing mode by calling a 2D drawing function
2072         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2073         // next R_RenderScene call
2074         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2075
2076         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2077         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2078         {
2079                 // apply night vision effect
2080                 vector tc_00, tc_01, tc_10, tc_11;
2081                 vector rgb = '0 0 0';
2082
2083                 if(!nightvision_noise)
2084                 {
2085                         nightvision_noise = new(nightvision_noise);
2086                 }
2087                 if(!nightvision_noise2)
2088                 {
2089                         nightvision_noise2 = new(nightvision_noise2);
2090                 }
2091
2092                 // color tint in yellow
2093                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2094
2095                 // draw BG
2096                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2097                 rgb = '1 1 1';
2098                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2099                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2100                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2101                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2102                 tc_11 = tc_01 + tc_10 - tc_00;
2103                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2104                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2105                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2106                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2107                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2108                 R_EndPolygon();
2109
2110                 // draw FG
2111                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2112                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2113                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2114                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2115                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2116                 tc_11 = tc_01 + tc_10 - tc_00;
2117                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2118                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2119                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2120                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2121                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2122                 R_EndPolygon();
2123         }
2124
2125         if(autocvar_cl_reticle)
2126         {
2127                 string reticle_image = string_null;
2128                 bool wep_zoomed = false;
2129                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2130                 {
2131                         entity wepe = viewmodels[slot];
2132                         Weapon wep = wepe.activeweapon;
2133                         if(wep != WEP_Null && wep.wr_zoom)
2134                         {
2135                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2136                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2137                                         reticle_image = wep.w_reticle;
2138                                 wep_zoomed += do_zoom;
2139                         }
2140                 }
2141                 // Draw the aiming reticle for weapons that use it
2142                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2143                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2144                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2145                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2146                 {
2147                         // no zoom reticle while dead
2148                         reticle_type = 0;
2149                 }
2150                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2151                 {
2152                         if(reticle_image) { reticle_type = 2; }
2153                         else { reticle_type = 0; }
2154                 }
2155                 else if(button_zoom || zoomscript_caught)
2156                 {
2157                         // normal zoom
2158                         reticle_type = 1;
2159                 }
2160
2161                 if(reticle_type)
2162                 {
2163                         if(autocvar_cl_reticle_stretch)
2164                         {
2165                                 reticle_size.x = vid_conwidth;
2166                                 reticle_size.y = vid_conheight;
2167                                 reticle_pos.x = 0;
2168                                 reticle_pos.y = 0;
2169                         }
2170                         else
2171                         {
2172                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2173                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2174                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2175                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2176                         }
2177
2178                         if(zoomscript_caught)
2179                                 f = 1;
2180                         else
2181                                 f = current_zoomfraction;
2182
2183                         if(f)
2184                         {
2185                                 switch(reticle_type)
2186                                 {
2187                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2188                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2189                                 }
2190                         }
2191                 }
2192         }
2193         else
2194         {
2195                 if(reticle_type != 0) { reticle_type = 0; }
2196         }
2197
2198
2199         // improved polyblend
2200         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2201         {
2202                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2203                 vector liquidcolor;
2204
2205                 switch(pointcontents(view_origin))
2206                 {
2207                         case CONTENT_WATER:
2208                                 liquidalpha = autocvar_hud_contents_water_alpha;
2209                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2210                                 incontent = 1;
2211                                 break;
2212
2213                         case CONTENT_LAVA:
2214                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2215                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2216                                 incontent = 1;
2217                                 break;
2218
2219                         case CONTENT_SLIME:
2220                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2221                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2222                                 incontent = 1;
2223                                 break;
2224
2225                         default:
2226                                 liquidalpha = 0;
2227                                 liquidcolor = '0 0 0';
2228                                 incontent = 0;
2229                                 break;
2230                 }
2231
2232                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2233                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2234                         contentfadetime = autocvar_hud_contents_fadeintime;
2235                         liquidalpha_prev = liquidalpha;
2236                         liquidcolor_prev = liquidcolor;
2237                 }
2238                 else
2239                         contentfadetime = autocvar_hud_contents_fadeouttime;
2240
2241                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2242                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2243
2244                 if(contentavgalpha)
2245                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2246
2247                 if(autocvar_hud_postprocessing)
2248                 {
2249                         if(autocvar_hud_contents_blur && contentavgalpha)
2250                         {
2251                                 content_blurpostprocess.x = 1;
2252                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2253                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2254                         }
2255                         else
2256                         {
2257                                 content_blurpostprocess.x = 0;
2258                                 content_blurpostprocess.y = 0;
2259                                 content_blurpostprocess.z = 0;
2260                         }
2261                 }
2262         }
2263
2264         if(autocvar_hud_damage && !STAT(FROZEN))
2265         {
2266                 splash_size.x = max(vid_conwidth, vid_conheight);
2267                 splash_size.y = max(vid_conwidth, vid_conheight);
2268                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2269                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2270
2271                 float myhealth_flash_temp;
2272                 myhealth = STAT(HEALTH);
2273
2274                 // fade out
2275                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2276                 // add new damage
2277                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2278
2279                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2280                 pain_threshold = autocvar_hud_damage_pain_threshold;
2281                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2282                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2283
2284                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2285                 {
2286                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2287                 }
2288
2289                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2290
2291                 if(myhealth_prev < 1)
2292                 {
2293                         if(myhealth >= 1)
2294                         {
2295                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2296                                 myhealth_flash_temp = 0;
2297                         }
2298                         else
2299                         {
2300                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2301                         }
2302                 }
2303
2304                 if(spectatee_status == -1 || intermission)
2305                 {
2306                         myhealth_flash = 0; // observing, or match ended
2307                         myhealth_flash_temp = 0;
2308                 }
2309
2310                 myhealth_prev = myhealth;
2311
2312                 // IDEA: change damage color/picture based on player model for robot/alien species?
2313                 // pro: matches model better
2314                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2315                 // maybe different reddish pics?
2316                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2317                 {
2318                         if(autocvar_cl_gentle_damage == 2)
2319                         {
2320                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2321                                         myhealth_gentlergb = randomvec();
2322                         }
2323                         else
2324                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2325
2326                         if(myhealth_flash_temp > 0)
2327                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2328                 }
2329                 else if(myhealth_flash_temp > 0)
2330                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2331
2332                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2333                 {
2334                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2335                         {
2336                                 damage_blurpostprocess.x = 1;
2337                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2338                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2339                         }
2340                         else
2341                         {
2342                                 damage_blurpostprocess.x = 0;
2343                                 damage_blurpostprocess.y = 0;
2344                                 damage_blurpostprocess.z = 0;
2345                         }
2346                 }
2347         }
2348
2349         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2350         float e2 = (autocvar_hud_powerup != 0);
2351         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2352         {
2353                 // enable or disable rendering types if they are used or not
2354                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2355                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2356
2357                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2358                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2359                 {
2360                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2361                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2362                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2363                         {
2364                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2365                                 old_blurradius = blurradius;
2366                                 old_bluralpha = bluralpha;
2367                         }
2368                 }
2369                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2370                 {
2371                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2372                         old_blurradius = 0;
2373                         old_bluralpha = 0;
2374                 }
2375
2376                 // edge detection postprocess handling done second (used by hud_powerup)
2377                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2378                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2379                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2380
2381                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2382
2383                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2384                 {
2385                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2386                         {
2387                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2388                                 old_sharpen_intensity = sharpen_intensity;
2389                         }
2390                 }
2391                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2392                 {
2393                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2394                         old_sharpen_intensity = 0;
2395                 }
2396
2397                 if(cvar("r_glsl_postprocess") == 0)
2398                         cvar_set("r_glsl_postprocess", "2");
2399         }
2400         else if(cvar("r_glsl_postprocess") == 2)
2401                 cvar_set("r_glsl_postprocess", "0");
2402
2403         /*if(gametype == MAPINFO_TYPE_CTF)
2404           {
2405           ctf_view();
2406           } else */
2407
2408         // draw 2D entities
2409         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2410         Draw_ShowNames_All();
2411 #if ENABLE_DEBUGDRAW
2412         Debug_Draw();
2413 #endif
2414
2415         scoreboard_active = Scoreboard_WouldDraw();
2416
2417         HUD_Draw(this); // this parameter for deep vehicle function
2418
2419         if(NextFrameCommand)
2420         {
2421                 localcmd("\n", NextFrameCommand, "\n");
2422                 NextFrameCommand = string_null;
2423         }
2424
2425         // we must do this check AFTER a frame was rendered, or it won't work
2426         if(cs_project_is_b0rked == 0)
2427         {
2428                 string w0, h0;
2429                 w0 = ftos(autocvar_vid_conwidth);
2430                 h0 = ftos(autocvar_vid_conheight);
2431                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2432                 //setproperty(VF_FOV, '90 90 0');
2433                 setproperty(VF_ORIGIN, '0 0 0');
2434                 setproperty(VF_ANGLES, '0 0 0');
2435                 setproperty(VF_PERSPECTIVE, 1);
2436                 makevectors('0 0 0');
2437                 vector v1, v2;
2438                 cvar_set("vid_conwidth", "800");
2439                 cvar_set("vid_conheight", "600");
2440                 v1 = cs_project(v_forward);
2441                 cvar_set("vid_conwidth", "640");
2442                 cvar_set("vid_conheight", "480");
2443                 v2 = cs_project(v_forward);
2444                 if(v1 == v2)
2445                         cs_project_is_b0rked = 1;
2446                 else
2447                         cs_project_is_b0rked = -1;
2448                 cvar_set("vid_conwidth", w0);
2449                 cvar_set("vid_conheight", h0);
2450         }
2451
2452         if(autocvar__hud_configure)
2453                 HUD_Panel_Mouse();
2454         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2455                 HUD_Minigame_Mouse();
2456         else if(QuickMenu_IsOpened())
2457                 QuickMenu_Mouse();
2458         else if(local_player.viewloc && (local_player.viewloc.spawnflags & VIEWLOC_FREEAIM))
2459                 ViewLocation_Mouse(); // NOTE: doesn't use cursormode
2460         else
2461                 HUD_Radar_Mouse();
2462
2463         cl_notice_run();
2464         unpause_update();
2465         Net_Flush();
2466
2467         // let's reset the view back to normal for the end
2468         setproperty(VF_MIN, '0 0 0');
2469         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2470
2471         IL_ENDFRAME();
2472 }
2473
2474
2475 // following vectors must be global to allow seamless switching between camera modes
2476 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2477 void CSQC_Demo_Camera()
2478 {
2479         float speed, attenuation, dimensions;
2480         vector tmp, delta;
2481
2482         if( autocvar_camera_reset || !camera_mode )
2483         {
2484                 camera_offset = '0 0 0';
2485                 current_angles = '0 0 0';
2486                 camera_direction = '0 0 0';
2487                 camera_offset.z += 30;
2488                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2489                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2490                 current_origin = view_origin;
2491                 current_camera_offset  = camera_offset;
2492                 cvar_set("camera_reset", "0");
2493                 camera_mode = CAMERA_CHASE;
2494         }
2495
2496         // Camera angles
2497         if( camera_roll )
2498                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2499
2500         if(autocvar_camera_look_player)
2501         {
2502                 vector dir;
2503                 float n;
2504
2505                 dir = normalize(view_origin - current_position);
2506                 n = mouse_angles.z;
2507                 mouse_angles = vectoangles(dir);
2508                 mouse_angles.x = mouse_angles.x * -1;
2509                 mouse_angles.z = n;
2510         }
2511         else
2512         {
2513                 tmp = getmousepos() * 0.1;
2514                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2515                 {
2516                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2517                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2518                 }
2519         }
2520
2521         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2522         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2523         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2524         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2525
2526         // Fix difference when angles don't have the same sign
2527         delta = '0 0 0';
2528         if(mouse_angles.y < -60 && current_angles.y > 60)
2529                 delta = '0 360 0';
2530         if(mouse_angles.y > 60 && current_angles.y < -60)
2531                 delta = '0 -360 0';
2532
2533         if(autocvar_camera_look_player)
2534                 attenuation = autocvar_camera_look_attenuation;
2535         else
2536                 attenuation = autocvar_camera_speed_attenuation;
2537
2538         attenuation = 1 / max(1, attenuation);
2539         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2540
2541         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2542         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2543         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2544         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2545
2546         // Camera position
2547         tmp = '0 0 0';
2548         dimensions = 0;
2549
2550         if( camera_direction.x )
2551         {
2552                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2553                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2554                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2555                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2556                 ++dimensions;
2557         }
2558
2559         if( camera_direction.y )
2560         {
2561                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2562                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2563                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2564                 ++dimensions;
2565         }
2566
2567         if( camera_direction.z )
2568         {
2569                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2570                 ++dimensions;
2571         }
2572
2573         if(autocvar_camera_free)
2574                 speed = autocvar_camera_speed_free;
2575         else
2576                 speed = autocvar_camera_speed_chase;
2577
2578         if(dimensions)
2579         {
2580                 speed = speed * sqrt(1 / dimensions);
2581                 camera_offset += tmp * speed;
2582         }
2583
2584         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2585
2586         // Camera modes
2587         if( autocvar_camera_free )
2588         {
2589                 if ( camera_mode == CAMERA_CHASE )
2590                 {
2591                         current_camera_offset = current_origin + current_camera_offset;
2592                         camera_offset = current_origin + camera_offset;
2593                 }
2594
2595                 camera_mode = CAMERA_FREE;
2596                 current_position = current_camera_offset;
2597         }
2598         else
2599         {
2600                 if ( camera_mode == CAMERA_FREE )
2601                 {
2602                         current_origin = view_origin;
2603                         camera_offset = camera_offset - current_origin;
2604                         current_camera_offset = current_camera_offset - current_origin;
2605                 }
2606
2607                 camera_mode = CAMERA_CHASE;
2608
2609                 if(autocvar_camera_chase_smoothly)
2610                         current_origin += (view_origin - current_origin) * attenuation;
2611                 else
2612                         current_origin = view_origin;
2613
2614                 current_position = current_origin + current_camera_offset;
2615         }
2616
2617         setproperty(VF_ANGLES, current_angles);
2618         setproperty(VF_ORIGIN, current_position);
2619 }