qcsrc/client/view.qc

   1 #include "_all.qh"
   2
   3 #include "announcer.qh"
   4 #include "hook.qh"
   5 #include "hud.qh"
   6 #include "hud_config.qh"
   7 #include "mapvoting.qh"
   8 #include "noise.qh"
   9 #include "scoreboard.qh"
  10 #include "shownames.qh"
  11 #include "vehicles/all.qh"
  12 #include "waypointsprites.qh"
  13
  14 #include "../common/constants.qh"
  15 #include "../common/mapinfo.qh"
  16 #include "../common/nades.qh"
  17 #include "../common/stats.qh"
  18 #include "../common/triggers/target/music.qh"
  19 #include "../common/teams.qh"
  20 #include "../common/util.qh"
  21
  22 #include "../common/weapons/all.qh"
  23
  24 #include "../csqcmodellib/cl_player.qh"
  25
  26 #include "../warpzonelib/client.qh"
  27 #include "../warpzonelib/common.qh"
  28 #include "../warpzonelib/mathlib.qh"
  29
  30 entity porto;
  31 vector polyline[16];
  32 void Porto_Draw()
  33 {
  34         vector p, dir, ang, q, nextdir;
  35         float portal_number, portal1_idx;
  36
  37         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
  38                 return;
  39         if(g_balance_porto_secondary)
  40                 return;
  41         if(intermission == 1)
  42                 return;
  43         if(intermission == 2)
  44                 return;
  45         if (getstati(STAT_HEALTH) <= 0)
  46                 return;
  47
  48         dir = view_forward;
  49
  50         if(angles_held_status)
  51         {
  52                 makevectors(angles_held);
  53                 dir = v_forward;
  54         }
  55
  56         p = view_origin;
  57
  58         polyline[0] = p;
  59         int idx = 1;
  60         portal_number = 0;
  61         nextdir = dir;
  62
  63         for (;;)
  64         {
  65                 dir = nextdir;
  66                 traceline(p, p + 65536 * dir, true, porto);
  67                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  68                         return;
  69                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
  70                 p = trace_endpos;
  71                 polyline[idx] = p;
  72                 ++idx;
  73                 if(idx >= 16)
  74                         return;
  75                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
  76                         continue;
  77                 ++portal_number;
  78                 ang = vectoangles2(trace_plane_normal, dir);
  79                 ang.x = -ang.x;
  80                 makevectors(ang);
  81                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
  82                         return;
  83                 if(portal_number == 1)
  84                 {
  85                         portal1_idx = idx;
  86                         if(portal_number >= 2)
  87                                 break;
  88                 }
  89         }
  90
  91         while(idx >= 2)
  92         {
  93                 p = polyline[idx-2];
  94                 q = polyline[idx-1];
  95                 if(idx == 2)
  96                         p = p - view_up * 16;
  97                 if(idx-1 >= portal1_idx)
  98                 {
  99                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 100                 }
 101                 else
 102                 {
 103                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 104                 }
 105                 --idx;
 106         }
 107 }
 108
 109 void Porto_Init()
 110 {
 111         porto = spawn();
 112         porto.classname = "porto";
 113         porto.draw = Porto_Draw;
 114         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 115 }
 116
 117 float drawtime;
 118 float avgspeed;
 119 vector GetCurrentFov(float fov)
 120 {
 121         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 122         float velocityzoom, curspeed;
 123         vector v;
 124
 125         zoomsensitivity = autocvar_cl_zoomsensitivity;
 126         zoomfactor = autocvar_cl_zoomfactor;
 127         if(zoomfactor < 1 || zoomfactor > 16)
 128                 zoomfactor = 2.5;
 129         zoomspeed = autocvar_cl_zoomspeed;
 130         if(zoomspeed >= 0)
 131         if(zoomspeed < 0.5 || zoomspeed > 16)
 132                         zoomspeed = 3.5;
 133
 134         zoomdir = button_zoom;
 135         if(hud == HUD_NORMAL)
 136         if((activeweapon == WEP_VORTEX && vortex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 137                 zoomdir += button_attack2;
 138         if(spectatee_status > 0 || isdemo())
 139         {
 140                 if(spectatorbutton_zoom)
 141                 {
 142                         if(zoomdir)
 143                                 zoomdir = 0;
 144                         else
 145                                 zoomdir = 1;
 146                 }
 147                 // fteqcc failed twice here already, don't optimize this
 148         }
 149
 150         if(zoomdir) { zoomin_effect = 0; }
 151
 152         if(camera_active)
 153         {
 154                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 155         }
 156         else if(autocvar_cl_spawnzoom && zoomin_effect)
 157         {
 158                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 16);
 159
 160                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 161                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 162                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 163         }
 164         else
 165         {
 166                 if(zoomspeed < 0) // instant zoom
 167                 {
 168                         if(zoomdir)
 169                                 current_viewzoom = 1 / zoomfactor;
 170                         else
 171                                 current_viewzoom = 1;
 172                 }
 173                 else
 174                 {
 175                         if(zoomdir)
 176                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 177                         else
 178                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 179                 }
 180         }
 181
 182         if(almost_equals(current_viewzoom, 1))
 183                 current_zoomfraction = 0;
 184         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 185                 current_zoomfraction = 1;
 186         else
 187                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 188
 189         if(zoomsensitivity < 1)
 190                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 191         else
 192                 setsensitivityscale(1);
 193
 194         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 195         {
 196                 if(intermission) { curspeed = 0; }
 197                 else
 198                 {
 199
 200                         makevectors(view_angles);
 201                         v = pmove_vel;
 202                         if(csqcplayer)
 203                                 v = csqcplayer.velocity;
 204
 205                         switch(autocvar_cl_velocityzoom_type)
 206                         {
 207                                 case 3: curspeed = max(0, v_forward * v); break;
 208                                 case 2: curspeed = (v_forward * v); break;
 209                                 case 1: default: curspeed = vlen(v); break;
 210                         }
 211                 }
 212
 213                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 214                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 215                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 216
 217                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 218         }
 219         else
 220                 velocityzoom = 1;
 221
 222         float frustumx, frustumy, fovx, fovy;
 223         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 224         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 225         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 226         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 227
 228         return '1 0 0' * fovx + '0 1 0' * fovy;
 229 }
 230
 231 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 232 {
 233         float fovx, fovy;
 234         float width = (ov_worldmax.x - ov_worldmin.x);
 235         float height = (ov_worldmax.y - ov_worldmin.y);
 236         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 237         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 238         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 239         return '1 0 0' * fovx + '0 1 0' * fovy;
 240 }
 241
 242 // this function must match W_SetupShot!
 243 float zoomscript_caught;
 244
 245 vector wcross_origin;
 246 float wcross_scale_prev, wcross_alpha_prev;
 247 vector wcross_color_prev;
 248 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 249 vector wcross_color_goal_prev;
 250 float wcross_changedonetime;
 251
 252 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 253 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 254 float wcross_name_changestarttime, wcross_name_changedonetime;
 255 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 256
 257 float wcross_ring_prev;
 258
 259 entity trueaim;
 260 entity trueaim_rifle;
 261
 262 const float SHOTTYPE_HITTEAM = 1;
 263 const float SHOTTYPE_HITOBSTRUCTION = 2;
 264 const float SHOTTYPE_HITWORLD = 3;
 265 const float SHOTTYPE_HITENEMY = 4;
 266
 267 void TrueAim_Init()
 268 {
 269         trueaim = spawn();
 270         trueaim.classname = "trueaim";
 271         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 272         trueaim_rifle = spawn();
 273         trueaim_rifle.classname = "trueaim_rifle";
 274         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 275 }
 276
 277 float EnemyHitCheck()
 278 {
 279         float t, n;
 280         wcross_origin = project_3d_to_2d(trace_endpos);
 281         wcross_origin.z = 0;
 282         if(trace_ent)
 283                 n = trace_ent.entnum;
 284         else
 285                 n = trace_networkentity;
 286         if(n < 1)
 287                 return SHOTTYPE_HITWORLD;
 288         if(n > maxclients)
 289                 return SHOTTYPE_HITWORLD;
 290         t = GetPlayerColor(n - 1);
 291         if(teamplay)
 292                 if(t == myteam)
 293                         return SHOTTYPE_HITTEAM;
 294         if(t == NUM_SPECTATOR)
 295                 return SHOTTYPE_HITWORLD;
 296         return SHOTTYPE_HITENEMY;
 297 }
 298
 299 float TrueAimCheck()
 300 {
 301         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 302         vector vecs, trueaimpoint, w_shotorg;
 303         vector mi, ma, dv;
 304         float shottype;
 305         entity ta;
 306         float mv;
 307
 308         mi = ma = '0 0 0';
 309         ta = trueaim;
 310         mv = MOVE_NOMONSTERS;
 311
 312         switch(activeweapon) // WEAPONTODO
 313         {
 314                 case WEP_TUBA: // no aim
 315                 case WEP_PORTO: // shoots from eye
 316                 case WEP_HOOK: // no trueaim
 317                 case WEP_MORTAR: // toss curve
 318                         return SHOTTYPE_HITWORLD;
 319                 case WEP_VORTEX:
 320                 case WEP_VAPORIZER:
 321                         mv = MOVE_NORMAL;
 322                         break;
 323                 case WEP_RIFLE:
 324                         ta = trueaim_rifle;
 325                         mv = MOVE_NORMAL;
 326                         if(zoomscript_caught)
 327                         {
 328                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 329                                 return EnemyHitCheck();
 330                         }
 331                         break;
 332                 case WEP_DEVASTATOR: // projectile has a size!
 333                         mi = '-3 -3 -3';
 334                         ma = '3 3 3';
 335                         break;
 336                 case WEP_FIREBALL: // projectile has a size!
 337                         mi = '-16 -16 -16';
 338                         ma = '16 16 16';
 339                         break;
 340                 case WEP_SEEKER: // projectile has a size!
 341                         mi = '-2 -2 -2';
 342                         ma = '2 2 2';
 343                         break;
 344                 case WEP_ELECTRO: // projectile has a size!
 345                         mi = '0 0 -3';
 346                         ma = '0 0 -3';
 347                         break;
 348         }
 349
 350         vector traceorigin = getplayerorigin(player_localentnum-1) + (eZ * getstati(STAT_VIEWHEIGHT));
 351
 352         vecs = decompressShotOrigin(getstati(STAT_SHOTORG));
 353
 354         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 355         trueaimpoint = trace_endpos;
 356
 357         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 358                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 359
 360         if(vecs.x > 0)
 361                 vecs.y = -vecs.y;
 362         else
 363                 vecs = '0 0 0';
 364
 365         dv = view_right * vecs.y + view_up * vecs.z;
 366         w_shotorg = traceorigin + dv;
 367
 368         // now move the vecs forward as much as requested if possible
 369         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 370         w_shotorg = trace_endpos - view_forward * nudge;
 371
 372         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 373         shottype = EnemyHitCheck();
 374         if(shottype != SHOTTYPE_HITWORLD)
 375                 return shottype;
 376
 377 #if 0
 378         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 379         // or rather, I know why, but see no fix
 380         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 381                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 382                 return SHOTTYPE_HITOBSTRUCTION;
 383 #endif
 384
 385         return SHOTTYPE_HITWORLD;
 386 }
 387
 388 void CSQC_common_hud(void);
 389
 390 void PostInit(void);
 391 void CSQC_Demo_Camera();
 392 float HUD_WouldDrawScoreboard();
 393 float camera_mode;
 394 const float CAMERA_FREE = 1;
 395 const float CAMERA_CHASE = 2;
 396 float reticle_type;
 397 string reticle_image;
 398 string NextFrameCommand;
 399 void CSQC_SPIDER_HUD();
 400 void CSQC_RAPTOR_HUD();
 401
 402 vector freeze_org, freeze_ang;
 403 entity nightvision_noise, nightvision_noise2;
 404
 405 const float MAX_TIME_DIFF = 5;
 406 float pickup_crosshair_time, pickup_crosshair_size;
 407 float hitindication_crosshair_size;
 408 float use_vortex_chargepool;
 409
 410 float myhealth, myhealth_prev;
 411 float myhealth_flash;
 412
 413 float old_blurradius, old_bluralpha;
 414 float old_sharpen_intensity;
 415
 416 vector myhealth_gentlergb;
 417
 418 float contentavgalpha, liquidalpha_prev;
 419 vector liquidcolor_prev;
 420
 421 float eventchase_current_distance;
 422 float eventchase_running;
 423 float WantEventchase()
 424 {
 425         if(autocvar_cl_orthoview)
 426                 return false;
 427         if(intermission)
 428                 return true;
 429         if(spectatee_status >= 0)
 430         {
 431                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WepSet_FromWeapon(WEP_PORTO)))
 432                         return true;
 433                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 434                 {
 435                         if(autocvar_cl_eventchase_death == 2)
 436                         {
 437                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 438                                 if(self.velocity == '0 0 0' || eventchase_running)
 439                                         return true;
 440                         }
 441                         else return true;
 442                 }
 443         }
 444         return false;
 445 }
 446
 447 vector damage_blurpostprocess, content_blurpostprocess;
 448
 449 float checkfail[16];
 450
 451 float unaccounted_damage = 0;
 452 void UpdateDamage()
 453 {
 454         // accumulate damage with each stat update
 455         static float damage_total_prev = 0;
 456         float damage_total = getstati(STAT_DAMAGE_DEALT_TOTAL);
 457         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 458         damage_total_prev = damage_total;
 459
 460         static float damage_dealt_time_prev = 0;
 461         float damage_dealt_time = getstatf(STAT_HIT_TIME);
 462         if (damage_dealt_time != damage_dealt_time_prev)
 463         {
 464                 unaccounted_damage += unaccounted_damage_new;
 465                 dprint("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 466         }
 467         damage_dealt_time_prev = damage_dealt_time;
 468
 469         // prevent hitsound when switching spectatee
 470         static float spectatee_status_prev = 0;
 471         if (spectatee_status != spectatee_status_prev)
 472                 unaccounted_damage = 0;
 473         spectatee_status_prev = spectatee_status;
 474 }
 475
 476 void UpdateHitsound()
 477 {
 478         // varying sound pitch
 479
 480         static float hitsound_time_prev = 0;
 481         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 482         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 483         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 484         {
 485                 if (autocvar_cl_hitsound && unaccounted_damage)
 486                 {
 487                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 488                         float a = autocvar_cl_hitsound_max_pitch;
 489                         float b = autocvar_cl_hitsound_min_pitch;
 490                         float c = autocvar_cl_hitsound_nom_damage;
 491                         float x = unaccounted_damage;
 492                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 493
 494                         // if sound variation is disabled, set pitch_shift to 1
 495                         if (autocvar_cl_hitsound == 1)
 496                                 pitch_shift = 1;
 497
 498                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 499                         if (autocvar_cl_hitsound == 3)
 500                         {
 501                                 float mirror_value = (a-b)/2 + b;
 502                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 503                         }
 504
 505                         dprint("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 506
 507                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 508                         // todo: normalize sound pressure levels? seems unnecessary
 509
 510                         sound7(world, CH_INFO, "misc/hit.wav", VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 511                 }
 512                 unaccounted_damage = 0;
 513                 hitsound_time_prev = time;
 514         }
 515
 516         static float typehit_time_prev = 0;
 517         float typehit_time = getstatf(STAT_TYPEHIT_TIME);
 518         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 519         {
 520                 sound(world, CH_INFO, "misc/typehit.wav", VOL_BASE, ATTN_NONE);
 521                 typehit_time_prev = typehit_time;
 522         }
 523 }
 524
 525 void UpdateCrosshair()
 526 {
 527         static float rainbow_last_flicker;
 528     static vector rainbow_prev_color;
 529         entity e = self;
 530         float f, i, j;
 531         vector v;
 532         if(getstati(STAT_FROZEN))
 533                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, ((getstatf(STAT_REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * getstatf(STAT_REVIVE_PROGRESS)) + ('0 1 1' * getstatf(STAT_REVIVE_PROGRESS) * -1)) : '0.25 0.90 1'), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 534         else if (getstatf(STAT_HEALING_ORB)>time)
 535                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, Nade_Color(NADE_TYPE_HEAL), autocvar_hud_colorflash_alpha*getstatf(STAT_HEALING_ORB_ALPHA), DRAWFLAG_ADDITIVE);
 536         if(!intermission)
 537         if(getstatf(STAT_NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
 538         {
 539                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * getstatf(STAT_NADE_TIMER)) - ('0 1 1' * getstatf(STAT_NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 540                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 541         }
 542         else if(getstatf(STAT_REVIVE_PROGRESS))
 543         {
 544                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", getstatf(STAT_REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
 545                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
 546         }
 547
 548         if(autocvar_r_letterbox == 0)
 549                 if(autocvar_viewsize < 120)
 550                         CSQC_common_hud();
 551
 552         // crosshair goes VERY LAST
 553         if(!scoreboard_active && !camera_active && intermission != 2 && spectatee_status != -1 && hud == HUD_NORMAL)
 554         {
 555                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 556                         return;
 557
 558                 string wcross_style;
 559                 float wcross_alpha, wcross_resolution;
 560                 wcross_style = autocvar_crosshair;
 561                 if (wcross_style == "0")
 562                         return;
 563                 wcross_resolution = autocvar_crosshair_size;
 564                 if (wcross_resolution == 0)
 565                         return;
 566                 wcross_alpha = autocvar_crosshair_alpha;
 567                 if (wcross_alpha == 0)
 568                         return;
 569
 570                 // TrueAim check
 571                 float shottype;
 572
 573                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 574                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 575                 wcross_origin.z = 0;
 576                 if(autocvar_crosshair_hittest)
 577                 {
 578                         vector wcross_oldorigin;
 579                         wcross_oldorigin = wcross_origin;
 580                         shottype = TrueAimCheck();
 581                         if(shottype == SHOTTYPE_HITWORLD)
 582                         {
 583                                 v = wcross_origin - wcross_oldorigin;
 584                                 v.x /= vid_conwidth;
 585                                 v.y /= vid_conheight;
 586                                 if(vlen(v) > 0.01)
 587                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 588                         }
 589                         if(!autocvar_crosshair_hittest_showimpact)
 590                                 wcross_origin = wcross_oldorigin;
 591                 }
 592                 else
 593                         shottype = SHOTTYPE_HITWORLD;
 594
 595                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 596                 string wcross_name = "";
 597                 float wcross_scale, wcross_blur;
 598
 599                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 600                 {
 601                         e = get_weaponinfo(switchingweapon);
 602                         if(e)
 603                         {
 604                                 if(autocvar_crosshair_per_weapon)
 605                                 {
 606                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 607                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 608                                         //if (wcross_resolution == 0)
 609                                                 //return;
 610
 611                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 612                                         wcross_resolution *= e.w_crosshair_size;
 613                                         wcross_name = e.w_crosshair;
 614                                 }
 615                         }
 616                 }
 617
 618                 if(wcross_name == "")
 619                         wcross_name = strcat("gfx/crosshair", wcross_style);
 620
 621                 // MAIN CROSSHAIR COLOR DECISION
 622                 switch(autocvar_crosshair_color_special)
 623                 {
 624                         case 1: // crosshair_color_per_weapon
 625                         {
 626                                 if(e)
 627                                 {
 628                                         wcross_color = e.wpcolor;
 629                                         break;
 630                                 }
 631                                 else { goto normalcolor; }
 632                         }
 633
 634                         case 2: // crosshair_color_by_health
 635                         {
 636                                 float x = getstati(STAT_HEALTH);
 637
 638                                 //x = red
 639                                 //y = green
 640                                 //z = blue
 641
 642                                 wcross_color.z = 0;
 643
 644                                 if(x > 200)
 645                                 {
 646                                         wcross_color.x = 0;
 647                                         wcross_color.y = 1;
 648                                 }
 649                                 else if(x > 150)
 650                                 {
 651                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 652                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 653                                 }
 654                                 else if(x > 100)
 655                                 {
 656                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 657                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 658                                         wcross_color.z = 1 - (x-100)*0.02;
 659                                 }
 660                                 else if(x > 50)
 661                                 {
 662                                         wcross_color.x = 1;
 663                                         wcross_color.y = 1;
 664                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 665                                 }
 666                                 else if(x > 20)
 667                                 {
 668                                         wcross_color.x = 1;
 669                                         wcross_color.y = (x-20)*90/27/100;
 670                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 671                                 }
 672                                 else
 673                                 {
 674                                         wcross_color.x = 1;
 675                                         wcross_color.y = 0;
 676                                 }
 677                                 break;
 678                         }
 679
 680                         case 3: // crosshair_color_rainbow
 681                         {
 682                                 if(time >= rainbow_last_flicker)
 683                                 {
 684                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
 685                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
 686                                 }
 687                                 wcross_color = rainbow_prev_color;
 688                                 break;
 689                         }
 690                         :normalcolor
 691                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
 692                 }
 693
 694                 if(autocvar_crosshair_effect_scalefade)
 695                 {
 696                         wcross_scale = wcross_resolution;
 697                         wcross_resolution = 1;
 698                 }
 699                 else
 700                 {
 701                         wcross_scale = 1;
 702                 }
 703
 704                 if(autocvar_crosshair_pickup)
 705                 {
 706                         float stat_pickup_time = getstatf(STAT_LAST_PICKUP);
 707
 708                         if(pickup_crosshair_time < stat_pickup_time)
 709                         {
 710                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
 711                                         pickup_crosshair_size = 1;
 712
 713                                 pickup_crosshair_time = stat_pickup_time;
 714                         }
 715
 716                         if(pickup_crosshair_size > 0)
 717                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
 718                         else
 719                                 pickup_crosshair_size = 0;
 720
 721                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
 722                 }
 723
 724                 // todo: make crosshair hit indication dependent on damage dealt
 725                 if(autocvar_crosshair_hitindication)
 726                 {
 727                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
 728
 729                         if(unaccounted_damage)
 730                         {
 731                                 hitindication_crosshair_size = 1;
 732                         }
 733
 734                         if(hitindication_crosshair_size > 0)
 735                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
 736                         else
 737                                 hitindication_crosshair_size = 0;
 738
 739                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
 740                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
 741                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
 742                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
 743                 }
 744
 745                 if(shottype == SHOTTYPE_HITENEMY)
 746                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
 747                 if(shottype == SHOTTYPE_HITTEAM)
 748                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
 749
 750                 f = fabs(autocvar_crosshair_effect_time);
 751                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
 752                 {
 753                         wcross_changedonetime = time + f;
 754                 }
 755                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
 756                 {
 757                         wcross_name_changestarttime = time;
 758                         wcross_name_changedonetime = time + f;
 759                         if(wcross_name_goal_prev_prev)
 760                                 strunzone(wcross_name_goal_prev_prev);
 761                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
 762                         wcross_name_goal_prev = strzone(wcross_name);
 763                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
 764                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
 765                         wcross_resolution_goal_prev = wcross_resolution;
 766                 }
 767
 768                 wcross_scale_goal_prev = wcross_scale;
 769                 wcross_alpha_goal_prev = wcross_alpha;
 770                 wcross_color_goal_prev = wcross_color;
 771
 772                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
 773                 {
 774                         wcross_blur = 1;
 775                         wcross_alpha *= 0.75;
 776                 }
 777                 else
 778                         wcross_blur = 0;
 779                 // *_prev is at time-frametime
 780                 // * is at wcross_changedonetime+f
 781                 // what do we have at time?
 782                 if(time < wcross_changedonetime)
 783                 {
 784                         f = frametime / (wcross_changedonetime - time + frametime);
 785                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
 786                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
 787                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
 788                 }
 789
 790                 wcross_scale_prev = wcross_scale;
 791                 wcross_alpha_prev = wcross_alpha;
 792                 wcross_color_prev = wcross_color;
 793
 794                 wcross_scale *= 1 - autocvar__menu_alpha;
 795                 wcross_alpha *= 1 - autocvar__menu_alpha;
 796                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 797
 798                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
 799                 {
 800                         // crosshair rings for weapon stats
 801                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
 802                         {
 803                                 // declarations and stats
 804                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
 805                                 string ring_image = string_null, ring_inner_image = string_null;
 806                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
 807
 808                                 ring_scale = autocvar_crosshair_ring_size;
 809
 810                                 float weapon_clipload, weapon_clipsize;
 811                                 weapon_clipload = getstati(STAT_WEAPON_CLIPLOAD);
 812                                 weapon_clipsize = getstati(STAT_WEAPON_CLIPSIZE);
 813
 814                                 float ok_ammo_charge, ok_ammo_chargepool;
 815                                 ok_ammo_charge = getstatf(STAT_OK_AMMO_CHARGE);
 816                                 ok_ammo_chargepool = getstatf(STAT_OK_AMMO_CHARGEPOOL);
 817
 818                                 float vortex_charge, vortex_chargepool;
 819                                 vortex_charge = getstatf(STAT_VORTEX_CHARGE);
 820                                 vortex_chargepool = getstatf(STAT_VORTEX_CHARGEPOOL);
 821
 822                                 float arc_heat = getstatf(STAT_ARC_HEAT);
 823
 824                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
 825                                         vortex_charge_movingavg = vortex_charge;
 826
 827
 828                                 // handle the values
 829                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
 830                                 {
 831                                         if (vortex_chargepool || use_vortex_chargepool) {
 832                                                 use_vortex_chargepool = 1;
 833                                                 ring_inner_value = vortex_chargepool;
 834                                         } else {
 835                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
 836                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
 837                                         }
 838
 839                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
 840                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
 841                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
 842
 843                                         // draw the outer ring to show the current charge of the weapon
 844                                         ring_value = vortex_charge;
 845                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
 846                                         ring_rgb = wcross_color;
 847                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
 848                                 }
 849                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
 850                                 {
 851                                         ring_value = bound(0, getstati(STAT_LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
 852                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
 853                                         ring_rgb = wcross_color;
 854                                         ring_image = "gfx/crosshair_ring.tga";
 855                                 }
 856                                 else if (activeweapon == WEP_HAGAR && getstati(STAT_HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
 857                                 {
 858                                         ring_value = bound(0, getstati(STAT_HAGAR_LOAD) / hagar_maxrockets, 1);
 859                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
 860                                         ring_rgb = wcross_color;
 861                                         ring_image = "gfx/crosshair_ring.tga";
 862                                 }
 863                                 else if (ok_ammo_charge)
 864                                 {
 865                                         ring_value = ok_ammo_chargepool;
 866                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 867                                         ring_rgb = wcross_color;
 868                                         ring_image = "gfx/crosshair_ring.tga";
 869                                 }
 870                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
 871                                 {
 872                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
 873                                         ring_scale = autocvar_crosshair_ring_reload_size;
 874                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
 875                                         ring_rgb = wcross_color;
 876
 877                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
 878                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
 879                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
 880                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
 881                                         else
 882                                                 ring_image = "gfx/crosshair_ring.tga";
 883                                 }
 884                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
 885                                 {
 886                                         ring_value = arc_heat;
 887                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
 888                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
 889                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
 890                                         ring_image = "gfx/crosshair_ring.tga";
 891                                 }
 892
 893                                 // if in weapon switch animation, fade ring out/in
 894                                 if(autocvar_crosshair_effect_time > 0)
 895                                 {
 896                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
 897                                         if (f >= 1)
 898                                         {
 899                                                 wcross_ring_prev = ((ring_image) ? true : false);
 900                                         }
 901
 902                                         if(wcross_ring_prev)
 903                                         {
 904                                                 if(f < 1)
 905                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
 906                                         }
 907                                         else
 908                                         {
 909                                                 if(f < 1)
 910                                                         ring_alpha *= bound(0, f, 1);
 911                                         }
 912                                 }
 913
 914                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
 915                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
 916
 917                                 if (ring_value)
 918                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
 919                         }
 920
 921 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
 922                         do \
 923                         { \
 924                                 if(wcross_blur > 0) \
 925                                 { \
 926                                         for(i = -2; i <= 2; ++i) \
 927                                         for(j = -2; j <= 2; ++j) \
 928                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
 929                                 } \
 930                                 else \
 931                                 { \
 932                                         M(0,0,sz,wcross_name,wcross_alpha); \
 933                                 } \
 934                         } \
 935                         while(0)
 936
 937 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
 938                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
 939
 940 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
 941                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
 942
 943                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
 944                         {
 945                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
 946                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
 947                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
 948                                 f = 1 - f;
 949                         }
 950                         else
 951                         {
 952                                 f = 1;
 953                         }
 954                         wcross_name_alpha_goal_prev = f;
 955
 956                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
 957                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
 958
 959                         if(autocvar_crosshair_dot)
 960                         {
 961                                 vector wcross_color_old;
 962                                 wcross_color_old = wcross_color;
 963
 964                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
 965                                         wcross_color = stov(autocvar_crosshair_dot_color);
 966
 967                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
 968                                 // FIXME why don't we use wcross_alpha here?cl_notice_run();
 969                                 wcross_color = wcross_color_old;
 970                         }
 971                 }
 972         }
 973         else
 974         {
 975                 wcross_scale_prev = 0;
 976                 wcross_alpha_prev = 0;
 977                 wcross_scale_goal_prev = 0;
 978                 wcross_alpha_goal_prev = 0;
 979                 wcross_changedonetime = 0;
 980                 if(wcross_name_goal_prev)
 981                         strunzone(wcross_name_goal_prev);
 982                 wcross_name_goal_prev = string_null;
 983                 if(wcross_name_goal_prev_prev)
 984                         strunzone(wcross_name_goal_prev_prev);
 985                 wcross_name_goal_prev_prev = string_null;
 986                 wcross_name_changestarttime = 0;
 987                 wcross_name_changedonetime = 0;
 988                 wcross_name_alpha_goal_prev = 0;
 989                 wcross_name_alpha_goal_prev_prev = 0;
 990                 wcross_resolution_goal_prev = 0;
 991                 wcross_resolution_goal_prev_prev = 0;
 992         }
 993 }
 994
 995 const int BUTTON_3 = 4;
 996 const int BUTTON_4 = 8;
 997 float cl_notice_run();
 998 float prev_myteam;
 999 void CSQC_UpdateView(float w, float h)
1000 {
1001         entity e;
1002         float fov;
1003         float f;
1004         int i;
1005         vector vf_size, vf_min;
1006         float a;
1007
1008         execute_next_frame();
1009
1010         ++framecount;
1011
1012         hud = getstati(STAT_HUD);
1013
1014         if(autocvar__hud_showbinds_reload) // menu can set this one
1015         {
1016                 db_close(binddb);
1017                 binddb = db_create();
1018                 cvar_set("_hud_showbinds_reload", "0");
1019         }
1020
1021         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1022                 view_quality = getproperty(VF_MINFPS_QUALITY);
1023         else
1024                 view_quality = 1;
1025
1026         button_attack2 = (input_buttons & BUTTON_3);
1027         button_zoom = (input_buttons & BUTTON_4);
1028
1029 #define CHECKFAIL_ASSERT(flag,func,parm,val) do {                                                                   \
1030         float checkfailv = (func)(parm);                                                                                \
1031         if (checkfailv != (val)) {                                                                                      \
1032                 if (!checkfail[(flag)])                                                                                     \
1033                 localcmd(sprintf("\ncmd checkfail %s %s %d %d\n", #func, parm, val, checkfailv));                           \
1034                 checkfail[(flag)] = 1;                                                                                      \
1035         }                                                                                                               \
1036 } while(0)
1037         CHECKFAIL_ASSERT(0, cvar_type, "\{100}\{105}\{118}\{48}\{95}\{101}\{118}\{97}\{100}\{101}", 0);
1038         CHECKFAIL_ASSERT(1, cvar_type, "\{97}\{97}\{95}\{101}\{110}\{97}\{98}\{108}\{101}", 0);
1039         CHECKFAIL_ASSERT(2, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{100}\{105}\{115}\{97}\{98}\{108}\{101}\{100}\{101}\{112}\{116}\{104}\{116}\{101}\{115}\{116}", 0);
1040         CHECKFAIL_ASSERT(3, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1041         CHECKFAIL_ASSERT(4, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{108}\{105}\{103}\{104}\{116}", 0);
1042         CHECKFAIL_ASSERT(5, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{115}\{104}\{97}\{100}\{111}\{119}\{118}\{111}\{108}\{117}\{109}\{101}\{115}", 0);
1043         CHECKFAIL_ASSERT(6, cvar, "\{114}\{95}\{115}\{104}\{111}\{119}\{111}\{118}\{101}\{114}\{100}\{114}\{97}\{119}", 0);
1044
1045         vf_size = getpropertyvec(VF_SIZE);
1046         vf_min = getpropertyvec(VF_MIN);
1047         vid_width = vf_size.x;
1048         vid_height = vf_size.y;
1049
1050         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1051         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1052
1053         WaypointSprite_Load();
1054
1055         CSQCPlayer_SetCamera();
1056
1057         if(player_localentnum <= maxclients) // is it a client?
1058                 current_player = player_localentnum - 1;
1059         else // then player_localentnum is the vehicle I'm driving
1060                 current_player = player_localnum;
1061         myteam = GetPlayerColor(current_player);
1062
1063         if(myteam != prev_myteam)
1064         {
1065                 myteamcolors = colormapPaletteColor(myteam, 1);
1066                 for(i = 0; i < HUD_PANEL_NUM; ++i)
1067                         hud_panel[i].update_time = time;
1068                 prev_myteam = myteam;
1069         }
1070
1071         ticrate = getstatf(STAT_MOVEVARS_TICRATE) * getstatf(STAT_MOVEVARS_TIMESCALE);
1072
1073         float is_dead = (getstati(STAT_HEALTH) <= 0);
1074
1075         // FIXME do we need this hack?
1076         if(isdemo())
1077         {
1078                 // in demos, input_buttons do not work
1079                 button_zoom = (autocvar__togglezoom == "-");
1080         }
1081         else if(button_zoom
1082                 && autocvar_cl_unpress_zoom_on_death
1083                 && (spectatee_status >= 0)
1084                 && (is_dead || intermission))
1085         {
1086                 // no zoom while dead or in intermission please
1087                 localcmd("-zoom\n");
1088                 button_zoom = false;
1089         }
1090
1091         // event chase camera
1092         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1093         {
1094                 if(WantEventchase())
1095                 {
1096                         eventchase_running = true;
1097
1098                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1099                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1100
1101                         // detect maximum viewoffset and use it
1102                         if(autocvar_cl_eventchase_viewoffset)
1103                         {
1104                                 WarpZone_TraceLine(current_view_origin, current_view_origin + autocvar_cl_eventchase_viewoffset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1105                                 if(trace_fraction == 1) { current_view_origin += autocvar_cl_eventchase_viewoffset; }
1106                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1107                         }
1108
1109                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1110                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1111                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1112                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1113
1114                         // make the camera smooth back
1115                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < autocvar_cl_eventchase_distance)
1116                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (autocvar_cl_eventchase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1117                         else if(eventchase_current_distance != autocvar_cl_eventchase_distance)
1118                                 eventchase_current_distance = autocvar_cl_eventchase_distance;
1119
1120                         makevectors(view_angles);
1121
1122                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1123                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1124
1125                         // If the boxtrace fails, revert back to line tracing.
1126                         if(trace_startsolid)
1127                         {
1128                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1129                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1130                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1131                         }
1132                         else { setproperty(VF_ORIGIN, trace_endpos); }
1133
1134                         setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1135                 }
1136                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1137                 {
1138                         eventchase_running = false;
1139                         cvar_set("chase_active", "0");
1140                         eventchase_current_distance = 0; // start from 0 next time
1141                 }
1142         }
1143         // workaround for camera stuck between player's legs when using chase_active 1
1144         // because the engine stops updating the chase_active camera when the game ends
1145         else if(intermission)
1146         {
1147                 cvar_settemp("chase_active", "-1");
1148                 eventchase_current_distance = 0;
1149         }
1150
1151         // do lockview after event chase camera so that it still applies whenever necessary.
1152         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1)))
1153         {
1154                 setproperty(VF_ORIGIN, freeze_org);
1155                 setproperty(VF_ANGLES, freeze_ang);
1156         }
1157         else
1158         {
1159                 freeze_org = getpropertyvec(VF_ORIGIN);
1160                 freeze_ang = getpropertyvec(VF_ANGLES);
1161         }
1162
1163         WarpZone_FixView();
1164         //WarpZone_FixPMove();
1165
1166         vector ov_org = '0 0 0';
1167         vector ov_mid = '0 0 0';
1168         vector ov_worldmin = '0 0 0';
1169         vector ov_worldmax = '0 0 0';
1170         if(autocvar_cl_orthoview)
1171         {
1172                 ov_worldmin = mi_picmin;
1173                 ov_worldmax = mi_picmax;
1174
1175                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1176                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1177                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1178
1179                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1180                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1181
1182                 float ov_nearest = vlen(ov_org - vec3(
1183                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1184                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1185                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1186                 ));
1187
1188                 float ov_furthest = 0;
1189                 float dist = 0;
1190
1191                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1192                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1193                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1194                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1195                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1196                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1197                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1198                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1199
1200                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1201                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1202                 cvar_settemp("r_farclip_world", "0");
1203                 cvar_settemp("r_novis", "1");
1204                 cvar_settemp("r_useportalculling", "0");
1205                 cvar_settemp("r_useinfinitefarclip", "0");
1206
1207                 setproperty(VF_ORIGIN, ov_org);
1208                 setproperty(VF_ANGLES, '90 0 0');
1209
1210                 #if 0
1211                 printf("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1212                         vtos(ov_org),
1213                         vtos(getpropertyvec(VF_ANGLES)),
1214                         ov_distance,
1215                         ov_nearest,
1216                         ov_furthest);
1217                 #endif
1218         }
1219
1220         // Render the Scene
1221         view_origin = getpropertyvec(VF_ORIGIN);
1222         view_angles = getpropertyvec(VF_ANGLES);
1223         makevectors(view_angles);
1224         view_forward = v_forward;
1225         view_right = v_right;
1226         view_up = v_up;
1227
1228 #ifdef BLURTEST
1229         if(time > blurtest_time0 && time < blurtest_time1)
1230         {
1231                 float r, t;
1232
1233                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1234                 r = t * blurtest_radius;
1235                 f = 1 / pow(t, blurtest_power) - 1;
1236
1237                 cvar_set("r_glsl_postprocess", "1");
1238                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1239         }
1240         else
1241         {
1242                 cvar_set("r_glsl_postprocess", "0");
1243                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1244         }
1245 #endif
1246
1247         TargetMusic_Advance();
1248         Fog_Force();
1249
1250         if(drawtime == 0)
1251                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1252         else
1253                 drawframetime = bound(0.000001, time - drawtime, 1);
1254         drawtime = time;
1255
1256         // watch for gametype changes here...
1257         // in ParseStuffCMD the cmd isn't executed yet :/
1258         // might even be better to add the gametype to TE_CSQC_INIT...?
1259         if(!postinit)
1260                 PostInit();
1261
1262         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1263         {
1264                 if(calledhooks & HOOK_START)
1265                 {
1266                         localcmd("\ncl_hook_gameend\n");
1267                         calledhooks |= HOOK_END;
1268                 }
1269         }
1270
1271         Announcer();
1272
1273         fov = autocvar_fov;
1274         if(fov <= 59.5)
1275         {
1276                 if(!zoomscript_caught)
1277                 {
1278                         localcmd("+button9\n");
1279                         zoomscript_caught = 1;
1280                 }
1281         }
1282         else
1283         {
1284                 if(zoomscript_caught)
1285                 {
1286                         localcmd("-button9\n");
1287                         zoomscript_caught = 0;
1288                 }
1289         }
1290
1291         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1292
1293         // next WANTED weapon (for HUD)
1294         switchweapon = getstati(STAT_SWITCHWEAPON);
1295
1296         // currently switching-to weapon (for crosshair)
1297         switchingweapon = getstati(STAT_SWITCHINGWEAPON);
1298
1299         // actually active weapon (for zoom)
1300         activeweapon = getstati(STAT_ACTIVEWEAPON);
1301
1302         f = (serverflags & SERVERFLAG_TEAMPLAY);
1303         if(f != teamplay)
1304         {
1305                 teamplay = f;
1306                 HUD_InitScores();
1307         }
1308
1309         if(last_switchweapon != switchweapon)
1310         {
1311                 weapontime = time;
1312                 last_switchweapon = switchweapon;
1313                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1314                 {
1315                         localcmd("-zoom\n");
1316                         button_zoom = false;
1317                 }
1318                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1319                 {
1320                         localcmd("-fire\n");
1321                         localcmd("-fire2\n");
1322                         button_attack2 = false;
1323                 }
1324         }
1325         if(last_activeweapon != activeweapon)
1326         {
1327                 last_activeweapon = activeweapon;
1328
1329                 e = get_weaponinfo(activeweapon);
1330                 if(e.netname != "")
1331                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1332                 else
1333                         localcmd("\ncl_hook_activeweapon none\n");
1334         }
1335
1336         // ALWAYS Clear Current Scene First
1337         clearscene();
1338
1339         setproperty(VF_ORIGIN, view_origin);
1340         setproperty(VF_ANGLES, view_angles);
1341
1342         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1343         setproperty(VF_SIZE, vf_size);
1344         setproperty(VF_MIN, vf_min);
1345
1346         // Assign Standard Viewflags
1347         // Draw the World (and sky)
1348         setproperty(VF_DRAWWORLD, 1);
1349
1350         // Set the console size vars
1351         vid_conwidth = autocvar_vid_conwidth;
1352         vid_conheight = autocvar_vid_conheight;
1353         vid_pixelheight = autocvar_vid_pixelheight;
1354
1355         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1356         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1357
1358         // Camera for demo playback
1359         if(camera_active)
1360         {
1361                 if(autocvar_camera_enable)
1362                         CSQC_Demo_Camera();
1363                 else
1364                 {
1365                         cvar_set("chase_active", ftos(chase_active_backup));
1366                         cvar_set("cl_demo_mousegrab", "0");
1367                         camera_active = false;
1368                 }
1369         }
1370         else
1371         {
1372 #ifdef CAMERATEST
1373                 if(autocvar_camera_enable)
1374 #else
1375                 if(autocvar_camera_enable && isdemo())
1376 #endif
1377                 {
1378                         // Enable required Darkplaces cvars
1379                         chase_active_backup = autocvar_chase_active;
1380                         cvar_set("chase_active", "2");
1381                         cvar_set("cl_demo_mousegrab", "1");
1382                         camera_active = true;
1383                         camera_mode = false;
1384                 }
1385         }
1386
1387         // Draw the Crosshair
1388         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1389
1390         // Draw the Engine Status Bar (the default Quake HUD)
1391         setproperty(VF_DRAWENGINESBAR, 0);
1392
1393         // Update the mouse position
1394         /*
1395            mousepos_x = vid_conwidth;
1396            mousepos_y = vid_conheight;
1397            mousepos = mousepos*0.5 + getmousepos();
1398          */
1399
1400         e = self;
1401         for(self = world; (self = nextent(self)); )
1402                 if(self.draw)
1403                         self.draw();
1404         self = e;
1405
1406         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1407         renderscene();
1408
1409         // now switch to 2D drawing mode by calling a 2D drawing function
1410         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1411         // next R_RenderScene call
1412         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1413
1414         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1415         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1416         {
1417                 // apply night vision effect
1418                 vector tc_00, tc_01, tc_10, tc_11;
1419                 vector rgb = '0 0 0';
1420
1421                 if(!nightvision_noise)
1422                 {
1423                         nightvision_noise = spawn();
1424                         nightvision_noise.classname = "nightvision_noise";
1425                 }
1426                 if(!nightvision_noise2)
1427                 {
1428                         nightvision_noise2 = spawn();
1429                         nightvision_noise2.classname = "nightvision_noise2";
1430                 }
1431
1432                 // color tint in yellow
1433                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1434
1435                 // draw BG
1436                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1437                 rgb = '1 1 1';
1438                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1439                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1440                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1441                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1442                 tc_11 = tc_01 + tc_10 - tc_00;
1443                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1444                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1445                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1446                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1447                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1448                 R_EndPolygon();
1449
1450                 // draw FG
1451                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1452                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1453                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1454                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1455                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1456                 tc_11 = tc_01 + tc_10 - tc_00;
1457                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1458                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1459                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1460                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1461                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1462                 R_EndPolygon();
1463         }
1464
1465         if(autocvar_cl_reticle)
1466         {
1467                 // Draw the aiming reticle for weapons that use it
1468                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1469                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1470                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1471                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1472                 {
1473                         // no zoom reticle while dead
1474                         reticle_type = 0;
1475                 }
1476                 else if(WEP_ACTION(activeweapon, WR_ZOOMRETICLE) && autocvar_cl_reticle_weapon)
1477                 {
1478                         if(reticle_image != "") { reticle_type = 2; }
1479                         else { reticle_type = 0; }
1480                 }
1481                 else if(button_zoom || zoomscript_caught)
1482                 {
1483                         // normal zoom
1484                         reticle_type = 1;
1485                 }
1486
1487                 if(reticle_type)
1488                 {
1489                         if(autocvar_cl_reticle_stretch)
1490                         {
1491                                 reticle_size.x = vid_conwidth;
1492                                 reticle_size.y = vid_conheight;
1493                                 reticle_pos.x = 0;
1494                                 reticle_pos.y = 0;
1495                         }
1496                         else
1497                         {
1498                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1499                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1500                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1501                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1502                         }
1503
1504                         if(zoomscript_caught)
1505                                 f = 1;
1506                         else
1507                                 f = current_zoomfraction;
1508
1509                         if(f)
1510                         {
1511                                 switch(reticle_type)
1512                                 {
1513                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1514                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1515                                 }
1516                         }
1517                 }
1518         }
1519         else
1520         {
1521                 if(reticle_type != 0) { reticle_type = 0; }
1522         }
1523
1524
1525         // improved polyblend
1526         if(autocvar_hud_contents)
1527         {
1528                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1529                 vector liquidcolor;
1530
1531                 switch(pointcontents(view_origin))
1532                 {
1533                         case CONTENT_WATER:
1534                                 liquidalpha = autocvar_hud_contents_water_alpha;
1535                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1536                                 incontent = 1;
1537                                 break;
1538
1539                         case CONTENT_LAVA:
1540                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1541                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1542                                 incontent = 1;
1543                                 break;
1544
1545                         case CONTENT_SLIME:
1546                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1547                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1548                                 incontent = 1;
1549                                 break;
1550
1551                         default:
1552                                 liquidalpha = 0;
1553                                 liquidcolor = '0 0 0';
1554                                 incontent = 0;
1555                                 break;
1556                 }
1557
1558                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1559                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1560                         contentfadetime = autocvar_hud_contents_fadeintime;
1561                         liquidalpha_prev = liquidalpha;
1562                         liquidcolor_prev = liquidcolor;
1563                 }
1564                 else
1565                         contentfadetime = autocvar_hud_contents_fadeouttime;
1566
1567                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1568                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1569
1570                 if(contentavgalpha)
1571                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1572
1573                 if(autocvar_hud_postprocessing)
1574                 {
1575                         if(autocvar_hud_contents_blur && contentavgalpha)
1576                         {
1577                                 content_blurpostprocess.x = 1;
1578                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1579                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1580                         }
1581                         else
1582                         {
1583                                 content_blurpostprocess.x = 0;
1584                                 content_blurpostprocess.y = 0;
1585                                 content_blurpostprocess.z = 0;
1586                         }
1587                 }
1588         }
1589
1590         if(autocvar_hud_damage && !getstati(STAT_FROZEN))
1591         {
1592                 splash_size.x = max(vid_conwidth, vid_conheight);
1593                 splash_size.y = max(vid_conwidth, vid_conheight);
1594                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
1595                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
1596
1597                 float myhealth_flash_temp;
1598                 myhealth = getstati(STAT_HEALTH);
1599
1600                 // fade out
1601                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
1602                 // add new damage
1603                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
1604
1605                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
1606                 pain_threshold = autocvar_hud_damage_pain_threshold;
1607                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
1608                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
1609
1610                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
1611                 {
1612                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
1613                 }
1614
1615                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
1616
1617                 if(myhealth_prev < 1)
1618                 {
1619                         if(myhealth >= 1)
1620                         {
1621                                 myhealth_flash = 0; // just spawned, clear the flash immediately
1622                                 myhealth_flash_temp = 0;
1623                         }
1624                         else
1625                         {
1626                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
1627                         }
1628                 }
1629
1630                 if(spectatee_status == -1 || intermission)
1631                 {
1632                         myhealth_flash = 0; // observing, or match ended
1633                         myhealth_flash_temp = 0;
1634                 }
1635
1636                 myhealth_prev = myhealth;
1637
1638                 // IDEA: change damage color/picture based on player model for robot/alien species?
1639                 // pro: matches model better
1640                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
1641                 // maybe different reddish pics?
1642                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
1643                 {
1644                         if(autocvar_cl_gentle_damage == 2)
1645                         {
1646                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
1647                                 {
1648                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
1649                                 }
1650                         }
1651                         else
1652                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
1653
1654                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1655                 }
1656                 else
1657                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
1658
1659                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
1660                 {
1661                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
1662                         {
1663                                 damage_blurpostprocess.x = 1;
1664                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
1665                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
1666                         }
1667                         else
1668                         {
1669                                 damage_blurpostprocess.x = 0;
1670                                 damage_blurpostprocess.y = 0;
1671                                 damage_blurpostprocess.z = 0;
1672                         }
1673                 }
1674         }
1675
1676         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
1677         float e2 = (autocvar_hud_powerup != 0);
1678         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
1679         {
1680                 // enable or disable rendering types if they are used or not
1681                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
1682                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
1683
1684                 // blur postprocess handling done first (used by hud_damage and hud_contents)
1685                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
1686                 {
1687                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
1688                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
1689                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
1690                         {
1691                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
1692                                 old_blurradius = blurradius;
1693                                 old_bluralpha = bluralpha;
1694                         }
1695                 }
1696                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
1697                 {
1698                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1699                         old_blurradius = 0;
1700                         old_bluralpha = 0;
1701                 }
1702
1703                 // edge detection postprocess handling done second (used by hud_powerup)
1704                 float sharpen_intensity = 0, strength_finished = getstatf(STAT_STRENGTH_FINISHED), invincible_finished = getstatf(STAT_INVINCIBLE_FINISHED);
1705                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
1706                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
1707
1708                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
1709
1710                 if(autocvar_hud_powerup && sharpen_intensity > 0)
1711                 {
1712                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
1713                         {
1714                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
1715                                 old_sharpen_intensity = sharpen_intensity;
1716                         }
1717                 }
1718                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
1719                 {
1720                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
1721                         old_sharpen_intensity = 0;
1722                 }
1723
1724                 if(cvar("r_glsl_postprocess") == 0)
1725                         cvar_set("r_glsl_postprocess", "2");
1726         }
1727         else if(cvar("r_glsl_postprocess") == 2)
1728                 cvar_set("r_glsl_postprocess", "0");
1729
1730         if(menu_visible)
1731                 menu_show();
1732
1733         /*if(gametype == MAPINFO_TYPE_CTF)
1734           {
1735           ctf_view();
1736           } else */
1737
1738         // draw 2D entities
1739         e = self;
1740         for(self = world; (self = nextent(self)); )
1741                 if(self.draw2d)
1742                         self.draw2d();
1743         self = e;
1744         Draw_ShowNames_All();
1745
1746         scoreboard_active = HUD_WouldDrawScoreboard();
1747
1748         UpdateDamage();
1749         UpdateCrosshair();
1750         UpdateHitsound();
1751
1752         if(NextFrameCommand)
1753         {
1754                 localcmd("\n", NextFrameCommand, "\n");
1755                 NextFrameCommand = string_null;
1756         }
1757
1758         // we must do this check AFTER a frame was rendered, or it won't work
1759         if(cs_project_is_b0rked == 0)
1760         {
1761                 string w0, h0;
1762                 w0 = ftos(autocvar_vid_conwidth);
1763                 h0 = ftos(autocvar_vid_conheight);
1764                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
1765                 //setproperty(VF_FOV, '90 90 0');
1766                 setproperty(VF_ORIGIN, '0 0 0');
1767                 setproperty(VF_ANGLES, '0 0 0');
1768                 setproperty(VF_PERSPECTIVE, 1);
1769                 makevectors('0 0 0');
1770                 vector v1, v2;
1771                 cvar_set("vid_conwidth", "800");
1772                 cvar_set("vid_conheight", "600");
1773                 v1 = cs_project(v_forward);
1774                 cvar_set("vid_conwidth", "640");
1775                 cvar_set("vid_conheight", "480");
1776                 v2 = cs_project(v_forward);
1777                 if(v1 == v2)
1778                         cs_project_is_b0rked = 1;
1779                 else
1780                         cs_project_is_b0rked = -1;
1781                 cvar_set("vid_conwidth", w0);
1782                 cvar_set("vid_conheight", h0);
1783         }
1784
1785         if(autocvar__hud_configure)
1786                 HUD_Panel_Mouse();
1787
1788     if(hud && !intermission)
1789     {
1790         if(hud == HUD_SPIDERBOT)
1791             CSQC_SPIDER_HUD();
1792         else if(hud == HUD_WAKIZASHI)
1793             CSQC_WAKIZASHI_HUD();
1794         else if(hud == HUD_RAPTOR)
1795             CSQC_RAPTOR_HUD();
1796         else if(hud == HUD_BUMBLEBEE)
1797             CSQC_BUMBLE_HUD();
1798         else if(hud == HUD_BUMBLEBEE_GUN)
1799             CSQC_BUMBLE_GUN_HUD();
1800     }
1801
1802         cl_notice_run();
1803
1804         // let's reset the view back to normal for the end
1805         setproperty(VF_MIN, '0 0 0');
1806         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
1807 }
1808
1809
1810 void CSQC_common_hud(void)
1811 {
1812         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1813                 Accuracy_LoadLevels();
1814
1815         HUD_Main(); // always run these functions for alpha checks
1816         HUD_DrawScoreboard();
1817
1818         if (scoreboard_active) // scoreboard/accuracy
1819                 HUD_Reset();
1820         else if (intermission == 2) // map voting screen
1821         {
1822                 MapVote_Draw();
1823                 HUD_Reset();
1824         }
1825 }
1826
1827
1828 // following vectors must be global to allow seamless switching between camera modes
1829 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
1830 void CSQC_Demo_Camera()
1831 {
1832         float speed, attenuation, dimensions;
1833         vector tmp, delta;
1834
1835         if( autocvar_camera_reset || !camera_mode )
1836         {
1837                 camera_offset = '0 0 0';
1838                 current_angles = '0 0 0';
1839                 camera_direction = '0 0 0';
1840                 camera_offset.z += 30;
1841                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
1842                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
1843                 current_origin = view_origin;
1844                 current_camera_offset  = camera_offset;
1845                 cvar_set("camera_reset", "0");
1846                 camera_mode = CAMERA_CHASE;
1847         }
1848
1849         // Camera angles
1850         if( camera_roll )
1851                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
1852
1853         if(autocvar_camera_look_player)
1854         {
1855                 vector dir;
1856                 float n;
1857
1858                 dir = normalize(view_origin - current_position);
1859                 n = mouse_angles.z;
1860                 mouse_angles = vectoangles(dir);
1861                 mouse_angles.x = mouse_angles.x * -1;
1862                 mouse_angles.z = n;
1863         }
1864         else
1865         {
1866                 tmp = getmousepos() * 0.1;
1867                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
1868                 {
1869                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
1870                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
1871                 }
1872         }
1873
1874         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
1875         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
1876         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
1877         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
1878
1879         // Fix difference when angles don't have the same sign
1880         delta = '0 0 0';
1881         if(mouse_angles.y < -60 && current_angles.y > 60)
1882                 delta = '0 360 0';
1883         if(mouse_angles.y > 60 && current_angles.y < -60)
1884                 delta = '0 -360 0';
1885
1886         if(autocvar_camera_look_player)
1887                 attenuation = autocvar_camera_look_attenuation;
1888         else
1889                 attenuation = autocvar_camera_speed_attenuation;
1890
1891         attenuation = 1 / max(1, attenuation);
1892         current_angles += (mouse_angles - current_angles + delta) * attenuation;
1893
1894         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
1895         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
1896         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
1897         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
1898
1899         // Camera position
1900         tmp = '0 0 0';
1901         dimensions = 0;
1902
1903         if( camera_direction.x )
1904         {
1905                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
1906                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
1907                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
1908                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
1909                 ++dimensions;
1910         }
1911
1912         if( camera_direction.y )
1913         {
1914                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
1915                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
1916                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
1917                 ++dimensions;
1918         }
1919
1920         if( camera_direction.z )
1921         {
1922                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
1923                 ++dimensions;
1924         }
1925
1926         if(autocvar_camera_free)
1927                 speed = autocvar_camera_speed_free;
1928         else
1929                 speed = autocvar_camera_speed_chase;
1930
1931         if(dimensions)
1932         {
1933                 speed = speed * sqrt(1 / dimensions);
1934                 camera_offset += tmp * speed;
1935         }
1936
1937         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
1938
1939         // Camera modes
1940         if( autocvar_camera_free )
1941         {
1942                 if ( camera_mode == CAMERA_CHASE )
1943                 {
1944                         current_camera_offset = current_origin + current_camera_offset;
1945                         camera_offset = current_origin + camera_offset;
1946                 }
1947
1948                 camera_mode = CAMERA_FREE;
1949                 current_position = current_camera_offset;
1950         }
1951         else
1952         {
1953                 if ( camera_mode == CAMERA_FREE )
1954                 {
1955                         current_origin = view_origin;
1956                         camera_offset = camera_offset - current_origin;
1957                         current_camera_offset = current_camera_offset - current_origin;
1958                 }
1959
1960                 camera_mode = CAMERA_CHASE;
1961
1962                 if(autocvar_camera_chase_smoothly)
1963                         current_origin += (view_origin - current_origin) * attenuation;
1964                 else
1965                         current_origin = view_origin;
1966
1967                 current_position = current_origin + current_camera_offset;
1968         }
1969
1970         setproperty(VF_ANGLES, current_angles);
1971         setproperty(VF_ORIGIN, current_position);
1972 }