qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include "mutators/events.qh"
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/debug.qh>
  21 #include <common/mapinfo.qh>
  22 #include <common/gamemodes/_mod.qh>
  23 #include <common/physics/player.qh>
  24 #include <common/stats.qh>
  25 #include <common/triggers/target/music.qh>
  26 #include <common/teams.qh>
  27 #include <common/wepent.qh>
  28
  29 #include <common/weapons/weapon/tuba.qh>
  30
  31 #include <common/vehicles/all.qh>
  32 #include <common/weapons/_all.qh>
  33 #include <common/viewloc.qh>
  34 #include <common/triggers/trigger/viewloc.qh>
  35 #include <common/minigames/cl_minigames.qh>
  36 #include <common/minigames/cl_minigames_hud.qh>
  37
  38 #include <lib/csqcmodel/cl_player.qh>
  39 #include <lib/csqcmodel/cl_model.qh>
  40 #include "csqcmodel_hooks.qh"
  41
  42 #include <lib/warpzone/client.qh>
  43 #include <lib/warpzone/common.qh>
  44
  45 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  46
  47 float autocvar_cl_viewmodel_scale;
  48
  49 bool autocvar_cl_bobmodel;
  50 float autocvar_cl_bobmodel_speed;
  51 float autocvar_cl_bobmodel_side;
  52 float autocvar_cl_bobmodel_up;
  53
  54 float autocvar_cl_followmodel;
  55 float autocvar_cl_followmodel_speed = 0.3;
  56 float autocvar_cl_followmodel_limit = 135;
  57 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  58 float autocvar_cl_followmodel_highpass = 0.05;
  59 float autocvar_cl_followmodel_lowpass = 0.03;
  60 bool autocvar_cl_followmodel_velocity_absolute;
  61
  62 float autocvar_cl_leanmodel;
  63 float autocvar_cl_leanmodel_speed = 0.3;
  64 float autocvar_cl_leanmodel_limit = 30;
  65 float autocvar_cl_leanmodel_highpass1 = 0.2;
  66 float autocvar_cl_leanmodel_highpass = 0.2;
  67 float autocvar_cl_leanmodel_lowpass = 0.05;
  68
  69 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  70
  71 #define lowpass(value, frac, ref_store, ret) \
  72         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  73
  74 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  75 { \
  76         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  77         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  78 } MACRO_END
  79
  80 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  81 { \
  82         float __f = 0; lowpass(value, frac, ref_store, __f); \
  83         ret = (value) - __f; \
  84 } MACRO_END
  85
  86 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  87 { \
  88         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  89         ret = (value) - __f; \
  90 } MACRO_END
  91
  92 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  93 { \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 } MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99 { \
 100         highpass(value.x, frac, ref_store.x, ref_out.x); \
 101         highpass(value.y, frac, ref_store.y, ref_out.y); \
 102 } MACRO_END
 103
 104 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 105 { \
 106         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 107         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 108 } MACRO_END
 109
 110 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 111 { \
 112         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 113         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 114         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 115 } MACRO_END
 116
 117 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 118 { \
 119         highpass(value.x, frac, ref_store.x, ref_out.x); \
 120         highpass(value.y, frac, ref_store.y, ref_out.y); \
 121         highpass(value.z, frac, ref_store.z, ref_out.z); \
 122 } MACRO_END
 123
 124 void calc_followmodel_ofs(entity view)
 125 {
 126         if(cl_followmodel_time == time)
 127                 return; // cl_followmodel_ofs already calculated for this frame
 128
 129         float frac;
 130         vector gunorg = '0 0 0';
 131         static vector vel_average;
 132         static vector gunorg_adjustment_highpass;
 133         static vector gunorg_adjustment_lowpass;
 134
 135         vector vel;
 136         if (autocvar_cl_followmodel_velocity_absolute)
 137                 vel = view.velocity;
 138         else
 139         {
 140                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 141                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 142                 vel.x = view.velocity * forward;
 143                 vel.y = view.velocity * right * -1;
 144                 vel.z = view.velocity * up;
 145         }
 146
 147         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 148         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 149         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 150
 151         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 152         lowpass3(vel, frac, vel_average, gunorg);
 153
 154         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 155
 156         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 157         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 158         frac = avg_factor(autocvar_cl_followmodel_highpass);
 159         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 160         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 161         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 162
 163         if (autocvar_cl_followmodel_velocity_absolute)
 164         {
 165                 vector fixed_gunorg;
 166                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 167                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 168                 fixed_gunorg.x = gunorg * forward;
 169                 fixed_gunorg.y = gunorg * right * -1;
 170                 fixed_gunorg.z = gunorg * up;
 171                 gunorg = fixed_gunorg;
 172         }
 173
 174         cl_followmodel_ofs = gunorg;
 175         cl_followmodel_time = time;
 176 }
 177
 178 vector leanmodel_ofs(entity view)
 179 {
 180         float frac;
 181         vector gunangles = '0 0 0';
 182         static vector gunangles_prev = '0 0 0';
 183         static vector gunangles_highpass = '0 0 0';
 184         static vector gunangles_adjustment_highpass;
 185         static vector gunangles_adjustment_lowpass;
 186
 187         if (view.csqcmodel_teleported)
 188                 gunangles_prev = view_angles;
 189
 190         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 191         gunangles_highpass += gunangles_prev;
 192         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 193         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 194         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 195         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 196         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 197         gunangles_prev = view_angles;
 198         gunangles_highpass -= gunangles_prev;
 199
 200         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 201         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 202
 203         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 204         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 205         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 206         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 207         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 208
 209         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 210
 211         return gunangles;
 212 }
 213
 214 vector bobmodel_ofs(entity view)
 215 {
 216         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 217         static bool oldonground;
 218         static float hitgroundtime;
 219         if (clonground)
 220         {
 221                 float f = time; // cl.movecmd[0].time
 222                 if (!oldonground)
 223                         hitgroundtime = f;
 224         }
 225         oldonground = clonground;
 226
 227         // calculate for swinging gun model
 228         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 229         vector gunorg = '0 0 0';
 230         static float bobmodel_scale = 0;
 231         static float time_ofs = 0; // makes the effect always restart in the same way
 232         if (clonground)
 233         {
 234                 if (time - hitgroundtime > 0.05)
 235                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 236         }
 237         else
 238                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 239
 240         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 241         if (bobmodel_scale && xyspeed)
 242         {
 243                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 244                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 245                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 246                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 247         }
 248         else
 249                 time_ofs = time;
 250
 251         return gunorg;
 252 }
 253
 254 void viewmodel_animate(entity this)
 255 {
 256         if (autocvar_chase_active) return;
 257         if (STAT(HEALTH) <= 0) return;
 258
 259         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 260
 261         if (autocvar_cl_followmodel)
 262         {
 263                 calc_followmodel_ofs(view);
 264                 this.origin += cl_followmodel_ofs;
 265         }
 266
 267         if (autocvar_cl_leanmodel)
 268                 this.angles += leanmodel_ofs(view);
 269
 270         // vertical view bobbing code
 271         // TODO: cl_bob
 272
 273         // horizontal view bobbing code
 274         // TODO: cl_bob2
 275
 276         // fall bobbing code
 277         // causes the view to swing down and back up when touching the ground
 278         // TODO: cl_bobfall
 279
 280         // gun model bobbing code
 281         if (autocvar_cl_bobmodel)
 282                 this.origin += bobmodel_ofs(view);
 283 }
 284
 285 .vector viewmodel_origin, viewmodel_angles;
 286 .float weapon_nextthink;
 287 .float weapon_eta_last;
 288 .float weapon_switchdelay;
 289
 290 .string name_last;
 291
 292 void viewmodel_draw(entity this)
 293 {
 294         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 295                 return;
 296         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 297         float a = this.alpha;
 298         static bool wasinvehicle;
 299         bool invehicle = player_localentnum > maxclients;
 300         if (invehicle) a = -1;
 301         else if (wasinvehicle) a = 1;
 302         wasinvehicle = invehicle;
 303         Weapon wep = this.activeweapon;
 304         int c = entcs_GetClientColors(current_player);
 305         vector g = weaponentity_glowmod(wep, NULL, c, this);
 306         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 307         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 308                 | EF_NODEPTHTEST)
 309                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 310         for (entity e = this; e; e = e.weaponchild)
 311         {
 312                 e.drawmask = mask;
 313                 e.alpha = a;
 314                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 315                 e.glowmod = g;
 316                 e.csqcmodel_effects = fx;
 317                 CSQCModel_Effects_Apply(e);
 318         }
 319         if(a >= 0)
 320         {
 321                 string name = wep.mdl;
 322                 string newname = wep.wr_viewmodel(wep, this);
 323                 if(newname)
 324                         name = newname;
 325                 bool swap = name != this.name_last;
 326                 // if (swap)
 327                 {
 328                         this.name_last = name;
 329                         CL_WeaponEntity_SetModel(this, name, swap);
 330                         this.viewmodel_origin = this.origin;
 331                         this.viewmodel_angles = this.angles;
 332                 }
 333                 anim_update(this);
 334                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 335                         anim_set(this, this.anim_idle, true, false, false);
 336         }
 337         float f = 0; // 0..1; 0: fully active
 338         float rate = STAT(WEAPONRATEFACTOR);
 339         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 340         if (eta <= 0) f = this.weapon_eta_last;
 341         else switch (this.state)
 342         {
 343                 case WS_RAISE:
 344                 {
 345                         f = eta / max(eta, this.weapon_switchdelay);
 346                         break;
 347                 }
 348                 case WS_DROP:
 349                 {
 350                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 351                         break;
 352                 }
 353                 case WS_CLEAR:
 354                 {
 355                         f = 1;
 356                         break;
 357                 }
 358         }
 359         this.weapon_eta_last = f;
 360         this.origin = this.viewmodel_origin;
 361         this.angles = this.viewmodel_angles;
 362         this.angles_x = (-90 * f * f);
 363         viewmodel_animate(this);
 364         MUTATOR_CALLHOOK(DrawViewModel, this);
 365         setorigin(this, this.origin);
 366 }
 367
 368 STATIC_INIT(viewmodel) {
 369     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 370         viewmodels[slot] = new(viewmodel);
 371 }
 372
 373 void Porto_Draw(entity this);
 374 STATIC_INIT(Porto)
 375 {
 376         entity e = new_pure(porto);
 377         e.draw = Porto_Draw;
 378         IL_PUSH(g_drawables, e);
 379         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 380 }
 381
 382 const int polyline_length = 16;
 383 .vector polyline[polyline_length];
 384 void Porto_Draw(entity this)
 385 {
 386         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 387         {
 388                 entity wepent = viewmodels[slot];
 389
 390                 if (wepent.activeweapon != WEP_PORTO) continue;
 391                 if (spectatee_status) continue;
 392                 if (WEP_CVAR(porto, secondary)) continue;
 393                 if (intermission == 1) continue;
 394                 if (intermission == 2) continue;
 395                 if (STAT(HEALTH) <= 0) continue;
 396
 397                 vector pos = view_origin;
 398                 vector dir = view_forward;
 399                 if (wepent.angles_held_status)
 400                 {
 401                         makevectors(wepent.angles_held);
 402                         dir = v_forward;
 403                 }
 404
 405                 wepent.polyline[0] = pos;
 406
 407                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 408                 int n = 1 + 2;  // 2 lines == 3 points
 409                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 410                 {
 411                         traceline(pos, pos + 65536 * dir, true, this);
 412                         dir = reflect(dir, trace_plane_normal);
 413                         pos = trace_endpos;
 414                         wepent.polyline[++idx] = pos;
 415                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 416                         {
 417                                 n += 1;
 418                                 continue;
 419                         }
 420                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 421                         {
 422                                 n = max(2, idx);
 423                                 break;
 424                         }
 425                         // check size
 426                         {
 427                                 vector ang = vectoangles2(trace_plane_normal, dir);
 428                                 ang.x = -ang.x;
 429                                 makevectors(ang);
 430                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 431                                 {
 432                                         n = max(2, idx);
 433                                         break;
 434                                 }
 435                         }
 436                         portal_number += 1;
 437                         if (portal_number >= portal_max) break;
 438                         if (portal_number == 1) portal1_idx = idx;
 439                 }
 440                 for (int idx = 0; idx < n - 1; ++idx)
 441                 {
 442                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 443                         if (idx == 0) p -= view_up * 16;  // line from player
 444                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 445                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 446                 }
 447         }
 448 }
 449
 450 float drawtime;
 451 float avgspeed;
 452 vector GetCurrentFov(float fov)
 453 {
 454         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 455         float velocityzoom, curspeed;
 456         vector v;
 457
 458         zoomsensitivity = autocvar_cl_zoomsensitivity;
 459         zoomfactor = autocvar_cl_zoomfactor;
 460         if(zoomfactor < 1 || zoomfactor > 30)
 461                 zoomfactor = 2.5;
 462         zoomspeed = autocvar_cl_zoomspeed;
 463         if(zoomspeed >= 0)
 464         if(zoomspeed < 0.5 || zoomspeed > 16)
 465                         zoomspeed = 3.5;
 466
 467         zoomdir = button_zoom;
 468
 469         if(hud == HUD_NORMAL && !spectatee_status)
 470         {
 471                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 472                 {
 473                         entity wepent = viewmodels[slot];
 474                         if(wepent.switchweapon == wepent.activeweapon)
 475                         if((wepent.activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (wepent.activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 476                                 zoomdir += button_attack2;
 477                 }
 478         }
 479         if(spectatee_status > 0 || isdemo())
 480         {
 481                 if(spectatorbutton_zoom)
 482                 {
 483                         if(zoomdir)
 484                                 zoomdir = 0;
 485                         else
 486                                 zoomdir = 1;
 487                 }
 488                 // fteqcc failed twice here already, don't optimize this
 489         }
 490
 491         if(zoomdir) { zoomin_effect = 0; }
 492
 493         if(camera_active)
 494         {
 495                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 496         }
 497         else if(autocvar_cl_spawnzoom && zoomin_effect)
 498         {
 499                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 500
 501                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 502                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 503                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 504         }
 505         else
 506         {
 507                 if(zoomspeed < 0) // instant zoom
 508                 {
 509                         if(zoomdir)
 510                                 current_viewzoom = 1 / zoomfactor;
 511                         else
 512                                 current_viewzoom = 1;
 513                 }
 514                 else
 515                 {
 516                         if(zoomdir)
 517                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 518                         else
 519                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 520                 }
 521         }
 522
 523         if(almost_equals(current_viewzoom, 1))
 524                 current_zoomfraction = 0;
 525         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 526                 current_zoomfraction = 1;
 527         else
 528                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 529
 530         if(zoomsensitivity < 1)
 531                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 532         else
 533                 setsensitivityscale(1);
 534
 535         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 536         {
 537                 if(intermission) { curspeed = 0; }
 538                 else
 539                 {
 540
 541                         makevectors(view_angles);
 542                         v = pmove_vel;
 543                         if(csqcplayer)
 544                                 v = csqcplayer.velocity;
 545
 546                         switch(autocvar_cl_velocityzoom_type)
 547                         {
 548                                 case 3: curspeed = max(0, v_forward * v); break;
 549                                 case 2: curspeed = (v_forward * v); break;
 550                                 case 1: default: curspeed = vlen(v); break;
 551                         }
 552                 }
 553
 554                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 555                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 556                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 557
 558                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 559         }
 560         else
 561                 velocityzoom = 1;
 562
 563         float frustumx, frustumy, fovx, fovy;
 564         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 565         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 566         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 567         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 568
 569         return '1 0 0' * fovx + '0 1 0' * fovy;
 570 }
 571
 572 vector GetViewLocationFOV(float fov)
 573 {
 574         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 575         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 576         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 577         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 578         return '1 0 0' * fovx + '0 1 0' * fovy;
 579 }
 580
 581 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 582 {
 583         float fovx, fovy;
 584         float width = (ov_worldmax.x - ov_worldmin.x);
 585         float height = (ov_worldmax.y - ov_worldmin.y);
 586         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 587         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 588         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 589         return '1 0 0' * fovx + '0 1 0' * fovy;
 590 }
 591
 592 // this function must match W_SetupShot!
 593 float zoomscript_caught;
 594
 595 vector wcross_origin;
 596 float wcross_scale_prev, wcross_alpha_prev;
 597 vector wcross_color_prev;
 598 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 599 vector wcross_color_goal_prev;
 600 float wcross_changedonetime;
 601
 602 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 603 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 604 float wcross_name_changestarttime, wcross_name_changedonetime;
 605 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 606
 607 float wcross_ring_prev;
 608
 609 entity trueaim;
 610 entity trueaim_rifle;
 611
 612 const float SHOTTYPE_HITTEAM = 1;
 613 const float SHOTTYPE_HITOBSTRUCTION = 2;
 614 const float SHOTTYPE_HITWORLD = 3;
 615 const float SHOTTYPE_HITENEMY = 4;
 616
 617 void TrueAim_Init()
 618 {
 619         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 620         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 621 }
 622
 623 float EnemyHitCheck()
 624 {
 625         float t, n;
 626         wcross_origin = project_3d_to_2d(trace_endpos);
 627         wcross_origin.z = 0;
 628         if(trace_ent)
 629                 n = trace_ent.entnum;
 630         else
 631                 n = trace_networkentity;
 632         if(n < 1)
 633                 return SHOTTYPE_HITWORLD;
 634         if(n > maxclients)
 635                 return SHOTTYPE_HITWORLD;
 636         t = entcs_GetTeam(n - 1);
 637         if(teamplay)
 638                 if(t == myteam)
 639                         return SHOTTYPE_HITTEAM;
 640         if(t == NUM_SPECTATOR)
 641                 return SHOTTYPE_HITWORLD;
 642         return SHOTTYPE_HITENEMY;
 643 }
 644
 645 float TrueAimCheck(entity wepent)
 646 {
 647         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 648         vector vecs, trueaimpoint, w_shotorg;
 649         vector mi, ma, dv;
 650         float shottype;
 651         entity ta;
 652         float mv;
 653
 654         mi = ma = '0 0 0';
 655         ta = trueaim;
 656         mv = MOVE_NOMONSTERS;
 657
 658         switch(wepent.activeweapon) // WEAPONTODO
 659         {
 660                 case WEP_TUBA: // no aim
 661                 case WEP_PORTO: // shoots from eye
 662                 case WEP_NEXBALL: // shoots from eye
 663                 case WEP_HOOK: // no trueaim
 664                 case WEP_MORTAR: // toss curve
 665                         return SHOTTYPE_HITWORLD;
 666                 case WEP_VORTEX:
 667                 case WEP_VAPORIZER:
 668                         mv = MOVE_NORMAL;
 669                         break;
 670                 case WEP_RIFLE:
 671                         ta = trueaim_rifle;
 672                         mv = MOVE_NORMAL;
 673                         if(zoomscript_caught)
 674                         {
 675                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 676                                 return EnemyHitCheck();
 677                         }
 678                         break;
 679                 case WEP_DEVASTATOR: // projectile has a size!
 680                         mi = '-3 -3 -3';
 681                         ma = '3 3 3';
 682                         break;
 683                 case WEP_FIREBALL: // projectile has a size!
 684                         mi = '-16 -16 -16';
 685                         ma = '16 16 16';
 686                         break;
 687                 case WEP_SEEKER: // projectile has a size!
 688                         mi = '-2 -2 -2';
 689                         ma = '2 2 2';
 690                         break;
 691                 case WEP_ELECTRO: // projectile has a size!
 692                         mi = '0 0 -3';
 693                         ma = '0 0 -3';
 694                         break;
 695         }
 696
 697         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 698
 699         vecs = decompressShotOrigin(STAT(SHOTORG));
 700
 701         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 702         trueaimpoint = trace_endpos;
 703
 704         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 705                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 706
 707         if(vecs.x > 0)
 708                 vecs.y = -vecs.y;
 709         else
 710                 vecs = '0 0 0';
 711
 712         dv = view_right * vecs.y + view_up * vecs.z;
 713         w_shotorg = traceorigin + dv;
 714
 715         // now move the vecs forward as much as requested if possible
 716         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 717         w_shotorg = trace_endpos - view_forward * nudge;
 718
 719         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 720         shottype = EnemyHitCheck();
 721         if(shottype != SHOTTYPE_HITWORLD)
 722                 return shottype;
 723
 724 #if 0
 725         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 726         // or rather, I know why, but see no fix
 727         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 728                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 729                 return SHOTTYPE_HITOBSTRUCTION;
 730 #endif
 731
 732         return SHOTTYPE_HITWORLD;
 733 }
 734
 735 void PostInit();
 736 void CSQC_Demo_Camera();
 737 float camera_mode;
 738 const float CAMERA_FREE = 1;
 739 const float CAMERA_CHASE = 2;
 740 float reticle_type;
 741 string NextFrameCommand;
 742
 743 vector freeze_org, freeze_ang;
 744 entity nightvision_noise, nightvision_noise2;
 745
 746 const float MAX_TIME_DIFF = 5;
 747 float pickup_crosshair_time, pickup_crosshair_size;
 748 float hitindication_crosshair_size;
 749 float use_vortex_chargepool;
 750
 751 float myhealth, myhealth_prev;
 752 float myhealth_flash;
 753
 754 float old_blurradius, old_bluralpha;
 755 float old_sharpen_intensity;
 756
 757 vector myhealth_gentlergb;
 758
 759 float contentavgalpha, liquidalpha_prev;
 760 vector liquidcolor_prev;
 761
 762 float eventchase_current_distance;
 763 float eventchase_running;
 764 bool WantEventchase(entity this)
 765 {
 766         if(autocvar_cl_orthoview)
 767                 return false;
 768         if(STAT(GAME_STOPPED) || intermission)
 769                 return true;
 770         if(this.viewloc)
 771                 return true;
 772         if(spectatee_status >= 0)
 773         {
 774                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 775                         return true;
 776                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 777                         return true;
 778                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 779                         return true;
 780                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 781                 {
 782                         if(autocvar_cl_eventchase_death == 2)
 783                         {
 784                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 785                                 if(this.velocity == '0 0 0' || eventchase_running)
 786                                         return true;
 787                         }
 788                         else return true;
 789                 }
 790         }
 791         return false;
 792 }
 793
 794 void HUD_Crosshair_Vehicle(entity this)
 795 {
 796         if(hud != HUD_BUMBLEBEE_GUN)
 797         {
 798                 Vehicle info = Vehicles_from(hud);
 799                 info.vr_crosshair(info, this);
 800         }
 801 }
 802
 803 vector damage_blurpostprocess, content_blurpostprocess;
 804
 805 float unaccounted_damage = 0;
 806 void UpdateDamage()
 807 {
 808         // accumulate damage with each stat update
 809         static float damage_total_prev = 0;
 810         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 811         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 812         damage_total_prev = damage_total;
 813
 814         static float damage_dealt_time_prev = 0;
 815         float damage_dealt_time = STAT(HIT_TIME);
 816         if (damage_dealt_time != damage_dealt_time_prev)
 817         {
 818                 unaccounted_damage += unaccounted_damage_new;
 819                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 820         }
 821         damage_dealt_time_prev = damage_dealt_time;
 822
 823         // prevent hitsound when switching spectatee
 824         static float spectatee_status_prev = 0;
 825         if (spectatee_status != spectatee_status_prev)
 826                 unaccounted_damage = 0;
 827         spectatee_status_prev = spectatee_status;
 828 }
 829
 830 void HitSound()
 831 {
 832         // varying sound pitch
 833
 834         bool have_arc = false;
 835         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 836         {
 837                 entity wepent = viewmodels[slot];
 838
 839                 if(wepent.activeweapon == WEP_ARC)
 840                         have_arc = true;
 841         }
 842
 843         static float hitsound_time_prev = 0;
 844         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 845         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 846         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 847         {
 848                 if (autocvar_cl_hitsound && unaccounted_damage)
 849                 {
 850                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 851                         float a = autocvar_cl_hitsound_max_pitch;
 852                         float b = autocvar_cl_hitsound_min_pitch;
 853                         float c = autocvar_cl_hitsound_nom_damage;
 854                         float d = unaccounted_damage;
 855                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 856
 857                         // if sound variation is disabled, set pitch_shift to 1
 858                         if (autocvar_cl_hitsound == 1)
 859                                 pitch_shift = 1;
 860
 861                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 862                         if (autocvar_cl_hitsound == 3)
 863                         {
 864                                 float mirror_value = (a-b)/2 + b;
 865                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 866                         }
 867
 868                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 869
 870                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 871                         // todo: normalize sound pressure levels? seems unnecessary
 872
 873                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 874                 }
 875                 unaccounted_damage = 0;
 876                 hitsound_time_prev = time;
 877         }
 878
 879         static float typehit_time_prev = 0;
 880         float typehit_time = STAT(TYPEHIT_TIME);
 881         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 882         {
 883                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 884                 typehit_time_prev = typehit_time;
 885         }
 886
 887         static float kill_time_prev = 0;
 888         float kill_time = STAT(KILL_TIME);
 889         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 890         {
 891                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 892                 kill_time_prev = kill_time;
 893         }
 894 }
 895
 896 vector crosshair_getcolor(entity this, float health_stat)
 897 {
 898         static float rainbow_last_flicker;
 899         static vector rainbow_prev_color;
 900         vector wcross_color = '0 0 0';
 901         switch(autocvar_crosshair_color_special)
 902         {
 903                 case 1: // crosshair_color_per_weapon
 904                 {
 905                         if(this != WEP_Null && hud == HUD_NORMAL)
 906                         {
 907                                 wcross_color = this.wpcolor;
 908                                 break;
 909                         }
 910                         else { goto normalcolor; }
 911                 }
 912
 913                 case 2: // crosshair_color_by_health
 914                 {
 915                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 916                         float hp = floor(v.x + 1);
 917
 918                         //x = red
 919                         //y = green
 920                         //z = blue
 921
 922                         wcross_color.z = 0;
 923
 924                         if(hp > 200)
 925                         {
 926                                 wcross_color.x = 0;
 927                                 wcross_color.y = 1;
 928                         }
 929                         else if(hp > 150)
 930                         {
 931                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 932                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 933                         }
 934                         else if(hp > 100)
 935                         {
 936                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 937                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 938                                 wcross_color.z = 1 - (hp-100)*0.02;
 939                         }
 940                         else if(hp > 50)
 941                         {
 942                                 wcross_color.x = 1;
 943                                 wcross_color.y = 1;
 944                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 945                         }
 946                         else if(hp > 20)
 947                         {
 948                                 wcross_color.x = 1;
 949                                 wcross_color.y = (hp-20)*90/27/100;
 950                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 951                         }
 952                         else
 953                         {
 954                                 wcross_color.x = 1;
 955                                 wcross_color.y = 0;
 956                         }
 957                         break;
 958                 }
 959
 960                 case 3: // crosshair_color_rainbow
 961                 {
 962                         if(time >= rainbow_last_flicker)
 963                         {
 964                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 965                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 966                         }
 967                         wcross_color = rainbow_prev_color;
 968                         break;
 969                 }
 970 LABEL(normalcolor)
 971                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 972         }
 973
 974         return wcross_color;
 975 }
 976
 977 void HUD_Crosshair(entity this)
 978 {
 979         float f, i, j;
 980         vector v;
 981         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 982                 spectatee_status != -1 && !csqcplayer.viewloc && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 983                 !HUD_MinigameMenu_IsOpened() )
 984         {
 985                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 986                         return;
 987
 988                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 989                         return;
 990
 991                 if (hud != HUD_NORMAL)
 992                 {
 993                         HUD_Crosshair_Vehicle(this);
 994                         return;
 995                 }
 996
 997                 string wcross_style;
 998                 float wcross_alpha, wcross_resolution;
 999                 wcross_style = autocvar_crosshair;
1000                 if (wcross_style == "0")
1001                         return;
1002                 wcross_resolution = autocvar_crosshair_size;
1003                 if (wcross_resolution == 0)
1004                         return;
1005                 wcross_alpha = autocvar_crosshair_alpha;
1006                 if (wcross_alpha == 0)
1007                         return;
1008
1009                 // TrueAim check
1010                 float shottype;
1011
1012                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1013                 wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1014                 wcross_origin.z = 0;
1015                 if(autocvar_crosshair_hittest)
1016                 {
1017                         vector wcross_oldorigin;
1018                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1019                         wcross_oldorigin = wcross_origin;
1020                         shottype = TrueAimCheck(thiswep);
1021                         if(shottype == SHOTTYPE_HITWORLD)
1022                         {
1023                                 v = wcross_origin - wcross_oldorigin;
1024                                 v.x /= vid_conwidth;
1025                                 v.y /= vid_conheight;
1026                                 if(vdist(v, >, 0.01))
1027                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1028                         }
1029                         if(!autocvar_crosshair_hittest_showimpact)
1030                                 wcross_origin = wcross_oldorigin;
1031                 }
1032                 else
1033                         shottype = SHOTTYPE_HITWORLD;
1034
1035                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1036                 string wcross_name = "";
1037                 float wcross_scale, wcross_blur;
1038
1039         entity e = WEP_Null;
1040                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1041                 {
1042                         entity wepent = viewmodels[0]; // TODO: unhardcode
1043                         e = wepent.switchingweapon;
1044                         if(e)
1045                         {
1046                                 if(autocvar_crosshair_per_weapon)
1047                                 {
1048                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1049                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1050                                         //if (wcross_resolution == 0)
1051                                                 //return;
1052
1053                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1054                                         wcross_resolution *= e.w_crosshair_size;
1055                                         wcross_name = e.w_crosshair;
1056                                 }
1057                         }
1058                 }
1059
1060                 if(wcross_name == "")
1061                         wcross_name = strcat("gfx/crosshair", wcross_style);
1062
1063                 // MAIN CROSSHAIR COLOR DECISION
1064                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1065
1066                 if(autocvar_crosshair_effect_scalefade)
1067                 {
1068                         wcross_scale = wcross_resolution;
1069                         wcross_resolution = 1;
1070                 }
1071                 else
1072                 {
1073                         wcross_scale = 1;
1074                 }
1075
1076                 if(autocvar_crosshair_pickup)
1077                 {
1078                         float stat_pickup_time = STAT(LAST_PICKUP);
1079
1080                         if(pickup_crosshair_time < stat_pickup_time)
1081                         {
1082                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1083                                         pickup_crosshair_size = 1;
1084
1085                                 pickup_crosshair_time = stat_pickup_time;
1086                         }
1087
1088                         if(pickup_crosshair_size > 0)
1089                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1090                         else
1091                                 pickup_crosshair_size = 0;
1092
1093                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1094                 }
1095
1096                 // todo: make crosshair hit indication dependent on damage dealt
1097                 if(autocvar_crosshair_hitindication)
1098                 {
1099                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1100
1101                         if(unaccounted_damage)
1102                         {
1103                                 hitindication_crosshair_size = 1;
1104                         }
1105
1106                         if(hitindication_crosshair_size > 0)
1107                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1108                         else
1109                                 hitindication_crosshair_size = 0;
1110
1111                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1112                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1113                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1114                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1115                 }
1116
1117                 if(shottype == SHOTTYPE_HITENEMY)
1118                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1119                 if(shottype == SHOTTYPE_HITTEAM)
1120                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1121
1122                 f = fabs(autocvar_crosshair_effect_time);
1123                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1124                 {
1125                         wcross_changedonetime = time + f;
1126                 }
1127                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1128                 {
1129                         wcross_name_changestarttime = time;
1130                         wcross_name_changedonetime = time + f;
1131                         if(wcross_name_goal_prev_prev)
1132                                 strunzone(wcross_name_goal_prev_prev);
1133                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1134                         wcross_name_goal_prev = strzone(wcross_name);
1135                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1136                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1137                         wcross_resolution_goal_prev = wcross_resolution;
1138                 }
1139
1140                 wcross_scale_goal_prev = wcross_scale;
1141                 wcross_alpha_goal_prev = wcross_alpha;
1142                 wcross_color_goal_prev = wcross_color;
1143
1144                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1145                 {
1146                         wcross_blur = 1;
1147                         wcross_alpha *= 0.75;
1148                 }
1149                 else
1150                         wcross_blur = 0;
1151                 // *_prev is at time-frametime
1152                 // * is at wcross_changedonetime+f
1153                 // what do we have at time?
1154                 if(time < wcross_changedonetime)
1155                 {
1156                         f = frametime / (wcross_changedonetime - time + frametime);
1157                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1158                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1159                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1160                 }
1161
1162                 wcross_scale_prev = wcross_scale;
1163                 wcross_alpha_prev = wcross_alpha;
1164                 wcross_color_prev = wcross_color;
1165
1166                 MUTATOR_CALLHOOK(UpdateCrosshair);
1167
1168                 wcross_scale *= 1 - autocvar__menu_alpha;
1169                 wcross_alpha *= 1 - autocvar__menu_alpha;
1170                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1171
1172                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1173                 {
1174                         // crosshair rings for weapon stats
1175                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1176                         {
1177                                 // declarations and stats
1178                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1179                                 string ring_image = string_null, ring_inner_image = string_null;
1180                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1181
1182                                 ring_scale = autocvar_crosshair_ring_size;
1183
1184                                 float weapon_clipload, weapon_clipsize;
1185                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1186                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1187
1188                                 float vortex_charge, vortex_chargepool;
1189                                 vortex_charge = STAT(VORTEX_CHARGE);
1190                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1191
1192                                 float arc_heat = STAT(ARC_HEAT);
1193
1194                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1195                                         vortex_charge_movingavg = vortex_charge;
1196
1197                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1198
1199                                 // handle the values
1200                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1201                                 {
1202                                         if (vortex_chargepool || use_vortex_chargepool) {
1203                                                 use_vortex_chargepool = 1;
1204                                                 ring_inner_value = vortex_chargepool;
1205                                         } else {
1206                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1207                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1208                                         }
1209
1210                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1211                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1212                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1213
1214                                         // draw the outer ring to show the current charge of the weapon
1215                                         ring_value = vortex_charge;
1216                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1217                                         ring_rgb = wcross_color;
1218                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1219                                 }
1220                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1221                                 {
1222                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1223                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1224                                         ring_rgb = wcross_color;
1225                                         ring_image = "gfx/crosshair_ring.tga";
1226                                 }
1227                                 else if (wepent.activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1228                                 {
1229                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1230                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1231                                         ring_rgb = wcross_color;
1232                                         ring_image = "gfx/crosshair_ring.tga";
1233                                 }
1234                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1235                                 {
1236                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1237                                         ring_scale = autocvar_crosshair_ring_reload_size;
1238                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1239                                         ring_rgb = wcross_color;
1240
1241                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1242                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1243                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1244                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1245                                         else
1246                                                 ring_image = "gfx/crosshair_ring.tga";
1247                                 }
1248                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1249                                 {
1250                                         ring_value = arc_heat;
1251                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1252                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1253                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1254                                         ring_image = "gfx/crosshair_ring.tga";
1255                                 }
1256
1257                                 // if in weapon switch animation, fade ring out/in
1258                                 if(autocvar_crosshair_effect_time > 0)
1259                                 {
1260                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1261                                         if (f >= 1)
1262                                         {
1263                                                 wcross_ring_prev = ((ring_image) ? true : false);
1264                                         }
1265
1266                                         if(wcross_ring_prev)
1267                                         {
1268                                                 if(f < 1)
1269                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1270                                         }
1271                                         else
1272                                         {
1273                                                 if(f < 1)
1274                                                         ring_alpha *= bound(0, f, 1);
1275                                         }
1276                                 }
1277
1278                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1279                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1280
1281                                 if (ring_value)
1282                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1283                         }
1284
1285 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1286                         MACRO_BEGIN { \
1287                                 if(wcross_blur > 0) \
1288                                 { \
1289                                         for(i = -2; i <= 2; ++i) \
1290                                         for(j = -2; j <= 2; ++j) \
1291                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1292                                 } \
1293                                 else \
1294                                 { \
1295                                         M(0,0,sz,wcross_name,wcross_alpha); \
1296                                 } \
1297                         } MACRO_END
1298
1299 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1300                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1301
1302 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1303                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1304
1305                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1306                         {
1307                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1308                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1309                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1310                                 f = 1 - f;
1311                         }
1312                         else
1313                         {
1314                                 f = 1;
1315                         }
1316                         wcross_name_alpha_goal_prev = f;
1317
1318                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1319                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1320
1321                         if(autocvar_crosshair_dot)
1322                         {
1323                                 vector wcross_color_old;
1324                                 wcross_color_old = wcross_color;
1325
1326                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1327                                         wcross_color = stov(autocvar_crosshair_dot_color);
1328
1329                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1330                                 // FIXME why don't we use wcross_alpha here?
1331                                 wcross_color = wcross_color_old;
1332                         }
1333                 }
1334         }
1335         else
1336         {
1337                 wcross_scale_prev = 0;
1338                 wcross_alpha_prev = 0;
1339                 wcross_scale_goal_prev = 0;
1340                 wcross_alpha_goal_prev = 0;
1341                 wcross_changedonetime = 0;
1342                 if(wcross_name_goal_prev)
1343                         strunzone(wcross_name_goal_prev);
1344                 wcross_name_goal_prev = string_null;
1345                 if(wcross_name_goal_prev_prev)
1346                         strunzone(wcross_name_goal_prev_prev);
1347                 wcross_name_goal_prev_prev = string_null;
1348                 wcross_name_changestarttime = 0;
1349                 wcross_name_changedonetime = 0;
1350                 wcross_name_alpha_goal_prev = 0;
1351                 wcross_name_alpha_goal_prev_prev = 0;
1352                 wcross_resolution_goal_prev = 0;
1353                 wcross_resolution_goal_prev_prev = 0;
1354         }
1355 }
1356
1357 const int MAX_SPECIALCOMMAND = 15;
1358 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1359 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1360 const float SPECIALCOMMAND_SPEED = 150;
1361 const float SPECIALCOMMAND_TURNSPEED = 2;
1362 const float SPECIALCOMMAND_SIZE = 0.025;
1363 const float SPECIALCOMMAND_CHANCE = 0.35;
1364 float sc_spawntime, sc_changetime;
1365 vector sc_color = '1 1 1';
1366 void SpecialCommand()
1367 {
1368         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1369                 return;
1370
1371         if(time >= sc_changetime)
1372         {
1373                 sc_changetime = time + 1;
1374                 sc_color = randomvec() * 1.5;
1375                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1376                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1377                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1378         }
1379         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1380
1381         if(!precache_pic("gfx/smile"))
1382                 return; // damn party poopers
1383
1384         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1385         {
1386                 vector slot = specialcommand_slots[j];
1387                 if(slot.y)
1388                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1389                 if(slot.z)
1390                         slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1391                 if(slot.y >= vid_conheight)
1392                         slot = '0 0 0';
1393
1394                 if(slot == '0 0 0')
1395                 {
1396                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1397                         {
1398                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1399                                 slot.y = 1; // start it off 0 so we can use it
1400                                 slot.z = random();
1401                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1402                                 vector newcolor = randomvec() * 2;
1403                                 newcolor.x = bound(0.4, newcolor.x, 1);
1404                                 newcolor.y = bound(0.4, newcolor.y, 1);
1405                                 newcolor.z = bound(0.4, newcolor.z, 1);
1406                                 specialcommand_colors[j] = newcolor;
1407                         }
1408                 }
1409                 else
1410                 {
1411                         vector splash_size = '0 0 0';
1412                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1413                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1414                         drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1415                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1416                 }
1417
1418                 specialcommand_slots[j] = slot;
1419         }
1420 }
1421
1422 void HUD_Draw(entity this)
1423 {
1424         // if we don't know gametype and scores yet avoid drawing the scoreboard
1425         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1426         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1427         // cl_deathscoreboard would show the scoreboard and so on
1428         if(!gametype)
1429                 return;
1430
1431         Hud_Dynamic_Frame();
1432
1433         if(!intermission)
1434         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1435         {
1436                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1437         }
1438         else if(STAT(FROZEN))
1439         {
1440                 vector col = '0.25 0.90 1';
1441                 if(STAT(REVIVE_PROGRESS))
1442                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1443                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1444         }
1445
1446         HUD_Scale_Enable();
1447         if(!intermission)
1448         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1449         {
1450                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1451                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1452                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1453         }
1454         else if(STAT(CAPTURE_PROGRESS))
1455         {
1456                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1457                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1458         }
1459         else if(STAT(REVIVE_PROGRESS))
1460         {
1461                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1462                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1463         }
1464         HUD_Scale_Disable();
1465
1466         if(autocvar_r_letterbox == 0)
1467                 if(autocvar_viewsize < 120)
1468                 {
1469                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1470                                 Accuracy_LoadLevels();
1471
1472                         HUD_Main();
1473                         HUD_Scale_Disable();
1474                 }
1475
1476         // crosshair goes VERY LAST
1477         SpecialCommand();
1478         UpdateDamage();
1479         HUD_Crosshair(this);
1480         HitSound();
1481 }
1482
1483 void ViewLocation_Mouse()
1484 {
1485         if(spectatee_status)
1486                 return; // don't draw it as spectator!
1487
1488         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1489         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1490         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1491
1492         float cursor_alpha = 1 - autocvar__menu_alpha;
1493         draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1494 }
1495
1496 bool ov_enabled;
1497 float oldr_nearclip;
1498 float oldr_farclip_base;
1499 float oldr_farclip_world;
1500 float oldr_novis;
1501 float oldr_useportalculling;
1502 float oldr_useinfinitefarclip;
1503
1504 void cl_notice_run();
1505
1506 float prev_myteam;
1507 int lasthud;
1508 float vh_notice_time;
1509 void WaypointSprite_Load();
1510 void CSQC_UpdateView(entity this, float w, float h)
1511 {
1512     TC(int, w); TC(int, h);
1513         entity e;
1514         float fov;
1515         float f;
1516         vector vf_size, vf_min;
1517         float a;
1518
1519         execute_next_frame();
1520
1521         ++framecount;
1522
1523         stats_get();
1524         hud = STAT(HUD);
1525
1526         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1527                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1528
1529         lasthud = hud;
1530
1531         HUD_Scale_Disable();
1532
1533         if(autocvar__hud_showbinds_reload) // menu can set this one
1534         {
1535                 db_close(binddb);
1536                 binddb = db_create();
1537                 cvar_set("_hud_showbinds_reload", "0");
1538         }
1539
1540         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1541                 view_quality = getproperty(VF_MINFPS_QUALITY);
1542         else
1543                 view_quality = 1;
1544
1545         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1546         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1547
1548         vf_size = getpropertyvec(VF_SIZE);
1549         vf_min = getpropertyvec(VF_MIN);
1550         vid_width = vf_size.x;
1551         vid_height = vf_size.y;
1552
1553         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1554         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1555
1556         WaypointSprite_Load();
1557
1558         CSQCPlayer_SetCamera();
1559
1560         if(player_localentnum <= maxclients) // is it a client?
1561                 current_player = player_localentnum - 1;
1562         else // then player_localentnum is the vehicle I'm driving
1563                 current_player = player_localnum;
1564         myteam = entcs_GetTeam(current_player);
1565
1566         if(myteam != prev_myteam)
1567         {
1568                 myteamcolors = colormapPaletteColor(myteam, 1);
1569                 FOREACH(hud_panels, true, it.update_time = time);
1570                 prev_myteam = myteam;
1571         }
1572
1573         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1574
1575         float is_dead = (STAT(HEALTH) <= 0);
1576
1577         // FIXME do we need this hack?
1578         if(isdemo())
1579         {
1580                 // in demos, input_buttons do not work
1581                 button_zoom = (autocvar__togglezoom == "-");
1582         }
1583         else if(button_zoom
1584                 && autocvar_cl_unpress_zoom_on_death
1585                 && (spectatee_status >= 0)
1586                 && (is_dead || intermission))
1587         {
1588                 // no zoom while dead or in intermission please
1589                 localcmd("-zoom\n");
1590                 button_zoom = false;
1591         }
1592
1593         // abused multiple places below
1594         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1595         if(!local_player)
1596                 local_player = this; // fall back!
1597
1598         // event chase camera
1599         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1600         {
1601                 if(STAT(CAMERA_SPECTATOR))
1602                 {
1603                         if(spectatee_status > 0)
1604                         {
1605                                 if(!autocvar_chase_active)
1606                                 {
1607                                         cvar_set("chase_active", "-2");
1608                                         goto skip_eventchase_death;
1609                                 }
1610                         }
1611                         else if(autocvar_chase_active == -2)
1612                                 cvar_set("chase_active", "0");
1613
1614                         if(autocvar_chase_active == -2)
1615                                 goto skip_eventchase_death;
1616                 }
1617                 else if(autocvar_chase_active == -2)
1618                         cvar_set("chase_active", "0");
1619
1620                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1621
1622                 float vehicle_viewdist = 0;
1623                 vector vehicle_viewofs = '0 0 0';
1624
1625                 if(vehicle_chase)
1626                 {
1627                         if(hud != HUD_BUMBLEBEE_GUN)
1628                         {
1629                                 Vehicle info = Vehicles_from(hud);
1630                                 vehicle_viewdist = info.height;
1631                                 vehicle_viewofs = info.view_ofs;
1632                         }
1633                 }
1634
1635                 if(WantEventchase(this))
1636                 {
1637                         vector current_view_origin_override = '0 0 0';
1638                         vector view_offset_override = '0 0 0';
1639                         float chase_distance_override = 0;
1640                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1641                         if(custom_eventchase)
1642                         {
1643                                 current_view_origin_override = M_ARGV(0, vector);
1644                                 view_offset_override = M_ARGV(1, vector);
1645                                 chase_distance_override = M_ARGV(0, float);
1646                         }
1647                         eventchase_running = true;
1648
1649                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1650                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1651                         if (custom_eventchase)
1652                                 current_view_origin = current_view_origin_override;
1653
1654                         // detect maximum viewoffset and use it
1655                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1656                         if(vehicle_chase)
1657                         {
1658                                 if(vehicle_viewofs)
1659                                         view_offset = vehicle_viewofs;
1660                                 else
1661                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1662                         }
1663                         if (custom_eventchase)
1664                                 view_offset = view_offset_override;
1665
1666                         if(view_offset)
1667                         {
1668                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1669                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1670                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1671                         }
1672
1673                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1674                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1675                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1676                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1677
1678                         // make the camera smooth back
1679                         float chase_distance = autocvar_cl_eventchase_distance;
1680                         if(vehicle_chase)
1681                         {
1682                                 if(vehicle_viewofs)
1683                                         chase_distance = vehicle_viewdist;
1684                                 else
1685                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1686                         }
1687                         if (custom_eventchase)
1688                                 chase_distance = chase_distance_override;
1689
1690                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1691                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1692                         else if(eventchase_current_distance != chase_distance)
1693                                 eventchase_current_distance = chase_distance;
1694
1695                         makevectors(view_angles);
1696
1697                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1698                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1699
1700                         // If the boxtrace fails, revert back to line tracing.
1701                         if(!local_player.viewloc)
1702                         if(trace_startsolid)
1703                         {
1704                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1705                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1706                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1707                         }
1708                         else { setproperty(VF_ORIGIN, trace_endpos); }
1709
1710                         if(!local_player.viewloc)
1711                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1712                 }
1713                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1714                 {
1715                         eventchase_running = false;
1716                         cvar_set("chase_active", "0");
1717                         eventchase_current_distance = 0; // start from 0 next time
1718                 }
1719         }
1720         // workaround for camera stuck between player's legs when using chase_active 1
1721         // because the engine stops updating the chase_active camera when the game ends
1722         else if(intermission)
1723         {
1724                 cvar_settemp("chase_active", "-1");
1725                 eventchase_current_distance = 0;
1726         }
1727
1728         LABEL(skip_eventchase_death);
1729
1730         // do lockview after event chase camera so that it still applies whenever necessary.
1731         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1732         {
1733                 setproperty(VF_ORIGIN, freeze_org);
1734                 setproperty(VF_ANGLES, freeze_ang);
1735         }
1736         else
1737         {
1738                 freeze_org = getpropertyvec(VF_ORIGIN);
1739                 freeze_ang = getpropertyvec(VF_ANGLES);
1740         }
1741
1742         WarpZone_FixView();
1743         //WarpZone_FixPMove();
1744
1745         vector ov_org = '0 0 0';
1746         vector ov_mid = '0 0 0';
1747         vector ov_worldmin = '0 0 0';
1748         vector ov_worldmax = '0 0 0';
1749         if(autocvar_cl_orthoview)
1750         {
1751                 ov_worldmin = mi_picmin;
1752                 ov_worldmax = mi_picmax;
1753
1754                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1755                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1756                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1757
1758                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1759                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1760
1761                 float ov_nearest = vlen(ov_org - vec3(
1762                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1763                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1764                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1765                 ));
1766
1767                 float ov_furthest = 0;
1768                 float dist = 0;
1769
1770                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1771                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1772                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1773                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1774                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1775                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1776                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1777                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1778
1779                 if(!ov_enabled)
1780                 {
1781                         oldr_nearclip = cvar("r_nearclip");
1782                         oldr_farclip_base = cvar("r_farclip_base");
1783                         oldr_farclip_world = cvar("r_farclip_world");
1784                         oldr_novis = cvar("r_novis");
1785                         oldr_useportalculling = cvar("r_useportalculling");
1786                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1787                 }
1788
1789                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1790                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1791                 cvar_settemp("r_farclip_world", "0");
1792                 cvar_settemp("r_novis", "1");
1793                 cvar_settemp("r_useportalculling", "0");
1794                 cvar_settemp("r_useinfinitefarclip", "0");
1795
1796                 setproperty(VF_ORIGIN, ov_org);
1797                 setproperty(VF_ANGLES, '90 0 0');
1798
1799                 ov_enabled = true;
1800
1801                 #if 0
1802                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1803                         vtos(ov_org),
1804                         vtos(getpropertyvec(VF_ANGLES)),
1805                         ov_distance,
1806                         ov_nearest,
1807                         ov_furthest);
1808                 #endif
1809         }
1810         else
1811         {
1812                 if(ov_enabled)
1813                 {
1814                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1815                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1816                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1817                         cvar_set("r_novis", ftos(oldr_novis));
1818                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1819                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1820                 }
1821                 ov_enabled = false;
1822         }
1823
1824         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1825         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1826         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1827                 viewmodel_draw(viewmodels[slot]);
1828
1829         // Render the Scene
1830         view_origin = getpropertyvec(VF_ORIGIN);
1831         view_angles = getpropertyvec(VF_ANGLES);
1832         makevectors(view_angles);
1833         view_forward = v_forward;
1834         view_right = v_right;
1835         view_up = v_up;
1836
1837 #ifdef BLURTEST
1838         if(time > blurtest_time0 && time < blurtest_time1)
1839         {
1840                 float r, t;
1841
1842                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1843                 r = t * blurtest_radius;
1844                 f = 1 / (t ** blurtest_power) - 1;
1845
1846                 cvar_set("r_glsl_postprocess", "1");
1847                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1848         }
1849         else
1850         {
1851                 cvar_set("r_glsl_postprocess", "0");
1852                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1853         }
1854 #endif
1855
1856         TargetMusic_Advance();
1857         Fog_Force();
1858
1859         if(drawtime == 0)
1860                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1861         else
1862                 drawframetime = bound(0.000001, time - drawtime, 1);
1863         drawtime = time;
1864
1865         // watch for gametype changes here...
1866         // in ParseStuffCMD the cmd isn't executed yet :/
1867         // might even be better to add the gametype to TE_CSQC_INIT...?
1868         if(!postinit)
1869                 PostInit();
1870
1871         if(intermission && !intermission_time)
1872                 intermission_time = time;
1873
1874         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1875         {
1876                 if(calledhooks & HOOK_START)
1877                 {
1878                         localcmd("\ncl_hook_gameend\n");
1879                         calledhooks |= HOOK_END;
1880                 }
1881         }
1882
1883         Announcer();
1884
1885         fov = autocvar_fov;
1886         if(fov <= 59.5)
1887         {
1888                 if(!zoomscript_caught)
1889                 {
1890                         localcmd("+button9\n");
1891                         zoomscript_caught = 1;
1892                 }
1893         }
1894         else
1895         {
1896                 if(zoomscript_caught)
1897                 {
1898                         localcmd("-button9\n");
1899                         zoomscript_caught = 0;
1900                 }
1901         }
1902
1903         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1904
1905         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1906         {
1907                 entity wepent = viewmodels[slot];
1908
1909                 if(wepent.last_switchweapon != wepent.switchweapon)
1910                 {
1911                         weapontime = time;
1912                         wepent.last_switchweapon = wepent.switchweapon;
1913                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1914                         {
1915                                 localcmd("-zoom\n");
1916                                 button_zoom = false;
1917                         }
1918                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1919                         {
1920                                 localcmd("-fire\n");
1921                                 localcmd("-fire2\n");
1922                                 button_attack2 = false;
1923                         }
1924                 }
1925                 if(wepent.last_activeweapon != wepent.activeweapon)
1926                 {
1927                         wepent.last_activeweapon = wepent.activeweapon;
1928
1929                         e = wepent.activeweapon;
1930                         if(e.netname != "")
1931                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1932                         else if(slot == 0)
1933                                 localcmd("\ncl_hook_activeweapon none\n");
1934                 }
1935         }
1936
1937         // ALWAYS Clear Current Scene First
1938         clearscene();
1939
1940         setproperty(VF_ORIGIN, view_origin);
1941         setproperty(VF_ANGLES, view_angles);
1942
1943         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1944         setproperty(VF_SIZE, vf_size);
1945         setproperty(VF_MIN, vf_min);
1946
1947         // Assign Standard Viewflags
1948         // Draw the World (and sky)
1949         setproperty(VF_DRAWWORLD, 1);
1950
1951         // Set the console size vars
1952         vid_conwidth = autocvar_vid_conwidth;
1953         vid_conheight = autocvar_vid_conheight;
1954         vid_pixelheight = autocvar_vid_pixelheight;
1955
1956         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1957         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1958         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1959
1960         if(camera_active) // Camera for demo playback
1961         {
1962                 if(autocvar_camera_enable)
1963                         CSQC_Demo_Camera();
1964                 else
1965                 {
1966                         cvar_set("chase_active", ftos(chase_active_backup));
1967                         cvar_set("cl_demo_mousegrab", "0");
1968                         camera_active = false;
1969                 }
1970         }
1971         else
1972         {
1973 #ifdef CAMERATEST
1974                 if(autocvar_camera_enable)
1975 #else
1976                 if(autocvar_camera_enable && isdemo())
1977 #endif
1978                 {
1979                         // Enable required Darkplaces cvars
1980                         chase_active_backup = autocvar_chase_active;
1981                         cvar_set("chase_active", "2");
1982                         cvar_set("cl_demo_mousegrab", "1");
1983                         camera_active = true;
1984                         camera_mode = false;
1985                 }
1986         }
1987
1988         // Draw the Crosshair
1989         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1990
1991         // Draw the Engine Status Bar (the default Quake HUD)
1992         setproperty(VF_DRAWENGINESBAR, 0);
1993
1994         // Update the mouse position
1995         /*
1996            mousepos_x = vid_conwidth;
1997            mousepos_y = vid_conheight;
1998            mousepos = mousepos*0.5 + getmousepos();
1999          */
2000
2001         IL_EACH(g_drawables, it.draw, it.draw(it));
2002
2003         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
2004         renderscene();
2005
2006         // now switch to 2D drawing mode by calling a 2D drawing function
2007         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2008         // next R_RenderScene call
2009         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2010
2011         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2012         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2013         {
2014                 // apply night vision effect
2015                 vector tc_00, tc_01, tc_10, tc_11;
2016                 vector rgb = '0 0 0';
2017
2018                 if(!nightvision_noise)
2019                 {
2020                         nightvision_noise = new(nightvision_noise);
2021                 }
2022                 if(!nightvision_noise2)
2023                 {
2024                         nightvision_noise2 = new(nightvision_noise2);
2025                 }
2026
2027                 // color tint in yellow
2028                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2029
2030                 // draw BG
2031                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2032                 rgb = '1 1 1';
2033                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2034                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2035                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2036                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2037                 tc_11 = tc_01 + tc_10 - tc_00;
2038                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2039                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2040                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2041                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2042                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2043                 R_EndPolygon();
2044
2045                 // draw FG
2046                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2047                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2048                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2049                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2050                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2051                 tc_11 = tc_01 + tc_10 - tc_00;
2052                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2053                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2054                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2055                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2056                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2057                 R_EndPolygon();
2058         }
2059
2060         if(autocvar_cl_reticle)
2061         {
2062                 string reticle_image = string_null;
2063                 bool wep_zoomed = false;
2064                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2065                 {
2066                         entity wepe = viewmodels[slot];
2067                         Weapon wep = wepe.activeweapon;
2068                         if(wep != WEP_Null && wep.wr_zoom)
2069                         {
2070                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2071                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2072                                         reticle_image = wep.w_reticle;
2073                                 wep_zoomed += do_zoom;
2074                         }
2075                 }
2076                 // Draw the aiming reticle for weapons that use it
2077                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2078                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2079                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2080                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2081                 {
2082                         // no zoom reticle while dead
2083                         reticle_type = 0;
2084                 }
2085                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2086                 {
2087                         if(reticle_image) { reticle_type = 2; }
2088                         else { reticle_type = 0; }
2089                 }
2090                 else if(button_zoom || zoomscript_caught)
2091                 {
2092                         // normal zoom
2093                         reticle_type = 1;
2094                 }
2095
2096                 if(reticle_type)
2097                 {
2098                         if(autocvar_cl_reticle_stretch)
2099                         {
2100                                 reticle_size.x = vid_conwidth;
2101                                 reticle_size.y = vid_conheight;
2102                                 reticle_pos.x = 0;
2103                                 reticle_pos.y = 0;
2104                         }
2105                         else
2106                         {
2107                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2108                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2109                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2110                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2111                         }
2112
2113                         if(zoomscript_caught)
2114                                 f = 1;
2115                         else
2116                                 f = current_zoomfraction;
2117
2118                         if(f)
2119                         {
2120                                 switch(reticle_type)
2121                                 {
2122                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2123                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2124                                 }
2125                         }
2126                 }
2127         }
2128         else
2129         {
2130                 if(reticle_type != 0) { reticle_type = 0; }
2131         }
2132
2133
2134         // improved polyblend
2135         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2136         {
2137                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2138                 vector liquidcolor;
2139
2140                 switch(pointcontents(view_origin))
2141                 {
2142                         case CONTENT_WATER:
2143                                 liquidalpha = autocvar_hud_contents_water_alpha;
2144                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2145                                 incontent = 1;
2146                                 break;
2147
2148                         case CONTENT_LAVA:
2149                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2150                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2151                                 incontent = 1;
2152                                 break;
2153
2154                         case CONTENT_SLIME:
2155                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2156                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2157                                 incontent = 1;
2158                                 break;
2159
2160                         default:
2161                                 liquidalpha = 0;
2162                                 liquidcolor = '0 0 0';
2163                                 incontent = 0;
2164                                 break;
2165                 }
2166
2167                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2168                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2169                         contentfadetime = autocvar_hud_contents_fadeintime;
2170                         liquidalpha_prev = liquidalpha;
2171                         liquidcolor_prev = liquidcolor;
2172                 }
2173                 else
2174                         contentfadetime = autocvar_hud_contents_fadeouttime;
2175
2176                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2177                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2178
2179                 if(contentavgalpha)
2180                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2181
2182                 if(autocvar_hud_postprocessing)
2183                 {
2184                         if(autocvar_hud_contents_blur && contentavgalpha)
2185                         {
2186                                 content_blurpostprocess.x = 1;
2187                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2188                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2189                         }
2190                         else
2191                         {
2192                                 content_blurpostprocess.x = 0;
2193                                 content_blurpostprocess.y = 0;
2194                                 content_blurpostprocess.z = 0;
2195                         }
2196                 }
2197         }
2198
2199         if(autocvar_hud_damage && !STAT(FROZEN))
2200         {
2201                 splash_size.x = max(vid_conwidth, vid_conheight);
2202                 splash_size.y = max(vid_conwidth, vid_conheight);
2203                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2204                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2205
2206                 float myhealth_flash_temp;
2207                 myhealth = STAT(HEALTH);
2208
2209                 // fade out
2210                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2211                 // add new damage
2212                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2213
2214                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2215                 pain_threshold = autocvar_hud_damage_pain_threshold;
2216                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2217                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2218
2219                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2220                 {
2221                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2222                 }
2223
2224                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2225
2226                 if(myhealth_prev < 1)
2227                 {
2228                         if(myhealth >= 1)
2229                         {
2230                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2231                                 myhealth_flash_temp = 0;
2232                         }
2233                         else
2234                         {
2235                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2236                         }
2237                 }
2238
2239                 if(spectatee_status == -1 || intermission)
2240                 {
2241                         myhealth_flash = 0; // observing, or match ended
2242                         myhealth_flash_temp = 0;
2243                 }
2244
2245                 myhealth_prev = myhealth;
2246
2247                 // IDEA: change damage color/picture based on player model for robot/alien species?
2248                 // pro: matches model better
2249                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2250                 // maybe different reddish pics?
2251                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2252                 {
2253                         if(autocvar_cl_gentle_damage == 2)
2254                         {
2255                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2256                                         myhealth_gentlergb = randomvec();
2257                         }
2258                         else
2259                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2260
2261                         if(myhealth_flash_temp > 0)
2262                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2263                 }
2264                 else if(myhealth_flash_temp > 0)
2265                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2266
2267                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2268                 {
2269                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2270                         {
2271                                 damage_blurpostprocess.x = 1;
2272                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2273                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2274                         }
2275                         else
2276                         {
2277                                 damage_blurpostprocess.x = 0;
2278                                 damage_blurpostprocess.y = 0;
2279                                 damage_blurpostprocess.z = 0;
2280                         }
2281                 }
2282         }
2283
2284         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2285         float e2 = (autocvar_hud_powerup != 0);
2286         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2287         {
2288                 // enable or disable rendering types if they are used or not
2289                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2290                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2291
2292                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2293                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2294                 {
2295                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2296                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2297                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2298                         {
2299                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2300                                 old_blurradius = blurradius;
2301                                 old_bluralpha = bluralpha;
2302                         }
2303                 }
2304                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2305                 {
2306                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2307                         old_blurradius = 0;
2308                         old_bluralpha = 0;
2309                 }
2310
2311                 // edge detection postprocess handling done second (used by hud_powerup)
2312                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2313                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2314                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2315
2316                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2317
2318                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2319                 {
2320                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2321                         {
2322                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2323                                 old_sharpen_intensity = sharpen_intensity;
2324                         }
2325                 }
2326                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2327                 {
2328                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2329                         old_sharpen_intensity = 0;
2330                 }
2331
2332                 if(cvar("r_glsl_postprocess") == 0)
2333                         cvar_set("r_glsl_postprocess", "2");
2334         }
2335         else if(cvar("r_glsl_postprocess") == 2)
2336                 cvar_set("r_glsl_postprocess", "0");
2337
2338         /*if(gametype == MAPINFO_TYPE_CTF)
2339           {
2340           ctf_view();
2341           } else */
2342
2343         // draw 2D entities
2344         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2345         Draw_ShowNames_All();
2346 #if ENABLE_DEBUGDRAW
2347         Debug_Draw();
2348 #endif
2349
2350         scoreboard_active = Scoreboard_WouldDraw();
2351
2352         HUD_Draw(this); // this parameter for deep vehicle function
2353
2354         if(NextFrameCommand)
2355         {
2356                 localcmd("\n", NextFrameCommand, "\n");
2357                 NextFrameCommand = string_null;
2358         }
2359
2360         // we must do this check AFTER a frame was rendered, or it won't work
2361         if(cs_project_is_b0rked == 0)
2362         {
2363                 string w0, h0;
2364                 w0 = ftos(autocvar_vid_conwidth);
2365                 h0 = ftos(autocvar_vid_conheight);
2366                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2367                 //setproperty(VF_FOV, '90 90 0');
2368                 setproperty(VF_ORIGIN, '0 0 0');
2369                 setproperty(VF_ANGLES, '0 0 0');
2370                 setproperty(VF_PERSPECTIVE, 1);
2371                 makevectors('0 0 0');
2372                 vector v1, v2;
2373                 cvar_set("vid_conwidth", "800");
2374                 cvar_set("vid_conheight", "600");
2375                 v1 = cs_project(v_forward);
2376                 cvar_set("vid_conwidth", "640");
2377                 cvar_set("vid_conheight", "480");
2378                 v2 = cs_project(v_forward);
2379                 if(v1 == v2)
2380                         cs_project_is_b0rked = 1;
2381                 else
2382                         cs_project_is_b0rked = -1;
2383                 cvar_set("vid_conwidth", w0);
2384                 cvar_set("vid_conheight", h0);
2385         }
2386
2387         if(autocvar__hud_configure)
2388                 HUD_Panel_Mouse();
2389         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2390                 HUD_Minigame_Mouse();
2391         else if(QuickMenu_IsOpened())
2392                 QuickMenu_Mouse();
2393         else if(local_player.viewloc && (local_player.viewloc.spawnflags & VIEWLOC_FREEAIM))
2394                 ViewLocation_Mouse(); // NOTE: doesn't use cursormode
2395         else
2396                 HUD_Radar_Mouse();
2397
2398         cl_notice_run();
2399         unpause_update();
2400         Net_Flush();
2401
2402         // let's reset the view back to normal for the end
2403         setproperty(VF_MIN, '0 0 0');
2404         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2405
2406         IL_ENDFRAME();
2407 }
2408
2409
2410 // following vectors must be global to allow seamless switching between camera modes
2411 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2412 void CSQC_Demo_Camera()
2413 {
2414         float speed, attenuation, dimensions;
2415         vector tmp, delta;
2416
2417         if( autocvar_camera_reset || !camera_mode )
2418         {
2419                 camera_offset = '0 0 0';
2420                 current_angles = '0 0 0';
2421                 camera_direction = '0 0 0';
2422                 camera_offset.z += 30;
2423                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2424                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2425                 current_origin = view_origin;
2426                 current_camera_offset  = camera_offset;
2427                 cvar_set("camera_reset", "0");
2428                 camera_mode = CAMERA_CHASE;
2429         }
2430
2431         // Camera angles
2432         if( camera_roll )
2433                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2434
2435         if(autocvar_camera_look_player)
2436         {
2437                 vector dir;
2438                 float n;
2439
2440                 dir = normalize(view_origin - current_position);
2441                 n = mouse_angles.z;
2442                 mouse_angles = vectoangles(dir);
2443                 mouse_angles.x = mouse_angles.x * -1;
2444                 mouse_angles.z = n;
2445         }
2446         else
2447         {
2448                 tmp = getmousepos() * 0.1;
2449                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2450                 {
2451                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2452                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2453                 }
2454         }
2455
2456         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2457         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2458         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2459         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2460
2461         // Fix difference when angles don't have the same sign
2462         delta = '0 0 0';
2463         if(mouse_angles.y < -60 && current_angles.y > 60)
2464                 delta = '0 360 0';
2465         if(mouse_angles.y > 60 && current_angles.y < -60)
2466                 delta = '0 -360 0';
2467
2468         if(autocvar_camera_look_player)
2469                 attenuation = autocvar_camera_look_attenuation;
2470         else
2471                 attenuation = autocvar_camera_speed_attenuation;
2472
2473         attenuation = 1 / max(1, attenuation);
2474         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2475
2476         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2477         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2478         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2479         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2480
2481         // Camera position
2482         tmp = '0 0 0';
2483         dimensions = 0;
2484
2485         if( camera_direction.x )
2486         {
2487                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2488                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2489                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2490                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2491                 ++dimensions;
2492         }
2493
2494         if( camera_direction.y )
2495         {
2496                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2497                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2498                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2499                 ++dimensions;
2500         }
2501
2502         if( camera_direction.z )
2503         {
2504                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2505                 ++dimensions;
2506         }
2507
2508         if(autocvar_camera_free)
2509                 speed = autocvar_camera_speed_free;
2510         else
2511                 speed = autocvar_camera_speed_chase;
2512
2513         if(dimensions)
2514         {
2515                 speed = speed * sqrt(1 / dimensions);
2516                 camera_offset += tmp * speed;
2517         }
2518
2519         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2520
2521         // Camera modes
2522         if( autocvar_camera_free )
2523         {
2524                 if ( camera_mode == CAMERA_CHASE )
2525                 {
2526                         current_camera_offset = current_origin + current_camera_offset;
2527                         camera_offset = current_origin + camera_offset;
2528                 }
2529
2530                 camera_mode = CAMERA_FREE;
2531                 current_position = current_camera_offset;
2532         }
2533         else
2534         {
2535                 if ( camera_mode == CAMERA_FREE )
2536                 {
2537                         current_origin = view_origin;
2538                         camera_offset = camera_offset - current_origin;
2539                         current_camera_offset = current_camera_offset - current_origin;
2540                 }
2541
2542                 camera_mode = CAMERA_CHASE;
2543
2544                 if(autocvar_camera_chase_smoothly)
2545                         current_origin += (view_origin - current_origin) * attenuation;
2546                 else
2547                         current_origin = view_origin;
2548
2549                 current_position = current_origin + current_camera_offset;
2550         }
2551
2552         setproperty(VF_ANGLES, current_angles);
2553         setproperty(VF_ORIGIN, current_position);
2554 }