Purge client/defs.qh
[xonotic/xonotic-data.pk3dir.git] / qcsrc / client / weapons / projectile.qc
1 #include "projectile.qh"
2
3 #include "../autocvars.qh"
4 #include "../main.qh"
5 #include <client/mutators/_mod.qh>
6
7 #include <common/constants.qh>
8 #include <common/effects/effect.qh>
9 #include <common/effects/all.qh>
10 #include <common/net_linked.qh>
11 #include <common/physics/movetypes/movetypes.qh>
12
13 #include <common/mutators/mutator/nades/nades.qh>
14
15 #include <lib/csqcmodel/interpolate.qh>
16
17 #include <lib/warpzone/anglestransform.qh>
18
19 .float alpha;
20 .float scale;
21 .vector colormod;
22
23 void SUB_Stop(entity this, entity toucher)
24 {
25         this.velocity = this.avelocity = '0 0 0';
26         set_movetype(this, MOVETYPE_NONE);
27 }
28
29 void Projectile_ResetTrail(entity this, vector to)
30 {
31         this.trail_oldorigin = to;
32         this.trail_oldtime = time;
33 }
34
35 void Projectile_DrawTrail(entity this, vector to)
36 {
37         vector from = this.trail_oldorigin;
38         // float t0 = this.trail_oldtime;
39         this.trail_oldorigin = to;
40         this.trail_oldtime = time;
41
42         // force the effect even for stationary firemine
43         if (this.cnt == PROJECTILE_FIREMINE)
44                 if (from == to)
45                         from.z += 1;
46
47         if (this.traileffect)
48         {
49                 particles_alphamin = particles_alphamax = particles_fade = sqrt(this.alpha);
50                 entity eff = REGISTRY_GET(Effects, this.traileffect);
51                 boxparticles(particleeffectnum(eff), this, from, to, this.velocity, this.velocity, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE | PARTICLES_DRAWASTRAIL);
52         }
53 }
54
55 void Projectile_Draw(entity this)
56 {
57         vector rot;
58         vector trailorigin;
59         int f;
60         bool drawn;
61         float t;
62         float a;
63
64         f = this.flags;
65
66         if (this.count & 0x80)
67         {
68                 // UNSET_ONGROUND(this);
69                 if (this.move_movetype == MOVETYPE_NONE || this.move_movetype == MOVETYPE_FLY)
70                         Movetype_Physics_NoMatchServer(this);
71                 // the trivial movetypes do not have to match the
72                 // server's ticrate as they are ticrate independent
73                 // NOTE: this assumption is only true if MOVETYPE_FLY
74                 // projectiles detonate on impact. If they continue
75                 // moving, we might still be ticrate dependent.
76                 else
77                         Movetype_Physics_MatchServer(this, autocvar_cl_projectiles_sloppy);
78                 if (!IS_ONGROUND(this))
79                         if (this.velocity != '0 0 0')
80                                 this.angles = vectoangles(this.velocity);
81         }
82         else
83         {
84                 InterpolateOrigin_Do(this);
85         }
86
87         if (this.count & 0x80)
88         {
89                 drawn = (time >= this.spawntime - 0.02);
90                 t = max(time, this.spawntime);
91         }
92         else
93         {
94                 drawn = (this.iflags & IFLAG_VALID);
95                 t = time;
96         }
97
98         if (!(f & FL_ONGROUND))
99         {
100                 rot = '0 0 0';
101                 switch (this.cnt)
102                 {
103                         /*
104                         case PROJECTILE_GRENADE:
105                             rot = '-2000 0 0'; // forward
106                             break;
107                         */
108                         case PROJECTILE_GRENADE_BOUNCING:
109                                 rot = '0 -1000 0'; // sideways
110                                 break;
111                         case PROJECTILE_HOOKBOMB:
112                                 rot = '1000 0 0';  // forward
113                                 break;
114                         case PROJECTILE_ROCKET:
115                                 rot = '0 0 720'; // spinning
116                                 break;
117                         default:
118                                 break;
119                 }
120
121                 if (Projectile_isnade(this.cnt))
122                         rot = this.avelocity;
123
124                 this.angles = AnglesTransform_ToAngles(AnglesTransform_Multiply(AnglesTransform_FromAngles(this.angles), rot * (t - this.spawntime)));
125         }
126
127         vector ang;
128         ang = this.angles;
129         ang.x = -ang.x;
130         makevectors(ang);
131
132         a = 1 - (time - this.fade_time) * this.fade_rate;
133         this.alpha = bound(0, this.alphamod * a, 1);
134         if (this.alpha <= 0)
135                 drawn = 0;
136         this.renderflags = 0;
137
138         trailorigin = this.origin;
139         switch (this.cnt)
140         {
141                 case PROJECTILE_GRENADE:
142                 case PROJECTILE_GRENADE_BOUNCING:
143                         trailorigin += v_right * 1 + v_forward * -10;
144                         break;
145                 default:
146                         break;
147         }
148
149         if (Projectile_isnade(this.cnt))
150                 trailorigin += v_up * 4;
151
152         if (drawn)
153                 Projectile_DrawTrail(this, trailorigin);
154         else
155                 Projectile_ResetTrail(this, trailorigin);
156
157         this.drawmask = 0;
158
159         if (!drawn)
160                 return;
161
162         switch (this.cnt)
163         {
164                 // Possibly add dlights here.
165                 default:
166                         break;
167         }
168
169         this.drawmask = MASK_NORMAL;
170 }
171
172 void loopsound(entity e, int ch, Sound samp, float vol, float attn)
173 {
174         TC(int, ch);
175         if (e.silent)
176                 return;
177
178         sound(e, ch, samp, vol, attn);
179         e.snd_looping = ch;
180 }
181
182 void Ent_RemoveProjectile(entity this)
183 {
184         if (this.count & 0x80)
185         {
186                 tracebox(this.origin, this.mins, this.maxs, this.origin + this.velocity * 0.05, MOVE_NORMAL, this);
187                 Projectile_DrawTrail(this, trace_endpos);
188         }
189 }
190
191 NET_HANDLE(ENT_CLIENT_PROJECTILE, bool isnew)
192 {
193         // projectile properties:
194         //   kind (interpolated, or clientside)
195         //
196         //   modelindex
197         //   origin
198         //   scale
199         //   if clientside:
200         //     velocity
201         //     gravity
202         //   soundindex (hardcoded list)
203         //   effects
204         //
205         // projectiles don't send angles, because they always follow the velocity
206
207         int f = ReadByte();
208         this.count = (f & 0x80);
209         this.flags |= FL_PROJECTILE;
210         this.iflags = (this.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES | IFLAG_ORIGIN;
211         this.solid = SOLID_TRIGGER;
212         // this.effects = EF_NOMODELFLAGS;
213
214         // this should make collisions with bmodels more exact, but it leads to
215         // projectiles no longer being able to lie on a bmodel
216         this.move_nomonsters = MOVE_WORLDONLY;
217         if (f & 0x40)
218                 SET_ONGROUND(this);
219         else
220                 UNSET_ONGROUND(this);
221
222         if (!this.move_time)
223         {
224                 // for some unknown reason, we don't need to care for
225                 // sv_gameplayfix_delayprojectiles here.
226                 this.move_time = time;
227                 this.spawntime = time;
228         }
229         else
230         {
231                 this.move_time = max(this.move_time, time);
232         }
233
234         if (!(this.count & 0x80))
235                 InterpolateOrigin_Undo(this);
236
237         if (f & 1)
238         {
239                 this.origin = ReadVector();
240                 setorigin(this, this.origin);
241                 if (this.count & 0x80)
242                 {
243                         this.velocity = ReadVector();
244                         if (f & 0x10)
245                                 this.gravity = ReadCoord();
246                         else
247                                 this.gravity = 0;  // none
248                 }
249
250                 if (time == this.spawntime || (this.count & 0x80) || (f & 0x08))
251                 {
252                         this.trail_oldorigin = this.origin;
253                         if (!(this.count & 0x80))
254                                 InterpolateOrigin_Reset(this);
255                 }
256
257                 if (f & 0x20)
258                 {
259                         this.fade_time = time + ReadByte() * ticrate;
260                         this.fade_rate = 1 / (ReadByte() * ticrate);
261                 }
262                 else
263                 {
264                         this.fade_time = 0;
265                         this.fade_rate = 0;
266                 }
267
268                 int proj_team = ReadByte();
269                 this.team = proj_team - 1;
270
271                 if(teamplay)
272                 {
273                         if(proj_team)
274                                 this.colormap = (this.team) * 0x11; // note: team - 1 on server (client uses different numbers)
275                         else
276                                 this.colormap = 0x00;
277                         this.colormap |= BIT(10); // RENDER_COLORMAPPED
278                 }
279                 else
280                         this.colormap = proj_team;
281                 // TODO: projectiles use glowmaps for their color, not teams
282                 #if 0
283                 if(this.colormap > 0)
284                         this.glowmod = colormapPaletteColor(this.colormap & 0x0F, true) * 2;
285                 else
286                         this.glowmod = '1 1 1';
287                 #endif
288         }
289
290         if (f & 2)
291         {
292                 this.cnt = ReadByte();
293
294                 this.silent = (this.cnt & 0x80);
295                 this.cnt = (this.cnt & 0x7F);
296
297                 this.scale = 1;
298                 this.traileffect = 0;
299                 switch (this.cnt)
300                 {
301 #define HANDLE(id) case PROJECTILE_##id: setmodel(this, MDL_PROJECTILE_##id);
302                         HANDLE(ELECTRO)            this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
303                         HANDLE(ROCKET)             this.traileffect = EFFECT_TR_ROCKET.m_id; this.scale = 2; break;
304                         HANDLE(CRYLINK)            this.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
305                         HANDLE(CRYLINK_BOUNCING)   this.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
306                         HANDLE(ELECTRO_BEAM)       this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
307                         HANDLE(GRENADE)            this.traileffect = EFFECT_TR_GRENADE.m_id; break;
308                         HANDLE(GRENADE_BOUNCING)   this.traileffect = EFFECT_TR_GRENADE.m_id; break;
309                         HANDLE(MINE)               this.traileffect = EFFECT_TR_GRENADE.m_id; break;
310                         HANDLE(BLASTER)            this.traileffect = EFFECT_Null.m_id; break;
311                         HANDLE(ARC_BOLT)           this.traileffect = EFFECT_Null.m_id; break;
312                         HANDLE(HLAC)               this.traileffect = EFFECT_Null.m_id; break;
313                         HANDLE(PORTO_RED)          this.traileffect = EFFECT_TR_WIZSPIKE.m_id; this.scale = 4; break;
314                         HANDLE(PORTO_BLUE)         this.traileffect = EFFECT_TR_WIZSPIKE.m_id; this.scale = 4; break;
315                         HANDLE(HOOKBOMB)           this.traileffect = EFFECT_TR_KNIGHTSPIKE.m_id; break;
316                         HANDLE(HAGAR)              this.traileffect = EFFECT_HAGAR_ROCKET.m_id; this.scale = 0.75; break;
317                         HANDLE(HAGAR_BOUNCING)     this.traileffect = EFFECT_HAGAR_ROCKET.m_id; this.scale = 0.75; break;
318                         HANDLE(FIREBALL)           this.modelindex = 0; this.traileffect = EFFECT_FIREBALL.m_id; break; // particle effect is good enough
319                         HANDLE(FIREMINE)           this.modelindex = 0; this.traileffect = EFFECT_FIREMINE.m_id; break; // particle effect is good enough
320                         HANDLE(TAG)                this.traileffect = EFFECT_TR_ROCKET.m_id; break;
321                         HANDLE(FLAC)               this.scale = 0.4; this.traileffect = EFFECT_FLAC_TRAIL.m_id; break;
322                         HANDLE(SEEKER)             this.traileffect = EFFECT_SEEKER_TRAIL.m_id; break;
323
324                         HANDLE(MAGE_SPIKE)         this.traileffect = EFFECT_TR_VORESPIKE.m_id; break;
325                         HANDLE(SHAMBLER_LIGHTNING) this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
326
327                         HANDLE(RAPTORBOMB)         this.gravity = 1; this.avelocity = '0 0 180'; this.traileffect = EFFECT_Null.m_id; break;
328                         HANDLE(RAPTORBOMBLET)      this.gravity = 1; this.avelocity = '0 0 180'; this.traileffect = EFFECT_Null.m_id; break;
329                         HANDLE(RAPTORCANNON)       this.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
330
331                         HANDLE(SPIDERROCKET)       this.traileffect = EFFECT_SPIDERBOT_ROCKET_TRAIL.m_id; break;
332                         HANDLE(WAKIROCKET)         this.traileffect = EFFECT_RACER_ROCKET_TRAIL.m_id; break;
333                         HANDLE(WAKICANNON)         this.traileffect = EFFECT_Null.m_id; break;
334
335                         HANDLE(BUMBLE_GUN)         this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
336                         HANDLE(BUMBLE_BEAM)        this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
337
338                         HANDLE(RPC)                this.traileffect = EFFECT_TR_ROCKET.m_id; break;
339
340                         HANDLE(ROCKETMINSTA_LASER) this.traileffect = EFFECT_ROCKETMINSTA_LASER(this.team).m_id; break;
341 #undef HANDLE
342                         default:
343                                 if (MUTATOR_CALLHOOK(Ent_Projectile, this))
344                                         break;
345
346                                 error("Received invalid CSQC projectile, can't work with this!");
347                                 break;
348                 }
349
350                 this.mins = '0 0 0';
351                 this.maxs = '0 0 0';
352                 this.colormod = '0 0 0';
353                 settouch(this, SUB_Stop);
354                 set_movetype(this, MOVETYPE_TOSS);
355                 this.alphamod = 1;
356
357                 switch (this.cnt)
358                 {
359                         case PROJECTILE_ELECTRO:
360                                 // only new engines support sound moving with object
361                                 loopsound(this, CH_SHOTS_SINGLE, SND_ELECTRO_FLY, VOL_BASE, ATTEN_NORM);
362                                 this.mins = '-4 -4 -4';
363                                 this.maxs = '4 4 4';
364                                 set_movetype(this, MOVETYPE_BOUNCE);
365                                 settouch(this, func_null);
366                                 this.bouncefactor = WEP_CVAR_SEC(electro, bouncefactor);
367                                 this.bouncestop = WEP_CVAR_SEC(electro, bouncestop);
368                                 break;
369                         case PROJECTILE_RPC:
370                         case PROJECTILE_ROCKET:
371                                 loopsound(this, CH_SHOTS_SINGLE, SND_ROCKET_FLY, VOL_BASE, ATTEN_NORM);
372                                 this.mins = '-3 -3 -3';
373                                 this.maxs = '3 3 3';
374                                 break;
375                         case PROJECTILE_GRENADE:
376                                 this.mins = '-3 -3 -3';
377                                 this.maxs = '3 3 3';
378                                 break;
379                         case PROJECTILE_GRENADE_BOUNCING:
380                                 this.mins = '-3 -3 -3';
381                                 this.maxs = '3 3 3';
382                                 set_movetype(this, MOVETYPE_BOUNCE);
383                                 settouch(this, func_null);
384                                 this.bouncefactor = WEP_CVAR(mortar, bouncefactor);
385                                 this.bouncestop = WEP_CVAR(mortar, bouncestop);
386                                 break;
387                         case PROJECTILE_SHAMBLER_LIGHTNING:
388                                 this.mins = '-8 -8 -8';
389                                 this.maxs = '8 8 8';
390                                 this.scale = 2.5;
391                                 this.avelocity = randomvec() * 720;
392                                 break;
393                         case PROJECTILE_MINE:
394                                 this.mins = '-4 -4 -4';
395                                 this.maxs = '4 4 4';
396                                 break;
397                         case PROJECTILE_PORTO_RED:
398                                 this.colormod = '2 1 1';
399                                 this.alphamod = 0.5;
400                                 set_movetype(this, MOVETYPE_BOUNCE);
401                                 settouch(this, func_null);
402                                 break;
403                         case PROJECTILE_PORTO_BLUE:
404                                 this.colormod = '1 1 2';
405                                 this.alphamod = 0.5;
406                                 set_movetype(this, MOVETYPE_BOUNCE);
407                                 settouch(this, func_null);
408                                 break;
409                         case PROJECTILE_HAGAR_BOUNCING:
410                                 set_movetype(this, MOVETYPE_BOUNCE);
411                                 settouch(this, func_null);
412                                 break;
413                         case PROJECTILE_CRYLINK_BOUNCING:
414                                 set_movetype(this, MOVETYPE_BOUNCE);
415                                 settouch(this, func_null);
416                                 break;
417                         case PROJECTILE_FIREBALL:
418                                 loopsound(this, CH_SHOTS_SINGLE, SND_FIREBALL_FLY2, VOL_BASE, ATTEN_NORM);
419                                 this.mins = '-16 -16 -16';
420                                 this.maxs = '16 16 16';
421                                 break;
422                         case PROJECTILE_FIREMINE:
423                                 loopsound(this, CH_SHOTS_SINGLE, SND_FIREBALL_FLY, VOL_BASE, ATTEN_NORM);
424                                 set_movetype(this, MOVETYPE_BOUNCE);
425                                 settouch(this, func_null);
426                                 this.mins = '-4 -4 -4';
427                                 this.maxs = '4 4 4';
428                                 break;
429                         case PROJECTILE_TAG:
430                                 this.mins = '-2 -2 -2';
431                                 this.maxs = '2 2 2';
432                                 break;
433                         case PROJECTILE_FLAC:
434                                 this.mins = '-2 -2 -2';
435                                 this.maxs = '2 2 2';
436                                 break;
437                         case PROJECTILE_SEEKER:
438                                 loopsound(this, CH_SHOTS_SINGLE, SND_TAG_ROCKET_FLY, VOL_BASE, ATTEN_NORM);
439                                 this.mins = '-4 -4 -4';
440                                 this.maxs = '4 4 4';
441                                 break;
442                         case PROJECTILE_RAPTORBOMB:
443                                 this.mins = '-3 -3 -3';
444                                 this.maxs = '3 3 3';
445                                 break;
446                         case PROJECTILE_RAPTORBOMBLET:
447                                 break;
448                         case PROJECTILE_RAPTORCANNON:
449                                 break;
450                         case PROJECTILE_SPIDERROCKET:
451                                 loopsound(this, CH_SHOTS_SINGLE, SND_TAG_ROCKET_FLY, VOL_BASE, ATTEN_NORM);
452                                 break;
453                         case PROJECTILE_WAKIROCKET:
454                                 loopsound(this, CH_SHOTS_SINGLE, SND_TAG_ROCKET_FLY, VOL_BASE, ATTEN_NORM);
455                                 break;
456                         /*
457                         case PROJECTILE_WAKICANNON:
458                             break;
459                         case PROJECTILE_BUMBLE_GUN:
460                             // only new engines support sound moving with object
461                             loopsound(this, CH_SHOTS_SINGLE, SND_ELECTRO_FLY, VOL_BASE, ATTEN_NORM);
462                             this.mins = '0 0 -4';
463                             this.maxs = '0 0 -4';
464                             this.move_movetype = MOVETYPE_BOUNCE;
465                             settouch(this, func_null);
466                             this.bouncefactor = WEP_CVAR_SEC(electro, bouncefactor);
467                             this.bouncestop = WEP_CVAR_SEC(electro, bouncestop);
468                             break;
469                         */
470                         default:
471                                 break;
472                 }
473
474                 MUTATOR_CALLHOOK(EditProjectile, this);
475
476                 setsize(this, this.mins, this.maxs);
477         }
478
479         return = true;
480
481         if (this.gravity)
482         {
483                 if (this.move_movetype == MOVETYPE_FLY)
484                         set_movetype(this, MOVETYPE_TOSS);
485                 if (this.move_movetype == MOVETYPE_BOUNCEMISSILE)
486                         set_movetype(this, MOVETYPE_BOUNCE);
487         }
488         else
489         {
490                 if (this.move_movetype == MOVETYPE_TOSS)
491                         set_movetype(this, MOVETYPE_FLY);
492                 if (this.move_movetype == MOVETYPE_BOUNCE)
493                         set_movetype(this, MOVETYPE_BOUNCEMISSILE);
494         }
495
496         if (!(this.count & 0x80))
497                 InterpolateOrigin_Note(this);
498
499         this.classname = "csqcprojectile";
500         this.draw = Projectile_Draw;
501         if (isnew) IL_PUSH(g_drawables, this);
502         this.entremove = Ent_RemoveProjectile;
503 }
504
505 PRECACHE(Projectiles)
506 {
507         MUTATOR_CALLHOOK(PrecacheProjectiles);
508 }