qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hook.qh"
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "scoreboard.qh"
   7 #include "shownames.qh"
   8 #include "quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include "../common/anim.qh"
  13 #include "../common/constants.qh"
  14 #include "../common/debug.qh"
  15 #include "../common/mapinfo.qh"
  16 #include "../common/gamemodes/all.qh"
  17 #include "../common/physics.qh"
  18 #include "../common/stats.qh"
  19 #include "../common/triggers/target/music.qh"
  20 #include "../common/teams.qh"
  21
  22 #include "../common/vehicles/all.qh"
  23 #include "../common/weapons/all.qh"
  24 #include "../common/viewloc.qh"
  25 #include "../common/minigames/cl_minigames.qh"
  26 #include "../common/minigames/cl_minigames_hud.qh"
  27
  28 #include "../lib/csqcmodel/cl_player.qh"
  29
  30 #include "../lib/warpzone/client.qh"
  31 #include "../lib/warpzone/common.qh"
  32
  33 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  34
  35 float autocvar_cl_viewmodel_scale;
  36
  37 bool autocvar_cl_bobmodel;
  38 float autocvar_cl_bobmodel_speed;
  39 float autocvar_cl_bobmodel_side;
  40 float autocvar_cl_bobmodel_up;
  41
  42 float autocvar_cl_followmodel;
  43 float autocvar_cl_followmodel_side_speed;
  44 float autocvar_cl_followmodel_side_highpass;
  45 float autocvar_cl_followmodel_side_highpass1;
  46 float autocvar_cl_followmodel_side_limit;
  47 float autocvar_cl_followmodel_side_lowpass;
  48 float autocvar_cl_followmodel_up_speed;
  49 float autocvar_cl_followmodel_up_highpass;
  50 float autocvar_cl_followmodel_up_highpass1;
  51 float autocvar_cl_followmodel_up_limit;
  52 float autocvar_cl_followmodel_up_lowpass;
  53
  54 float autocvar_cl_leanmodel;
  55 float autocvar_cl_leanmodel_side_speed;
  56 float autocvar_cl_leanmodel_side_highpass;
  57 float autocvar_cl_leanmodel_side_highpass1;
  58 float autocvar_cl_leanmodel_side_lowpass;
  59 float autocvar_cl_leanmodel_side_limit;
  60 float autocvar_cl_leanmodel_up_speed;
  61 float autocvar_cl_leanmodel_up_highpass;
  62 float autocvar_cl_leanmodel_up_highpass1;
  63 float autocvar_cl_leanmodel_up_lowpass;
  64 float autocvar_cl_leanmodel_up_limit;
  65
  66 #define lowpass(value, frac, ref_store, ret) do \
  67 { \
  68         float __frac = bound(0, frac, 1); \
  69         ret = ref_store = ref_store * (1 - __frac) + (value) * __frac; \
  70 } while (0)
  71
  72 #define lowpass_limited(value, frac, limit, ref_store, ret) do \
  73 { \
  74         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  75         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  76 } while (0)
  77
  78 #define highpass(value, frac, ref_store, ret) do \
  79 { \
  80         float __f; lowpass(value, frac, ref_store, __f); \
  81         ret = (value) - __f; \
  82 } while (0)
  83
  84 #define highpass_limited(value, frac, limit, ref_store, ret) do \
  85 { \
  86         float __f; lowpass_limited(value, frac, limit, ref_store, __f); \
  87         ret = (value) - __f; \
  88 } while (0)
  89
  90 #define lowpass3(value, fracx, fracy, fracz, ref_store, ref_out) do \
  91 { \
  92         lowpass(value.x, fracx, ref_store.x, ref_out.x); \
  93         lowpass(value.y, fracy, ref_store.y, ref_out.y); \
  94         lowpass(value.z, fracz, ref_store.z, ref_out.z); \
  95 } while (0)
  96
  97 #define highpass3(value, fracx, fracy, fracz, ref_store, ref_out) do \
  98 { \
  99         highpass(value.x, fracx, ref_store.x, ref_out.x); \
 100         highpass(value.y, fracy, ref_store.y, ref_out.y); \
 101         highpass(value.z, fracz, ref_store.z, ref_out.z); \
 102 } while (0)
 103
 104 #define highpass3_limited(value, fracx, limitx, fracy, limity, fracz, limitz, ref_store, ref_out) do \
 105 { \
 106         highpass_limited(value.x, fracx, limitx, ref_store.x, ref_out.x); \
 107         highpass_limited(value.y, fracy, limity, ref_store.y, ref_out.y); \
 108         highpass_limited(value.z, fracz, limitz, ref_store.z, ref_out.z); \
 109 } while (0)
 110
 111 void viewmodel_animate(entity this)
 112 {
 113         static float prevtime;
 114         float frametime = (time - prevtime) * STAT(MOVEVARS_TIMESCALE);
 115         prevtime = time;
 116
 117         if (autocvar_chase_active) return;
 118         if (getstati(STAT_HEALTH) <= 0) return;
 119
 120         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 121
 122         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 123         static bool oldonground;
 124         static float hitgroundtime;
 125         static float lastongroundtime;
 126         if (clonground)
 127         {
 128                 float f = time; // cl.movecmd[0].time
 129                 if (!oldonground)
 130                         hitgroundtime = f;
 131                 lastongroundtime = f;
 132         }
 133         oldonground = clonground;
 134
 135         vector gunorg = '0 0 0', gunangles = '0 0 0';
 136         static vector gunorg_prev = '0 0 0', gunangles_prev = '0 0 0';
 137
 138         bool teleported = view.csqcmodel_teleported;
 139
 140         // 1. if we teleported, clear the frametime... the lowpass will recover the previous value then
 141         if (teleported)
 142         {
 143                 // try to fix the first highpass; result is NOT
 144                 // perfect! TODO find a better fix
 145                 gunangles_prev = view_angles;
 146                 gunorg_prev = view_origin;
 147         }
 148
 149         static vector gunorg_highpass = '0 0 0';
 150
 151         // 2. for the gun origin, only keep the high frequency (non-DC) parts, which is "somewhat like velocity"
 152         gunorg_highpass += gunorg_prev;
 153         highpass3_limited(view_origin,
 154                 frametime * autocvar_cl_followmodel_side_highpass1, autocvar_cl_followmodel_side_limit,
 155                 frametime * autocvar_cl_followmodel_side_highpass1, autocvar_cl_followmodel_side_limit,
 156                 frametime * autocvar_cl_followmodel_up_highpass1, autocvar_cl_followmodel_up_limit,
 157                 gunorg_highpass, gunorg);
 158         gunorg_prev = view_origin;
 159         gunorg_highpass -= gunorg_prev;
 160
 161         static vector gunangles_highpass = '0 0 0';
 162
 163         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 164         gunangles_highpass += gunangles_prev;
 165         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 166         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 167         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 168         highpass3_limited(view_angles,
 169                 frametime * autocvar_cl_leanmodel_up_highpass1, autocvar_cl_leanmodel_up_limit,
 170                 frametime * autocvar_cl_leanmodel_side_highpass1, autocvar_cl_leanmodel_side_limit,
 171                 0, 0,
 172                 gunangles_highpass, gunangles);
 173         gunangles_prev = view_angles;
 174         gunangles_highpass -= gunangles_prev;
 175
 176         // 3. calculate the RAW adjustment vectors
 177         gunorg.x *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_side_speed : 0);
 178         gunorg.y *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_side_speed : 0);
 179         gunorg.z *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_up_speed : 0);
 180
 181         PITCH(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_up_speed : 0);
 182         YAW(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_side_speed : 0);
 183         ROLL(gunangles) = 0;
 184
 185         static vector gunorg_adjustment_highpass;
 186         static vector gunorg_adjustment_lowpass;
 187         static vector gunangles_adjustment_highpass;
 188         static vector gunangles_adjustment_lowpass;
 189
 190         // 4. perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 191         //    trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 192         highpass3(gunorg,
 193                 frametime * autocvar_cl_followmodel_side_highpass,
 194                 frametime * autocvar_cl_followmodel_side_highpass,
 195                 frametime * autocvar_cl_followmodel_up_highpass,
 196                 gunorg_adjustment_highpass, gunorg);
 197         lowpass3(gunorg,
 198                 frametime * autocvar_cl_followmodel_side_lowpass,
 199                 frametime * autocvar_cl_followmodel_side_lowpass,
 200                 frametime * autocvar_cl_followmodel_up_lowpass,
 201                 gunorg_adjustment_lowpass, gunorg);
 202         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 203         highpass3(gunangles,
 204                 frametime * autocvar_cl_leanmodel_up_highpass,
 205                 frametime * autocvar_cl_leanmodel_side_highpass,
 206                 0,
 207                 gunangles_adjustment_highpass, gunangles);
 208         lowpass3(gunangles,
 209                 frametime * autocvar_cl_leanmodel_up_lowpass,
 210                 frametime * autocvar_cl_leanmodel_side_lowpass,
 211                 0,
 212                 gunangles_adjustment_lowpass, gunangles);
 213         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 214
 215         // vertical view bobbing code
 216         // TODO: cl_bob
 217
 218         // horizontal view bobbing code
 219         // TODO: cl_bob2
 220
 221         // fall bobbing code
 222         // causes the view to swing down and back up when touching the ground
 223         // TODO: cl_bobfall
 224
 225         // gun model bobbing code
 226         if (autocvar_cl_bobmodel)
 227         {
 228                 // calculate for swinging gun model
 229                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 230                 // Sajt: I tried to smooth out the transitions between bob and no bob, which works
 231                 // for the most part, but for some reason when you go through a message trigger or
 232                 // pick up an item or anything like that it will momentarily jolt the gun.
 233                 vector forward, right, up;
 234                 float bspeed;
 235                 float t = 1;
 236                 float s = time * autocvar_cl_bobmodel_speed;
 237                 if (clonground)
 238                 {
 239                         if (time - hitgroundtime < 0.2)
 240                         {
 241                                 // just hit the ground, speed the bob back up over the next 0.2 seconds
 242                                 t = time - hitgroundtime;
 243                                 t = bound(0, t, 0.2);
 244                                 t *= 5;
 245                         }
 246                 }
 247                 else
 248                 {
 249                         // recently left the ground, slow the bob down over the next 0.2 seconds
 250                         t = time - lastongroundtime;
 251                         t = 0.2 - bound(0, t, 0.2);
 252                         t *= 5;
 253                 }
 254                 bspeed = xyspeed * 0.01;
 255                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 256                 float bobr = bspeed * autocvar_cl_bobmodel_side * autocvar_cl_viewmodel_scale * sin(s) * t;
 257                 gunorg += bobr * right;
 258                 float bobu = bspeed * autocvar_cl_bobmodel_up * autocvar_cl_viewmodel_scale * cos(s * 2) * t;
 259                 gunorg += bobu * up;
 260         }
 261         vector v = rotate(gunorg, YAW(view_angles) * DEG2RAD); // rotate world coordinates to relative ones
 262         v.z = gunorg.z;
 263         this.origin += v;
 264         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 265         this.angles += gunangles;
 266 }
 267
 268 .vector viewmodel_origin, viewmodel_angles;
 269 .float weapon_nextthink;
 270 .float weapon_eta_last;
 271 .float weapon_switchdelay;
 272
 273 void viewmodel_draw(entity this)
 274 {
 275         int mask = (intermission || (getstati(STAT_HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 276         float a = this.alpha;
 277         int c = stof(getplayerkeyvalue(current_player, "colors"));
 278         vector g;
 279         Weapon wep = activeweapon;
 280         if (!(g = wep.wr_glow(wep))) g = colormapPaletteColor(c & 0x0F, true) * 2;
 281         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 282         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 283                 | EF_NODEPTHTEST)
 284                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 285         for (entity e = this; e; e = e.weaponchild)
 286         {
 287                 e.drawmask = mask;
 288                 e.alpha = a;
 289                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 290                 e.glowmod = g;
 291                 e.csqcmodel_effects = fx;
 292                 WITH(entity, self, e, CSQCModel_Effects_Apply());
 293         }
 294         {
 295                 static string name_last;
 296                 string name = wep.mdl;
 297                 if (name != name_last)
 298                 {
 299                         name_last = name;
 300                         CL_WeaponEntity_SetModel(this, name);
 301                         this.viewmodel_origin = this.origin;
 302                         this.viewmodel_angles = this.angles;
 303                 }
 304                 anim_update(this);
 305                 if (!this.animstate_override)
 306                         anim_set(this, this.anim_idle, true, false, false);
 307         }
 308         float f = 0; // 0..1; 0: fully active
 309         float eta = (this.weapon_nextthink - time) / STAT(WEAPONRATEFACTOR);
 310         if (eta <= 0) f = this.weapon_eta_last;
 311         else switch (this.state)
 312         {
 313                 case WS_RAISE:
 314                 {
 315                         f = eta / max(eta, this.weapon_switchdelay);
 316                         break;
 317                 }
 318                 case WS_DROP:
 319                 {
 320                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 321                         break;
 322                 }
 323                 case WS_CLEAR:
 324                 {
 325                         f = 1;
 326                         break;
 327                 }
 328         }
 329         this.weapon_eta_last = f;
 330         this.origin = this.viewmodel_origin;
 331         this.angles = this.viewmodel_angles;
 332         this.angles_x = (-90 * f * f);
 333         viewmodel_animate(this);
 334         setorigin(this, this.origin);
 335 }
 336
 337 entity viewmodel;
 338 STATIC_INIT(viewmodel) {
 339     viewmodel = new(viewmodel);
 340     make_pure(viewmodel);
 341         viewmodel.draw = viewmodel_draw;
 342 }
 343
 344 entity porto;
 345 vector polyline[16];
 346 void Porto_Draw(entity this)
 347 {
 348         vector p, dir, ang, q, nextdir;
 349         float portal_number, portal1_idx;
 350
 351         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
 352                 return;
 353         if(g_balance_porto_secondary)
 354                 return;
 355         if(intermission == 1)
 356                 return;
 357         if(intermission == 2)
 358                 return;
 359         if (getstati(STAT_HEALTH) <= 0)
 360                 return;
 361
 362         dir = view_forward;
 363
 364         if(angles_held_status)
 365         {
 366                 makevectors(angles_held);
 367                 dir = v_forward;
 368         }
 369
 370         p = view_origin;
 371
 372         polyline[0] = p;
 373         int idx = 1;
 374         portal_number = 0;
 375         nextdir = dir;
 376
 377         for (;;)
 378         {
 379                 dir = nextdir;
 380                 traceline(p, p + 65536 * dir, true, porto);
 381                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 382                         return;
 383                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
 384                 p = trace_endpos;
 385                 polyline[idx] = p;
 386                 ++idx;
 387                 if(idx >= 16)
 388                         return;
 389                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 390                         continue;
 391                 ++portal_number;
 392                 ang = vectoangles2(trace_plane_normal, dir);
 393                 ang.x = -ang.x;
 394                 makevectors(ang);
 395                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 396                         return;
 397                 if(portal_number == 1)
 398                 {
 399                         portal1_idx = idx;
 400                         if(portal_number >= 2)
 401                                 break;
 402                 }
 403         }
 404
 405         while(idx >= 2)
 406         {
 407                 p = polyline[idx-2];
 408                 q = polyline[idx-1];
 409                 if(idx == 2)
 410                         p = p - view_up * 16;
 411                 if(idx-1 >= portal1_idx)
 412                 {
 413                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 414                 }
 415                 else
 416                 {
 417                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 418                 }
 419                 --idx;
 420         }
 421 }
 422
 423 void Porto_Init()
 424 {
 425         porto = new(porto);
 426         make_pure(porto);
 427         porto.draw = Porto_Draw;
 428         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 429 }
 430
 431 float drawtime;
 432 float avgspeed;
 433 vector GetCurrentFov(float fov)
 434 {
 435         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 436         float velocityzoom, curspeed;
 437         vector v;
 438
 439         zoomsensitivity = autocvar_cl_zoomsensitivity;
 440         zoomfactor = autocvar_cl_zoomfactor;
 441         if(zoomfactor < 1 || zoomfactor > 30)
 442                 zoomfactor = 2.5;
 443         zoomspeed = autocvar_cl_zoomspeed;
 444         if(zoomspeed >= 0)
 445         if(zoomspeed < 0.5 || zoomspeed > 16)
 446                         zoomspeed = 3.5;
 447
 448         zoomdir = button_zoom;
 449         if(hud == HUD_NORMAL)
 450         if(switchweapon == activeweapon)
 451         if((activeweapon == WEP_VORTEX && vortex_scope) || (activeweapon == WEP_RIFLE && rifle_scope)) // do NOT use switchweapon here
 452                 zoomdir += button_attack2;
 453         if(spectatee_status > 0 || isdemo())
 454         {
 455                 if(spectatorbutton_zoom)
 456                 {
 457                         if(zoomdir)
 458                                 zoomdir = 0;
 459                         else
 460                                 zoomdir = 1;
 461                 }
 462                 // fteqcc failed twice here already, don't optimize this
 463         }
 464
 465         if(zoomdir) { zoomin_effect = 0; }
 466
 467         if(camera_active)
 468         {
 469                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 470         }
 471         else if(autocvar_cl_spawnzoom && zoomin_effect)
 472         {
 473                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 474
 475                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 476                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 477                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 478         }
 479         else
 480         {
 481                 if(zoomspeed < 0) // instant zoom
 482                 {
 483                         if(zoomdir)
 484                                 current_viewzoom = 1 / zoomfactor;
 485                         else
 486                                 current_viewzoom = 1;
 487                 }
 488                 else
 489                 {
 490                         if(zoomdir)
 491                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 492                         else
 493                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 494                 }
 495         }
 496
 497         if(almost_equals(current_viewzoom, 1))
 498                 current_zoomfraction = 0;
 499         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 500                 current_zoomfraction = 1;
 501         else
 502                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 503
 504         if(zoomsensitivity < 1)
 505                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 506         else
 507                 setsensitivityscale(1);
 508
 509         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 510         {
 511                 if(intermission) { curspeed = 0; }
 512                 else
 513                 {
 514
 515                         makevectors(view_angles);
 516                         v = pmove_vel;
 517                         if(csqcplayer)
 518                                 v = csqcplayer.velocity;
 519
 520                         switch(autocvar_cl_velocityzoom_type)
 521                         {
 522                                 case 3: curspeed = max(0, v_forward * v); break;
 523                                 case 2: curspeed = (v_forward * v); break;
 524                                 case 1: default: curspeed = vlen(v); break;
 525                         }
 526                 }
 527
 528                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 529                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 530                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 531
 532                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 533         }
 534         else
 535                 velocityzoom = 1;
 536
 537         float frustumx, frustumy, fovx, fovy;
 538         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 539         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 540         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 541         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 542
 543         return '1 0 0' * fovx + '0 1 0' * fovy;
 544 }
 545
 546 vector GetViewLocationFOV(float fov)
 547 {
 548         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 549         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 550         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 551         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 552         return '1 0 0' * fovx + '0 1 0' * fovy;
 553 }
 554
 555 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 556 {
 557         float fovx, fovy;
 558         float width = (ov_worldmax.x - ov_worldmin.x);
 559         float height = (ov_worldmax.y - ov_worldmin.y);
 560         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 561         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 562         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 563         return '1 0 0' * fovx + '0 1 0' * fovy;
 564 }
 565
 566 // this function must match W_SetupShot!
 567 float zoomscript_caught;
 568
 569 vector wcross_origin;
 570 float wcross_scale_prev, wcross_alpha_prev;
 571 vector wcross_color_prev;
 572 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 573 vector wcross_color_goal_prev;
 574 float wcross_changedonetime;
 575
 576 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 577 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 578 float wcross_name_changestarttime, wcross_name_changedonetime;
 579 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 580
 581 float wcross_ring_prev;
 582
 583 entity trueaim;
 584 entity trueaim_rifle;
 585
 586 const float SHOTTYPE_HITTEAM = 1;
 587 const float SHOTTYPE_HITOBSTRUCTION = 2;
 588 const float SHOTTYPE_HITWORLD = 3;
 589 const float SHOTTYPE_HITENEMY = 4;
 590
 591 void TrueAim_Init()
 592 {
 593         trueaim = new(trueaim);
 594         make_pure(trueaim);
 595         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 596         trueaim_rifle = new(trueaim_rifle);
 597         make_pure(trueaim_rifle);
 598         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 599 }
 600
 601 float EnemyHitCheck()
 602 {
 603         float t, n;
 604         wcross_origin = project_3d_to_2d(trace_endpos);
 605         wcross_origin.z = 0;
 606         if(trace_ent)
 607                 n = trace_ent.entnum;
 608         else
 609                 n = trace_networkentity;
 610         if(n < 1)
 611                 return SHOTTYPE_HITWORLD;
 612         if(n > maxclients)
 613                 return SHOTTYPE_HITWORLD;
 614         t = entcs_GetTeam(n - 1);
 615         if(teamplay)
 616                 if(t == myteam)
 617                         return SHOTTYPE_HITTEAM;
 618         if(t == NUM_SPECTATOR)
 619                 return SHOTTYPE_HITWORLD;
 620         return SHOTTYPE_HITENEMY;
 621 }
 622
 623 float TrueAimCheck()
 624 {
 625         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 626         vector vecs, trueaimpoint, w_shotorg;
 627         vector mi, ma, dv;
 628         float shottype;
 629         entity ta;
 630         float mv;
 631
 632         mi = ma = '0 0 0';
 633         ta = trueaim;
 634         mv = MOVE_NOMONSTERS;
 635
 636         switch(activeweapon) // WEAPONTODO
 637         {
 638                 case WEP_TUBA: // no aim
 639                 case WEP_PORTO: // shoots from eye
 640                 case WEP_NEXBALL: // shoots from eye
 641                 case WEP_HOOK: // no trueaim
 642                 case WEP_MORTAR: // toss curve
 643                         return SHOTTYPE_HITWORLD;
 644                 case WEP_VORTEX:
 645                 case WEP_VAPORIZER:
 646                         mv = MOVE_NORMAL;
 647                         break;
 648                 case WEP_RIFLE:
 649                         ta = trueaim_rifle;
 650                         mv = MOVE_NORMAL;
 651                         if(zoomscript_caught)
 652                         {
 653                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 654                                 return EnemyHitCheck();
 655                         }
 656                         break;
 657                 case WEP_DEVASTATOR: // projectile has a size!
 658                         mi = '-3 -3 -3';
 659                         ma = '3 3 3';
 660                         break;
 661                 case WEP_FIREBALL: // projectile has a size!
 662                         mi = '-16 -16 -16';
 663                         ma = '16 16 16';
 664                         break;
 665                 case WEP_SEEKER: // projectile has a size!
 666                         mi = '-2 -2 -2';
 667                         ma = '2 2 2';
 668                         break;
 669                 case WEP_ELECTRO: // projectile has a size!
 670                         mi = '0 0 -3';
 671                         ma = '0 0 -3';
 672                         break;
 673         }
 674
 675         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * getstati(STAT_VIEWHEIGHT));
 676
 677         vecs = decompressShotOrigin(STAT(SHOTORG));
 678
 679         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 680         trueaimpoint = trace_endpos;
 681
 682         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 683                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 684
 685         if(vecs.x > 0)
 686                 vecs.y = -vecs.y;
 687         else
 688                 vecs = '0 0 0';
 689
 690         dv = view_right * vecs.y + view_up * vecs.z;
 691         w_shotorg = traceorigin + dv;
 692
 693         // now move the vecs forward as much as requested if possible
 694         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 695         w_shotorg = trace_endpos - view_forward * nudge;
 696
 697         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 698         shottype = EnemyHitCheck();
 699         if(shottype != SHOTTYPE_HITWORLD)
 700                 return shottype;
 701
 702 #if 0
 703         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 704         // or rather, I know why, but see no fix
 705         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 706                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 707                 return SHOTTYPE_HITOBSTRUCTION;
 708 #endif
 709
 710         return SHOTTYPE_HITWORLD;
 711 }
 712
 713 void PostInit();
 714 void CSQC_Demo_Camera();
 715 float HUD_WouldDrawScoreboard();
 716 float camera_mode;
 717 const float CAMERA_FREE = 1;
 718 const float CAMERA_CHASE = 2;
 719 float reticle_type;
 720 string reticle_image;
 721 string NextFrameCommand;
 722
 723 vector freeze_org, freeze_ang;
 724 entity nightvision_noise, nightvision_noise2;
 725
 726 const float MAX_TIME_DIFF = 5;
 727 float pickup_crosshair_time, pickup_crosshair_size;
 728 float hitindication_crosshair_size;
 729 float use_vortex_chargepool;
 730
 731 float myhealth, myhealth_prev;
 732 float myhealth_flash;
 733
 734 float old_blurradius, old_bluralpha;
 735 float old_sharpen_intensity;
 736
 737 vector myhealth_gentlergb;
 738
 739 float contentavgalpha, liquidalpha_prev;
 740 vector liquidcolor_prev;
 741
 742 float eventchase_current_distance;
 743 float eventchase_running;
 744 bool WantEventchase()
 745 {SELFPARAM();
 746         if(autocvar_cl_orthoview)
 747                 return false;
 748         if(intermission)
 749                 return true;
 750         if(self.viewloc)
 751                 return true;
 752         if(spectatee_status >= 0)
 753         {
 754                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 755                         return true;
 756                 if(MUTATOR_CALLHOOK(WantEventchase, self))
 757                         return true;
 758                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
 759                         return true;
 760                 if(autocvar_cl_eventchase_death && (getstati(STAT_HEALTH) <= 0))
 761                 {
 762                         if(autocvar_cl_eventchase_death == 2)
 763                         {
 764                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 765                                 if(self.velocity == '0 0 0' || eventchase_running)
 766                                         return true;
 767                         }
 768                         else return true;
 769                 }
 770         }
 771         return false;
 772 }
 773
 774 void HUD_Crosshair_Vehicle()
 775 {
 776         if(hud != HUD_BUMBLEBEE_GUN)
 777         {
 778                 Vehicle info = get_vehicleinfo(hud);
 779                 info.vr_crosshair(info);
 780         }
 781 }
 782
 783 vector damage_blurpostprocess, content_blurpostprocess;
 784
 785 float unaccounted_damage = 0;
 786 void UpdateDamage()
 787 {
 788         // accumulate damage with each stat update
 789         static float damage_total_prev = 0;
 790         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 791         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 792         damage_total_prev = damage_total;
 793
 794         static float damage_dealt_time_prev = 0;
 795         float damage_dealt_time = STAT(HIT_TIME);
 796         if (damage_dealt_time != damage_dealt_time_prev)
 797         {
 798                 unaccounted_damage += unaccounted_damage_new;
 799                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 800         }
 801         damage_dealt_time_prev = damage_dealt_time;
 802
 803         // prevent hitsound when switching spectatee
 804         static float spectatee_status_prev = 0;
 805         if (spectatee_status != spectatee_status_prev)
 806                 unaccounted_damage = 0;
 807         spectatee_status_prev = spectatee_status;
 808 }
 809
 810 void HitSound()
 811 {
 812         // varying sound pitch
 813
 814         static float hitsound_time_prev = 0;
 815         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 816         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 817         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 818         {
 819                 if (autocvar_cl_hitsound && unaccounted_damage)
 820                 {
 821                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 822                         float a = autocvar_cl_hitsound_max_pitch;
 823                         float b = autocvar_cl_hitsound_min_pitch;
 824                         float c = autocvar_cl_hitsound_nom_damage;
 825                         float x = unaccounted_damage;
 826                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 827
 828                         // if sound variation is disabled, set pitch_shift to 1
 829                         if (autocvar_cl_hitsound == 1)
 830                                 pitch_shift = 1;
 831
 832                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 833                         if (autocvar_cl_hitsound == 3)
 834                         {
 835                                 float mirror_value = (a-b)/2 + b;
 836                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 837                         }
 838
 839                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 840
 841                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 842                         // todo: normalize sound pressure levels? seems unnecessary
 843
 844                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 845                 }
 846                 unaccounted_damage = 0;
 847                 hitsound_time_prev = time;
 848         }
 849
 850         static float typehit_time_prev = 0;
 851         float typehit_time = STAT(TYPEHIT_TIME);
 852         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 853         {
 854                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 855                 typehit_time_prev = typehit_time;
 856         }
 857 }
 858
 859 void HUD_Crosshair()
 860 {SELFPARAM();
 861         static float rainbow_last_flicker;
 862         static vector rainbow_prev_color;
 863         entity e = self;
 864         float f, i, j;
 865         vector v;
 866         if(!scoreboard_active && !camera_active && intermission != 2 &&
 867                 spectatee_status != -1 && !csqcplayer.viewloc &&
 868                 !HUD_MinigameMenu_IsOpened() )
 869         {
 870                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 871                         return;
 872
 873                 if (hud != HUD_NORMAL)
 874                 {
 875                         HUD_Crosshair_Vehicle();
 876                         return;
 877                 }
 878
 879                 string wcross_style;
 880                 float wcross_alpha, wcross_resolution;
 881                 wcross_style = autocvar_crosshair;
 882                 if (wcross_style == "0")
 883                         return;
 884                 wcross_resolution = autocvar_crosshair_size;
 885                 if (wcross_resolution == 0)
 886                         return;
 887                 wcross_alpha = autocvar_crosshair_alpha;
 888                 if (wcross_alpha == 0)
 889                         return;
 890
 891                 // TrueAim check
 892                 float shottype;
 893
 894                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 895                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 896                 wcross_origin.z = 0;
 897                 if(autocvar_crosshair_hittest)
 898                 {
 899                         vector wcross_oldorigin;
 900                         wcross_oldorigin = wcross_origin;
 901                         shottype = TrueAimCheck();
 902                         if(shottype == SHOTTYPE_HITWORLD)
 903                         {
 904                                 v = wcross_origin - wcross_oldorigin;
 905                                 v.x /= vid_conwidth;
 906                                 v.y /= vid_conheight;
 907                                 if(vlen(v) > 0.01)
 908                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 909                         }
 910                         if(!autocvar_crosshair_hittest_showimpact)
 911                                 wcross_origin = wcross_oldorigin;
 912                 }
 913                 else
 914                         shottype = SHOTTYPE_HITWORLD;
 915
 916                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 917                 string wcross_name = "";
 918                 float wcross_scale, wcross_blur;
 919
 920                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 921                 {
 922                         e = switchingweapon;
 923                         if(e)
 924                         {
 925                                 if(autocvar_crosshair_per_weapon)
 926                                 {
 927                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 928                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 929                                         //if (wcross_resolution == 0)
 930                                                 //return;
 931
 932                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 933                                         wcross_resolution *= e.w_crosshair_size;
 934                                         wcross_name = e.w_crosshair;
 935                                 }
 936                         }
 937                 }
 938
 939                 if(wcross_name == "")
 940                         wcross_name = strcat("gfx/crosshair", wcross_style);
 941
 942                 // MAIN CROSSHAIR COLOR DECISION
 943                 switch(autocvar_crosshair_color_special)
 944                 {
 945                         case 1: // crosshair_color_per_weapon
 946                         {
 947                                 if(e)
 948                                 {
 949                                         wcross_color = e.wpcolor;
 950                                         break;
 951                                 }
 952                                 else { goto normalcolor; }
 953                         }
 954
 955                         case 2: // crosshair_color_by_health
 956                         {
 957                                 float x = getstati(STAT_HEALTH);
 958
 959                                 //x = red
 960                                 //y = green
 961                                 //z = blue
 962
 963                                 wcross_color.z = 0;
 964
 965                                 if(x > 200)
 966                                 {
 967                                         wcross_color.x = 0;
 968                                         wcross_color.y = 1;
 969                                 }
 970                                 else if(x > 150)
 971                                 {
 972                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 973                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 974                                 }
 975                                 else if(x > 100)
 976                                 {
 977                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 978                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 979                                         wcross_color.z = 1 - (x-100)*0.02;
 980                                 }
 981                                 else if(x > 50)
 982                                 {
 983                                         wcross_color.x = 1;
 984                                         wcross_color.y = 1;
 985                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 986                                 }
 987                                 else if(x > 20)
 988                                 {
 989                                         wcross_color.x = 1;
 990                                         wcross_color.y = (x-20)*90/27/100;
 991                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 992                                 }
 993                                 else
 994                                 {
 995                                         wcross_color.x = 1;
 996                                         wcross_color.y = 0;
 997                                 }
 998                                 break;
 999                         }
1000
1001                         case 3: // crosshair_color_rainbow
1002                         {
1003                                 if(time >= rainbow_last_flicker)
1004                                 {
1005                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1006                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1007                                 }
1008                                 wcross_color = rainbow_prev_color;
1009                                 break;
1010                         }
1011                         :normalcolor
1012                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
1013                 }
1014
1015                 if(autocvar_crosshair_effect_scalefade)
1016                 {
1017                         wcross_scale = wcross_resolution;
1018                         wcross_resolution = 1;
1019                 }
1020                 else
1021                 {
1022                         wcross_scale = 1;
1023                 }
1024
1025                 if(autocvar_crosshair_pickup)
1026                 {
1027                         float stat_pickup_time = STAT(LAST_PICKUP);
1028
1029                         if(pickup_crosshair_time < stat_pickup_time)
1030                         {
1031                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1032                                         pickup_crosshair_size = 1;
1033
1034                                 pickup_crosshair_time = stat_pickup_time;
1035                         }
1036
1037                         if(pickup_crosshair_size > 0)
1038                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1039                         else
1040                                 pickup_crosshair_size = 0;
1041
1042                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1043                 }
1044
1045                 // todo: make crosshair hit indication dependent on damage dealt
1046                 if(autocvar_crosshair_hitindication)
1047                 {
1048                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1049
1050                         if(unaccounted_damage)
1051                         {
1052                                 hitindication_crosshair_size = 1;
1053                         }
1054
1055                         if(hitindication_crosshair_size > 0)
1056                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1057                         else
1058                                 hitindication_crosshair_size = 0;
1059
1060                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1061                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1062                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1063                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1064                 }
1065
1066                 if(shottype == SHOTTYPE_HITENEMY)
1067                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1068                 if(shottype == SHOTTYPE_HITTEAM)
1069                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1070
1071                 f = fabs(autocvar_crosshair_effect_time);
1072                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1073                 {
1074                         wcross_changedonetime = time + f;
1075                 }
1076                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1077                 {
1078                         wcross_name_changestarttime = time;
1079                         wcross_name_changedonetime = time + f;
1080                         if(wcross_name_goal_prev_prev)
1081                                 strunzone(wcross_name_goal_prev_prev);
1082                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1083                         wcross_name_goal_prev = strzone(wcross_name);
1084                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1085                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1086                         wcross_resolution_goal_prev = wcross_resolution;
1087                 }
1088
1089                 wcross_scale_goal_prev = wcross_scale;
1090                 wcross_alpha_goal_prev = wcross_alpha;
1091                 wcross_color_goal_prev = wcross_color;
1092
1093                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1094                 {
1095                         wcross_blur = 1;
1096                         wcross_alpha *= 0.75;
1097                 }
1098                 else
1099                         wcross_blur = 0;
1100                 // *_prev is at time-frametime
1101                 // * is at wcross_changedonetime+f
1102                 // what do we have at time?
1103                 if(time < wcross_changedonetime)
1104                 {
1105                         f = frametime / (wcross_changedonetime - time + frametime);
1106                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1107                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1108                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1109                 }
1110
1111                 wcross_scale_prev = wcross_scale;
1112                 wcross_alpha_prev = wcross_alpha;
1113                 wcross_color_prev = wcross_color;
1114
1115                 MUTATOR_CALLHOOK(UpdateCrosshair);
1116
1117                 wcross_scale *= 1 - autocvar__menu_alpha;
1118                 wcross_alpha *= 1 - autocvar__menu_alpha;
1119                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1120
1121                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1122                 {
1123                         // crosshair rings for weapon stats
1124                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1125                         {
1126                                 // declarations and stats
1127                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1128                                 string ring_image = string_null, ring_inner_image = string_null;
1129                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1130
1131                                 ring_scale = autocvar_crosshair_ring_size;
1132
1133                                 float weapon_clipload, weapon_clipsize;
1134                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1135                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1136
1137                                 float ok_ammo_charge, ok_ammo_chargepool;
1138                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1139                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1140
1141                                 float vortex_charge, vortex_chargepool;
1142                                 vortex_charge = STAT(VORTEX_CHARGE);
1143                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1144
1145                                 float arc_heat = STAT(ARC_HEAT);
1146
1147                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1148                                         vortex_charge_movingavg = vortex_charge;
1149
1150
1151                                 // handle the values
1152                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1153                                 {
1154                                         if (vortex_chargepool || use_vortex_chargepool) {
1155                                                 use_vortex_chargepool = 1;
1156                                                 ring_inner_value = vortex_chargepool;
1157                                         } else {
1158                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1159                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1160                                         }
1161
1162                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1163                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1164                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1165
1166                                         // draw the outer ring to show the current charge of the weapon
1167                                         ring_value = vortex_charge;
1168                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1169                                         ring_rgb = wcross_color;
1170                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1171                                 }
1172                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && minelayer_maxmines && autocvar_crosshair_ring_minelayer)
1173                                 {
1174                                         ring_value = bound(0, STAT(LAYED_MINES) / minelayer_maxmines, 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1175                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1176                                         ring_rgb = wcross_color;
1177                                         ring_image = "gfx/crosshair_ring.tga";
1178                                 }
1179                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1180                                 {
1181                                         ring_value = bound(0, STAT(HAGAR_LOAD) / hagar_maxrockets, 1);
1182                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1183                                         ring_rgb = wcross_color;
1184                                         ring_image = "gfx/crosshair_ring.tga";
1185                                 }
1186                                 else if (ok_ammo_charge)
1187                                 {
1188                                         ring_value = ok_ammo_chargepool;
1189                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1190                                         ring_rgb = wcross_color;
1191                                         ring_image = "gfx/crosshair_ring.tga";
1192                                 }
1193                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1194                                 {
1195                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1196                                         ring_scale = autocvar_crosshair_ring_reload_size;
1197                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1198                                         ring_rgb = wcross_color;
1199
1200                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1201                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1202                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1203                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1204                                         else
1205                                                 ring_image = "gfx/crosshair_ring.tga";
1206                                 }
1207                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1208                                 {
1209                                         ring_value = arc_heat;
1210                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1211                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1212                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1213                                         ring_image = "gfx/crosshair_ring.tga";
1214                                 }
1215
1216                                 // if in weapon switch animation, fade ring out/in
1217                                 if(autocvar_crosshair_effect_time > 0)
1218                                 {
1219                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1220                                         if (f >= 1)
1221                                         {
1222                                                 wcross_ring_prev = ((ring_image) ? true : false);
1223                                         }
1224
1225                                         if(wcross_ring_prev)
1226                                         {
1227                                                 if(f < 1)
1228                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1229                                         }
1230                                         else
1231                                         {
1232                                                 if(f < 1)
1233                                                         ring_alpha *= bound(0, f, 1);
1234                                         }
1235                                 }
1236
1237                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1238                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1239
1240                                 if (ring_value)
1241                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1242                         }
1243
1244 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1245                         do \
1246                         { \
1247                                 if(wcross_blur > 0) \
1248                                 { \
1249                                         for(i = -2; i <= 2; ++i) \
1250                                         for(j = -2; j <= 2; ++j) \
1251                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1252                                 } \
1253                                 else \
1254                                 { \
1255                                         M(0,0,sz,wcross_name,wcross_alpha); \
1256                                 } \
1257                         } \
1258                         while(0)
1259
1260 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1261                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1262
1263 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1264                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1265
1266                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1267                         {
1268                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1269                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1270                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1271                                 f = 1 - f;
1272                         }
1273                         else
1274                         {
1275                                 f = 1;
1276                         }
1277                         wcross_name_alpha_goal_prev = f;
1278
1279                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1280                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1281
1282                         if(autocvar_crosshair_dot)
1283                         {
1284                                 vector wcross_color_old;
1285                                 wcross_color_old = wcross_color;
1286
1287                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1288                                         wcross_color = stov(autocvar_crosshair_dot_color);
1289
1290                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1291                                 // FIXME why don't we use wcross_alpha here?
1292                                 wcross_color = wcross_color_old;
1293                         }
1294                 }
1295         }
1296         else
1297         {
1298                 wcross_scale_prev = 0;
1299                 wcross_alpha_prev = 0;
1300                 wcross_scale_goal_prev = 0;
1301                 wcross_alpha_goal_prev = 0;
1302                 wcross_changedonetime = 0;
1303                 if(wcross_name_goal_prev)
1304                         strunzone(wcross_name_goal_prev);
1305                 wcross_name_goal_prev = string_null;
1306                 if(wcross_name_goal_prev_prev)
1307                         strunzone(wcross_name_goal_prev_prev);
1308                 wcross_name_goal_prev_prev = string_null;
1309                 wcross_name_changestarttime = 0;
1310                 wcross_name_changedonetime = 0;
1311                 wcross_name_alpha_goal_prev = 0;
1312                 wcross_name_alpha_goal_prev_prev = 0;
1313                 wcross_resolution_goal_prev = 0;
1314                 wcross_resolution_goal_prev_prev = 0;
1315         }
1316 }
1317
1318 void HUD_Draw()
1319 {
1320         vector rgb = '0 0 0';
1321         float a = 1;
1322         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1323         {
1324                 rgb = MUTATOR_ARGV(0, vector);
1325                 a = MUTATOR_ARGV(0, float);
1326         }
1327         else if(STAT(FROZEN))
1328         {
1329                 rgb = ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1');
1330         }
1331         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, rgb, autocvar_hud_colorflash_alpha * a, DRAWFLAG_ADDITIVE);
1332         if(!intermission)
1333         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1334         {
1335                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1336                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1337         }
1338         else if(STAT(REVIVE_PROGRESS))
1339         {
1340                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1341                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1342         }
1343
1344         if(autocvar_r_letterbox == 0)
1345                 if(autocvar_viewsize < 120)
1346                 {
1347                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1348                                 Accuracy_LoadLevels();
1349
1350                         HUD_Main();
1351                         HUD_DrawScoreboard();
1352                 }
1353
1354         // crosshair goes VERY LAST
1355         UpdateDamage();
1356         HUD_Crosshair();
1357         HitSound();
1358 }
1359
1360 bool ov_enabled;
1361 float oldr_nearclip;
1362 float oldr_farclip_base;
1363 float oldr_farclip_world;
1364 float oldr_novis;
1365 float oldr_useportalculling;
1366 float oldr_useinfinitefarclip;
1367
1368 void cl_notice_run();
1369 float prev_myteam;
1370 int lasthud;
1371 float vh_notice_time;
1372 void WaypointSprite_Load();
1373 void CSQC_UpdateView(float w, float h)
1374 {SELFPARAM();
1375         entity e;
1376         float fov;
1377         float f;
1378         vector vf_size, vf_min;
1379         float a;
1380
1381         execute_next_frame();
1382
1383         ++framecount;
1384
1385         stats_get();
1386         hud = STAT(HUD);
1387
1388         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1389                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1390
1391         lasthud = hud;
1392
1393         if(autocvar__hud_showbinds_reload) // menu can set this one
1394         {
1395                 db_close(binddb);
1396                 binddb = db_create();
1397                 cvar_set("_hud_showbinds_reload", "0");
1398         }
1399
1400         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1401                 view_quality = getproperty(VF_MINFPS_QUALITY);
1402         else
1403                 view_quality = 1;
1404
1405         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(self);
1406         button_zoom = PHYS_INPUT_BUTTON_ZOOM(self);
1407
1408         vf_size = getpropertyvec(VF_SIZE);
1409         vf_min = getpropertyvec(VF_MIN);
1410         vid_width = vf_size.x;
1411         vid_height = vf_size.y;
1412
1413         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1414         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1415
1416         WaypointSprite_Load();
1417
1418         CSQCPlayer_SetCamera();
1419
1420         if(player_localentnum <= maxclients) // is it a client?
1421                 current_player = player_localentnum - 1;
1422         else // then player_localentnum is the vehicle I'm driving
1423                 current_player = player_localnum;
1424         myteam = entcs_GetTeam(current_player);
1425
1426         if(myteam != prev_myteam)
1427         {
1428                 myteamcolors = colormapPaletteColor(myteam, 1);
1429                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1430                 prev_myteam = myteam;
1431         }
1432
1433         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1434
1435         float is_dead = (getstati(STAT_HEALTH) <= 0);
1436
1437         // FIXME do we need this hack?
1438         if(isdemo())
1439         {
1440                 // in demos, input_buttons do not work
1441                 button_zoom = (autocvar__togglezoom == "-");
1442         }
1443         else if(button_zoom
1444                 && autocvar_cl_unpress_zoom_on_death
1445                 && (spectatee_status >= 0)
1446                 && (is_dead || intermission))
1447         {
1448                 // no zoom while dead or in intermission please
1449                 localcmd("-zoom\n");
1450                 button_zoom = false;
1451         }
1452
1453         // event chase camera
1454         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1455         {
1456                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1457                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1458                 entity gen = world;
1459
1460                 if(ons_roundlost)
1461                 {
1462                         entity e;
1463                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1464                         {
1465                                 if(e.health <= 0)
1466                                 {
1467                                         gen = e;
1468                                         break;
1469                                 }
1470                         }
1471                         if(!gen)
1472                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1473                 }
1474                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1475                 {
1476                         eventchase_running = true;
1477
1478                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1479                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1480                         if(ons_roundlost) { current_view_origin = gen.origin; }
1481
1482                         // detect maximum viewoffset and use it
1483                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1484                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1485                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1486
1487                         if(view_offset)
1488                         {
1489                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1490                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1491                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1492                         }
1493
1494                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1495                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1496                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1497                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1498
1499                         // make the camera smooth back
1500                         float chase_distance = autocvar_cl_eventchase_distance;
1501                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1502                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1503
1504                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1505                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1506                         else if(eventchase_current_distance != chase_distance)
1507                                 eventchase_current_distance = chase_distance;
1508
1509                         makevectors(view_angles);
1510
1511                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1512                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1513
1514                         // If the boxtrace fails, revert back to line tracing.
1515                         if(!self.viewloc)
1516                         if(trace_startsolid)
1517                         {
1518                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1519                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1520                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1521                         }
1522                         else { setproperty(VF_ORIGIN, trace_endpos); }
1523
1524                         if(!self.viewloc)
1525                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1526                 }
1527                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1528                 {
1529                         eventchase_running = false;
1530                         cvar_set("chase_active", "0");
1531                         eventchase_current_distance = 0; // start from 0 next time
1532                 }
1533         }
1534         // workaround for camera stuck between player's legs when using chase_active 1
1535         // because the engine stops updating the chase_active camera when the game ends
1536         else if(intermission)
1537         {
1538                 cvar_settemp("chase_active", "-1");
1539                 eventchase_current_distance = 0;
1540         }
1541
1542         // do lockview after event chase camera so that it still applies whenever necessary.
1543         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1544         {
1545                 setproperty(VF_ORIGIN, freeze_org);
1546                 setproperty(VF_ANGLES, freeze_ang);
1547         }
1548         else
1549         {
1550                 freeze_org = getpropertyvec(VF_ORIGIN);
1551                 freeze_ang = getpropertyvec(VF_ANGLES);
1552         }
1553
1554         WarpZone_FixView();
1555         //WarpZone_FixPMove();
1556
1557         vector ov_org = '0 0 0';
1558         vector ov_mid = '0 0 0';
1559         vector ov_worldmin = '0 0 0';
1560         vector ov_worldmax = '0 0 0';
1561         if(autocvar_cl_orthoview)
1562         {
1563                 ov_worldmin = mi_picmin;
1564                 ov_worldmax = mi_picmax;
1565
1566                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1567                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1568                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1569
1570                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1571                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1572
1573                 float ov_nearest = vlen(ov_org - vec3(
1574                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1575                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1576                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1577                 ));
1578
1579                 float ov_furthest = 0;
1580                 float dist = 0;
1581
1582                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1583                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1584                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1585                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1586                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1587                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1588                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1589                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1590
1591                 if(!ov_enabled)
1592                 {
1593                         oldr_nearclip = cvar("r_nearclip");
1594                         oldr_farclip_base = cvar("r_farclip_base");
1595                         oldr_farclip_world = cvar("r_farclip_world");
1596                         oldr_novis = cvar("r_novis");
1597                         oldr_useportalculling = cvar("r_useportalculling");
1598                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1599                 }
1600
1601                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1602                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1603                 cvar_settemp("r_farclip_world", "0");
1604                 cvar_settemp("r_novis", "1");
1605                 cvar_settemp("r_useportalculling", "0");
1606                 cvar_settemp("r_useinfinitefarclip", "0");
1607
1608                 setproperty(VF_ORIGIN, ov_org);
1609                 setproperty(VF_ANGLES, '90 0 0');
1610
1611                 ov_enabled = true;
1612
1613                 #if 0
1614                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1615                         vtos(ov_org),
1616                         vtos(getpropertyvec(VF_ANGLES)),
1617                         ov_distance,
1618                         ov_nearest,
1619                         ov_furthest);
1620                 #endif
1621         }
1622         else
1623         {
1624                 if(ov_enabled)
1625                 {
1626                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1627                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1628                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1629                         cvar_set("r_novis", ftos(oldr_novis));
1630                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1631                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1632                 }
1633                 ov_enabled = false;
1634         }
1635
1636         // Render the Scene
1637         view_origin = getpropertyvec(VF_ORIGIN);
1638         view_angles = getpropertyvec(VF_ANGLES);
1639         makevectors(view_angles);
1640         view_forward = v_forward;
1641         view_right = v_right;
1642         view_up = v_up;
1643
1644 #ifdef BLURTEST
1645         if(time > blurtest_time0 && time < blurtest_time1)
1646         {
1647                 float r, t;
1648
1649                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1650                 r = t * blurtest_radius;
1651                 f = 1 / pow(t, blurtest_power) - 1;
1652
1653                 cvar_set("r_glsl_postprocess", "1");
1654                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1655         }
1656         else
1657         {
1658                 cvar_set("r_glsl_postprocess", "0");
1659                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1660         }
1661 #endif
1662
1663         TargetMusic_Advance();
1664         Fog_Force();
1665
1666         if(drawtime == 0)
1667                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1668         else
1669                 drawframetime = bound(0.000001, time - drawtime, 1);
1670         drawtime = time;
1671
1672         // watch for gametype changes here...
1673         // in ParseStuffCMD the cmd isn't executed yet :/
1674         // might even be better to add the gametype to TE_CSQC_INIT...?
1675         if(!postinit)
1676                 PostInit();
1677
1678         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1679         {
1680                 if(calledhooks & HOOK_START)
1681                 {
1682                         localcmd("\ncl_hook_gameend\n");
1683                         calledhooks |= HOOK_END;
1684                 }
1685         }
1686
1687         Announcer();
1688
1689         fov = autocvar_fov;
1690         if(fov <= 59.5)
1691         {
1692                 if(!zoomscript_caught)
1693                 {
1694                         localcmd("+button9\n");
1695                         zoomscript_caught = 1;
1696                 }
1697         }
1698         else
1699         {
1700                 if(zoomscript_caught)
1701                 {
1702                         localcmd("-button9\n");
1703                         zoomscript_caught = 0;
1704                 }
1705         }
1706
1707         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1708
1709         // currently switching-to weapon (for crosshair)
1710         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1711
1712         // actually active weapon (for zoom)
1713         activeweapon = Weapons_from(getstati(STAT_ACTIVEWEAPON));
1714
1715         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1716
1717         f = (serverflags & SERVERFLAG_TEAMPLAY);
1718         if(f != teamplay)
1719         {
1720                 teamplay = f;
1721                 HUD_InitScores();
1722         }
1723
1724         if(last_switchweapon != switchweapon)
1725         {
1726                 weapontime = time;
1727                 last_switchweapon = switchweapon;
1728                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1729                 {
1730                         localcmd("-zoom\n");
1731                         button_zoom = false;
1732                 }
1733                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1734                 {
1735                         localcmd("-fire\n");
1736                         localcmd("-fire2\n");
1737                         button_attack2 = false;
1738                 }
1739         }
1740         if(last_activeweapon != activeweapon)
1741         {
1742                 last_activeweapon = activeweapon;
1743
1744                 e = activeweapon;
1745                 if(e.netname != "")
1746                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1747                 else
1748                         localcmd("\ncl_hook_activeweapon none\n");
1749         }
1750
1751         // ALWAYS Clear Current Scene First
1752         clearscene();
1753
1754         setproperty(VF_ORIGIN, view_origin);
1755         setproperty(VF_ANGLES, view_angles);
1756
1757         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1758         setproperty(VF_SIZE, vf_size);
1759         setproperty(VF_MIN, vf_min);
1760
1761         // Assign Standard Viewflags
1762         // Draw the World (and sky)
1763         setproperty(VF_DRAWWORLD, 1);
1764
1765         // Set the console size vars
1766         vid_conwidth = autocvar_vid_conwidth;
1767         vid_conheight = autocvar_vid_conheight;
1768         vid_pixelheight = autocvar_vid_pixelheight;
1769
1770         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1771         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1772         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1773
1774         // Camera for demo playback
1775         if(camera_active)
1776         {
1777                 if(autocvar_camera_enable)
1778                         CSQC_Demo_Camera();
1779                 else
1780                 {
1781                         cvar_set("chase_active", ftos(chase_active_backup));
1782                         cvar_set("cl_demo_mousegrab", "0");
1783                         camera_active = false;
1784                 }
1785         }
1786         else
1787         {
1788 #ifdef CAMERATEST
1789                 if(autocvar_camera_enable)
1790 #else
1791                 if(autocvar_camera_enable && isdemo())
1792 #endif
1793                 {
1794                         // Enable required Darkplaces cvars
1795                         chase_active_backup = autocvar_chase_active;
1796                         cvar_set("chase_active", "2");
1797                         cvar_set("cl_demo_mousegrab", "1");
1798                         camera_active = true;
1799                         camera_mode = false;
1800                 }
1801         }
1802
1803         // Draw the Crosshair
1804         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1805
1806         // Draw the Engine Status Bar (the default Quake HUD)
1807         setproperty(VF_DRAWENGINESBAR, 0);
1808
1809         // Update the mouse position
1810         /*
1811            mousepos_x = vid_conwidth;
1812            mousepos_y = vid_conheight;
1813            mousepos = mousepos*0.5 + getmousepos();
1814          */
1815
1816         FOREACH_ENTITY(it.draw, LAMBDA(WITH(entity, self, it, it.draw(it))));
1817
1818         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1819         renderscene();
1820
1821         // now switch to 2D drawing mode by calling a 2D drawing function
1822         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1823         // next R_RenderScene call
1824         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1825
1826         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1827         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1828         {
1829                 // apply night vision effect
1830                 vector tc_00, tc_01, tc_10, tc_11;
1831                 vector rgb = '0 0 0';
1832
1833                 if(!nightvision_noise)
1834                 {
1835                         nightvision_noise = new(nightvision_noise);
1836                 }
1837                 if(!nightvision_noise2)
1838                 {
1839                         nightvision_noise2 = new(nightvision_noise2);
1840                 }
1841
1842                 // color tint in yellow
1843                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1844
1845                 // draw BG
1846                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1847                 rgb = '1 1 1';
1848                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1849                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1850                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1851                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1852                 tc_11 = tc_01 + tc_10 - tc_00;
1853                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1854                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1855                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1856                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1857                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1858                 R_EndPolygon();
1859
1860                 // draw FG
1861                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1862                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1863                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1864                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1865                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1866                 tc_11 = tc_01 + tc_10 - tc_00;
1867                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1868                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1869                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1870                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1871                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1872                 R_EndPolygon();
1873         }
1874
1875         if(autocvar_cl_reticle)
1876         {
1877                 Weapon wep = activeweapon;
1878                 // Draw the aiming reticle for weapons that use it
1879                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1880                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1881                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1882                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1883                 {
1884                         // no zoom reticle while dead
1885                         reticle_type = 0;
1886                 }
1887                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1888                 {
1889                         if(reticle_image != "") { reticle_type = 2; }
1890                         else { reticle_type = 0; }
1891                 }
1892                 else if(button_zoom || zoomscript_caught)
1893                 {
1894                         // normal zoom
1895                         reticle_type = 1;
1896                 }
1897
1898                 if(reticle_type)
1899                 {
1900                         if(autocvar_cl_reticle_stretch)
1901                         {
1902                                 reticle_size.x = vid_conwidth;
1903                                 reticle_size.y = vid_conheight;
1904                                 reticle_pos.x = 0;
1905                                 reticle_pos.y = 0;
1906                         }
1907                         else
1908                         {
1909                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1910                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1911                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1912                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1913                         }
1914
1915                         if(zoomscript_caught)
1916                                 f = 1;
1917                         else
1918                                 f = current_zoomfraction;
1919
1920                         if(f)
1921                         {
1922                                 switch(reticle_type)
1923                                 {
1924                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1925                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1926                                 }
1927                         }
1928                 }
1929         }
1930         else
1931         {
1932                 if(reticle_type != 0) { reticle_type = 0; }
1933         }
1934
1935
1936         // improved polyblend
1937         if(autocvar_hud_contents)
1938         {
1939                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1940                 vector liquidcolor;
1941
1942                 switch(pointcontents(view_origin))
1943                 {
1944                         case CONTENT_WATER:
1945                                 liquidalpha = autocvar_hud_contents_water_alpha;
1946                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1947                                 incontent = 1;
1948                                 break;
1949
1950                         case CONTENT_LAVA:
1951                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1952                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1953                                 incontent = 1;
1954                                 break;
1955
1956                         case CONTENT_SLIME:
1957                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1958                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1959                                 incontent = 1;
1960                                 break;
1961
1962                         default:
1963                                 liquidalpha = 0;
1964                                 liquidcolor = '0 0 0';
1965                                 incontent = 0;
1966                                 break;
1967                 }
1968
1969                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1970                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1971                         contentfadetime = autocvar_hud_contents_fadeintime;
1972                         liquidalpha_prev = liquidalpha;
1973                         liquidcolor_prev = liquidcolor;
1974                 }
1975                 else
1976                         contentfadetime = autocvar_hud_contents_fadeouttime;
1977
1978                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1979                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1980
1981                 if(contentavgalpha)
1982                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1983
1984                 if(autocvar_hud_postprocessing)
1985                 {
1986                         if(autocvar_hud_contents_blur && contentavgalpha)
1987                         {
1988                                 content_blurpostprocess.x = 1;
1989                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1990                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1991                         }
1992                         else
1993                         {
1994                                 content_blurpostprocess.x = 0;
1995                                 content_blurpostprocess.y = 0;
1996                                 content_blurpostprocess.z = 0;
1997                         }
1998                 }
1999         }
2000
2001         if(autocvar_hud_damage && !STAT(FROZEN))
2002         {
2003                 splash_size.x = max(vid_conwidth, vid_conheight);
2004                 splash_size.y = max(vid_conwidth, vid_conheight);
2005                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2006                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2007
2008                 float myhealth_flash_temp;
2009                 myhealth = getstati(STAT_HEALTH);
2010
2011                 // fade out
2012                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2013                 // add new damage
2014                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2015
2016                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2017                 pain_threshold = autocvar_hud_damage_pain_threshold;
2018                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2019                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2020
2021                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2022                 {
2023                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2024                 }
2025
2026                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2027
2028                 if(myhealth_prev < 1)
2029                 {
2030                         if(myhealth >= 1)
2031                         {
2032                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2033                                 myhealth_flash_temp = 0;
2034                         }
2035                         else
2036                         {
2037                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2038                         }
2039                 }
2040
2041                 if(spectatee_status == -1 || intermission)
2042                 {
2043                         myhealth_flash = 0; // observing, or match ended
2044                         myhealth_flash_temp = 0;
2045                 }
2046
2047                 myhealth_prev = myhealth;
2048
2049                 // IDEA: change damage color/picture based on player model for robot/alien species?
2050                 // pro: matches model better
2051                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2052                 // maybe different reddish pics?
2053                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2054                 {
2055                         if(autocvar_cl_gentle_damage == 2)
2056                         {
2057                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2058                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2059                         }
2060                         else
2061                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2062
2063                         if(myhealth_flash_temp > 0)
2064                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2065                 }
2066                 else if(myhealth_flash_temp > 0)
2067                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2068
2069                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2070                 {
2071                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2072                         {
2073                                 damage_blurpostprocess.x = 1;
2074                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2075                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2076                         }
2077                         else
2078                         {
2079                                 damage_blurpostprocess.x = 0;
2080                                 damage_blurpostprocess.y = 0;
2081                                 damage_blurpostprocess.z = 0;
2082                         }
2083                 }
2084         }
2085
2086         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2087         float e2 = (autocvar_hud_powerup != 0);
2088         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2089         {
2090                 // enable or disable rendering types if they are used or not
2091                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2092                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2093
2094                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2095                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2096                 {
2097                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2098                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2099                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2100                         {
2101                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2102                                 old_blurradius = blurradius;
2103                                 old_bluralpha = bluralpha;
2104                         }
2105                 }
2106                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2107                 {
2108                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2109                         old_blurradius = 0;
2110                         old_bluralpha = 0;
2111                 }
2112
2113                 // edge detection postprocess handling done second (used by hud_powerup)
2114                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2115                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2116                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2117
2118                 sharpen_intensity = bound(0, ((getstati(STAT_HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2119
2120                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2121                 {
2122                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2123                         {
2124                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2125                                 old_sharpen_intensity = sharpen_intensity;
2126                         }
2127                 }
2128                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2129                 {
2130                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2131                         old_sharpen_intensity = 0;
2132                 }
2133
2134                 if(cvar("r_glsl_postprocess") == 0)
2135                         cvar_set("r_glsl_postprocess", "2");
2136         }
2137         else if(cvar("r_glsl_postprocess") == 2)
2138                 cvar_set("r_glsl_postprocess", "0");
2139
2140         /*if(gametype == MAPINFO_TYPE_CTF)
2141           {
2142           ctf_view();
2143           } else */
2144
2145         // draw 2D entities
2146         FOREACH_ENTITY(it.draw2d, LAMBDA(WITH(entity, self, it, it.draw2d(it))));
2147         Draw_ShowNames_All();
2148         Debug_Draw();
2149
2150         scoreboard_active = HUD_WouldDrawScoreboard();
2151
2152         HUD_Draw();
2153
2154         if(NextFrameCommand)
2155         {
2156                 localcmd("\n", NextFrameCommand, "\n");
2157                 NextFrameCommand = string_null;
2158         }
2159
2160         // we must do this check AFTER a frame was rendered, or it won't work
2161         if(cs_project_is_b0rked == 0)
2162         {
2163                 string w0, h0;
2164                 w0 = ftos(autocvar_vid_conwidth);
2165                 h0 = ftos(autocvar_vid_conheight);
2166                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2167                 //setproperty(VF_FOV, '90 90 0');
2168                 setproperty(VF_ORIGIN, '0 0 0');
2169                 setproperty(VF_ANGLES, '0 0 0');
2170                 setproperty(VF_PERSPECTIVE, 1);
2171                 makevectors('0 0 0');
2172                 vector v1, v2;
2173                 cvar_set("vid_conwidth", "800");
2174                 cvar_set("vid_conheight", "600");
2175                 v1 = cs_project(v_forward);
2176                 cvar_set("vid_conwidth", "640");
2177                 cvar_set("vid_conheight", "480");
2178                 v2 = cs_project(v_forward);
2179                 if(v1 == v2)
2180                         cs_project_is_b0rked = 1;
2181                 else
2182                         cs_project_is_b0rked = -1;
2183                 cvar_set("vid_conwidth", w0);
2184                 cvar_set("vid_conheight", h0);
2185         }
2186
2187         if(autocvar__hud_configure)
2188                 HUD_Panel_Mouse();
2189         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2190                 HUD_Minigame_Mouse();
2191         else if(QuickMenu_IsOpened())
2192                 QuickMenu_Mouse();
2193         else
2194                 HUD_Radar_Mouse();
2195
2196         cl_notice_run();
2197
2198         // let's reset the view back to normal for the end
2199         setproperty(VF_MIN, '0 0 0');
2200         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2201 }
2202
2203
2204 // following vectors must be global to allow seamless switching between camera modes
2205 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2206 void CSQC_Demo_Camera()
2207 {
2208         float speed, attenuation, dimensions;
2209         vector tmp, delta;
2210
2211         if( autocvar_camera_reset || !camera_mode )
2212         {
2213                 camera_offset = '0 0 0';
2214                 current_angles = '0 0 0';
2215                 camera_direction = '0 0 0';
2216                 camera_offset.z += 30;
2217                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2218                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2219                 current_origin = view_origin;
2220                 current_camera_offset  = camera_offset;
2221                 cvar_set("camera_reset", "0");
2222                 camera_mode = CAMERA_CHASE;
2223         }
2224
2225         // Camera angles
2226         if( camera_roll )
2227                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2228
2229         if(autocvar_camera_look_player)
2230         {
2231                 vector dir;
2232                 float n;
2233
2234                 dir = normalize(view_origin - current_position);
2235                 n = mouse_angles.z;
2236                 mouse_angles = vectoangles(dir);
2237                 mouse_angles.x = mouse_angles.x * -1;
2238                 mouse_angles.z = n;
2239         }
2240         else
2241         {
2242                 tmp = getmousepos() * 0.1;
2243                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
2244                 {
2245                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2246                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2247                 }
2248         }
2249
2250         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2251         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2252         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2253         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2254
2255         // Fix difference when angles don't have the same sign
2256         delta = '0 0 0';
2257         if(mouse_angles.y < -60 && current_angles.y > 60)
2258                 delta = '0 360 0';
2259         if(mouse_angles.y > 60 && current_angles.y < -60)
2260                 delta = '0 -360 0';
2261
2262         if(autocvar_camera_look_player)
2263                 attenuation = autocvar_camera_look_attenuation;
2264         else
2265                 attenuation = autocvar_camera_speed_attenuation;
2266
2267         attenuation = 1 / max(1, attenuation);
2268         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2269
2270         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2271         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2272         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2273         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2274
2275         // Camera position
2276         tmp = '0 0 0';
2277         dimensions = 0;
2278
2279         if( camera_direction.x )
2280         {
2281                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2282                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2283                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2284                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2285                 ++dimensions;
2286         }
2287
2288         if( camera_direction.y )
2289         {
2290                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2291                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2292                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2293                 ++dimensions;
2294         }
2295
2296         if( camera_direction.z )
2297         {
2298                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2299                 ++dimensions;
2300         }
2301
2302         if(autocvar_camera_free)
2303                 speed = autocvar_camera_speed_free;
2304         else
2305                 speed = autocvar_camera_speed_chase;
2306
2307         if(dimensions)
2308         {
2309                 speed = speed * sqrt(1 / dimensions);
2310                 camera_offset += tmp * speed;
2311         }
2312
2313         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2314
2315         // Camera modes
2316         if( autocvar_camera_free )
2317         {
2318                 if ( camera_mode == CAMERA_CHASE )
2319                 {
2320                         current_camera_offset = current_origin + current_camera_offset;
2321                         camera_offset = current_origin + camera_offset;
2322                 }
2323
2324                 camera_mode = CAMERA_FREE;
2325                 current_position = current_camera_offset;
2326         }
2327         else
2328         {
2329                 if ( camera_mode == CAMERA_FREE )
2330                 {
2331                         current_origin = view_origin;
2332                         camera_offset = camera_offset - current_origin;
2333                         current_camera_offset = current_camera_offset - current_origin;
2334                 }
2335
2336                 camera_mode = CAMERA_CHASE;
2337
2338                 if(autocvar_camera_chase_smoothly)
2339                         current_origin += (view_origin - current_origin) * attenuation;
2340                 else
2341                         current_origin = view_origin;
2342
2343                 current_position = current_origin + current_camera_offset;
2344         }
2345
2346         setproperty(VF_ANGLES, current_angles);
2347         setproperty(VF_ORIGIN, current_position);
2348 }