Fix restartnotifs command
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / command / generic.qc
1 // =========================================================
2 //  Generic program common command code, written by Samual
3 //  Last updated: February 19th, 2012
4 // =========================================================
5
6 // used by generic commands for better help/usage information
7 string GetProgramCommandPrefix(void)
8 {
9         #ifdef SVQC
10         return "sv_cmd";
11         #endif
12         #ifdef CSQC
13         return "cl_cmd";
14         #endif
15         #ifdef MENUQC
16         return "menu_cmd";
17         #endif
18 }
19
20 // used by curl command
21 void Curl_URI_Get_Callback(float id, float status, string data)
22 {
23         float i;
24         float do_exec;
25         string do_cvar;
26         i = id - URI_GET_CURL;
27         do_exec = curl_uri_get_exec[i];
28         do_cvar = curl_uri_get_cvar[i];
29         if(status != 0)
30         {
31                 print(sprintf(_("error: status is %d\n"), status));
32                 if(do_cvar)
33                         strunzone(do_cvar);
34                 return;
35         }
36         if(do_exec)
37                 localcmd(data);
38         if(do_cvar)
39         {
40                 cvar_set(do_cvar, data);
41                 strunzone(do_cvar);
42         }
43         if(!do_exec)
44                 if not(do_cvar)
45                         print(data);
46 }
47
48
49 // =======================
50 //  Command Sub-Functions
51 // =======================
52
53 void GenericCommand_addtolist(float request, float argc)
54 {
55         switch(request)
56         {
57                 case CMD_REQUEST_COMMAND:
58                 {
59                         float i;
60                         
61                         if(argc >= 2)
62                         {
63                                 string original_cvar = argv(1);
64                                 string tmp_string = argv(2);
65                                 
66                                 if(cvar_string(original_cvar) == "") // cvar was empty
67                                 {
68                                         cvar_set(original_cvar, tmp_string);
69                                 }
70                                 else // add it to the end of the list if the list doesn't already have it
71                                 {
72                                         argc = tokenizebyseparator(cvar_string(original_cvar), " ");
73                                         
74                                         for(i = 0; i < argc; ++i)
75                                                 if(argv(i) == tmp_string)
76                                                         return; // already in list
77                                                         
78                                         cvar_set(original_cvar, strcat(tmp_string, " ", cvar_string(original_cvar)));
79                                 }
80                                 return;
81                         }
82                 }
83                         
84                 default:
85                         print("Incorrect parameters for ^2addtolist^7\n");
86                 case CMD_REQUEST_USAGE:
87                 {
88                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " addtolist variable value\n"));
89                         print("  Where 'variable' is what to add 'value' to.\n");
90                         print("See also: ^2removefromlist^7\n");
91                         return;
92                 }
93         }
94 }
95
96 void GenericCommand_qc_curl(float request, float argc)
97 {
98         switch(request)
99         {
100                 case CMD_REQUEST_COMMAND:
101                 {
102                         float do_exec;
103                         string do_cvar;
104                         float key;
105                         float i, j;
106                         string url;
107                         float buf;
108                         float r;
109
110                         do_exec = FALSE;
111                         do_cvar = string_null;
112                         key = -1;
113
114                         for(i = 1; i+1 < argc; ++i)
115                         {
116                                 if(argv(i) == "--cvar" && i+2 < argc)
117                                 {
118                                         ++i;
119                                         do_cvar = strzone(argv(i));
120                                         continue;
121                                 }
122                                 if(argv(i) == "--exec")
123                                 {
124                                         do_exec = TRUE;
125                                         continue;
126                                 }
127                                 if(argv(i) == "--key" && i+2 < argc)
128                                 {
129                                         ++i;
130                                         key = stof(argv(i));
131                                         continue;
132                                 }
133                                 break;
134                         }
135
136                         // now, argv(i) is the URL
137                         // following args may be POST parameters
138                         url = argv(i);
139                         ++i;
140                         buf = buf_create();
141                         j = 0;
142                         for(; i+1 < argc; i += 2)
143                                 bufstr_set(buf, ++j, sprintf("%s=%s", uri_escape(argv(i)), uri_escape(argv(i+1))));
144                         if(i < argc)
145                                 bufstr_set(buf, ++j, sprintf("submit=%s", uri_escape(argv(i))));
146
147                         if(j == 0) // no args: GET
148                                 r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, string_null, string_null, -1, key);
149                         else // with args: POST
150                                 r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, "application/x-www-form-urlencoded", "&", buf, key);
151
152                         if(r)
153                         {
154                                 curl_uri_get_exec[curl_uri_get_pos] = do_exec;
155                                 curl_uri_get_cvar[curl_uri_get_pos] = do_cvar;
156                                 curl_uri_get_pos = mod(curl_uri_get_pos + 1, URI_GET_CURL_END - URI_GET_CURL + 1);
157                         }
158                         else
159                                 print(_("error creating curl handle\n"));
160
161                         buf_del(buf);
162
163                         return;
164                 }
165                         
166                 default:
167                 case CMD_REQUEST_USAGE:
168                 {
169                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " qc_curl [--key N] [--cvar] [--exec] URL [postargs...]"));
170                         return;
171                 }
172         }
173 }
174
175 void GenericCommand_dumpcommands(float request)
176 {
177         switch(request)
178         {
179                 case CMD_REQUEST_COMMAND:
180                 {
181                         float fh;
182                         string filename = strcat(GetProgramCommandPrefix(), "_dump.txt");
183                         fh = fopen(filename, FILE_WRITE);
184                         
185                         if(fh >= 0)
186                         {
187                                 #ifdef SVQC
188                                         CMD_Write("dump of server console commands:\n");
189                                         GameCommand_macro_write_aliases(fh);
190                                         
191                                         CMD_Write("\ndump of networked client only commands:\n");
192                                         ClientCommand_macro_write_aliases(fh);
193                                         
194                                         CMD_Write("\ndump of common commands:\n");
195                                         CommonCommand_macro_write_aliases(fh);
196
197                                         CMD_Write("\ndump of ban commands:\n");
198                                         BanCommand_macro_write_aliases(fh);
199                                 #endif
200                                                                 
201                                 #ifdef CSQC
202                                         CMD_Write("dump of client commands:\n");
203                                         LocalCommand_macro_write_aliases(fh);
204                                 #endif
205                                 
206                                 CMD_Write("\ndump of generic commands:\n");
207                                 GenericCommand_macro_write_aliases(fh);
208                                 
209                                 print("Completed dump of aliases in ^2data/data/", GetProgramCommandPrefix(), "_dump.txt^7.\n");
210                                 
211                                 fclose(fh);
212                         }
213                         else
214                         {
215                                 print("^1Error: ^7Could not dump to file!\n");
216                         }
217                         return;
218                 }
219                         
220                 default:
221                 case CMD_REQUEST_USAGE:
222                 {
223                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpcommands"));
224                         print("  No arguments required.\n");
225                         return;
226                 }
227         }
228 }
229
230 void GenericCommand_dumpnotifs(float request)
231 {
232         switch(request)
233         {
234                 case CMD_REQUEST_COMMAND:
235                 {
236                         #ifndef MENUQC
237                         float fh, alsoprint = FALSE;
238                         string filename = argv(1);
239                         
240                         if(filename == "")
241                         {
242                                 filename = "notifications.cfg";
243                                 alsoprint = FALSE;
244                         }
245                         else if(filename == "-")
246                         {
247                                 filename = "notifications.cfg";
248                                 alsoprint = TRUE;
249                         }
250                         fh = fopen(filename, FILE_WRITE);
251                         
252                         if(fh >= 0)
253                         {
254                                 Dump_Notifications(fh, alsoprint);
255                                 print(sprintf("Dumping notifications... File located in ^2data/data/%s^7.\n", filename));
256                                 fclose(fh);
257                         }
258                         else
259                         {
260                                 print(sprintf("^1Error: ^7Could not open file '%s'!\n", filename));
261                         }
262                         #else
263                         print(_("Notification dump command only works with cl_cmd and sv_cmd.\n"));
264                         #endif
265                         return;
266                 }
267                         
268                 default:
269                 case CMD_REQUEST_USAGE:
270                 {
271                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]"));
272                         print("  Where 'filename' is the file to write (default is notifications.cfg),\n");
273                         print("  if supplied with '-' output to console as well as default,\n");
274                         print("  if left blank, it will only write to default.\n");
275                         return;
276                 }
277         }
278 }
279
280 void GenericCommand_maplist(float request, float argc)
281 {
282         switch(request)
283         {
284                 case CMD_REQUEST_COMMAND:
285                 {
286                         string tmp_string;
287                         float i;
288                         
289                         switch(argv(1))
290                         {
291                                 case "add": // appends new maps to the maplist
292                                 {
293                                         if(argc == 3)
294                                         {
295                                                 if (!fexists(strcat("maps/", argv(2), ".bsp")))
296                                                 {
297                                                         print("maplist: ERROR: ", argv(2), " does not exist!\n");
298                                                         break;
299                                                 }
300                                                 
301                                                 if(cvar_string("g_maplist") == "")
302                                                         cvar_set("g_maplist", argv(2));
303                                                 else
304                                                         cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
305                                                         
306                                                 return;
307                                         }
308                                         break; // go to usage
309                                 }
310                                 
311                                 case "cleanup": // scans maplist and only adds back the ones which are really usable
312                                 {
313                                         MapInfo_Enumerate();
314                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
315                                         argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
316                                         
317                                         tmp_string = "";
318                                         for(i = 0; i < argc; ++i)
319                                                 if(MapInfo_CheckMap(argv(i)))
320                                                         tmp_string = strcat(tmp_string, " ", argv(i));
321                                                         
322                                         tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
323                                         cvar_set("g_maplist", tmp_string);
324                                         
325                                         return;
326                                 }
327                                 
328                                 case "remove": // scans maplist and only adds back whatever maps were not provided in argv(2)
329                                 {
330                                         if(argc == 3)
331                                         {
332                                                 argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
333                                                 
334                                                 tmp_string = "";
335                                                 for(i = 0; i < argc; ++i)
336                                                         if(argv(i) != argv(2))
337                                                                 tmp_string = strcat(tmp_string, " ", argv(i));
338                                                                 
339                                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
340                                                 cvar_set("g_maplist", tmp_string);
341                                                 
342                                                 return;
343                                         }
344                                         break; // go to usage
345                                 }
346                                 
347                                 case "shuffle": // randomly shuffle the maplist
348                                 {
349                                         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
350                                         return;
351                                 }
352                                         
353                                 default: break;
354                         }
355                 }
356                         
357                 default:
358                         print("Incorrect parameters for ^2maplist^7\n");
359                 case CMD_REQUEST_USAGE:
360                 {
361                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " maplist action [map]\n"));
362                         print("  Where 'action' is the command to complete,\n");
363                         print("  and 'map' is what it acts upon (if required).\n");
364                         print("  Full list of commands here: \"add, cleanup, remove, shuffle.\"\n");
365                         return;
366                 }
367         }
368 }
369
370 void GenericCommand_nextframe(float request, float arguments, string command)
371 {
372         switch(request)
373         {
374                 case CMD_REQUEST_COMMAND:
375                 {
376                         queue_to_execute_next_frame(substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
377                         return;
378                 }
379                         
380                 default:
381                 case CMD_REQUEST_USAGE:
382                 {
383                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " nextframe command...\n"));
384                         print("  Where command will be executed next frame of this VM\n");
385                         return;
386                 }
387         }
388 }
389
390 void GenericCommand_removefromlist(float request, float argc)
391 {
392         switch(request)
393         {
394                 case CMD_REQUEST_COMMAND:
395                 {
396                         if(argc == 3)
397                         {
398                                 float i;
399                                 string original_cvar = argv(1);
400                                 string removal = argv(2);
401                                 string tmp_string;
402                                 
403                                 argc = tokenizebyseparator(cvar_string(original_cvar), " ");
404                                 
405                                 tmp_string = "";
406                                 for(i = 0; i < argc; ++i)
407                                         if(argv(i) != removal)
408                                                 tmp_string = strcat(tmp_string, " ", argv(i));
409                                                 
410                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
411                                 cvar_set(original_cvar, tmp_string);
412                                 
413                                 return;
414                         }
415                 }
416                         
417                 default:
418                         print("Incorrect parameters for ^2removefromlist^7\n");
419                 case CMD_REQUEST_USAGE:
420                 {
421                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " removefromlist variable value\n"));
422                         print("  Where 'variable' is what cvar to remove 'value' from.\n");
423                         print("See also: ^2addtolist^7\n");
424                         return;
425                 }
426         }
427 }
428
429 void GenericCommand_restartnotifs(float request)
430 {
431         switch(request)
432         {
433                 case CMD_REQUEST_COMMAND:
434                 {
435                         #ifndef MENUQC
436                         print(sprintf(
437                                 strcat(
438                                         "Restart_Notifications(): Restarting %d notifications... ",
439                                         "Counts: MSG_ANNCE = %d, MSG_INFO = %d, MSG_CENTER = %d, MSG_MULTI = %d, MSG_CHOICE = %d\n"
440                                 ),
441                                 (
442                                         NOTIF_ANNCE_COUNT +
443                                         NOTIF_INFO_COUNT +
444                                         NOTIF_CENTER_COUNT +
445                                         NOTIF_MULTI_COUNT +
446                                         NOTIF_CHOICE_COUNT
447                                 ),
448                                 NOTIF_ANNCE_COUNT,
449                                 NOTIF_INFO_COUNT,
450                                 NOTIF_CENTER_COUNT,
451                                 NOTIF_MULTI_COUNT,
452                                 NOTIF_CHOICE_COUNT
453                         ));     
454                         Destroy_All_Notifications();
455                         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
456                         #else
457                         print(_("Notification restart command only works with cl_cmd and sv_cmd.\n"));
458                         #endif
459                         return;
460                 }
461                         
462                 default:
463                 case CMD_REQUEST_USAGE:
464                 {
465                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " restartnotifs"));
466                         print("  No arguments required.\n");
467                         return;
468                 }
469         }
470 }
471
472 void GenericCommand_settemp(float request, float argc)
473 {
474         switch(request)
475         {
476                 case CMD_REQUEST_COMMAND:
477                 {
478                         if(argc >= 3)
479                         {
480                                 float f = cvar_settemp(argv(1), argv(2));
481                                 if(f == 1)
482                                         dprint("Creating new settemp tracker for ", argv(1), " and setting it to \"", argv(2), "\" temporarily.\n"); 
483                                 else if(f == -1)
484                                         dprint("Already had a tracker for ", argv(1), ", updating it to \"", argv(2), "\".\n");
485                                 // else cvar_settemp itself errors out
486
487                                 return;
488                         }
489                 }
490
491                 default:
492                         print("Incorrect parameters for ^2settemp^7\n");
493                 case CMD_REQUEST_USAGE:
494                 {
495                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp \"cvar\" \"arguments\"\n"));
496                         print("  Where 'cvar' is the cvar you want to temporarily set with 'arguments'.\n");
497                         print("See also: ^2settemp_restore^7\n");
498                         return;
499                 }
500         }
501 }
502
503 void GenericCommand_settemp_restore(float request, float argc)
504 {
505         switch(request)
506         {
507                 case CMD_REQUEST_COMMAND:
508                 {
509                         float i = cvar_settemp_restore();
510                         
511                         if(i)
512                                 dprint("Restored ", ftos(i), " temporary cvar settings to their original values.\n");
513                         else
514                                 dprint("Nothing to restore.\n");
515                         
516                         return;
517                 }
518                         
519                 default:
520                 case CMD_REQUEST_USAGE:
521                 {
522                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp_restore\n"));
523                         print("  No arguments required.\n");
524                         print("See also: ^2settemp^7\n");
525                         return;
526                 }
527         }
528 }
529
530 void GenericCommand_runtest(float request, float argc)
531 {
532         switch(request)
533         {
534                 case CMD_REQUEST_COMMAND:
535                 {
536                         if(argc > 1)
537                         {
538                                 float i;
539                                 for(i = 1; i < argc; ++i)
540                                         TEST_Run(argv(i));
541                         }
542                         else
543                                 TEST_RunAll();
544                         return;
545                 }
546                         
547                 default:
548                 case CMD_REQUEST_USAGE:
549                 {
550                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " [function to run]"));
551                         return;
552                 }
553         }
554 }
555
556 /* use this when creating a new command, making sure to place it in alphabetical order... also,
557 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
558 void GenericCommand_(float request)
559 {
560         switch(request)
561         {
562                 case CMD_REQUEST_COMMAND:
563                 {
564                         
565                         return;
566                 }
567                         
568                 default:
569                 case CMD_REQUEST_USAGE:
570                 {
571                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " "));
572                         print("  No arguments required.\n");
573                         return;
574                 }
575         }
576 }
577 */
578
579 // ==================================
580 //  Macro system for server commands
581 // ==================================
582
583 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
584 #define GENERIC_COMMANDS(request,arguments,command) \
585         GENERIC_COMMAND("addtolist", GenericCommand_addtolist(request, arguments), "Add a string to a cvar") \
586         GENERIC_COMMAND("dumpcommands", GenericCommand_dumpcommands(request), "Dump all commands on the program to *_cmd_dump.txt") \
587         GENERIC_COMMAND("dumpnotifs", GenericCommand_dumpnotifs(request), "Dump all notifications into notifications_dump.txt") \
588         GENERIC_COMMAND("maplist", GenericCommand_maplist(request, arguments), "Automatic control of maplist") \
589         GENERIC_COMMAND("nextframe", GenericCommand_nextframe(request, arguments, command), "Execute the given command next frame of this VM") \
590         GENERIC_COMMAND("qc_curl", GenericCommand_qc_curl(request, arguments), "Queries a URL") \
591         GENERIC_COMMAND("removefromlist", GenericCommand_removefromlist(request, arguments), "Remove a string from a cvar") \
592         GENERIC_COMMAND("restartnotifs", GenericCommand_restartnotifs(request), "Re-initialize all notifications") \
593         GENERIC_COMMAND("rpn", GenericCommand_rpn(request, arguments, command), "RPN calculator") \
594         GENERIC_COMMAND("settemp", GenericCommand_settemp(request, arguments), "Temporarily set a value to a cvar which is restored later") \
595         GENERIC_COMMAND("settemp_restore", GenericCommand_settemp_restore(request, arguments), "Restore all cvars set by settemp command") \
596         GENERIC_COMMAND("runtest", GenericCommand_runtest(request, arguments), "Run unit tests") \
597         /* nothing */
598
599 void GenericCommand_macro_help()
600 {
601         #define GENERIC_COMMAND(name,function,description) \
602                 { print("  ^2", name, "^7: ", description, "\n"); }
603                 
604         GENERIC_COMMANDS(0, 0, "")
605         #undef GENERIC_COMMAND
606         
607         return;
608 }
609
610 float GenericCommand_macro_command(float argc, string command)
611 {
612         #define GENERIC_COMMAND(name,function,description) \
613                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
614                 
615         GENERIC_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
616         #undef GENERIC_COMMAND
617         
618         return FALSE;
619 }
620
621 float GenericCommand_macro_usage(float argc)
622 {
623         #define GENERIC_COMMAND(name,function,description) \
624                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
625                 
626         GENERIC_COMMANDS(CMD_REQUEST_USAGE, argc, "")
627         #undef GENERIC_COMMAND
628         
629         return FALSE;
630 }
631
632 void GenericCommand_macro_write_aliases(float fh)
633 {
634         #define GENERIC_COMMAND(name,function,description) \
635                 { CMD_Write_Alias("qc_cmd_svmenu", name, description); }
636         
637         GENERIC_COMMANDS(0, 0, "")
638         #undef GENERIC_COMMAND
639         
640         return;
641 }
642         
643
644 // ===========================================
645 //  Main Common Function For Generic Commands
646 // ===========================================
647 // Commands spread out among all programs (menu, client, and server) 
648
649 float GenericCommand(string command)
650 {
651         float argc = tokenize_console(command);
652         float n, j, f, i;
653         string s, s2, c;
654         vector rgb;
655
656         // Guide for working with argc arguments by example:
657         // argc:   1    - 2      - 3     - 4
658         // argv:   0    - 1      - 2     - 3 
659         // cmd     vote - master - login - password
660         
661         if(GenericCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
662         {
663                 return TRUE; // handled by one of the above GenericCommand_* functions
664         }
665         else if(argc >= 3 && argv(0) == "red")
666         {
667                 s = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
668                 localcmd(strcat(argv(1), " ", GenericCommand_markup(s)));
669                 return TRUE;
670         }
671         else if(argc >= 3 && crc16(0, argv(0)) == 38566 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 59830)
672         {
673                 // other test case
674                 s = strconv(2, 0, 0, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
675
676                 n = floor(random() * 6 + 2);
677
678                 s2 = "";
679                 for(i = 0; i < n; ++i)
680                 {
681                         s2 = strcat(s2, "AH");
682                 }
683
684                 if(random() < 0.1)
685                         s2 = strcat(substring(s2, 1, strlen(s2) - 1), "A");
686
687                 if(s == "")
688                         s = s2;
689                 else
690                         if(random() < 0.8)
691                                 s = strcat(s, " ", s2);
692                         else
693                                 s = strcat(s2, " ", s);
694
695                 s2 = substring(s, strlen(s) - 2, 2);
696                 if(s2 == "AH" || s2 == "AY")
697                         s = strcat(s, "))");
698                 else
699                         s = strcat(s, " ))");
700
701                 if(random() < 0.1)
702                         s = substring(s, 0, strlen(s) - 1);
703
704                 if(random() < 0.1)
705                         s = strconv(1, 0, 0, s);
706
707                 localcmd(strcat(argv(1), " ", s));
708
709                 return TRUE;
710         }
711         else if(argc >= 3 && crc16(0, argv(0)) == 3826 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 55790)
712         {
713                 // test case for terencehill's color codes
714                 s = strdecolorize(substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
715                 s2 = "";
716                 
717                 n = strlen(s);
718                 j = ((6 * max(1, floor(strlen(s)/32 + random() * 2 - 1))) / n) * (1 - 2 * (random() > 0.5));
719                 f = random() * 6;
720
721                 for(i = 0; i < n; ++i)
722                 {
723                         c = substring(s, i, 1);
724
725                         if(c == ";")
726                                 c = ":";
727                         else if(c == "^")
728                         {
729                                 c = "^^";
730                                 if(substring(s, i+1, 1) == "^")
731                                         ++i;
732                         }
733
734                         if(c != " ")
735                         {
736                                 rgb = hsl_to_rgb('1 0 0' * (j * i + f) + '0 1 .5');
737                                 c = strcat(rgb_to_hexcolor(rgb), c);
738                         }
739                         s2 = strcat(s2, c);
740                 }
741
742                 localcmd(strcat(argv(1), " ", s2));
743
744                 return TRUE;
745         }
746
747         return FALSE;
748 }