qcsrc/client/view.qc

   1 #include "view.qh"
   2
   3 #include "autocvars.qh"
   4 #include "miscfunctions.qh"
   5 #include "announcer.qh"
   6 #include "hud/_mod.qh"
   7 #include "mapvoting.qh"
   8 #include "shownames.qh"
   9 #include "hud/panel/scoreboard.qh"
  10 #include "hud/panel/quickmenu.qh"
  11
  12 #include "mutators/events.qh"
  13
  14 #include <common/animdecide.qh>
  15 #include <common/deathtypes/all.qh>
  16 #include <common/ent_cs.qh>
  17 #include <common/anim.qh>
  18 #include <common/constants.qh>
  19 #include <common/net_linked.qh>
  20 #include <common/debug.qh>
  21 #include <common/mapinfo.qh>
  22 #include <common/gamemodes/_mod.qh>
  23 #include <common/physics/player.qh>
  24 #include <common/stats.qh>
  25 #include <common/mapobjects/target/music.qh>
  26 #include <common/teams.qh>
  27 #include <common/wepent.qh>
  28
  29 #include <common/weapons/weapon/tuba.qh>
  30
  31 #include <common/vehicles/all.qh>
  32 #include <common/weapons/_all.qh>
  33 #include <common/mutators/mutator/overkill/oknex.qh>
  34 #include <common/viewloc.qh>
  35 #include <common/mapobjects/trigger/viewloc.qh>
  36 #include <common/minigames/cl_minigames.qh>
  37 #include <common/minigames/cl_minigames_hud.qh>
  38
  39 #include <lib/csqcmodel/cl_player.qh>
  40 #include <lib/csqcmodel/cl_model.qh>
  41 #include "csqcmodel_hooks.qh"
  42
  43 #include <lib/warpzone/client.qh>
  44 #include <lib/warpzone/common.qh>
  45
  46 #define EFMASK_CHEAP (EF_ADDITIVE | EF_DOUBLESIDED | EF_FULLBRIGHT | EF_NODEPTHTEST | EF_NODRAW | EF_NOSHADOW | EF_SELECTABLE | EF_TELEPORT_BIT)
  47
  48 float autocvar_cl_viewmodel_scale;
  49
  50 bool autocvar_cl_bobmodel;
  51 float autocvar_cl_bobmodel_speed;
  52 float autocvar_cl_bobmodel_side;
  53 float autocvar_cl_bobmodel_up;
  54
  55 float autocvar_cl_followmodel;
  56 float autocvar_cl_followmodel_speed = 0.3;
  57 float autocvar_cl_followmodel_limit = 135;
  58 float autocvar_cl_followmodel_velocity_lowpass = 0.05;
  59 float autocvar_cl_followmodel_highpass = 0.05;
  60 float autocvar_cl_followmodel_lowpass = 0.03;
  61 bool autocvar_cl_followmodel_velocity_absolute;
  62
  63 float autocvar_cl_leanmodel;
  64 float autocvar_cl_leanmodel_speed = 0.3;
  65 float autocvar_cl_leanmodel_limit = 30;
  66 float autocvar_cl_leanmodel_highpass1 = 0.2;
  67 float autocvar_cl_leanmodel_highpass = 0.2;
  68 float autocvar_cl_leanmodel_lowpass = 0.05;
  69
  70 #define avg_factor(avg_time) (1 - exp(-frametime / max(0.001, avg_time)))
  71
  72 #define lowpass(value, frac, ref_store, ret) \
  73         ret = ref_store = ref_store * (1 - frac) + (value) * frac;
  74
  75 #define lowpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  76 { \
  77         float __ignore; lowpass(value, frac, ref_store, __ignore); \
  78         ret = ref_store = bound((value) - (limit), ref_store, (value) + (limit)); \
  79 } MACRO_END
  80
  81 #define highpass(value, frac, ref_store, ret) MACRO_BEGIN \
  82 { \
  83         float __f = 0; lowpass(value, frac, ref_store, __f); \
  84         ret = (value) - __f; \
  85 } MACRO_END
  86
  87 #define highpass_limited(value, frac, limit, ref_store, ret) MACRO_BEGIN \
  88 { \
  89         float __f = 0; lowpass_limited(value, frac, limit, ref_store, __f); \
  90         ret = (value) - __f; \
  91 } MACRO_END
  92
  93 #define lowpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
  94 { \
  95         lowpass(value.x, frac, ref_store.x, ref_out.x); \
  96         lowpass(value.y, frac, ref_store.y, ref_out.y); \
  97 } MACRO_END
  98
  99 #define highpass2(value, frac, ref_store, ref_out) MACRO_BEGIN \
 100 { \
 101         highpass(value.x, frac, ref_store.x, ref_out.x); \
 102         highpass(value.y, frac, ref_store.y, ref_out.y); \
 103 } MACRO_END
 104
 105 #define highpass2_limited(value, frac, limit, ref_store, ref_out) MACRO_BEGIN \
 106 { \
 107         highpass_limited(value.x, frac, limit, ref_store.x, ref_out.x); \
 108         highpass_limited(value.y, frac, limit, ref_store.y, ref_out.y); \
 109 } MACRO_END
 110
 111 #define lowpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 112 { \
 113         lowpass(value.x, frac, ref_store.x, ref_out.x); \
 114         lowpass(value.y, frac, ref_store.y, ref_out.y); \
 115         lowpass(value.z, frac, ref_store.z, ref_out.z); \
 116 } MACRO_END
 117
 118 #define highpass3(value, frac, ref_store, ref_out) MACRO_BEGIN \
 119 { \
 120         highpass(value.x, frac, ref_store.x, ref_out.x); \
 121         highpass(value.y, frac, ref_store.y, ref_out.y); \
 122         highpass(value.z, frac, ref_store.z, ref_out.z); \
 123 } MACRO_END
 124
 125 void calc_followmodel_ofs(entity view)
 126 {
 127         if(cl_followmodel_time == time)
 128                 return; // cl_followmodel_ofs already calculated for this frame
 129
 130         float frac;
 131         vector gunorg = '0 0 0';
 132         static vector vel_average;
 133         static vector gunorg_adjustment_highpass;
 134         static vector gunorg_adjustment_lowpass;
 135
 136         vector vel;
 137         if (autocvar_cl_followmodel_velocity_absolute)
 138                 vel = view.velocity;
 139         else
 140         {
 141                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 142                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 143                 vel.x = view.velocity * forward;
 144                 vel.y = view.velocity * right * -1;
 145                 vel.z = view.velocity * up;
 146         }
 147
 148         vel.x = bound(vel_average.x - autocvar_cl_followmodel_limit, vel.x, vel_average.x + autocvar_cl_followmodel_limit);
 149         vel.y = bound(vel_average.y - autocvar_cl_followmodel_limit, vel.y, vel_average.y + autocvar_cl_followmodel_limit);
 150         vel.z = bound(vel_average.z - autocvar_cl_followmodel_limit, vel.z, vel_average.z + autocvar_cl_followmodel_limit);
 151
 152         frac = avg_factor(autocvar_cl_followmodel_velocity_lowpass);
 153         lowpass3(vel, frac, vel_average, gunorg);
 154
 155         gunorg *= -autocvar_cl_followmodel_speed * 0.042;
 156
 157         // perform highpass/lowpass on the adjustment vectors (turning velocity into acceleration!)
 158         // trick: we must do the lowpass LAST, so the lowpass vector IS the final vector!
 159         frac = avg_factor(autocvar_cl_followmodel_highpass);
 160         highpass3(gunorg, frac, gunorg_adjustment_highpass, gunorg);
 161         frac = avg_factor(autocvar_cl_followmodel_lowpass);
 162         lowpass3(gunorg, frac, gunorg_adjustment_lowpass, gunorg);
 163
 164         if (autocvar_cl_followmodel_velocity_absolute)
 165         {
 166                 vector fixed_gunorg;
 167                 vector forward = '0 0 0', right = '0 0 0', up = '0 0 0';
 168                 MAKEVECTORS(makevectors, view_angles, forward, right, up);
 169                 fixed_gunorg.x = gunorg * forward;
 170                 fixed_gunorg.y = gunorg * right * -1;
 171                 fixed_gunorg.z = gunorg * up;
 172                 gunorg = fixed_gunorg;
 173         }
 174
 175         cl_followmodel_ofs = gunorg;
 176         cl_followmodel_time = time;
 177 }
 178
 179 vector leanmodel_ofs(entity view)
 180 {
 181         float frac;
 182         vector gunangles = '0 0 0';
 183         static vector gunangles_prev = '0 0 0';
 184         static vector gunangles_highpass = '0 0 0';
 185         static vector gunangles_adjustment_highpass;
 186         static vector gunangles_adjustment_lowpass;
 187
 188         if (view.csqcmodel_teleported)
 189                 gunangles_prev = view_angles;
 190
 191         // in the highpass, we _store_ the DIFFERENCE to the actual view angles...
 192         gunangles_highpass += gunangles_prev;
 193         PITCH(gunangles_highpass) += 360 * floor((PITCH(view_angles) - PITCH(gunangles_highpass)) / 360 + 0.5);
 194         YAW(gunangles_highpass) += 360 * floor((YAW(view_angles) - YAW(gunangles_highpass)) / 360 + 0.5);
 195         ROLL(gunangles_highpass) += 360 * floor((ROLL(view_angles) - ROLL(gunangles_highpass)) / 360 + 0.5);
 196         frac = avg_factor(autocvar_cl_leanmodel_highpass1);
 197         highpass2_limited(view_angles, frac, autocvar_cl_leanmodel_limit, gunangles_highpass, gunangles);
 198         gunangles_prev = view_angles;
 199         gunangles_highpass -= gunangles_prev;
 200
 201         PITCH(gunangles) *= -autocvar_cl_leanmodel_speed;
 202         YAW(gunangles) *= -autocvar_cl_leanmodel_speed;
 203
 204         // we assume here: PITCH = 0, YAW = 1, ROLL = 2
 205         frac = avg_factor(autocvar_cl_leanmodel_highpass);
 206         highpass2(gunangles, frac, gunangles_adjustment_highpass, gunangles);
 207         frac = avg_factor(autocvar_cl_leanmodel_lowpass);
 208         lowpass2(gunangles, frac, gunangles_adjustment_lowpass, gunangles);
 209
 210         gunangles.x = -gunangles.x; // pitch was inverted, now that actually matters
 211
 212         return gunangles;
 213 }
 214
 215 vector bobmodel_ofs(entity view)
 216 {
 217         bool clonground = !(view.anim_implicit_state & ANIMIMPLICITSTATE_INAIR);
 218         static bool oldonground;
 219         static float hitgroundtime;
 220         if (clonground)
 221         {
 222                 float f = time; // cl.movecmd[0].time
 223                 if (!oldonground)
 224                         hitgroundtime = f;
 225         }
 226         oldonground = clonground;
 227
 228         // calculate for swinging gun model
 229         // the gun bobs when running on the ground, but doesn't bob when you're in the air.
 230         vector gunorg = '0 0 0';
 231         static float bobmodel_scale = 0;
 232         static float time_ofs = 0; // makes the effect always restart in the same way
 233         if (clonground)
 234         {
 235                 if (time - hitgroundtime > 0.05)
 236                         bobmodel_scale = min(1, bobmodel_scale + frametime * 5);
 237         }
 238         else
 239                 bobmodel_scale = max(0, bobmodel_scale - frametime * 5);
 240
 241         float xyspeed = bound(0, vlen(vec2(view.velocity)), 400);
 242         if (bobmodel_scale && xyspeed)
 243         {
 244                 float bspeed = xyspeed * 0.01 * autocvar_cl_viewmodel_scale * bobmodel_scale;
 245                 float s = (time - time_ofs) * autocvar_cl_bobmodel_speed;
 246                 gunorg.y = bspeed * autocvar_cl_bobmodel_side * sin(s);
 247                 gunorg.z = bspeed * autocvar_cl_bobmodel_up * cos(s * 2);
 248         }
 249         else
 250                 time_ofs = time;
 251
 252         return gunorg;
 253 }
 254
 255 void viewmodel_animate(entity this)
 256 {
 257         if (autocvar_chase_active) return;
 258         if (STAT(HEALTH) <= 0) return;
 259
 260         entity view = CSQCModel_server2csqc(player_localentnum - 1);
 261
 262         if (autocvar_cl_followmodel)
 263         {
 264                 calc_followmodel_ofs(view);
 265                 this.origin += cl_followmodel_ofs;
 266         }
 267
 268         if (autocvar_cl_leanmodel)
 269                 this.angles += leanmodel_ofs(view);
 270
 271         // vertical view bobbing code
 272         // TODO: cl_bob
 273
 274         // horizontal view bobbing code
 275         // TODO: cl_bob2
 276
 277         // fall bobbing code
 278         // causes the view to swing down and back up when touching the ground
 279         // TODO: cl_bobfall
 280
 281         // gun model bobbing code
 282         if (autocvar_cl_bobmodel)
 283                 this.origin += bobmodel_ofs(view);
 284 }
 285
 286 .vector viewmodel_origin, viewmodel_angles;
 287 .float weapon_nextthink;
 288 .float weapon_eta_last;
 289 .float weapon_switchdelay;
 290
 291 .string name_last;
 292
 293 void viewmodel_draw(entity this)
 294 {
 295         if(!this.activeweapon || !autocvar_r_drawviewmodel)
 296                 return;
 297         int mask = (intermission || (STAT(HEALTH) <= 0) || autocvar_chase_active) ? 0 : MASK_NORMAL;
 298         float a = this.alpha;
 299         static bool wasinvehicle;
 300         bool invehicle = player_localentnum > maxclients;
 301         if (invehicle) a = -1;
 302         else if (wasinvehicle) a = 1;
 303         wasinvehicle = invehicle;
 304         Weapon wep = this.activeweapon;
 305         int c = entcs_GetClientColors(current_player);
 306         vector g = weaponentity_glowmod(wep, NULL, c, this);
 307         entity me = CSQCModel_server2csqc(player_localentnum - 1);
 308         int fx = ((me.csqcmodel_effects & EFMASK_CHEAP)
 309                 | EF_NODEPTHTEST)
 310                 &~ (EF_FULLBRIGHT); // can mask team color, so get rid of it
 311         for (entity e = this; e; e = e.weaponchild)
 312         {
 313                 e.drawmask = mask;
 314                 e.alpha = a;
 315                 e.colormap = 256 + c;  // colormap == 0 is black, c == 0 is white
 316                 e.glowmod = g;
 317                 e.csqcmodel_effects = fx;
 318                 CSQCModel_Effects_Apply(e);
 319         }
 320         if(a >= 0)
 321         {
 322                 string name = wep.mdl;
 323                 string newname = wep.wr_viewmodel(wep, this);
 324                 if(newname)
 325                         name = newname;
 326                 bool swap = name != this.name_last;
 327                 // if (swap)
 328                 {
 329                         this.name_last = name;
 330                         CL_WeaponEntity_SetModel(this, name, swap);
 331                         this.viewmodel_origin = this.origin;
 332                         this.viewmodel_angles = this.angles;
 333                 }
 334                 anim_update(this);
 335                 if ((!this.animstate_override && !this.animstate_looping) || time > this.animstate_endtime)
 336                         anim_set(this, this.anim_idle, true, false, false);
 337         }
 338         float f = 0; // 0..1; 0: fully active
 339         float rate = STAT(WEAPONRATEFACTOR);
 340         float eta = rate ? ((this.weapon_nextthink - time) / rate) : 0;
 341         if (eta <= 0) f = this.weapon_eta_last;
 342         else switch (this.state)
 343         {
 344                 case WS_RAISE:
 345                 {
 346                         f = eta / max(eta, this.weapon_switchdelay);
 347                         break;
 348                 }
 349                 case WS_DROP:
 350                 {
 351                         f = 1 - eta / max(eta, this.weapon_switchdelay);
 352                         break;
 353                 }
 354                 case WS_CLEAR:
 355                 {
 356                         f = 1;
 357                         break;
 358                 }
 359         }
 360         this.weapon_eta_last = f;
 361         this.origin = this.viewmodel_origin;
 362         this.angles = this.viewmodel_angles;
 363         this.angles_x = (-90 * f * f);
 364         viewmodel_animate(this);
 365         MUTATOR_CALLHOOK(DrawViewModel, this);
 366         setorigin(this, this.origin);
 367 }
 368
 369 STATIC_INIT(viewmodel) {
 370     for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 371         viewmodels[slot] = new(viewmodel);
 372 }
 373
 374 float showfps_prevfps;
 375 float showfps_prevfps_time;
 376 int showfps_framecounter;
 377
 378 void fpscounter_update()
 379 {
 380         if(!STAT(SHOWFPS))
 381                 return;
 382
 383         float currentTime = gettime(GETTIME_REALTIME);
 384         showfps_framecounter += 1;
 385         if(currentTime - showfps_prevfps_time > STAT(SHOWFPS))
 386         {
 387                 showfps_prevfps = showfps_framecounter/(currentTime - showfps_prevfps_time);
 388                 showfps_framecounter = 0;
 389                 showfps_prevfps_time = currentTime;
 390
 391                 int channel = MSG_C2S;
 392                 WriteHeader(channel, fpsreport);
 393                 WriteShort(channel, bound(0, rint(showfps_prevfps), 65535)); // prevent insane fps values
 394         }
 395 }
 396
 397 STATIC_INIT(fpscounter_init)
 398 {
 399         float currentTime = gettime(GETTIME_REALTIME);
 400         showfps_prevfps_time = currentTime; // we must initialize it to avoid an instant low frame sending
 401 }
 402
 403 void Porto_Draw(entity this);
 404 STATIC_INIT(Porto)
 405 {
 406         entity e = new_pure(porto);
 407         e.draw = Porto_Draw;
 408         IL_PUSH(g_drawables, e);
 409         e.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP;
 410 }
 411
 412 const int polyline_length = 16;
 413 .vector polyline[polyline_length];
 414 void Porto_Draw(entity this)
 415 {
 416         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 417         {
 418                 entity wepent = viewmodels[slot];
 419
 420                 if (wepent.activeweapon != WEP_PORTO) continue;
 421                 if (spectatee_status) continue;
 422                 if (WEP_CVAR(porto, secondary)) continue;
 423                 if (intermission == 1) continue;
 424                 if (intermission == 2) continue;
 425                 if (STAT(HEALTH) <= 0) continue;
 426
 427                 vector pos = view_origin;
 428                 vector dir = view_forward;
 429                 if (wepent.angles_held_status)
 430                 {
 431                         makevectors(wepent.angles_held);
 432                         dir = v_forward;
 433                 }
 434
 435                 wepent.polyline[0] = pos;
 436
 437                 int portal_number = 0, portal1_idx = 1, portal_max = 2;
 438                 int n = 1 + 2;  // 2 lines == 3 points
 439                 for (int idx = 0; idx < n && idx < polyline_length - 1; )
 440                 {
 441                         traceline(pos, pos + 65536 * dir, true, this);
 442                         dir = reflect(dir, trace_plane_normal);
 443                         pos = trace_endpos;
 444                         wepent.polyline[++idx] = pos;
 445                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SLICK || trace_dphitcontents & DPCONTENTS_PLAYERCLIP)
 446                         {
 447                                 n += 1;
 448                                 continue;
 449                         }
 450                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
 451                         {
 452                                 n = max(2, idx);
 453                                 break;
 454                         }
 455                         // check size
 456                         {
 457                                 vector ang = vectoangles2(trace_plane_normal, dir);
 458                                 ang.x = -ang.x;
 459                                 makevectors(ang);
 460                                 if (!CheckWireframeBox(this, pos - 48 * v_right - 48 * v_up + 16 * v_forward, 96 * v_right, 96 * v_up, 96 * v_forward))
 461                                 {
 462                                         n = max(2, idx);
 463                                         break;
 464                                 }
 465                         }
 466                         portal_number += 1;
 467                         if (portal_number >= portal_max) break;
 468                         if (portal_number == 1) portal1_idx = idx;
 469                 }
 470                 for (int idx = 0; idx < n - 1; ++idx)
 471                 {
 472                         vector p = wepent.polyline[idx], q = wepent.polyline[idx + 1];
 473                         if (idx == 0) p -= view_up * 16;  // line from player
 474                         vector rgb = (idx < portal1_idx) ? '1 0 0' : '0 0 1';
 475                         Draw_CylindricLine(p, q, 4, "", 1, 0, rgb, 0.5, DRAWFLAG_NORMAL, view_origin);
 476                 }
 477         }
 478 }
 479
 480 float drawtime;
 481 float avgspeed;
 482 vector GetCurrentFov(float fov)
 483 {
 484         float zoomsensitivity, zoomspeed, zoomfactor, zoomdir;
 485         float velocityzoom, curspeed;
 486         vector v;
 487
 488         zoomsensitivity = autocvar_cl_zoomsensitivity;
 489         zoomfactor = autocvar_cl_zoomfactor;
 490         if(zoomfactor < 1 || zoomfactor > 30)
 491                 zoomfactor = 2.5;
 492         zoomspeed = autocvar_cl_zoomspeed;
 493         if(zoomspeed >= 0)
 494         if(zoomspeed < 0.5 || zoomspeed > 16)
 495                         zoomspeed = 3.5;
 496
 497         zoomdir = button_zoom;
 498
 499         if(hud == HUD_NORMAL && !spectatee_status)
 500         {
 501                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 502                 {
 503                         entity wepent = viewmodels[slot];
 504                         if(wepent.switchweapon != wepent.activeweapon)
 505                                 continue;
 506                         Weapon wep = wepent.activeweapon;
 507                         if(wep != WEP_Null && wep.wr_zoomdir)
 508                         {
 509                                 bool do_zoom = wep.wr_zoomdir(wep); // TODO: merge this with wr_zoom?
 510                                 zoomdir += do_zoom;
 511                         }
 512                 }
 513         }
 514         if(spectatee_status > 0 || isdemo())
 515         {
 516                 if(spectatorbutton_zoom)
 517                 {
 518                         if(zoomdir)
 519                                 zoomdir = 0;
 520                         else
 521                                 zoomdir = 1;
 522                 }
 523                 // fteqcc failed twice here already, don't optimize this
 524         }
 525
 526         if(zoomdir) { zoomin_effect = 0; }
 527
 528         if(camera_active)
 529         {
 530                 current_viewzoom = min(1, current_viewzoom + drawframetime);
 531         }
 532         else if(autocvar_cl_spawnzoom && zoomin_effect)
 533         {
 534                 float spawnzoomfactor = bound(1, autocvar_cl_spawnzoom_factor, 30);
 535
 536                 current_viewzoom += (autocvar_cl_spawnzoom_speed * (spawnzoomfactor - current_viewzoom) * drawframetime);
 537                 current_viewzoom = bound(1 / spawnzoomfactor, current_viewzoom, 1);
 538                 if(current_viewzoom == 1) { zoomin_effect = 0; }
 539         }
 540         else
 541         {
 542                 if(zoomspeed < 0) // instant zoom
 543                 {
 544                         if(zoomdir)
 545                                 current_viewzoom = 1 / zoomfactor;
 546                         else
 547                                 current_viewzoom = 1;
 548                 }
 549                 else
 550                 {
 551                         if(zoomdir)
 552                                 current_viewzoom = 1 / bound(1, 1 / current_viewzoom + drawframetime * zoomspeed * (zoomfactor - 1), zoomfactor);
 553                         else
 554                                 current_viewzoom = bound(1 / zoomfactor, current_viewzoom + drawframetime * zoomspeed * (1 - 1 / zoomfactor), 1);
 555                 }
 556         }
 557
 558         if(almost_equals(current_viewzoom, 1))
 559                 current_zoomfraction = 0;
 560         else if(almost_equals(current_viewzoom, 1/zoomfactor))
 561                 current_zoomfraction = 1;
 562         else
 563                 current_zoomfraction = (current_viewzoom - 1) / (1/zoomfactor - 1);
 564
 565         if(zoomsensitivity < 1)
 566                 setsensitivityscale(current_viewzoom ** (1 - zoomsensitivity));
 567         else
 568                 setsensitivityscale(1);
 569
 570         if(autocvar_cl_velocityzoom_enabled && autocvar_cl_velocityzoom_type) // _type = 0 disables velocity zoom too
 571         {
 572                 if(intermission) { curspeed = 0; }
 573                 else
 574                 {
 575
 576                         makevectors(view_angles);
 577                         v = pmove_vel;
 578                         if(csqcplayer)
 579                                 v = csqcplayer.velocity;
 580
 581                         switch(autocvar_cl_velocityzoom_type)
 582                         {
 583                                 case 3: curspeed = max(0, v_forward * v); break;
 584                                 case 2: curspeed = (v_forward * v); break;
 585                                 case 1: default: curspeed = vlen(v); break;
 586                         }
 587                 }
 588
 589                 velocityzoom = bound(0, drawframetime / max(0.000000001, autocvar_cl_velocityzoom_time), 1); // speed at which the zoom adapts to player velocity
 590                 avgspeed = avgspeed * (1 - velocityzoom) + (curspeed / autocvar_cl_velocityzoom_speed) * velocityzoom;
 591                 velocityzoom = exp(float2range11(avgspeed * -autocvar_cl_velocityzoom_factor / 1) * 1);
 592
 593                 //print(ftos(avgspeed), " avgspeed, ", ftos(curspeed), " curspeed, ", ftos(velocityzoom), " return\n"); // for debugging
 594         }
 595         else
 596                 velocityzoom = 1;
 597
 598         float frustumx, frustumy, fovx, fovy;
 599         frustumy = tan(fov * M_PI / 360.0) * 0.75 * current_viewzoom * velocityzoom;
 600         frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 601         fovx = atan2(frustumx, 1) / M_PI * 360.0;
 602         fovy = atan2(frustumy, 1) / M_PI * 360.0;
 603
 604         return '1 0 0' * fovx + '0 1 0' * fovy;
 605 }
 606
 607 vector GetViewLocationFOV(float fov)
 608 {
 609         float frustumy = tan(fov * M_PI / 360.0) * 0.75;
 610         float frustumx = frustumy * vid_width / vid_height / vid_pixelheight;
 611         float fovx = atan2(frustumx, 1) / M_PI * 360.0;
 612         float fovy = atan2(frustumy, 1) / M_PI * 360.0;
 613         return '1 0 0' * fovx + '0 1 0' * fovy;
 614 }
 615
 616 vector GetOrthoviewFOV(vector ov_worldmin, vector ov_worldmax, vector ov_mid, vector ov_org)
 617 {
 618         float fovx, fovy;
 619         float width = (ov_worldmax.x - ov_worldmin.x);
 620         float height = (ov_worldmax.y - ov_worldmin.y);
 621         float distance_to_middle_of_world = vlen(ov_mid - ov_org);
 622         fovx = atan2(width/2, distance_to_middle_of_world) / M_PI * 360.0;
 623         fovy = atan2(height/2, distance_to_middle_of_world) / M_PI * 360.0;
 624         return '1 0 0' * fovx + '0 1 0' * fovy;
 625 }
 626
 627 // this function must match W_SetupShot!
 628 float zoomscript_caught;
 629
 630 vector wcross_origin;
 631 float wcross_scale_prev, wcross_alpha_prev;
 632 vector wcross_color_prev;
 633 float wcross_scale_goal_prev, wcross_alpha_goal_prev;
 634 vector wcross_color_goal_prev;
 635 float wcross_changedonetime;
 636
 637 string wcross_name_goal_prev, wcross_name_goal_prev_prev;
 638 float wcross_resolution_goal_prev, wcross_resolution_goal_prev_prev;
 639 float wcross_name_changestarttime, wcross_name_changedonetime;
 640 float wcross_name_alpha_goal_prev, wcross_name_alpha_goal_prev_prev;
 641
 642 float wcross_ring_prev;
 643
 644 entity trueaim;
 645 entity trueaim_rifle;
 646
 647 const float SHOTTYPE_HITTEAM = 1;
 648 const float SHOTTYPE_HITOBSTRUCTION = 2;
 649 const float SHOTTYPE_HITWORLD = 3;
 650 const float SHOTTYPE_HITENEMY = 4;
 651
 652 void TrueAim_Init()
 653 {
 654         (trueaim = new_pure(trueaim)).dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 655         (trueaim_rifle = new_pure(trueaim_rifle)).dphitcontentsmask = DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 656 }
 657
 658 float EnemyHitCheck()
 659 {
 660         float t, n;
 661         wcross_origin = project_3d_to_2d(trace_endpos);
 662         wcross_origin.z = 0;
 663         if(trace_ent)
 664                 n = trace_ent.entnum;
 665         else
 666                 n = trace_networkentity;
 667         if(n < 1)
 668                 return SHOTTYPE_HITWORLD;
 669         if(n > maxclients)
 670                 return SHOTTYPE_HITWORLD;
 671         t = entcs_GetTeam(n - 1);
 672         if(teamplay)
 673                 if(t == myteam)
 674                         return SHOTTYPE_HITTEAM;
 675         if(t == NUM_SPECTATOR)
 676                 return SHOTTYPE_HITWORLD;
 677         return SHOTTYPE_HITENEMY;
 678 }
 679
 680 float TrueAimCheck(entity wepent)
 681 {
 682         float nudge = 1; // added to traceline target and subtracted from result TOOD(divVerent): do we still need this? Doesn't the engine do this now for us?
 683         vector vecs, trueaimpoint, w_shotorg;
 684         vector mi, ma, dv;
 685         float shottype;
 686         entity ta;
 687         float mv;
 688
 689         mi = ma = '0 0 0';
 690         ta = trueaim;
 691         mv = MOVE_NOMONSTERS;
 692
 693         switch(wepent.activeweapon) // WEAPONTODO
 694         {
 695                 case WEP_TUBA: // no aim
 696                 case WEP_PORTO: // shoots from eye
 697                 case WEP_NEXBALL: // shoots from eye
 698                 case WEP_HOOK: // no trueaim
 699                 case WEP_MORTAR: // toss curve
 700                         return SHOTTYPE_HITWORLD;
 701                 case WEP_VORTEX:
 702                 case WEP_OVERKILL_NEX:
 703                 case WEP_VAPORIZER:
 704                         mv = MOVE_NORMAL;
 705                         break;
 706                 case WEP_RIFLE:
 707                         ta = trueaim_rifle;
 708                         mv = MOVE_NORMAL;
 709                         if(zoomscript_caught)
 710                         {
 711                                 tracebox(view_origin, '0 0 0', '0 0 0', view_origin + view_forward * max_shot_distance, mv, ta);
 712                                 return EnemyHitCheck();
 713                         }
 714                         break;
 715                 case WEP_DEVASTATOR: // projectile has a size!
 716                         mi = '-3 -3 -3';
 717                         ma = '3 3 3';
 718                         break;
 719                 case WEP_FIREBALL: // projectile has a size!
 720                         mi = '-16 -16 -16';
 721                         ma = '16 16 16';
 722                         break;
 723                 case WEP_SEEKER: // projectile has a size!
 724                         mi = '-2 -2 -2';
 725                         ma = '2 2 2';
 726                         break;
 727                 case WEP_ELECTRO: // projectile has a size!
 728                         mi = '0 0 -3';
 729                         ma = '0 0 -3';
 730                         break;
 731         }
 732
 733         vector traceorigin = entcs_receiver(player_localentnum - 1).origin + (eZ * STAT(VIEWHEIGHT));
 734
 735         vecs = decompressShotOrigin(STAT(SHOTORG));
 736
 737         traceline(traceorigin, traceorigin + view_forward * max_shot_distance, mv, ta);
 738         trueaimpoint = trace_endpos;
 739
 740         if(vdist((trueaimpoint - traceorigin), <, g_trueaim_minrange))
 741                 trueaimpoint = traceorigin + view_forward * g_trueaim_minrange;
 742
 743         if(vecs.x > 0)
 744                 vecs.y = -vecs.y;
 745         else
 746                 vecs = '0 0 0';
 747
 748         dv = view_right * vecs.y + view_up * vecs.z;
 749         w_shotorg = traceorigin + dv;
 750
 751         // now move the vecs forward as much as requested if possible
 752         tracebox(w_shotorg, mi, ma, w_shotorg + view_forward * (vecs.x + nudge), MOVE_NORMAL, ta); // FIXME this MOVE_NORMAL part will misbehave a little in csqc
 753         w_shotorg = trace_endpos - view_forward * nudge;
 754
 755         tracebox(w_shotorg, mi, ma, trueaimpoint, MOVE_NORMAL, ta);
 756         shottype = EnemyHitCheck();
 757         if(shottype != SHOTTYPE_HITWORLD)
 758                 return shottype;
 759
 760 #if 0
 761         // FIXME WHY DOES THIS NOT WORK FOR THE ROCKET LAUNCHER?
 762         // or rather, I know why, but see no fix
 763         if(vlen(trace_endpos - trueaimpoint) > vlen(ma) + vlen(mi) + 1)
 764                 // yes, this is an ugly hack... but it seems good enough to find out whether the test hits the same place as the initial trace
 765                 return SHOTTYPE_HITOBSTRUCTION;
 766 #endif
 767
 768         return SHOTTYPE_HITWORLD;
 769 }
 770
 771 void PostInit();
 772 void CSQC_Demo_Camera();
 773 float camera_mode;
 774 const float CAMERA_FREE = 1;
 775 const float CAMERA_CHASE = 2;
 776 float reticle_type;
 777 string NextFrameCommand;
 778
 779 vector freeze_org, freeze_ang;
 780 entity nightvision_noise, nightvision_noise2;
 781
 782 const float MAX_TIME_DIFF = 5;
 783 float pickup_crosshair_time, pickup_crosshair_size;
 784 float hitindication_crosshair_size;
 785 float use_vortex_chargepool;
 786
 787 float myhealth, myhealth_prev;
 788 float myhealth_flash;
 789
 790 float old_blurradius, old_bluralpha;
 791 float old_sharpen_intensity;
 792
 793 vector myhealth_gentlergb;
 794
 795 float contentavgalpha, liquidalpha_prev;
 796 vector liquidcolor_prev;
 797
 798 float eventchase_current_distance;
 799 float eventchase_running;
 800 bool WantEventchase(entity this)
 801 {
 802         if(autocvar_cl_orthoview)
 803                 return false;
 804         if(STAT(GAME_STOPPED) || intermission)
 805                 return true;
 806         if(this.viewloc)
 807                 return true;
 808         if(spectatee_status >= 0)
 809         {
 810                 if(hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0))
 811                         return true;
 812                 if(MUTATOR_CALLHOOK(WantEventchase, this))
 813                         return true;
 814                 if(autocvar_cl_eventchase_frozen && STAT(FROZEN))
 815                         return true;
 816                 if(autocvar_cl_eventchase_death && (STAT(HEALTH) <= 0))
 817                 {
 818                         if(autocvar_cl_eventchase_death == 2)
 819                         {
 820                                 // don't stop eventchase once it's started (even if velocity changes afterwards)
 821                                 if(this.velocity == '0 0 0' || eventchase_running)
 822                                         return true;
 823                         }
 824                         else return true;
 825                 }
 826         }
 827         return false;
 828 }
 829
 830 void HUD_Crosshair_Vehicle(entity this)
 831 {
 832         if(hud != HUD_BUMBLEBEE_GUN)
 833         {
 834                 Vehicle info = Vehicles_from(hud);
 835                 info.vr_crosshair(info, this);
 836         }
 837 }
 838
 839 vector damage_blurpostprocess, content_blurpostprocess;
 840
 841 float unaccounted_damage = 0;
 842 void UpdateDamage()
 843 {
 844         // accumulate damage with each stat update
 845         static float damage_total_prev = 0;
 846         float damage_total = STAT(DAMAGE_DEALT_TOTAL);
 847         float unaccounted_damage_new = COMPARE_INCREASING(damage_total, damage_total_prev);
 848         damage_total_prev = damage_total;
 849
 850         static float damage_dealt_time_prev = 0;
 851         float damage_dealt_time = STAT(HIT_TIME);
 852         if (damage_dealt_time != damage_dealt_time_prev)
 853         {
 854                 unaccounted_damage += unaccounted_damage_new;
 855                 LOG_TRACE("dmg total: ", ftos(unaccounted_damage), " (+", ftos(unaccounted_damage_new), ")");
 856         }
 857         damage_dealt_time_prev = damage_dealt_time;
 858
 859         // prevent hitsound when switching spectatee
 860         static float spectatee_status_prev = 0;
 861         if (spectatee_status != spectatee_status_prev)
 862                 unaccounted_damage = 0;
 863         spectatee_status_prev = spectatee_status;
 864 }
 865
 866 void HitSound()
 867 {
 868         // varying sound pitch
 869
 870         bool have_arc = false;
 871         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 872         {
 873                 entity wepent = viewmodels[slot];
 874
 875                 if(wepent.activeweapon == WEP_ARC)
 876                         have_arc = true;
 877         }
 878
 879         static float hitsound_time_prev = 0;
 880         // HACK: the only way to get the arc to sound consistent with pitch shift is to ignore cl_hitsound_antispam_time
 881         bool arc_hack = have_arc && autocvar_cl_hitsound >= 2;
 882         if (arc_hack || COMPARE_INCREASING(time, hitsound_time_prev) > autocvar_cl_hitsound_antispam_time)
 883         {
 884                 if (autocvar_cl_hitsound && unaccounted_damage)
 885                 {
 886                         // customizable gradient function that crosses (0,a), (c,1) and asymptotically approaches b
 887                         float a = autocvar_cl_hitsound_max_pitch;
 888                         float b = autocvar_cl_hitsound_min_pitch;
 889                         float c = autocvar_cl_hitsound_nom_damage;
 890                         float d = unaccounted_damage;
 891                         float pitch_shift = (b*d*(a-1) + a*c*(1-b)) / (d*(a-1) + c*(1-b));
 892
 893                         // if sound variation is disabled, set pitch_shift to 1
 894                         if (autocvar_cl_hitsound == 1)
 895                                 pitch_shift = 1;
 896
 897                         // if pitch shift is reversed, mirror in (max-min)/2 + min
 898                         if (autocvar_cl_hitsound == 3)
 899                         {
 900                                 float mirror_value = (a-b)/2 + b;
 901                                 pitch_shift = mirror_value + (mirror_value - pitch_shift);
 902                         }
 903
 904                         LOG_TRACE("dmg total (dmg): ", ftos(unaccounted_damage), " , pitch shift: ", ftos(pitch_shift));
 905
 906                         // todo: avoid very long and very short sounds from wave stretching using different sound files? seems unnecessary
 907                         // todo: normalize sound pressure levels? seems unnecessary
 908
 909                         sound7(NULL, CH_INFO, SND(HIT), VOL_BASE, ATTN_NONE, pitch_shift * 100, 0);
 910                 }
 911                 unaccounted_damage = 0;
 912                 hitsound_time_prev = time;
 913         }
 914
 915         static float typehit_time_prev = 0;
 916         float typehit_time = STAT(TYPEHIT_TIME);
 917         if (COMPARE_INCREASING(typehit_time, typehit_time_prev) > autocvar_cl_hitsound_antispam_time)
 918         {
 919                 sound(NULL, CH_INFO, SND_TYPEHIT, VOL_BASE, ATTN_NONE);
 920                 typehit_time_prev = typehit_time;
 921         }
 922
 923         static float kill_time_prev = 0;
 924         float kill_time = STAT(KILL_TIME);
 925         if (COMPARE_INCREASING(kill_time, kill_time_prev) > autocvar_cl_hitsound_antispam_time)
 926         {
 927                 sound(NULL, CH_INFO, SND_KILL, VOL_BASE, ATTN_NONE);
 928                 kill_time_prev = kill_time;
 929         }
 930 }
 931
 932 vector crosshair_getcolor(entity this, float health_stat)
 933 {
 934         static float rainbow_last_flicker;
 935         static vector rainbow_prev_color;
 936         vector wcross_color = '0 0 0';
 937         switch(autocvar_crosshair_color_special)
 938         {
 939                 case 1: // crosshair_color_per_weapon
 940                 {
 941                         if(this != WEP_Null && hud == HUD_NORMAL)
 942                         {
 943                                 wcross_color = this.wpcolor;
 944                                 break;
 945                         }
 946                         else { goto normalcolor; }
 947                 }
 948
 949                 case 2: // crosshair_color_by_health
 950                 {
 951                         vector v = healtharmor_maxdamage(health_stat, STAT(ARMOR), armorblockpercent, DEATH_WEAPON.m_id);
 952                         float hp = floor(v.x + 1);
 953
 954                         //x = red
 955                         //y = green
 956                         //z = blue
 957
 958                         wcross_color.z = 0;
 959
 960                         if(hp > 200)
 961                         {
 962                                 wcross_color.x = 0;
 963                                 wcross_color.y = 1;
 964                         }
 965                         else if(hp > 150)
 966                         {
 967                                 wcross_color.x = 0.4 - (hp-150)*0.02 * 0.4;
 968                                 wcross_color.y = 0.9 + (hp-150)*0.02 * 0.1;
 969                         }
 970                         else if(hp > 100)
 971                         {
 972                                 wcross_color.x = 1 - (hp-100)*0.02 * 0.6;
 973                                 wcross_color.y = 1 - (hp-100)*0.02 * 0.1;
 974                                 wcross_color.z = 1 - (hp-100)*0.02;
 975                         }
 976                         else if(hp > 50)
 977                         {
 978                                 wcross_color.x = 1;
 979                                 wcross_color.y = 1;
 980                                 wcross_color.z = 0.2 + (hp-50)*0.02 * 0.8;
 981                         }
 982                         else if(hp > 20)
 983                         {
 984                                 wcross_color.x = 1;
 985                                 wcross_color.y = (hp-20)*90/27/100;
 986                                 wcross_color.z = (hp-20)*90/27/100 * 0.2;
 987                         }
 988                         else
 989                         {
 990                                 wcross_color.x = 1;
 991                                 wcross_color.y = 0;
 992                         }
 993                         break;
 994                 }
 995
 996                 case 3: // crosshair_color_rainbow
 997                 {
 998                         if(time >= rainbow_last_flicker)
 999                         {
1000                                 rainbow_prev_color = randomvec() * autocvar_crosshair_color_special_rainbow_brightness;
1001                                 rainbow_last_flicker = time + autocvar_crosshair_color_special_rainbow_delay;
1002                         }
1003                         wcross_color = rainbow_prev_color;
1004                         break;
1005                 }
1006 LABEL(normalcolor)
1007                 default: { wcross_color = stov(autocvar_crosshair_color); break; }
1008         }
1009
1010         return wcross_color;
1011 }
1012
1013 void HUD_Crosshair(entity this)
1014 {
1015         float f, i, j;
1016         vector v;
1017         if(!scoreboard_active && !camera_active && intermission != 2 && !STAT(GAME_STOPPED) &&
1018                 spectatee_status != -1 && (!csqcplayer.viewloc || (!spectatee_status && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))) && !MUTATOR_CALLHOOK(DrawCrosshair) &&
1019                 !HUD_MinigameMenu_IsOpened() )
1020         {
1021                 if (!autocvar_crosshair_enabled) // main toggle for crosshair rendering
1022                         return;
1023
1024                 if (spectatee_status > 0 && STAT(CAMERA_SPECTATOR) == 2)
1025                         return;
1026
1027                 if (hud != HUD_NORMAL)
1028                 {
1029                         HUD_Crosshair_Vehicle(this);
1030                         return;
1031                 }
1032
1033                 string wcross_style;
1034                 float wcross_alpha, wcross_resolution;
1035                 wcross_style = autocvar_crosshair;
1036                 if (csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM) && autocvar_crosshair_2d != "")
1037                         wcross_style = autocvar_crosshair_2d;
1038                 if (wcross_style == "0")
1039                         return;
1040                 wcross_resolution = autocvar_crosshair_size;
1041                 if (wcross_resolution == 0)
1042                         return;
1043                 wcross_alpha = autocvar_crosshair_alpha;
1044                 if (wcross_alpha == 0)
1045                         return;
1046
1047                 // TrueAim check
1048                 float shottype;
1049
1050                 // wcross_origin = '0.5 0 0' * vid_conwidth + '0 0.5 0' * vid_conheight;
1051                 if(csqcplayer.viewloc && (csqcplayer.viewloc.spawnflags & VIEWLOC_FREEAIM))
1052                         wcross_origin = viewloc_mousepos;
1053                 else
1054                         wcross_origin = project_3d_to_2d(view_origin + max_shot_distance * view_forward);
1055                 wcross_origin.z = 0;
1056                 if(autocvar_crosshair_hittest)
1057                 {
1058                         vector wcross_oldorigin;
1059                         entity thiswep = viewmodels[0]; // TODO: unhardcode
1060                         wcross_oldorigin = wcross_origin;
1061                         shottype = TrueAimCheck(thiswep);
1062                         if(shottype == SHOTTYPE_HITWORLD)
1063                         {
1064                                 v = wcross_origin - wcross_oldorigin;
1065                                 v.x /= vid_conwidth;
1066                                 v.y /= vid_conheight;
1067                                 if(vdist(v, >, 0.01))
1068                                         shottype = SHOTTYPE_HITOBSTRUCTION;
1069                         }
1070                         if(!autocvar_crosshair_hittest_showimpact)
1071                                 wcross_origin = wcross_oldorigin;
1072                 }
1073                 else
1074                         shottype = SHOTTYPE_HITWORLD;
1075
1076                 vector wcross_color = '0 0 0', wcross_size = '0 0 0';
1077                 string wcross_name = "";
1078                 float wcross_scale, wcross_blur;
1079
1080         entity e = WEP_Null;
1081                 if(autocvar_crosshair_per_weapon || (autocvar_crosshair_color_special == 1))
1082                 {
1083                         entity wepent = viewmodels[0]; // TODO: unhardcode
1084                         e = wepent.switchingweapon;
1085                         if(e)
1086                         {
1087                                 if(autocvar_crosshair_per_weapon)
1088                                 {
1089                                         // WEAPONTODO: access these through some general settings (with non-balance config settings)
1090                                         //wcross_resolution *= cvar(strcat("crosshair_", wcross_wep, "_size"));
1091                                         //if (wcross_resolution == 0)
1092                                                 //return;
1093
1094                                         //wcross_style = cvar_string(strcat("crosshair_", wcross_wep));
1095                                         wcross_resolution *= e.w_crosshair_size;
1096                                         wcross_name = e.w_crosshair;
1097                                 }
1098                         }
1099                 }
1100
1101                 if(wcross_name == "")
1102                         wcross_name = strcat("gfx/crosshair", wcross_style);
1103
1104                 // MAIN CROSSHAIR COLOR DECISION
1105                 wcross_color = crosshair_getcolor(e, STAT(HEALTH));
1106
1107                 if(autocvar_crosshair_effect_scalefade)
1108                 {
1109                         wcross_scale = wcross_resolution;
1110                         wcross_resolution = 1;
1111                 }
1112                 else
1113                 {
1114                         wcross_scale = 1;
1115                 }
1116
1117                 if(autocvar_crosshair_pickup)
1118                 {
1119                         float stat_pickup_time = STAT(LAST_PICKUP);
1120
1121                         if(pickup_crosshair_time < stat_pickup_time)
1122                         {
1123                                 if(time - stat_pickup_time < MAX_TIME_DIFF) // don't trigger the animation if it's too old
1124                                         pickup_crosshair_size = 1;
1125
1126                                 pickup_crosshair_time = stat_pickup_time;
1127                         }
1128
1129                         if(pickup_crosshair_size > 0)
1130                                 pickup_crosshair_size -= autocvar_crosshair_pickup_speed * frametime;
1131                         else
1132                                 pickup_crosshair_size = 0;
1133
1134                         wcross_scale += sin(pickup_crosshair_size) * autocvar_crosshair_pickup;
1135                 }
1136
1137                 // todo: make crosshair hit indication dependent on damage dealt
1138                 if(autocvar_crosshair_hitindication)
1139                 {
1140                         vector hitindication_color = ((autocvar_crosshair_color_special == 1) ? stov(autocvar_crosshair_hitindication_per_weapon_color) : stov(autocvar_crosshair_hitindication_color));
1141
1142                         if(unaccounted_damage)
1143                         {
1144                                 hitindication_crosshair_size = 1;
1145                         }
1146
1147                         if(hitindication_crosshair_size > 0)
1148                                 hitindication_crosshair_size -= autocvar_crosshair_hitindication_speed * frametime;
1149                         else
1150                                 hitindication_crosshair_size = 0;
1151
1152                         wcross_scale += sin(hitindication_crosshair_size) * autocvar_crosshair_hitindication;
1153                         wcross_color.x += sin(hitindication_crosshair_size) * hitindication_color.x;
1154                         wcross_color.y += sin(hitindication_crosshair_size) * hitindication_color.y;
1155                         wcross_color.z += sin(hitindication_crosshair_size) * hitindication_color.z;
1156                 }
1157
1158                 if(shottype == SHOTTYPE_HITENEMY)
1159                         wcross_scale *= autocvar_crosshair_hittest; // is not queried if hittest is 0
1160                 if(shottype == SHOTTYPE_HITTEAM)
1161                         wcross_scale /= autocvar_crosshair_hittest; // is not queried if hittest is 0
1162
1163                 f = fabs(autocvar_crosshair_effect_time);
1164                 if(wcross_scale != wcross_scale_goal_prev || wcross_alpha != wcross_alpha_goal_prev || wcross_color != wcross_color_goal_prev)
1165                 {
1166                         wcross_changedonetime = time + f;
1167                 }
1168                 if(wcross_name != wcross_name_goal_prev || wcross_resolution != wcross_resolution_goal_prev)
1169                 {
1170                         wcross_name_changestarttime = time;
1171                         wcross_name_changedonetime = time + f;
1172                         if(wcross_name_goal_prev_prev)
1173                                 strunzone(wcross_name_goal_prev_prev);
1174                         wcross_name_goal_prev_prev = wcross_name_goal_prev;
1175                         wcross_name_goal_prev = strzone(wcross_name);
1176                         wcross_name_alpha_goal_prev_prev = wcross_name_alpha_goal_prev;
1177                         wcross_resolution_goal_prev_prev = wcross_resolution_goal_prev;
1178                         wcross_resolution_goal_prev = wcross_resolution;
1179                 }
1180
1181                 wcross_scale_goal_prev = wcross_scale;
1182                 wcross_alpha_goal_prev = wcross_alpha;
1183                 wcross_color_goal_prev = wcross_color;
1184
1185                 if(spectatee_status == -1 && shottype == SHOTTYPE_HITTEAM || (shottype == SHOTTYPE_HITOBSTRUCTION && autocvar_crosshair_hittest_blur && !autocvar_chase_active))
1186                 {
1187                         wcross_blur = 1;
1188                         wcross_alpha *= 0.75;
1189                 }
1190                 else
1191                         wcross_blur = 0;
1192                 // *_prev is at time-frametime
1193                 // * is at wcross_changedonetime+f
1194                 // what do we have at time?
1195                 if(time < wcross_changedonetime)
1196                 {
1197                         f = frametime / (wcross_changedonetime - time + frametime);
1198                         wcross_scale = f * wcross_scale + (1 - f) * wcross_scale_prev;
1199                         wcross_alpha = f * wcross_alpha + (1 - f) * wcross_alpha_prev;
1200                         wcross_color = f * wcross_color + (1 - f) * wcross_color_prev;
1201                 }
1202
1203                 wcross_scale_prev = wcross_scale;
1204                 wcross_alpha_prev = wcross_alpha;
1205                 wcross_color_prev = wcross_color;
1206
1207                 MUTATOR_CALLHOOK(UpdateCrosshair);
1208
1209                 wcross_scale *= 1 - autocvar__menu_alpha;
1210                 wcross_alpha *= 1 - autocvar__menu_alpha;
1211                 wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1212
1213                 if(wcross_scale >= 0.001 && wcross_alpha >= 0.001)
1214                 {
1215                         // crosshair rings for weapon stats
1216                         if (autocvar_crosshair_ring || autocvar_crosshair_ring_reload)
1217                         {
1218                                 // declarations and stats
1219                                 float ring_value = 0, ring_scale = 0, ring_alpha = 0, ring_inner_value = 0, ring_inner_alpha = 0;
1220                                 string ring_image = string_null, ring_inner_image = string_null;
1221                                 vector ring_rgb = '0 0 0', ring_inner_rgb = '0 0 0';
1222
1223                                 ring_scale = autocvar_crosshair_ring_size;
1224
1225                                 entity wepent = viewmodels[0]; // TODO: unhardcode
1226
1227                                 int weapon_clipload = wepent.clip_load;
1228                                 int weapon_clipsize = wepent.clip_size;
1229
1230                                 float arc_heat = wepent.arc_heat_percent;
1231                                 float vcharge = wepent.vortex_charge;
1232                                 float vchargepool = wepent.vortex_chargepool_ammo;
1233                                 float oknex_charge_ = wepent.oknex_charge;
1234                                 float oknex_chargepool_ = wepent.oknex_chargepool_ammo;
1235
1236                                 if(vortex_charge_movingavg == 0) // this should only happen if we have just loaded up the game
1237                                         vortex_charge_movingavg = vcharge;
1238
1239                                 // handle the values
1240                                 if (autocvar_crosshair_ring && wepent.activeweapon == WEP_VORTEX && vcharge && autocvar_crosshair_ring_vortex) // ring around crosshair representing velocity-dependent damage for the vortex
1241                                 {
1242                                         if (vchargepool || use_vortex_chargepool) {
1243                                                 use_vortex_chargepool = 1;
1244                                                 ring_inner_value = vchargepool;
1245                                         } else {
1246                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * vcharge;
1247                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (vcharge - vortex_charge_movingavg), 1);
1248                                         }
1249
1250                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1251                                         ring_inner_rgb = vec3(autocvar_crosshair_ring_vortex_inner_color_red, autocvar_crosshair_ring_vortex_inner_color_green, autocvar_crosshair_ring_vortex_inner_color_blue);
1252                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1253
1254                                         // draw the outer ring to show the current charge of the weapon
1255                                         ring_value = vcharge;
1256                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1257                                         ring_rgb = wcross_color;
1258                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1259                                 }
1260                                 else if (autocvar_crosshair_ring && (wepent.activeweapon == WEP_OVERKILL_NEX) && oknex_charge_ && autocvar_crosshair_ring_vortex)
1261                                 {
1262                                         if (oknex_chargepool_ || use_vortex_chargepool) {
1263                                                 use_vortex_chargepool = 1;
1264                                                 ring_inner_value = oknex_chargepool_;
1265                                         } else {
1266                                                 vortex_charge_movingavg = (1 - autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate) * vortex_charge_movingavg + autocvar_crosshair_ring_vortex_currentcharge_movingavg_rate * oknex_charge_;
1267                                                 ring_inner_value = bound(0, autocvar_crosshair_ring_vortex_currentcharge_scale * (oknex_charge_ - vortex_charge_movingavg), 1);
1268                                         }
1269
1270                                         ring_inner_alpha = autocvar_crosshair_ring_vortex_inner_alpha;
1271                                         ring_inner_rgb = eX * autocvar_crosshair_ring_vortex_inner_color_red + eY * autocvar_crosshair_ring_vortex_inner_color_green + eZ * autocvar_crosshair_ring_vortex_inner_color_blue;
1272                                         ring_inner_image = "gfx/crosshair_ring_inner.tga";
1273
1274                                         // draw the outer ring to show the current charge of the weapon
1275                                         ring_value = oknex_charge_;
1276                                         ring_alpha = autocvar_crosshair_ring_vortex_alpha;
1277                                         ring_rgb = wcross_color;
1278                                         ring_image = "gfx/crosshair_ring_nexgun.tga";
1279                                 }
1280                                 else if (autocvar_crosshair_ring && wepent.activeweapon == WEP_MINE_LAYER && WEP_CVAR(minelayer, limit) && autocvar_crosshair_ring_minelayer)
1281                                 {
1282                                         ring_value = bound(0, wepent.minelayer_mines / WEP_CVAR(minelayer, limit), 1); // if you later need to use the count of bullets in another place, then add a float for it. For now, no need to.
1283                                         ring_alpha = autocvar_crosshair_ring_minelayer_alpha;
1284                                         ring_rgb = wcross_color;
1285                                         ring_image = "gfx/crosshair_ring.tga";
1286                                 }
1287                                 else if (wepent.activeweapon == WEP_HAGAR && wepent.hagar_load && autocvar_crosshair_ring_hagar)
1288                                 {
1289                                         ring_value = bound(0, wepent.hagar_load / WEP_CVAR_SEC(hagar, load_max), 1);
1290                                         ring_alpha = autocvar_crosshair_ring_hagar_alpha;
1291                                         ring_rgb = wcross_color;
1292                                         ring_image = "gfx/crosshair_ring.tga";
1293                                 }
1294                                 else if(autocvar_crosshair_ring_reload && weapon_clipsize) // forces there to be only an ammo ring
1295                                 {
1296                                         ring_value = bound(0, weapon_clipload / weapon_clipsize, 1);
1297                                         ring_scale = autocvar_crosshair_ring_reload_size;
1298                                         ring_alpha = autocvar_crosshair_ring_reload_alpha;
1299                                         ring_rgb = wcross_color;
1300
1301                                         // Note: This is to stop Taoki from complaining that the image doesn't match all potential balances.
1302                                         // if a new image for another weapon is added, add the code (and its respective file/value) here
1303                                         if ((wepent.activeweapon == WEP_RIFLE) && (weapon_clipsize == 80))
1304                                                 ring_image = "gfx/crosshair_ring_rifle.tga";
1305                                         else
1306                                                 ring_image = "gfx/crosshair_ring.tga";
1307                                 }
1308                                 else if ( autocvar_crosshair_ring && autocvar_crosshair_ring_arc && arc_heat && wepent.activeweapon == WEP_ARC )
1309                                 {
1310                                         ring_value = arc_heat;
1311                                         ring_alpha = (1-arc_heat)*autocvar_crosshair_ring_arc_cold_alpha +
1312                                                 arc_heat*autocvar_crosshair_ring_arc_hot_alpha;
1313                                         ring_rgb = (1-arc_heat)*wcross_color + arc_heat*autocvar_crosshair_ring_arc_hot_color;
1314                                         ring_image = "gfx/crosshair_ring.tga";
1315                                 }
1316
1317                                 // if in weapon switch animation, fade ring out/in
1318                                 if(autocvar_crosshair_effect_time > 0)
1319                                 {
1320                                         f = (time - wcross_name_changestarttime) / autocvar_crosshair_effect_time;
1321                                         if (f >= 1)
1322                                         {
1323                                                 wcross_ring_prev = ((ring_image) ? true : false);
1324                                         }
1325
1326                                         if(wcross_ring_prev)
1327                                         {
1328                                                 if(f < 1)
1329                                                         ring_alpha *= fabs(1 - bound(0, f, 1));
1330                                         }
1331                                         else
1332                                         {
1333                                                 if(f < 1)
1334                                                         ring_alpha *= bound(0, f, 1);
1335                                         }
1336                                 }
1337
1338                                 if (autocvar_crosshair_ring_inner && ring_inner_value) // lets draw a ring inside a ring so you can ring while you ring
1339                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_inner_image, ring_inner_value, ring_inner_rgb, wcross_alpha * ring_inner_alpha, DRAWFLAG_ADDITIVE);
1340
1341                                 if (ring_value)
1342                                         DrawCircleClippedPic(wcross_origin, wcross_size.x * ring_scale, ring_image, ring_value, ring_rgb, wcross_alpha * ring_alpha, DRAWFLAG_ADDITIVE);
1343                         }
1344
1345 #define CROSSHAIR_DO_BLUR(M,sz,wcross_name,wcross_alpha) \
1346                         MACRO_BEGIN { \
1347                                 if(wcross_blur > 0) \
1348                                 { \
1349                                         for(i = -2; i <= 2; ++i) \
1350                                         for(j = -2; j <= 2; ++j) \
1351                                         M(i,j,sz,wcross_name,wcross_alpha*0.04); \
1352                                 } \
1353                                 else \
1354                                 { \
1355                                         M(0,0,sz,wcross_name,wcross_alpha); \
1356                                 } \
1357                         } MACRO_END
1358
1359 #define CROSSHAIR_DRAW_SINGLE(i,j,sz,wcross_name,wcross_alpha) \
1360                         drawpic(wcross_origin - ('0.5 0 0' * (sz * wcross_size.x + i * wcross_blur) + '0 0.5 0' * (sz * wcross_size.y + j * wcross_blur)), wcross_name, sz * wcross_size, wcross_color, wcross_alpha, DRAWFLAG_NORMAL)
1361
1362 #define CROSSHAIR_DRAW(sz,wcross_name,wcross_alpha) \
1363                         CROSSHAIR_DO_BLUR(CROSSHAIR_DRAW_SINGLE,sz,wcross_name,wcross_alpha)
1364
1365                         if(time < wcross_name_changedonetime && wcross_name != wcross_name_goal_prev_prev && wcross_name_goal_prev_prev)
1366                         {
1367                                 f = (wcross_name_changedonetime - time) / (wcross_name_changedonetime - wcross_name_changestarttime);
1368                                 wcross_size = draw_getimagesize(wcross_name_goal_prev_prev) * wcross_scale;
1369                                 CROSSHAIR_DRAW(wcross_resolution_goal_prev_prev, wcross_name_goal_prev_prev, wcross_alpha * f * wcross_name_alpha_goal_prev_prev);
1370                                 f = 1 - f;
1371                         }
1372                         else
1373                         {
1374                                 f = 1;
1375                         }
1376                         wcross_name_alpha_goal_prev = f;
1377
1378                         wcross_size = draw_getimagesize(wcross_name) * wcross_scale;
1379                         CROSSHAIR_DRAW(wcross_resolution, wcross_name, wcross_alpha * f);
1380
1381                         if(autocvar_crosshair_dot)
1382                         {
1383                                 vector wcross_color_old;
1384                                 wcross_color_old = wcross_color;
1385
1386                                 if((autocvar_crosshair_dot_color_custom) && (autocvar_crosshair_dot_color != "0"))
1387                                         wcross_color = stov(autocvar_crosshair_dot_color);
1388
1389                                 CROSSHAIR_DRAW(wcross_resolution * autocvar_crosshair_dot_size, "gfx/crosshairdot.tga", f * autocvar_crosshair_dot_alpha);
1390                                 // FIXME why don't we use wcross_alpha here?
1391                                 wcross_color = wcross_color_old;
1392                         }
1393                 }
1394         }
1395         else
1396         {
1397                 wcross_scale_prev = 0;
1398                 wcross_alpha_prev = 0;
1399                 wcross_scale_goal_prev = 0;
1400                 wcross_alpha_goal_prev = 0;
1401                 wcross_changedonetime = 0;
1402                 strfree(wcross_name_goal_prev);
1403                 strfree(wcross_name_goal_prev_prev);
1404                 wcross_name_changestarttime = 0;
1405                 wcross_name_changedonetime = 0;
1406                 wcross_name_alpha_goal_prev = 0;
1407                 wcross_name_alpha_goal_prev_prev = 0;
1408                 wcross_resolution_goal_prev = 0;
1409                 wcross_resolution_goal_prev_prev = 0;
1410         }
1411 }
1412
1413 const int MAX_SPECIALCOMMAND = 15;
1414 vector specialcommand_slots[MAX_SPECIALCOMMAND];
1415 vector specialcommand_colors[MAX_SPECIALCOMMAND];
1416 const float SPECIALCOMMAND_SPEED = 150;
1417 const float SPECIALCOMMAND_TURNSPEED = 2;
1418 const float SPECIALCOMMAND_SIZE = 0.025;
1419 const float SPECIALCOMMAND_CHANCE = 0.35;
1420 float sc_spawntime, sc_changetime;
1421 vector sc_color = '1 1 1';
1422 void SpecialCommand()
1423 {
1424         if(!STAT(MOVEVARS_SPECIALCOMMAND))
1425                 return;
1426
1427         if(time >= sc_changetime)
1428         {
1429                 sc_changetime = time + 1;
1430                 sc_color = randomvec() * 1.5;
1431                 sc_color.x = bound(0.2, sc_color.x, 0.75);
1432                 sc_color.y = bound(0.2, sc_color.y, 0.75);
1433                 sc_color.z = bound(0.2, sc_color.z, 0.75);
1434         }
1435         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), sc_color, autocvar_hud_colorflash_alpha * bound(0.1, sc_changetime - time, 0.3), DRAWFLAG_ADDITIVE);
1436
1437         if(!precache_pic("gfx/smile"))
1438                 return; // damn party poopers
1439
1440         for(int j = MAX_SPECIALCOMMAND - 1; j >= 0; --j)
1441         {
1442                 vector slot = specialcommand_slots[j];
1443                 if(slot.y)
1444                         slot.y += SPECIALCOMMAND_SPEED * frametime;
1445                 //if(slot.z)
1446                         //slot.z = sin(SPECIALCOMMAND_TURNSPEED * M_PI * time);
1447                 if(slot.y >= vid_conheight)
1448                         slot = '0 0 0';
1449
1450                 if(slot == '0 0 0')
1451                 {
1452                         if(random() <= SPECIALCOMMAND_CHANCE && time > sc_spawntime) // low chance to spawn!
1453                         {
1454                                 slot.x = bound(0, (random() * vid_conwidth + 1), vid_conwidth);
1455                                 slot.y = 1; // start it off 0 so we can use it
1456                                 slot.z = floor(random() * Weapons_MAX);
1457                                 sc_spawntime = time + bound(0.4, random(), 0.75); // prevent spawning another one for this amount of time!
1458                                 vector newcolor = randomvec() * 2;
1459                                 newcolor.x = bound(0.4, newcolor.x, 1);
1460                                 newcolor.y = bound(0.4, newcolor.y, 1);
1461                                 newcolor.z = bound(0.4, newcolor.z, 1);
1462                                 specialcommand_colors[j] = newcolor;
1463                         }
1464                 }
1465                 else
1466                 {
1467                         vector splash_size = '0 0 0';
1468                         splash_size.x = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1469                         splash_size.y = max(vid_conwidth, vid_conheight) * SPECIALCOMMAND_SIZE;
1470                         entity wep = Weapons_from(slot.z);
1471                         if(wep == WEP_Null)
1472                                 drawpic(vec2(slot), "gfx/smile", vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1473                         else
1474                                 drawpic_skin(vec2(slot), wep.model2, vec2(splash_size), specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1475                         //drawrotpic(vec2(slot), slot.z, "gfx/smile", vec2(splash_size), vec2(splash_size) / 2, specialcommand_colors[j], 0.95, DRAWFLAG_NORMAL);
1476                 }
1477
1478                 specialcommand_slots[j] = slot;
1479         }
1480 }
1481
1482 void HUD_Draw(entity this)
1483 {
1484         // if we don't know gametype and scores yet avoid drawing the scoreboard
1485         // also in the very first frames, player state may be inconsistent so avoid drawing the hud at all
1486         // e.g. since initial player's health is 0 hud would display the hud_damage effect,
1487         // cl_deathscoreboard would show the scoreboard and so on
1488         if(!gametype)
1489                 return;
1490
1491         Hud_Dynamic_Frame();
1492
1493         if(!intermission)
1494         if (MUTATOR_CALLHOOK(HUD_Draw_overlay))
1495         {
1496                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), M_ARGV(0, vector), autocvar_hud_colorflash_alpha * M_ARGV(1, float), DRAWFLAG_ADDITIVE);
1497         }
1498         else if(STAT(FROZEN))
1499         {
1500                 vector col = '0.25 0.90 1';
1501                 if(STAT(REVIVE_PROGRESS))
1502                         col += vec3(STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS), -STAT(REVIVE_PROGRESS));
1503                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1504         }
1505
1506         HUD_Scale_Enable();
1507         if(!intermission)
1508         if(STAT(NADE_TIMER) && autocvar_cl_nade_timer) // give nade top priority, as it's a matter of life and death
1509         {
1510                 vector col = '0.25 0.90 1' + vec3(STAT(NADE_TIMER), -STAT(NADE_TIMER), -STAT(NADE_TIMER));
1511                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(NADE_TIMER), col, autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1512                 drawstring_aspect(eY * 0.64 * vid_conheight, ((autocvar_cl_nade_timer == 2) ? _("Nade timer") : ""), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1513         }
1514         else if(STAT(CAPTURE_PROGRESS))
1515         {
1516                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(CAPTURE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1517                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Capture progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1518         }
1519         else if(STAT(REVIVE_PROGRESS))
1520         {
1521                 DrawCircleClippedPic(vec2(0.5 * vid_conwidth, 0.6 * vid_conheight), 0.1 * vid_conheight, "gfx/crosshair_ring.tga", STAT(REVIVE_PROGRESS), '0.25 0.90 1', autocvar_hud_colorflash_alpha, DRAWFLAG_ADDITIVE);
1522                 drawstring_aspect(eY * 0.64 * vid_conheight, _("Revival progress"), vec2(vid_conwidth, 0.025 * vid_conheight), '1 1 1', 1, DRAWFLAG_NORMAL);
1523         }
1524         HUD_Scale_Disable();
1525
1526         if(autocvar_r_letterbox == 0)
1527                 if(autocvar_viewsize < 120)
1528                 {
1529                         if(!(gametype == MAPINFO_TYPE_RACE || gametype == MAPINFO_TYPE_CTS))
1530                                 Accuracy_LoadLevels();
1531
1532                         HUD_Main();
1533                         HUD_Scale_Disable();
1534                 }
1535
1536         // crosshair goes VERY LAST
1537         SpecialCommand();
1538         UpdateDamage();
1539         HUD_Crosshair(this);
1540         HitSound();
1541 }
1542
1543 void ViewLocation_Mouse()
1544 {
1545         if(spectatee_status)
1546                 return; // don't draw it as spectator!
1547
1548         viewloc_mousepos += getmousepos() * autocvar_menu_mouse_speed;
1549         viewloc_mousepos.x = bound(0, viewloc_mousepos.x, vid_conwidth);
1550         viewloc_mousepos.y = bound(0, viewloc_mousepos.y, vid_conheight);
1551
1552         //float cursor_alpha = 1 - autocvar__menu_alpha;
1553         //draw_cursor(viewloc_mousepos, '0.5 0.5 0', "/cursor_move", '1 1 1', cursor_alpha);
1554 }
1555
1556 bool ov_enabled;
1557 float oldr_nearclip;
1558 float oldr_farclip_base;
1559 float oldr_farclip_world;
1560 float oldr_novis;
1561 float oldr_useportalculling;
1562 float oldr_useinfinitefarclip;
1563
1564 void cl_notice_run();
1565
1566 float prev_myteam;
1567 int lasthud;
1568 float vh_notice_time;
1569 void WaypointSprite_Load();
1570 void CSQC_UpdateView(entity this, float w, float h)
1571 {
1572     TC(int, w); TC(int, h);
1573         entity e;
1574         float fov;
1575         float f;
1576         vector vf_size, vf_min;
1577         float a;
1578
1579         execute_next_frame();
1580
1581         ++framecount;
1582
1583         stats_get();
1584         hud = STAT(HUD);
1585
1586         if(hud != HUD_NORMAL && lasthud == HUD_NORMAL)
1587                 vh_notice_time = time + autocvar_cl_vehicles_notify_time;
1588
1589         lasthud = hud;
1590
1591         HUD_Scale_Disable();
1592
1593         if(autocvar__hud_showbinds_reload) // menu can set this one
1594         {
1595                 db_close(binddb);
1596                 binddb = db_create();
1597                 cvar_set("_hud_showbinds_reload", "0");
1598         }
1599
1600         if(checkextension("DP_CSQC_MINFPS_QUALITY"))
1601                 view_quality = getproperty(VF_MINFPS_QUALITY);
1602         else
1603                 view_quality = 1;
1604
1605         button_attack2 = PHYS_INPUT_BUTTON_ATCK2(this);
1606         button_zoom = PHYS_INPUT_BUTTON_ZOOM(this);
1607
1608         vf_size = getpropertyvec(VF_SIZE);
1609         vf_min = getpropertyvec(VF_MIN);
1610         vid_width = vf_size.x;
1611         vid_height = vf_size.y;
1612
1613         vector reticle_pos = '0 0 0', reticle_size = '0 0 0';
1614         vector splash_pos = '0 0 0', splash_size = '0 0 0';
1615
1616         WaypointSprite_Load();
1617
1618         CSQCPlayer_SetCamera();
1619
1620         if(player_localentnum <= maxclients) // is it a client?
1621                 current_player = player_localentnum - 1;
1622         else // then player_localentnum is the vehicle I'm driving
1623                 current_player = player_localnum;
1624         myteam = entcs_GetTeam(current_player);
1625
1626         if(myteam != prev_myteam)
1627         {
1628                 myteamcolors = colormapPaletteColor(myteam, 1);
1629                 FOREACH(hud_panels, true, it.update_time = time);
1630                 prev_myteam = myteam;
1631         }
1632
1633         ticrate = STAT(MOVEVARS_TICRATE) * STAT(MOVEVARS_TIMESCALE);
1634
1635         float is_dead = (STAT(HEALTH) <= 0);
1636
1637         // FIXME do we need this hack?
1638         if(isdemo())
1639         {
1640                 // in demos, input_buttons do not work
1641                 button_zoom = (autocvar__togglezoom == "-");
1642         }
1643         else if(button_zoom
1644                 && autocvar_cl_unpress_zoom_on_death
1645                 && (spectatee_status >= 0)
1646                 && (is_dead || intermission))
1647         {
1648                 // no zoom while dead or in intermission please
1649                 localcmd("-zoom\n");
1650                 button_zoom = false;
1651         }
1652
1653         // abused multiple places below
1654         entity local_player = ((csqcplayer) ? csqcplayer : CSQCModel_server2csqc(player_localentnum - 1));
1655         if(!local_player)
1656                 local_player = this; // fall back!
1657
1658         // event chase camera
1659         if(autocvar_chase_active <= 0) // greater than 0 means it's enabled manually, and this code is skipped
1660         {
1661                 if(STAT(CAMERA_SPECTATOR))
1662                 {
1663                         if(spectatee_status > 0)
1664                         {
1665                                 if(!autocvar_chase_active)
1666                                 {
1667                                         cvar_set("chase_active", "-2");
1668                                         goto skip_eventchase_death;
1669                                 }
1670                         }
1671                         else if(autocvar_chase_active == -2)
1672                                 cvar_set("chase_active", "0");
1673
1674                         if(autocvar_chase_active == -2)
1675                                 goto skip_eventchase_death;
1676                 }
1677                 else if(autocvar_chase_active == -2)
1678                         cvar_set("chase_active", "0");
1679
1680                 float vehicle_chase = (hud != HUD_NORMAL && (autocvar_cl_eventchase_vehicle || spectatee_status > 0));
1681
1682                 float vehicle_viewdist = 0;
1683                 vector vehicle_viewofs = '0 0 0';
1684
1685                 if(vehicle_chase)
1686                 {
1687                         if(hud != HUD_BUMBLEBEE_GUN)
1688                         {
1689                                 Vehicle info = Vehicles_from(hud);
1690                                 vehicle_viewdist = info.height;
1691                                 vehicle_viewofs = info.view_ofs;
1692                         }
1693                 }
1694
1695                 if(WantEventchase(this))
1696                 {
1697                         vector current_view_origin_override = '0 0 0';
1698                         vector view_offset_override = '0 0 0';
1699                         float chase_distance_override = 0;
1700                         bool custom_eventchase = MUTATOR_CALLHOOK(CustomizeEventchase, this);
1701                         if(custom_eventchase)
1702                         {
1703                                 current_view_origin_override = M_ARGV(0, vector);
1704                                 view_offset_override = M_ARGV(1, vector);
1705                                 chase_distance_override = M_ARGV(0, float);
1706                         }
1707                         eventchase_running = true;
1708
1709                         // make special vector since we can't use view_origin (It is one frame old as of this code, it gets set later with the results this code makes.)
1710                         vector current_view_origin = (csqcplayer ? csqcplayer.origin : pmove_org);
1711                         if (custom_eventchase)
1712                                 current_view_origin = current_view_origin_override;
1713
1714                         // detect maximum viewoffset and use it
1715                         vector view_offset = autocvar_cl_eventchase_viewoffset;
1716                         if(vehicle_chase)
1717                         {
1718                                 if(vehicle_viewofs)
1719                                         view_offset = vehicle_viewofs;
1720                                 else
1721                                         view_offset = autocvar_cl_eventchase_vehicle_viewoffset;
1722                         }
1723                         if (custom_eventchase)
1724                                 view_offset = view_offset_override;
1725
1726                         if(view_offset)
1727                         {
1728                                 WarpZone_TraceLine(current_view_origin, current_view_origin + view_offset + ('0 0 1' * autocvar_cl_eventchase_maxs.z), MOVE_WORLDONLY, this);
1729                                 if(trace_fraction == 1) { current_view_origin += view_offset; }
1730                                 else { current_view_origin.z += max(0, (trace_endpos.z - current_view_origin.z) - autocvar_cl_eventchase_maxs.z); }
1731                         }
1732
1733                         // We must enable chase_active to get a third person view (weapon viewmodel hidden and own player model showing).
1734                         // Ideally, there should be another way to enable third person cameras, such as through setproperty()
1735                         // -1 enables chase_active while marking it as set by this code, and not by the user (which would be 1)
1736                         if(!autocvar_chase_active) { cvar_set("chase_active", "-1"); }
1737
1738                         // make the camera smooth back
1739                         float chase_distance = autocvar_cl_eventchase_distance;
1740                         if(vehicle_chase)
1741                         {
1742                                 if(vehicle_viewofs)
1743                                         chase_distance = vehicle_viewdist;
1744                                 else
1745                                         chase_distance = autocvar_cl_eventchase_vehicle_distance;
1746                         }
1747                         if (custom_eventchase)
1748                                 chase_distance = chase_distance_override;
1749
1750                         if(autocvar_cl_eventchase_speed && eventchase_current_distance < chase_distance)
1751                                 eventchase_current_distance += autocvar_cl_eventchase_speed * (chase_distance - eventchase_current_distance) * frametime; // slow down the further we get
1752                         else if(eventchase_current_distance != chase_distance)
1753                                 eventchase_current_distance = chase_distance;
1754
1755                         makevectors(view_angles);
1756
1757                         vector eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1758                         WarpZone_TraceBox(current_view_origin, autocvar_cl_eventchase_mins, autocvar_cl_eventchase_maxs, eventchase_target_origin, MOVE_WORLDONLY, this);
1759
1760                         // If the boxtrace fails, revert back to line tracing.
1761                         if(!local_player.viewloc)
1762                         if(trace_startsolid)
1763                         {
1764                                 eventchase_target_origin = (current_view_origin - (v_forward * eventchase_current_distance));
1765                                 WarpZone_TraceLine(current_view_origin, eventchase_target_origin, MOVE_WORLDONLY, this);
1766                                 setproperty(VF_ORIGIN, (trace_endpos - (v_forward * autocvar_cl_eventchase_mins.z)));
1767                         }
1768                         else { setproperty(VF_ORIGIN, trace_endpos); }
1769
1770                         if(!local_player.viewloc)
1771                                 setproperty(VF_ANGLES, WarpZone_TransformVAngles(WarpZone_trace_transform, view_angles));
1772                 }
1773                 else if(autocvar_chase_active < 0) // time to disable chase_active if it was set by this code
1774                 {
1775                         eventchase_running = false;
1776                         cvar_set("chase_active", "0");
1777                         eventchase_current_distance = 0; // start from 0 next time
1778                 }
1779         }
1780         // workaround for camera stuck between player's legs when using chase_active 1
1781         // because the engine stops updating the chase_active camera when the game ends
1782         else if(intermission)
1783         {
1784                 cvar_settemp("chase_active", "-1");
1785                 eventchase_current_distance = 0;
1786         }
1787
1788         LABEL(skip_eventchase_death);
1789
1790         // do lockview after event chase camera so that it still applies whenever necessary.
1791         if(autocvar_cl_lockview || (!autocvar_hud_cursormode && (autocvar__hud_configure && spectatee_status <= 0 || intermission > 1 || QuickMenu_IsOpened())))
1792         {
1793                 setproperty(VF_ORIGIN, freeze_org);
1794                 setproperty(VF_ANGLES, freeze_ang);
1795         }
1796         else
1797         {
1798                 freeze_org = getpropertyvec(VF_ORIGIN);
1799                 freeze_ang = getpropertyvec(VF_ANGLES);
1800         }
1801
1802         WarpZone_FixView();
1803         //WarpZone_FixPMove();
1804
1805         vector ov_org = '0 0 0';
1806         vector ov_mid = '0 0 0';
1807         vector ov_worldmin = '0 0 0';
1808         vector ov_worldmax = '0 0 0';
1809         if(autocvar_cl_orthoview)
1810         {
1811                 ov_worldmin = mi_picmin;
1812                 ov_worldmax = mi_picmax;
1813
1814                 float ov_width = (ov_worldmax.x - ov_worldmin.x);
1815                 float ov_height = (ov_worldmax.y - ov_worldmin.y);
1816                 float ov_distance = (max(vid_width, vid_height) * max(ov_width, ov_height));
1817
1818                 ov_mid = ((ov_worldmax + ov_worldmin) * 0.5);
1819                 ov_org = vec3(ov_mid.x, ov_mid.y, (ov_mid.z + ov_distance));
1820
1821                 float ov_nearest = vlen(ov_org - vec3(
1822                         bound(ov_worldmin.x, ov_org.x, ov_worldmax.x),
1823                         bound(ov_worldmin.y, ov_org.y, ov_worldmax.y),
1824                         bound(ov_worldmin.z, ov_org.z, ov_worldmax.z)
1825                 ));
1826
1827                 float ov_furthest = 0;
1828                 float dist = 0;
1829
1830                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1831                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1832                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1833                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1834                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmin.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1835                 if((dist = vdist((vec3(ov_worldmin.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1836                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmin.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1837                 if((dist = vdist((vec3(ov_worldmax.x, ov_worldmax.y, ov_worldmax.z) - ov_org), >, ov_furthest))) { ov_furthest = dist; }
1838
1839                 if(!ov_enabled)
1840                 {
1841                         oldr_nearclip = cvar("r_nearclip");
1842                         oldr_farclip_base = cvar("r_farclip_base");
1843                         oldr_farclip_world = cvar("r_farclip_world");
1844                         oldr_novis = cvar("r_novis");
1845                         oldr_useportalculling = cvar("r_useportalculling");
1846                         oldr_useinfinitefarclip = cvar("r_useinfinitefarclip");
1847                 }
1848
1849                 cvar_settemp("r_nearclip", ftos(ov_nearest));
1850                 cvar_settemp("r_farclip_base", ftos(ov_furthest));
1851                 cvar_settemp("r_farclip_world", "0");
1852                 cvar_settemp("r_novis", "1");
1853                 cvar_settemp("r_useportalculling", "0");
1854                 cvar_settemp("r_useinfinitefarclip", "0");
1855
1856                 setproperty(VF_ORIGIN, ov_org);
1857                 setproperty(VF_ANGLES, '90 0 0');
1858
1859                 ov_enabled = true;
1860
1861                 #if 0
1862                 LOG_INFOF("OrthoView: org = %s, angles = %s, distance = %f, nearest = %f, furthest = %f",
1863                         vtos(ov_org),
1864                         vtos(getpropertyvec(VF_ANGLES)),
1865                         ov_distance,
1866                         ov_nearest,
1867                         ov_furthest);
1868                 #endif
1869         }
1870         else
1871         {
1872                 if(ov_enabled)
1873                 {
1874                         cvar_set("r_nearclip", ftos(oldr_nearclip));
1875                         cvar_set("r_farclip_base", ftos(oldr_farclip_base));
1876                         cvar_set("r_farclip_world", ftos(oldr_farclip_world));
1877                         cvar_set("r_novis", ftos(oldr_novis));
1878                         cvar_set("r_useportalculling", ftos(oldr_useportalculling));
1879                         cvar_set("r_useinfinitefarclip", ftos(oldr_useinfinitefarclip));
1880                 }
1881                 ov_enabled = false;
1882         }
1883
1884         // run viewmodel_draw before updating view_angles to the angles calculated by WarpZone_FixView
1885         // viewmodel_draw needs to use the view_angles set by the engine on every CSQC_UpdateView call
1886         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1887                 viewmodel_draw(viewmodels[slot]);
1888
1889         // Render the Scene
1890         view_origin = getpropertyvec(VF_ORIGIN);
1891         view_angles = getpropertyvec(VF_ANGLES);
1892         makevectors(view_angles);
1893         view_forward = v_forward;
1894         view_right = v_right;
1895         view_up = v_up;
1896
1897 #ifdef BLURTEST
1898         if(time > blurtest_time0 && time < blurtest_time1)
1899         {
1900                 float r, t;
1901
1902                 t = (time - blurtest_time0) / (blurtest_time1 - blurtest_time0);
1903                 r = t * blurtest_radius;
1904                 f = 1 / (t ** blurtest_power) - 1;
1905
1906                 cvar_set("r_glsl_postprocess", "1");
1907                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(r), " ", ftos(f), " 0 0"));
1908         }
1909         else
1910         {
1911                 cvar_set("r_glsl_postprocess", "0");
1912                 cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
1913         }
1914 #endif
1915
1916         TargetMusic_Advance();
1917         Fog_Force();
1918         fpscounter_update();
1919
1920         if(drawtime == 0)
1921                 drawframetime = 0.01666667; // when we don't know fps yet, we assume 60fps
1922         else
1923                 drawframetime = bound(0.000001, time - drawtime, 1);
1924         drawtime = time;
1925
1926         // watch for gametype changes here...
1927         // in ParseStuffCMD the cmd isn't executed yet :/
1928         // might even be better to add the gametype to TE_CSQC_INIT...?
1929         if(!postinit)
1930                 PostInit();
1931
1932         if(intermission && !intermission_time)
1933                 intermission_time = time;
1934
1935         if(intermission && !isdemo() && !(calledhooks & HOOK_END))
1936         {
1937                 if(calledhooks & HOOK_START)
1938                 {
1939                         localcmd("\ncl_hook_gameend\n");
1940                         calledhooks |= HOOK_END;
1941                 }
1942         }
1943
1944         Announcer();
1945
1946         fov = autocvar_fov;
1947         if(fov <= 59.5)
1948         {
1949                 if(!zoomscript_caught)
1950                 {
1951                         localcmd("+button9\n");
1952                         zoomscript_caught = 1;
1953                 }
1954         }
1955         else
1956         {
1957                 if(zoomscript_caught)
1958                 {
1959                         localcmd("-button9\n");
1960                         zoomscript_caught = 0;
1961                 }
1962         }
1963
1964         ColorTranslateMode = autocvar_cl_stripcolorcodes;
1965
1966         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
1967         {
1968                 entity wepent = viewmodels[slot];
1969
1970                 if(wepent.last_switchweapon != wepent.switchweapon)
1971                 {
1972                         weapontime = time;
1973                         wepent.last_switchweapon = wepent.switchweapon;
1974                         if(slot == 0 && button_zoom && autocvar_cl_unpress_zoom_on_weapon_switch)
1975                         {
1976                                 localcmd("-zoom\n");
1977                                 button_zoom = false;
1978                         }
1979                         if(slot == 0 && autocvar_cl_unpress_attack_on_weapon_switch)
1980                         {
1981                                 localcmd("-fire\n");
1982                                 localcmd("-fire2\n");
1983                                 button_attack2 = false;
1984                         }
1985                 }
1986                 if(wepent.last_activeweapon != wepent.activeweapon)
1987                 {
1988                         wepent.last_activeweapon = wepent.activeweapon;
1989
1990                         e = wepent.activeweapon;
1991                         if(e.netname != "")
1992                                 localcmd(strcat("\ncl_hook_activeweapon ", e.netname), "\n");
1993                         else if(slot == 0)
1994                                 localcmd("\ncl_hook_activeweapon none\n");
1995                 }
1996         }
1997
1998         // ALWAYS Clear Current Scene First
1999         clearscene();
2000
2001         setproperty(VF_ORIGIN, view_origin);
2002         setproperty(VF_ANGLES, view_angles);
2003
2004         // FIXME engine bug? VF_SIZE and VF_MIN are not restored to sensible values by this
2005         setproperty(VF_SIZE, vf_size);
2006         setproperty(VF_MIN, vf_min);
2007
2008         // Assign Standard Viewflags
2009         // Draw the World (and sky)
2010         setproperty(VF_DRAWWORLD, 1);
2011
2012         // Set the console size vars
2013         vid_conwidth = autocvar_vid_conwidth;
2014         vid_conheight = autocvar_vid_conheight;
2015         vid_pixelheight = autocvar_vid_pixelheight;
2016
2017         if(autocvar_cl_orthoview) { setproperty(VF_FOV, GetOrthoviewFOV(ov_worldmin, ov_worldmax, ov_mid, ov_org)); }
2018         else if(csqcplayer.viewloc) { setproperty(VF_FOV, GetViewLocationFOV(110)); } // enforce 110 fov, so things dont look odd
2019         else { setproperty(VF_FOV, GetCurrentFov(fov)); }
2020
2021         if(camera_active) // Camera for demo playback
2022         {
2023                 if(autocvar_camera_enable)
2024                         CSQC_Demo_Camera();
2025                 else
2026                 {
2027                         cvar_set("chase_active", ftos(chase_active_backup));
2028                         cvar_set("cl_demo_mousegrab", "0");
2029                         camera_active = false;
2030                 }
2031         }
2032         else
2033         {
2034 #ifdef CAMERATEST
2035                 if(autocvar_camera_enable)
2036 #else
2037                 if(autocvar_camera_enable && isdemo())
2038 #endif
2039                 {
2040                         // Enable required Darkplaces cvars
2041                         chase_active_backup = autocvar_chase_active;
2042                         cvar_set("chase_active", "2");
2043                         cvar_set("cl_demo_mousegrab", "1");
2044                         camera_active = true;
2045                         camera_mode = false;
2046                 }
2047         }
2048
2049         // Draw the Crosshair
2050         setproperty(VF_DRAWCROSSHAIR, 0); //Make sure engine crosshairs are always hidden
2051
2052         // Draw the Engine Status Bar (the default Quake HUD)
2053         setproperty(VF_DRAWENGINESBAR, 0);
2054
2055         // Update the mouse position
2056         /*
2057            mousepos_x = vid_conwidth;
2058            mousepos_y = vid_conheight;
2059            mousepos = mousepos*0.5 + getmousepos();
2060          */
2061
2062         IL_EACH(g_drawables, it.draw, it.draw(it));
2063
2064         addentities(MASK_NORMAL | MASK_ENGINE | MASK_ENGINEVIEWMODELS);
2065         renderscene();
2066
2067         // now switch to 2D drawing mode by calling a 2D drawing function
2068         // then polygon drawing will draw as 2D stuff, and NOT get queued until the
2069         // next R_RenderScene call
2070         drawstring('0 0 0', "", '1 1 0', '1 1 1', 0, 0);
2071
2072         if(autocvar_r_fakelight >= 2 || autocvar_r_fullbright)
2073         if (!(serverflags & SERVERFLAG_ALLOW_FULLBRIGHT))
2074         {
2075                 // apply night vision effect
2076                 vector tc_00, tc_01, tc_10, tc_11;
2077                 vector rgb = '0 0 0';
2078
2079                 if(!nightvision_noise)
2080                 {
2081                         nightvision_noise = new(nightvision_noise);
2082                 }
2083                 if(!nightvision_noise2)
2084                 {
2085                         nightvision_noise2 = new(nightvision_noise2);
2086                 }
2087
2088                 // color tint in yellow
2089                 drawfill('0 0 0', autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', '0.5 1 0.3', 1, DRAWFLAG_MODULATE);
2090
2091                 // draw BG
2092                 a = Noise_Pink(nightvision_noise, frametime * 1.5) * 0.05 + 0.15;
2093                 rgb = '1 1 1';
2094                 tc_00 = '0 0 0' + '0.2 0 0' * sin(time * 0.3) + '0 0.3 0' * cos(time * 0.7);
2095                 tc_01 = '0 2.25 0' + '0.6 0 0' * cos(time * 1.2) - '0 0.3 0' * sin(time * 2.2);
2096                 tc_10 = '1.5 0 0' - '0.2 0 0' * sin(time * 0.5) + '0 0.5 0' * cos(time * 1.7);
2097                 //tc_11 = '1 1 0' + '0.6 0 0' * sin(time * 0.6) + '0 0.3 0' * cos(time * 0.1);
2098                 tc_11 = tc_01 + tc_10 - tc_00;
2099                 R_BeginPolygon("gfx/nightvision-bg.tga", DRAWFLAG_ADDITIVE);
2100                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2101                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2102                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2103                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2104                 R_EndPolygon();
2105
2106                 // draw FG
2107                 a = Noise_Pink(nightvision_noise2, frametime * 0.1) * 0.05 + 0.12;
2108                 rgb = '0.3 0.6 0.4' + '0.1 0.4 0.2' * Noise_White(nightvision_noise2, frametime);
2109                 tc_00 = '0 0 0' + '1 0 0' * Noise_White(nightvision_noise2, frametime) + '0 1 0' * Noise_White(nightvision_noise2, frametime);
2110                 tc_01 = tc_00 + '0 3 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.2);
2111                 tc_10 = tc_00 + '2 0 0' * (1 + Noise_White(nightvision_noise2, frametime) * 0.3);
2112                 tc_11 = tc_01 + tc_10 - tc_00;
2113                 R_BeginPolygon("gfx/nightvision-fg.tga", DRAWFLAG_ADDITIVE);
2114                 R_PolygonVertex('0 0 0', tc_00, rgb, a);
2115                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0', tc_10, rgb, a);
2116                 R_PolygonVertex(autocvar_vid_conwidth * '1 0 0' + autocvar_vid_conheight * '0 1 0', tc_11, rgb, a);
2117                 R_PolygonVertex(autocvar_vid_conheight * '0 1 0', tc_01, rgb, a);
2118                 R_EndPolygon();
2119         }
2120
2121         if(autocvar_cl_reticle)
2122         {
2123                 string reticle_image = string_null;
2124                 bool wep_zoomed = false;
2125                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
2126                 {
2127                         entity wepe = viewmodels[slot];
2128                         Weapon wep = wepe.activeweapon;
2129                         if(wep != WEP_Null && wep.wr_zoom)
2130                         {
2131                                 bool do_zoom = wep.wr_zoom(wep, NULL);
2132                                 if(!reticle_image && wep.w_reticle && wep.w_reticle != "")
2133                                         reticle_image = wep.w_reticle;
2134                                 wep_zoomed += do_zoom;
2135                         }
2136                 }
2137                 // Draw the aiming reticle for weapons that use it
2138                 // reticle_type is changed to the item we are zooming / aiming with, to decide which reticle to use
2139                 // It must be a persisted float for fading out to work properly (you let go of the zoom button for
2140                 // the view to go back to normal, so reticle_type would become 0 as we fade out)
2141                 if(spectatee_status || is_dead || hud != HUD_NORMAL || local_player.viewloc)
2142                 {
2143                         // no zoom reticle while dead
2144                         reticle_type = 0;
2145                 }
2146                 else if(wep_zoomed && autocvar_cl_reticle_weapon)
2147                 {
2148                         if(reticle_image) { reticle_type = 2; }
2149                         else { reticle_type = 0; }
2150                 }
2151                 else if(button_zoom || zoomscript_caught)
2152                 {
2153                         // normal zoom
2154                         reticle_type = 1;
2155                 }
2156
2157                 if(reticle_type)
2158                 {
2159                         if(autocvar_cl_reticle_stretch)
2160                         {
2161                                 reticle_size.x = vid_conwidth;
2162                                 reticle_size.y = vid_conheight;
2163                                 reticle_pos.x = 0;
2164                                 reticle_pos.y = 0;
2165                         }
2166                         else
2167                         {
2168                                 reticle_size.x = max(vid_conwidth, vid_conheight);
2169                                 reticle_size.y = max(vid_conwidth, vid_conheight);
2170                                 reticle_pos.x = (vid_conwidth - reticle_size.x) / 2;
2171                                 reticle_pos.y = (vid_conheight - reticle_size.y) / 2;
2172                         }
2173
2174                         if(zoomscript_caught)
2175                                 f = 1;
2176                         else
2177                                 f = current_zoomfraction;
2178
2179                         if(f)
2180                         {
2181                                 switch(reticle_type)
2182                                 {
2183                                         case 1: drawpic(reticle_pos, "gfx/reticle_normal", reticle_size, '1 1 1', f * autocvar_cl_reticle_normal_alpha, DRAWFLAG_NORMAL); break;
2184                                         case 2: if(reticle_image) drawpic(reticle_pos, reticle_image, reticle_size, '1 1 1', f * autocvar_cl_reticle_weapon_alpha, DRAWFLAG_NORMAL); break;
2185                                 }
2186                         }
2187                 }
2188         }
2189         else
2190         {
2191                 if(reticle_type != 0) { reticle_type = 0; }
2192         }
2193
2194
2195         // improved polyblend
2196         if(autocvar_hud_contents && !MUTATOR_CALLHOOK(HUD_Contents))
2197         {
2198                 float contentalpha_temp, incontent, liquidalpha, contentfadetime;
2199                 vector liquidcolor;
2200
2201                 switch(pointcontents(view_origin))
2202                 {
2203                         case CONTENT_WATER:
2204                                 liquidalpha = autocvar_hud_contents_water_alpha;
2205                                 liquidcolor = stov(autocvar_hud_contents_water_color);
2206                                 incontent = 1;
2207                                 break;
2208
2209                         case CONTENT_LAVA:
2210                                 liquidalpha = autocvar_hud_contents_lava_alpha;
2211                                 liquidcolor = stov(autocvar_hud_contents_lava_color);
2212                                 incontent = 1;
2213                                 break;
2214
2215                         case CONTENT_SLIME:
2216                                 liquidalpha = autocvar_hud_contents_slime_alpha;
2217                                 liquidcolor = stov(autocvar_hud_contents_slime_color);
2218                                 incontent = 1;
2219                                 break;
2220
2221                         default:
2222                                 liquidalpha = 0;
2223                                 liquidcolor = '0 0 0';
2224                                 incontent = 0;
2225                                 break;
2226                 }
2227
2228                 if(incontent) // fade in/out at different speeds so you can do e.g. instant fade when entering water and slow when leaving it.
2229                 { // also lets delcare previous values for blending properties, this way it isn't reset until after you have entered a different content
2230                         contentfadetime = autocvar_hud_contents_fadeintime;
2231                         liquidalpha_prev = liquidalpha;
2232                         liquidcolor_prev = liquidcolor;
2233                 }
2234                 else
2235                         contentfadetime = autocvar_hud_contents_fadeouttime;
2236
2237                 contentalpha_temp = bound(0, drawframetime / max(0.0001, contentfadetime), 1);
2238                 contentavgalpha = contentavgalpha * (1 - contentalpha_temp) + incontent * contentalpha_temp;
2239
2240                 if(contentavgalpha)
2241                         drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), liquidcolor_prev, contentavgalpha * liquidalpha_prev, DRAWFLAG_NORMAL);
2242
2243                 if(autocvar_hud_postprocessing)
2244                 {
2245                         if(autocvar_hud_contents_blur && contentavgalpha)
2246                         {
2247                                 content_blurpostprocess.x = 1;
2248                                 content_blurpostprocess.y = contentavgalpha * autocvar_hud_contents_blur;
2249                                 content_blurpostprocess.z = contentavgalpha * autocvar_hud_contents_blur_alpha;
2250                         }
2251                         else
2252                         {
2253                                 content_blurpostprocess.x = 0;
2254                                 content_blurpostprocess.y = 0;
2255                                 content_blurpostprocess.z = 0;
2256                         }
2257                 }
2258         }
2259
2260         if(autocvar_hud_damage && !STAT(FROZEN))
2261         {
2262                 splash_size.x = max(vid_conwidth, vid_conheight);
2263                 splash_size.y = max(vid_conwidth, vid_conheight);
2264                 splash_pos.x = (vid_conwidth - splash_size.x) / 2;
2265                 splash_pos.y = (vid_conheight - splash_size.y) / 2;
2266
2267                 float myhealth_flash_temp;
2268                 myhealth = STAT(HEALTH);
2269
2270                 // fade out
2271                 myhealth_flash = max(0, myhealth_flash - autocvar_hud_damage_fade_rate * frametime);
2272                 // add new damage
2273                 myhealth_flash = bound(0, myhealth_flash + dmg_take * autocvar_hud_damage_factor, autocvar_hud_damage_maxalpha);
2274
2275                 float pain_threshold, pain_threshold_lower, pain_threshold_lower_health;
2276                 pain_threshold = autocvar_hud_damage_pain_threshold;
2277                 pain_threshold_lower = autocvar_hud_damage_pain_threshold_lower;
2278                 pain_threshold_lower_health = autocvar_hud_damage_pain_threshold_lower_health;
2279
2280                 if(pain_threshold_lower && myhealth < pain_threshold_lower_health)
2281                 {
2282                         pain_threshold = pain_threshold - max(autocvar_hud_damage_pain_threshold_pulsating_min, fabs(sin(M_PI * time / autocvar_hud_damage_pain_threshold_pulsating_period))) * pain_threshold_lower * (1 - max(0, myhealth)/pain_threshold_lower_health);
2283                 }
2284
2285                 myhealth_flash_temp = bound(0, myhealth_flash - pain_threshold, 1);
2286
2287                 if(myhealth_prev < 1)
2288                 {
2289                         if(myhealth >= 1)
2290                         {
2291                                 myhealth_flash = 0; // just spawned, clear the flash immediately
2292                                 myhealth_flash_temp = 0;
2293                         }
2294                         else
2295                         {
2296                                 myhealth_flash += autocvar_hud_damage_fade_rate * frametime; // dead
2297                         }
2298                 }
2299
2300                 if(spectatee_status == -1 || intermission)
2301                 {
2302                         myhealth_flash = 0; // observing, or match ended
2303                         myhealth_flash_temp = 0;
2304                 }
2305
2306                 myhealth_prev = myhealth;
2307
2308                 // IDEA: change damage color/picture based on player model for robot/alien species?
2309                 // pro: matches model better
2310                 // contra: it's not red because blood is red, but because red is an alarming color, so red should stay
2311                 // maybe different reddish pics?
2312                 if(autocvar_cl_gentle_damage || autocvar_cl_gentle)
2313                 {
2314                         if(autocvar_cl_gentle_damage == 2)
2315                         {
2316                                 if(myhealth_flash < pain_threshold) // only randomize when the flash is gone
2317                                         myhealth_gentlergb = randomvec();
2318                         }
2319                         else
2320                                 myhealth_gentlergb = stov(autocvar_hud_damage_gentle_color);
2321
2322                         if(myhealth_flash_temp > 0)
2323                                 drawfill('0 0 0', vec2(vid_conwidth, vid_conheight), myhealth_gentlergb, autocvar_hud_damage_gentle_alpha_multiplier * bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2324                 }
2325                 else if(myhealth_flash_temp > 0)
2326                         drawpic(splash_pos, "gfx/blood", splash_size, stov(autocvar_hud_damage_color), bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage, DRAWFLAG_NORMAL);
2327
2328                 if(autocvar_hud_postprocessing) // we still need to set this anyway even when chase_active is set, this way it doesn't get stuck on.
2329                 {
2330                         if(autocvar_hud_damage_blur && myhealth_flash_temp)
2331                         {
2332                                 damage_blurpostprocess.x = 1;
2333                                 damage_blurpostprocess.y = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur;
2334                                 damage_blurpostprocess.z = bound(0, myhealth_flash_temp, 1) * autocvar_hud_damage_blur_alpha;
2335                         }
2336                         else
2337                         {
2338                                 damage_blurpostprocess.x = 0;
2339                                 damage_blurpostprocess.y = 0;
2340                                 damage_blurpostprocess.z = 0;
2341                         }
2342                 }
2343         }
2344
2345         float e1 = (autocvar_hud_postprocessing_maxbluralpha != 0);
2346         float e2 = (autocvar_hud_powerup != 0);
2347         if(autocvar_hud_postprocessing && (e1 || e2)) // TODO: Remove this code and re-do the postprocess handling in the engine, where it properly belongs.
2348         {
2349                 // enable or disable rendering types if they are used or not
2350                 if(cvar("r_glsl_postprocess_uservec1_enable") != e1) { cvar_set("r_glsl_postprocess_uservec1_enable", ftos(e1)); }
2351                 if(cvar("r_glsl_postprocess_uservec2_enable") != e2) { cvar_set("r_glsl_postprocess_uservec2_enable", ftos(e2)); }
2352
2353                 // blur postprocess handling done first (used by hud_damage and hud_contents)
2354                 if((damage_blurpostprocess.x || content_blurpostprocess.x))
2355                 {
2356                         float blurradius = bound(0, damage_blurpostprocess.y + content_blurpostprocess.y, autocvar_hud_postprocessing_maxblurradius);
2357                         float bluralpha = bound(0, damage_blurpostprocess.z + content_blurpostprocess.z, autocvar_hud_postprocessing_maxbluralpha);
2358                         if(blurradius != old_blurradius || bluralpha != old_bluralpha) // reduce cvar_set spam as much as possible
2359                         {
2360                                 cvar_set("r_glsl_postprocess_uservec1", strcat(ftos(blurradius), " ", ftos(bluralpha), " 0 0"));
2361                                 old_blurradius = blurradius;
2362                                 old_bluralpha = bluralpha;
2363                         }
2364                 }
2365                 else if(cvar_string("r_glsl_postprocess_uservec1") != "0 0 0 0") // reduce cvar_set spam as much as possible
2366                 {
2367                         cvar_set("r_glsl_postprocess_uservec1", "0 0 0 0");
2368                         old_blurradius = 0;
2369                         old_bluralpha = 0;
2370                 }
2371
2372                 // edge detection postprocess handling done second (used by hud_powerup)
2373                 float sharpen_intensity = 0, strength_finished = STAT(STRENGTH_FINISHED), invincible_finished = STAT(INVINCIBLE_FINISHED);
2374                 if (strength_finished - time > 0) { sharpen_intensity += (strength_finished - time); }
2375                 if (invincible_finished - time > 0) { sharpen_intensity += (invincible_finished - time); }
2376
2377                 sharpen_intensity = bound(0, ((STAT(HEALTH) > 0) ? sharpen_intensity : 0), 5); // Check to see if player is alive (if not, set 0) - also bound to fade out starting at 5 seconds.
2378
2379                 if(autocvar_hud_powerup && sharpen_intensity > 0)
2380                 {
2381                         if(sharpen_intensity != old_sharpen_intensity) // reduce cvar_set spam as much as possible
2382                         {
2383                                 cvar_set("r_glsl_postprocess_uservec2", strcat(ftos((sharpen_intensity / 5) * autocvar_hud_powerup), " ", ftos(-sharpen_intensity * autocvar_hud_powerup), " 0 0"));
2384                                 old_sharpen_intensity = sharpen_intensity;
2385                         }
2386                 }
2387                 else if(cvar_string("r_glsl_postprocess_uservec2") != "0 0 0 0") // reduce cvar_set spam as much as possible
2388                 {
2389                         cvar_set("r_glsl_postprocess_uservec2", "0 0 0 0");
2390                         old_sharpen_intensity = 0;
2391                 }
2392
2393                 if(cvar("r_glsl_postprocess") == 0)
2394                         cvar_set("r_glsl_postprocess", "2");
2395         }
2396         else if(cvar("r_glsl_postprocess") == 2)
2397                 cvar_set("r_glsl_postprocess", "0");
2398
2399         /*if(gametype == MAPINFO_TYPE_CTF)
2400           {
2401           ctf_view();
2402           } else */
2403
2404         // draw 2D entities
2405         IL_EACH(g_drawables_2d, it.draw2d, it.draw2d(it));
2406         Draw_ShowNames_All();
2407 #if ENABLE_DEBUGDRAW
2408         Debug_Draw();
2409 #endif
2410
2411         scoreboard_active = Scoreboard_WouldDraw();
2412
2413         HUD_Draw(this); // this parameter for deep vehicle function
2414
2415         if(NextFrameCommand)
2416         {
2417                 localcmd("\n", NextFrameCommand, "\n");
2418                 NextFrameCommand = string_null;
2419         }
2420
2421         // we must do this check AFTER a frame was rendered, or it won't work
2422         if(cs_project_is_b0rked == 0)
2423         {
2424                 string w0, h0;
2425                 w0 = ftos(autocvar_vid_conwidth);
2426                 h0 = ftos(autocvar_vid_conheight);
2427                 //setproperty(VF_VIEWPORT, '0 0 0', '640 480 0');
2428                 //setproperty(VF_FOV, '90 90 0');
2429                 setproperty(VF_ORIGIN, '0 0 0');
2430                 setproperty(VF_ANGLES, '0 0 0');
2431                 setproperty(VF_PERSPECTIVE, 1);
2432                 makevectors('0 0 0');
2433                 vector v1, v2;
2434                 cvar_set("vid_conwidth", "800");
2435                 cvar_set("vid_conheight", "600");
2436                 v1 = cs_project(v_forward);
2437                 cvar_set("vid_conwidth", "640");
2438                 cvar_set("vid_conheight", "480");
2439                 v2 = cs_project(v_forward);
2440                 if(v1 == v2)
2441                         cs_project_is_b0rked = 1;
2442                 else
2443                         cs_project_is_b0rked = -1;
2444                 cvar_set("vid_conwidth", w0);
2445                 cvar_set("vid_conheight", h0);
2446         }
2447
2448         if(autocvar__hud_configure)
2449                 HUD_Panel_Mouse();
2450         else if (HUD_MinigameMenu_IsOpened() || active_minigame)
2451                 HUD_Minigame_Mouse();
2452         else if(QuickMenu_IsOpened())
2453                 QuickMenu_Mouse();
2454         else if(local_player.viewloc && (local_player.viewloc.spawnflags & VIEWLOC_FREEAIM))
2455                 ViewLocation_Mouse(); // NOTE: doesn't use cursormode
2456         else
2457                 HUD_Radar_Mouse();
2458
2459         cl_notice_run();
2460         unpause_update();
2461         Net_Flush();
2462
2463         // let's reset the view back to normal for the end
2464         setproperty(VF_MIN, '0 0 0');
2465         setproperty(VF_SIZE, '1 0 0' * w + '0 1 0' * h);
2466
2467         IL_ENDFRAME();
2468 }
2469
2470
2471 // following vectors must be global to allow seamless switching between camera modes
2472 vector camera_offset, current_camera_offset, mouse_angles, current_angles, current_origin, current_position;
2473 void CSQC_Demo_Camera()
2474 {
2475         float speed, attenuation, dimensions;
2476         vector tmp, delta;
2477
2478         if( autocvar_camera_reset || !camera_mode )
2479         {
2480                 camera_offset = '0 0 0';
2481                 current_angles = '0 0 0';
2482                 camera_direction = '0 0 0';
2483                 camera_offset.z += 30;
2484                 camera_offset.x += 30 * -cos(current_angles.y * DEG2RAD);
2485                 camera_offset.y += 30 * -sin(current_angles.y * DEG2RAD);
2486                 current_origin = view_origin;
2487                 current_camera_offset  = camera_offset;
2488                 cvar_set("camera_reset", "0");
2489                 camera_mode = CAMERA_CHASE;
2490         }
2491
2492         // Camera angles
2493         if( camera_roll )
2494                 mouse_angles.z += camera_roll * autocvar_camera_speed_roll;
2495
2496         if(autocvar_camera_look_player)
2497         {
2498                 vector dir;
2499                 float n;
2500
2501                 dir = normalize(view_origin - current_position);
2502                 n = mouse_angles.z;
2503                 mouse_angles = vectoangles(dir);
2504                 mouse_angles.x = mouse_angles.x * -1;
2505                 mouse_angles.z = n;
2506         }
2507         else
2508         {
2509                 tmp = getmousepos() * 0.1;
2510                 if(vdist(tmp, >, autocvar_camera_mouse_threshold))
2511                 {
2512                         mouse_angles.x += tmp.y * cos(mouse_angles.z * DEG2RAD) + (tmp.x * sin(mouse_angles.z * DEG2RAD));
2513                         mouse_angles.y -= tmp.x * cos(mouse_angles.z * DEG2RAD) + (tmp.y * -sin(mouse_angles.z * DEG2RAD));
2514                 }
2515         }
2516
2517         while (mouse_angles.x < -180) mouse_angles.x = mouse_angles.x + 360;
2518         while (mouse_angles.x > 180) mouse_angles.x = mouse_angles.x - 360;
2519         while (mouse_angles.y < -180) mouse_angles.y = mouse_angles.y + 360;
2520         while (mouse_angles.y > 180) mouse_angles.y = mouse_angles.y - 360;
2521
2522         // Fix difference when angles don't have the same sign
2523         delta = '0 0 0';
2524         if(mouse_angles.y < -60 && current_angles.y > 60)
2525                 delta = '0 360 0';
2526         if(mouse_angles.y > 60 && current_angles.y < -60)
2527                 delta = '0 -360 0';
2528
2529         if(autocvar_camera_look_player)
2530                 attenuation = autocvar_camera_look_attenuation;
2531         else
2532                 attenuation = autocvar_camera_speed_attenuation;
2533
2534         attenuation = 1 / max(1, attenuation);
2535         current_angles += (mouse_angles - current_angles + delta) * attenuation;
2536
2537         while (current_angles.x < -180) current_angles.x = current_angles.x + 360;
2538         while (current_angles.x > 180) current_angles.x = current_angles.x - 360;
2539         while (current_angles.y < -180) current_angles.y = current_angles.y + 360;
2540         while (current_angles.y > 180) current_angles.y = current_angles.y - 360;
2541
2542         // Camera position
2543         tmp = '0 0 0';
2544         dimensions = 0;
2545
2546         if( camera_direction.x )
2547         {
2548                 tmp.x = camera_direction.x * cos(current_angles.y * DEG2RAD);
2549                 tmp.y = camera_direction.x * sin(current_angles.y * DEG2RAD);
2550                 if( autocvar_camera_forward_follows && !autocvar_camera_look_player )
2551                         tmp.z = camera_direction.x * -sin(current_angles.x * DEG2RAD);
2552                 ++dimensions;
2553         }
2554
2555         if( camera_direction.y )
2556         {
2557                 tmp.x += camera_direction.y * -sin(current_angles.y * DEG2RAD);
2558                 tmp.y += camera_direction.y * cos(current_angles.y * DEG2RAD) * cos(current_angles.z * DEG2RAD);
2559                 tmp.z += camera_direction.y * sin(current_angles.z * DEG2RAD);
2560                 ++dimensions;
2561         }
2562
2563         if( camera_direction.z )
2564         {
2565                 tmp.z += camera_direction.z * cos(current_angles.z * DEG2RAD);
2566                 ++dimensions;
2567         }
2568
2569         if(autocvar_camera_free)
2570                 speed = autocvar_camera_speed_free;
2571         else
2572                 speed = autocvar_camera_speed_chase;
2573
2574         if(dimensions)
2575         {
2576                 speed = speed * sqrt(1 / dimensions);
2577                 camera_offset += tmp * speed;
2578         }
2579
2580         current_camera_offset += (camera_offset - current_camera_offset) * attenuation;
2581
2582         // Camera modes
2583         if( autocvar_camera_free )
2584         {
2585                 if ( camera_mode == CAMERA_CHASE )
2586                 {
2587                         current_camera_offset = current_origin + current_camera_offset;
2588                         camera_offset = current_origin + camera_offset;
2589                 }
2590
2591                 camera_mode = CAMERA_FREE;
2592                 current_position = current_camera_offset;
2593         }
2594         else
2595         {
2596                 if ( camera_mode == CAMERA_FREE )
2597                 {
2598                         current_origin = view_origin;
2599                         camera_offset = camera_offset - current_origin;
2600                         current_camera_offset = current_camera_offset - current_origin;
2601                 }
2602
2603                 camera_mode = CAMERA_CHASE;
2604
2605                 if(autocvar_camera_chase_smoothly)
2606                         current_origin += (view_origin - current_origin) * attenuation;
2607                 else
2608                         current_origin = view_origin;
2609
2610                 current_position = current_origin + current_camera_offset;
2611         }
2612
2613         setproperty(VF_ANGLES, current_angles);
2614         setproperty(VF_ORIGIN, current_position);
2615 }