qcsrc/common/animdecide.qc

   1 #include "animdecide.qh"
   2
   3 #include <common/monsters/_mod.qh>
   4
   5 #if defined(SVQC)
   6     #include "util.qh"
   7     #include <common/weapons/_all.qh>
   8     #include <common/stats.qh>
   9 #endif
  10
  11 bool monsters_animoverride(entity this)
  12 {
  13         Monster monster_id = NULL;
  14         FOREACH(Monsters, it != MON_Null && it.m_model.model_str() == this.model, {
  15         monster_id = it;
  16         break;
  17         });
  18
  19         if(!monster_id) { return false; }
  20
  21         monster_id.mr_anim(monster_id, this);
  22
  23         vector none = '0 0 0';
  24         this.anim_duckwalk = this.anim_walk;
  25         this.anim_duckjump = animfixfps(this, '5 1 10', none);
  26         this.anim_duckidle = this.anim_idle;
  27         this.anim_jump = animfixfps(this, '8 1 10', none);
  28         this.anim_taunt = animfixfps(this, '12 1 0.33', none);
  29         this.anim_runbackwards = this.anim_run;
  30         this.anim_strafeleft = this.anim_run;
  31         this.anim_straferight = this.anim_run;
  32         this.anim_forwardright = this.anim_run;
  33         this.anim_forwardleft = this.anim_run;
  34         this.anim_backright = this.anim_run;
  35         this.anim_backleft  = this.anim_run;
  36         this.anim_duckwalkbackwards = this.anim_walk;
  37         this.anim_duckwalkstrafeleft = this.anim_walk;
  38         this.anim_duckwalkstraferight = this.anim_walk;
  39         this.anim_duckwalkforwardright = this.anim_walk;
  40         this.anim_duckwalkforwardleft = this.anim_walk;
  41         this.anim_duckwalkbackright = this.anim_walk;
  42         this.anim_duckwalkbackleft  = this.anim_walk;
  43
  44         // these anims ought to stay until stopped explicitly by weaponsystem
  45         this.anim_shoot_z = 0.001;
  46         this.anim_melee_z = 0.001;
  47
  48         return true;
  49 }
  50
  51 void animdecide_load_if_needed(entity e)
  52 {
  53         int mdlidx = e.modelindex;
  54         if (mdlidx == e.animdecide_modelindex) return;
  55         e.animdecide_modelindex = mdlidx;
  56
  57         if(substring(e.model, 0, 16) == "models/monsters/")
  58         {
  59                 if(monsters_animoverride(e))
  60                         return;
  61         }
  62
  63 #define ANIM_VEC(a, frames, rate) anim_vec(ANIM_##a, mdlidx, frames, rate)
  64
  65         vector none = '0 0 0';
  66         e.anim_die1 = animfixfps(e, ANIM_VEC(die1, 1, 0.5), none); // 2 seconds
  67         e.anim_die2 = animfixfps(e, ANIM_VEC(die2, 1, 0.5), none); // 2 seconds
  68         e.anim_draw = animfixfps(e, ANIM_VEC(draw, 1, 3), none);
  69         e.anim_duckwalk = animfixfps(e, ANIM_VEC(duckwalk, 1, 1), none);
  70         e.anim_duckjump = animfixfps(e, ANIM_VEC(duckjump, 1, 10), none);
  71         e.anim_duckidle = animfixfps(e, ANIM_VEC(duckidle, 1, 1), none);
  72         e.anim_idle = animfixfps(e, ANIM_VEC(idle, 1, 1), none);
  73         e.anim_jump = animfixfps(e, ANIM_VEC(jump, 1, 10), none);
  74         e.anim_pain1 = animfixfps(e, ANIM_VEC(pain1, 1, 2), none); // 0.5 seconds
  75         e.anim_pain2 = animfixfps(e, ANIM_VEC(pain2, 1, 2), none); // 0.5 seconds
  76         e.anim_shoot = animfixfps(e, ANIM_VEC(shoot, 1, 5), none); // analyze models and set framerate
  77         e.anim_taunt = animfixfps(e, ANIM_VEC(taunt, 1, 0.33), none);
  78         e.anim_run = animfixfps(e, ANIM_VEC(run, 1, 1), none);
  79         e.anim_runbackwards = animfixfps(e, ANIM_VEC(runbackwards, 1, 1), none);
  80         e.anim_strafeleft = animfixfps(e, ANIM_VEC(strafeleft, 1, 1), none);
  81         e.anim_straferight = animfixfps(e, ANIM_VEC(straferight, 1, 1), none);
  82         e.anim_forwardright = animfixfps(e, ANIM_VEC(forwardright, 1, 1), ANIM_VEC(straferight, 1, 1));
  83         e.anim_forwardleft = animfixfps(e, ANIM_VEC(forwardleft, 1, 1), ANIM_VEC(strafeleft, 1, 1));
  84         e.anim_backright = animfixfps(e, ANIM_VEC(backright, 1, 1), ANIM_VEC(straferight, 1, 1));
  85         e.anim_backleft  = animfixfps(e, ANIM_VEC(backleft , 1, 1), ANIM_VEC(strafeleft, 1, 1));
  86         e.anim_melee = animfixfps(e, ANIM_VEC(melee, 1, 1), ANIM_VEC(shoot, 1, 1));
  87         e.anim_duckwalkbackwards = animfixfps(e, ANIM_VEC(duckwalkbackwards, 1, 1), ANIM_VEC(duckwalk, 1, 1));
  88         e.anim_duckwalkstrafeleft = animfixfps(e, ANIM_VEC(duckwalkstrafeleft, 1, 1), ANIM_VEC(duckwalk, 1, 1));
  89         e.anim_duckwalkstraferight = animfixfps(e, ANIM_VEC(duckwalkstraferight, 1, 1), ANIM_VEC(duckwalk, 1, 1));
  90         e.anim_duckwalkforwardright = animfixfps(e, ANIM_VEC(duckwalkforwardright, 1, 1), ANIM_VEC(duckwalk, 1, 1));
  91         e.anim_duckwalkforwardleft = animfixfps(e, ANIM_VEC(duckwalkforwardleft, 1, 1), ANIM_VEC(duckwalk, 1, 1));
  92         e.anim_duckwalkbackright = animfixfps(e, ANIM_VEC(duckwalkbackright, 1,  1), ANIM_VEC(duckwalk, 1, 1));
  93         e.anim_duckwalkbackleft  = animfixfps(e, ANIM_VEC(duckwalkbackleft , 1,  1), ANIM_VEC(duckwalk, 1, 1));
  94
  95 #undef ANIM_VEC
  96
  97         // these anims ought to stay until stopped explicitly by weaponsystem
  98         e.anim_shoot_z = 0.001;
  99         e.anim_melee_z = 0.001;
 100 }
 101
 102 const float ANIMPRIO_IDLE = 0;
 103 const float ANIMPRIO_ACTIVE = 1;
 104 const float ANIMPRIO_CROUCH = 2;
 105 const float ANIMPRIO_DEAD = 3;
 106
 107 vector animdecide_getupperanim(entity e)
 108 {
 109         // death etc.
 110         if(e.anim_state & ANIMSTATE_FROZEN)
 111                 return vec3(e.anim_idle.x, e.anim_time, ANIMPRIO_DEAD);
 112         if(e.anim_state & ANIMSTATE_DEAD1)
 113                 return vec3(e.anim_die1_x, e.anim_time, ANIMPRIO_DEAD);
 114         if(e.anim_state & ANIMSTATE_DEAD2)
 115                 return vec3(e.anim_die2_x, e.anim_time, ANIMPRIO_DEAD);
 116
 117         // is there an action?
 118         vector outframe = '-1 0 0';
 119         float t, a;
 120         if(e.anim_upper_time >= e.anim_upper_implicit_time)
 121         {
 122                 a = e.anim_upper_action;
 123                 t = e.anim_upper_time;
 124         }
 125         else
 126         {
 127                 a = e.anim_upper_implicit_action;
 128                 t = e.anim_upper_implicit_time;
 129         }
 130         switch(a)
 131         {
 132                 case ANIMACTION_DRAW: outframe = e.anim_draw; break;
 133                 case ANIMACTION_PAIN1: outframe = e.anim_pain1; break;
 134                 case ANIMACTION_PAIN2: outframe = e.anim_pain2; break;
 135                 case ANIMACTION_SHOOT: outframe = e.anim_shoot; break;
 136                 case ANIMACTION_TAUNT: outframe = e.anim_taunt; break;
 137                 case ANIMACTION_MELEE: outframe = e.anim_melee; break;
 138         }
 139         if(outframe.x >= 0)
 140         {
 141                 if(time <= t + outframe.y / outframe.z)
 142                 {
 143                         // animation is running!
 144                         return vec3(outframe.x, t, ANIMPRIO_ACTIVE);
 145                 }
 146         }
 147         // or, decide the anim by state
 148         t = max(e.anim_time, e.anim_implicit_time);
 149         // but all states are for lower body!
 150         return vec3(e.anim_idle.x, t, ANIMPRIO_IDLE);
 151 }
 152
 153 vector animdecide_getloweranim(entity e)
 154 {
 155         // death etc.
 156         if(e.anim_state & ANIMSTATE_FOLLOW)
 157                 return vec3(((e.anim_state & ANIMSTATE_DUCK) ? e.anim_duckidle_x : e.anim_idle_x), e.anim_time, ANIMPRIO_DEAD); // dead priority so it's above all
 158         if(e.anim_state & ANIMSTATE_FROZEN)
 159                 return vec3(e.anim_idle.x, e.anim_time, ANIMPRIO_DEAD);
 160         if(e.anim_state & ANIMSTATE_DEAD1)
 161                 return vec3(e.anim_die1_x, e.anim_time, ANIMPRIO_DEAD);
 162         if(e.anim_state & ANIMSTATE_DEAD2)
 163                 return vec3(e.anim_die2_x, e.anim_time, ANIMPRIO_DEAD);
 164
 165         // is there an action?
 166         vector outframe = '-1 0 0';
 167         float t, a;
 168         if(e.anim_lower_time >= e.anim_lower_implicit_time)
 169         {
 170                 a = e.anim_lower_action;
 171                 t = e.anim_lower_time;
 172         }
 173         else
 174         {
 175                 a = e.anim_lower_implicit_action;
 176                 t = e.anim_lower_implicit_time;
 177         }
 178         switch(a)
 179         {
 180                 case ANIMACTION_JUMP: if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR) { if(e.anim_state & ANIMSTATE_DUCK) outframe = e.anim_duckjump; else outframe = e.anim_jump; } break;
 181         }
 182         if(outframe.x >= 0)
 183         {
 184                 if(time <= t + outframe.y / outframe.z)
 185                 {
 186                         // animation is running!
 187                         return vec3(outframe.x, t, ANIMPRIO_ACTIVE);
 188                 }
 189         }
 190         // or, decide the anim by state
 191         t = max(e.anim_time, e.anim_implicit_time);
 192         if(e.anim_state & ANIMSTATE_DUCK)
 193         {
 194                 if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR)
 195                         return vec3(e.anim_duckjump.x, 0, ANIMPRIO_CROUCH); // play the END of the jump anim
 196                 else switch(e.anim_implicit_state & (ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT | ANIMIMPLICITSTATE_RIGHT))
 197                 {
 198                         case ANIMIMPLICITSTATE_FORWARD:
 199                                 return vec3(e.anim_duckwalk.x, t, ANIMPRIO_CROUCH);
 200                         case ANIMIMPLICITSTATE_BACKWARDS:
 201                                 return vec3(e.anim_duckwalkbackwards.x, t, ANIMPRIO_CROUCH);
 202                         case ANIMIMPLICITSTATE_RIGHT:
 203                                 return vec3(e.anim_duckwalkstraferight.x, t, ANIMPRIO_CROUCH);
 204                         case ANIMIMPLICITSTATE_LEFT:
 205                                 return vec3(e.anim_duckwalkstrafeleft.x, t, ANIMPRIO_CROUCH);
 206                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_RIGHT:
 207                                 return vec3(e.anim_duckwalkforwardright.x, t, ANIMPRIO_CROUCH);
 208                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_LEFT:
 209                                 return vec3(e.anim_duckwalkforwardleft.x, t, ANIMPRIO_CROUCH);
 210                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_RIGHT:
 211                                 return vec3(e.anim_duckwalkbackright.x, t, ANIMPRIO_CROUCH);
 212                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT:
 213                                 return vec3(e.anim_duckwalkbackleft.x, t, ANIMPRIO_CROUCH);
 214                 }
 215                 return vec3(e.anim_duckidle.x, t, ANIMPRIO_CROUCH);
 216         }
 217         else
 218         {
 219                 if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR)
 220                         return vec3(e.anim_jump.x, 0, ANIMPRIO_ACTIVE); // play the END of the jump anim
 221                 else switch(e.anim_implicit_state & (ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT | ANIMIMPLICITSTATE_RIGHT))
 222                 {
 223                         case ANIMIMPLICITSTATE_FORWARD:
 224                                 return vec3(e.anim_run.x, t, ANIMPRIO_ACTIVE);
 225                         case ANIMIMPLICITSTATE_BACKWARDS:
 226                                 return vec3(e.anim_runbackwards.x, t, ANIMPRIO_ACTIVE);
 227                         case ANIMIMPLICITSTATE_RIGHT:
 228                                 return vec3(e.anim_straferight.x, t, ANIMPRIO_ACTIVE);
 229                         case ANIMIMPLICITSTATE_LEFT:
 230                                 return vec3(e.anim_strafeleft.x, t, ANIMPRIO_ACTIVE);
 231                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_RIGHT:
 232                                 return vec3(e.anim_forwardright.x, t, ANIMPRIO_ACTIVE);
 233                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_LEFT:
 234                                 return vec3(e.anim_forwardleft.x, t, ANIMPRIO_ACTIVE);
 235                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_RIGHT:
 236                                 return vec3(e.anim_backright.x, t, ANIMPRIO_ACTIVE);
 237                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT:
 238                                 return vec3(e.anim_backleft.x, t, ANIMPRIO_ACTIVE);
 239                 }
 240                 return vec3(e.anim_idle.x, t, ANIMPRIO_IDLE);
 241         }
 242         // can't get here
 243         //return vec3(e.anim_idle.x, t, ANIMPRIO_IDLE);
 244 }
 245
 246 void animdecide_setimplicitstate(entity e, float onground)
 247 {
 248         int s = 0;
 249
 250         makevectors(e.angles);
 251         vector v;
 252         v.x = e.velocity * v_forward;
 253         v.y = e.velocity * v_right;
 254         v.z = 0;
 255
 256         // we want to match like this:
 257         // the 8 directions shall be "evenly spaced"
 258         // that means, the forward key includes anything from -67.5 to +67.5 degrees
 259         // which then means x > |y| * cot(3pi/8)
 260         //
 261         // BUT, the engine's clip-movement-to-keyboard function uses 0.5 here,
 262         // which would be an angle range from -63.43 to +63.43 degrees, making
 263         // it slightly less likely to "hit two keys at once", so let's do this
 264         // here too
 265
 266         if(vdist(v, >, 10))
 267         {
 268                 if(v.x >  fabs(v.y) * 0.5)
 269                         s |= ANIMIMPLICITSTATE_FORWARD;
 270                 if(v.x < -fabs(v.y) * 0.5)
 271                         s |= ANIMIMPLICITSTATE_BACKWARDS;
 272                 if(v.y >  fabs(v.x) * 0.5)
 273                         s |= ANIMIMPLICITSTATE_RIGHT;
 274                 if(v.y < -fabs(v.x) * 0.5)
 275                         s |= ANIMIMPLICITSTATE_LEFT;
 276         }
 277         if(!onground)
 278                 s |= ANIMIMPLICITSTATE_INAIR;
 279
 280         // detect some kinds of otherwise misdetected jumps (ground to air transition)
 281         // NOTE: currently, in CSQC this is the only jump detection, as the explicit jump action is never called!
 282         if(!(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR) && (s & ANIMIMPLICITSTATE_INAIR))
 283         {
 284                 e.anim_lower_implicit_action = ANIMACTION_JUMP;
 285                 e.anim_lower_implicit_time = time;
 286         }
 287
 288         if(s != e.anim_implicit_state)
 289         {
 290                 e.anim_implicit_state = s;
 291                 e.anim_implicit_time = time;
 292         }
 293 }
 294 void animdecide_setframes(entity e, float support_blending, .float fld_frame, .float fld_frame1time, .float fld_frame2, .float fld_frame2time)
 295 {
 296         // _x: frame
 297         // _y: start time
 298         // _z: priority
 299         vector upper = animdecide_getupperanim(e);
 300         vector lower = animdecide_getloweranim(e);
 301         //print("UPPER: ", vtos(upper), ", LOWER: ", vtos(lower), "\n");
 302         if(support_blending)
 303         {
 304                 if(upper.z && !lower.z)
 305                         lower = upper;
 306                 else if(lower.z && !upper.z)
 307                         upper = lower;
 308                 if(e.frame1time != upper.y || e.frame2time != lower.y)
 309                         BITXOR_ASSIGN(e.effects, EF_RESTARTANIM_BIT);
 310                 e.(fld_frame) = upper.x;
 311                 e.(fld_frame1time) = upper.y;
 312                 e.(fld_frame2) = lower.x;
 313                 e.(fld_frame2time) = lower.y;
 314         }
 315         else
 316         {
 317                 if(upper.z > lower.z)
 318                         lower = upper;
 319                 else if(lower.z > upper.z)
 320                         upper = lower;
 321                 if(e.frame1time != upper.y)
 322                         BITXOR_ASSIGN(e.effects, EF_RESTARTANIM_BIT);
 323                 e.(fld_frame) = upper.x;
 324                 e.(fld_frame1time) = upper.y;
 325         }
 326 }
 327
 328 void animdecide_setstate(entity e, int newstate, float restart)
 329 {
 330         if(!restart)
 331                 if(newstate == e.anim_state)
 332                         return;
 333         e.anim_state = newstate;
 334         e.anim_time = time;
 335 }
 336 void animdecide_setaction(entity e, float action, float restart)
 337 {
 338         if(action < 0)
 339         {
 340                 if(!restart)
 341                         if(action == e.anim_lower_action)
 342                                 return;
 343                 e.anim_lower_action = action;
 344                 e.anim_lower_time = time;
 345         }
 346         else
 347         {
 348                 if(!restart)
 349                         if(action == e.anim_upper_action)
 350                                 return;
 351                 e.anim_upper_action = action;
 352                 e.anim_upper_time = time;
 353         }
 354 }