qcsrc/client/weapons/projectile.qc

   1 .vector iorigin1, iorigin2;
   2 .float spawntime;
   3 .vector trail_oldorigin;
   4 .float trail_oldtime;
   5 .float fade_time, fade_rate;
   6
   7 void SUB_Stop()
   8 {
   9         self.move_velocity = self.move_avelocity = '0 0 0';
  10         self.move_movetype = MOVETYPE_NONE;
  11 }
  12
  13 .float alphamod;
  14 .float count; // set if clientside projectile
  15 .float cnt; // sound index
  16 .float gravity;
  17 .float snd_looping;
  18 .float silent;
  19
  20 void Projectile_ResetTrail(vector to)
  21 {
  22         self.trail_oldorigin = to;
  23         self.trail_oldtime = time;
  24 }
  25
  26 void Projectile_DrawTrail(vector to)
  27 {
  28         vector from;
  29         float t0;
  30
  31         from = self.trail_oldorigin;
  32         t0 = self.trail_oldtime;
  33         self.trail_oldorigin = to;
  34         self.trail_oldtime = time;
  35
  36         // force the effect even for stationary firemine
  37         if(self.cnt == PROJECTILE_FIREMINE)
  38                 if(from == to)
  39                         from_z += 1;
  40
  41         if (self.traileffect)
  42         {
  43                 particles_alphamin = particles_alphamax = particles_fade = sqrt(self.alpha);
  44                 boxparticles(self.traileffect, self, from, to, self.velocity, self.velocity, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE | PARTICLES_DRAWASTRAIL);
  45         }
  46 }
  47
  48 void Projectile_Draw()
  49 {
  50         vector rot;
  51         vector trailorigin;
  52         float f;
  53         float drawn;
  54         float t;
  55         float a;
  56
  57         f = self.move_flags;
  58
  59         if(self.count & 0x80)
  60         {
  61                 //self.move_flags &= ~FL_ONGROUND;
  62                 if(self.move_movetype == MOVETYPE_NONE || self.move_movetype == MOVETYPE_FLY)
  63                         Movetype_Physics_NoMatchServer();
  64                         // the trivial movetypes do not have to match the
  65                         // server's ticrate as they are ticrate independent
  66                         // NOTE: this assumption is only true if MOVETYPE_FLY
  67                         // projectiles detonate on impact. If they continue
  68                         // moving, we might still be ticrate dependent.
  69                 else
  70                         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  71                 if(!(self.move_flags & FL_ONGROUND))
  72                         if(self.velocity != '0 0 0')
  73                                 self.move_angles = self.angles = vectoangles(self.velocity);
  74         }
  75         else
  76         {
  77                 InterpolateOrigin_Do();
  78         }
  79
  80         if(self.count & 0x80)
  81         {
  82                 drawn = (time >= self.spawntime - 0.02);
  83                 t = max(time, self.spawntime);
  84         }
  85         else
  86         {
  87                 drawn = (self.iflags & IFLAG_VALID);
  88                 t = time;
  89         }
  90
  91         if(!(f & FL_ONGROUND))
  92         {
  93                 rot = '0 0 0';
  94                 switch(self.cnt)
  95                 {
  96                         /*
  97                         case PROJECTILE_GRENADE:
  98                                 rot = '-2000 0 0'; // forward
  99                                 break;
 100                         */
 101                         case PROJECTILE_GRENADE_BOUNCING:
 102                                 rot = '0 -1000 0'; // sideways
 103                                 break;
 104                         case PROJECTILE_HOOKBOMB:
 105                                 rot = '1000 0 0'; // forward
 106                                 break;
 107                         default:
 108                                 break;
 109                 }
 110
 111                 if(Nade_IDFromProjectile(self.cnt) != 0)
 112                         rot = self.avelocity;
 113
 114                 self.angles = AnglesTransform_ToAngles(AnglesTransform_Multiply(AnglesTransform_FromAngles(self.angles), rot * (t - self.spawntime)));
 115         }
 116
 117         vector ang;
 118         ang = self.angles;
 119         ang_x = -ang_x;
 120         makevectors(ang);
 121
 122         a = 1 - (time - self.fade_time) * self.fade_rate;
 123         self.alpha = bound(0, self.alphamod * a, 1);
 124         if(self.alpha <= 0)
 125                 drawn = 0;
 126         self.renderflags = 0;
 127
 128         trailorigin = self.origin;
 129         switch(self.cnt)
 130         {
 131                 case PROJECTILE_GRENADE:
 132                 case PROJECTILE_GRENADE_BOUNCING:
 133                         trailorigin += v_right * 1 + v_forward * -10;
 134                         break;
 135                 default:
 136                         break;
 137         }
 138
 139         if(Nade_IDFromProjectile(self.cnt) != 0)
 140                 trailorigin += v_up * 4;
 141
 142         if(drawn)
 143                 Projectile_DrawTrail(trailorigin);
 144         else
 145                 Projectile_ResetTrail(trailorigin);
 146
 147         self.drawmask = 0;
 148
 149         if(!drawn)
 150                 return;
 151
 152         switch(self.cnt)
 153         {
 154                 // Possibly add dlights here.
 155                 default:
 156                         break;
 157         }
 158
 159         self.drawmask = MASK_NORMAL;
 160 }
 161
 162 void loopsound(entity e, float ch, string samp, float vol, float attn)
 163 {
 164         if(self.silent)
 165                 return;
 166
 167         sound(e, ch, samp, vol, attn);
 168         e.snd_looping = ch;
 169 }
 170
 171 void Ent_RemoveProjectile()
 172 {
 173         if(self.count & 0x80)
 174         {
 175                 tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.05, MOVE_NORMAL, self);
 176                 Projectile_DrawTrail(trace_endpos);
 177         }
 178 }
 179
 180 void Ent_Projectile()
 181 {
 182         float f;
 183
 184         // projectile properties:
 185         //   kind (interpolated, or clientside)
 186         //
 187         //   modelindex
 188         //   origin
 189         //   scale
 190         //   if clientside:
 191         //     velocity
 192         //     gravity
 193         //   soundindex (hardcoded list)
 194         //   effects
 195         //
 196         // projectiles don't send angles, because they always follow the velocity
 197
 198         f = ReadByte();
 199         self.count = (f & 0x80);
 200         self.iflags = (self.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES | IFLAG_ORIGIN;
 201         self.solid = SOLID_TRIGGER;
 202         //self.effects = EF_NOMODELFLAGS;
 203
 204         // this should make collisions with bmodels more exact, but it leads to
 205         // projectiles no longer being able to lie on a bmodel
 206         self.move_nomonsters = MOVE_WORLDONLY;
 207         if(f & 0x40)
 208                 self.move_flags |= FL_ONGROUND;
 209         else
 210                 self.move_flags &= ~FL_ONGROUND;
 211
 212         if(!self.move_time)
 213         {
 214                 // for some unknown reason, we don't need to care for
 215                 // sv_gameplayfix_delayprojectiles here.
 216                 self.move_time = time;
 217                 self.spawntime = time;
 218         }
 219         else
 220                 self.move_time = max(self.move_time, time);
 221
 222         if(!(self.count & 0x80))
 223                 InterpolateOrigin_Undo();
 224
 225         if(f & 1)
 226         {
 227                 self.origin_x = ReadCoord();
 228                 self.origin_y = ReadCoord();
 229                 self.origin_z = ReadCoord();
 230                 setorigin(self, self.origin);
 231                 if(self.count & 0x80)
 232                 {
 233                         self.velocity_x = ReadCoord();
 234                         self.velocity_y = ReadCoord();
 235                         self.velocity_z = ReadCoord();
 236                         if(f & 0x10)
 237                                 self.gravity = ReadCoord();
 238                         else
 239                                 self.gravity = 0; // none
 240                         self.move_origin = self.origin;
 241                         self.move_velocity = self.velocity;
 242                 }
 243
 244                 if(time == self.spawntime || (self.count & 0x80) || (f & 0x08))
 245                 {
 246                         self.trail_oldorigin = self.origin;
 247                         if(!(self.count & 0x80))
 248                                 InterpolateOrigin_Reset();
 249                 }
 250
 251                 if(f & 0x20)
 252                 {
 253                         self.fade_time = time + ReadByte() * ticrate;
 254                         self.fade_rate = 1 / (ReadByte() * ticrate);
 255                 }
 256                 else
 257                 {
 258                         self.fade_time = 0;
 259                         self.fade_rate = 0;
 260                 }
 261
 262                 self.team = ReadByte() - 1;
 263         }
 264
 265         if(f & 2)
 266         {
 267                 self.cnt = ReadByte();
 268
 269                 self.silent = (self.cnt & 0x80);
 270                 self.cnt = (self.cnt & 0x7F);
 271
 272                 self.scale = 1;
 273                 self.traileffect = 0;
 274                 switch(self.cnt)
 275                 {
 276                         case PROJECTILE_ELECTRO: setmodel(self, "models/ebomb.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 277                         case PROJECTILE_ROCKET: setmodel(self, "models/rocket.md3");self.traileffect = particleeffectnum("TR_ROCKET"); self.scale = 2; break;
 278                         case PROJECTILE_CRYLINK: setmodel(self, "models/plasmatrail.mdl");self.traileffect = particleeffectnum("TR_CRYLINKPLASMA"); break;
 279                         case PROJECTILE_CRYLINK_BOUNCING: setmodel(self, "models/plasmatrail.mdl");self.traileffect = particleeffectnum("TR_CRYLINKPLASMA"); break;
 280                         case PROJECTILE_ELECTRO_BEAM: setmodel(self, "models/elaser.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 281                         case PROJECTILE_GRENADE: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_GRENADE"); break;
 282                         case PROJECTILE_GRENADE_BOUNCING: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_GRENADE"); break;
 283                         case PROJECTILE_MINE: setmodel(self, "models/mine.md3");self.traileffect = particleeffectnum("TR_GRENADE"); break;
 284                         case PROJECTILE_BLASTER: setmodel(self, "models/laser.mdl");self.traileffect = particleeffectnum(""); break;
 285                         case PROJECTILE_HLAC: setmodel(self, "models/hlac_bullet.md3");self.traileffect = particleeffectnum(""); break;
 286                         case PROJECTILE_PORTO_RED: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_WIZSPIKE"); self.scale = 4; break;
 287                         case PROJECTILE_PORTO_BLUE: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_WIZSPIKE"); self.scale = 4; break;
 288                         case PROJECTILE_HOOKBOMB: setmodel(self, "models/grenademodel.md3");self.traileffect = particleeffectnum("TR_KNIGHTSPIKE"); break;
 289                         case PROJECTILE_HAGAR: setmodel(self, "models/hagarmissile.mdl");self.traileffect = particleeffectnum("tr_hagar"); self.scale = 0.75; break;
 290                         case PROJECTILE_HAGAR_BOUNCING: setmodel(self, "models/hagarmissile.mdl");self.traileffect = particleeffectnum("tr_hagar"); self.scale = 0.75; break;
 291                         case PROJECTILE_NAPALM_FOUNTAIN: //self.model = ""; self.modelindex = 0; self.traileffect = particleeffectnum("torch_small"); break;
 292                         case PROJECTILE_FIREBALL: self.model = ""; self.modelindex = 0; self.traileffect = particleeffectnum("fireball"); break; // particle effect is good enough
 293                         case PROJECTILE_FIREMINE: self.model = ""; self.modelindex = 0; self.traileffect = particleeffectnum("firemine"); break; // particle effect is good enough
 294                         case PROJECTILE_TAG: setmodel(self, "models/laser.mdl"); self.traileffect = particleeffectnum("TR_ROCKET"); break;
 295                         case PROJECTILE_FLAC: setmodel(self, "models/hagarmissile.mdl"); self.scale = 0.4; self.traileffect = particleeffectnum("TR_SEEKER"); break;
 296                         case PROJECTILE_SEEKER: setmodel(self, "models/tagrocket.md3"); self.traileffect = particleeffectnum("TR_SEEKER"); break;
 297
 298                         case PROJECTILE_MAGE_SPIKE: setmodel(self, "models/ebomb.mdl"); self.traileffect = particleeffectnum("TR_VORESPIKE"); break;
 299                         case PROJECTILE_SHAMBLER_LIGHTNING: setmodel(self, "models/ebomb.mdl"); self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 300
 301                         case PROJECTILE_RAPTORBOMB:    setmodel(self, "models/vehicles/clusterbomb.md3"); self.gravity = 1; self.avelocity = '0 0 180'; self.traileffect = particleeffectnum(""); break;
 302                         case PROJECTILE_RAPTORBOMBLET: setmodel(self, "models/vehicles/bomblet.md3");     self.gravity = 1; self.avelocity = '0 0 180'; self.traileffect = particleeffectnum(""); break;
 303                         case PROJECTILE_RAPTORCANNON:  setmodel(self, "models/plasmatrail.mdl"); self.traileffect = particleeffectnum("TR_CRYLINKPLASMA"); break;
 304
 305                         case PROJECTILE_SPIDERROCKET: setmodel(self, "models/vehicles/rocket02.md3"); self.traileffect = particleeffectnum("spiderbot_rocket_thrust"); break;
 306                         case PROJECTILE_WAKIROCKET:   setmodel(self, "models/vehicles/rocket01.md3");  self.traileffect = particleeffectnum("wakizashi_rocket_thrust"); break;
 307                         case PROJECTILE_WAKICANNON:   setmodel(self, "models/laser.mdl");  self.traileffect = particleeffectnum(""); break;
 308
 309                         case PROJECTILE_BUMBLE_GUN: setmodel(self, "models/elaser.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 310                         case PROJECTILE_BUMBLE_BEAM: setmodel(self, "models/elaser.mdl");self.traileffect = particleeffectnum("TR_NEXUIZPLASMA"); break;
 311
 312                         case PROJECTILE_RPC: setmodel(self, "models/weapons/ok_rocket.md3");self.traileffect = particleeffectnum("TR_ROCKET"); break;
 313
 314                         default:
 315                                 if(Nade_IDFromProjectile(self.cnt) != 0) { setmodel(self, "models/weapons/v_ok_grenade.md3");self.traileffect = particleeffectnum(Nade_TrailEffect(self.cnt, self.team)); break; }
 316                                 error("Received invalid CSQC projectile, can't work with this!");
 317                                 break;
 318                 }
 319
 320                 self.mins = '0 0 0';
 321                 self.maxs = '0 0 0';
 322                 self.colormod = '0 0 0';
 323                 self.move_touch = SUB_Stop;
 324                 self.move_movetype = MOVETYPE_TOSS;
 325                 self.alphamod = 1;
 326
 327                 switch(self.cnt)
 328                 {
 329                         case PROJECTILE_ELECTRO:
 330                                 // only new engines support sound moving with object
 331                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/electro_fly.wav", VOL_BASE, ATTEN_NORM);
 332                                 self.mins = '0 0 -4';
 333                                 self.maxs = '0 0 -4';
 334                                 self.move_movetype = MOVETYPE_BOUNCE;
 335                                 self.move_touch = func_null;
 336                                 self.move_bounce_factor = g_balance_electro_secondary_bouncefactor;
 337                                 self.move_bounce_stopspeed = g_balance_electro_secondary_bouncestop;
 338                                 break;
 339                         case PROJECTILE_RPC:
 340                         case PROJECTILE_ROCKET:
 341                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/rocket_fly.wav", VOL_BASE, ATTEN_NORM);
 342                                 self.mins = '-3 -3 -3';
 343                                 self.maxs = '3 3 3';
 344                                 break;
 345                         case PROJECTILE_GRENADE:
 346                                 self.mins = '-3 -3 -3';
 347                                 self.maxs = '3 3 3';
 348                                 break;
 349                         case PROJECTILE_GRENADE_BOUNCING:
 350                                 self.mins = '-3 -3 -3';
 351                                 self.maxs = '3 3 3';
 352                                 self.move_movetype = MOVETYPE_BOUNCE;
 353                                 self.move_touch = func_null;
 354                                 self.move_bounce_factor = g_balance_mortar_bouncefactor;
 355                                 self.move_bounce_stopspeed = g_balance_mortar_bouncestop;
 356                                 break;
 357                         case PROJECTILE_SHAMBLER_LIGHTNING:
 358                                 self.mins = '-8 -8 -8';
 359                                 self.maxs = '8 8 8';
 360                                 self.scale = 2.5;
 361                                 self.avelocity = randomvec() * 720;
 362                                 break;
 363                         case PROJECTILE_MINE:
 364                                 self.mins = '-4 -4 -4';
 365                                 self.maxs = '4 4 4';
 366                                 break;
 367                         case PROJECTILE_PORTO_RED:
 368                                 self.colormod = '2 1 1';
 369                                 self.alphamod = 0.5;
 370                                 self.move_movetype = MOVETYPE_BOUNCE;
 371                                 self.move_touch = func_null;
 372                                 break;
 373                         case PROJECTILE_PORTO_BLUE:
 374                                 self.colormod = '1 1 2';
 375                                 self.alphamod = 0.5;
 376                                 self.move_movetype = MOVETYPE_BOUNCE;
 377                                 self.move_touch = func_null;
 378                                 break;
 379                         case PROJECTILE_HAGAR_BOUNCING:
 380                                 self.move_movetype = MOVETYPE_BOUNCE;
 381                                 self.move_touch = func_null;
 382                                 break;
 383                         case PROJECTILE_CRYLINK_BOUNCING:
 384                                 self.move_movetype = MOVETYPE_BOUNCE;
 385                                 self.move_touch = func_null;
 386                                 break;
 387                         case PROJECTILE_NAPALM_FOUNTAIN:
 388                         case PROJECTILE_FIREBALL:
 389                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/fireball_fly2.wav", VOL_BASE, ATTEN_NORM);
 390                                 self.mins = '-16 -16 -16';
 391                                 self.maxs = '16 16 16';
 392                                 break;
 393                         case PROJECTILE_FIREMINE:
 394                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/fireball_fly.wav", VOL_BASE, ATTEN_NORM);
 395                                 self.move_movetype = MOVETYPE_BOUNCE;
 396                                 self.move_touch = func_null;
 397                                 self.mins = '-4 -4 -4';
 398                                 self.maxs = '4 4 4';
 399                                 break;
 400                         case PROJECTILE_TAG:
 401                                 self.mins = '-2 -2 -2';
 402                                 self.maxs = '2 2 2';
 403                                 break;
 404                         case PROJECTILE_FLAC:
 405                                 self.mins = '-2 -2 -2';
 406                                 self.maxs = '2 2 2';
 407                                 break;
 408                         case PROJECTILE_SEEKER:
 409                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTEN_NORM);
 410                                 self.mins = '-4 -4 -4';
 411                                 self.maxs = '4 4 4';
 412                                 break;
 413             case PROJECTILE_RAPTORBOMB:
 414                                 self.mins = '-3 -3 -3';
 415                                 self.maxs = '3 3 3';
 416                                 break;
 417             case PROJECTILE_RAPTORBOMBLET:
 418                                 break;
 419             case PROJECTILE_RAPTORCANNON:
 420                                 break;
 421             case PROJECTILE_SPIDERROCKET:
 422                 loopsound(self, CH_SHOTS_SINGLE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTEN_NORM);
 423                                 break;
 424             case PROJECTILE_WAKIROCKET:
 425                 loopsound(self, CH_SHOTS_SINGLE, "weapons/tag_rocket_fly.wav", VOL_BASE, ATTEN_NORM);
 426                                 break;
 427             /*
 428             case PROJECTILE_WAKICANNON:
 429                                 break;
 430                         case PROJECTILE_BUMBLE_GUN:
 431                                 // only new engines support sound moving with object
 432                                 loopsound(self, CH_SHOTS_SINGLE, "weapons/electro_fly.wav", VOL_BASE, ATTEN_NORM);
 433                                 self.mins = '0 0 -4';
 434                                 self.maxs = '0 0 -4';
 435                                 self.move_movetype = MOVETYPE_BOUNCE;
 436                                 self.move_touch = func_null;
 437                                 self.move_bounce_factor = g_balance_electro_secondary_bouncefactor;
 438                                 self.move_bounce_stopspeed = g_balance_electro_secondary_bouncestop;
 439                                 break;
 440                         */
 441                         default:
 442                                 break;
 443                 }
 444
 445                 if(Nade_IDFromProjectile(self.cnt) != 0)
 446                 {
 447                         self.mins = '-16 -16 -16';
 448                         self.maxs = '16 16 16';
 449                         self.colormod = Nade_Color(Nade_IDFromProjectile(self.cnt));
 450                         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 451                         self.move_movetype = MOVETYPE_BOUNCE;
 452                         self.move_touch = func_null;
 453                         self.scale = 1.5;
 454                         self.avelocity = randomvec() * 720;
 455
 456                         if(Nade_IDFromProjectile(self.cnt) == NADE_TYPE_TRANSLOCATE)
 457                                 self.solid = SOLID_TRIGGER;
 458                 }
 459
 460                 setsize(self, self.mins, self.maxs);
 461         }
 462
 463         if(self.gravity)
 464         {
 465                 if(self.move_movetype == MOVETYPE_FLY)
 466                         self.move_movetype = MOVETYPE_TOSS;
 467                 if(self.move_movetype == MOVETYPE_BOUNCEMISSILE)
 468                         self.move_movetype = MOVETYPE_BOUNCE;
 469         }
 470         else
 471         {
 472                 if(self.move_movetype == MOVETYPE_TOSS)
 473                         self.move_movetype = MOVETYPE_FLY;
 474                 if(self.move_movetype == MOVETYPE_BOUNCE)
 475                         self.move_movetype = MOVETYPE_BOUNCEMISSILE;
 476         }
 477
 478         if(!(self.count & 0x80))
 479                 InterpolateOrigin_Note();
 480
 481         self.draw = Projectile_Draw;
 482         self.entremove = Ent_RemoveProjectile;
 483 }
 484
 485 void Projectile_Precache()
 486 {
 487         precache_model("models/ebomb.mdl");
 488         precache_model("models/elaser.mdl");
 489         precache_model("models/grenademodel.md3");
 490         precache_model("models/mine.md3");
 491         precache_model("models/hagarmissile.mdl");
 492         precache_model("models/hlac_bullet.md3");
 493         precache_model("models/laser.mdl");
 494         precache_model("models/plasmatrail.mdl");
 495         precache_model("models/rocket.md3");
 496         precache_model("models/tagrocket.md3");
 497         precache_model("models/tracer.mdl");
 498         precache_model("models/sphere/sphere.md3");
 499
 500         precache_model("models/weapons/v_ok_grenade.md3");
 501         precache_model("models/weapons/ok_rocket.md3");
 502
 503         precache_sound("weapons/electro_fly.wav");
 504         precache_sound("weapons/rocket_fly.wav");
 505         precache_sound("weapons/fireball_fly.wav");
 506         precache_sound("weapons/fireball_fly2.wav");
 507         precache_sound("weapons/tag_rocket_fly.wav");
 508
 509 }