qcsrc/common/command/generic.qc

   1 // =========================================================
   2 //  Generic program common command code, written by Samual
   3 //  Last updated: February 19th, 2012
   4 // =========================================================
   5
   6 // used by generic commands for better help/usage information
   7 string GetProgramCommandPrefix(void)
   8 {
   9         #ifdef SVQC
  10         return "sv_cmd";
  11         #endif
  12         #ifdef CSQC
  13         return "cl_cmd";
  14         #endif
  15         #ifdef MENUQC
  16         return "menu_cmd";
  17         #endif
  18 }
  19
  20 // used by curl command
  21 void Curl_URI_Get_Callback(float id, float status, string data)
  22 {
  23         float i;
  24         float do_exec;
  25         string do_cvar;
  26         i = id - URI_GET_CURL;
  27         do_exec = curl_uri_get_exec[i];
  28         do_cvar = curl_uri_get_cvar[i];
  29         if(status != 0)
  30         {
  31                 print(sprintf(_("error: status is %d\n"), status));
  32                 if(do_cvar)
  33                         strunzone(do_cvar);
  34                 return;
  35         }
  36         if(do_exec)
  37                 localcmd(data);
  38         if(do_cvar)
  39         {
  40                 cvar_set(do_cvar, data);
  41                 strunzone(do_cvar);
  42         }
  43         if(!do_exec)
  44                 if not(do_cvar)
  45                         print(data);
  46 }
  47
  48
  49 // =======================
  50 //  Command Sub-Functions
  51 // =======================
  52
  53 void GenericCommand_addtolist(float request, float argc)
  54 {
  55         switch(request)
  56         {
  57                 case CMD_REQUEST_COMMAND:
  58                 {
  59                         float i;
  60
  61                         if(argc >= 2)
  62                         {
  63                                 string original_cvar = argv(1);
  64                                 string tmp_string = argv(2);
  65
  66                                 if(cvar_string(original_cvar) == "") // cvar was empty
  67                                 {
  68                                         cvar_set(original_cvar, tmp_string);
  69                                 }
  70                                 else // add it to the end of the list if the list doesn't already have it
  71                                 {
  72                                         argc = tokenizebyseparator(cvar_string(original_cvar), " ");
  73
  74                                         for(i = 0; i < argc; ++i)
  75                                                 if(argv(i) == tmp_string)
  76                                                         return; // already in list
  77
  78                                         cvar_set(original_cvar, strcat(tmp_string, " ", cvar_string(original_cvar)));
  79                                 }
  80                                 return;
  81                         }
  82                 }
  83
  84                 default:
  85                         print("Incorrect parameters for ^2addtolist^7\n");
  86                 case CMD_REQUEST_USAGE:
  87                 {
  88                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " addtolist variable value\n"));
  89                         print("  Where 'variable' is what to add 'value' to.\n");
  90                         print("See also: ^2removefromlist^7\n");
  91                         return;
  92                 }
  93         }
  94 }
  95
  96 void GenericCommand_qc_curl(float request, float argc)
  97 {
  98         switch(request)
  99         {
 100                 case CMD_REQUEST_COMMAND:
 101                 {
 102                         float do_exec;
 103                         string do_cvar;
 104                         float key;
 105                         float i, j;
 106                         string url;
 107                         float buf;
 108                         float r;
 109
 110                         do_exec = FALSE;
 111                         do_cvar = string_null;
 112                         key = -1;
 113
 114                         for(i = 1; i+1 < argc; ++i)
 115                         {
 116                                 if(argv(i) == "--cvar" && i+2 < argc)
 117                                 {
 118                                         ++i;
 119                                         do_cvar = strzone(argv(i));
 120                                         continue;
 121                                 }
 122                                 if(argv(i) == "--exec")
 123                                 {
 124                                         do_exec = TRUE;
 125                                         continue;
 126                                 }
 127                                 if(argv(i) == "--key" && i+2 < argc)
 128                                 {
 129                                         ++i;
 130                                         key = stof(argv(i));
 131                                         continue;
 132                                 }
 133                                 break;
 134                         }
 135
 136                         // now, argv(i) is the URL
 137                         // following args may be POST parameters
 138                         url = argv(i);
 139                         ++i;
 140                         buf = buf_create();
 141                         j = 0;
 142                         for(; i+1 < argc; i += 2)
 143                                 bufstr_set(buf, ++j, sprintf("%s=%s", uri_escape(argv(i)), uri_escape(argv(i+1))));
 144                         if(i < argc)
 145                                 bufstr_set(buf, ++j, sprintf("submit=%s", uri_escape(argv(i))));
 146
 147                         if(j == 0) // no args: GET
 148                                 r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, string_null, string_null, -1, key);
 149                         else // with args: POST
 150                                 r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, "application/x-www-form-urlencoded", "&", buf, key);
 151
 152                         if(r)
 153                         {
 154                                 curl_uri_get_exec[curl_uri_get_pos] = do_exec;
 155                                 curl_uri_get_cvar[curl_uri_get_pos] = do_cvar;
 156                                 curl_uri_get_pos = mod(curl_uri_get_pos + 1, URI_GET_CURL_END - URI_GET_CURL + 1);
 157                         }
 158                         else
 159                                 print(_("error creating curl handle\n"));
 160
 161                         buf_del(buf);
 162
 163                         return;
 164                 }
 165
 166                 default:
 167                 case CMD_REQUEST_USAGE:
 168                 {
 169                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " qc_curl [--key N] [--cvar] [--exec] URL [postargs...]"));
 170                         return;
 171                 }
 172         }
 173 }
 174
 175 void GenericCommand_dumpcommands(float request)
 176 {
 177         switch(request)
 178         {
 179                 case CMD_REQUEST_COMMAND:
 180                 {
 181                         float fh;
 182                         string filename = strcat(GetProgramCommandPrefix(), "_dump.txt");
 183                         fh = fopen(filename, FILE_WRITE);
 184
 185                         if(fh >= 0)
 186                         {
 187                                 #ifdef SVQC
 188                                         CMD_Write("dump of server console commands:\n");
 189                                         GameCommand_macro_write_aliases(fh);
 190
 191                                         CMD_Write("\ndump of networked client only commands:\n");
 192                                         ClientCommand_macro_write_aliases(fh);
 193
 194                                         CMD_Write("\ndump of common commands:\n");
 195                                         CommonCommand_macro_write_aliases(fh);
 196
 197                                         CMD_Write("\ndump of ban commands:\n");
 198                                         BanCommand_macro_write_aliases(fh);
 199                                 #endif
 200
 201                                 #ifdef CSQC
 202                                         CMD_Write("dump of client commands:\n");
 203                                         LocalCommand_macro_write_aliases(fh);
 204                                 #endif
 205
 206                                 CMD_Write("\ndump of generic commands:\n");
 207                                 GenericCommand_macro_write_aliases(fh);
 208
 209                                 print("Completed dump of aliases in ^2data/data/", GetProgramCommandPrefix(), "_dump.txt^7.\n");
 210
 211                                 fclose(fh);
 212                         }
 213                         else
 214                         {
 215                                 print("^1Error: ^7Could not dump to file!\n");
 216                         }
 217                         return;
 218                 }
 219
 220                 default:
 221                 case CMD_REQUEST_USAGE:
 222                 {
 223                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpcommands"));
 224                         print("  No arguments required.\n");
 225                         return;
 226                 }
 227         }
 228 }
 229
 230 void GenericCommand_dumpnotifs(float request)
 231 {
 232         switch(request)
 233         {
 234                 case CMD_REQUEST_COMMAND:
 235                 {
 236                         float fh, alsoprint = FALSE;
 237
 238                         string filename = argv(1);
 239
 240                         if(filename == "")
 241                         {
 242                                 filename = "notifications_dump.txt";
 243                                 alsoprint = FALSE;
 244                         }
 245                         else if(filename == "-")
 246                         {
 247                                 filename = "notifications_dump.txt";
 248                                 alsoprint = TRUE;
 249                         }
 250                         fh = fopen(filename, FILE_WRITE);
 251
 252                         if(fh >= 0)
 253                         {
 254                                 fputs(fh, "dump of notifications list:\n");
 255                                 if(alsoprint) { print("dump of notifications list:\n"); }
 256                                 Dump_Notifications(fh, alsoprint);
 257                                 print(sprintf("File located in ^2data/data/%s^7.\n", filename));
 258                                 fclose(fh);
 259                         }
 260                         else
 261                         {
 262                                 print(sprintf("^1Error: ^7Could not open file '%s'!\n", filename));
 263                         }
 264                         return;
 265                 }
 266
 267                 default:
 268                 case CMD_REQUEST_USAGE:
 269                 {
 270                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]"));
 271                         print("  Where 'filename' is the file to write (default is notifications_dump.txt),\n");
 272                         print("  if supplied with '-' output to console as well as default,\n");
 273                         print("  if left blank, it will only write to default.\n");
 274                         return;
 275                 }
 276         }
 277 }
 278
 279 void GenericCommand_maplist(float request, float argc)
 280 {
 281         switch(request)
 282         {
 283                 case CMD_REQUEST_COMMAND:
 284                 {
 285                         string tmp_string;
 286                         float i;
 287
 288                         switch(argv(1))
 289                         {
 290                                 case "add": // appends new maps to the maplist
 291                                 {
 292                                         if(argc == 3)
 293                                         {
 294                                                 if (!fexists(strcat("maps/", argv(2), ".bsp")))
 295                                                 {
 296                                                         print("maplist: ERROR: ", argv(2), " does not exist!\n");
 297                                                         break;
 298                                                 }
 299
 300                                                 if(cvar_string("g_maplist") == "")
 301                                                         cvar_set("g_maplist", argv(2));
 302                                                 else
 303                                                         cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
 304
 305                                                 return;
 306                                         }
 307                                         break; // go to usage
 308                                 }
 309
 310                                 case "cleanup": // scans maplist and only adds back the ones which are really usable
 311                                 {
 312                                         MapInfo_Enumerate();
 313                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 314                                         argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
 315
 316                                         tmp_string = "";
 317                                         for(i = 0; i < argc; ++i)
 318                                                 if(MapInfo_CheckMap(argv(i)))
 319                                                         tmp_string = strcat(tmp_string, " ", argv(i));
 320
 321                                         tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 322                                         cvar_set("g_maplist", tmp_string);
 323
 324                                         return;
 325                                 }
 326
 327                                 case "remove": // scans maplist and only adds back whatever maps were not provided in argv(2)
 328                                 {
 329                                         if(argc == 3)
 330                                         {
 331                                                 argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
 332
 333                                                 tmp_string = "";
 334                                                 for(i = 0; i < argc; ++i)
 335                                                         if(argv(i) != argv(2))
 336                                                                 tmp_string = strcat(tmp_string, " ", argv(i));
 337
 338                                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 339                                                 cvar_set("g_maplist", tmp_string);
 340
 341                                                 return;
 342                                         }
 343                                         break; // go to usage
 344                                 }
 345
 346                                 case "shuffle": // randomly shuffle the maplist
 347                                 {
 348                                         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
 349                                         return;
 350                                 }
 351
 352                                 default: break;
 353                         }
 354                 }
 355
 356                 default:
 357                         print("Incorrect parameters for ^2maplist^7\n");
 358                 case CMD_REQUEST_USAGE:
 359                 {
 360                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " maplist action [map]\n"));
 361                         print("  Where 'action' is the command to complete,\n");
 362                         print("  and 'map' is what it acts upon (if required).\n");
 363                         print("  Full list of commands here: \"add, cleanup, remove, shuffle.\"\n");
 364                         return;
 365                 }
 366         }
 367 }
 368
 369 void GenericCommand_nextframe(float request, float arguments, string command)
 370 {
 371         switch(request)
 372         {
 373                 case CMD_REQUEST_COMMAND:
 374                 {
 375                         queue_to_execute_next_frame(substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 376                         return;
 377                 }
 378
 379                 default:
 380                 case CMD_REQUEST_USAGE:
 381                 {
 382                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " nextframe command...\n"));
 383                         print("  Where command will be executed next frame of this VM\n");
 384                         return;
 385                 }
 386         }
 387 }
 388
 389 void GenericCommand_removefromlist(float request, float argc)
 390 {
 391         switch(request)
 392         {
 393                 case CMD_REQUEST_COMMAND:
 394                 {
 395                         if(argc == 3)
 396                         {
 397                                 float i;
 398                                 string original_cvar = argv(1);
 399                                 string removal = argv(2);
 400                                 string tmp_string;
 401
 402                                 argc = tokenizebyseparator(cvar_string(original_cvar), " ");
 403
 404                                 tmp_string = "";
 405                                 for(i = 0; i < argc; ++i)
 406                                         if(argv(i) != removal)
 407                                                 tmp_string = strcat(tmp_string, " ", argv(i));
 408
 409                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 410                                 cvar_set(original_cvar, tmp_string);
 411
 412                                 return;
 413                         }
 414                 }
 415
 416                 default:
 417                         print("Incorrect parameters for ^2removefromlist^7\n");
 418                 case CMD_REQUEST_USAGE:
 419                 {
 420                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " removefromlist variable value\n"));
 421                         print("  Where 'variable' is what cvar to remove 'value' from.\n");
 422                         print("See also: ^2addtolist^7\n");
 423                         return;
 424                 }
 425         }
 426 }
 427
 428 void GenericCommand_settemp(float request, float argc)
 429 {
 430         switch(request)
 431         {
 432                 case CMD_REQUEST_COMMAND:
 433                 {
 434                         if(argc >= 3)
 435                         {
 436                                 float f = cvar_settemp(argv(1), argv(2));
 437                                 if(f == 1)
 438                                         dprint("Creating new settemp tracker for ", argv(1), " and setting it to \"", argv(2), "\" temporarily.\n");
 439                                 else if(f == -1)
 440                                         dprint("Already had a tracker for ", argv(1), ", updating it to \"", argv(2), "\".\n");
 441                                 // else cvar_settemp itself errors out
 442
 443                                 return;
 444                         }
 445                 }
 446
 447                 default:
 448                         print("Incorrect parameters for ^2settemp^7\n");
 449                 case CMD_REQUEST_USAGE:
 450                 {
 451                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp \"cvar\" \"arguments\"\n"));
 452                         print("  Where 'cvar' is the cvar you want to temporarily set with 'arguments'.\n");
 453                         print("See also: ^2settemp_restore^7\n");
 454                         return;
 455                 }
 456         }
 457 }
 458
 459 void GenericCommand_settemp_restore(float request, float argc)
 460 {
 461         switch(request)
 462         {
 463                 case CMD_REQUEST_COMMAND:
 464                 {
 465                         float i = cvar_settemp_restore();
 466
 467                         if(i)
 468                                 dprint("Restored ", ftos(i), " temporary cvar settings to their original values.\n");
 469                         else
 470                                 dprint("Nothing to restore.\n");
 471
 472                         return;
 473                 }
 474
 475                 default:
 476                 case CMD_REQUEST_USAGE:
 477                 {
 478                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp_restore\n"));
 479                         print("  No arguments required.\n");
 480                         print("See also: ^2settemp^7\n");
 481                         return;
 482                 }
 483         }
 484 }
 485
 486 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 487 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 488 void GenericCommand_(float request)
 489 {
 490         switch(request)
 491         {
 492                 case CMD_REQUEST_COMMAND:
 493                 {
 494
 495                         return;
 496                 }
 497
 498                 default:
 499                 case CMD_REQUEST_USAGE:
 500                 {
 501                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " "));
 502                         print("  No arguments required.\n");
 503                         return;
 504                 }
 505         }
 506 }
 507 */
 508
 509 // ==================================
 510 //  Macro system for server commands
 511 // ==================================
 512
 513 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 514 #define GENERIC_COMMANDS(request,arguments,command) \
 515         GENERIC_COMMAND("addtolist", GenericCommand_addtolist(request, arguments), "Add a string to a cvar") \
 516         GENERIC_COMMAND("dumpcommands", GenericCommand_dumpcommands(request), "Dump all commands on the program to *_cmd_dump.txt") \
 517         GENERIC_COMMAND("dumpnotifs", GenericCommand_dumpnotifs(request), "Dump all notifications into notifications_dump.txt") \
 518         GENERIC_COMMAND("maplist", GenericCommand_maplist(request, arguments), "Automatic control of maplist") \
 519         GENERIC_COMMAND("nextframe", GenericCommand_nextframe(request, arguments, command), "Execute the given command next frame of this VM") \
 520         GENERIC_COMMAND("qc_curl", GenericCommand_qc_curl(request, arguments), "Queries a URL") \
 521         GENERIC_COMMAND("removefromlist", GenericCommand_removefromlist(request, arguments), "Remove a string from a cvar") \
 522         GENERIC_COMMAND("rpn", GenericCommand_rpn(request, arguments, command), "RPN calculator") \
 523         GENERIC_COMMAND("settemp", GenericCommand_settemp(request, arguments), "Temporarily set a value to a cvar which is restored later") \
 524         GENERIC_COMMAND("settemp_restore", GenericCommand_settemp_restore(request, arguments), "Restore all cvars set by settemp command") \
 525         /* nothing */
 526
 527 void GenericCommand_macro_help()
 528 {
 529         #define GENERIC_COMMAND(name,function,description) \
 530                 { print("  ^2", name, "^7: ", description, "\n"); }
 531
 532         GENERIC_COMMANDS(0, 0, "")
 533         #undef GENERIC_COMMAND
 534
 535         return;
 536 }
 537
 538 float GenericCommand_macro_command(float argc, string command)
 539 {
 540         #define GENERIC_COMMAND(name,function,description) \
 541                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 542
 543         GENERIC_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 544         #undef GENERIC_COMMAND
 545
 546         return FALSE;
 547 }
 548
 549 float GenericCommand_macro_usage(float argc)
 550 {
 551         #define GENERIC_COMMAND(name,function,description) \
 552                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 553
 554         GENERIC_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 555         #undef GENERIC_COMMAND
 556
 557         return FALSE;
 558 }
 559
 560 void GenericCommand_macro_write_aliases(float fh)
 561 {
 562         #define GENERIC_COMMAND(name,function,description) \
 563                 { CMD_Write_Alias("qc_cmd_svmenu", name, description); }
 564
 565         GENERIC_COMMANDS(0, 0, "")
 566         #undef GENERIC_COMMAND
 567
 568         return;
 569 }
 570
 571
 572 // ===========================================
 573 //  Main Common Function For Generic Commands
 574 // ===========================================
 575 // Commands spread out among all programs (menu, client, and server)
 576
 577 float GenericCommand(string command)
 578 {
 579         float argc = tokenize_console(command);
 580         float n, j, f, i;
 581         string s, s2, c;
 582         vector rgb;
 583
 584         // Guide for working with argc arguments by example:
 585         // argc:   1    - 2      - 3     - 4
 586         // argv:   0    - 1      - 2     - 3
 587         // cmd     vote - master - login - password
 588
 589         if(GenericCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 590         {
 591                 return TRUE; // handled by one of the above GenericCommand_* functions
 592         }
 593         else if(argc >= 3 && argv(0) == "red")
 594         {
 595                 s = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 596                 localcmd(strcat(argv(1), " ", GenericCommand_markup(s)));
 597                 return TRUE;
 598         }
 599         else if(argc >= 3 && crc16(0, argv(0)) == 38566 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 59830)
 600         {
 601                 // other test case
 602                 s = strconv(2, 0, 0, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 603
 604                 n = floor(random() * 6 + 2);
 605
 606                 s2 = "";
 607                 for(i = 0; i < n; ++i)
 608                 {
 609                         s2 = strcat(s2, "AH");
 610                 }
 611
 612                 if(random() < 0.1)
 613                         s2 = strcat(substring(s2, 1, strlen(s2) - 1), "A");
 614
 615                 if(s == "")
 616                         s = s2;
 617                 else
 618                         if(random() < 0.8)
 619                                 s = strcat(s, " ", s2);
 620                         else
 621                                 s = strcat(s2, " ", s);
 622
 623                 s2 = substring(s, strlen(s) - 2, 2);
 624                 if(s2 == "AH" || s2 == "AY")
 625                         s = strcat(s, "))");
 626                 else
 627                         s = strcat(s, " ))");
 628
 629                 if(random() < 0.1)
 630                         s = substring(s, 0, strlen(s) - 1);
 631
 632                 if(random() < 0.1)
 633                         s = strconv(1, 0, 0, s);
 634
 635                 localcmd(strcat(argv(1), " ", s));
 636
 637                 return TRUE;
 638         }
 639         else if(argc >= 3 && crc16(0, argv(0)) == 3826 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 55790)
 640         {
 641                 // test case for terencehill's color codes
 642                 s = strdecolorize(substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 643                 s2 = "";
 644
 645                 n = strlen(s);
 646                 j = ((6 * max(1, floor(strlen(s)/32 + random() * 2 - 1))) / n) * (1 - 2 * (random() > 0.5));
 647                 f = random() * 6;
 648
 649                 for(i = 0; i < n; ++i)
 650                 {
 651                         c = substring(s, i, 1);
 652
 653                         if(c == ";")
 654                                 c = ":";
 655                         else if(c == "^")
 656                         {
 657                                 c = "^^";
 658                                 if(substring(s, i+1, 1) == "^")
 659                                         ++i;
 660                         }
 661
 662                         if(c != " ")
 663                         {
 664                                 rgb = hsl_to_rgb('1 0 0' * (j * i + f) + '0 1 .5');
 665                                 c = strcat(rgb_to_hexcolor(rgb), c);
 666                         }
 667                         s2 = strcat(s2, c);
 668                 }
 669
 670                 localcmd(strcat(argv(1), " ", s2));
 671
 672                 return TRUE;
 673         }
 674
 675         return FALSE;
 676 }