qcsrc/client/view.qc

   1
   2 #include "announcer.qh"
   3 #include "hook.qh"
   4 #include "hud/all.qh"
   5 #include "mapvoting.qh"
   6 #include "scoreboard.qh"
   7 #include "shownames.qh"
   8 #include "quickmenu.qh"
   9
  10 #include "mutators/events.qh"
  11
  12 #include "../common/anim.qh"
  13 #include "../common/constants.qh"
  14 #include "../common/debug.qh"
  15 #include "../common/mapinfo.qh"
  16 #include "../common/gamemodes/all.qh"
  17 #include "../common/physics/player.qh"
  18 #include "../common/stats.qh"
  19 #include "../common/triggers/target/music.qh"
  20 #include "../common/teams.qh"
  21
  22 #include "../common/vehicles/all.qh"
  23 #include "../common/weapons/all.qh"
  24 #include "../common/viewloc.qh"
  25 #include "../common/minigames/cl_minigames.qh"
  26 #include "../common/minigames/cl_minigames_hud.qh"
  27
  28 #include "../lib/csqcmodel/cl_player.qh"
  29
  30 #include "../lib/warpzone/client.qh"
  31 #include "../lib/warpzone/common.qh"
  32
  33 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  34
  35 float autocvar_cl_viewmodel_scale;
  36
  37 bool autocvar_cl_bobmodel;
  38 float autocvar_cl_bobmodel_speed;
  39 float autocvar_cl_bobmodel_side;
  40 float autocvar_cl_bobmodel_up;
  41
  42 float autocvar_cl_followmodel;
  43 float autocvar_cl_followmodel_side_speed;
  44 float autocvar_cl_followmodel_side_highpass;
  45 float autocvar_cl_followmodel_side_highpass1;
  46 float autocvar_cl_followmodel_side_limit;
  47 float autocvar_cl_followmodel_side_lowpass;
  48 float autocvar_cl_followmodel_up_speed;
  49 float autocvar_cl_followmodel_up_highpass;
  50 float autocvar_cl_followmodel_up_highpass1;
  51 float autocvar_cl_followmodel_up_limit;
  52 float autocvar_cl_followmodel_up_lowpass;
  53
  54 float autocvar_cl_leanmodel;
  55 float autocvar_cl_leanmodel_side_speed;
  56 float autocvar_cl_leanmodel_side_highpass;
  57 float autocvar_cl_leanmodel_side_highpass1;
  58 float autocvar_cl_leanmodel_side_lowpass;
  59 float autocvar_cl_leanmodel_side_limit;
  60 float autocvar_cl_leanmodel_up_speed;
  61 float autocvar_cl_leanmodel_up_highpass;
  62 float autocvar_cl_leanmodel_up_highpass1;
  63 float autocvar_cl_leanmodel_up_lowpass;
  64 float autocvar_cl_leanmodel_up_limit;
  65
  66 #define lowpass(value, frac, ref_store, ret) MACRO_BEGIN \
  67 { \
  68         float __frac = bound(0, frac, 1); \
  69         ret = ref_store = ref_store * (1 - __frac) + (value) * __frac; \
  70 } MACRO_END
  71
  72 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  73 { \
  74         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  75         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  76 } MACRO_END
  77
  78 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  79 { \
  80         float __f = 0; lowpass(value, frac, ref_store, __f); \
  81         ret = (value) - __f; \
  82 } MACRO_END
  83
  84 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  85 { \
  86         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  87         ret = (value) - __f; \
  88 } MACRO_END
  89
  90 #define lowpass3(value, fracx, fracy, fracz, ref_store, ref_out) MACRO_BEGIN \
  91 { \
  92         lowpass(value.x, fracx, ref_store.x, ref_out.x); \
  93         lowpass(value.y, fracy, ref_store.y, ref_out.y); \
  94         lowpass(value.z, fracz, ref_store.z, ref_out.z); \
  95 } MACRO_END
  96
  97 #define highpass3(value, fracx, fracy, fracz, ref_store, ref_out) MACRO_BEGIN \
  98 { \
  99         highpass(value.x, fracx, ref_store.x, ref_out.x); \
 100         highpass(value.y, fracy, ref_store.y, ref_out.y); \
 101         highpass(value.z, fracz, ref_store.z, ref_out.z); \
 102 } MACRO_END
 103
 104 #define highpass3_limited(value, fracx, limitx, fracy, limity, fracz, limitz, ref_store, ref_out) MACRO_BEGIN \
 105 { \
 106         highpass_limited(value.x, fracx, limitx, ref_store.x, ref_out.x); \
 107         highpass_limited(value.y, fracy, limity, ref_store.y, ref_out.y); \
 108         highpass_limited(value.z, fracz, limitz, ref_store.z, ref_out.z); \
 109 } MACRO_END
 110
 111 void viewmodel_animate(entity this)
 112 {
 113         static float prevtime;
 114         float frametime = (time - prevtime) * STAT(MOVEVARS_TIMESCALE);
 115         prevtime = time;
 116
 117         if (autocvar_chase_active) return;
 118         if (STAT(HEALTH) <= 0) return;
 119
 120         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 121
 122         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 123         static bool oldonground;
 124         static float hitgroundtime;
 125         static float lastongroundtime;
 126         if (clonground)
 127         {
 128                 float f = time; // cl.movecmd[0].time
 129                 if (!oldonground)
 130                         hitgroundtime = f;
 131                 lastongroundtime = f;
 132         }
 133         oldonground = clonground;
 134
 135         vector gunorg = '0 0 0', gunangles = '0 0 0';
 136         static vector gunorg_prev = '0 0 0', gunangles_prev = '0 0 0';
 137
 138         bool teleported = view.csqcmodel_teleported;
 139
 140         // 1. if we teleported, clear the frametime... the lowpass will recover the previous value then
 141         if (teleported)
 142         {
 143                 // try to fix the first highpass; result is NOT
 144                 // perfect! TODO find a better fix
 145                 gunangles_prev = view_angles;
 146                 gunorg_prev = view_origin;
 147         }
 148
 149         static vector gunorg_highpass = '0 0 0';
 150
 151         // 2. for the gun origin, only keep the high frequency (non-DC) parts, which is "somewhat like velocity"
 152         gunorg_highpass += gunorg_prev;
 153         highpass3_limited(view_origin,
 154                 frametime * autocvar_cl_followmodel_side_highpass1, autocvar_cl_followmodel_side_limit,
 155                 frametime * autocvar_cl_followmodel_side_highpass1, autocvar_cl_followmodel_side_limit,
 156                 frametime * autocvar_cl_followmodel_up_highpass1, autocvar_cl_followmodel_up_limit,
 157                 gunorg_highpass, gunorg);
 158         gunorg_prev = view_origin;
 159         gunorg_highpass -= gunorg_prev;
 160
 161         static vector gunangles_highpass = '0 0 0';
 162
 163         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 164         gunangles_highpass += gunangles_prev;
 165         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 166         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 167         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 168         highpass3_limited(view_angles,
 169                 frametime * autocvar_cl_leanmodel_up_highpass1, autocvar_cl_leanmodel_up_limit,
 170                 frametime * autocvar_cl_leanmodel_side_highpass1, autocvar_cl_leanmodel_side_limit,
 171                 0, 0,
 172                 gunangles_highpass, gunangles);
 173         gunangles_prev = view_angles;
 174         gunangles_highpass -= gunangles_prev;
 175
 176         // 3. calculate the RAW adjustment vectors
 177         gunorg.x *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_side_speed : 0);
 178         gunorg.y *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_side_speed : 0);
 179         gunorg.z *= (autocvar_cl_followmodel ? -autocvar_cl_followmodel_up_speed : 0);
 180
 181         PITCH(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_up_speed : 0);
 182         YAW(gunangles) *= (autocvar_cl_leanmodel ? -autocvar_cl_leanmodel_side_speed : 0);
 183         ROLL(gunangles) = 0;
 184
 185         static vector gunorg_adjustment_highpass;
 186         static vector gunorg_adjustment_lowpass;
 187         static vector gunangles_adjustment_highpass;
 188         static vector gunangles_adjustment_lowpass;
 189
 190         // 4. perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 191         //    trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 192         highpass3(gunorg,
 193                 frametime * autocvar_cl_followmodel_side_highpass,
 194                 frametime * autocvar_cl_followmodel_side_highpass,
 195                 frametime * autocvar_cl_followmodel_up_highpass,
 196                 gunorg_adjustment_highpass, gunorg);
 197         lowpass3(gunorg,
 198                 frametime * autocvar_cl_followmodel_side_lowpass,
 199                 frametime * autocvar_cl_followmodel_side_lowpass,
 200                 frametime * autocvar_cl_followmodel_up_lowpass,
 201                 gunorg_adjustment_lowpass, gunorg);
 202         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 203         highpass3(gunangles,
 204                 frametime * autocvar_cl_leanmodel_up_highpass,
 205                 frametime * autocvar_cl_leanmodel_side_highpass,
 206                 0,
 207                 gunangles_adjustment_highpass, gunangles);
 208         lowpass3(gunangles,
 209                 frametime * autocvar_cl_leanmodel_up_lowpass,
 210                 frametime * autocvar_cl_leanmodel_side_lowpass,
 211                 0,
 212                 gunangles_adjustment_lowpass, gunangles);
 213         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 214
 215         // vertical view bobbing code
 216         // TODO: cl_bob
 217
 218         // horizontal view bobbing code
 219         // TODO: cl_bob2
 220
 221         // fall bobbing code
 222         // causes the view to swing down and back up when touching the ground
 223         // TODO: cl_bobfall
 224
 225         // gun model bobbing code
 226         if (autocvar_cl_bobmodel)
 227         {
 228                 // calculate for swinging gun model
 229                 // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 230                 // Sajt: I tried to smooth out the transitions between bob and no bob, which works
 231                 // for the most part, but for some reason when you go through a message trigger or
 232                 // pick up an item or anything like that it will momentarily jolt the gun.
 233                 vector forward, right = '0 0 0', up = '0 0 0';
 234                 float bspeed;
 235                 float t = 1;
 236                 float s = time * autocvar_cl_bobmodel_speed;
 237                 if (clonground)
 238                 {
 239                         if (time - hitgroundtime < 0.2)
 240                         {
 241                                 // just hit the ground, speed the bob back up over the next 0.2 seconds
 242                                 t = time - hitgroundtime;
 243                                 t = bound(0, t, 0.2);
 244                                 t *= 5;
 245                         }
 246                 }
 247                 else
 248                 {
 249                         // recently left the ground, slow the bob down over the next 0.2 seconds
 250                         t = time - lastongroundtime;
 251                         t = 0.2 - bound(0, t, 0.2);
 252                         t *= 5;
 253                 }
 254                 bspeed = xyspeed * 0.01;
 255                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 256                 float bobr = bspeed * autocvar_cl_bobmodel_side * autocvar_cl_viewmodel_scale * sin(s) * t;
 257                 gunorg += bobr * right;
 258                 float bobu = bspeed * autocvar_cl_bobmodel_up * autocvar_cl_viewmodel_scale * cos(s * 2) * t;
 259                 gunorg += bobu * up;
 260         }
 261         vector v = rotate(gunorg, YAW(view_angles) * DEG2RAD); // rotate world coordinates to relative ones
 262         v.z = gunorg.z;
 263         this.origin += v;
 264         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 265         this.angles += gunangles;
 266 }
 267
 268 .vector viewmodel_origin, viewmodel_angles;
 269 .float weapon_nextthink;
 270 .float weapon_eta_last;
 271 .float weapon_switchdelay;
 272
 273 void viewmodel_draw(entity this)
 274 {
 275         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 276         float a = this.alpha;
 277         static bool wasinvehicle;
 278         bool invehicle = player_localentnum > maxclients;
 279         if (invehicle) a = -1;
 280         else if (wasinvehicle) a = 1;
 281         wasinvehicle = invehicle;
 282         int c = stof(getplayerkeyvalue(current_player, "colors"));
 283         vector g;
 284         Weapon wep = activeweapon;
 285         if (!(g = wep.wr_glow(wep))) g = colormapPaletteColor(c & 0x0F, true) * 2;
 286         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 287         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 288                 | EF_NODEPTHTEST)
 289                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 290         for (entity e = this; e; e = e.weaponchild)
 291         {
 292                 e.drawmask = mask;
 293                 e.alpha = a;
 294                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 295                 e.glowmod = g;
 296                 e.csqcmodel_effects = fx;
 297                 WITH(entity, self, e, CSQCModel_Effects_Apply());
 298         }
 299         {
 300                 static string name_last;
 301                 string name = wep.mdl;
 302                 if (name != name_last)
 303                 {
 304                         name_last = name;
 305                         CL_WeaponEntity_SetModel(this, name);
 306                         this.viewmodel_origin = this.origin;
 307                         this.viewmodel_angles = this.angles;
 308                 }
 309                 anim_update(this);
 310                 if (!this.animstate_override)
 311                         anim_set(this, this.anim_idle, true, false, false);
 312         }
 313         float f = 0; // 0..1; 0: fully active
 314         float eta = (this.weapon_nextthink - time) / STAT(WEAPONRATEFACTOR);
 315         if (eta <= 0) f = this.weapon_eta_last;
 316         else switch (this.state)
 317         {
 318                 case WS_RAISE:
 319                 {
 320                         f = eta / max(eta, this.weapon_switchdelay);
 321                         break;
 322                 }
 323                 case WS_DROP:
 324                 {
 325                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 326                         break;
 327                 }
 328                 case WS_CLEAR:
 329                 {
 330                         f = 1;
 331                         break;
 332                 }
 333         }
 334         this.weapon_eta_last = f;
 335         this.origin = this.viewmodel_origin;
 336         this.angles = this.viewmodel_angles;
 337         this.angles_x = (-90 * f * f);
 338         viewmodel_animate(this);
 339         setorigin(this, this.origin);
 340 }
 341
 342 entity viewmodel;
 343 STATIC_INIT(viewmodel) {
 344     viewmodel = new(viewmodel);
 345     make_pure(viewmodel);
 346         viewmodel.draw = viewmodel_draw;
 347 }
 348
 349 entity porto;
 350 vector polyline[16];
 351 void Porto_Draw(entity this)
 352 {
 353         vector p, dir, ang, q, nextdir;
 354         float portal_number, portal1_idx;
 355
 356         if(activeweapon != WEP_PORTO || spectatee_status || gametype == MAPINFO_TYPE_NEXBALL)
 357                 return;
 358         if(WEP_CVAR(porto, secondary))
 359                 return;
 360         if(intermission == 1)
 361                 return;
 362         if(intermission == 2)
 363                 return;
 364         if (STAT(HEALTH) <= 0)
 365                 return;
 366
 367         dir = view_forward;
 368
 369         if(angles_held_status)
 370         {
 371                 makevectors(angles_held);
 372                 dir = v_forward;
 373         }
 374
 375         p = view_origin;
 376
 377         polyline[0] = p;
 378         int idx = 1;
 379         portal_number = 0;
 380         nextdir = dir;
 381
 382         for (;;)
 383         {
 384                 dir = nextdir;
 385                 traceline(p, p + 65536 * dir, true, porto);
 386                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 387                         return;
 388                 nextdir = dir - 2 * (dir * trace_plane_normal) * trace_plane_normal; // mirror dir at trace_plane_normal
 389                 p = trace_endpos;
 390                 polyline[idx] = p;
 391                 ++idx;
 392                 if(idx >= 16)
 393                         return;
 394                 if(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 395                         continue;
 396                 ++portal_number;
 397                 ang = vectoangles2(trace_plane_normal, dir);
 398                 ang.x = -ang.x;
 399                 makevectors(ang);
 400                 if(!CheckWireframeBox(porto, p - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 401                         return;
 402                 if(portal_number == 1)
 403                 {
 404                         portal1_idx = idx;
 405                         if(portal_number >= 2)
 406                                 break;
 407                 }
 408         }
 409
 410         while(idx >= 2)
 411         {
 412                 p = polyline[idx-2];
 413                 q = polyline[idx-1];
 414                 if(idx == 2)
 415                         p = p - view_up * 16;
 416                 if(idx-1 >= portal1_idx)
 417                 {
 418                         Draw_CylindricLine(p, q, 4, "", 1, 0, '0 0 1', 0.5, DRAWFLAG_NORMAL, view_origin);
 419                 }
 420                 else
 421                 {
 422                         Draw_CylindricLine(p, q, 4, "", 1, 0, '1 0 0', 0.5, DRAWFLAG_NORMAL, view_origin);
 423                 }
 424                 --idx;
 425         }
 426 }
 427
 428 void Porto_Init()
 429 {
 430         porto = new(porto);
 431         make_pure(porto);
 432         porto.draw = Porto_Draw;
 433         porto.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 434 }
 435
 436 float drawtime;
 437 float avgspeed;
 438 vector GetCurrentFov(float fov)
 439 {
 440         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 441         float velocityzoom, curspeed;
 442         vector v;
 443
 444         zoomsensitivity = autocvar_cl_zoomsensitivity;
 445         zoomfactor = autocvar_cl_zoomfactor;
 446         if(zoomfactor < 1 || zoomfactor > 30)
 447                 zoomfactor = 2.5;
 448         zoomspeed = autocvar_cl_zoomspeed;
 449         if(zoomspeed >= 0)
 450         if(zoomspeed < 0.5 || zoomspeed > 16)
 451                         zoomspeed = 3.5;
 452
 453         zoomdir = button_zoom;
 454         if(hud == HUD_NORMAL)
 455         if(switchweapon == activeweapon)
 456         if((activeweapon == WEP_VORTEX && !WEP_CVAR(vortex, secondary)) || (activeweapon == WEP_RIFLE && !WEP_CVAR(rifle, secondary))) // do NOT use switchweapon here
 457                 zoomdir += button_attack2;
 458         if(spectatee_status > 0 || isdemo())
 459         {
 460                 if(spectatorbutton_zoom)
 461                 {
 462                         if(zoomdir)
 463                                 zoomdir = 0;
 464                         else
 465                                 zoomdir = 1;
 466                 }
 467                 // fteqcc failed twice here already, don't optimize this
 468         }
 469
 470         if(zoomdir) { zoomin_effect = 0; }
 471
 472         if(camera_active)
 473         {
 474                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 475         }
 476         else if(autocvar_cl_spawnzoom && zoomin_effect)
 477         {
 478                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 479
 480                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 481                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 482                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 483         }
 484         else
 485         {
 486                 if(zoomspeed < 0) // instant zoom
 487                 {
 488                         if(zoomdir)
 489                                 current_viewzoom = 1 / zoomfactor;
 490                         else
 491                                 current_viewzoom = 1;
 492                 }
 493                 else
 494                 {
 495                         if(zoomdir)
 496                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 497                         else
 498                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 499                 }
 500         }
 501
 502         if(almost_equals(current_viewzoom, 1))
 503                 current_zoomfraction = 0;
 504         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 505                 current_zoomfraction = 1;
 506         else
 507                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 508
 509         if(zoomsensitivity < 1)
 510                 setsensitivityscale(pow(current_viewzoom, 1 - zoomsensitivity));
 511         else
 512                 setsensitivityscale(1);
 513
 514         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 515         {
 516                 if(intermission) { curspeed = 0; }
 517                 else
 518                 {
 519
 520                         makevectors(view_angles);
 521                         v = pmove_vel;
 522                         if(csqcplayer)
 523                                 v = csqcplayer.velocity;
 524
 525                         switch(autocvar_cl_velocityzoom_type)
 526                         {
 527                                 case 3: curspeed = max(0, v_forward * v); break;
 528                                 case 2: curspeed = (v_forward * v); break;
 529                                 case 1: default: curspeed = vlen(v); break;
 530                         }
 531                 }
 532
 533                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 534                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 535                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 536
 537                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 538         }
 539         else
 540                 velocityzoom = 1;
 541
 542         float frustumx, frustumy, fovx, fovy;
 543         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 544         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 545         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 546         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 547
 548         return '1 0 0' * fovx + '0 1 0' * fovy;
 549 }
 550
 551 vector GetViewLocationFOV(float fov)
 552 {
 553         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 554         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 555         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 556         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 557         return '1 0 0' * fovx + '0 1 0' * fovy;
 558 }
 559
 560 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 561 {
 562         float fovx, fovy;
 563         float width = (ov_worldmax.x - ov_worldmin.x);
 564         float height = (ov_worldmax.y - ov_worldmin.y);
 565         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 566         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 567         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 568         return '1 0 0' * fovx + '0 1 0' * fovy;
 569 }
 570
 571 // this function must match W_SetupShot!
 572 float zoomscript_caught;
 573
 574 vector wcross_origin;
 575 float wcross_scale_prev, wcross_alpha_prev;
 576 vector wcross_color_prev;
 577 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 578 vector wcross_color_goal_prev;
 579 float wcross_changedonetime;
 580
 581 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 582 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 583 float wcross_name_changestarttime, wcross_name_changedonetime;
 584 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 585
 586 float wcross_ring_prev;
 587
 588 entity trueaim;
 589 entity trueaim_rifle;
 590
 591 const float SHOTTYPE_HITTEAM = 1;
 592 const float SHOTTYPE_HITOBSTRUCTION = 2;
 593 const float SHOTTYPE_HITWORLD = 3;
 594 const float SHOTTYPE_HITENEMY = 4;
 595
 596 void TrueAim_Init()
 597 {
 598         trueaim = new(trueaim);
 599         make_pure(trueaim);
 600         trueaim.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 601         trueaim_rifle = new(trueaim_rifle);
 602         make_pure(trueaim_rifle);
 603         trueaim_rifle.dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 604 }
 605
 606 float EnemyHitCheck()
 607 {
 608         float t, n;
 609         wcross_origin = project_3d_to_2d(trace_endpos);
 610         wcross_origin.z = 0;
 611         if(trace_ent)
 612                 n = trace_ent.entnum;
 613         else
 614                 n = trace_networkentity;
 615         if(n < 1)
 616                 return SHOTTYPE_HITWORLD;
 617         if(n > maxclients)
 618                 return SHOTTYPE_HITWORLD;
 619         t = entcs_GetTeam(n - 1);
 620         if(teamplay)
 621                 if(t == myteam)
 622                         return SHOTTYPE_HITTEAM;
 623         if(t == NUM_SPECTATOR)
 624                 return SHOTTYPE_HITWORLD;
 625         return SHOTTYPE_HITENEMY;
 626 }
 627
 628 float TrueAimCheck()
 629 {
 630         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 631         vector vecs, trueaimpoint, w_shotorg;
 632         vector mi, ma, dv;
 633         float shottype;
 634         entity ta;
 635         float mv;
 636
 637         mi = ma = '0 0 0';
 638         ta = trueaim;
 639         mv = MOVE_NOMONSTERS;
 640
 641         switch(activeweapon) // WEAPONTODO
 642         {
 643                 case WEP_TUBA: // no aim
 644                 case WEP_PORTO: // shoots from eye
 645                 case WEP_NEXBALL: // shoots from eye
 646                 case WEP_HOOK: // no trueaim
 647                 case WEP_MORTAR: // toss curve
 648                         return SHOTTYPE_HITWORLD;
 649                 case WEP_VORTEX:
 650                 case WEP_VAPORIZER:
 651                         mv = MOVE_NORMAL;
 652                         break;
 653                 case WEP_RIFLE:
 654                         ta = trueaim_rifle;
 655                         mv = MOVE_NORMAL;
 656                         if(zoomscript_caught)
 657                         {
 658                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 659                                 return EnemyHitCheck();
 660                         }
 661                         break;
 662                 case WEP_DEVASTATOR: // projectile has a size!
 663                         mi = '-3 -3 -3';
 664                         ma = '3 3 3';
 665                         break;
 666                 case WEP_FIREBALL: // projectile has a size!
 667                         mi = '-16 -16 -16';
 668                         ma = '16 16 16';
 669                         break;
 670                 case WEP_SEEKER: // projectile has a size!
 671                         mi = '-2 -2 -2';
 672                         ma = '2 2 2';
 673                         break;
 674                 case WEP_ELECTRO: // projectile has a size!
 675                         mi = '0 0 -3';
 676                         ma = '0 0 -3';
 677                         break;
 678         }
 679
 680         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 681
 682         vecs = decompressShotOrigin(STAT(SHOTORG));
 683
 684         traceline(traceorigin, traceorigin + view_forward * MAX_SHOT_DISTANCE, mv, ta);
 685         trueaimpoint = trace_endpos;
 686
 687         if(vlen(trueaimpoint - traceorigin) < g_trueaim_minrange)
 688                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 689
 690         if(vecs.x > 0)
 691                 vecs.y = -vecs.y;
 692         else
 693                 vecs = '0 0 0';
 694
 695         dv = view_right * vecs.y + view_up * vecs.z;
 696         w_shotorg = traceorigin + dv;
 697
 698         // now move the vecs forward as much as requested if possible
 699         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 700         w_shotorg = trace_endpos - view_forward * nudge;
 701
 702         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 703         shottype = EnemyHitCheck();
 704         if(shottype != SHOTTYPE_HITWORLD)
 705                 return shottype;
 706
 707 #if 0
 708         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 709         // or rather, I know why, but see no fix
 710         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 711                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 712                 return SHOTTYPE_HITOBSTRUCTION;
 713 #endif
 714
 715         return SHOTTYPE_HITWORLD;
 716 }
 717
 718 void PostInit();
 719 void CSQC_Demo_Camera();
 720 float HUD_WouldDrawScoreboard();
 721 float camera_mode;
 722 const float CAMERA_FREE = 1;
 723 const float CAMERA_CHASE = 2;
 724 float reticle_type;
 725 string reticle_image;
 726 string NextFrameCommand;
 727
 728 vector freeze_org, freeze_ang;
 729 entity nightvision_noise, nightvision_noise2;
 730
 731 const float MAX_TIME_DIFF = 5;
 732 float pickup_crosshair_time, pickup_crosshair_size;
 733 float hitindication_crosshair_size;
 734 float use_vortex_chargepool;
 735
 736 float myhealth, myhealth_prev;
 737 float myhealth_flash;
 738
 739 float old_blurradius, old_bluralpha;
 740 float old_sharpen_intensity;
 741
 742 vector myhealth_gentlergb;
 743
 744 float contentavgalpha, liquidalpha_prev;
 745 vector liquidcolor_prev;
 746
 747 float eventchase_current_distance;
 748 float eventchase_running;
 749 bool WantEventchase()
 750 {SELFPARAM();
 751         if(autocvar_cl_orthoview)
 752                 return false;
 753         if(intermission)
 754                 return true;
 755         if(self.viewloc)
 756                 return true;
 757         if(spectatee_status >= 0)
 758         {
 759                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 760                         return true;
 761                 if(MUTATOR_CALLHOOK(WantEventchase, self))
 762                         return true;
 763                 if(autocvar_cl_eventchase_nexball && gametype == MAPINFO_TYPE_NEXBALL && !(WepSet_GetFromStat() & WEPSET(NEXBALL)))
 764                         return true;
 765                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 766                 {
 767                         if(autocvar_cl_eventchase_death == 2)
 768                         {
 769                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 770                                 if(self.velocity == '0 0 0' || eventchase_running)
 771                                         return true;
 772                         }
 773                         else return true;
 774                 }
 775         }
 776         return false;
 777 }
 778
 779 void HUD_Crosshair_Vehicle()
 780 {
 781         if(hud != HUD_BUMBLEBEE_GUN)
 782         {
 783                 Vehicle info = get_vehicleinfo(hud);
 784                 info.vr_crosshair(info);
 785         }
 786 }
 787
 788 vector damage_blurpostprocess, content_blurpostprocess;
 789
 790 float unaccounted_damage = 0;
 791 void UpdateDamage()
 792 {
 793         // accumulate damage with each stat update
 794         static float damage_total_prev = 0;
 795         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 796         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 797         damage_total_prev = damage_total;
 798
 799         static float damage_dealt_time_prev = 0;
 800         float damage_dealt_time = STAT(HIT_TIME);
 801         if (damage_dealt_time != damage_dealt_time_prev)
 802         {
 803                 unaccounted_damage += unaccounted_damage_new;
 804                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")", "\n");
 805         }
 806         damage_dealt_time_prev = damage_dealt_time;
 807
 808         // prevent hitsound when switching spectatee
 809         static float spectatee_status_prev = 0;
 810         if (spectatee_status != spectatee_status_prev)
 811                 unaccounted_damage = 0;
 812         spectatee_status_prev = spectatee_status;
 813 }
 814
 815 void HitSound()
 816 {
 817         // varying sound pitch
 818
 819         static float hitsound_time_prev = 0;
 820         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 821         float arc_hack = activeweapon == WEP_ARC && autocvar_cl_hitsound >= 2;
 822         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 823         {
 824                 if (autocvar_cl_hitsound && unaccounted_damage)
 825                 {
 826                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 827                         float a = autocvar_cl_hitsound_max_pitch;
 828                         float b = autocvar_cl_hitsound_min_pitch;
 829                         float c = autocvar_cl_hitsound_nom_damage;
 830                         float x = unaccounted_damage;
 831                         float pitch_shift = (b*x*(a-1) + a*c*(1-b)) / (x*(a-1) + c*(1-b));
 832
 833                         // if sound variation is disabled, set pitch_shift to 1
 834                         if (autocvar_cl_hitsound == 1)
 835                                 pitch_shift = 1;
 836
 837                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 838                         if (autocvar_cl_hitsound == 3)
 839                         {
 840                                 float mirror_value = (a-b)/2 + b;
 841                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 842                         }
 843
 844                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift), "\n");
 845
 846                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 847                         // todo: normalize sound pressure levels? seems unnecessary
 848
 849                         sound7(world, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 850                 }
 851                 unaccounted_damage = 0;
 852                 hitsound_time_prev = time;
 853         }
 854
 855         static float typehit_time_prev = 0;
 856         float typehit_time = STAT(TYPEHIT_TIME);
 857         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 858         {
 859                 sound(world, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 860                 typehit_time_prev = typehit_time;
 861         }
 862 }
 863
 864 void HUD_Crosshair()
 865 {SELFPARAM();
 866         static float rainbow_last_flicker;
 867         static vector rainbow_prev_color;
 868         entity e = self;
 869         float f, i, j;
 870         vector v;
 871         if(!scoreboard_active && !camera_active && intermission != 2 &&
 872                 spectatee_status != -1 && !csqcplayer.viewloc &&
 873                 !HUD_MinigameMenu_IsOpened() )
 874         {
 875                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
 876                         return;
 877
 878                 if (hud != HUD_NORMAL)
 879                 {
 880                         HUD_Crosshair_Vehicle();
 881                         return;
 882                 }
 883
 884                 string wcross_style;
 885                 float wcross_alpha, wcross_resolution;
 886                 wcross_style = autocvar_crosshair;
 887                 if (wcross_style == "0")
 888                         return;
 889                 wcross_resolution = autocvar_crosshair_size;
 890                 if (wcross_resolution == 0)
 891                         return;
 892                 wcross_alpha = autocvar_crosshair_alpha;
 893                 if (wcross_alpha == 0)
 894                         return;
 895
 896                 // TrueAim check
 897                 float shottype;
 898
 899                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
 900                 wcross_origin = project_3d_to_2d(view_origin + MAX_SHOT_DISTANCE * view_forward);
 901                 wcross_origin.z = 0;
 902                 if(autocvar_crosshair_hittest)
 903                 {
 904                         vector wcross_oldorigin;
 905                         wcross_oldorigin = wcross_origin;
 906                         shottype = TrueAimCheck();
 907                         if(shottype == SHOTTYPE_HITWORLD)
 908                         {
 909                                 v = wcross_origin - wcross_oldorigin;
 910                                 v.x /= vid_conwidth;
 911                                 v.y /= vid_conheight;
 912                                 if(vlen(v) > 0.01)
 913                                         shottype = SHOTTYPE_HITOBSTRUCTION;
 914                         }
 915                         if(!autocvar_crosshair_hittest_showimpact)
 916                                 wcross_origin = wcross_oldorigin;
 917                 }
 918                 else
 919                         shottype = SHOTTYPE_HITWORLD;
 920
 921                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
 922                 string wcross_name = "";
 923                 float wcross_scale, wcross_blur;
 924
 925                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
 926                 {
 927                         e = switchingweapon;
 928                         if(e)
 929                         {
 930                                 if(autocvar_crosshair_per_weapon)
 931                                 {
 932                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
 933                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
 934                                         //if (wcross_resolution == 0)
 935                                                 //return;
 936
 937                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
 938                                         wcross_resolution *= e.w_crosshair_size;
 939                                         wcross_name = e.w_crosshair;
 940                                 }
 941                         }
 942                 }
 943
 944                 if(wcross_name == "")
 945                         wcross_name = strcat("gfx/crosshair", wcross_style);
 946
 947                 // MAIN CROSSHAIR COLOR DECISION
 948                 switch(autocvar_crosshair_color_special)
 949                 {
 950                         case 1: // crosshair_color_per_weapon
 951                         {
 952                                 if(e)
 953                                 {
 954                                         wcross_color = e.wpcolor;
 955                                         break;
 956                                 }
 957                                 else { goto normalcolor; }
 958                         }
 959
 960                         case 2: // crosshair_color_by_health
 961                         {
 962                                 float x = STAT(HEALTH);
 963
 964                                 //x = red
 965                                 //y = green
 966                                 //z = blue
 967
 968                                 wcross_color.z = 0;
 969
 970                                 if(x > 200)
 971                                 {
 972                                         wcross_color.x = 0;
 973                                         wcross_color.y = 1;
 974                                 }
 975                                 else if(x > 150)
 976                                 {
 977                                         wcross_color.x = 0.4 - (x-150)*0.02 * 0.4;
 978                                         wcross_color.y = 0.9 + (x-150)*0.02 * 0.1;
 979                                 }
 980                                 else if(x > 100)
 981                                 {
 982                                         wcross_color.x = 1 - (x-100)*0.02 * 0.6;
 983                                         wcross_color.y = 1 - (x-100)*0.02 * 0.1;
 984                                         wcross_color.z = 1 - (x-100)*0.02;
 985                                 }
 986                                 else if(x > 50)
 987                                 {
 988                                         wcross_color.x = 1;
 989                                         wcross_color.y = 1;
 990                                         wcross_color.z = 0.2 + (x-50)*0.02 * 0.8;
 991                                 }
 992                                 else if(x > 20)
 993                                 {
 994                                         wcross_color.x = 1;
 995                                         wcross_color.y = (x-20)*90/27/100;
 996                                         wcross_color.z = (x-20)*90/27/100 * 0.2;
 997                                 }
 998                                 else
 999                                 {
1000                                         wcross_color.x = 1;
1001                                         wcross_color.y = 0;
1002                                 }
1003                                 break;
1004                         }
1005
1006                         case 3: // crosshair_color_rainbow
1007                         {
1008                                 if(time >= rainbow_last_flicker)
1009                                 {
1010                                         rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1011                                         rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1012                                 }
1013                                 wcross_color = rainbow_prev_color;
1014                                 break;
1015                         }
1016                         :normalcolor
1017                         default: { wcross_color = stov(autocvar_crosshair_color); break; }
1018                 }
1019
1020                 if(autocvar_crosshair_effect_scalefade)
1021                 {
1022                         wcross_scale = wcross_resolution;
1023                         wcross_resolution = 1;
1024                 }
1025                 else
1026                 {
1027                         wcross_scale = 1;
1028                 }
1029
1030                 if(autocvar_crosshair_pickup)
1031                 {
1032                         float stat_pickup_time = STAT(LAST_PICKUP);
1033
1034                         if(pickup_crosshair_time < stat_pickup_time)
1035                         {
1036                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1037                                         pickup_crosshair_size = 1;
1038
1039                                 pickup_crosshair_time = stat_pickup_time;
1040                         }
1041
1042                         if(pickup_crosshair_size > 0)
1043                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1044                         else
1045                                 pickup_crosshair_size = 0;
1046
1047                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1048                 }
1049
1050                 // todo: make crosshair hit indication dependent on damage dealt
1051                 if(autocvar_crosshair_hitindication)
1052                 {
1053                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1054
1055                         if(unaccounted_damage)
1056                         {
1057                                 hitindication_crosshair_size = 1;
1058                         }
1059
1060                         if(hitindication_crosshair_size > 0)
1061                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1062                         else
1063                                 hitindication_crosshair_size = 0;
1064
1065                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1066                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1067                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1068                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1069                 }
1070
1071                 if(shottype == SHOTTYPE_HITENEMY)
1072                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1073                 if(shottype == SHOTTYPE_HITTEAM)
1074                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1075
1076                 f = fabs(autocvar_crosshair_effect_time);
1077                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1078                 {
1079                         wcross_changedonetime = time + f;
1080                 }
1081                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1082                 {
1083                         wcross_name_changestarttime = time;
1084                         wcross_name_changedonetime = time + f;
1085                         if(wcross_name_goal_prev_prev)
1086                                 strunzone(wcross_name_goal_prev_prev);
1087                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1088                         wcross_name_goal_prev = strzone(wcross_name);
1089                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1090                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1091                         wcross_resolution_goal_prev = wcross_resolution;
1092                 }
1093
1094                 wcross_scale_goal_prev = wcross_scale;
1095                 wcross_alpha_goal_prev = wcross_alpha;
1096                 wcross_color_goal_prev = wcross_color;
1097
1098                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1099                 {
1100                         wcross_blur = 1;
1101                         wcross_alpha *= 0.75;
1102                 }
1103                 else
1104                         wcross_blur = 0;
1105                 // *_prev is at time-frametime
1106                 // * is at wcross_changedonetime+f
1107                 // what do we have at time?
1108                 if(time < wcross_changedonetime)
1109                 {
1110                         f = frametime / (wcross_changedonetime - time + frametime);
1111                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1112                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1113                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1114                 }
1115
1116                 wcross_scale_prev = wcross_scale;
1117                 wcross_alpha_prev = wcross_alpha;
1118                 wcross_color_prev = wcross_color;
1119
1120                 MUTATOR_CALLHOOK(UpdateCrosshair);
1121
1122                 wcross_scale *= 1 - autocvar__menu_alpha;
1123                 wcross_alpha *= 1 - autocvar__menu_alpha;
1124                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1125
1126                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1127                 {
1128                         // crosshair rings for weapon stats
1129                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1130                         {
1131                                 // declarations and stats
1132                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1133                                 string ring_image = string_null, ring_inner_image = string_null;
1134                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1135
1136                                 ring_scale = autocvar_crosshair_ring_size;
1137
1138                                 float weapon_clipload, weapon_clipsize;
1139                                 weapon_clipload = STAT(WEAPON_CLIPLOAD);
1140                                 weapon_clipsize = STAT(WEAPON_CLIPSIZE);
1141
1142                                 float ok_ammo_charge, ok_ammo_chargepool;
1143                                 ok_ammo_charge = STAT(OK_AMMO_CHARGE);
1144                                 ok_ammo_chargepool = STAT(OK_AMMO_CHARGEPOOL);
1145
1146                                 float vortex_charge, vortex_chargepool;
1147                                 vortex_charge = STAT(VORTEX_CHARGE);
1148                                 vortex_chargepool = STAT(VORTEX_CHARGEPOOL);
1149
1150                                 float arc_heat = STAT(ARC_HEAT);
1151
1152                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1153                                         vortex_charge_movingavg = vortex_charge;
1154
1155
1156                                 // handle the values
1157                                 if (autocvar_crosshair_ring && activeweapon == WEP_VORTEX && vortex_charge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1158                                 {
1159                                         if (vortex_chargepool || use_vortex_chargepool) {
1160                                                 use_vortex_chargepool = 1;
1161                                                 ring_inner_value = vortex_chargepool;
1162                                         } else {
1163                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vortex_charge;
1164                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vortex_charge - vortex_charge_movingavg), 1);
1165                                         }
1166
1167                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1168                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1169                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1170
1171                                         // draw the outer ring to show the current charge of the weapon
1172                                         ring_value = vortex_charge;
1173                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1174                                         ring_rgb = wcross_color;
1175                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1176                                 }
1177                                 else if (autocvar_crosshair_ring && activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1178                                 {
1179                                         ring_value = bound(0, STAT(LAYED_MINES) / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1180                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1181                                         ring_rgb = wcross_color;
1182                                         ring_image = "gfx/crosshair_ring.tga";
1183                                 }
1184                                 else if (activeweapon == WEP_HAGAR && STAT(HAGAR_LOAD) && autocvar_crosshair_ring_hagar)
1185                                 {
1186                                         ring_value = bound(0, STAT(HAGAR_LOAD) / WEP_CVAR_SEC(hagar, load_max), 1);
1187                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1188                                         ring_rgb = wcross_color;
1189                                         ring_image = "gfx/crosshair_ring.tga";
1190                                 }
1191                                 else if (ok_ammo_charge)
1192                                 {
1193                                         ring_value = ok_ammo_chargepool;
1194                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1195                                         ring_rgb = wcross_color;
1196                                         ring_image = "gfx/crosshair_ring.tga";
1197                                 }
1198                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1199                                 {
1200                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1201                                         ring_scale = autocvar_crosshair_ring_reload_size;
1202                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1203                                         ring_rgb = wcross_color;
1204
1205                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1206                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1207                                         if ((activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1208                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1209                                         else
1210                                                 ring_image = "gfx/crosshair_ring.tga";
1211                                 }
1212                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && activeweapon == WEP_ARC )
1213                                 {
1214                                         ring_value = arc_heat;
1215                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1216                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1217                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1218                                         ring_image = "gfx/crosshair_ring.tga";
1219                                 }
1220
1221                                 // if in weapon switch animation, fade ring out/in
1222                                 if(autocvar_crosshair_effect_time > 0)
1223                                 {
1224                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1225                                         if (f >= 1)
1226                                         {
1227                                                 wcross_ring_prev = ((ring_image) ? true : false);
1228                                         }
1229
1230                                         if(wcross_ring_prev)
1231                                         {
1232                                                 if(f < 1)
1233                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1234                                         }
1235                                         else
1236                                         {
1237                                                 if(f < 1)
1238                                                         ring_alpha *= bound(0, f, 1);
1239                                         }
1240                                 }
1241
1242                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1243                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1244
1245                                 if (ring_value)
1246                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1247                         }
1248
1249 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1250                         MACRO_BEGIN { \
1251                                 if(wcross_blur > 0) \
1252                                 { \
1253                                         for(i = -2; i <= 2; ++i) \
1254                                         for(j = -2; j <= 2; ++j) \
1255                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1256                                 } \
1257                                 else \
1258                                 { \
1259                                         M(0,0,sz,wcross_name,wcross_alpha); \
1260                                 } \
1261                         } MACRO_END
1262
1263 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1264                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1265
1266 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1267                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1268
1269                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1270                         {
1271                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1272                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1273                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1274                                 f = 1 - f;
1275                         }
1276                         else
1277                         {
1278                                 f = 1;
1279                         }
1280                         wcross_name_alpha_goal_prev = f;
1281
1282                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1283                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1284
1285                         if(autocvar_crosshair_dot)
1286                         {
1287                                 vector wcross_color_old;
1288                                 wcross_color_old = wcross_color;
1289
1290                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1291                                         wcross_color = stov(autocvar_crosshair_dot_color);
1292
1293                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1294                                 // FIXME why don't we use wcross_alpha here?
1295                                 wcross_color = wcross_color_old;
1296                         }
1297                 }
1298         }
1299         else
1300         {
1301                 wcross_scale_prev = 0;
1302                 wcross_alpha_prev = 0;
1303                 wcross_scale_goal_prev = 0;
1304                 wcross_alpha_goal_prev = 0;
1305                 wcross_changedonetime = 0;
1306                 if(wcross_name_goal_prev)
1307                         strunzone(wcross_name_goal_prev);
1308                 wcross_name_goal_prev = string_null;
1309                 if(wcross_name_goal_prev_prev)
1310                         strunzone(wcross_name_goal_prev_prev);
1311                 wcross_name_goal_prev_prev = string_null;
1312                 wcross_name_changestarttime = 0;
1313                 wcross_name_changedonetime = 0;
1314                 wcross_name_alpha_goal_prev = 0;
1315                 wcross_name_alpha_goal_prev_prev = 0;
1316                 wcross_resolution_goal_prev = 0;
1317                 wcross_resolution_goal_prev_prev = 0;
1318         }
1319 }
1320
1321 void HUD_Draw()
1322 {
1323         vector rgb = '0 0 0';
1324         float a = 1;
1325         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1326         {
1327                 rgb = MUTATOR_ARGV(0, vector);
1328                 a = MUTATOR_ARGV(0, float);
1329         }
1330         else if(STAT(FROZEN))
1331         {
1332                 rgb = ((STAT(REVIVE_PROGRESS)) ? ('0.25 0.90 1' + ('1 0 0' * STAT(REVIVE_PROGRESS)) + ('0 1 1' * STAT(REVIVE_PROGRESS) * -1)) : '0.25 0.90 1');
1333         }
1334         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, rgb, autocvar_hud_colorflash_alpha * a, DRAWFLAG_ADDITIVE);
1335         if(!intermission)
1336         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1337         {
1338                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), '0.25 0.90 1' + ('1 0 0' * STAT(NADE_TIMER)) - ('0 1 1' * STAT(NADE_TIMER)), autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1339                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1340         }
1341         else if(STAT(REVIVE_PROGRESS))
1342         {
1343                 DrawCircleClippedPic(eX * 0.5 * vid_conwidth + eY * 0.6 * vid_conheight, 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1344                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), eX * vid_conwidth + eY * 0.025 * vid_conheight, '1 1 1', 1, DRAWFLAG_NORMAL);
1345         }
1346
1347         if(autocvar_r_letterbox == 0)
1348                 if(autocvar_viewsize < 120)
1349                 {
1350                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1351                                 Accuracy_LoadLevels();
1352
1353                         HUD_Main();
1354                         HUD_DrawScoreboard();
1355                 }
1356
1357         // crosshair goes VERY LAST
1358         UpdateDamage();
1359         HUD_Crosshair();
1360         HitSound();
1361 }
1362
1363 bool ov_enabled;
1364 float oldr_nearclip;
1365 float oldr_farclip_base;
1366 float oldr_farclip_world;
1367 float oldr_novis;
1368 float oldr_useportalculling;
1369 float oldr_useinfinitefarclip;
1370
1371 void cl_notice_run();
1372 float prev_myteam;
1373 int lasthud;
1374 float vh_notice_time;
1375 void WaypointSprite_Load();
1376 void CSQC_UpdateView(float w, float h)
1377 {SELFPARAM();
1378         entity e;
1379         float fov;
1380         float f;
1381         vector vf_size, vf_min;
1382         float a;
1383
1384         execute_next_frame();
1385
1386         ++framecount;
1387
1388         stats_get();
1389         hud = STAT(HUD);
1390
1391         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1392                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1393
1394         lasthud = hud;
1395
1396         if(autocvar__hud_showbinds_reload) // menu can set this one
1397         {
1398                 db_close(binddb);
1399                 binddb = db_create();
1400                 cvar_set("_hud_showbinds_reload", "0");
1401         }
1402
1403         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1404                 view_quality = getproperty(VF_MINFPS_QUALITY);
1405         else
1406                 view_quality = 1;
1407
1408         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(self);
1409         button_zoom = PHYS_INPUT_BUTTON_ZOOM(self);
1410
1411         vf_size = getpropertyvec(VF_SIZE);
1412         vf_min = getpropertyvec(VF_MIN);
1413         vid_width = vf_size.x;
1414         vid_height = vf_size.y;
1415
1416         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1417         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1418
1419         WaypointSprite_Load();
1420
1421         CSQCPlayer_SetCamera();
1422
1423         if(player_localentnum <= maxclients) // is it a client?
1424                 current_player = player_localentnum - 1;
1425         else // then player_localentnum is the vehicle I'm driving
1426                 current_player = player_localnum;
1427         myteam = entcs_GetTeam(current_player);
1428
1429         if(myteam != prev_myteam)
1430         {
1431                 myteamcolors = colormapPaletteColor(myteam, 1);
1432                 FOREACH(hud_panels, true, LAMBDA(it.update_time = time));
1433                 prev_myteam = myteam;
1434         }
1435
1436         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1437
1438         float is_dead = (STAT(HEALTH) <= 0);
1439
1440         // FIXME do we need this hack?
1441         if(isdemo())
1442         {
1443                 // in demos, input_buttons do not work
1444                 button_zoom = (autocvar__togglezoom == "-");
1445         }
1446         else if(button_zoom
1447                 && autocvar_cl_unpress_zoom_on_death
1448                 && (spectatee_status >= 0)
1449                 && (is_dead || intermission))
1450         {
1451                 // no zoom while dead or in intermission please
1452                 localcmd("-zoom\n");
1453                 button_zoom = false;
1454         }
1455
1456         // event chase camera
1457         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1458         {
1459                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1460                 float ons_roundlost = (gametype == MAPINFO_TYPE_ONSLAUGHT && STAT(ROUNDLOST));
1461                 entity gen = world;
1462
1463                 if(ons_roundlost)
1464                 {
1465                         entity e;
1466                         for(e = world; (e = find(e, classname, "onslaught_generator")); )
1467                         {
1468                                 if(e.health <= 0)
1469                                 {
1470                                         gen = e;
1471                                         break;
1472                                 }
1473                         }
1474                         if(!gen)
1475                                 ons_roundlost = FALSE; // don't enforce the 3rd person camera if there is no dead generator to show
1476                 }
1477                 if(WantEventchase() || (!autocvar_cl_orthoview && ons_roundlost))
1478                 {
1479                         eventchase_running = true;
1480
1481                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1482                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1483                         if(ons_roundlost) { current_view_origin = gen.origin; }
1484
1485                         // detect maximum viewoffset and use it
1486                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1487                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_viewoffset) { view_offset = autocvar_cl_eventchase_vehicle_viewoffset; }
1488                         if(ons_roundlost) { view_offset = autocvar_cl_eventchase_generator_viewoffset; }
1489
1490                         if(view_offset)
1491                         {
1492                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, self);
1493                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1494                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1495                         }
1496
1497                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1498                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1499                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1500                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1501
1502                         // make the camera smooth back
1503                         float chase_distance = autocvar_cl_eventchase_distance;
1504                         if(vehicle_chase && autocvar_cl_eventchase_vehicle_distance) { chase_distance = autocvar_cl_eventchase_vehicle_distance; }
1505                         if(ons_roundlost) { chase_distance = autocvar_cl_eventchase_generator_distance; }
1506
1507                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1508                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1509                         else if(eventchase_current_distance != chase_distance)
1510                                 eventchase_current_distance = chase_distance;
1511
1512                         makevectors(view_angles);
1513
1514                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1515                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, self);
1516
1517                         // If the boxtrace fails, revert back to line tracing.
1518                         if(!self.viewloc)
1519                         if(trace_startsolid)
1520                         {
1521                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1522                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, self);
1523                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1524                         }
1525                         else { setproperty(VF_ORIGIN, trace_endpos); }
1526
1527                         if(!self.viewloc)
1528                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1529                 }
1530                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1531                 {
1532                         eventchase_running = false;
1533                         cvar_set("chase_active", "0");
1534                         eventchase_current_distance = 0; // start from 0 next time
1535                 }
1536         }
1537         // workaround for camera stuck between player's legs when using chase_active 1
1538         // because the engine stops updating the chase_active camera when the game ends
1539         else if(intermission)
1540         {
1541                 cvar_settemp("chase_active", "-1");
1542                 eventchase_current_distance = 0;
1543         }
1544
1545         // do lockview after event chase camera so that it still applies whenever necessary.
1546         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1547         {
1548                 setproperty(VF_ORIGIN, freeze_org);
1549                 setproperty(VF_ANGLES, freeze_ang);
1550         }
1551         else
1552         {
1553                 freeze_org = getpropertyvec(VF_ORIGIN);
1554                 freeze_ang = getpropertyvec(VF_ANGLES);
1555         }
1556
1557         WarpZone_FixView();
1558         //WarpZone_FixPMove();
1559
1560         vector ov_org = '0 0 0';
1561         vector ov_mid = '0 0 0';
1562         vector ov_worldmin = '0 0 0';
1563         vector ov_worldmax = '0 0 0';
1564         if(autocvar_cl_orthoview)
1565         {
1566                 ov_worldmin = mi_picmin;
1567                 ov_worldmax = mi_picmax;
1568
1569                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1570                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1571                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1572
1573                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1574                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1575
1576                 float ov_nearest = vlen(ov_org - vec3(
1577                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1578                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1579                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1580                 ));
1581
1582                 float ov_furthest = 0;
1583                 float dist = 0;
1584
1585                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1586                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1587                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1588                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1589                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1590                 if((dist = vlen(vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1591                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1592                 if((dist = vlen(vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org)) > ov_furthest) { ov_furthest = dist; }
1593
1594                 if(!ov_enabled)
1595                 {
1596                         oldr_nearclip = cvar("r_nearclip");
1597                         oldr_farclip_base = cvar("r_farclip_base");
1598                         oldr_farclip_world = cvar("r_farclip_world");
1599                         oldr_novis = cvar("r_novis");
1600                         oldr_useportalculling = cvar("r_useportalculling");
1601                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1602                 }
1603
1604                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1605                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1606                 cvar_settemp("r_farclip_world", "0");
1607                 cvar_settemp("r_novis", "1");
1608                 cvar_settemp("r_useportalculling", "0");
1609                 cvar_settemp("r_useinfinitefarclip", "0");
1610
1611                 setproperty(VF_ORIGIN, ov_org);
1612                 setproperty(VF_ANGLES, '90 0 0');
1613
1614                 ov_enabled = true;
1615
1616                 #if 0
1617                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f\n",
1618                         vtos(ov_org),
1619                         vtos(getpropertyvec(VF_ANGLES)),
1620                         ov_distance,
1621                         ov_nearest,
1622                         ov_furthest);
1623                 #endif
1624         }
1625         else
1626         {
1627                 if(ov_enabled)
1628                 {
1629                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1630                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1631                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1632                         cvar_set("r_novis", ftos(oldr_novis));
1633                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1634                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1635                 }
1636                 ov_enabled = false;
1637         }
1638
1639         // Render the Scene
1640         view_origin = getpropertyvec(VF_ORIGIN);
1641         view_angles = getpropertyvec(VF_ANGLES);
1642         makevectors(view_angles);
1643         view_forward = v_forward;
1644         view_right = v_right;
1645         view_up = v_up;
1646
1647 #ifdef BLURTEST
1648         if(time > blurtest_time0 && time < blurtest_time1)
1649         {
1650                 float r, t;
1651
1652                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1653                 r = t * blurtest_radius;
1654                 f = 1 / pow(t, blurtest_power) - 1;
1655
1656                 cvar_set("r_glsl_postprocess", "1");
1657                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1658         }
1659         else
1660         {
1661                 cvar_set("r_glsl_postprocess", "0");
1662                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1663         }
1664 #endif
1665
1666         TargetMusic_Advance();
1667         Fog_Force();
1668
1669         if(drawtime == 0)
1670                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1671         else
1672                 drawframetime = bound(0.000001, time - drawtime, 1);
1673         drawtime = time;
1674
1675         // watch for gametype changes here...
1676         // in ParseStuffCMD the cmd isn't executed yet :/
1677         // might even be better to add the gametype to TE_CSQC_INIT...?
1678         if(!postinit)
1679                 PostInit();
1680
1681         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1682         {
1683                 if(calledhooks & HOOK_START)
1684                 {
1685                         localcmd("\ncl_hook_gameend\n");
1686                         calledhooks |= HOOK_END;
1687                 }
1688         }
1689
1690         Announcer();
1691
1692         fov = autocvar_fov;
1693         if(fov <= 59.5)
1694         {
1695                 if(!zoomscript_caught)
1696                 {
1697                         localcmd("+button9\n");
1698                         zoomscript_caught = 1;
1699                 }
1700         }
1701         else
1702         {
1703                 if(zoomscript_caught)
1704                 {
1705                         localcmd("-button9\n");
1706                         zoomscript_caught = 0;
1707                 }
1708         }
1709
1710         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1711
1712         // currently switching-to weapon (for crosshair)
1713         switchingweapon = Weapons_from(STAT(SWITCHINGWEAPON));
1714
1715         // actually active weapon (for zoom)
1716         activeweapon = Weapons_from(STAT(ACTIVEWEAPON));
1717
1718         switchweapon = Weapons_from(STAT(SWITCHWEAPON));
1719
1720         f = (serverflags & SERVERFLAG_TEAMPLAY);
1721         if(f != teamplay)
1722         {
1723                 teamplay = f;
1724                 HUD_InitScores();
1725         }
1726
1727         if(last_switchweapon != switchweapon)
1728         {
1729                 weapontime = time;
1730                 last_switchweapon = switchweapon;
1731                 if(button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1732                 {
1733                         localcmd("-zoom\n");
1734                         button_zoom = false;
1735                 }
1736                 if(autocvar_cl_unpress_attack_on_weapon_switch)
1737                 {
1738                         localcmd("-fire\n");
1739                         localcmd("-fire2\n");
1740                         button_attack2 = false;
1741                 }
1742         }
1743         if(last_activeweapon != activeweapon)
1744         {
1745                 last_activeweapon = activeweapon;
1746
1747                 e = activeweapon;
1748                 if(e.netname != "")
1749                         localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1750                 else
1751                         localcmd("\ncl_hook_activeweapon none\n");
1752         }
1753
1754         // ALWAYS Clear Current Scene First
1755         clearscene();
1756
1757         setproperty(VF_ORIGIN, view_origin);
1758         setproperty(VF_ANGLES, view_angles);
1759
1760         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
1761         setproperty(VF_SIZE, vf_size);
1762         setproperty(VF_MIN, vf_min);
1763
1764         // Assign Standard Viewflags
1765         // Draw the World (and sky)
1766         setproperty(VF_DRAWWORLD, 1);
1767
1768         // Set the console size vars
1769         vid_conwidth = autocvar_vid_conwidth;
1770         vid_conheight = autocvar_vid_conheight;
1771         vid_pixelheight = autocvar_vid_pixelheight;
1772
1773         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
1774         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
1775         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
1776
1777         // Camera for demo playback
1778         if(camera_active)
1779         {
1780                 if(autocvar_camera_enable)
1781                         CSQC_Demo_Camera();
1782                 else
1783                 {
1784                         cvar_set("chase_active", ftos(chase_active_backup));
1785                         cvar_set("cl_demo_mousegrab", "0");
1786                         camera_active = false;
1787                 }
1788         }
1789         else
1790         {
1791 #ifdef CAMERATEST
1792                 if(autocvar_camera_enable)
1793 #else
1794                 if(autocvar_camera_enable && isdemo())
1795 #endif
1796                 {
1797                         // Enable required Darkplaces cvars
1798                         chase_active_backup = autocvar_chase_active;
1799                         cvar_set("chase_active", "2");
1800                         cvar_set("cl_demo_mousegrab", "1");
1801                         camera_active = true;
1802                         camera_mode = false;
1803                 }
1804         }
1805
1806         // Draw the Crosshair
1807         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
1808
1809         // Draw the Engine Status Bar (the default Quake HUD)
1810         setproperty(VF_DRAWENGINESBAR, 0);
1811
1812         // Update the mouse position
1813         /*
1814            mousepos_x = vid_conwidth;
1815            mousepos_y = vid_conheight;
1816            mousepos = mousepos*0.5 + getmousepos();
1817          */
1818
1819         FOREACH_ENTITY(it.draw, LAMBDA(WITH(entity, self, it, it.draw(it))));
1820
1821         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
1822         renderscene();
1823
1824         // now switch to 2D drawing mode by calling a 2D drawing function
1825         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
1826         // next R_RenderScene call
1827         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
1828
1829         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
1830         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
1831         {
1832                 // apply night vision effect
1833                 vector tc_00, tc_01, tc_10, tc_11;
1834                 vector rgb = '0 0 0';
1835
1836                 if(!nightvision_noise)
1837                 {
1838                         nightvision_noise = new(nightvision_noise);
1839                 }
1840                 if(!nightvision_noise2)
1841                 {
1842                         nightvision_noise2 = new(nightvision_noise2);
1843                 }
1844
1845                 // color tint in yellow
1846                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
1847
1848                 // draw BG
1849                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
1850                 rgb = '1 1 1';
1851                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
1852                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
1853                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
1854                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
1855                 tc_11 = tc_01 + tc_10 - tc_00;
1856                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
1857                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1858                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1859                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1860                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1861                 R_EndPolygon();
1862
1863                 // draw FG
1864                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
1865                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
1866                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
1867                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
1868                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
1869                 tc_11 = tc_01 + tc_10 - tc_00;
1870                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
1871                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
1872                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
1873                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
1874                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
1875                 R_EndPolygon();
1876         }
1877
1878         if(autocvar_cl_reticle)
1879         {
1880                 Weapon wep = activeweapon;
1881                 // Draw the aiming reticle for weapons that use it
1882                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
1883                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
1884                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
1885                 if(spectatee_status || is_dead || hud != HUD_NORMAL)
1886                 {
1887                         // no zoom reticle while dead
1888                         reticle_type = 0;
1889                 }
1890                 else if(wep.wr_zoomreticle(wep) && autocvar_cl_reticle_weapon)
1891                 {
1892                         if(reticle_image != "") { reticle_type = 2; }
1893                         else { reticle_type = 0; }
1894                 }
1895                 else if(button_zoom || zoomscript_caught)
1896                 {
1897                         // normal zoom
1898                         reticle_type = 1;
1899                 }
1900
1901                 if(reticle_type)
1902                 {
1903                         if(autocvar_cl_reticle_stretch)
1904                         {
1905                                 reticle_size.x = vid_conwidth;
1906                                 reticle_size.y = vid_conheight;
1907                                 reticle_pos.x = 0;
1908                                 reticle_pos.y = 0;
1909                         }
1910                         else
1911                         {
1912                                 reticle_size.x = max(vid_conwidth, vid_conheight);
1913                                 reticle_size.y = max(vid_conwidth, vid_conheight);
1914                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
1915                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
1916                         }
1917
1918                         if(zoomscript_caught)
1919                                 f = 1;
1920                         else
1921                                 f = current_zoomfraction;
1922
1923                         if(f)
1924                         {
1925                                 switch(reticle_type)
1926                                 {
1927                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
1928                                         case 2: drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
1929                                 }
1930                         }
1931                 }
1932         }
1933         else
1934         {
1935                 if(reticle_type != 0) { reticle_type = 0; }
1936         }
1937
1938
1939         // improved polyblend
1940         if(autocvar_hud_contents)
1941         {
1942                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
1943                 vector liquidcolor;
1944
1945                 switch(pointcontents(view_origin))
1946                 {
1947                         case CONTENT_WATER:
1948                                 liquidalpha = autocvar_hud_contents_water_alpha;
1949                                 liquidcolor = stov(autocvar_hud_contents_water_color);
1950                                 incontent = 1;
1951                                 break;
1952
1953                         case CONTENT_LAVA:
1954                                 liquidalpha = autocvar_hud_contents_lava_alpha;
1955                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
1956                                 incontent = 1;
1957                                 break;
1958
1959                         case CONTENT_SLIME:
1960                                 liquidalpha = autocvar_hud_contents_slime_alpha;
1961                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
1962                                 incontent = 1;
1963                                 break;
1964
1965                         default:
1966                                 liquidalpha = 0;
1967                                 liquidcolor = '0 0 0';
1968                                 incontent = 0;
1969                                 break;
1970                 }
1971
1972                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
1973                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
1974                         contentfadetime = autocvar_hud_contents_fadeintime;
1975                         liquidalpha_prev = liquidalpha;
1976                         liquidcolor_prev = liquidcolor;
1977                 }
1978                 else
1979                         contentfadetime = autocvar_hud_contents_fadeouttime;
1980
1981                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
1982                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
1983
1984                 if(contentavgalpha)
1985                         drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
1986
1987                 if(autocvar_hud_postprocessing)
1988                 {
1989                         if(autocvar_hud_contents_blur && contentavgalpha)
1990                         {
1991                                 content_blurpostprocess.x = 1;
1992                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
1993                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
1994                         }
1995                         else
1996                         {
1997                                 content_blurpostprocess.x = 0;
1998                                 content_blurpostprocess.y = 0;
1999                                 content_blurpostprocess.z = 0;
2000                         }
2001                 }
2002         }
2003
2004         if(autocvar_hud_damage && !STAT(FROZEN))
2005         {
2006                 splash_size.x = max(vid_conwidth, vid_conheight);
2007                 splash_size.y = max(vid_conwidth, vid_conheight);
2008                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2009                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2010
2011                 float myhealth_flash_temp;
2012                 myhealth = STAT(HEALTH);
2013
2014                 // fade out
2015                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2016                 // add new damage
2017                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2018
2019                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2020                 pain_threshold = autocvar_hud_damage_pain_threshold;
2021                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2022                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2023
2024                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2025                 {
2026                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2027                 }
2028
2029                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2030
2031                 if(myhealth_prev < 1)
2032                 {
2033                         if(myhealth >= 1)
2034                         {
2035                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2036                                 myhealth_flash_temp = 0;
2037                         }
2038                         else
2039                         {
2040                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2041                         }
2042                 }
2043
2044                 if(spectatee_status == -1 || intermission)
2045                 {
2046                         myhealth_flash = 0; // observing, or match ended
2047                         myhealth_flash_temp = 0;
2048                 }
2049
2050                 myhealth_prev = myhealth;
2051
2052                 // IDEA: change damage color/picture based on player model for robot/alien species?
2053                 // pro: matches model better
2054                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2055                 // maybe different reddish pics?
2056                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2057                 {
2058                         if(autocvar_cl_gentle_damage == 2)
2059                         {
2060                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2061                                         myhealth_gentlergb = eX * random() + eY * random() + eZ * random();
2062                         }
2063                         else
2064                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2065
2066                         if(myhealth_flash_temp > 0)
2067                                 drawfill('0 0 0', eX * vid_conwidth + eY * vid_conheight, myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2068                 }
2069                 else if(myhealth_flash_temp > 0)
2070                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2071
2072                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2073                 {
2074                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2075                         {
2076                                 damage_blurpostprocess.x = 1;
2077                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2078                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2079                         }
2080                         else
2081                         {
2082                                 damage_blurpostprocess.x = 0;
2083                                 damage_blurpostprocess.y = 0;
2084                                 damage_blurpostprocess.z = 0;
2085                         }
2086                 }
2087         }
2088
2089         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2090         float e2 = (autocvar_hud_powerup != 0);
2091         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2092         {
2093                 // enable or disable rendering types if they are used or not
2094                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2095                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2096
2097                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2098                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2099                 {
2100                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2101                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2102                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2103                         {
2104                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2105                                 old_blurradius = blurradius;
2106                                 old_bluralpha = bluralpha;
2107                         }
2108                 }
2109                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2110                 {
2111                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2112                         old_blurradius = 0;
2113                         old_bluralpha = 0;
2114                 }
2115
2116                 // edge detection postprocess handling done second (used by hud_powerup)
2117                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2118                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2119                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2120
2121                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2122
2123                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2124                 {
2125                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2126                         {
2127                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2128                                 old_sharpen_intensity = sharpen_intensity;
2129                         }
2130                 }
2131                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2132                 {
2133                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2134                         old_sharpen_intensity = 0;
2135                 }
2136
2137                 if(cvar("r_glsl_postprocess") == 0)
2138                         cvar_set("r_glsl_postprocess", "2");
2139         }
2140         else if(cvar("r_glsl_postprocess") == 2)
2141                 cvar_set("r_glsl_postprocess", "0");
2142
2143         /*if(gametype == MAPINFO_TYPE_CTF)
2144           {
2145           ctf_view();
2146           } else */
2147
2148         // draw 2D entities
2149         FOREACH_ENTITY(it.draw2d, LAMBDA(WITH(entity, self, it, it.draw2d(it))));
2150         Draw_ShowNames_All();
2151         Debug_Draw();
2152
2153         scoreboard_active = HUD_WouldDrawScoreboard();
2154
2155         HUD_Draw();
2156
2157         if(NextFrameCommand)
2158         {
2159                 localcmd("\n", NextFrameCommand, "\n");
2160                 NextFrameCommand = string_null;
2161         }
2162
2163         // we must do this check AFTER a frame was rendered, or it won't work
2164         if(cs_project_is_b0rked == 0)
2165         {
2166                 string w0, h0;
2167                 w0 = ftos(autocvar_vid_conwidth);
2168                 h0 = ftos(autocvar_vid_conheight);
2169                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2170                 //setproperty(VF_FOV, '90 90 0');
2171                 setproperty(VF_ORIGIN, '0 0 0');
2172                 setproperty(VF_ANGLES, '0 0 0');
2173                 setproperty(VF_PERSPECTIVE, 1);
2174                 makevectors('0 0 0');
2175                 vector v1, v2;
2176                 cvar_set("vid_conwidth", "800");
2177                 cvar_set("vid_conheight", "600");
2178                 v1 = cs_project(v_forward);
2179                 cvar_set("vid_conwidth", "640");
2180                 cvar_set("vid_conheight", "480");
2181                 v2 = cs_project(v_forward);
2182                 if(v1 == v2)
2183                         cs_project_is_b0rked = 1;
2184                 else
2185                         cs_project_is_b0rked = -1;
2186                 cvar_set("vid_conwidth", w0);
2187                 cvar_set("vid_conheight", h0);
2188         }
2189
2190         if(autocvar__hud_configure)
2191                 HUD_Panel_Mouse();
2192         else if ( HUD_MinigameMenu_IsOpened() || minigame_isactive() )
2193                 HUD_Minigame_Mouse();
2194         else if(QuickMenu_IsOpened())
2195                 QuickMenu_Mouse();
2196         else
2197                 HUD_Radar_Mouse();
2198
2199         cl_notice_run();
2200         unpause_update();
2201         Net_Flush();
2202
2203         // let's reset the view back to normal for the end
2204         setproperty(VF_MIN, '0 0 0');
2205         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2206 }
2207
2208
2209 // following vectors must be global to allow seamless switching between camera modes
2210 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2211 void CSQC_Demo_Camera()
2212 {
2213         float speed, attenuation, dimensions;
2214         vector tmp, delta;
2215
2216         if( autocvar_camera_reset || !camera_mode )
2217         {
2218                 camera_offset = '0 0 0';
2219                 current_angles = '0 0 0';
2220                 camera_direction = '0 0 0';
2221                 camera_offset.z += 30;
2222                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2223                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2224                 current_origin = view_origin;
2225                 current_camera_offset  = camera_offset;
2226                 cvar_set("camera_reset", "0");
2227                 camera_mode = CAMERA_CHASE;
2228         }
2229
2230         // Camera angles
2231         if( camera_roll )
2232                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2233
2234         if(autocvar_camera_look_player)
2235         {
2236                 vector dir;
2237                 float n;
2238
2239                 dir = normalize(view_origin - current_position);
2240                 n = mouse_angles.z;
2241                 mouse_angles = vectoangles(dir);
2242                 mouse_angles.x = mouse_angles.x * -1;
2243                 mouse_angles.z = n;
2244         }
2245         else
2246         {
2247                 tmp = getmousepos() * 0.1;
2248                 if(vlen(tmp)>autocvar_camera_mouse_threshold)
2249                 {
2250                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2251                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2252                 }
2253         }
2254
2255         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2256         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2257         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2258         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2259
2260         // Fix difference when angles don't have the same sign
2261         delta = '0 0 0';
2262         if(mouse_angles.y < -60 && current_angles.y > 60)
2263                 delta = '0 360 0';
2264         if(mouse_angles.y > 60 && current_angles.y < -60)
2265                 delta = '0 -360 0';
2266
2267         if(autocvar_camera_look_player)
2268                 attenuation = autocvar_camera_look_attenuation;
2269         else
2270                 attenuation = autocvar_camera_speed_attenuation;
2271
2272         attenuation = 1 / max(1, attenuation);
2273         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2274
2275         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2276         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2277         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2278         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2279
2280         // Camera position
2281         tmp = '0 0 0';
2282         dimensions = 0;
2283
2284         if( camera_direction.x )
2285         {
2286                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2287                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2288                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2289                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2290                 ++dimensions;
2291         }
2292
2293         if( camera_direction.y )
2294         {
2295                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2296                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2297                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2298                 ++dimensions;
2299         }
2300
2301         if( camera_direction.z )
2302         {
2303                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2304                 ++dimensions;
2305         }
2306
2307         if(autocvar_camera_free)
2308                 speed = autocvar_camera_speed_free;
2309         else
2310                 speed = autocvar_camera_speed_chase;
2311
2312         if(dimensions)
2313         {
2314                 speed = speed * sqrt(1 / dimensions);
2315                 camera_offset += tmp * speed;
2316         }
2317
2318         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2319
2320         // Camera modes
2321         if( autocvar_camera_free )
2322         {
2323                 if ( camera_mode == CAMERA_CHASE )
2324                 {
2325                         current_camera_offset = current_origin + current_camera_offset;
2326                         camera_offset = current_origin + camera_offset;
2327                 }
2328
2329                 camera_mode = CAMERA_FREE;
2330                 current_position = current_camera_offset;
2331         }
2332         else
2333         {
2334                 if ( camera_mode == CAMERA_FREE )
2335                 {
2336                         current_origin = view_origin;
2337                         camera_offset = camera_offset - current_origin;
2338                         current_camera_offset = current_camera_offset - current_origin;
2339                 }
2340
2341                 camera_mode = CAMERA_CHASE;
2342
2343                 if(autocvar_camera_chase_smoothly)
2344                         current_origin += (view_origin - current_origin) * attenuation;
2345                 else
2346                         current_origin = view_origin;
2347
2348                 current_position = current_origin + current_camera_offset;
2349         }
2350
2351         setproperty(VF_ANGLES, current_angles);
2352         setproperty(VF_ORIGIN, current_position);
2353 }