qcsrc/common/command/generic.qc

   1 // =========================================================
   2 //  Generic program common command code, written by Samual
   3 //  Last updated: February 19th, 2012
   4 // =========================================================
   5
   6 // used by generic commands for better help/usage information
   7 string GetProgramCommandPrefix(void)
   8 {
   9         #ifdef SVQC
  10         return "sv_cmd";
  11         #endif
  12         #ifdef CSQC
  13         return "cl_cmd";
  14         #endif
  15         #ifdef MENUQC
  16         return "menu_cmd";
  17         #endif
  18 }
  19
  20 // used by curl command
  21 void Curl_URI_Get_Callback(float id, float status, string data)
  22 {
  23         float i;
  24         float do_exec;
  25         string do_cvar;
  26         i = id - URI_GET_CURL;
  27         do_exec = curl_uri_get_exec[i];
  28         do_cvar = curl_uri_get_cvar[i];
  29         if(status != 0)
  30         {
  31                 print(sprintf(_("error: status is %d\n"), status));
  32                 if(do_cvar)
  33                         strunzone(do_cvar);
  34                 return;
  35         }
  36         if(do_exec)
  37                 localcmd(data);
  38         if(do_cvar)
  39         {
  40                 cvar_set(do_cvar, data);
  41                 strunzone(do_cvar);
  42         }
  43         if(!do_exec && !do_cvar)
  44                 print(data);
  45 }
  46
  47
  48 // =======================
  49 //  Command Sub-Functions
  50 // =======================
  51
  52 void GenericCommand_addtolist(float request, float argc)
  53 {
  54         switch(request)
  55         {
  56                 case CMD_REQUEST_COMMAND:
  57                 {
  58                         float i;
  59
  60                         if(argc >= 2)
  61                         {
  62                                 string original_cvar = argv(1);
  63                                 string tmp_string = argv(2);
  64
  65                                 if(cvar_string(original_cvar) == "") // cvar was empty
  66                                 {
  67                                         cvar_set(original_cvar, tmp_string);
  68                                 }
  69                                 else // add it to the end of the list if the list doesn't already have it
  70                                 {
  71                                         argc = tokenizebyseparator(cvar_string(original_cvar), " ");
  72
  73                                         for(i = 0; i < argc; ++i)
  74                                                 if(argv(i) == tmp_string)
  75                                                         return; // already in list
  76
  77                                         cvar_set(original_cvar, strcat(tmp_string, " ", cvar_string(original_cvar)));
  78                                 }
  79                                 return;
  80                         }
  81                 }
  82
  83                 default:
  84                         print("Incorrect parameters for ^2addtolist^7\n");
  85                 case CMD_REQUEST_USAGE:
  86                 {
  87                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " addtolist variable value\n"));
  88                         print("  Where 'variable' is what to add 'value' to.\n");
  89                         print("See also: ^2removefromlist^7\n");
  90                         return;
  91                 }
  92         }
  93 }
  94
  95 void GenericCommand_qc_curl(float request, float argc)
  96 {
  97         switch(request)
  98         {
  99                 case CMD_REQUEST_COMMAND:
 100                 {
 101                         float do_exec;
 102                         string do_cvar;
 103                         float key;
 104                         float i, j;
 105                         string url;
 106                         float buf;
 107                         float r;
 108
 109                         do_exec = FALSE;
 110                         do_cvar = string_null;
 111                         key = -1;
 112
 113                         for(i = 1; i+1 < argc; ++i)
 114                         {
 115                                 if(argv(i) == "--cvar" && i+2 < argc)
 116                                 {
 117                                         ++i;
 118                                         do_cvar = strzone(argv(i));
 119                                         continue;
 120                                 }
 121                                 if(argv(i) == "--exec")
 122                                 {
 123                                         do_exec = TRUE;
 124                                         continue;
 125                                 }
 126                                 if(argv(i) == "--key" && i+2 < argc)
 127                                 {
 128                                         ++i;
 129                                         key = stof(argv(i));
 130                                         continue;
 131                                 }
 132                                 break;
 133                         }
 134
 135                         // now, argv(i) is the URL
 136                         // following args may be POST parameters
 137                         url = argv(i);
 138                         ++i;
 139                         buf = buf_create();
 140                         j = 0;
 141                         for(; i+1 < argc; i += 2)
 142                                 bufstr_set(buf, ++j, sprintf("%s=%s", uri_escape(argv(i)), uri_escape(argv(i+1))));
 143                         if(i < argc)
 144                                 bufstr_set(buf, ++j, sprintf("submit=%s", uri_escape(argv(i))));
 145
 146                         if(j == 0) // no args: GET
 147                                 r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, string_null, string_null, -1, key);
 148                         else // with args: POST
 149                                 r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, "application/x-www-form-urlencoded", "&", buf, key);
 150
 151                         if(r)
 152                         {
 153                                 curl_uri_get_exec[curl_uri_get_pos] = do_exec;
 154                                 curl_uri_get_cvar[curl_uri_get_pos] = do_cvar;
 155                                 curl_uri_get_pos = mod(curl_uri_get_pos + 1, URI_GET_CURL_END - URI_GET_CURL + 1);
 156                         }
 157                         else
 158                                 print(_("error creating curl handle\n"));
 159
 160                         buf_del(buf);
 161
 162                         return;
 163                 }
 164
 165                 default:
 166                 case CMD_REQUEST_USAGE:
 167                 {
 168                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " qc_curl [--key N] [--cvar] [--exec] URL [postargs...]"));
 169                         return;
 170                 }
 171         }
 172 }
 173
 174 void GenericCommand_dumpcommands(float request)
 175 {
 176         switch(request)
 177         {
 178                 case CMD_REQUEST_COMMAND:
 179                 {
 180                         float fh;
 181                         string filename = strcat(GetProgramCommandPrefix(), "_dump.txt");
 182                         fh = fopen(filename, FILE_WRITE);
 183
 184                         if(fh >= 0)
 185                         {
 186                                 #ifdef SVQC
 187                                         CMD_Write("dump of server console commands:\n");
 188                                         GameCommand_macro_write_aliases(fh);
 189
 190                                         CMD_Write("\ndump of networked client only commands:\n");
 191                                         ClientCommand_macro_write_aliases(fh);
 192
 193                                         CMD_Write("\ndump of common commands:\n");
 194                                         CommonCommand_macro_write_aliases(fh);
 195
 196                                         CMD_Write("\ndump of ban commands:\n");
 197                                         BanCommand_macro_write_aliases(fh);
 198                                 #endif
 199
 200                                 #ifdef CSQC
 201                                         CMD_Write("dump of client commands:\n");
 202                                         LocalCommand_macro_write_aliases(fh);
 203                                 #endif
 204
 205                                 CMD_Write("\ndump of generic commands:\n");
 206                                 GenericCommand_macro_write_aliases(fh);
 207
 208                                 print("Completed dump of aliases in ^2data/data/", GetProgramCommandPrefix(), "_dump.txt^7.\n");
 209
 210                                 fclose(fh);
 211                         }
 212                         else
 213                         {
 214                                 print("^1Error: ^7Could not dump to file!\n");
 215                         }
 216                         return;
 217                 }
 218
 219                 default:
 220                 case CMD_REQUEST_USAGE:
 221                 {
 222                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpcommands"));
 223                         print("  No arguments required.\n");
 224                         return;
 225                 }
 226         }
 227 }
 228
 229 void GenericCommand_dumpnotifs(float request)
 230 {
 231         switch(request)
 232         {
 233                 case CMD_REQUEST_COMMAND:
 234                 {
 235                         float fh, alsoprint;
 236
 237                         string filename = argv(1);
 238
 239                         if(filename == "")
 240                         {
 241                                 filename = "notifications_dump.txt";
 242                                 alsoprint = FALSE;
 243                         }
 244                         else if(filename == "-")
 245                         {
 246                                 filename = "notifications_dump.txt";
 247                                 alsoprint = TRUE;
 248                         }
 249                         fh = fopen(filename, FILE_WRITE);
 250
 251                         if(fh >= 0)
 252                         {
 253                                 fputs(fh, "dump of notifications list:\n");
 254                                 if(alsoprint) { print("dump of notifications list:\n"); }
 255                                 Dump_Notifications(fh, alsoprint);
 256                                 print(sprintf("File located in ^2data/data/%s^7.\n", filename));
 257                                 fclose(fh);
 258                         }
 259                         else
 260                         {
 261                                 print(sprintf("^1Error: ^7Could not open file '%s'!\n", filename));
 262                         }
 263                         return;
 264                 }
 265
 266                 default:
 267                 case CMD_REQUEST_USAGE:
 268                 {
 269                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]"));
 270                         print("  Where 'filename' is the file to write (default is notifications_dump.txt),\n");
 271                         print("  if supplied with '-' output to console as well as default,\n");
 272                         print("  if left blank, it will only write to default.\n");
 273                         return;
 274                 }
 275         }
 276 }
 277
 278 void GenericCommand_maplist(float request, float argc)
 279 {
 280         switch(request)
 281         {
 282                 case CMD_REQUEST_COMMAND:
 283                 {
 284                         string tmp_string;
 285                         float i;
 286
 287                         switch(argv(1))
 288                         {
 289                                 case "add": // appends new maps to the maplist
 290                                 {
 291                                         if(argc == 3)
 292                                         {
 293                                                 if (!fexists(strcat("maps/", argv(2), ".bsp")))
 294                                                 {
 295                                                         print("maplist: ERROR: ", argv(2), " does not exist!\n");
 296                                                         break;
 297                                                 }
 298
 299                                                 if(cvar_string("g_maplist") == "")
 300                                                         cvar_set("g_maplist", argv(2));
 301                                                 else
 302                                                         cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
 303
 304                                                 return;
 305                                         }
 306                                         break; // go to usage
 307                                 }
 308
 309                                 case "cleanup": // scans maplist and only adds back the ones which are really usable
 310                                 {
 311                                         MapInfo_Enumerate();
 312                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 313                                         argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
 314
 315                                         tmp_string = "";
 316                                         for(i = 0; i < argc; ++i)
 317                                                 if(MapInfo_CheckMap(argv(i)))
 318                                                         tmp_string = strcat(tmp_string, " ", argv(i));
 319
 320                                         tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 321                                         cvar_set("g_maplist", tmp_string);
 322
 323                                         return;
 324                                 }
 325
 326                                 case "remove": // scans maplist and only adds back whatever maps were not provided in argv(2)
 327                                 {
 328                                         if(argc == 3)
 329                                         {
 330                                                 argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
 331
 332                                                 tmp_string = "";
 333                                                 for(i = 0; i < argc; ++i)
 334                                                         if(argv(i) != argv(2))
 335                                                                 tmp_string = strcat(tmp_string, " ", argv(i));
 336
 337                                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 338                                                 cvar_set("g_maplist", tmp_string);
 339
 340                                                 return;
 341                                         }
 342                                         break; // go to usage
 343                                 }
 344
 345                                 case "shuffle": // randomly shuffle the maplist
 346                                 {
 347                                         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
 348                                         return;
 349                                 }
 350
 351                                 default: break;
 352                         }
 353                 }
 354
 355                 default:
 356                         print("Incorrect parameters for ^2maplist^7\n");
 357                 case CMD_REQUEST_USAGE:
 358                 {
 359                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " maplist action [map]\n"));
 360                         print("  Where 'action' is the command to complete,\n");
 361                         print("  and 'map' is what it acts upon (if required).\n");
 362                         print("  Full list of commands here: \"add, cleanup, remove, shuffle.\"\n");
 363                         return;
 364                 }
 365         }
 366 }
 367
 368 void GenericCommand_nextframe(float request, float arguments, string command)
 369 {
 370         switch(request)
 371         {
 372                 case CMD_REQUEST_COMMAND:
 373                 {
 374                         queue_to_execute_next_frame(substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 375                         return;
 376                 }
 377
 378                 default:
 379                 case CMD_REQUEST_USAGE:
 380                 {
 381                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " nextframe command...\n"));
 382                         print("  Where command will be executed next frame of this VM\n");
 383                         return;
 384                 }
 385         }
 386 }
 387
 388 void GenericCommand_removefromlist(float request, float argc)
 389 {
 390         switch(request)
 391         {
 392                 case CMD_REQUEST_COMMAND:
 393                 {
 394                         if(argc == 3)
 395                         {
 396                                 float i;
 397                                 string original_cvar = argv(1);
 398                                 string removal = argv(2);
 399                                 string tmp_string;
 400
 401                                 argc = tokenizebyseparator(cvar_string(original_cvar), " ");
 402
 403                                 tmp_string = "";
 404                                 for(i = 0; i < argc; ++i)
 405                                         if(argv(i) != removal)
 406                                                 tmp_string = strcat(tmp_string, " ", argv(i));
 407
 408                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 409                                 cvar_set(original_cvar, tmp_string);
 410
 411                                 return;
 412                         }
 413                 }
 414
 415                 default:
 416                         print("Incorrect parameters for ^2removefromlist^7\n");
 417                 case CMD_REQUEST_USAGE:
 418                 {
 419                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " removefromlist variable value\n"));
 420                         print("  Where 'variable' is what cvar to remove 'value' from.\n");
 421                         print("See also: ^2addtolist^7\n");
 422                         return;
 423                 }
 424         }
 425 }
 426
 427 void GenericCommand_settemp(float request, float argc)
 428 {
 429         switch(request)
 430         {
 431                 case CMD_REQUEST_COMMAND:
 432                 {
 433                         if(argc >= 3)
 434                         {
 435                                 float f = cvar_settemp(argv(1), argv(2));
 436                                 if(f == 1)
 437                                         dprint("Creating new settemp tracker for ", argv(1), " and setting it to \"", argv(2), "\" temporarily.\n");
 438                                 else if(f == -1)
 439                                         dprint("Already had a tracker for ", argv(1), ", updating it to \"", argv(2), "\".\n");
 440                                 // else cvar_settemp itself errors out
 441
 442                                 return;
 443                         }
 444                 }
 445
 446                 default:
 447                         print("Incorrect parameters for ^2settemp^7\n");
 448                 case CMD_REQUEST_USAGE:
 449                 {
 450                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp \"cvar\" \"arguments\"\n"));
 451                         print("  Where 'cvar' is the cvar you want to temporarily set with 'arguments'.\n");
 452                         print("See also: ^2settemp_restore^7\n");
 453                         return;
 454                 }
 455         }
 456 }
 457
 458 void GenericCommand_settemp_restore(float request, float argc)
 459 {
 460         switch(request)
 461         {
 462                 case CMD_REQUEST_COMMAND:
 463                 {
 464                         float i = cvar_settemp_restore();
 465
 466                         if(i)
 467                                 dprint("Restored ", ftos(i), " temporary cvar settings to their original values.\n");
 468                         else
 469                                 dprint("Nothing to restore.\n");
 470
 471                         return;
 472                 }
 473
 474                 default:
 475                 case CMD_REQUEST_USAGE:
 476                 {
 477                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp_restore\n"));
 478                         print("  No arguments required.\n");
 479                         print("See also: ^2settemp^7\n");
 480                         return;
 481                 }
 482         }
 483 }
 484
 485 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 486 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 487 void GenericCommand_(float request)
 488 {
 489         switch(request)
 490         {
 491                 case CMD_REQUEST_COMMAND:
 492                 {
 493
 494                         return;
 495                 }
 496
 497                 default:
 498                 case CMD_REQUEST_USAGE:
 499                 {
 500                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " "));
 501                         print("  No arguments required.\n");
 502                         return;
 503                 }
 504         }
 505 }
 506 */
 507
 508 // ==================================
 509 //  Macro system for server commands
 510 // ==================================
 511
 512 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 513 #define GENERIC_COMMANDS(request,arguments,command) \
 514         GENERIC_COMMAND("addtolist", GenericCommand_addtolist(request, arguments), "Add a string to a cvar") \
 515         GENERIC_COMMAND("dumpcommands", GenericCommand_dumpcommands(request), "Dump all commands on the program to *_cmd_dump.txt") \
 516         GENERIC_COMMAND("dumpnotifs", GenericCommand_dumpnotifs(request), "Dump all notifications into notifications_dump.txt") \
 517         GENERIC_COMMAND("maplist", GenericCommand_maplist(request, arguments), "Automatic control of maplist") \
 518         GENERIC_COMMAND("nextframe", GenericCommand_nextframe(request, arguments, command), "Execute the given command next frame of this VM") \
 519         GENERIC_COMMAND("qc_curl", GenericCommand_qc_curl(request, arguments), "Queries a URL") \
 520         GENERIC_COMMAND("removefromlist", GenericCommand_removefromlist(request, arguments), "Remove a string from a cvar") \
 521         GENERIC_COMMAND("rpn", GenericCommand_rpn(request, arguments, command), "RPN calculator") \
 522         GENERIC_COMMAND("settemp", GenericCommand_settemp(request, arguments), "Temporarily set a value to a cvar which is restored later") \
 523         GENERIC_COMMAND("settemp_restore", GenericCommand_settemp_restore(request, arguments), "Restore all cvars set by settemp command") \
 524         /* nothing */
 525
 526 void GenericCommand_macro_help()
 527 {
 528         #define GENERIC_COMMAND(name,function,description) \
 529                 { print("  ^2", name, "^7: ", description, "\n"); }
 530
 531         GENERIC_COMMANDS(0, 0, "")
 532         #undef GENERIC_COMMAND
 533
 534         return;
 535 }
 536
 537 float GenericCommand_macro_command(float argc, string command)
 538 {
 539         #define GENERIC_COMMAND(name,function,description) \
 540                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 541
 542         GENERIC_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 543         #undef GENERIC_COMMAND
 544
 545         return FALSE;
 546 }
 547
 548 float GenericCommand_macro_usage(float argc)
 549 {
 550         #define GENERIC_COMMAND(name,function,description) \
 551                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 552
 553         GENERIC_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 554         #undef GENERIC_COMMAND
 555
 556         return FALSE;
 557 }
 558
 559 void GenericCommand_macro_write_aliases(float fh)
 560 {
 561         #define GENERIC_COMMAND(name,function,description) \
 562                 { CMD_Write_Alias("qc_cmd_svmenu", name, description); }
 563
 564         GENERIC_COMMANDS(0, 0, "")
 565         #undef GENERIC_COMMAND
 566
 567         return;
 568 }
 569
 570
 571 // ===========================================
 572 //  Main Common Function For Generic Commands
 573 // ===========================================
 574 // Commands spread out among all programs (menu, client, and server)
 575
 576 float GenericCommand(string command)
 577 {
 578         float argc = tokenize_console(command);
 579         float n, j, f, i;
 580         string s, s2, c;
 581         vector rgb;
 582
 583         // Guide for working with argc arguments by example:
 584         // argc:   1    - 2      - 3     - 4
 585         // argv:   0    - 1      - 2     - 3
 586         // cmd     vote - master - login - password
 587
 588         if(GenericCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 589         {
 590                 return TRUE; // handled by one of the above GenericCommand_* functions
 591         }
 592         else if(argc >= 3 && argv(0) == "red")
 593         {
 594                 s = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 595                 localcmd(strcat(argv(1), " ", GenericCommand_markup(s)));
 596                 return TRUE;
 597         }
 598         else if(argc >= 3 && crc16(0, argv(0)) == 38566 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 59830)
 599         {
 600                 // other test case
 601                 s = strconv(2, 0, 0, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 602
 603                 n = floor(random() * 6 + 2);
 604
 605                 s2 = "";
 606                 for(i = 0; i < n; ++i)
 607                 {
 608                         s2 = strcat(s2, "AH");
 609                 }
 610
 611                 if(random() < 0.1)
 612                         s2 = strcat(substring(s2, 1, strlen(s2) - 1), "A");
 613
 614                 if(s == "")
 615                         s = s2;
 616                 else
 617                         if(random() < 0.8)
 618                                 s = strcat(s, " ", s2);
 619                         else
 620                                 s = strcat(s2, " ", s);
 621
 622                 s2 = substring(s, strlen(s) - 2, 2);
 623                 if(s2 == "AH" || s2 == "AY")
 624                         s = strcat(s, "))");
 625                 else
 626                         s = strcat(s, " ))");
 627
 628                 if(random() < 0.1)
 629                         s = substring(s, 0, strlen(s) - 1);
 630
 631                 if(random() < 0.1)
 632                         s = strconv(1, 0, 0, s);
 633
 634                 localcmd(strcat(argv(1), " ", s));
 635
 636                 return TRUE;
 637         }
 638         else if(argc >= 3 && crc16(0, argv(0)) == 3826 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 55790)
 639         {
 640                 // test case for terencehill's color codes
 641                 s = strdecolorize(substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 642                 s2 = "";
 643
 644                 n = strlen(s);
 645                 j = ((6 * max(1, floor(strlen(s)/32 + random() * 2 - 1))) / n) * (1 - 2 * (random() > 0.5));
 646                 f = random() * 6;
 647
 648                 for(i = 0; i < n; ++i)
 649                 {
 650                         c = substring(s, i, 1);
 651
 652                         if(c == ";")
 653                                 c = ":";
 654                         else if(c == "^")
 655                         {
 656                                 c = "^^";
 657                                 if(substring(s, i+1, 1) == "^")
 658                                         ++i;
 659                         }
 660
 661                         if(c != " ")
 662                         {
 663                                 rgb = hsl_to_rgb('1 0 0' * (j * i + f) + '0 1 .5');
 664                                 c = strcat(rgb_to_hexcolor(rgb), c);
 665                         }
 666                         s2 = strcat(s2, c);
 667                 }
 668
 669                 localcmd(strcat(argv(1), " ", s2));
 670
 671                 return TRUE;
 672         }
 673
 674         return FALSE;
 675 }