qcsrc/common/command/generic.qc

   1 // =========================================================
   2 //  Generic program common command code, written by Samual
   3 //  Last updated: February 19th, 2012
   4 // =========================================================
   5
   6 // used by generic commands for better help/usage information
   7 string GetProgramCommandPrefix(void)
   8 {
   9         #ifdef SVQC
  10         return "sv_cmd";
  11         #endif
  12         #ifdef CSQC
  13         return "cl_cmd";
  14         #endif
  15         #ifdef MENUQC
  16         return "menu_cmd";
  17         #endif
  18 }
  19
  20 // used by curl command
  21 void Curl_URI_Get_Callback(float id, float status, string data)
  22 {
  23         float i;
  24         float do_exec;
  25         string do_cvar;
  26         i = id - URI_GET_CURL;
  27         do_exec = curl_uri_get_exec[i];
  28         do_cvar = curl_uri_get_cvar[i];
  29         if(status != 0)
  30         {
  31                 print(sprintf(_("error: status is %d\n"), status));
  32                 if(do_cvar)
  33                         strunzone(do_cvar);
  34                 return;
  35         }
  36         if(do_exec)
  37                 localcmd(data);
  38         if(do_cvar)
  39         {
  40                 cvar_set(do_cvar, data);
  41                 strunzone(do_cvar);
  42         }
  43         if(!do_exec && !do_cvar)
  44                 print(data);
  45 }
  46
  47
  48 // =======================
  49 //  Command Sub-Functions
  50 // =======================
  51
  52 void GenericCommand_addtolist(float request, float argc)
  53 {
  54         switch(request)
  55         {
  56                 case CMD_REQUEST_COMMAND:
  57                 {
  58                         float i;
  59
  60                         if(argc >= 2)
  61                         {
  62                                 string original_cvar = argv(1);
  63                                 string tmp_string = argv(2);
  64
  65                                 if(cvar_string(original_cvar) == "") // cvar was empty
  66                                 {
  67                                         cvar_set(original_cvar, tmp_string);
  68                                 }
  69                                 else // add it to the end of the list if the list doesn't already have it
  70                                 {
  71                                         argc = tokenizebyseparator(cvar_string(original_cvar), " ");
  72
  73                                         for(i = 0; i < argc; ++i)
  74                                                 if(argv(i) == tmp_string)
  75                                                         return; // already in list
  76
  77                                         cvar_set(original_cvar, strcat(tmp_string, " ", cvar_string(original_cvar)));
  78                                 }
  79                                 return;
  80                         }
  81                 }
  82
  83                 default:
  84                         print("Incorrect parameters for ^2addtolist^7\n");
  85                 case CMD_REQUEST_USAGE:
  86                 {
  87                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " addtolist variable value\n"));
  88                         print("  Where 'variable' is what to add 'value' to.\n");
  89                         print("See also: ^2removefromlist^7\n");
  90                         return;
  91                 }
  92         }
  93 }
  94
  95 void GenericCommand_curl(float request, float argc)
  96 {
  97         switch(request)
  98         {
  99                 case CMD_REQUEST_COMMAND:
 100                 {
 101                         float do_exec;
 102                         string do_cvar;
 103                         float key;
 104                         float i, j;
 105                         string url;
 106                         float buf;
 107                         float r;
 108
 109                         do_exec = FALSE;
 110                         do_cvar = string_null;
 111                         key = -1;
 112
 113                         for(i = 1; i+1 < argc; ++i)
 114                         {
 115                                 if(argv(i) == "--cvar" && i+2 < argc)
 116                                 {
 117                                         ++i;
 118                                         do_cvar = strzone(argv(i));
 119                                         continue;
 120                                 }
 121                                 if(argv(i) == "--exec")
 122                                 {
 123                                         do_exec = TRUE;
 124                                         continue;
 125                                 }
 126                                 if(argv(i) == "--key" && i+2 < argc)
 127                                 {
 128                                         ++i;
 129                                         key = stof(argv(i));
 130                                         continue;
 131                                 }
 132                                 break;
 133                         }
 134
 135                         // now, argv(i) is the URL
 136                         // following args may be POST parameters
 137                         url = argv(i);
 138                         ++i;
 139                         buf = buf_create();
 140                         j = 0;
 141                         for(; i+1 < argc; i += 2)
 142                                 bufstr_set(buf, ++j, sprintf("%s=%s", uri_escape(argv(i)), uri_escape(argv(i+1))));
 143                         if(i < argc)
 144                                 bufstr_set(buf, ++j, sprintf("submit=%s", uri_escape(argv(i))));
 145
 146                         if(j == 0) // no args: GET
 147                                 r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, string_null, string_null, -1, key);
 148                         else // with args: POST
 149                                 r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, "application/x-www-form-urlencoded", "&", buf, key);
 150
 151                         if(r)
 152                         {
 153                                 curl_uri_get_exec[curl_uri_get_pos] = do_exec;
 154                                 curl_uri_get_cvar[curl_uri_get_pos] = do_cvar;
 155                                 curl_uri_get_pos = mod(curl_uri_get_pos + 1, URI_GET_CURL_END - URI_GET_CURL + 1);
 156                         }
 157                         else
 158                                 print(_("error creating curl handle\n"));
 159
 160                         buf_del(buf);
 161
 162                         return;
 163                 }
 164
 165                 default:
 166                 case CMD_REQUEST_USAGE:
 167                 {
 168                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " curl [--key N] [--cvar] [--exec] URL [postargs...]"));
 169                         return;
 170                 }
 171         }
 172 }
 173
 174 void GenericCommand_dumpcommands(float request)
 175 {
 176         switch(request)
 177         {
 178                 case CMD_REQUEST_COMMAND:
 179                 {
 180                         float fh;
 181                         string filename = strcat(GetProgramCommandPrefix(), "_dump.txt");
 182                         fh = fopen(filename, FILE_WRITE);
 183
 184                         if(fh >= 0)
 185                         {
 186                                 #ifdef SVQC
 187                                         CMD_Write("dump of server console commands:\n");
 188                                         GameCommand_macro_write_aliases(fh);
 189
 190                                         CMD_Write("\ndump of networked client only commands:\n");
 191                                         ClientCommand_macro_write_aliases(fh);
 192
 193                                         CMD_Write("\ndump of common commands:\n");
 194                                         CommonCommand_macro_write_aliases(fh);
 195
 196                                         CMD_Write("\ndump of ban commands:\n");
 197                                         BanCommand_macro_write_aliases(fh);
 198                                 #endif
 199
 200                                 #ifdef CSQC
 201                                         CMD_Write("dump of client commands:\n");
 202                                         LocalCommand_macro_write_aliases(fh);
 203                                 #endif
 204
 205                                 CMD_Write("\ndump of generic commands:\n");
 206                                 GenericCommand_macro_write_aliases(fh);
 207
 208                                 print("Completed dump of aliases in ^2data/data/", GetProgramCommandPrefix(), "_dump.txt^7.\n");
 209
 210                                 fclose(fh);
 211                         }
 212                         else
 213                         {
 214                                 print("^1Error: ^7Could not dump to file!\n");
 215                         }
 216                         return;
 217                 }
 218
 219                 default:
 220                 case CMD_REQUEST_USAGE:
 221                 {
 222                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpcommands"));
 223                         print("  No arguments required.\n");
 224                         return;
 225                 }
 226         }
 227 }
 228
 229 void GenericCommand_maplist(float request, float argc)
 230 {
 231         switch(request)
 232         {
 233                 case CMD_REQUEST_COMMAND:
 234                 {
 235                         string tmp_string;
 236                         float i;
 237
 238                         switch(argv(1))
 239                         {
 240                                 case "add": // appends new maps to the maplist
 241                                 {
 242                                         if(argc == 3)
 243                                         {
 244                                                 if (!fexists(strcat("maps/", argv(2), ".bsp")))
 245                                                 {
 246                                                         print("maplist: ERROR: ", argv(2), " does not exist!\n");
 247                                                         break;
 248                                                 }
 249
 250                                                 if(cvar_string("g_maplist") == "")
 251                                                         cvar_set("g_maplist", argv(2));
 252                                                 else
 253                                                         cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
 254
 255                                                 return;
 256                                         }
 257                                         break; // go to usage
 258                                 }
 259
 260                                 case "cleanup": // scans maplist and only adds back the ones which are really usable
 261                                 {
 262                                         MapInfo_Enumerate();
 263                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 264                                         argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
 265
 266                                         tmp_string = "";
 267                                         for(i = 0; i < argc; ++i)
 268                                                 if(MapInfo_CheckMap(argv(i)))
 269                                                         tmp_string = strcat(tmp_string, " ", argv(i));
 270
 271                                         tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 272                                         cvar_set("g_maplist", tmp_string);
 273
 274                                         return;
 275                                 }
 276
 277                                 case "remove": // scans maplist and only adds back whatever maps were not provided in argv(2)
 278                                 {
 279                                         if(argc == 3)
 280                                         {
 281                                                 argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
 282
 283                                                 tmp_string = "";
 284                                                 for(i = 0; i < argc; ++i)
 285                                                         if(argv(i) != argv(2))
 286                                                                 tmp_string = strcat(tmp_string, " ", argv(i));
 287
 288                                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 289                                                 cvar_set("g_maplist", tmp_string);
 290
 291                                                 return;
 292                                         }
 293                                         break; // go to usage
 294                                 }
 295
 296                                 case "shuffle": // randomly shuffle the maplist
 297                                 {
 298                                         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
 299                                         return;
 300                                 }
 301
 302                                 default: break;
 303                         }
 304                 }
 305
 306                 default:
 307                         print("Incorrect parameters for ^2maplist^7\n");
 308                 case CMD_REQUEST_USAGE:
 309                 {
 310                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " maplist action [map]\n"));
 311                         print("  Where 'action' is the command to complete,\n");
 312                         print("  and 'map' is what it acts upon (if required).\n");
 313                         print("  Full list of commands here: \"add, cleanup, remove, shuffle.\"\n");
 314                         return;
 315                 }
 316         }
 317 }
 318
 319 void GenericCommand_nextframe(float request, float arguments, string command)
 320 {
 321         switch(request)
 322         {
 323                 case CMD_REQUEST_COMMAND:
 324                 {
 325                         queue_to_execute_next_frame(substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 326                         return;
 327                 }
 328
 329                 default:
 330                 case CMD_REQUEST_USAGE:
 331                 {
 332                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " nextframe command...\n"));
 333                         print("  Where command will be executed next frame of this VM\n");
 334                         return;
 335                 }
 336         }
 337 }
 338
 339 void GenericCommand_removefromlist(float request, float argc)
 340 {
 341         switch(request)
 342         {
 343                 case CMD_REQUEST_COMMAND:
 344                 {
 345                         if(argc == 3)
 346                         {
 347                                 float i;
 348                                 string original_cvar = argv(1);
 349                                 string removal = argv(2);
 350                                 string tmp_string;
 351
 352                                 argc = tokenizebyseparator(cvar_string(original_cvar), " ");
 353
 354                                 tmp_string = "";
 355                                 for(i = 0; i < argc; ++i)
 356                                         if(argv(i) != removal)
 357                                                 tmp_string = strcat(tmp_string, " ", argv(i));
 358
 359                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 360                                 cvar_set(original_cvar, tmp_string);
 361
 362                                 return;
 363                         }
 364                 }
 365
 366                 default:
 367                         print("Incorrect parameters for ^2removefromlist^7\n");
 368                 case CMD_REQUEST_USAGE:
 369                 {
 370                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " removefromlist variable value\n"));
 371                         print("  Where 'variable' is what cvar to remove 'value' from.\n");
 372                         print("See also: ^2addtolist^7\n");
 373                         return;
 374                 }
 375         }
 376 }
 377
 378 void GenericCommand_settemp(float request, float argc)
 379 {
 380         switch(request)
 381         {
 382                 case CMD_REQUEST_COMMAND:
 383                 {
 384                         if(argc >= 3)
 385                         {
 386                                 float f = cvar_settemp(argv(1), argv(2));
 387                                 if(f == 1)
 388                                         dprint("Creating new settemp tracker for ", argv(1), " and setting it to \"", argv(2), "\" temporarily.\n");
 389                                 else if(f == -1)
 390                                         dprint("Already had a tracker for ", argv(1), ", updating it to \"", argv(2), "\".\n");
 391                                 // else cvar_settemp itself errors out
 392
 393                                 return;
 394                         }
 395                 }
 396
 397                 default:
 398                         print("Incorrect parameters for ^2settemp^7\n");
 399                 case CMD_REQUEST_USAGE:
 400                 {
 401                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp \"cvar\" \"arguments\"\n"));
 402                         print("  Where 'cvar' is the cvar you want to temporarily set with 'arguments'.\n");
 403                         print("See also: ^2settemp_restore^7\n");
 404                         return;
 405                 }
 406         }
 407 }
 408
 409 void GenericCommand_settemp_restore(float request, float argc)
 410 {
 411         switch(request)
 412         {
 413                 case CMD_REQUEST_COMMAND:
 414                 {
 415                         float i = cvar_settemp_restore();
 416
 417                         if(i)
 418                                 dprint("Restored ", ftos(i), " temporary cvar settings to their original values.\n");
 419                         else
 420                                 dprint("Nothing to restore.\n");
 421
 422                         return;
 423                 }
 424
 425                 default:
 426                 case CMD_REQUEST_USAGE:
 427                 {
 428                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp_restore\n"));
 429                         print("  No arguments required.\n");
 430                         print("See also: ^2settemp^7\n");
 431                         return;
 432                 }
 433         }
 434 }
 435
 436 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 437 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 438 void GenericCommand_(float request)
 439 {
 440         switch(request)
 441         {
 442                 case CMD_REQUEST_COMMAND:
 443                 {
 444
 445                         return;
 446                 }
 447
 448                 default:
 449                 case CMD_REQUEST_USAGE:
 450                 {
 451                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " "));
 452                         print("  No arguments required.\n");
 453                         return;
 454                 }
 455         }
 456 }
 457 */
 458
 459 // ==================================
 460 //  Macro system for server commands
 461 // ==================================
 462
 463 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 464 #define GENERIC_COMMANDS(request,arguments,command) \
 465         GENERIC_COMMAND("addtolist", GenericCommand_addtolist(request, arguments), "Add a string to a cvar") \
 466         GENERIC_COMMAND("curl", GenericCommand_curl(request, arguments), "Queries an URL") \
 467         GENERIC_COMMAND("dumpcommands", GenericCommand_dumpcommands(request), "Dump all commands on the program to *_cmd_dump.txt") \
 468         GENERIC_COMMAND("maplist", GenericCommand_maplist(request, arguments), "Automatic control of maplist") \
 469         GENERIC_COMMAND("nextframe", GenericCommand_nextframe(request, arguments, command), "Execute the given command next frame of this VM") \
 470         GENERIC_COMMAND("removefromlist", GenericCommand_removefromlist(request, arguments), "Remove a string from a cvar") \
 471         GENERIC_COMMAND("rpn", GenericCommand_rpn(request, arguments, command), "RPN calculator") \
 472         GENERIC_COMMAND("settemp", GenericCommand_settemp(request, arguments), "Temporarily set a value to a cvar which is restored later") \
 473         GENERIC_COMMAND("settemp_restore", GenericCommand_settemp_restore(request, arguments), "Restore all cvars set by settemp command") \
 474         /* nothing */
 475
 476 void GenericCommand_macro_help()
 477 {
 478         #define GENERIC_COMMAND(name,function,description) \
 479                 { print("  ^2", name, "^7: ", description, "\n"); }
 480
 481         GENERIC_COMMANDS(0, 0, "")
 482         #undef GENERIC_COMMAND
 483
 484         return;
 485 }
 486
 487 float GenericCommand_macro_command(float argc, string command)
 488 {
 489         #define GENERIC_COMMAND(name,function,description) \
 490                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 491
 492         GENERIC_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 493         #undef GENERIC_COMMAND
 494
 495         return FALSE;
 496 }
 497
 498 float GenericCommand_macro_usage(float argc)
 499 {
 500         #define GENERIC_COMMAND(name,function,description) \
 501                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 502
 503         GENERIC_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 504         #undef GENERIC_COMMAND
 505
 506         return FALSE;
 507 }
 508
 509 void GenericCommand_macro_write_aliases(float fh)
 510 {
 511         #define GENERIC_COMMAND(name,function,description) \
 512                 { CMD_Write_Alias("qc_cmd_svmenu", name, description); }
 513
 514         GENERIC_COMMANDS(0, 0, "")
 515         #undef GENERIC_COMMAND
 516
 517         return;
 518 }
 519
 520
 521 // ===========================================
 522 //  Main Common Function For Generic Commands
 523 // ===========================================
 524 // Commands spread out among all programs (menu, client, and server)
 525
 526 float GenericCommand(string command)
 527 {
 528         float argc = tokenize_console(command);
 529         float n, j, f, i;
 530         string s, s2, c;
 531         vector rgb;
 532
 533         // Guide for working with argc arguments by example:
 534         // argc:   1    - 2      - 3     - 4
 535         // argv:   0    - 1      - 2     - 3
 536         // cmd     vote - master - login - password
 537
 538         if(GenericCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 539         {
 540                 return TRUE; // handled by one of the above GenericCommand_* functions
 541         }
 542         else if(argc >= 3 && argv(0) == "red")
 543         {
 544                 s = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 545                 localcmd(strcat(argv(1), " ", GenericCommand_markup(s)));
 546                 return TRUE;
 547         }
 548         else if(argc >= 3 && crc16(0, argv(0)) == 38566 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 59830)
 549         {
 550                 // other test case
 551                 s = strconv(2, 0, 0, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 552
 553                 n = floor(random() * 6 + 2);
 554
 555                 s2 = "";
 556                 for(i = 0; i < n; ++i)
 557                 {
 558                         s2 = strcat(s2, "AH");
 559                 }
 560
 561                 if(random() < 0.1)
 562                         s2 = strcat(substring(s2, 1, strlen(s2) - 1), "A");
 563
 564                 if(s == "")
 565                         s = s2;
 566                 else
 567                         if(random() < 0.8)
 568                                 s = strcat(s, " ", s2);
 569                         else
 570                                 s = strcat(s2, " ", s);
 571
 572                 s2 = substring(s, strlen(s) - 2, 2);
 573                 if(s2 == "AH" || s2 == "AY")
 574                         s = strcat(s, "))");
 575                 else
 576                         s = strcat(s, " ))");
 577
 578                 if(random() < 0.1)
 579                         s = substring(s, 0, strlen(s) - 1);
 580
 581                 if(random() < 0.1)
 582                         s = strconv(1, 0, 0, s);
 583
 584                 localcmd(strcat(argv(1), " ", s));
 585
 586                 return TRUE;
 587         }
 588         else if(argc >= 3 && crc16(0, argv(0)) == 3826 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 55790)
 589         {
 590                 // test case for terencehill's color codes
 591                 s = strdecolorize(substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 592                 s2 = "";
 593
 594                 n = strlen(s);
 595                 j = ((6 * max(1, floor(strlen(s)/32 + random() * 2 - 1))) / n) * (1 - 2 * (random() > 0.5));
 596                 f = random() * 6;
 597
 598                 for(i = 0; i < n; ++i)
 599                 {
 600                         c = substring(s, i, 1);
 601
 602                         if(c == ";")
 603                                 c = ":";
 604                         else if(c == "^")
 605                         {
 606                                 c = "^^";
 607                                 if(substring(s, i+1, 1) == "^")
 608                                         ++i;
 609                         }
 610
 611                         if(c != " ")
 612                         {
 613                                 rgb = hsl_to_rgb('1 0 0' * (j * i + f) + '0 1 .5');
 614                                 c = strcat(rgb_to_hexcolor(rgb), c);
 615                         }
 616                         s2 = strcat(s2, c);
 617                 }
 618
 619                 localcmd(strcat(argv(1), " ", s2));
 620
 621                 return TRUE;
 622         }
 623
 624         return FALSE;
 625 }