qcsrc/client/weapons/projectile.qc

   1 #include "projectile.qh"
   2
   3 #include "../autocvars.qh"
   4 #include "../defs.qh"
   5 #include "../main.qh"
   6 #include "../mutators/events.qh"
   7
   8 #include "../../common/constants.qh"
   9 #include "../../common/nades/all.qh"
  10 #include "../../common/movetypes/movetypes.qh"
  11
  12 #include "../../lib/csqcmodel/interpolate.qh"
  13
  14 #include "../../lib/warpzone/anglestransform.qh"
  15
  16 .float alpha;
  17 .float scale;
  18 .vector colormod;
  19
  20 void SUB_Stop()
  21 {SELFPARAM();
  22         self.move_velocity = self.move_avelocity = '0 0 0';
  23         self.move_movetype = MOVETYPE_NONE;
  24 }
  25
  26 void Projectile_ResetTrail(entity this, vector to)
  27 {
  28         this.trail_oldorigin = to;
  29         this.trail_oldtime = time;
  30 }
  31
  32 void Projectile_DrawTrail(entity this, vector to)
  33 {
  34         vector from = this.trail_oldorigin;
  35         // float t0 = this.trail_oldtime;
  36         this.trail_oldorigin = to;
  37         this.trail_oldtime = time;
  38
  39         // force the effect even for stationary firemine
  40         if(this.cnt == PROJECTILE_FIREMINE)
  41                 if(from == to)
  42                         from.z += 1;
  43
  44         if (this.traileffect)
  45         {
  46                 particles_alphamin = particles_alphamax = particles_fade = sqrt(this.alpha);
  47                 boxparticles(particleeffectnum(Effects[this.traileffect]), this, from, to, this.velocity, this.velocity, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE | PARTICLES_DRAWASTRAIL);
  48         }
  49 }
  50
  51 void Projectile_Draw(entity this)
  52 {
  53         vector rot;
  54         vector trailorigin;
  55         int f;
  56         bool drawn;
  57         float t;
  58         float a;
  59
  60         f = self.move_flags;
  61
  62         if(self.count & 0x80)
  63         {
  64                 //self.move_flags &= ~FL_ONGROUND;
  65                 if(self.move_movetype == MOVETYPE_NONE || self.move_movetype == MOVETYPE_FLY)
  66                         Movetype_Physics_NoMatchServer();
  67                         // the trivial movetypes do not have to match the
  68                         // server's ticrate as they are ticrate independent
  69                         // NOTE: this assumption is only true if MOVETYPE_FLY
  70                         // projectiles detonate on impact. If they continue
  71                         // moving, we might still be ticrate dependent.
  72                 else
  73                         Movetype_Physics_MatchServer(autocvar_cl_projectiles_sloppy);
  74                 if(!(self.move_flags & FL_ONGROUND))
  75                         if(self.velocity != '0 0 0')
  76                                 self.move_angles = self.angles = vectoangles(self.velocity);
  77         }
  78         else
  79         {
  80                 InterpolateOrigin_Do();
  81         }
  82
  83         if(self.count & 0x80)
  84         {
  85                 drawn = (time >= self.spawntime - 0.02);
  86                 t = max(time, self.spawntime);
  87         }
  88         else
  89         {
  90                 drawn = (self.iflags & IFLAG_VALID);
  91                 t = time;
  92         }
  93
  94         if(!(f & FL_ONGROUND))
  95         {
  96                 rot = '0 0 0';
  97                 switch(self.cnt)
  98                 {
  99                         /*
 100                         case PROJECTILE_GRENADE:
 101                                 rot = '-2000 0 0'; // forward
 102                                 break;
 103                         */
 104                         case PROJECTILE_GRENADE_BOUNCING:
 105                                 rot = '0 -1000 0'; // sideways
 106                                 break;
 107                         case PROJECTILE_HOOKBOMB:
 108                                 rot = '1000 0 0'; // forward
 109                                 break;
 110                         default:
 111                                 break;
 112                 }
 113
 114                 if(Nade_FromProjectile(self.cnt) != NADE_TYPE_Null)
 115                         rot = self.avelocity;
 116
 117                 self.angles = AnglesTransform_ToAngles(AnglesTransform_Multiply(AnglesTransform_FromAngles(self.angles), rot * (t - self.spawntime)));
 118         }
 119
 120         vector ang;
 121         ang = self.angles;
 122         ang.x = -ang.x;
 123         makevectors(ang);
 124
 125         a = 1 - (time - self.fade_time) * self.fade_rate;
 126         self.alpha = bound(0, self.alphamod * a, 1);
 127         if(self.alpha <= 0)
 128                 drawn = 0;
 129         self.renderflags = 0;
 130
 131         trailorigin = self.origin;
 132         switch(self.cnt)
 133         {
 134                 case PROJECTILE_GRENADE:
 135                 case PROJECTILE_GRENADE_BOUNCING:
 136                         trailorigin += v_right * 1 + v_forward * -10;
 137                         break;
 138                 default:
 139                         break;
 140         }
 141
 142         if(Nade_FromProjectile(self.cnt) != NADE_TYPE_Null)
 143                 trailorigin += v_up * 4;
 144
 145         if(drawn)
 146                 Projectile_DrawTrail(self, trailorigin);
 147         else
 148                 Projectile_ResetTrail(self, trailorigin);
 149
 150         self.drawmask = 0;
 151
 152         if(!drawn)
 153                 return;
 154
 155         switch(self.cnt)
 156         {
 157                 // Possibly add dlights here.
 158                 default:
 159                         break;
 160         }
 161
 162         self.drawmask = MASK_NORMAL;
 163 }
 164
 165 void loopsound(entity e, int ch, string samp, float vol, float attn)
 166 {SELFPARAM();
 167         if(self.silent)
 168                 return;
 169
 170         _sound(e, ch, samp, vol, attn);
 171         e.snd_looping = ch;
 172 }
 173
 174 void Ent_RemoveProjectile()
 175 {SELFPARAM();
 176         if(self.count & 0x80)
 177         {
 178                 tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.05, MOVE_NORMAL, self);
 179                 Projectile_DrawTrail(self, trace_endpos);
 180         }
 181 }
 182
 183 void Ent_Projectile()
 184 {SELFPARAM();
 185         int f;
 186
 187         // projectile properties:
 188         //   kind (interpolated, or clientside)
 189         //
 190         //   modelindex
 191         //   origin
 192         //   scale
 193         //   if clientside:
 194         //     velocity
 195         //     gravity
 196         //   soundindex (hardcoded list)
 197         //   effects
 198         //
 199         // projectiles don't send angles, because they always follow the velocity
 200
 201         f = ReadByte();
 202         self.count = (f & 0x80);
 203         self.iflags = (self.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES | IFLAG_ORIGIN;
 204         self.solid = SOLID_TRIGGER;
 205         //self.effects = EF_NOMODELFLAGS;
 206
 207         // this should make collisions with bmodels more exact, but it leads to
 208         // projectiles no longer being able to lie on a bmodel
 209         self.move_nomonsters = MOVE_WORLDONLY;
 210         if(f & 0x40)
 211                 self.move_flags |= FL_ONGROUND;
 212         else
 213                 self.move_flags &= ~FL_ONGROUND;
 214
 215         if(!self.move_time)
 216         {
 217                 // for some unknown reason, we don't need to care for
 218                 // sv_gameplayfix_delayprojectiles here.
 219                 self.move_time = time;
 220                 self.spawntime = time;
 221         }
 222         else
 223                 self.move_time = max(self.move_time, time);
 224
 225         if(!(self.count & 0x80))
 226                 InterpolateOrigin_Undo();
 227
 228         if(f & 1)
 229         {
 230                 self.origin_x = ReadCoord();
 231                 self.origin_y = ReadCoord();
 232                 self.origin_z = ReadCoord();
 233                 setorigin(self, self.origin);
 234                 if(self.count & 0x80)
 235                 {
 236                         self.velocity_x = ReadCoord();
 237                         self.velocity_y = ReadCoord();
 238                         self.velocity_z = ReadCoord();
 239                         if(f & 0x10)
 240                                 self.gravity = ReadCoord();
 241                         else
 242                                 self.gravity = 0; // none
 243                         self.move_origin = self.origin;
 244                         self.move_velocity = self.velocity;
 245                 }
 246
 247                 if(time == self.spawntime || (self.count & 0x80) || (f & 0x08))
 248                 {
 249                         self.trail_oldorigin = self.origin;
 250                         if(!(self.count & 0x80))
 251                                 InterpolateOrigin_Reset();
 252                 }
 253
 254                 if(f & 0x20)
 255                 {
 256                         self.fade_time = time + ReadByte() * ticrate;
 257                         self.fade_rate = 1 / (ReadByte() * ticrate);
 258                 }
 259                 else
 260                 {
 261                         self.fade_time = 0;
 262                         self.fade_rate = 0;
 263                 }
 264
 265                 self.team = ReadByte() - 1;
 266         }
 267
 268         if(f & 2)
 269         {
 270                 self.cnt = ReadByte();
 271
 272                 self.silent = (self.cnt & 0x80);
 273                 self.cnt = (self.cnt & 0x7F);
 274
 275                 self.scale = 1;
 276                 self.traileffect = 0;
 277                 switch (self.cnt) {
 278 #define CASE(id) case PROJECTILE_##id: setmodel(self, MDL_PROJECTILE_##id);
 279                         CASE(ELECTRO)            self.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 280                         CASE(ROCKET)             self.traileffect = EFFECT_TR_ROCKET.m_id; self.scale = 2; break;
 281                         CASE(CRYLINK)            self.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
 282                         CASE(CRYLINK_BOUNCING)   self.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
 283                         CASE(ELECTRO_BEAM)       self.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 284                         CASE(GRENADE)            self.traileffect = EFFECT_TR_GRENADE.m_id; break;
 285                         CASE(GRENADE_BOUNCING)   self.traileffect = EFFECT_TR_GRENADE.m_id; break;
 286                         CASE(MINE)               self.traileffect = EFFECT_TR_GRENADE.m_id; break;
 287                         CASE(BLASTER)            self.traileffect = EFFECT_Null.m_id; break;
 288                         CASE(HLAC)               self.traileffect = EFFECT_Null.m_id; break;
 289                         CASE(PORTO_RED)          self.traileffect = EFFECT_TR_WIZSPIKE.m_id; self.scale = 4; break;
 290                         CASE(PORTO_BLUE)         self.traileffect = EFFECT_TR_WIZSPIKE.m_id; self.scale = 4; break;
 291                         CASE(HOOKBOMB)           self.traileffect = EFFECT_TR_KNIGHTSPIKE.m_id; break;
 292                         CASE(HAGAR)              self.traileffect = EFFECT_HAGAR_ROCKET.m_id; self.scale = 0.75; break;
 293                         CASE(HAGAR_BOUNCING)     self.traileffect = EFFECT_HAGAR_ROCKET.m_id; self.scale = 0.75; break;
 294                         CASE(NAPALM_FOUNTAIN)    // fallthrough // sself.modelindex = 0; self.traileffect = _particleeffectnum("torch_small"); break;
 295                         CASE(FIREBALL)           self.modelindex = 0; self.traileffect = EFFECT_FIREBALL.m_id; break; // particle effect is good enough
 296                         CASE(FIREMINE)           self.modelindex = 0; self.traileffect = EFFECT_FIREMINE.m_id; break; // particle effect is good enough
 297                         CASE(TAG)                self.traileffect = EFFECT_TR_ROCKET.m_id; break;
 298                         CASE(FLAC)               self.scale = 0.4; self.traileffect = EFFECT_FLAC_TRAIL.m_id; break;
 299                         CASE(SEEKER)             self.traileffect = EFFECT_SEEKER_TRAIL.m_id; break;
 300
 301                         CASE(MAGE_SPIKE)         self.traileffect = EFFECT_TR_VORESPIKE.m_id; break;
 302                         CASE(SHAMBLER_LIGHTNING) self.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 303
 304                         CASE(RAPTORBOMB)         self.gravity = 1; self.avelocity = '0 0 180'; self.traileffect = EFFECT_Null.m_id; break;
 305                         CASE(RAPTORBOMBLET)      self.gravity = 1; self.avelocity = '0 0 180'; self.traileffect = EFFECT_Null.m_id; break;
 306                         CASE(RAPTORCANNON)       self.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
 307
 308                         CASE(SPIDERROCKET)       self.traileffect = EFFECT_SPIDERBOT_ROCKET_TRAIL.m_id; break;
 309                         CASE(WAKIROCKET)         self.traileffect = EFFECT_RACER_ROCKET_TRAIL.m_id; break;
 310                         CASE(WAKICANNON)         self.traileffect = EFFECT_Null.m_id; break;
 311
 312                         CASE(BUMBLE_GUN)         self.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 313                         CASE(BUMBLE_BEAM)        self.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 314
 315                         CASE(RPC)                self.traileffect = EFFECT_TR_ROCKET.m_id; break;
 316
 317                         CASE(ROCKETMINSTA_LASER) self.traileffect = EFFECT_ROCKETMINSTA_LASER(self.team).m_id; break;
 318 #undef CASE
 319                         default:
 320                                 if(MUTATOR_CALLHOOK(Ent_Projectile, self))
 321                                         break;
 322
 323                                 if (Nade_FromProjectile(self.cnt) != NADE_TYPE_Null)
 324                                 {
 325                                         setmodel(self, MDL_PROJECTILE_NADE);
 326                                         entity trail = Nade_TrailEffect(self.cnt, self.team);
 327                                         if (trail.eent_eff_name) self.traileffect = trail.m_id;
 328                                         break;
 329                                 }
 330                                 error("Received invalid CSQC projectile, can't work with this!");
 331                                 break;
 332                 }
 333
 334                 self.mins = '0 0 0';
 335                 self.maxs = '0 0 0';
 336                 self.colormod = '0 0 0';
 337                 self.move_touch = SUB_Stop;
 338                 self.move_movetype = MOVETYPE_TOSS;
 339                 self.alphamod = 1;
 340
 341                 switch(self.cnt)
 342                 {
 343                         case PROJECTILE_ELECTRO:
 344                                 // only new engines support sound moving with object
 345                                 loopsound(self, CH_SHOTS_SINGLE, SND(ELECTRO_FLY), VOL_BASE, ATTEN_NORM);
 346                                 self.mins = '0 0 -4';
 347                                 self.maxs = '0 0 -4';
 348                                 self.move_movetype = MOVETYPE_BOUNCE;
 349                                 self.move_touch = func_null;
 350                                 self.move_bounce_factor = g_balance_electro_secondary_bouncefactor;
 351                                 self.move_bounce_stopspeed = g_balance_electro_secondary_bouncestop;
 352                                 break;
 353                         case PROJECTILE_RPC:
 354                         case PROJECTILE_ROCKET:
 355                                 loopsound(self, CH_SHOTS_SINGLE, SND(ROCKET_FLY), VOL_BASE, ATTEN_NORM);
 356                                 self.mins = '-3 -3 -3';
 357                                 self.maxs = '3 3 3';
 358                                 break;
 359                         case PROJECTILE_GRENADE:
 360                                 self.mins = '-3 -3 -3';
 361                                 self.maxs = '3 3 3';
 362                                 break;
 363                         case PROJECTILE_GRENADE_BOUNCING:
 364                                 self.mins = '-3 -3 -3';
 365                                 self.maxs = '3 3 3';
 366                                 self.move_movetype = MOVETYPE_BOUNCE;
 367                                 self.move_touch = func_null;
 368                                 self.move_bounce_factor = g_balance_mortar_bouncefactor;
 369                                 self.move_bounce_stopspeed = g_balance_mortar_bouncestop;
 370                                 break;
 371                         case PROJECTILE_SHAMBLER_LIGHTNING:
 372                                 self.mins = '-8 -8 -8';
 373                                 self.maxs = '8 8 8';
 374                                 self.scale = 2.5;
 375                                 self.avelocity = randomvec() * 720;
 376                                 break;
 377                         case PROJECTILE_MINE:
 378                                 self.mins = '-4 -4 -4';
 379                                 self.maxs = '4 4 4';
 380                                 break;
 381                         case PROJECTILE_PORTO_RED:
 382                                 self.colormod = '2 1 1';
 383                                 self.alphamod = 0.5;
 384                                 self.move_movetype = MOVETYPE_BOUNCE;
 385                                 self.move_touch = func_null;
 386                                 break;
 387                         case PROJECTILE_PORTO_BLUE:
 388                                 self.colormod = '1 1 2';
 389                                 self.alphamod = 0.5;
 390                                 self.move_movetype = MOVETYPE_BOUNCE;
 391                                 self.move_touch = func_null;
 392                                 break;
 393                         case PROJECTILE_HAGAR_BOUNCING:
 394                                 self.move_movetype = MOVETYPE_BOUNCE;
 395                                 self.move_touch = func_null;
 396                                 break;
 397                         case PROJECTILE_CRYLINK_BOUNCING:
 398                                 self.move_movetype = MOVETYPE_BOUNCE;
 399                                 self.move_touch = func_null;
 400                                 break;
 401                         case PROJECTILE_NAPALM_FOUNTAIN:
 402                         case PROJECTILE_FIREBALL:
 403                                 loopsound(self, CH_SHOTS_SINGLE, SND(FIREBALL_FLY2), VOL_BASE, ATTEN_NORM);
 404                                 self.mins = '-16 -16 -16';
 405                                 self.maxs = '16 16 16';
 406                                 break;
 407                         case PROJECTILE_FIREMINE:
 408                                 loopsound(self, CH_SHOTS_SINGLE, SND(FIREBALL_FLY), VOL_BASE, ATTEN_NORM);
 409                                 self.move_movetype = MOVETYPE_BOUNCE;
 410                                 self.move_touch = func_null;
 411                                 self.mins = '-4 -4 -4';
 412                                 self.maxs = '4 4 4';
 413                                 break;
 414                         case PROJECTILE_TAG:
 415                                 self.mins = '-2 -2 -2';
 416                                 self.maxs = '2 2 2';
 417                                 break;
 418                         case PROJECTILE_FLAC:
 419                                 self.mins = '-2 -2 -2';
 420                                 self.maxs = '2 2 2';
 421                                 break;
 422                         case PROJECTILE_SEEKER:
 423                                 loopsound(self, CH_SHOTS_SINGLE, SND(TAG_ROCKET_FLY), VOL_BASE, ATTEN_NORM);
 424                                 self.mins = '-4 -4 -4';
 425                                 self.maxs = '4 4 4';
 426                                 break;
 427             case PROJECTILE_RAPTORBOMB:
 428                                 self.mins = '-3 -3 -3';
 429                                 self.maxs = '3 3 3';
 430                                 break;
 431             case PROJECTILE_RAPTORBOMBLET:
 432                                 break;
 433             case PROJECTILE_RAPTORCANNON:
 434                                 break;
 435             case PROJECTILE_SPIDERROCKET:
 436                 loopsound(self, CH_SHOTS_SINGLE, SND(TAG_ROCKET_FLY), VOL_BASE, ATTEN_NORM);
 437                                 break;
 438             case PROJECTILE_WAKIROCKET:
 439                 loopsound(self, CH_SHOTS_SINGLE, SND(TAG_ROCKET_FLY), VOL_BASE, ATTEN_NORM);
 440                                 break;
 441             /*
 442             case PROJECTILE_WAKICANNON:
 443                                 break;
 444                         case PROJECTILE_BUMBLE_GUN:
 445                                 // only new engines support sound moving with object
 446                                 loopsound(self, CH_SHOTS_SINGLE, SND(ELECTRO_FLY), VOL_BASE, ATTEN_NORM);
 447                                 self.mins = '0 0 -4';
 448                                 self.maxs = '0 0 -4';
 449                                 self.move_movetype = MOVETYPE_BOUNCE;
 450                                 self.move_touch = func_null;
 451                                 self.move_bounce_factor = g_balance_electro_secondary_bouncefactor;
 452                                 self.move_bounce_stopspeed = g_balance_electro_secondary_bouncestop;
 453                                 break;
 454                         */
 455                         default:
 456                                 break;
 457                 }
 458
 459                 if(Nade_FromProjectile(self.cnt) != NADE_TYPE_Null)
 460                 {
 461                         entity nade_type = Nade_FromProjectile(self.cnt);
 462                         self.mins = '-16 -16 -16';
 463                         self.maxs = '16 16 16';
 464                         self.colormod = nade_type.m_color;
 465                         self.move_movetype = MOVETYPE_BOUNCE;
 466                         self.move_touch = func_null;
 467                         self.scale = 1.5;
 468                         self.avelocity = randomvec() * 720;
 469
 470                         if(nade_type == NADE_TYPE_TRANSLOCATE || nade_type == NADE_TYPE_SPAWN)
 471                                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 472                         else
 473                                 self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY;
 474                 }
 475
 476                 MUTATOR_CALLHOOK(EditProjectile, self);
 477
 478                 setsize(self, self.mins, self.maxs);
 479         }
 480
 481         if(self.gravity)
 482         {
 483                 if(self.move_movetype == MOVETYPE_FLY)
 484                         self.move_movetype = MOVETYPE_TOSS;
 485                 if(self.move_movetype == MOVETYPE_BOUNCEMISSILE)
 486                         self.move_movetype = MOVETYPE_BOUNCE;
 487         }
 488         else
 489         {
 490                 if(self.move_movetype == MOVETYPE_TOSS)
 491                         self.move_movetype = MOVETYPE_FLY;
 492                 if(self.move_movetype == MOVETYPE_BOUNCE)
 493                         self.move_movetype = MOVETYPE_BOUNCEMISSILE;
 494         }
 495
 496         if(!(self.count & 0x80))
 497                 InterpolateOrigin_Note();
 498
 499         self.classname = "csqcprojectile";
 500         self.draw = Projectile_Draw;
 501         self.entremove = Ent_RemoveProjectile;
 502 }
 503
 504 void Projectile_Precache()
 505 {
 506         MUTATOR_CALLHOOK(PrecacheProjectiles);
 507 }