qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include <client/mutators/_mod.qh>
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/net_notice.qh>
  21 #include <common/debug.qh>
  22 #include <common/mapinfo.qh>
  23 #include <common/gamemodes/_mod.qh>
  24 #include <common/physics/player.qh>
  25 #include <common/stats.qh>
  26 #include <common/mapobjects/target/music.qh>
  27 #include <common/teams.qh>
  28 #include <common/wepent.qh>
  29
  30 #include <common/weapons/weapon/tuba.qh>
  31
  32 #include <common/vehicles/all.qh>
  33 #include <common/weapons/_all.qh>
  34 #include <common/mutators/mutator/overkill/oknex.qh>
  35 #include <common/mutators/mutator/waypoints/all.qh>
  36 #include <common/viewloc.qh>
  37 #include <common/mapobjects/trigger/viewloc.qh>
  38 #include <common/minigames/cl_minigames.qh>
  39 #include <common/minigames/cl_minigames_hud.qh>
  40
  41 #include <lib/csqcmodel/cl_player.qh>
  42 #include <lib/csqcmodel/cl_model.qh>
  43 #include "csqcmodel_hooks.qh"
  44
  45 #include <lib/warpzone/client.qh>
  46 #include <lib/warpzone/common.qh>
  47
  48 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  49
  50 float autocvar_cl_viewmodel_scale;
  51 float autocvar_cl_viewmodel_alpha;
  52
  53 bool autocvar_cl_bobmodel;
  54 float autocvar_cl_bobmodel_speed;
  55 float autocvar_cl_bobmodel_side;
  56 float autocvar_cl_bobmodel_up;
  57
  58 float autocvar_cl_followmodel;
  59 float autocvar_cl_followmodel_speed = 0.3;
  60 float autocvar_cl_followmodel_limit = 135;
  61 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  62 float autocvar_cl_followmodel_highpass = 0.05;
  63 float autocvar_cl_followmodel_lowpass = 0.03;
  64 bool autocvar_cl_followmodel_velocity_absolute;
  65
  66 float autocvar_cl_leanmodel;
  67 float autocvar_cl_leanmodel_speed = 0.3;
  68 float autocvar_cl_leanmodel_limit = 30;
  69 float autocvar_cl_leanmodel_highpass1 = 0.2;
  70 float autocvar_cl_leanmodel_highpass = 0.2;
  71 float autocvar_cl_leanmodel_lowpass = 0.05;
  72
  73 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  74
  75 #define lowpass(value, frac, ref_store, ret) \
  76         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  77
  78 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  79         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  80         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  81 MACRO_END
  82
  83 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  84         float __f = 0; lowpass(value, frac, ref_store, __f); \
  85         ret = (value) - __f; \
  86 MACRO_END
  87
  88 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  90         ret = (value) - __f; \
  91 MACRO_END
  92
  93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  95         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  96 MACRO_END
  97
  98 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  99         highpass(value.x, frac, ref_store.x, ref_out.x); \
 100         highpass(value.y, frac, ref_store.y, ref_out.y); \
 101 MACRO_END
 102
 103 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 104         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 105         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 106 MACRO_END
 107
 108 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 109         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 110         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 111         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 112 MACRO_END
 113
 114 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 115         highpass(value.x, frac, ref_store.x, ref_out.x); \
 116         highpass(value.y, frac, ref_store.y, ref_out.y); \
 117         highpass(value.z, frac, ref_store.z, ref_out.z); \
 118 MACRO_END
 119
 120 void calc_followmodel_ofs(entity view)
 121 {
 122         if(cl_followmodel_time == time)
 123                 return; // cl_followmodel_ofs already calculated for this frame
 124
 125         float frac;
 126         vector gunorg = '0 0 0';
 127         static vector vel_average;
 128         static vector gunorg_adjustment_highpass;
 129         static vector gunorg_adjustment_lowpass;
 130
 131         vector vel;
 132         if (autocvar_cl_followmodel_velocity_absolute)
 133                 vel = view.velocity;
 134         else
 135         {
 136                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 137                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 138                 vel.x = view.velocity * forward;
 139                 vel.y = view.velocity * right * -1;
 140                 vel.z = view.velocity * up;
 141         }
 142
 143         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 144         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 145         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 146
 147         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 148         lowpass3(vel, frac, vel_average, gunorg);
 149
 150         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 151
 152         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 153         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 154         frac = avg_factor(autocvar_cl_followmodel_highpass);
 155         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 156         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 157         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 158
 159         if (autocvar_cl_followmodel_velocity_absolute)
 160         {
 161                 vector fixed_gunorg;
 162                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 163                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 164                 fixed_gunorg.x = gunorg * forward;
 165                 fixed_gunorg.y = gunorg * right * -1;
 166                 fixed_gunorg.z = gunorg * up;
 167                 gunorg = fixed_gunorg;
 168         }
 169
 170         cl_followmodel_ofs = gunorg;
 171         cl_followmodel_time = time;
 172 }
 173
 174 vector leanmodel_ofs(entity view)
 175 {
 176         float frac;
 177         vector gunangles = '0 0 0';
 178         static vector gunangles_prev = '0 0 0';
 179         static vector gunangles_highpass = '0 0 0';
 180         static vector gunangles_adjustment_highpass;
 181         static vector gunangles_adjustment_lowpass;
 182
 183         if (view.csqcmodel_teleported)
 184                 gunangles_prev = view_angles;
 185
 186         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 187         gunangles_highpass += gunangles_prev;
 188         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 189         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 190         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 191         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 192         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 193         gunangles_prev = view_angles;
 194         gunangles_highpass -= gunangles_prev;
 195
 196         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 197         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 198
 199         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 200         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 201         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 202         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 203         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 204
 205         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 206
 207         return gunangles;
 208 }
 209
 210 vector bobmodel_ofs(entity view)
 211 {
 212         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 213         static bool oldonground;
 214         static float hitgroundtime;
 215         if (clonground)
 216         {
 217                 float f = time; // cl.movecmd[0].time
 218                 if (!oldonground)
 219                         hitgroundtime = f;
 220         }
 221         oldonground = clonground;
 222
 223         // calculate for swinging gun model
 224         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 225         vector gunorg = '0 0 0';
 226         static float bobmodel_scale = 0;
 227         static float time_ofs = 0; // makes the effect always restart in the same way
 228         if (clonground)
 229         {
 230                 if (time - hitgroundtime > 0.05)
 231                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 232         }
 233         else
 234                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 235
 236         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 237         if (bobmodel_scale && xyspeed)
 238         {
 239                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 240                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 241                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 242                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 243         }
 244         else
 245                 time_ofs = time;
 246
 247         return gunorg;
 248 }
 249
 250 void viewmodel_animate(entity this)
 251 {
 252         if (autocvar_chase_active) return;
 253         if (STAT(HEALTH) <= 0) return;
 254
 255         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 256
 257         if (autocvar_cl_followmodel)
 258         {
 259                 calc_followmodel_ofs(view);
 260                 this.origin += cl_followmodel_ofs;
 261         }
 262
 263         if (autocvar_cl_leanmodel)
 264                 this.angles += leanmodel_ofs(view);
 265
 266         // vertical view bobbing code
 267         // TODO: cl_bob
 268
 269         // horizontal view bobbing code
 270         // TODO: cl_bob2
 271
 272         // fall bobbing code
 273         // causes the view to swing down and back up when touching the ground
 274         // TODO: cl_bobfall
 275
 276         // gun model bobbing code
 277         if (autocvar_cl_bobmodel)
 278                 this.origin += bobmodel_ofs(view);
 279 }
 280
 281 .vector viewmodel_origin, viewmodel_angles;
 282 .float weapon_nextthink;
 283 .float weapon_eta_last;
 284 .float weapon_switchdelay;
 285
 286 .string name_last;
 287
 288 void viewmodel_draw(entity this)
 289 {
 290         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 291                 return;
 292         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 293         float a = ((autocvar_cl_viewmodel_alpha) ? bound(-1, autocvar_cl_viewmodel_alpha, this.m_alpha) : this.m_alpha);
 294         int wepskin = this.m_skin;
 295         bool invehicle = player_localentnum > maxclients;
 296         if (invehicle) a = -1;
 297         Weapon wep = this.activeweapon;
 298         int c = entcs_GetClientColors(current_player);
 299         vector g = weaponentity_glowmod(wep, NULL, c, this);
 300         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 301         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 302                 | EF_NODEPTHTEST)
 303                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 304         for (entity e = this; e; e = e.weaponchild)
 305         {
 306                 e.drawmask = mask;
 307                 e.alpha = a;
 308                 e.skin = wepskin;
 309                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 310                 e.glowmod = g;
 311                 e.csqcmodel_effects = fx;
 312                 CSQCModel_Effects_Apply(e);
 313         }
 314         if(a >= 0)
 315         {
 316                 string name = wep.mdl;
 317                 string newname = wep.wr_viewmodel(wep, this);
 318                 if(newname)
 319                         name = newname;
 320                 bool swap = name != this.name_last;
 321                 // if (swap)
 322                 {
 323                         this.name_last = name;
 324                         CL_WeaponEntity_SetModel(this, name, swap);
 325                         this.viewmodel_origin = this.origin;
 326                         this.viewmodel_angles = this.angles;
 327                 }
 328                 anim_update(this);
 329                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 330                         anim_set(this, this.anim_idle, true, false, false);
 331         }
 332         float f = 0; // 0..1; 0: fully active
 333         float rate = STAT(WEAPONRATEFACTOR);
 334         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 335         if (eta <= 0) f = this.weapon_eta_last;
 336         else switch (this.state)
 337         {
 338                 case WS_RAISE:
 339                 {
 340                         f = eta / max(eta, this.weapon_switchdelay);
 341                         break;
 342                 }
 343                 case WS_DROP:
 344                 {
 345                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 346                         break;
 347                 }
 348                 case WS_CLEAR:
 349                 {
 350                         f = 1;
 351                         break;
 352                 }
 353         }
 354         this.weapon_eta_last = f;
 355         this.origin = this.viewmodel_origin;
 356         this.angles = this.viewmodel_angles;
 357         this.angles_x = (-90 * f * f);
 358         viewmodel_animate(this);
 359         MUTATOR_CALLHOOK(DrawViewModel, this);
 360         setorigin(this, this.origin);
 361 }
 362
 363 STATIC_INIT(viewmodel) {
 364     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 365         viewmodels[slot] = new(viewmodel);
 366 }
 367
 368 float showfps_prevfps;
 369 float showfps_prevfps_time;
 370 int showfps_framecounter;
 371
 372 void fpscounter_update()
 373 {
 374         if(!STAT(SHOWFPS))
 375                 return;
 376
 377         float currentTime = gettime(GETTIME_REALTIME);
 378         showfps_framecounter += 1;
 379         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 380         {
 381                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 382                 showfps_framecounter = 0;
 383                 showfps_prevfps_time = currentTime;
 384
 385                 int channel = MSG_C2S;
 386                 WriteHeader(channel, fpsreport);
 387                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 388         }
 389 }
 390
 391 STATIC_INIT(fpscounter_init)
 392 {
 393         float currentTime = gettime(GETTIME_REALTIME);
 394         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 395 }
 396
 397 float drawtime;
 398 float avgspeed;
 399 vector GetCurrentFov(float fov)
 400 {
 401         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 402         float velocityzoom, curspeed;
 403         vector v;
 404
 405         zoomsensitivity = autocvar_cl_zoomsensitivity;
 406         zoomfactor = autocvar_cl_zoomfactor;
 407         if(zoomfactor < 1 || zoomfactor > 30)
 408                 zoomfactor = 2.5;
 409         zoomspeed = autocvar_cl_zoomspeed;
 410         if (zoomspeed >= 0 && (zoomspeed < 0.5 || zoomspeed > 16))
 411                 zoomspeed = 3.5;
 412
 413         zoomdir = button_zoom;
 414
 415         if(hud == HUD_NORMAL && !spectatee_status)
 416         {
 417                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 418                 {
 419                         entity wepent = viewmodels[slot];
 420                         if(wepent.switchweapon != wepent.activeweapon)
 421                                 continue;
 422                         Weapon wep = wepent.activeweapon;
 423                         if(wep != WEP_Null && wep.wr_zoomdir)
 424                         {
 425                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 426                                 zoomdir += do_zoom;
 427                         }
 428                 }
 429         }
 430         if(spectatee_status > 0 || isdemo())
 431         {
 432                 if(spectatorbutton_zoom)
 433                 {
 434                         if(zoomdir)
 435                                 zoomdir = 0;
 436                         else
 437                                 zoomdir = 1;
 438                 }
 439                 // fteqcc failed twice here already, don't optimize this
 440         }
 441
 442         if(zoomdir) { zoomin_effect = 0; }
 443
 444         if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 445         {
 446                 current_viewzoom = 1;
 447         }
 448         else if (camera_active)
 449         {
 450                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 451         }
 452         else if(autocvar_cl_spawnzoom && zoomin_effect)
 453         {
 454                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 455
 456                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 457                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 458                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 459         }
 460         else
 461         {
 462                 if(zoomspeed < 0) // instant zoom
 463                 {
 464                         if(zoomdir)
 465                                 current_viewzoom = 1 / zoomfactor;
 466                         else
 467                                 current_viewzoom = 1;
 468                 }
 469                 else
 470                 {
 471                         if(zoomdir)
 472                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 473                         else
 474                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 475                 }
 476         }
 477
 478         if(almost_equals(current_viewzoom, 1))
 479                 current_zoomfraction = 0;
 480         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 481                 current_zoomfraction = 1;
 482         else
 483                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 484
 485         if(zoomsensitivity < 1)
 486                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 487         else
 488                 setsensitivityscale(1);
 489
 490         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 491         {
 492                 if (intermission || (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2))
 493                         curspeed = 0;
 494                 else
 495                 {
 496                         makevectors(view_angles);
 497                         v = pmove_vel;
 498                         if(csqcplayer)
 499                                 v = csqcplayer.velocity;
 500
 501                         switch(autocvar_cl_velocityzoom_type)
 502                         {
 503                                 case 3: curspeed = max(0, v_forward * v); break;
 504                                 case 2: curspeed = (v_forward * v); break;
 505                                 case 1: default: curspeed = vlen(v); break;
 506                         }
 507                 }
 508
 509                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 510                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 511                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 512
 513                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 514         }
 515         else
 516                 velocityzoom = 1;
 517
 518         float frustumx, frustumy, fovx, fovy;
 519         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 520         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 521         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 522         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 523
 524         return '1 0 0' * fovx + '0 1 0' * fovy;
 525 }
 526
 527 vector GetViewLocationFOV(float fov)
 528 {
 529         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 530         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 531         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 532         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 533         return '1 0 0' * fovx + '0 1 0' * fovy;
 534 }
 535
 536 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 537 {
 538         float fovx, fovy;
 539         float width = (ov_worldmax.x - ov_worldmin.x);
 540         float height = (ov_worldmax.y - ov_worldmin.y);
 541         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 542         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 543         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 544         return '1 0 0' * fovx + '0 1 0' * fovy;
 545 }
 546
 547 // this function must match W_SetupShot!
 548 float zoomscript_caught;
 549
 550 bool minigame_wasactive;
 551
 552 vector wcross_origin;
 553 float wcross_scale_prev, wcross_alpha_prev;
 554 vector wcross_color_prev;
 555 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 556 vector wcross_color_goal_prev;
 557 float wcross_changedonetime;
 558
 559 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 560 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 561 float wcross_name_changestarttime, wcross_name_changedonetime;
 562 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 563
 564 float wcross_ring_prev;
 565
 566 entity trueaim;
 567 entity trueaim_rifle;
 568
 569 const float SHOTTYPE_HITTEAM = 1;
 570 const float SHOTTYPE_HITOBSTRUCTION = 2;
 571 const float SHOTTYPE_HITWORLD = 3;
 572 const float SHOTTYPE_HITENEMY = 4;
 573
 574 void TrueAim_Init()
 575 {
 576         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 577         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 578 }
 579
 580 float EnemyHitCheck()
 581 {
 582         float t, n;
 583         wcross_origin = project_3d_to_2d(trace_endpos);
 584         wcross_origin.z = 0;
 585         if(trace_ent)
 586                 n = trace_ent.entnum;
 587         else
 588                 n = trace_networkentity;
 589         if(n < 1)
 590                 return SHOTTYPE_HITWORLD;
 591         if(n > maxclients)
 592                 return SHOTTYPE_HITWORLD;
 593         t = entcs_GetTeam(n - 1);
 594         if(teamplay)
 595                 if(t == myteam)
 596                         return SHOTTYPE_HITTEAM;
 597         if(t == NUM_SPECTATOR)
 598                 return SHOTTYPE_HITWORLD;
 599         return SHOTTYPE_HITENEMY;
 600 }
 601
 602 float TrueAimCheck(entity wepent)
 603 {
 604         if(wepent.activeweapon.spawnflags & WEP_FLAG_NOTRUEAIM)
 605                 return SHOTTYPE_HITWORLD;
 606
 607         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 608         vector vecs, trueaimpoint, w_shotorg;
 609         vector mi, ma, dv;
 610         float shottype;
 611         entity ta;
 612         float mv;
 613
 614         mi = ma = '0 0 0';
 615         ta = trueaim;
 616         mv = MOVE_NOMONSTERS;
 617
 618         switch(wepent.activeweapon) // WEAPONTODO
 619         {
 620                 case WEP_VORTEX:
 621                 case WEP_OVERKILL_NEX:
 622                 case WEP_VAPORIZER:
 623                         mv = MOVE_NORMAL;
 624                         break;
 625                 case WEP_RIFLE:
 626                         ta = trueaim_rifle;
 627                         mv = MOVE_NORMAL;
 628                         if(zoomscript_caught)
 629                         {
 630                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 631                                 return EnemyHitCheck();
 632                         }
 633                         break;
 634                 case WEP_DEVASTATOR: // projectile has a size!
 635                         mi = '-3 -3 -3';
 636                         ma = '3 3 3';
 637                         break;
 638                 case WEP_FIREBALL: // projectile has a size!
 639                         mi = '-16 -16 -16';
 640                         ma = '16 16 16';
 641                         break;
 642                 case WEP_SEEKER: // projectile has a size!
 643                         mi = '-2 -2 -2';
 644                         ma = '2 2 2';
 645                         break;
 646                 case WEP_ELECTRO: // projectile has a size!
 647                         mi = '0 0 -3';
 648                         ma = '0 0 -3';
 649                         break;
 650         }
 651
 652         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 653
 654         vecs = decompressShotOrigin(STAT(SHOTORG));
 655
 656         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 657         trueaimpoint = trace_endpos;
 658
 659         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 660                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 661
 662         if(vecs.x > 0)
 663                 vecs.y = -vecs.y;
 664         else
 665                 vecs = '0 0 0';
 666
 667         dv = view_right * vecs.y + view_up * vecs.z;
 668         w_shotorg = traceorigin + dv;
 669
 670         // now move the vecs forward as much as requested if possible
 671         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 672         w_shotorg = trace_endpos - view_forward * nudge;
 673
 674         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 675         shottype = EnemyHitCheck();
 676         if(shottype != SHOTTYPE_HITWORLD)
 677                 return shottype;
 678
 679 #if 0
 680         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 681         // or rather, I know why, but see no fix
 682         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 683                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 684                 return SHOTTYPE_HITOBSTRUCTION;
 685 #endif
 686
 687         return SHOTTYPE_HITWORLD;
 688 }
 689
 690 float camera_mode;
 691 const float CAMERA_FREE = 1;
 692 const float CAMERA_CHASE = 2;
 693 float reticle_type;
 694 string NextFrameCommand;
 695
 696 vector freeze_org, freeze_ang;
 697 entity nightvision_noise, nightvision_noise2;
 698
 699 const float MAX_TIME_DIFF = 5;
 700 float pickup_crosshair_time, pickup_crosshair_size;
 701 float hitindication_crosshair_size;
 702 float use_vortex_chargepool;
 703
 704 float myhealth, myhealth_prev;
 705 float myhealth_flash;
 706
 707 float old_blurradius, old_bluralpha;
 708 float old_sharpen_intensity;
 709
 710 vector myhealth_gentlergb;
 711
 712 float contentavgalpha, liquidalpha_prev;
 713 vector liquidcolor_prev;
 714
 715 float eventchase_current_distance;
 716 float eventchase_running;
 717 int WantEventchase(entity this, bool want_vehiclechase)
 718 {
 719         if(autocvar_cl_orthoview)
 720                 return 0;
 721         if(STAT(GAME_STOPPED) || intermission)
 722                 return 1;
 723         if(this.viewloc)
 724                 return 1;
 725         if(spectatee_status >= 0)
 726         {
 727                 if(want_vehiclechase)
 728                         return 1;
 729                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 730                         return 1;
 731                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 732                         return 1;
 733                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 734                 {
 735                         if(autocvar_cl_eventchase_death == 2)
 736                         {
 737                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 738                                 if(this.velocity == '0 0 0' || eventchase_running)
 739                                         return 1;
 740                         }
 741                         else return 1;
 742                 }
 743                 if (spectatee_status > 0 && autocvar_cl_eventchase_spectated_change)
 744                 {
 745                         if (time <= spectatee_status_changed_time + min(3, autocvar_cl_eventchase_spectated_change_time))
 746                                 return 1;
 747                         else if (eventchase_running)
 748                                 return -1; // disable chase_active while eventchase is still enabled so to avoid a glicth
 749                 }
 750         }
 751         return 0;
 752 }
 753
 754 void HUD_Crosshair_Vehicle(entity this)
 755 {
 756         if(hud != HUD_BUMBLEBEE_GUN)
 757         {
 758                 Vehicle info = Vehicles_from(hud);
 759                 info.vr_crosshair(info, this);
 760         }
 761 }
 762
 763 vector damage_blurpostprocess, content_blurpostprocess;
 764
 765 float unaccounted_damage = 0;
 766 void UpdateDamage()
 767 {
 768         // accumulate damage with each stat update
 769         static float damage_total_prev = 0;
 770         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 771         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 772         damage_total_prev = damage_total;
 773
 774         static float damage_dealt_time_prev = 0;
 775         float damage_dealt_time = STAT(HIT_TIME);
 776         if (damage_dealt_time != damage_dealt_time_prev)
 777         {
 778                 unaccounted_damage += unaccounted_damage_new;
 779                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 780         }
 781         damage_dealt_time_prev = damage_dealt_time;
 782
 783         // prevent hitsound when switching spectatee
 784         static float spectatee_status_prev = 0;
 785         if (spectatee_status != spectatee_status_prev)
 786                 unaccounted_damage = 0;
 787         spectatee_status_prev = spectatee_status;
 788 }
 789
 790 void HitSound()
 791 {
 792         // varying sound pitch
 793
 794         bool have_arc = false;
 795         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 796         {
 797                 entity wepent = viewmodels[slot];
 798
 799                 if(wepent.activeweapon == WEP_ARC)
 800                         have_arc = true;
 801         }
 802
 803         static float hitsound_time_prev = 0;
 804         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 805         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 806         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 807         {
 808                 if (autocvar_cl_hitsound && unaccounted_damage)
 809                 {
 810                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 811                         float a = autocvar_cl_hitsound_max_pitch;
 812                         float b = autocvar_cl_hitsound_min_pitch;
 813                         float c = autocvar_cl_hitsound_nom_damage;
 814                         float d = unaccounted_damage;
 815                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 816
 817                         // if sound variation is disabled, set pitch_shift to 1
 818                         if (autocvar_cl_hitsound == 1)
 819                                 pitch_shift = 1;
 820
 821                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 822                         if (autocvar_cl_hitsound == 3)
 823                         {
 824                                 float mirror_value = (a-b)/2 + b;
 825                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 826                         }
 827
 828                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 829
 830                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 831                         // todo: normalize sound pressure levels? seems unnecessary
 832
 833                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 834                 }
 835                 unaccounted_damage = 0;
 836                 hitsound_time_prev = time;
 837         }
 838
 839         static float typehit_time_prev = 0;
 840         float typehit_time = STAT(TYPEHIT_TIME);
 841         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 842         {
 843                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 844                 typehit_time_prev = typehit_time;
 845         }
 846
 847         static float kill_time_prev = 0;
 848         float kill_time = STAT(KILL_TIME);
 849         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 850         {
 851                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 852                 kill_time_prev = kill_time;
 853         }
 854 }
 855
 856 vector crosshair_getcolor(entity this, float health_stat)
 857 {
 858         static float rainbow_last_flicker;
 859         static vector rainbow_prev_color;
 860         vector wcross_color = '0 0 0';
 861         switch(autocvar_crosshair_color_special)
 862         {
 863                 case 1: // crosshair_color_per_weapon
 864                 {
 865                         if(this != WEP_Null && hud == HUD_NORMAL)
 866                         {
 867                                 wcross_color = this.wpcolor;
 868                                 break;
 869                         }
 870                         else { goto normalcolor; }
 871                 }
 872
 873                 case 2: // crosshair_color_by_health
 874                 {
 875                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 876                         float hp = floor(v.x + 1);
 877
 878                         //x = red
 879                         //y = green
 880                         //z = blue
 881
 882                         wcross_color.z = 0;
 883
 884                         if(hp > 200)
 885                         {
 886                                 wcross_color.x = 0;
 887                                 wcross_color.y = 1;
 888                         }
 889                         else if(hp > 150)
 890                         {
 891                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 892                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 893                         }
 894                         else if(hp > 100)
 895                         {
 896                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 897                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 898                                 wcross_color.z = 1 - (hp-100)*0.02;
 899                         }
 900                         else if(hp > 50)
 901                         {
 902                                 wcross_color.x = 1;
 903                                 wcross_color.y = 1;
 904                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 905                         }
 906                         else if(hp > 20)
 907                         {
 908                                 wcross_color.x = 1;
 909                                 wcross_color.y = (hp-20)*90/27/100;
 910                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 911                         }
 912                         else
 913                         {
 914                                 wcross_color.x = 1;
 915                                 wcross_color.y = 0;
 916                         }
 917                         break;
 918                 }
 919
 920                 case 3: // crosshair_color_rainbow
 921                 {
 922                         if(time >= rainbow_last_flicker)
 923                         {
 924                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 925                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 926                         }
 927                         wcross_color = rainbow_prev_color;
 928                         break;
 929                 }
 930 LABEL(normalcolor)
 931                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
 932         }
 933
 934         return wcross_color;
 935 }
 936
 937 void HUD_Crosshair(entity this)
 938 {
 939         float f, i, j;
 940         vector v;
 941         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
 942                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
 943                 !HUD_MinigameMenu_IsOpened() )
 944         {
 945                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 946                         return;
 947
 948                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
 949                         return;
 950
 951                 if (hud != HUD_NORMAL)
 952                 {
 953                         HUD_Crosshair_Vehicle(this);
 954                         return;
 955                 }
 956
 957                 string wcross_style;
 958                 float wcross_alpha, wcross_resolution;
 959                 wcross_style = autocvar_crosshair;
 960                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
 961                         wcross_style = autocvar_crosshair_2d;
 962                 if (wcross_style == "0")
 963                         return;
 964                 wcross_resolution = autocvar_crosshair_size;
 965                 if (wcross_resolution == 0)
 966                         return;
 967                 wcross_alpha = autocvar_crosshair_alpha;
 968                 if (wcross_alpha == 0)
 969                         return;
 970
 971                 // TrueAim check
 972                 float shottype;
 973
 974                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 975                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
 976                         wcross_origin = viewloc_mousepos;
 977                 else if(autocvar_chase_active > 0 && autocvar_crosshair_chase)
 978                 {
 979                         vector player_org = ((csqcplayer) ? csqcplayer.origin + csqcplayer.view_ofs : view_origin);
 980                         if(csqcplayer && crosshair_chase_playeralpha && crosshair_chase_playeralpha < 1)
 981                         {
 982                                 traceline(view_origin, view_origin + max_shot_distance * view_forward, MOVE_NORMAL, NULL);
 983                                 float myalpha = (!csqcplayer.m_alpha) ? 1 : csqcplayer.m_alpha;
 984                                 if(trace_ent == csqcplayer && STAT(HEALTH) > 0)
 985                                         csqcplayer.alpha = min(crosshair_chase_playeralpha, myalpha);
 986                                 else
 987                                         csqcplayer.alpha = csqcplayer.m_alpha;
 988                         }
 989                         traceline(player_org, player_org + max_shot_distance * view_forward, MOVE_WORLDONLY, NULL);
 990                         wcross_origin = project_3d_to_2d(trace_endpos);
 991                 }
 992                 else
 993                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
 994                 wcross_origin.z = 0;
 995                 if(autocvar_crosshair_hittest)
 996                 {
 997                         vector wcross_oldorigin;
 998                         entity thiswep = viewmodels[0]; // TODO: unhardcode
 999                         wcross_oldorigin = wcross_origin;
1000                         shottype = TrueAimCheck(thiswep);
1001                         if(shottype == SHOTTYPE_HITWORLD)
1002                         {
1003                                 v = wcross_origin - wcross_oldorigin;
1004                                 v.x /= vid_conwidth;
1005                                 v.y /= vid_conheight;
1006                                 if(vdist(v, >, 0.01))
1007                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1008                         }
1009                         if(!autocvar_crosshair_hittest_showimpact)
1010                                 wcross_origin = wcross_oldorigin;
1011                 }
1012                 else
1013                         shottype = SHOTTYPE_HITWORLD;
1014
1015                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1016                 string wcross_name = "";
1017                 float wcross_scale, wcross_blur;
1018
1019         entity e = WEP_Null;
1020                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1021                 {
1022                         entity wepent = viewmodels[0]; // TODO: unhardcode
1023                         e = wepent.switchingweapon;
1024                         if(e)
1025                         {
1026                                 if(autocvar_crosshair_per_weapon)
1027                                 {
1028                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1029                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1030                                         //if (wcross_resolution == 0)
1031                                                 //return;
1032
1033                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1034                                         wcross_resolution *= e.w_crosshair_size;
1035                                         wcross_name = e.w_crosshair;
1036                                 }
1037                         }
1038                 }
1039
1040                 if(wcross_name == "")
1041                         wcross_name = strcat("gfx/crosshair", wcross_style);
1042
1043                 // MAIN CROSSHAIR COLOR DECISION
1044                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1045
1046                 if(autocvar_crosshair_effect_scalefade)
1047                 {
1048                         wcross_scale = wcross_resolution;
1049                         wcross_resolution = 1;
1050                 }
1051                 else
1052                 {
1053                         wcross_scale = 1;
1054                 }
1055
1056                 if(autocvar_crosshair_pickup)
1057                 {
1058                         float stat_pickup_time = STAT(LAST_PICKUP);
1059
1060                         if(pickup_crosshair_time < stat_pickup_time)
1061                         {
1062                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1063                                         pickup_crosshair_size = 1;
1064
1065                                 pickup_crosshair_time = stat_pickup_time;
1066                         }
1067
1068                         if(pickup_crosshair_size > 0)
1069                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1070                         else
1071                                 pickup_crosshair_size = 0;
1072
1073                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1074                 }
1075
1076                 // todo: make crosshair hit indication dependent on damage dealt
1077                 if(autocvar_crosshair_hitindication)
1078                 {
1079                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1080
1081                         if(unaccounted_damage)
1082                         {
1083                                 hitindication_crosshair_size = 1;
1084                         }
1085
1086                         if(hitindication_crosshair_size > 0)
1087                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1088                         else
1089                                 hitindication_crosshair_size = 0;
1090
1091                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1092                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1093                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1094                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1095                 }
1096
1097                 // no effects needed for targeting enemies, this can't possibly span all valid targets!
1098                 // just show for teammates to give a sign that they're an invalid target
1099                 //if(shottype == SHOTTYPE_HITENEMY)
1100                         //wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1101                 if(shottype == SHOTTYPE_HITTEAM)
1102                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1103
1104                 f = fabs(autocvar_crosshair_effect_time);
1105                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1106                 {
1107                         wcross_changedonetime = time + f;
1108                 }
1109                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1110                 {
1111                         wcross_name_changestarttime = time;
1112                         wcross_name_changedonetime = time + f;
1113                         if(wcross_name_goal_prev_prev)
1114                                 strunzone(wcross_name_goal_prev_prev);
1115                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1116                         wcross_name_goal_prev = strzone(wcross_name);
1117                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1118                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1119                         wcross_resolution_goal_prev = wcross_resolution;
1120                 }
1121
1122                 wcross_scale_goal_prev = wcross_scale;
1123                 wcross_alpha_goal_prev = wcross_alpha;
1124                 wcross_color_goal_prev = wcross_color;
1125
1126                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1127                 {
1128                         wcross_blur = 1;
1129                         wcross_alpha *= 0.75;
1130                 }
1131                 else
1132                         wcross_blur = 0;
1133                 // *_prev is at time-frametime
1134                 // * is at wcross_changedonetime+f
1135                 // what do we have at time?
1136                 if(time < wcross_changedonetime)
1137                 {
1138                         f = frametime / (wcross_changedonetime - time + frametime);
1139                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1140                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1141                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1142                 }
1143
1144                 wcross_scale_prev = wcross_scale;
1145                 wcross_alpha_prev = wcross_alpha;
1146                 wcross_color_prev = wcross_color;
1147
1148                 MUTATOR_CALLHOOK(UpdateCrosshair);
1149
1150                 wcross_scale *= 1 - autocvar__menu_alpha;
1151                 wcross_alpha *= 1 - autocvar__menu_alpha;
1152                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1153
1154                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1155                 {
1156                         // crosshair rings for weapon stats
1157                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1158                         {
1159                                 // declarations and stats
1160                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1161                                 string ring_image = string_null, ring_inner_image = string_null;
1162                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1163
1164                                 ring_scale = autocvar_crosshair_ring_size;
1165
1166                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1167
1168                                 int weapon_clipload = wepent.clip_load;
1169                                 int weapon_clipsize = wepent.clip_size;
1170
1171                                 float arc_heat = wepent.arc_heat_percent;
1172                                 float vcharge = wepent.vortex_charge;
1173                                 float vchargepool = wepent.vortex_chargepool_ammo;
1174                                 float oknex_charge_ = wepent.oknex_charge;
1175                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1176
1177                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1178                                         vortex_charge_movingavg = vcharge;
1179
1180                                 // handle the values
1181                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1182                                 {
1183                                         if (vchargepool || use_vortex_chargepool) {
1184                                                 use_vortex_chargepool = 1;
1185                                                 ring_inner_value = vchargepool;
1186                                         } else {
1187                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1188                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1189                                         }
1190
1191                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1192                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1193                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1194
1195                                         // draw the outer ring to show the current charge of the weapon
1196                                         ring_value = vcharge;
1197                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1198                                         ring_rgb = wcross_color;
1199                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1200                                 }
1201                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1202                                 {
1203                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1204                                                 use_vortex_chargepool = 1;
1205                                                 ring_inner_value = oknex_chargepool_;
1206                                         } else {
1207                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1208                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1209                                         }
1210
1211                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1212                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1213                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1214
1215                                         // draw the outer ring to show the current charge of the weapon
1216                                         ring_value = oknex_charge_;
1217                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1218                                         ring_rgb = wcross_color;
1219                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1220                                 }
1221                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1222                                 {
1223                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1224                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1225                                         ring_rgb = wcross_color;
1226                                         ring_image = "gfx/crosshair_ring.tga";
1227                                 }
1228                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1229                                 {
1230                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1231                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1232                                         ring_rgb = wcross_color;
1233                                         ring_image = "gfx/crosshair_ring.tga";
1234                                 }
1235                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1236                                 {
1237                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1238                                         ring_scale = autocvar_crosshair_ring_reload_size;
1239                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1240                                         ring_rgb = wcross_color;
1241
1242                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1243                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1244                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1245                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1246                                         else
1247                                                 ring_image = "gfx/crosshair_ring.tga";
1248                                 }
1249                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1250                                 {
1251                                         ring_value = arc_heat;
1252                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1253                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1254                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1255                                         ring_image = "gfx/crosshair_ring.tga";
1256                                 }
1257
1258                                 // if in weapon switch animation, fade ring out/in
1259                                 if(autocvar_crosshair_effect_time > 0)
1260                                 {
1261                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1262                                         if (f >= 1)
1263                                         {
1264                                                 wcross_ring_prev = ((ring_image) ? true : false);
1265                                         }
1266
1267                                         if(wcross_ring_prev)
1268                                         {
1269                                                 if(f < 1)
1270                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1271                                         }
1272                                         else
1273                                         {
1274                                                 if(f < 1)
1275                                                         ring_alpha *= bound(0, f, 1);
1276                                         }
1277                                 }
1278
1279                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1280                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1281
1282                                 if (ring_value)
1283                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1284                         }
1285
1286 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1287                         MACRO_BEGIN \
1288                                 vector scaled_sz = sz * wcross_size; \
1289                                 if(wcross_blur > 0) \
1290                                 { \
1291                                         for(i = -2; i <= 2; ++i) \
1292                                         for(j = -2; j <= 2; ++j) \
1293                                         M(i,j,sz,scaled_sz,wcross_name,wcross_alpha*0.04); \
1294                                 } \
1295                                 else \
1296                                 { \
1297                                         M(0,0,sz,scaled_sz,wcross_name,wcross_alpha); \
1298                                 } \
1299                         MACRO_END
1300
1301 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,scaled_sz,wcross_name,wcross_alpha) \
1302                         drawpic(wcross_origin - ('0.5 0 0' * (scaled_sz.x + i * wcross_blur) + '0 0.5 0' * (scaled_sz.y + j * wcross_blur)), wcross_name, scaled_sz, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1303
1304 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1305                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1306
1307                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1308                         {
1309                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1310                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1311                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1312                                 f = 1 - f;
1313                         }
1314                         else
1315                         {
1316                                 f = 1;
1317                         }
1318                         wcross_name_alpha_goal_prev = f;
1319
1320                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1321                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1322
1323                         if(autocvar_crosshair_dot)
1324                         {
1325                                 vector wcross_color_old;
1326                                 wcross_color_old = wcross_color;
1327
1328                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1329                                         wcross_color = stov(autocvar_crosshair_dot_color);
1330
1331                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1332                                 // FIXME why don't we use wcross_alpha here?
1333                                 wcross_color = wcross_color_old;
1334                         }
1335                 }
1336         }
1337         else
1338         {
1339                 wcross_scale_prev = 0;
1340                 wcross_alpha_prev = 0;
1341                 wcross_scale_goal_prev = 0;
1342                 wcross_alpha_goal_prev = 0;
1343                 wcross_changedonetime = 0;
1344                 strfree(wcross_name_goal_prev);
1345                 strfree(wcross_name_goal_prev_prev);
1346                 wcross_name_changestarttime = 0;
1347                 wcross_name_changedonetime = 0;
1348                 wcross_name_alpha_goal_prev = 0;
1349                 wcross_name_alpha_goal_prev_prev = 0;
1350                 wcross_resolution_goal_prev = 0;
1351                 wcross_resolution_goal_prev_prev = 0;
1352         }
1353 }
1354
1355 const int MAX_SPECIALCOMMAND = 15;
1356 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1357 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1358 const float SPECIALCOMMAND_SPEED = 150;
1359 const float SPECIALCOMMAND_TURNSPEED = 2;
1360 const float SPECIALCOMMAND_SIZE = 0.025;
1361 const float SPECIALCOMMAND_CHANCE = 0.35;
1362 float sc_spawntime, sc_changetime;
1363 vector sc_color = '1 1 1';
1364 void SpecialCommand()
1365 {
1366         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1367                 return;
1368
1369         if(time >= sc_changetime)
1370         {
1371                 sc_changetime = time + 1;
1372                 sc_color = randomvec() * 1.5;
1373                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1374                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1375                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1376         }
1377         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1378
1379         if(!precache_pic("gfx/smile"))
1380                 return; // damn party poopers
1381
1382         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1383         {
1384                 vector slot = specialcommand_slots[j];
1385                 if(slot.y)
1386                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1387                 //if(slot.z)
1388                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1389                 if(slot.y >= vid_conheight)
1390                         slot = '0 0 0';
1391
1392                 if(slot == '0 0 0')
1393                 {
1394                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1395                         {
1396                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1397                                 slot.y = 1; // start it off 0 so we can use it
1398                                 slot.z = floor(random() * Weapons_MAX);
1399                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1400                                 vector newcolor = randomvec() * 2;
1401                                 newcolor.x = bound(0.4, newcolor.x, 1);
1402                                 newcolor.y = bound(0.4, newcolor.y, 1);
1403                                 newcolor.z = bound(0.4, newcolor.z, 1);
1404                                 specialcommand_colors[j] = newcolor;
1405                         }
1406                 }
1407                 else
1408                 {
1409                         vector splash_size = '0 0 0';
1410                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1411                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1412                         entity wep = Weapons_from(slot.z);
1413                         if(wep == WEP_Null)
1414                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1415                         else
1416                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1417                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1418                 }
1419
1420                 specialcommand_slots[j] = slot;
1421         }
1422 }
1423
1424 void HUD_Draw(entity this)
1425 {
1426         // if we don't know gametype and scores yet avoid drawing the scoreboard
1427         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1428         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1429         // cl_deathscoreboard would show the scoreboard and so on
1430         if(!gametype)
1431                 return;
1432
1433         Hud_Dynamic_Frame();
1434
1435         if(!intermission)
1436         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1437         {
1438                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1439         }
1440         else if(STAT(FROZEN))
1441         {
1442                 vector col = '0.25 0.90 1';
1443                 if(STAT(REVIVE_PROGRESS))
1444                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1445                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1446         }
1447
1448         HUD_Scale_Enable();
1449         if(!intermission)
1450         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1451         {
1452                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1453                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1454                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1455         }
1456         else if(STAT(CAPTURE_PROGRESS))
1457         {
1458                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1459                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1460         }
1461         else if(STAT(REVIVE_PROGRESS))
1462         {
1463                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1464                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1465         }
1466         HUD_Scale_Disable();
1467
1468         if(autocvar_r_letterbox == 0)
1469                 if(autocvar_viewsize < 120)
1470                 {
1471                         if(!(ISGAMETYPE(RACE) || ISGAMETYPE(CTS)))
1472                                 Accuracy_LoadLevels();
1473
1474                         HUD_Main();
1475                         HUD_Scale_Disable();
1476                 }
1477
1478         // crosshair goes VERY LAST
1479         SpecialCommand();
1480         UpdateDamage();
1481         HUD_Crosshair(this);
1482         HitSound();
1483 }
1484
1485 void ViewLocation_Mouse()
1486 {
1487         if(spectatee_status)
1488                 return; // don't draw it as spectator!
1489
1490         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1491         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1492         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1493
1494         //float cursor_alpha = 1 - autocvar__menu_alpha;
1495         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1496 }
1497
1498 void HUD_Cursor_Show()
1499 {
1500         float cursor_alpha = 1 - autocvar__menu_alpha;
1501         if(cursor_type == CURSOR_NORMAL)
1502                 draw_cursor_normal(mousepos, '1 1 1', cursor_alpha);
1503         else if(cursor_type == CURSOR_MOVE)
1504                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1505         else if(cursor_type == CURSOR_RESIZE)
1506                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize", '1 1 1', cursor_alpha);
1507         else if(cursor_type == CURSOR_RESIZE2)
1508                 draw_cursor(mousepos, '0.5 0.5 0', "/cursor_resize2", '1 1 1', cursor_alpha);
1509 }
1510
1511 void HUD_Mouse(entity player)
1512 {
1513         if(autocvar__menu_alpha == 1)
1514                 return;
1515
1516         if(!cursor_active)
1517         {
1518                 if(player.viewloc && (player.viewloc.spawnflags & VIEWLOC_FREEAIM))
1519                         ViewLocation_Mouse(); // NOTE: doesn't use cursormode
1520                 return;
1521         }
1522
1523         if (cursor_active == -1) // starting to display the cursor
1524         {
1525                 // since HUD_Mouse is called by CSQC_UpdateView before CSQC_InputEvent,
1526                 // in the first frame mousepos is the mouse position of the last time
1527                 // the cursor was displayed, thus we ignore it to avoid a glictch
1528                 cursor_active = 1;
1529                 return;
1530         }
1531
1532         if(!autocvar_hud_cursormode)
1533                 update_mousepos();
1534
1535         if(autocvar__hud_configure)
1536                 HUD_Panel_Mouse();
1537         else
1538         {
1539                 if (HUD_MinigameMenu_IsOpened())
1540                         HUD_Minigame_Mouse();
1541                 if (QuickMenu_IsOpened())
1542                         QuickMenu_Mouse();
1543                 if (HUD_Radar_Clickable())
1544                         HUD_Radar_Mouse();
1545         }
1546
1547         prevMouseClicked = mouseClicked;
1548
1549         HUD_Cursor_Show();
1550 }
1551
1552 bool ov_enabled;
1553 float oldr_nearclip;
1554 float oldr_farclip_base;
1555 float oldr_farclip_world;
1556 float oldr_novis;
1557 float oldr_useportalculling;
1558 float oldr_useinfinitefarclip;
1559
1560 float prev_myteam;
1561 int lasthud;
1562 float vh_notice_time;
1563 void CSQC_UpdateView(entity this, float w, float h)
1564 {
1565         TC(int, w); TC(int, h);
1566         entity e;
1567         float fov;
1568         float f;
1569         vector vf_size, vf_min;
1570         float a;
1571
1572         execute_next_frame();
1573
1574         ++framecount;
1575
1576         stats_get();
1577         hud = STAT(HUD);
1578
1579         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1580                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1581
1582         lasthud = hud;
1583
1584         ReplicateVars(false);
1585         if (ReplicateVars_NOT_SENDING())
1586                 ReplicateVars_DELAY(0.8 + random() * 0.4); // no need to check cvars every frame
1587
1588         HUD_Scale_Disable();
1589
1590         if(autocvar__hud_showbinds_reload) // menu can set this one
1591         {
1592                 db_close(binddb);
1593                 binddb = db_create();
1594                 cvar_set("_hud_showbinds_reload", "0");
1595         }
1596
1597         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1598                 view_quality = getproperty(VF_MINFPS_QUALITY);
1599         else
1600                 view_quality = 1;
1601
1602         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1603         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1604
1605         vf_size = getpropertyvec(VF_SIZE);
1606         vf_min = getpropertyvec(VF_MIN);
1607         vid_width = vf_size.x;
1608         vid_height = vf_size.y;
1609
1610         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1611         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1612
1613         WaypointSprite_Load();
1614
1615         CSQCPlayer_SetCamera();
1616
1617         if(player_localentnum <= maxclients) // is it a client?
1618                 current_player = player_localentnum - 1;
1619         else // then player_localentnum is the vehicle I'm driving
1620                 current_player = player_localnum;
1621         myteam = entcs_GetTeam(current_player);
1622
1623         if(myteam != prev_myteam)
1624         {
1625                 myteamcolors = colormapPaletteColor(myteam, 1);
1626                 FOREACH(hud_panels, true, it.update_time = time);
1627                 prev_myteam = myteam;
1628         }
1629
1630         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1631
1632         float is_dead = (STAT(HEALTH) <= 0);
1633
1634         // FIXME do we need this hack?
1635         if(isdemo())
1636         {
1637                 // in demos, input_buttons do not work
1638                 button_zoom = (autocvar__togglezoom == "-");
1639         }
1640         else if(button_zoom
1641                 && autocvar_cl_unpress_zoom_on_death
1642                 && (spectatee_status >= 0)
1643                 && (is_dead || intermission))
1644         {
1645                 // no zoom while dead or in intermission please
1646                 localcmd("-zoom\n");
1647                 button_zoom = false;
1648         }
1649
1650         // abused multiple places below
1651         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1652         if(!local_player)
1653                 local_player = this; // fall back!
1654
1655         // event chase camera
1656         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1657         {
1658                 if(STAT(CAMERA_SPECTATOR))
1659                 {
1660                         if(spectatee_status > 0)
1661                         {
1662                                 if(!autocvar_chase_active)
1663                                 {
1664                                         cvar_set("chase_active", "-2");
1665                                         goto skip_eventchase_death;
1666                                 }
1667                         }
1668                         else if(autocvar_chase_active == -2)
1669                                 cvar_set("chase_active", "0");
1670
1671                         if(autocvar_chase_active == -2)
1672                                 goto skip_eventchase_death;
1673                 }
1674                 else if(autocvar_chase_active == -2)
1675                         cvar_set("chase_active", "0");
1676
1677                 bool vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1678
1679                 float vehicle_viewdist = 0;
1680                 vector vehicle_viewofs = '0 0 0';
1681
1682                 if(vehicle_chase)
1683                 {
1684                         if(hud != HUD_BUMBLEBEE_GUN)
1685                         {
1686                                 Vehicle info = Vehicles_from(hud);
1687                                 vehicle_viewdist = info.height;
1688                                 vehicle_viewofs = info.view_ofs;
1689                                 if(vehicle_viewdist < 0) // when set below 0, this vehicle doesn't use third person view (gunner slots)
1690                                         vehicle_chase = false;
1691                         }
1692                         else
1693                                 vehicle_chase = false;
1694                 }
1695
1696                 int eventchase = WantEventchase(this, vehicle_chase);
1697                 if (eventchase)
1698                 {
1699                         vector current_view_origin_override = '0 0 0';
1700                         vector view_offset_override = '0 0 0';
1701                         float chase_distance_override = 0;
1702                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1703                         if(custom_eventchase)
1704                         {
1705                                 current_view_origin_override = M_ARGV(0, vector);
1706                                 view_offset_override = M_ARGV(1, vector);
1707                                 chase_distance_override = M_ARGV(0, float);
1708                         }
1709                         eventchase_running = true;
1710
1711                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1712                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1713                         if (custom_eventchase)
1714                                 current_view_origin = current_view_origin_override;
1715
1716                         // detect maximum viewoffset and use it
1717                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1718                         if(vehicle_chase)
1719                         {
1720                                 if(vehicle_viewofs)
1721                                         view_offset = vehicle_viewofs;
1722                                 else
1723                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1724                         }
1725                         if (custom_eventchase)
1726                                 view_offset = view_offset_override;
1727
1728                         if(view_offset)
1729                         {
1730                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1731                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1732                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1733                         }
1734
1735                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1736                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1737                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1738                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1739
1740                         // make the camera smooth back
1741                         float chase_distance = autocvar_cl_eventchase_distance;
1742                         if(vehicle_chase)
1743                         {
1744                                 if(vehicle_viewofs)
1745                                         chase_distance = vehicle_viewdist;
1746                                 else
1747                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1748                         }
1749                         if (custom_eventchase)
1750                                 chase_distance = chase_distance_override;
1751
1752                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1753                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1754                         else if(eventchase_current_distance != chase_distance)
1755                                 eventchase_current_distance = chase_distance;
1756
1757                         makevectors(view_angles);
1758
1759                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1760                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1761
1762                         // If the boxtrace fails, revert back to line tracing.
1763                         if(!local_player.viewloc)
1764                         if(trace_startsolid)
1765                         {
1766                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1767                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1768                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1769                         }
1770                         else { setproperty(VF_ORIGIN, trace_endpos); }
1771
1772                         if(!local_player.viewloc)
1773                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1774                 }
1775
1776                 if (eventchase <= 0 && autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1777                 {
1778                         eventchase_running = false;
1779                         cvar_set("chase_active", "0");
1780                         eventchase_current_distance = 0; // start from 0 next time
1781                 }
1782         }
1783         // workaround for camera stuck between player's legs when using chase_active 1
1784         // because the engine stops updating the chase_active camera when the game ends
1785         else if(intermission)
1786         {
1787                 cvar_settemp("chase_active", "-1");
1788                 eventchase_current_distance = 0;
1789         }
1790
1791         LABEL(skip_eventchase_death);
1792
1793         // do lockview after event chase camera so that it still applies whenever necessary.
1794         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1795         {
1796                 setproperty(VF_ORIGIN, freeze_org);
1797                 setproperty(VF_ANGLES, freeze_ang);
1798         }
1799         else
1800         {
1801                 freeze_org = getpropertyvec(VF_ORIGIN);
1802                 freeze_ang = getpropertyvec(VF_ANGLES);
1803         }
1804
1805         WarpZone_FixView();
1806         //WarpZone_FixPMove();
1807
1808         vector ov_org = '0 0 0';
1809         vector ov_mid = '0 0 0';
1810         vector ov_worldmin = '0 0 0';
1811         vector ov_worldmax = '0 0 0';
1812         if(autocvar_cl_orthoview)
1813         {
1814                 ov_worldmin = mi_picmin;
1815                 ov_worldmax = mi_picmax;
1816
1817                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1818                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1819                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1820
1821                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1822                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1823
1824                 float ov_nearest = vlen(ov_org - vec3(
1825                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1826                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1827                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1828                 ));
1829
1830                 float ov_furthest = 0;
1831                 float dist = 0;
1832
1833                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1834                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1835                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1836                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1837                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1838                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1839                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1840                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1841
1842                 if(!ov_enabled)
1843                 {
1844                         oldr_nearclip = cvar("r_nearclip");
1845                         oldr_farclip_base = cvar("r_farclip_base");
1846                         oldr_farclip_world = cvar("r_farclip_world");
1847                         oldr_novis = cvar("r_novis");
1848                         oldr_useportalculling = cvar("r_useportalculling");
1849                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1850                 }
1851
1852                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1853                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1854                 cvar_settemp("r_farclip_world", "0");
1855                 cvar_settemp("r_novis", "1");
1856                 cvar_settemp("r_useportalculling", "0");
1857                 cvar_settemp("r_useinfinitefarclip", "0");
1858
1859                 setproperty(VF_ORIGIN, ov_org);
1860                 setproperty(VF_ANGLES, '90 0 0');
1861
1862                 ov_enabled = true;
1863
1864                 #if 0
1865                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1866                         vtos(ov_org),
1867                         vtos(getpropertyvec(VF_ANGLES)),
1868                         ov_distance,
1869                         ov_nearest,
1870                         ov_furthest);
1871                 #endif
1872         }
1873         else
1874         {
1875                 if(ov_enabled)
1876                 {
1877                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1878                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1879                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1880                         cvar_set("r_novis", ftos(oldr_novis));
1881                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1882                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1883                 }
1884                 ov_enabled = false;
1885         }
1886
1887         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1888         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1889         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1890                 viewmodel_draw(viewmodels[slot]);
1891
1892         // Render the Scene
1893         view_origin = getpropertyvec(VF_ORIGIN);
1894         view_angles = getpropertyvec(VF_ANGLES);
1895         MAKEVECTORS(makevectors, view_angles, view_forward, view_right, view_up);
1896
1897 #ifdef BLURTEST
1898         if(time > blurtest_time0 && time < blurtest_time1)
1899         {
1900                 float r, t;
1901
1902                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1903                 r = t * blurtest_radius;
1904                 f = 1 / (t ** blurtest_power) - 1;
1905
1906                 cvar_set("r_glsl_postprocess", "1");
1907                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1908         }
1909         else
1910         {
1911                 cvar_set("r_glsl_postprocess", "0");
1912                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1913         }
1914 #endif
1915
1916         TargetMusic_Advance();
1917         Fog_Force();
1918         fpscounter_update();
1919
1920         if(drawtime == 0)
1921                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1922         else
1923                 drawframetime = bound(0.000001, time - drawtime, 1);
1924         drawtime = time;
1925
1926         // watch for gametype changes here...
1927         // in ParseStuffCMD the cmd isn't executed yet :/
1928         // might even be better to add the gametype to TE_CSQC_INIT...?
1929         if(!postinit)
1930                 PostInit();
1931
1932         if(intermission && !intermission_time)
1933                 intermission_time = time;
1934
1935         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1936         {
1937                 if(calledhooks & HOOK_START)
1938                 {
1939                         localcmd("\ncl_hook_gameend\n");
1940                         calledhooks |= HOOK_END;
1941                 }
1942         }
1943
1944         Announcer();
1945
1946         fov = autocvar_fov;
1947         if(fov <= 59.5)
1948         {
1949                 if(!zoomscript_caught)
1950                 {
1951                         localcmd("+button9\n");
1952                         zoomscript_caught = 1;
1953                 }
1954         }
1955         else
1956         {
1957                 if(zoomscript_caught)
1958                 {
1959                         localcmd("-button9\n");
1960                         zoomscript_caught = 0;
1961                 }
1962         }
1963
1964         if(active_minigame && HUD_MinigameMenu_IsOpened())
1965         {
1966                 if(!minigame_wasactive)
1967                 {
1968                         localcmd("+button12\n");
1969                         minigame_wasactive = true;
1970                 }
1971         }
1972         else if(minigame_wasactive)
1973         {
1974                 localcmd("-button12\n");
1975                 minigame_wasactive = false;
1976         }
1977
1978         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1979
1980         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1981         {
1982                 entity wepent = viewmodels[slot];
1983
1984                 if(wepent.last_switchweapon != wepent.switchweapon)
1985                 {
1986                         weapontime = time;
1987                         wepent.last_switchweapon = wepent.switchweapon;
1988                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1989                         {
1990                                 localcmd("-zoom\n");
1991                                 button_zoom = false;
1992                         }
1993                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1994                         {
1995                                 localcmd("-fire\n");
1996                                 localcmd("-fire2\n");
1997                                 button_attack2 = false;
1998                         }
1999                 }
2000                 if(wepent.last_activeweapon != wepent.activeweapon)
2001                 {
2002                         wepent.last_activeweapon = wepent.activeweapon;
2003
2004                         e = wepent.activeweapon;
2005                         if(e.netname != "")
2006                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
2007                         else if(slot == 0)
2008                                 localcmd("\ncl_hook_activeweapon none\n");
2009                 }
2010         }
2011
2012         // ALWAYS Clear Current Scene First
2013         clearscene();
2014
2015         setproperty(VF_ORIGIN, view_origin);
2016         setproperty(VF_ANGLES, view_angles);
2017
2018         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2019         setproperty(VF_SIZE, vf_size);
2020         setproperty(VF_MIN, vf_min);
2021
2022         // Assign Standard Viewflags
2023         // Draw the World (and sky)
2024         setproperty(VF_DRAWWORLD, 1);
2025
2026         // Set the console size vars
2027         vid_conwidth = autocvar_vid_conwidth;
2028         vid_conheight = autocvar_vid_conheight;
2029         vid_pixelheight = autocvar_vid_pixelheight;
2030
2031         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2032         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2033         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2034
2035         if(camera_active) // Camera for demo playback
2036         {
2037                 if(autocvar_camera_enable)
2038                         CSQC_Demo_Camera();
2039                 else
2040                 {
2041                         cvar_set("chase_active", ftos(chase_active_backup));
2042                         cvar_set("cl_demo_mousegrab", "0");
2043                         camera_active = false;
2044                 }
2045         }
2046         else
2047         {
2048 #ifdef CAMERATEST
2049                 if(autocvar_camera_enable)
2050 #else
2051                 if(autocvar_camera_enable && isdemo())
2052 #endif
2053                 {
2054                         // Enable required Darkplaces cvars
2055                         chase_active_backup = autocvar_chase_active;
2056                         cvar_set("chase_active", "2");
2057                         cvar_set("cl_demo_mousegrab", "1");
2058                         camera_active = true;
2059                         camera_mode = false;
2060                 }
2061         }
2062
2063         // Draw the Crosshair
2064         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2065
2066         // Draw the Engine Status Bar (the default Quake HUD)
2067         setproperty(VF_DRAWENGINESBAR, 0);
2068
2069         // Update the mouse position
2070         /*
2071            mousepos_x = vid_conwidth;
2072            mousepos_y = vid_conheight;
2073            mousepos = mousepos*0.5 + getmousepos();
2074          */
2075
2076         IL_EACH(g_drawables, it.draw, it.draw(it));
2077
2078         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS); // TODO: .health is used in cl_deathfade (a feature we have turned off currently)
2079         renderscene();
2080
2081         // now switch to 2D drawing mode by calling a 2D drawing function
2082         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2083         // next R_RenderScene call
2084         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2085
2086         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2087         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2088         {
2089                 // apply night vision effect
2090                 vector tc_00, tc_01, tc_10, tc_11;
2091                 vector rgb = '0 0 0';
2092
2093                 if(!nightvision_noise)
2094                 {
2095                         nightvision_noise = new(nightvision_noise);
2096                 }
2097                 if(!nightvision_noise2)
2098                 {
2099                         nightvision_noise2 = new(nightvision_noise2);
2100                 }
2101
2102                 // color tint in yellow
2103                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2104
2105                 // draw BG
2106                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2107                 rgb = '1 1 1';
2108                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2109                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2110                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2111                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2112                 tc_11 = tc_01 + tc_10 - tc_00;
2113                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2114                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2115                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2116                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2117                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2118                 R_EndPolygon();
2119
2120                 // draw FG
2121                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2122                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2123                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2124                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2125                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2126                 tc_11 = tc_01 + tc_10 - tc_00;
2127                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2128                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2129                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2130                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2131                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2132                 R_EndPolygon();
2133         }
2134
2135         if(autocvar_cl_reticle && !MUTATOR_CALLHOOK(DrawReticle))
2136         {
2137                 string reticle_image = string_null;
2138                 bool wep_zoomed = false;
2139                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2140                 {
2141                         entity wepe = viewmodels[slot];
2142                         Weapon wep = wepe.activeweapon;
2143                         if(wep != WEP_Null && wep.wr_zoom)
2144                         {
2145                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2146                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2147                                         reticle_image = wep.w_reticle;
2148                                 wep_zoomed += do_zoom;
2149                         }
2150                 }
2151                 // Draw the aiming reticle for weapons that use it
2152                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2153                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2154                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2155                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2156                 {
2157                         // no zoom reticle while dead
2158                         reticle_type = 0;
2159                 }
2160                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2161                 {
2162                         if(reticle_image) { reticle_type = 2; }
2163                         else { reticle_type = 0; }
2164                 }
2165                 else if(button_zoom || zoomscript_caught)
2166                 {
2167                         // normal zoom
2168                         reticle_type = 1;
2169                 }
2170
2171                 if(reticle_type)
2172                 {
2173                         if(autocvar_cl_reticle_stretch)
2174                         {
2175                                 reticle_size.x = vid_conwidth;
2176                                 reticle_size.y = vid_conheight;
2177                                 reticle_pos.x = 0;
2178                                 reticle_pos.y = 0;
2179                         }
2180                         else
2181                         {
2182                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2183                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2184                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2185                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2186                         }
2187
2188                         if(zoomscript_caught)
2189                                 f = 1;
2190                         else
2191                                 f = current_zoomfraction;
2192
2193                         if(f)
2194                         {
2195                                 switch(reticle_type)
2196                                 {
2197                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2198                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2199                                 }
2200                         }
2201                 }
2202         }
2203         else
2204         {
2205                 if(reticle_type != 0) { reticle_type = 0; }
2206         }
2207
2208
2209         // improved polyblend
2210         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2211         {
2212                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2213                 vector liquidcolor;
2214
2215                 switch(pointcontents(view_origin))
2216                 {
2217                         case CONTENT_WATER:
2218                                 liquidalpha = autocvar_hud_contents_water_alpha;
2219                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2220                                 incontent = 1;
2221                                 break;
2222
2223                         case CONTENT_LAVA:
2224                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2225                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2226                                 incontent = 1;
2227                                 break;
2228
2229                         case CONTENT_SLIME:
2230                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2231                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2232                                 incontent = 1;
2233                                 break;
2234
2235                         default:
2236                                 liquidalpha = 0;
2237                                 liquidcolor = '0 0 0';
2238                                 incontent = 0;
2239                                 break;
2240                 }
2241
2242                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2243                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2244                         contentfadetime = autocvar_hud_contents_fadeintime;
2245                         liquidalpha_prev = liquidalpha;
2246                         liquidcolor_prev = liquidcolor;
2247                 }
2248                 else
2249                         contentfadetime = autocvar_hud_contents_fadeouttime;
2250
2251                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2252                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2253
2254                 if(contentavgalpha)
2255                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2256
2257                 if(autocvar_hud_postprocessing)
2258                 {
2259                         if(autocvar_hud_contents_blur && contentavgalpha)
2260                         {
2261                                 content_blurpostprocess.x = 1;
2262                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2263                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2264                         }
2265                         else
2266                         {
2267                                 content_blurpostprocess.x = 0;
2268                                 content_blurpostprocess.y = 0;
2269                                 content_blurpostprocess.z = 0;
2270                         }
2271                 }
2272         }
2273
2274         if(autocvar_hud_damage && !STAT(FROZEN))
2275         {
2276                 splash_size.x = max(vid_conwidth, vid_conheight);
2277                 splash_size.y = max(vid_conwidth, vid_conheight);
2278                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2279                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2280
2281                 float myhealth_flash_temp;
2282                 myhealth = STAT(HEALTH);
2283
2284                 // fade out
2285                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2286                 // add new damage
2287                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2288
2289                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2290                 pain_threshold = autocvar_hud_damage_pain_threshold;
2291                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2292                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2293
2294                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2295                 {
2296                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2297                 }
2298
2299                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2300
2301                 if(myhealth_prev < 1)
2302                 {
2303                         if(myhealth >= 1)
2304                         {
2305                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2306                                 myhealth_flash_temp = 0;
2307                         }
2308                         else
2309                         {
2310                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2311                         }
2312                 }
2313
2314                 if(spectatee_status == -1 || intermission)
2315                 {
2316                         myhealth_flash = 0; // observing, or match ended
2317                         myhealth_flash_temp = 0;
2318                 }
2319
2320                 myhealth_prev = myhealth;
2321
2322                 // IDEA: change damage color/picture based on player model for robot/alien species?
2323                 // pro: matches model better
2324                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2325                 // maybe different reddish pics?
2326                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2327                 {
2328                         if(autocvar_cl_gentle_damage == 2)
2329                         {
2330                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2331                                         myhealth_gentlergb = randomvec();
2332                         }
2333                         else
2334                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2335
2336                         if(myhealth_flash_temp > 0)
2337                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2338                 }
2339                 else if(myhealth_flash_temp > 0)
2340                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2341
2342                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2343                 {
2344                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2345                         {
2346                                 damage_blurpostprocess.x = 1;
2347                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2348                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2349                         }
2350                         else
2351                         {
2352                                 damage_blurpostprocess.x = 0;
2353                                 damage_blurpostprocess.y = 0;
2354                                 damage_blurpostprocess.z = 0;
2355                         }
2356                 }
2357         }
2358
2359         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2360         float e2 = (autocvar_hud_powerup != 0);
2361         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2362         {
2363                 // enable or disable rendering types if they are used or not
2364                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2365                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2366
2367                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2368                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2369                 {
2370                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2371                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2372                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2373                         {
2374                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2375                                 old_blurradius = blurradius;
2376                                 old_bluralpha = bluralpha;
2377                         }
2378                 }
2379                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2380                 {
2381                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2382                         old_blurradius = 0;
2383                         old_bluralpha = 0;
2384                 }
2385
2386                 // edge detection postprocess handling done second (used by hud_powerup)
2387                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2388                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2389                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2390
2391                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2392
2393                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2394                 {
2395                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2396                         {
2397                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2398                                 old_sharpen_intensity = sharpen_intensity;
2399                         }
2400                 }
2401                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2402                 {
2403                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2404                         old_sharpen_intensity = 0;
2405                 }
2406
2407                 if(cvar("r_glsl_postprocess") == 0)
2408                         cvar_set("r_glsl_postprocess", "2");
2409         }
2410         else if(cvar("r_glsl_postprocess") == 2)
2411                 cvar_set("r_glsl_postprocess", "0");
2412
2413         /*if(ISGAMETYPE(CTF))
2414           {
2415           ctf_view();
2416           } else */
2417
2418         // draw 2D entities
2419         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2420         Draw_ShowNames_All();
2421 #if ENABLE_DEBUGDRAW
2422         Debug_Draw();
2423 #endif
2424
2425         scoreboard_active = Scoreboard_WouldDraw();
2426
2427         HUD_Draw(this); // this parameter for deep vehicle function
2428
2429         if(NextFrameCommand)
2430         {
2431                 localcmd("\n", NextFrameCommand, "\n");
2432                 NextFrameCommand = string_null;
2433         }
2434
2435         // we must do this check AFTER a frame was rendered, or it won't work
2436         if(cs_project_is_b0rked == 0)
2437         {
2438                 string w0, h0;
2439                 w0 = ftos(autocvar_vid_conwidth);
2440                 h0 = ftos(autocvar_vid_conheight);
2441                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2442                 //setproperty(VF_FOV, '90 90 0');
2443                 setproperty(VF_ORIGIN, '0 0 0');
2444                 setproperty(VF_ANGLES, '0 0 0');
2445                 setproperty(VF_PERSPECTIVE, 1);
2446                 makevectors('0 0 0');
2447                 vector v1, v2;
2448                 cvar_set("vid_conwidth", "800");
2449                 cvar_set("vid_conheight", "600");
2450                 v1 = cs_project(v_forward);
2451                 cvar_set("vid_conwidth", "640");
2452                 cvar_set("vid_conheight", "480");
2453                 v2 = cs_project(v_forward);
2454                 if(v1 == v2)
2455                         cs_project_is_b0rked = 1;
2456                 else
2457                         cs_project_is_b0rked = -1;
2458                 cvar_set("vid_conwidth", w0);
2459                 cvar_set("vid_conheight", h0);
2460         }
2461
2462         HUD_Mouse(local_player);
2463
2464         cl_notice_run();
2465         unpause_update();
2466         Net_Flush();
2467
2468         // let's reset the view back to normal for the end
2469         setproperty(VF_MIN, '0 0 0');
2470         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2471
2472         IL_ENDFRAME();
2473 }
2474
2475
2476 // following vectors must be global to allow seamless switching between camera modes
2477 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2478 void CSQC_Demo_Camera()
2479 {
2480         float speed, attenuation, dimensions;
2481         vector tmp, delta;
2482
2483         if( autocvar_camera_reset || !camera_mode )
2484         {
2485                 camera_offset = '0 0 0';
2486                 current_angles = '0 0 0';
2487                 camera_direction = '0 0 0';
2488                 camera_offset.z += 30;
2489                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2490                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2491                 current_origin = view_origin;
2492                 current_camera_offset  = camera_offset;
2493                 cvar_set("camera_reset", "0");
2494                 camera_mode = CAMERA_CHASE;
2495         }
2496
2497         // Camera angles
2498         if( camera_roll )
2499                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2500
2501         if(autocvar_camera_look_player)
2502         {
2503                 vector dir;
2504                 float n;
2505
2506                 dir = normalize(view_origin - current_position);
2507                 n = mouse_angles.z;
2508                 mouse_angles = vectoangles(dir);
2509                 mouse_angles.x = mouse_angles.x * -1;
2510                 mouse_angles.z = n;
2511         }
2512         else
2513         {
2514                 tmp = getmousepos() * 0.1;
2515                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2516                 {
2517                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2518                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2519                 }
2520         }
2521
2522         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2523         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2524         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2525         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2526
2527         // Fix difference when angles don't have the same sign
2528         delta = '0 0 0';
2529         if(mouse_angles.y < -60 && current_angles.y > 60)
2530                 delta = '0 360 0';
2531         if(mouse_angles.y > 60 && current_angles.y < -60)
2532                 delta = '0 -360 0';
2533
2534         if(autocvar_camera_look_player)
2535                 attenuation = autocvar_camera_look_attenuation;
2536         else
2537                 attenuation = autocvar_camera_speed_attenuation;
2538
2539         attenuation = 1 / max(1, attenuation);
2540         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2541
2542         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2543         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2544         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2545         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2546
2547         // Camera position
2548         tmp = '0 0 0';
2549         dimensions = 0;
2550
2551         if( camera_direction.x )
2552         {
2553                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2554                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2555                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2556                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2557                 ++dimensions;
2558         }
2559
2560         if( camera_direction.y )
2561         {
2562                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2563                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2564                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2565                 ++dimensions;
2566         }
2567
2568         if( camera_direction.z )
2569         {
2570                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2571                 ++dimensions;
2572         }
2573
2574         if(autocvar_camera_free)
2575                 speed = autocvar_camera_speed_free;
2576         else
2577                 speed = autocvar_camera_speed_chase;
2578
2579         if(dimensions)
2580         {
2581                 speed = speed * sqrt(1 / dimensions);
2582                 camera_offset += tmp * speed;
2583         }
2584
2585         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2586
2587         // Camera modes
2588         if( autocvar_camera_free )
2589         {
2590                 if ( camera_mode == CAMERA_CHASE )
2591                 {
2592                         current_camera_offset = current_origin + current_camera_offset;
2593                         camera_offset = current_origin + camera_offset;
2594                 }
2595
2596                 camera_mode = CAMERA_FREE;
2597                 current_position = current_camera_offset;
2598         }
2599         else
2600         {
2601                 if ( camera_mode == CAMERA_FREE )
2602                 {
2603                         current_origin = view_origin;
2604                         camera_offset = camera_offset - current_origin;
2605                         current_camera_offset = current_camera_offset - current_origin;
2606                 }
2607
2608                 camera_mode = CAMERA_CHASE;
2609
2610                 if(autocvar_camera_chase_smoothly)
2611                         current_origin += (view_origin - current_origin) * attenuation;
2612                 else
2613                         current_origin = view_origin;
2614
2615                 current_position = current_origin + current_camera_offset;
2616         }
2617
2618         setproperty(VF_ANGLES, current_angles);
2619         setproperty(VF_ORIGIN, current_position);
2620 }