qcsrc/common/animdecide.qc

   1 #if defined(CSQC)
   2         #include "../dpdefs/csprogsdefs.qh"
   3         #include "animdecide.qh"
   4 #elif defined(MENUQC)
   5 #elif defined(SVQC)
   6         #include "../dpdefs/progsdefs.qh"
   7     #include "../dpdefs/dpextensions.qh"
   8     #include "util.qh"
   9     #include "animdecide.qh"
  10     #include "../server/defs.qh"
  11 #endif
  12
  13 // player animation data for this model
  14 // each vector is as follows:
  15 // _x = startframe
  16 // _y = numframes
  17 // _z = framerate
  18 .vector anim_die1; // player dies
  19 .vector anim_die2; // player dies differently
  20 .vector anim_draw; // player pulls out a weapon
  21 .vector anim_duckwalk; // player walking while crouching
  22 .vector anim_duckjump; // player jumping from a crouch
  23 .vector anim_duckidle; // player idling while crouching
  24 .vector anim_idle; // player standing
  25 .vector anim_jump; // player jump
  26 .vector anim_pain1; // player flinches from pain
  27 .vector anim_pain2; // player flinches from pain, differently
  28 .vector anim_shoot; // player shoots
  29 .vector anim_taunt; // player taunts others (FIXME: no code references this)
  30 .vector anim_run; // player running forward
  31 .vector anim_runbackwards; // player running backward
  32 .vector anim_strafeleft; // player shuffling left quickly
  33 .vector anim_straferight; // player shuffling right quickly
  34 .vector anim_forwardright; // player running forward and right
  35 .vector anim_forwardleft; // player running forward and left
  36 .vector anim_backright; // player running backward and right
  37 .vector anim_backleft; // player running back and left
  38 .vector anim_melee; // player doing the melee action
  39 .vector anim_duck; // player doing the melee action
  40 .vector anim_duckwalkbackwards;
  41 .vector anim_duckwalkstrafeleft;
  42 .vector anim_duckwalkstraferight;
  43 .vector anim_duckwalkforwardright;
  44 .vector anim_duckwalkforwardleft;
  45 .vector anim_duckwalkbackright;
  46 .vector anim_duckwalkbackleft;
  47 .float animdecide_modelindex;
  48
  49 void animdecide_load_if_needed(entity e)
  50 {
  51         if(e.modelindex == e.animdecide_modelindex)
  52                 return;
  53         e.animdecide_modelindex = e.modelindex;
  54
  55         vector none = '0 0 0';
  56         e.anim_die1 = animfixfps(e, '0 1 0.5', none); // 2 seconds
  57         e.anim_die2 = animfixfps(e, '1 1 0.5', none); // 2 seconds
  58         e.anim_draw = animfixfps(e, '2 1 3', none);
  59         e.anim_duckwalk = animfixfps(e, '4 1 1', none);
  60         e.anim_duckjump = animfixfps(e, '5 1 10', none);
  61         e.anim_duckidle = animfixfps(e, '6 1 1', none);
  62         e.anim_idle = animfixfps(e, '7 1 1', none);
  63         e.anim_jump = animfixfps(e, '8 1 10', none);
  64         e.anim_pain1 = animfixfps(e, '9 1 2', none); // 0.5 seconds
  65         e.anim_pain2 = animfixfps(e, '10 1 2', none); // 0.5 seconds
  66         e.anim_shoot = animfixfps(e, '11 1 5', none); // analyze models and set framerate
  67         e.anim_taunt = animfixfps(e, '12 1 0.33', none);
  68         e.anim_run = animfixfps(e, '13 1 1', none);
  69         e.anim_runbackwards = animfixfps(e, '14 1 1', none);
  70         e.anim_strafeleft = animfixfps(e, '15 1 1', none);
  71         e.anim_straferight = animfixfps(e, '16 1 1', none);
  72         e.anim_forwardright = animfixfps(e, '19 1 1', '16 1 1');
  73         e.anim_forwardleft = animfixfps(e, '20 1 1', '15 1 1');
  74         e.anim_backright = animfixfps(e, '21 1 1', '16 1 1');
  75         e.anim_backleft  = animfixfps(e, '22 1 1', '15 1 1');
  76         e.anim_melee = animfixfps(e, '23 1 1', '11 1 1');
  77         e.anim_duckwalkbackwards = animfixfps(e, '24 1 1', '4 1 1');
  78         e.anim_duckwalkstrafeleft = animfixfps(e, '25 1 1', '4 1 1');
  79         e.anim_duckwalkstraferight = animfixfps(e, '26 1 1', '4 1 1');
  80         e.anim_duckwalkforwardright = animfixfps(e, '27 1 1', '4 1 1');
  81         e.anim_duckwalkforwardleft = animfixfps(e, '28 1 1', '4 1 1');
  82         e.anim_duckwalkbackright = animfixfps(e, '29 1 1', '4 1 1');
  83         e.anim_duckwalkbackleft  = animfixfps(e, '30 1 1', '4 1 1');
  84
  85         // these anims ought to stay until stopped explicitly by weaponsystem
  86         e.anim_shoot_z = 0.001;
  87         e.anim_melee_z = 0.001;
  88 }
  89
  90 const float ANIMPRIO_IDLE = 0;
  91 const float ANIMPRIO_ACTIVE = 1;
  92 const float ANIMPRIO_CROUCH = 2;
  93 const float ANIMPRIO_DEAD = 3;
  94
  95 vector animdecide_getupperanim(entity e)
  96 {
  97         // death etc.
  98         if(e.anim_state & ANIMSTATE_FROZEN)
  99                 return vec3(e.anim_idle.x, e.anim_time, ANIMPRIO_DEAD);
 100         if(e.anim_state & ANIMSTATE_DEAD1)
 101                 return vec3(e.anim_die1_x, e.anim_time, ANIMPRIO_DEAD);
 102         if(e.anim_state & ANIMSTATE_DEAD2)
 103                 return vec3(e.anim_die2_x, e.anim_time, ANIMPRIO_DEAD);
 104
 105         // is there an action?
 106         vector outframe = '-1 0 0';
 107         float t, a;
 108         if(e.anim_upper_time >= e.anim_upper_implicit_time)
 109         {
 110                 a = e.anim_upper_action;
 111                 t = e.anim_upper_time;
 112         }
 113         else
 114         {
 115                 a = e.anim_upper_implicit_action;
 116                 t = e.anim_upper_implicit_time;
 117         }
 118         switch(a)
 119         {
 120                 case ANIMACTION_DRAW: outframe = e.anim_draw; break;
 121                 case ANIMACTION_PAIN1: outframe = e.anim_pain1; break;
 122                 case ANIMACTION_PAIN2: outframe = e.anim_pain2; break;
 123                 case ANIMACTION_SHOOT: outframe = e.anim_shoot; break;
 124                 case ANIMACTION_TAUNT: outframe = e.anim_taunt; break;
 125                 case ANIMACTION_MELEE: outframe = e.anim_melee; break;
 126         }
 127         if(outframe.x >= 0)
 128         {
 129                 if(time <= t + outframe.y / outframe.z)
 130                 {
 131                         // animation is running!
 132                         return vec3(outframe.x, t, ANIMPRIO_ACTIVE);
 133                 }
 134         }
 135         // or, decide the anim by state
 136         t = max(e.anim_time, e.anim_implicit_time);
 137         // but all states are for lower body!
 138         return vec3(e.anim_idle.x, t, ANIMPRIO_IDLE);
 139 }
 140
 141 vector animdecide_getloweranim(entity e)
 142 {
 143         // death etc.
 144         if(e.anim_state & ANIMSTATE_FROZEN)
 145                 return vec3(e.anim_idle.x, e.anim_time, ANIMPRIO_DEAD);
 146         if(e.anim_state & ANIMSTATE_DEAD1)
 147                 return vec3(e.anim_die1_x, e.anim_time, ANIMPRIO_DEAD);
 148         if(e.anim_state & ANIMSTATE_DEAD2)
 149                 return vec3(e.anim_die2_x, e.anim_time, ANIMPRIO_DEAD);
 150
 151         // is there an action?
 152         vector outframe = '-1 0 0';
 153         float t, a;
 154         if(e.anim_lower_time >= e.anim_lower_implicit_time)
 155         {
 156                 a = e.anim_lower_action;
 157                 t = e.anim_lower_time;
 158         }
 159         else
 160         {
 161                 a = e.anim_lower_implicit_action;
 162                 t = e.anim_lower_implicit_time;
 163         }
 164         switch(a)
 165         {
 166                 case ANIMACTION_JUMP: if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR) { if(e.anim_state & ANIMSTATE_DUCK) outframe = e.anim_duckjump; else outframe = e.anim_jump; } break;
 167         }
 168         if(outframe.x >= 0)
 169         {
 170                 if(time <= t + outframe.y / outframe.z)
 171                 {
 172                         // animation is running!
 173                         return vec3(outframe.x, t, ANIMPRIO_ACTIVE);
 174                 }
 175         }
 176         // or, decide the anim by state
 177         t = max(e.anim_time, e.anim_implicit_time);
 178         if(e.anim_state & ANIMSTATE_DUCK)
 179         {
 180                 if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR)
 181                         return vec3(e.anim_duckjump.x, 0, ANIMPRIO_CROUCH); // play the END of the jump anim
 182                 else switch(e.anim_implicit_state & (ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT | ANIMIMPLICITSTATE_RIGHT))
 183                 {
 184                         case ANIMIMPLICITSTATE_FORWARD:
 185                                 return vec3(e.anim_duckwalk.x, t, ANIMPRIO_CROUCH);
 186                         case ANIMIMPLICITSTATE_BACKWARDS:
 187                                 return vec3(e.anim_duckwalkbackwards.x, t, ANIMPRIO_CROUCH);
 188                         case ANIMIMPLICITSTATE_RIGHT:
 189                                 return vec3(e.anim_duckwalkstraferight.x, t, ANIMPRIO_CROUCH);
 190                         case ANIMIMPLICITSTATE_LEFT:
 191                                 return vec3(e.anim_duckwalkstrafeleft.x, t, ANIMPRIO_CROUCH);
 192                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_RIGHT:
 193                                 return vec3(e.anim_duckwalkforwardright.x, t, ANIMPRIO_CROUCH);
 194                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_LEFT:
 195                                 return vec3(e.anim_duckwalkforwardleft.x, t, ANIMPRIO_CROUCH);
 196                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_RIGHT:
 197                                 return vec3(e.anim_duckwalkbackright.x, t, ANIMPRIO_CROUCH);
 198                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT:
 199                                 return vec3(e.anim_duckwalkbackleft.x, t, ANIMPRIO_CROUCH);
 200                         default:
 201                                 return vec3(e.anim_duckidle.x, t, ANIMPRIO_CROUCH);
 202                 }
 203         }
 204         else
 205         {
 206                 if(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR)
 207                         return vec3(e.anim_jump.x, 0, ANIMPRIO_ACTIVE); // play the END of the jump anim
 208                 else switch(e.anim_implicit_state & (ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT | ANIMIMPLICITSTATE_RIGHT))
 209                 {
 210                         case ANIMIMPLICITSTATE_FORWARD:
 211                                 return vec3(e.anim_run.x, t, ANIMPRIO_ACTIVE);
 212                         case ANIMIMPLICITSTATE_BACKWARDS:
 213                                 return vec3(e.anim_runbackwards.x, t, ANIMPRIO_ACTIVE);
 214                         case ANIMIMPLICITSTATE_RIGHT:
 215                                 return vec3(e.anim_straferight.x, t, ANIMPRIO_ACTIVE);
 216                         case ANIMIMPLICITSTATE_LEFT:
 217                                 return vec3(e.anim_strafeleft.x, t, ANIMPRIO_ACTIVE);
 218                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_RIGHT:
 219                                 return vec3(e.anim_forwardright.x, t, ANIMPRIO_ACTIVE);
 220                         case ANIMIMPLICITSTATE_FORWARD | ANIMIMPLICITSTATE_LEFT:
 221                                 return vec3(e.anim_forwardleft.x, t, ANIMPRIO_ACTIVE);
 222                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_RIGHT:
 223                                 return vec3(e.anim_backright.x, t, ANIMPRIO_ACTIVE);
 224                         case ANIMIMPLICITSTATE_BACKWARDS | ANIMIMPLICITSTATE_LEFT:
 225                                 return vec3(e.anim_backleft.x, t, ANIMPRIO_ACTIVE);
 226                         default:
 227                                 return vec3(e.anim_idle.x, t, ANIMPRIO_IDLE);
 228                 }
 229         }
 230         // can't get here
 231         return vec3(e.anim_idle.x, t, ANIMPRIO_IDLE);
 232 }
 233
 234 void animdecide_setimplicitstate(entity e, float onground)
 235 {
 236         int s = 0;
 237
 238         makevectors(e.angles);
 239         vector v;
 240         v.x = e.velocity * v_forward;
 241         v.y = e.velocity * v_right;
 242         v.z = 0;
 243
 244         // we want to match like this:
 245         // the 8 directions shall be "evenly spaced"
 246         // that means, the forward key includes anything from -67.5 to +67.5 degrees
 247         // which then means x > |y| * cot(3pi/8)
 248         //
 249         // BUT, the engine's clip-movement-to-keyboard function uses 0.5 here,
 250         // which would be an angle range from -63.43 to +63.43 degrees, making
 251         // it slightly less likely to "hit two keys at once", so let's do this
 252         // here too
 253
 254         if(vlen(v) > 10)
 255         {
 256                 if(v.x >  fabs(v.y) * 0.5)
 257                         s |= ANIMIMPLICITSTATE_FORWARD;
 258                 if(v.x < -fabs(v.y) * 0.5)
 259                         s |= ANIMIMPLICITSTATE_BACKWARDS;
 260                 if(v.y >  fabs(v.x) * 0.5)
 261                         s |= ANIMIMPLICITSTATE_RIGHT;
 262                 if(v.y < -fabs(v.x) * 0.5)
 263                         s |= ANIMIMPLICITSTATE_LEFT;
 264         }
 265         if(!onground)
 266                 s |= ANIMIMPLICITSTATE_INAIR;
 267
 268         // detect some kinds of otherwise misdetected jumps (ground to air transition)
 269         // NOTE: currently, in CSQC this is the only jump detection, as the explicit jump action is never called!
 270         if(!(e.anim_implicit_state & ANIMIMPLICITSTATE_INAIR) && (s & ANIMIMPLICITSTATE_INAIR))
 271         {
 272                 e.anim_lower_implicit_action = ANIMACTION_JUMP;
 273                 e.anim_lower_implicit_time = time;
 274         }
 275
 276         if(s != e.anim_implicit_state)
 277         {
 278                 e.anim_implicit_state = s;
 279                 e.anim_implicit_time = time;
 280         }
 281 }
 282 void animdecide_setframes(entity e, float support_blending, .float fld_frame, .float fld_frame1time, .float fld_frame2, .float fld_frame2time)
 283 {
 284         // _x: frame
 285         // _y: start time
 286         // _z: priority
 287         vector upper = animdecide_getupperanim(e);
 288         vector lower = animdecide_getloweranim(e);
 289         //print("UPPER: ", vtos(upper), ", LOWER: ", vtos(lower), "\n");
 290         if(support_blending)
 291         {
 292                 if(upper.z && !lower.z)
 293                         lower = upper;
 294                 else if(lower.z && !upper.z)
 295                         upper = lower;
 296                 if(e.frame1time != upper.y || e.frame2time != lower.y)
 297                         BITXOR_ASSIGN(e.effects, EF_RESTARTANIM_BIT);
 298                 e.(fld_frame) = upper.x;
 299                 e.(fld_frame1time) = upper.y;
 300                 e.(fld_frame2) = lower.x;
 301                 e.(fld_frame2time) = lower.y;
 302         }
 303         else
 304         {
 305                 if(upper.z > lower.z)
 306                         lower = upper;
 307                 else if(lower.z > upper.z)
 308                         upper = lower;
 309                 if(e.frame1time != upper.y)
 310                         BITXOR_ASSIGN(e.effects, EF_RESTARTANIM_BIT);
 311                 e.(fld_frame) = upper.x;
 312                 e.(fld_frame1time) = upper.y;
 313         }
 314 }
 315
 316 void animdecide_setstate(entity e, int newstate, float restart)
 317 {
 318         if(!restart)
 319                 if(newstate == e.anim_state)
 320                         return;
 321         e.anim_state = newstate;
 322         e.anim_time = time;
 323 }
 324 void animdecide_setaction(entity e, float action, float restart)
 325 {
 326         if(action < 0)
 327         {
 328                 if(!restart)
 329                         if(action == e.anim_lower_action)
 330                                 return;
 331                 e.anim_lower_action = action;
 332                 e.anim_lower_time = time;
 333         }
 334         else
 335         {
 336                 if(!restart)
 337                         if(action == e.anim_upper_action)
 338                                 return;
 339                 e.anim_upper_action = action;
 340                 e.anim_upper_time = time;
 341         }
 342 }