qcsrc/client/weapons/projectile.qc

   1 #include "projectile.qh"
   2
   3 void SUB_Stop()
   4 {
   5         self.move_velocity = self.move_avelocity = '0 0 0';
   6         self.move_movetype = MOVETYPE_NONE;
   7 }
   8
   9 void Projectile_ResetTrail(vector to)
  10 {
  11         self.trail_oldorigin = to;
  12         self.trail_oldtime = time;
  13 }
  14
  15 void Projectile_DrawTrail(vector to)
  16 {
  17         vector from;
  18         float t0;
  19
  20         from = self.trail_oldorigin;
  21         t0 = self.trail_oldtime;
  22         self.trail_oldorigin = to;
  23         self.trail_oldtime = time;
  24
  25         // force the effect even for stationary firemine
  26         if(self.cnt == PROJECTILE_FIREMINE)
  27                 if(from == to)
  28                         from.z += 1;
  29
  30         if (self.traileffect)
  31         {
  32                 particles_alphamin = particles_alphamax = particles_fade = sqrt(self.alpha);
  33                 boxparticles(self.traileffect, self, from, to, self.velocity, self.velocity, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE | PARTICLES_DRAWASTRAIL);
  34         }
  35 }
  36
  37 void Projectile_Draw()
  38 {
  39         vector rot;
  40         vector trailorigin;
  41         int f;
  42         bool drawn;
  43         float t;
  44         float a;
  45
  46         f = self.move_flags;
  47
  48         if(self.count & 0x80)
  49         {
  50                 //self.move_flags &= ~FL_ONGROUND;
  51                 if(self.move_movetype == MOVETYPE_NONE || self.move_movetype == MOVETYPE_FLY)
  52                         Movetype_Physics_NoMatchServer();
  53                         // the trivial movetypes do not have to match the
  54                         // server's ticrate as they are ticrate independent
  55                         // NOTE: this assumption is only true if MOVETYPE_FLY
  56                         // projectiles detonate on impact. If they continue
  57                         // moving, we might still be ticrate dependent.
  58                 else
  59                         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  60                 if(!(self.move_flags & FL_ONGROUND))
  61                         if(self.velocity != '0 0 0')
  62                                 self.move_angles = self.angles = vectoangles(self.velocity);
  63         }
  64         else
  65         {
  66                 InterpolateOrigin_Do();
  67         }
  68
  69         if(self.count & 0x80)
  70         {
  71                 drawn = (time >= self.spawntime - 0.02);
  72                 t = max(time, self.spawntime);
  73         }
  74         else
  75         {
  76                 drawn = (self.iflags & IFLAG_VALID);
  77                 t = time;
  78         }
  79
  80         if(!(f & FL_ONGROUND))
  81         {
  82                 rot = '0 0 0';
  83                 switch(self.cnt)
  84                 {
  85                         /*
  86                         case PROJECTILE_GRENADE:
  87                                 rot = '-2000 0 0'; // forward
  88                                 break;
  89                         */
  90                         case PROJECTILE_GRENADE_BOUNCING:
  91                                 rot = '0 -1000 0'; // sideways
  92                                 break;
  93                         case PROJECTILE_HOOKBOMB:
  94                                 rot = '1000 0 0'; // forward
  95                                 break;
  96                         default:
  97                                 break;
  98                 }
  99
 100                 if(Nade_IDFromProjectile(self.cnt) != 0)
 101                         rot = self.avelocity;
 102
 103                 self.angles = AnglesTransform_ToAngles(AnglesTransform_Multiply(AnglesTransform_FromAngles(self.angles), rot * (t - self.spawntime)));
 104         }
 105
 106         vector ang;
 107         ang = self.angles;
 108         ang.x = -ang.x;
 109         makevectors(ang);
 110
 111         a = 1 - (time - self.fade_time) * self.fade_rate;
 112         self.alpha = bound(0, self.alphamod * a, 1);
 113         if(self.alpha <= 0)
 114                 drawn = 0;
 115         self.renderflags = 0;
 116
 117         trailorigin = self.origin;
 118         switch(self.cnt)
 119         {
 120                 case PROJECTILE_GRENADE:
 121                 case PROJECTILE_GRENADE_BOUNCING:
 122                         trailorigin += v_right * 1 + v_forward * -10;
 123                         break;
 124                 default:
 125                         break;
 126         }
 127
 128         if(Nade_IDFromProjectile(self.cnt) != 0)
 129                 trailorigin += v_up * 4;
 130
 131         if(drawn)
 132                 Projectile_DrawTrail(trailorigin);
 133         else
 134                 Projectile_ResetTrail(trailorigin);
 135
 136         self.drawmask = 0;
 137
 138         if(!drawn)
 139                 return;
 140
 141         switch(self.cnt)
 142         {
 143                 // Possibly add dlights here.
 144                 default:
 145                         break;
 146         }
 147
 148         self.drawmask = MASK_NORMAL;
 149 }
 150
 151 void loopsound(entity e, int ch, string samp, float vol, float attn)
 152 {
 153         if(self.silent)
 154                 return;
 155
 156         sound(e, ch, samp, vol, attn);
 157         e.snd_looping = ch;
 158 }
 159
 160 void Ent_RemoveProjectile()
 161 {
 162         if(self.count & 0x80)
 163         {
 164                 tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.05, MOVE_NORMAL, self);
 165                 Projectile_DrawTrail(trace_endpos);
 166         }
 167 }
 168
 169 void Ent_Projectile()
 170 {
 171         int f;
 172
 173         // projectile properties:
 174         //   kind (interpolated, or clientside)
 175         //
 176         //   modelindex
 177         //   origin
 178         //   scale
 179         //   if clientside:
 180         //     velocity
 181         //     gravity
 182         //   soundindex (hardcoded list)
 183         //   effects
 184         //
 185         // projectiles don't send angles, because they always follow the velocity
 186
 187         f = ReadByte();
 188         self.count = (f & 0x80);
 189         self.iflags = (self.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES | IFLAG_ORIGIN;
 190         self.solid = SOLID_TRIGGER;
 191         //self.effects = EF_NOMODELFLAGS;
 192
 193         // this should make collisions with bmodels more exact, but it leads to
 194         // projectiles no longer being able to lie on a bmodel
 195         self.move_nomonsters = MOVE_WORLDONLY;
 196         if(f & 0x40)
 197                 self.move_flags |= FL_ONGROUND;
 198         else
 199                 self.move_flags &= ~FL_ONGROUND;
 200
 201         if(!self.move_time)
 202         {
 203                 // for some unknown reason, we don't need to care for
 204                 // sv_gameplayfix_delayprojectiles here.
 205                 self.move_time = time;
 206                 self.spawntime = time;
 207         }
 208         else
 209                 self.move_time = max(self.move_time, time);
 210
 211         if(!(self.count & 0x80))
 212                 InterpolateOrigin_Undo();
 213
 214         if(f & 1)
 215         {
 216                 self.origin_x = ReadCoord();
 217                 self.origin_y = ReadCoord();
 218                 self.origin_z = ReadCoord();
 219                 setorigin(self, self.origin);
 220                 if(self.count & 0x80)
 221                 {
 222                         self.velocity_x = ReadCoord();
 223                         self.velocity_y = ReadCoord();
 224                         self.velocity_z = ReadCoord();
 225                         if(f & 0x10)
 226                                 self.gravity = ReadCoord();
 227                         else
 228                                 self.gravity = 0; // none
 229                         self.move_origin = self.origin;
 230                         self.move_velocity = self.velocity;
 231                 }
 232
 233                 if(time == self.spawntime || (self.count & 0x80) || (f & 0x08))
 234                 {
 235                         self.trail_oldorigin = self.origin;
 236                         if(!(self.count & 0x80))
 237                                 InterpolateOrigin_Reset();
 238                 }
 239
 240                 if(f & 0x20)
 241                 {
 242                         self.fade_time = time + ReadByte() * ticrate;
 243                         self.fade_rate = 1 / (ReadByte() * ticrate);
 244                 }
 245                 else
 246                 {
 247                         self.fade_time = 0;
 248                         self.fade_rate = 0;
 249                 }
 250
 251                 self.team = ReadByte() - 1;
 252         }
 253
 254         if(f & 2)
 255         {
 256                 self.cnt = ReadByte();
 257
 258                 self.silent = (self.cnt & 0x80);
 259                 self.cnt = (self.cnt & 0x7F);
 260
 261                 self.scale = 1;
 262                 self.traileffect = 0;
 263                 switch(self.cnt)
 264                 {
 265                         case PROJECTILE_ELECTRO: setmodel(self, "models/ebomb.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 266                         case PROJECTILE_ROCKET: setmodel(self, "models/rocket.md3");self.traileffect = particleeffectnum("TR_ROCKET"); self.scale = 2; break;
 267                         case PROJECTILE_CRYLINK: setmodel(self, "models/plasmatrail.mdl");self.traileffect = particleeffectnum("TR_CRYLINKPLASMA"); break;
 268                         case PROJECTILE_CRYLINK_BOUNCING: setmodel(self, "models/plasmatrail.mdl");self.traileffect = particleeffectnum("TR_CRYLINKPLASMA"); break;
 269                         case PROJECTILE_ELECTRO_BEAM: setmodel(self, "models/elaser.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 270                         case PROJECTILE_GRENADE: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_GRENADE"); break;
 271                         case PROJECTILE_GRENADE_BOUNCING: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_GRENADE"); break;
 272                         case PROJECTILE_MINE: setmodel(self, "models/mine.md3");self.traileffect = particleeffectnum("TR_GRENADE"); break;
 273                         case PROJECTILE_BLASTER: setmodel(self, "models/laser.mdl");self.traileffect = particleeffectnum(""); break;
 274                         case PROJECTILE_HLAC: setmodel(self, "models/hlac_bullet.md3");self.traileffect = particleeffectnum(""); break;
 275                         case PROJECTILE_PORTO_RED: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_WIZSPIKE"); self.scale = 4; break;
 276                         case PROJECTILE_PORTO_BLUE: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_WIZSPIKE"); self.scale = 4; break;
 277                         case PROJECTILE_HOOKBOMB: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_KNIGHTSPIKE"); break;
 278                         case PROJECTILE_HAGAR: setmodel(self, "models/hagarmissile.mdl");self.traileffect = particleeffectnum("tr_hagar"); self.scale = 0.75; break;
 279                         case PROJECTILE_HAGAR_BOUNCING: setmodel(self, "models/hagarmissile.mdl");self.traileffect = particleeffectnum("tr_hagar"); self.scale = 0.75; break;
 280                         case PROJECTILE_NAPALM_FOUNTAIN: //self.model = ""; self.modelindex = 0; self.traileffect = particleeffectnum("torch_small"); break;
 281                         case PROJECTILE_FIREBALL: self.model = ""; self.modelindex = 0; self.traileffect = particleeffectnum("fireball"); break; // particle effect is good enough
 282                         case PROJECTILE_FIREMINE: self.model = ""; self.modelindex = 0; self.traileffect = particleeffectnum("firemine"); break; // particle effect is good enough
 283                         case PROJECTILE_TAG: setmodel(self, "models/laser.mdl"); self.traileffect = particleeffectnum("TR_ROCKET"); break;
 284                         case PROJECTILE_FLAC: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; self.traileffect = particleeffectnum("TR_SEEKER"); break;
 285                         case PROJECTILE_SEEKER: setmodel(self, "models/tagrocket.md3"); self.traileffect = particleeffectnum("TR_SEEKER"); break;
 286
 287                         case PROJECTILE_MAGE_SPIKE: setmodel(self, "models/ebomb.mdl"); self.traileffect = particleeffectnum("TR_VORESPIKE"); break;
 288                         case PROJECTILE_SHAMBLER_LIGHTNING: setmodel(self, "models/ebomb.mdl"); self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 289
 290                         case PROJECTILE_RAPTORBOMB:    setmodel(self, "models/vehicles/clusterbomb.md3"); self.gravity = 1; self.avelocity = '0 0 180'; self.traileffect = particleeffectnum(""); break;
 291                         case PROJECTILE_RAPTORBOMBLET: setmodel(self, "models/vehicles/bomblet.md3");     self.gravity = 1; self.avelocity = '0 0 180'; self.traileffect = particleeffectnum(""); break;
 292                         case PROJECTILE_RAPTORCANNON:  setmodel(self, "models/plasmatrail.mdl"); self.traileffect = particleeffectnum("TR_CRYLINKPLASMA"); break;
 293
 294                         case PROJECTILE_SPIDERROCKET: setmodel(self, "models/vehicles/rocket02.md3"); self.traileffect = particleeffectnum("spiderbot_rocket_thrust"); break;
 295                         case PROJECTILE_WAKIROCKET:   setmodel(self, "models/vehicles/rocket01.md3");  self.traileffect = particleeffectnum("wakizashi_rocket_thrust"); break;
 296                         case PROJECTILE_WAKICANNON:   setmodel(self, "models/laser.mdl");  self.traileffect = particleeffectnum(""); break;
 297
 298                         case PROJECTILE_BUMBLE_GUN: setmodel(self, "models/elaser.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 299                         case PROJECTILE_BUMBLE_BEAM: setmodel(self, "models/elaser.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 300
 301                         case PROJECTILE_RPC: setmodel(self, "models/weapons/ok_rocket.md3");self.traileffect = particleeffectnum("TR_ROCKET"); break;
 302
 303                         default:
 304                                 if(Nade_IDFromProjectile(self.cnt) != 0) { setmodel(self, "models/weapons/v_ok_grenade.md3");self.traileffect = particleeffectnum(Nade_TrailEffect(self.cnt, self.team)); break; }
 305                                 error("Received invalid CSQC projectile, can't work with this!");
 306                                 break;
 307                 }
 308
 309                 self.mins = '0 0 0';
 310                 self.maxs = '0 0 0';
 311                 self.colormod = '0 0 0';
 312                 self.move_touch = SUB_Stop;
 313                 self.move_movetype = MOVETYPE_TOSS;
 314                 self.alphamod = 1;
 315
 316                 switch(self.cnt)
 317                 {
 318                         case PROJECTILE_ELECTRO:
 319                                 // only new engines support sound moving with object
 320                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/electro_fly.wav", VOL_BASE, ATTEN_NORM);
 321                                 self.mins = '0 0 -4';
 322                                 self.maxs = '0 0 -4';
 323                                 self.move_movetype = MOVETYPE_BOUNCE;
 324                                 self.move_touch = func_null;
 325                                 self.move_bounce_factor = g_balance_electro_secondary_bouncefactor;
 326                                 self.move_bounce_stopspeed = g_balance_electro_secondary_bouncestop;
 327                                 break;
 328                         case PROJECTILE_RPC:
 329                         case PROJECTILE_ROCKET:
 330                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/rocket_fly.wav", VOL_BASE, ATTEN_NORM);
 331                                 self.mins = '-3 -3 -3';
 332                                 self.maxs = '3 3 3';
 333                                 break;
 334                         case PROJECTILE_GRENADE:
 335                                 self.mins = '-3 -3 -3';
 336                                 self.maxs = '3 3 3';
 337                                 break;
 338                         case PROJECTILE_GRENADE_BOUNCING:
 339                                 self.mins = '-3 -3 -3';
 340                                 self.maxs = '3 3 3';
 341                                 self.move_movetype = MOVETYPE_BOUNCE;
 342                                 self.move_touch = func_null;
 343                                 self.move_bounce_factor = g_balance_mortar_bouncefactor;
 344                                 self.move_bounce_stopspeed = g_balance_mortar_bouncestop;
 345                                 break;
 346                         case PROJECTILE_SHAMBLER_LIGHTNING:
 347                                 self.mins = '-8 -8 -8';
 348                                 self.maxs = '8 8 8';
 349                                 self.scale = 2.5;
 350                                 self.avelocity = randomvec() * 720;
 351                                 break;
 352                         case PROJECTILE_MINE:
 353                                 self.mins = '-4 -4 -4';
 354                                 self.maxs = '4 4 4';
 355                                 break;
 356                         case PROJECTILE_PORTO_RED:
 357                                 self.colormod = '2 1 1';
 358                                 self.alphamod = 0.5;
 359                                 self.move_movetype = MOVETYPE_BOUNCE;
 360                                 self.move_touch = func_null;
 361                                 break;
 362                         case PROJECTILE_PORTO_BLUE:
 363                                 self.colormod = '1 1 2';
 364                                 self.alphamod = 0.5;
 365                                 self.move_movetype = MOVETYPE_BOUNCE;
 366                                 self.move_touch = func_null;
 367                                 break;
 368                         case PROJECTILE_HAGAR_BOUNCING:
 369                                 self.move_movetype = MOVETYPE_BOUNCE;
 370                                 self.move_touch = func_null;
 371                                 break;
 372                         case PROJECTILE_CRYLINK_BOUNCING:
 373                                 self.move_movetype = MOVETYPE_BOUNCE;
 374                                 self.move_touch = func_null;
 375                                 break;
 376                         case PROJECTILE_NAPALM_FOUNTAIN:
 377                         case PROJECTILE_FIREBALL:
 378                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/fireball_fly2.wav", VOL_BASE, ATTEN_NORM);
 379                                 self.mins = '-16 -16 -16';
 380                                 self.maxs = '16 16 16';
 381                                 break;
 382                         case PROJECTILE_FIREMINE:
 383                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/fireball_fly.wav", VOL_BASE, ATTEN_NORM);
 384                                 self.move_movetype = MOVETYPE_BOUNCE;
 385                                 self.move_touch = func_null;
 386                                 self.mins = '-4 -4 -4';
 387                                 self.maxs = '4 4 4';
 388                                 break;
 389                         case PROJECTILE_TAG:
 390                                 self.mins = '-2 -2 -2';
 391                                 self.maxs = '2 2 2';
 392                                 break;
 393                         case PROJECTILE_FLAC:
 394                                 self.mins = '-2 -2 -2';
 395                                 self.maxs = '2 2 2';
 396                                 break;
 397                         case PROJECTILE_SEEKER:
 398                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTEN_NORM);
 399                                 self.mins = '-4 -4 -4';
 400                                 self.maxs = '4 4 4';
 401                                 break;
 402             case PROJECTILE_RAPTORBOMB:
 403                                 self.mins = '-3 -3 -3';
 404                                 self.maxs = '3 3 3';
 405                                 break;
 406             case PROJECTILE_RAPTORBOMBLET:
 407                                 break;
 408             case PROJECTILE_RAPTORCANNON:
 409                                 break;
 410             case PROJECTILE_SPIDERROCKET:
 411                 loopsound(self, CH_SHOTS_SINGLE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTEN_NORM);
 412                                 break;
 413             case PROJECTILE_WAKIROCKET:
 414                 loopsound(self, CH_SHOTS_SINGLE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTEN_NORM);
 415                                 break;
 416             /*
 417             case PROJECTILE_WAKICANNON:
 418                                 break;
 419                         case PROJECTILE_BUMBLE_GUN:
 420                                 // only new engines support sound moving with object
 421                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/electro_fly.wav", VOL_BASE, ATTEN_NORM);
 422                                 self.mins = '0 0 -4';
 423                                 self.maxs = '0 0 -4';
 424                                 self.move_movetype = MOVETYPE_BOUNCE;
 425                                 self.move_touch = func_null;
 426                                 self.move_bounce_factor = g_balance_electro_secondary_bouncefactor;
 427                                 self.move_bounce_stopspeed = g_balance_electro_secondary_bouncestop;
 428                                 break;
 429                         */
 430                         default:
 431                                 break;
 432                 }
 433
 434                 if(Nade_IDFromProjectile(self.cnt) != 0)
 435                 {
 436                         int nade_type = Nade_IDFromProjectile(self.cnt);
 437                         self.mins = '-16 -16 -16';
 438                         self.maxs = '16 16 16';
 439                         self.colormod = Nade_Color(nade_type);
 440                         self.move_movetype = MOVETYPE_BOUNCE;
 441                         self.move_touch = func_null;
 442                         self.scale = 1.5;
 443                         self.avelocity = randomvec() * 720;
 444
 445                         if(nade_type == NADE_TYPE_TRANSLOCATE || nade_type == NADE_TYPE_SPAWN)
 446                                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 447                         else
 448                                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 449                 }
 450
 451                 setsize(self, self.mins, self.maxs);
 452         }
 453
 454         if(self.gravity)
 455         {
 456                 if(self.move_movetype == MOVETYPE_FLY)
 457                         self.move_movetype = MOVETYPE_TOSS;
 458                 if(self.move_movetype == MOVETYPE_BOUNCEMISSILE)
 459                         self.move_movetype = MOVETYPE_BOUNCE;
 460         }
 461         else
 462         {
 463                 if(self.move_movetype == MOVETYPE_TOSS)
 464                         self.move_movetype = MOVETYPE_FLY;
 465                 if(self.move_movetype == MOVETYPE_BOUNCE)
 466                         self.move_movetype = MOVETYPE_BOUNCEMISSILE;
 467         }
 468
 469         if(!(self.count & 0x80))
 470                 InterpolateOrigin_Note();
 471
 472         self.draw = Projectile_Draw;
 473         self.entremove = Ent_RemoveProjectile;
 474 }
 475
 476 void Projectile_Precache()
 477 {
 478         precache_model("models/ebomb.mdl");
 479         precache_model("models/elaser.mdl");
 480         precache_model("models/grenademodel.md3");
 481         precache_model("models/mine.md3");
 482         precache_model("models/hagarmissile.mdl");
 483         precache_model("models/hlac_bullet.md3");
 484         precache_model("models/laser.mdl");
 485         precache_model("models/plasmatrail.mdl");
 486         precache_model("models/rocket.md3");
 487         precache_model("models/tagrocket.md3");
 488         precache_model("models/tracer.mdl");
 489         precache_model("models/sphere/sphere.md3");
 490
 491         precache_model("models/weapons/v_ok_grenade.md3");
 492         precache_model("models/weapons/ok_rocket.md3");
 493
 494         precache_sound("weapons/electro_fly.wav");
 495         precache_sound("weapons/rocket_fly.wav");
 496         precache_sound("weapons/fireball_fly.wav");
 497         precache_sound("weapons/fireball_fly2.wav");
 498         precache_sound("weapons/tag_rocket_fly.wav");
 499
 500 }