qcsrc/client/weapons/projectile.qc

   1 #include "projectile.qh"
   2
   3 #include "../autocvars.qh"
   4 #include "../defs.qh"
   5 #include "../main.qh"
   6 #include "../mutators/events.qh"
   7
   8 #include <common/constants.qh>
   9 #include <common/physics/movetypes/movetypes.qh>
  10
  11 #include <lib/csqcmodel/interpolate.qh>
  12
  13 #include <lib/warpzone/anglestransform.qh>
  14
  15 .float alpha;
  16 .float scale;
  17 .vector colormod;
  18
  19 void SUB_Stop(entity this)
  20 {
  21         this.move_velocity = this.move_avelocity = '0 0 0';
  22         this.move_movetype = MOVETYPE_NONE;
  23 }
  24
  25 void Projectile_ResetTrail(entity this, vector to)
  26 {
  27         this.trail_oldorigin = to;
  28         this.trail_oldtime = time;
  29 }
  30
  31 void Projectile_DrawTrail(entity this, vector to)
  32 {
  33         vector from = this.trail_oldorigin;
  34         // float t0 = this.trail_oldtime;
  35         this.trail_oldorigin = to;
  36         this.trail_oldtime = time;
  37
  38         // force the effect even for stationary firemine
  39         if (this.cnt == PROJECTILE_FIREMINE)
  40                 if (from == to)
  41                         from.z += 1;
  42
  43         if (this.traileffect)
  44         {
  45                 particles_alphamin = particles_alphamax = particles_fade = sqrt(this.alpha);
  46                 boxparticles(particleeffectnum(Effects_from(this.traileffect)), this, from, to, this.velocity, this.velocity, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE | PARTICLES_DRAWASTRAIL);
  47         }
  48 }
  49
  50 bool Projectile_isnade(int proj); // TODO: remove
  51
  52 void Projectile_Draw(entity this)
  53 {
  54         vector rot;
  55         vector trailorigin;
  56         int f;
  57         bool drawn;
  58         float t;
  59         float a;
  60
  61         f = this.move_flags;
  62
  63         if (this.count & 0x80)
  64         {
  65                 // this.move_flags &= ~FL_ONGROUND;
  66                 if (this.move_movetype == MOVETYPE_NONE || this.move_movetype == MOVETYPE_FLY)
  67                         Movetype_Physics_NoMatchServer(this);
  68                 // the trivial movetypes do not have to match the
  69                 // server's ticrate as they are ticrate independent
  70                 // NOTE: this assumption is only true if MOVETYPE_FLY
  71                 // projectiles detonate on impact. If they continue
  72                 // moving, we might still be ticrate dependent.
  73                 else
  74                         Movetype_Physics_MatchServer(this, autocvar_cl_projectiles_sloppy);
  75                 if (!(this.move_flags & FL_ONGROUND))
  76                         if (this.velocity != '0 0 0')
  77                                 this.move_angles = this.angles = vectoangles(this.velocity);
  78         }
  79         else
  80         {
  81                 InterpolateOrigin_Do(this);
  82         }
  83
  84         if (this.count & 0x80)
  85         {
  86                 drawn = (time >= this.spawntime - 0.02);
  87                 t = max(time, this.spawntime);
  88         }
  89         else
  90         {
  91                 drawn = (this.iflags & IFLAG_VALID);
  92                 t = time;
  93         }
  94
  95         if (!(f & FL_ONGROUND))
  96         {
  97                 rot = '0 0 0';
  98                 switch (this.cnt)
  99                 {
 100                         /*
 101                         case PROJECTILE_GRENADE:
 102                             rot = '-2000 0 0'; // forward
 103                             break;
 104                         */
 105                         case PROJECTILE_GRENADE_BOUNCING:
 106                                 rot = '0 -1000 0'; // sideways
 107                                 break;
 108                         case PROJECTILE_HOOKBOMB:
 109                                 rot = '1000 0 0';  // forward
 110                                 break;
 111                         default:
 112                                 break;
 113                 }
 114
 115                 if (Projectile_isnade(this.cnt))
 116                         rot = this.avelocity;
 117
 118                 this.angles = AnglesTransform_ToAngles(AnglesTransform_Multiply(AnglesTransform_FromAngles(this.angles), rot * (t - this.spawntime)));
 119         }
 120
 121         vector ang;
 122         ang = this.angles;
 123         ang.x = -ang.x;
 124         makevectors(ang);
 125
 126         a = 1 - (time - this.fade_time) * this.fade_rate;
 127         this.alpha = bound(0, this.alphamod * a, 1);
 128         if (this.alpha <= 0)
 129                 drawn = 0;
 130         this.renderflags = 0;
 131
 132         trailorigin = this.origin;
 133         switch (this.cnt)
 134         {
 135                 case PROJECTILE_GRENADE:
 136                 case PROJECTILE_GRENADE_BOUNCING:
 137                         trailorigin += v_right * 1 + v_forward * -10;
 138                         break;
 139                 default:
 140                         break;
 141         }
 142
 143         if (Projectile_isnade(this.cnt))
 144                 trailorigin += v_up * 4;
 145
 146         if (drawn)
 147                 Projectile_DrawTrail(this, trailorigin);
 148         else
 149                 Projectile_ResetTrail(this, trailorigin);
 150
 151         this.drawmask = 0;
 152
 153         if (!drawn)
 154                 return;
 155
 156         switch (this.cnt)
 157         {
 158                 // Possibly add dlights here.
 159                 default:
 160                         break;
 161         }
 162
 163         this.drawmask = MASK_NORMAL;
 164 }
 165
 166 void loopsound(entity e, int ch, string samp, float vol, float attn)
 167 {
 168     TC(int, ch);
 169         if (e.silent)
 170                 return;
 171
 172         _sound(e, ch, samp, vol, attn);
 173         e.snd_looping = ch;
 174 }
 175
 176 void Ent_RemoveProjectile(entity this)
 177 {
 178         if (this.count & 0x80)
 179         {
 180                 tracebox(this.origin, this.mins, this.maxs, this.origin + this.velocity * 0.05, MOVE_NORMAL, this);
 181                 Projectile_DrawTrail(this, trace_endpos);
 182         }
 183 }
 184
 185 NET_HANDLE(ENT_CLIENT_PROJECTILE, bool isnew)
 186 {
 187         // projectile properties:
 188         //   kind (interpolated, or clientside)
 189         //
 190         //   modelindex
 191         //   origin
 192         //   scale
 193         //   if clientside:
 194         //     velocity
 195         //     gravity
 196         //   soundindex (hardcoded list)
 197         //   effects
 198         //
 199         // projectiles don't send angles, because they always follow the velocity
 200
 201         int f = ReadByte();
 202         this.count = (f & 0x80);
 203         this.flags |= FL_PROJECTILE;
 204         this.iflags = (this.iflags & IFLAG_INTERNALMASK) | IFLAG_AUTOANGLES | IFLAG_ANGLES | IFLAG_ORIGIN;
 205         this.solid = SOLID_TRIGGER;
 206         // this.effects = EF_NOMODELFLAGS;
 207
 208         // this should make collisions with bmodels more exact, but it leads to
 209         // projectiles no longer being able to lie on a bmodel
 210         this.move_nomonsters = MOVE_WORLDONLY;
 211         if (f & 0x40)
 212                 this.move_flags |= FL_ONGROUND;
 213         else
 214                 this.move_flags &= ~FL_ONGROUND;
 215
 216         if (!this.move_time)
 217         {
 218                 // for some unknown reason, we don't need to care for
 219                 // sv_gameplayfix_delayprojectiles here.
 220                 this.move_time = time;
 221                 this.spawntime = time;
 222         }
 223         else
 224         {
 225                 this.move_time = max(this.move_time, time);
 226         }
 227
 228         if (!(this.count & 0x80))
 229                 InterpolateOrigin_Undo(this);
 230
 231         if (f & 1)
 232         {
 233                 this.origin_x = ReadCoord();
 234                 this.origin_y = ReadCoord();
 235                 this.origin_z = ReadCoord();
 236                 setorigin(this, this.origin);
 237                 if (this.count & 0x80)
 238                 {
 239                         this.velocity_x = ReadCoord();
 240                         this.velocity_y = ReadCoord();
 241                         this.velocity_z = ReadCoord();
 242                         if (f & 0x10)
 243                                 this.gravity = ReadCoord();
 244                         else
 245                                 this.gravity = 0;  // none
 246                         this.move_origin = this.origin;
 247                         this.move_velocity = this.velocity;
 248                 }
 249
 250                 if (time == this.spawntime || (this.count & 0x80) || (f & 0x08))
 251                 {
 252                         this.trail_oldorigin = this.origin;
 253                         if (!(this.count & 0x80))
 254                                 InterpolateOrigin_Reset(this);
 255                 }
 256
 257                 if (f & 0x20)
 258                 {
 259                         this.fade_time = time + ReadByte() * ticrate;
 260                         this.fade_rate = 1 / (ReadByte() * ticrate);
 261                 }
 262                 else
 263                 {
 264                         this.fade_time = 0;
 265                         this.fade_rate = 0;
 266                 }
 267
 268                 this.team = ReadByte() - 1;
 269         }
 270
 271         if (f & 2)
 272         {
 273                 this.cnt = ReadByte();
 274
 275                 this.silent = (this.cnt & 0x80);
 276                 this.cnt = (this.cnt & 0x7F);
 277
 278                 this.scale = 1;
 279                 this.traileffect = 0;
 280                 switch (this.cnt)
 281                 {
 282 #define HANDLE(id) case PROJECTILE_##id: setmodel(this, MDL_PROJECTILE_##id);
 283                         HANDLE(ELECTRO)            this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 284                         HANDLE(ROCKET)             this.traileffect = EFFECT_TR_ROCKET.m_id; this.scale = 2; break;
 285                         HANDLE(CRYLINK)            this.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
 286                         HANDLE(CRYLINK_BOUNCING)   this.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
 287                         HANDLE(ELECTRO_BEAM)       this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 288                         HANDLE(GRENADE)            this.traileffect = EFFECT_TR_GRENADE.m_id; break;
 289                         HANDLE(GRENADE_BOUNCING)   this.traileffect = EFFECT_TR_GRENADE.m_id; break;
 290                         HANDLE(MINE)               this.traileffect = EFFECT_TR_GRENADE.m_id; break;
 291                         HANDLE(BLASTER)            this.traileffect = EFFECT_Null.m_id; break;
 292                         HANDLE(ARC_BOLT)           this.traileffect = EFFECT_Null.m_id; break;
 293                         HANDLE(HLAC)               this.traileffect = EFFECT_Null.m_id; break;
 294                         HANDLE(PORTO_RED)          this.traileffect = EFFECT_TR_WIZSPIKE.m_id; this.scale = 4; break;
 295                         HANDLE(PORTO_BLUE)         this.traileffect = EFFECT_TR_WIZSPIKE.m_id; this.scale = 4; break;
 296                         HANDLE(HOOKBOMB)           this.traileffect = EFFECT_TR_KNIGHTSPIKE.m_id; break;
 297                         HANDLE(HAGAR)              this.traileffect = EFFECT_HAGAR_ROCKET.m_id; this.scale = 0.75; break;
 298                         HANDLE(HAGAR_BOUNCING)     this.traileffect = EFFECT_HAGAR_ROCKET.m_id; this.scale = 0.75; break;
 299                         HANDLE(FIREBALL)           this.modelindex = 0; this.traileffect = EFFECT_FIREBALL.m_id; break; // particle effect is good enough
 300                         HANDLE(FIREMINE)           this.modelindex = 0; this.traileffect = EFFECT_FIREMINE.m_id; break; // particle effect is good enough
 301                         HANDLE(TAG)                this.traileffect = EFFECT_TR_ROCKET.m_id; break;
 302                         HANDLE(FLAC)               this.scale = 0.4; this.traileffect = EFFECT_FLAC_TRAIL.m_id; break;
 303                         HANDLE(SEEKER)             this.traileffect = EFFECT_SEEKER_TRAIL.m_id; break;
 304
 305                         HANDLE(MAGE_SPIKE)         this.traileffect = EFFECT_TR_VORESPIKE.m_id; break;
 306                         HANDLE(SHAMBLER_LIGHTNING) this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 307
 308                         HANDLE(RAPTORBOMB)         this.gravity = 1; this.avelocity = '0 0 180'; this.traileffect = EFFECT_Null.m_id; break;
 309                         HANDLE(RAPTORBOMBLET)      this.gravity = 1; this.avelocity = '0 0 180'; this.traileffect = EFFECT_Null.m_id; break;
 310                         HANDLE(RAPTORCANNON)       this.traileffect = EFFECT_TR_CRYLINKPLASMA.m_id; break;
 311
 312                         HANDLE(SPIDERROCKET)       this.traileffect = EFFECT_SPIDERBOT_ROCKET_TRAIL.m_id; break;
 313                         HANDLE(WAKIROCKET)         this.traileffect = EFFECT_RACER_ROCKET_TRAIL.m_id; break;
 314                         HANDLE(WAKICANNON)         this.traileffect = EFFECT_Null.m_id; break;
 315
 316                         HANDLE(BUMBLE_GUN)         this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 317                         HANDLE(BUMBLE_BEAM)        this.traileffect = EFFECT_TR_NEXUIZPLASMA.m_id; break;
 318
 319                         HANDLE(RPC)                this.traileffect = EFFECT_TR_ROCKET.m_id; break;
 320
 321                         HANDLE(ROCKETMINSTA_LASER) this.traileffect = EFFECT_ROCKETMINSTA_LASER(this.team).m_id; break;
 322 #undef HANDLE
 323                         default:
 324                                 if (MUTATOR_CALLHOOK(Ent_Projectile, this))
 325                                         break;
 326
 327                                 error("Received invalid CSQC projectile, can't work with this!");
 328                                 break;
 329                 }
 330
 331                 this.mins = '0 0 0';
 332                 this.maxs = '0 0 0';
 333                 this.colormod = '0 0 0';
 334                 settouch(this, SUB_Stop);
 335                 this.move_movetype = MOVETYPE_TOSS;
 336                 this.alphamod = 1;
 337
 338                 switch (this.cnt)
 339                 {
 340                         case PROJECTILE_ELECTRO:
 341                                 // only new engines support sound moving with object
 342                                 loopsound(this, CH_SHOTS_SINGLE, SND(ELECTRO_FLY), VOL_BASE, ATTEN_NORM);
 343                                 this.mins = '0 0 -4';
 344                                 this.maxs = '0 0 -4';
 345                                 this.move_movetype = MOVETYPE_BOUNCE;
 346                                 settouch(this, func_null);
 347                                 this.move_bounce_factor = WEP_CVAR_SEC(electro, bouncefactor);
 348                                 this.move_bounce_stopspeed = WEP_CVAR_SEC(electro, bouncestop);
 349                                 break;
 350                         case PROJECTILE_RPC:
 351                         case PROJECTILE_ROCKET:
 352                                 loopsound(this, CH_SHOTS_SINGLE, SND(ROCKET_FLY), VOL_BASE, ATTEN_NORM);
 353                                 this.mins = '-3 -3 -3';
 354                                 this.maxs = '3 3 3';
 355                                 break;
 356                         case PROJECTILE_GRENADE:
 357                                 this.mins = '-3 -3 -3';
 358                                 this.maxs = '3 3 3';
 359                                 break;
 360                         case PROJECTILE_GRENADE_BOUNCING:
 361                                 this.mins = '-3 -3 -3';
 362                                 this.maxs = '3 3 3';
 363                                 this.move_movetype = MOVETYPE_BOUNCE;
 364                                 settouch(this, func_null);
 365                                 this.move_bounce_factor = WEP_CVAR(mortar, bouncefactor);
 366                                 this.move_bounce_stopspeed = WEP_CVAR(mortar, bouncestop);
 367                                 break;
 368                         case PROJECTILE_SHAMBLER_LIGHTNING:
 369                                 this.mins = '-8 -8 -8';
 370                                 this.maxs = '8 8 8';
 371                                 this.scale = 2.5;
 372                                 this.avelocity = randomvec() * 720;
 373                                 break;
 374                         case PROJECTILE_MINE:
 375                                 this.mins = '-4 -4 -4';
 376                                 this.maxs = '4 4 4';
 377                                 break;
 378                         case PROJECTILE_PORTO_RED:
 379                                 this.colormod = '2 1 1';
 380                                 this.alphamod = 0.5;
 381                                 this.move_movetype = MOVETYPE_BOUNCE;
 382                                 settouch(this, func_null);
 383                                 break;
 384                         case PROJECTILE_PORTO_BLUE:
 385                                 this.colormod = '1 1 2';
 386                                 this.alphamod = 0.5;
 387                                 this.move_movetype = MOVETYPE_BOUNCE;
 388                                 settouch(this, func_null);
 389                                 break;
 390                         case PROJECTILE_HAGAR_BOUNCING:
 391                                 this.move_movetype = MOVETYPE_BOUNCE;
 392                                 settouch(this, func_null);
 393                                 break;
 394                         case PROJECTILE_CRYLINK_BOUNCING:
 395                                 this.move_movetype = MOVETYPE_BOUNCE;
 396                                 settouch(this, func_null);
 397                                 break;
 398                         case PROJECTILE_FIREBALL:
 399                                 loopsound(this, CH_SHOTS_SINGLE, SND(FIREBALL_FLY2), VOL_BASE, ATTEN_NORM);
 400                                 this.mins = '-16 -16 -16';
 401                                 this.maxs = '16 16 16';
 402                                 break;
 403                         case PROJECTILE_FIREMINE:
 404                                 loopsound(this, CH_SHOTS_SINGLE, SND(FIREBALL_FLY), VOL_BASE, ATTEN_NORM);
 405                                 this.move_movetype = MOVETYPE_BOUNCE;
 406                                 settouch(this, func_null);
 407                                 this.mins = '-4 -4 -4';
 408                                 this.maxs = '4 4 4';
 409                                 break;
 410                         case PROJECTILE_TAG:
 411                                 this.mins = '-2 -2 -2';
 412                                 this.maxs = '2 2 2';
 413                                 break;
 414                         case PROJECTILE_FLAC:
 415                                 this.mins = '-2 -2 -2';
 416                                 this.maxs = '2 2 2';
 417                                 break;
 418                         case PROJECTILE_SEEKER:
 419                                 loopsound(this, CH_SHOTS_SINGLE, SND(TAG_ROCKET_FLY), VOL_BASE, ATTEN_NORM);
 420                                 this.mins = '-4 -4 -4';
 421                                 this.maxs = '4 4 4';
 422                                 break;
 423                         case PROJECTILE_RAPTORBOMB:
 424                                 this.mins = '-3 -3 -3';
 425                                 this.maxs = '3 3 3';
 426                                 break;
 427                         case PROJECTILE_RAPTORBOMBLET:
 428                                 break;
 429                         case PROJECTILE_RAPTORCANNON:
 430                                 break;
 431                         case PROJECTILE_SPIDERROCKET:
 432                                 loopsound(this, CH_SHOTS_SINGLE, SND(TAG_ROCKET_FLY), VOL_BASE, ATTEN_NORM);
 433                                 break;
 434                         case PROJECTILE_WAKIROCKET:
 435                                 loopsound(this, CH_SHOTS_SINGLE, SND(TAG_ROCKET_FLY), VOL_BASE, ATTEN_NORM);
 436                                 break;
 437                         /*
 438                         case PROJECTILE_WAKICANNON:
 439                             break;
 440                         case PROJECTILE_BUMBLE_GUN:
 441                             // only new engines support sound moving with object
 442                             loopsound(this, CH_SHOTS_SINGLE, SND(ELECTRO_FLY), VOL_BASE, ATTEN_NORM);
 443                             this.mins = '0 0 -4';
 444                             this.maxs = '0 0 -4';
 445                             this.move_movetype = MOVETYPE_BOUNCE;
 446                             this.move_touch = func_null;
 447                             this.move_bounce_factor = WEP_CVAR_SEC(electro, bouncefactor);
 448                             this.move_bounce_stopspeed = WEP_CVAR_SEC(electro, bouncestop);
 449                             break;
 450                         */
 451                         default:
 452                                 break;
 453                 }
 454
 455                 MUTATOR_CALLHOOK(EditProjectile, this);
 456
 457                 setsize(this, this.mins, this.maxs);
 458         }
 459
 460         return = true;
 461
 462         if (this.gravity)
 463         {
 464                 if (this.move_movetype == MOVETYPE_FLY)
 465                         this.move_movetype = MOVETYPE_TOSS;
 466                 if (this.move_movetype == MOVETYPE_BOUNCEMISSILE)
 467                         this.move_movetype = MOVETYPE_BOUNCE;
 468         }
 469         else
 470         {
 471                 if (this.move_movetype == MOVETYPE_TOSS)
 472                         this.move_movetype = MOVETYPE_FLY;
 473                 if (this.move_movetype == MOVETYPE_BOUNCE)
 474                         this.move_movetype = MOVETYPE_BOUNCEMISSILE;
 475         }
 476
 477         if (!(this.count & 0x80))
 478                 InterpolateOrigin_Note(this);
 479
 480         this.classname = "csqcprojectile";
 481         this.draw = Projectile_Draw;
 482         this.entremove = Ent_RemoveProjectile;
 483 }
 484
 485 PRECACHE(Projectiles)
 486 {
 487         MUTATOR_CALLHOOK(PrecacheProjectiles);
 488 }