qcsrc/common/command/generic.qc

   1 // =========================================================
   2 //  Generic program common command code, written by Samual
   3 //  Last updated: February 19th, 2012
   4 // =========================================================
   5
   6 // used by generic commands for better help/usage information
   7 string GetProgramCommandPrefix(void)
   8 {
   9         #ifdef SVQC
  10         return "sv_cmd";
  11         #endif
  12         #ifdef CSQC
  13         return "cl_cmd";
  14         #endif
  15         #ifdef MENUQC
  16         return "menu_cmd";
  17         #endif
  18 }
  19
  20 // used by curl command
  21 void Curl_URI_Get_Callback(float id, float status, string data)
  22 {
  23         float i;
  24         float do_exec;
  25         string do_cvar;
  26         i = id - URI_GET_CURL;
  27         do_exec = curl_uri_get_exec[i];
  28         do_cvar = curl_uri_get_cvar[i];
  29         if(status != 0)
  30         {
  31                 printf(_("error: status is %d\n"), status);
  32                 if(do_cvar)
  33                         strunzone(do_cvar);
  34                 return;
  35         }
  36         if(do_exec)
  37                 localcmd(data);
  38         if(do_cvar)
  39         {
  40                 cvar_set(do_cvar, data);
  41                 strunzone(do_cvar);
  42         }
  43         if(!do_exec)
  44                 if (!do_cvar)
  45                         print(data);
  46 }
  47
  48
  49 // =======================
  50 //  Command Sub-Functions
  51 // =======================
  52
  53 void GenericCommand_addtolist(float request, float argc)
  54 {
  55         switch(request)
  56         {
  57                 case CMD_REQUEST_COMMAND:
  58                 {
  59                         float i;
  60
  61                         if(argc >= 2)
  62                         {
  63                                 string original_cvar = argv(1);
  64                                 string tmp_string = argv(2);
  65
  66                                 if(cvar_string(original_cvar) == "") // cvar was empty
  67                                 {
  68                                         cvar_set(original_cvar, tmp_string);
  69                                 }
  70                                 else // add it to the end of the list if the list doesn't already have it
  71                                 {
  72                                         argc = tokenizebyseparator(cvar_string(original_cvar), " ");
  73
  74                                         for(i = 0; i < argc; ++i)
  75                                                 if(argv(i) == tmp_string)
  76                                                         return; // already in list
  77
  78                                         cvar_set(original_cvar, strcat(tmp_string, " ", cvar_string(original_cvar)));
  79                                 }
  80                                 return;
  81                         }
  82                 }
  83
  84                 default:
  85                         print("Incorrect parameters for ^2addtolist^7\n");
  86                 case CMD_REQUEST_USAGE:
  87                 {
  88                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " addtolist variable value\n"));
  89                         print("  Where 'variable' is what to add 'value' to.\n");
  90                         print("See also: ^2removefromlist^7\n");
  91                         return;
  92                 }
  93         }
  94 }
  95
  96 void GenericCommand_qc_curl(float request, float argc)
  97 {
  98         switch(request)
  99         {
 100                 case CMD_REQUEST_COMMAND:
 101                 {
 102                         float do_exec;
 103                         string do_cvar;
 104                         float key;
 105                         float i, j;
 106                         string url;
 107                         float buf;
 108                         float r;
 109
 110                         do_exec = FALSE;
 111                         do_cvar = string_null;
 112                         key = -1;
 113
 114                         for(i = 1; i+1 < argc; ++i)
 115                         {
 116                                 if(argv(i) == "--cvar" && i+2 < argc)
 117                                 {
 118                                         ++i;
 119                                         do_cvar = strzone(argv(i));
 120                                         continue;
 121                                 }
 122                                 if(argv(i) == "--exec")
 123                                 {
 124                                         do_exec = TRUE;
 125                                         continue;
 126                                 }
 127                                 if(argv(i) == "--key" && i+2 < argc)
 128                                 {
 129                                         ++i;
 130                                         key = stof(argv(i));
 131                                         continue;
 132                                 }
 133                                 break;
 134                         }
 135
 136                         // now, argv(i) is the URL
 137                         // following args may be POST parameters
 138                         url = argv(i);
 139                         ++i;
 140                         buf = buf_create();
 141                         j = 0;
 142                         for(; i+1 < argc; i += 2)
 143                                 bufstr_set(buf, ++j, sprintf("%s=%s", uri_escape(argv(i)), uri_escape(argv(i+1))));
 144                         if(i < argc)
 145                                 bufstr_set(buf, ++j, sprintf("submit=%s", uri_escape(argv(i))));
 146
 147                         if(j == 0) // no args: GET
 148                                 r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, string_null, string_null, -1, key);
 149                         else // with args: POST
 150                                 r = crypto_uri_postbuf(url, URI_GET_CURL + curl_uri_get_pos, "application/x-www-form-urlencoded", "&", buf, key);
 151
 152                         if(r)
 153                         {
 154                                 curl_uri_get_exec[curl_uri_get_pos] = do_exec;
 155                                 curl_uri_get_cvar[curl_uri_get_pos] = do_cvar;
 156                                 curl_uri_get_pos = mod(curl_uri_get_pos + 1, URI_GET_CURL_END - URI_GET_CURL + 1);
 157                         }
 158                         else
 159                                 print(_("error creating curl handle\n"));
 160
 161                         buf_del(buf);
 162
 163                         return;
 164                 }
 165
 166                 default:
 167                 case CMD_REQUEST_USAGE:
 168                 {
 169                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " qc_curl [--key N] [--cvar] [--exec] URL [postargs...]"));
 170                         return;
 171                 }
 172         }
 173 }
 174
 175 void GenericCommand_dumpcommands(float request)
 176 {
 177         switch(request)
 178         {
 179                 case CMD_REQUEST_COMMAND:
 180                 {
 181                         float fh;
 182                         string filename = strcat(GetProgramCommandPrefix(), "_dump.txt");
 183                         fh = fopen(filename, FILE_WRITE);
 184
 185                         if(fh >= 0)
 186                         {
 187                                 #ifdef SVQC
 188                                         CMD_Write("dump of server console commands:\n");
 189                                         GameCommand_macro_write_aliases(fh);
 190
 191                                         CMD_Write("\ndump of networked client only commands:\n");
 192                                         ClientCommand_macro_write_aliases(fh);
 193
 194                                         CMD_Write("\ndump of common commands:\n");
 195                                         CommonCommand_macro_write_aliases(fh);
 196
 197                                         CMD_Write("\ndump of ban commands:\n");
 198                                         BanCommand_macro_write_aliases(fh);
 199                                 #endif
 200
 201                                 #ifdef CSQC
 202                                         CMD_Write("dump of client commands:\n");
 203                                         LocalCommand_macro_write_aliases(fh);
 204                                 #endif
 205
 206                                 CMD_Write("\ndump of generic commands:\n");
 207                                 GenericCommand_macro_write_aliases(fh);
 208
 209                                 print("Completed dump of aliases in ^2data/data/", GetProgramCommandPrefix(), "_dump.txt^7.\n");
 210
 211                                 fclose(fh);
 212                         }
 213                         else
 214                         {
 215                                 print("^1Error: ^7Could not dump to file!\n");
 216                         }
 217                         return;
 218                 }
 219
 220                 default:
 221                 case CMD_REQUEST_USAGE:
 222                 {
 223                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpcommands"));
 224                         print("  No arguments required.\n");
 225                         return;
 226                 }
 227         }
 228 }
 229
 230 void GenericCommand_dumpnotifs(float request)
 231 {
 232         switch(request)
 233         {
 234                 case CMD_REQUEST_COMMAND:
 235                 {
 236                         #ifndef MENUQC
 237                         float fh, alsoprint = FALSE;
 238                         string filename = argv(1);
 239
 240                         if(filename == "")
 241                         {
 242                                 filename = "notifications_dump.cfg";
 243                                 alsoprint = FALSE;
 244                         }
 245                         else if(filename == "-")
 246                         {
 247                                 filename = "notifications_dump.cfg";
 248                                 alsoprint = TRUE;
 249                         }
 250                         fh = fopen(filename, FILE_WRITE);
 251
 252                         if(fh >= 0)
 253                         {
 254                                 Dump_Notifications(fh, alsoprint);
 255                                 printf("Dumping notifications... File located in ^2data/data/%s^7.\n", filename);
 256                                 fclose(fh);
 257                         }
 258                         else
 259                         {
 260                                 printf("^1Error: ^7Could not open file '%s'!\n", filename);
 261                         }
 262                         #else
 263                         print(_("Notification dump command only works with cl_cmd and sv_cmd.\n"));
 264                         #endif
 265                         return;
 266                 }
 267
 268                 default:
 269                 case CMD_REQUEST_USAGE:
 270                 {
 271                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpnotifs [filename]"));
 272                         print("  Where 'filename' is the file to write (default is notifications_dump.cfg),\n");
 273                         print("  if supplied with '-' output to console as well as default,\n");
 274                         print("  if left blank, it will only write to default.\n");
 275                         return;
 276                 }
 277         }
 278 }
 279
 280 void GenericCommand_dumpweapons(float request) // WEAPONTODO: make this work with other progs than just server
 281 {
 282         switch(request)
 283         {
 284                 case CMD_REQUEST_COMMAND:
 285                 {
 286                         #ifdef SVQC
 287                         wep_config_file = -1;
 288                         wep_config_alsoprint = -1;
 289                         string filename = argv(1);
 290
 291                         if(filename == "")
 292                         {
 293                                 filename = "weapons_dump.cfg";
 294                                 wep_config_alsoprint = FALSE;
 295                         }
 296                         else if(filename == "-")
 297                         {
 298                                 filename = "weapons_dump.cfg";
 299                                 wep_config_alsoprint = TRUE;
 300                         }
 301                         wep_config_file = fopen(filename, FILE_WRITE);
 302
 303                         if(wep_config_file >= 0)
 304                         {
 305                                 Dump_Weapon_Settings();
 306                                 print(sprintf("Dumping weapons... File located in ^2data/data/%s^7.\n", filename));
 307                                 fclose(wep_config_file);
 308                                 wep_config_file = -1;
 309                                 wep_config_alsoprint = -1;
 310                         }
 311                         else
 312                         {
 313                                 print(sprintf("^1Error: ^7Could not open file '%s'!\n", filename));
 314                         }
 315                         #else
 316                         print(_("Weapons dump command only works with sv_cmd.\n"));
 317                         #endif
 318                         return;
 319                 }
 320
 321                 default:
 322                 case CMD_REQUEST_USAGE:
 323                 {
 324                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " dumpweapons [filename]"));
 325                         print("  Where 'filename' is the file to write (default is weapons_dump.cfg),\n");
 326                         print("  if supplied with '-' output to console as well as default,\n");
 327                         print("  if left blank, it will only write to default.\n");
 328                         return;
 329                 }
 330         }
 331 }
 332
 333 void GenericCommand_maplist(float request, float argc)
 334 {
 335         switch(request)
 336         {
 337                 case CMD_REQUEST_COMMAND:
 338                 {
 339                         string tmp_string;
 340                         float i;
 341
 342                         switch(argv(1))
 343                         {
 344                                 case "add": // appends new maps to the maplist
 345                                 {
 346                                         if(argc == 3)
 347                                         {
 348                                                 if (!fexists(strcat("maps/", argv(2), ".bsp")))
 349                                                 {
 350                                                         print("maplist: ERROR: ", argv(2), " does not exist!\n");
 351                                                         break;
 352                                                 }
 353
 354                                                 if(cvar_string("g_maplist") == "")
 355                                                         cvar_set("g_maplist", argv(2));
 356                                                 else
 357                                                         cvar_set("g_maplist", strcat(argv(2), " ", cvar_string("g_maplist")));
 358
 359                                                 return;
 360                                         }
 361                                         break; // go to usage
 362                                 }
 363
 364                                 case "cleanup": // scans maplist and only adds back the ones which are really usable
 365                                 {
 366                                         MapInfo_Enumerate();
 367                                         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 368                                         argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
 369
 370                                         tmp_string = "";
 371                                         for(i = 0; i < argc; ++i)
 372                                                 if(MapInfo_CheckMap(argv(i)))
 373                                                         tmp_string = strcat(tmp_string, " ", argv(i));
 374
 375                                         tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 376                                         cvar_set("g_maplist", tmp_string);
 377
 378                                         return;
 379                                 }
 380
 381                                 case "remove": // scans maplist and only adds back whatever maps were not provided in argv(2)
 382                                 {
 383                                         if(argc == 3)
 384                                         {
 385                                                 argc = tokenizebyseparator(cvar_string("g_maplist"), " ");
 386
 387                                                 tmp_string = "";
 388                                                 for(i = 0; i < argc; ++i)
 389                                                         if(argv(i) != argv(2))
 390                                                                 tmp_string = strcat(tmp_string, " ", argv(i));
 391
 392                                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 393                                                 cvar_set("g_maplist", tmp_string);
 394
 395                                                 return;
 396                                         }
 397                                         break; // go to usage
 398                                 }
 399
 400                                 case "shuffle": // randomly shuffle the maplist
 401                                 {
 402                                         cvar_set("g_maplist", shufflewords(cvar_string("g_maplist")));
 403                                         return;
 404                                 }
 405
 406                                 default: break;
 407                         }
 408                 }
 409
 410                 default:
 411                         print("Incorrect parameters for ^2maplist^7\n");
 412                 case CMD_REQUEST_USAGE:
 413                 {
 414                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " maplist action [map]\n"));
 415                         print("  Where 'action' is the command to complete,\n");
 416                         print("  and 'map' is what it acts upon (if required).\n");
 417                         print("  Full list of commands here: \"add, cleanup, remove, shuffle.\"\n");
 418                         return;
 419                 }
 420         }
 421 }
 422
 423 void GenericCommand_nextframe(float request, float arguments, string command)
 424 {
 425         switch(request)
 426         {
 427                 case CMD_REQUEST_COMMAND:
 428                 {
 429                         queue_to_execute_next_frame(substring(command, argv_start_index(1), argv_end_index(-1) - argv_start_index(1)));
 430                         return;
 431                 }
 432
 433                 default:
 434                 case CMD_REQUEST_USAGE:
 435                 {
 436                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " nextframe command...\n"));
 437                         print("  Where command will be executed next frame of this VM\n");
 438                         return;
 439                 }
 440         }
 441 }
 442
 443 void GenericCommand_removefromlist(float request, float argc)
 444 {
 445         switch(request)
 446         {
 447                 case CMD_REQUEST_COMMAND:
 448                 {
 449                         if(argc == 3)
 450                         {
 451                                 float i;
 452                                 string original_cvar = argv(1);
 453                                 string removal = argv(2);
 454                                 string tmp_string;
 455
 456                                 argc = tokenizebyseparator(cvar_string(original_cvar), " ");
 457
 458                                 tmp_string = "";
 459                                 for(i = 0; i < argc; ++i)
 460                                         if(argv(i) != removal)
 461                                                 tmp_string = strcat(tmp_string, " ", argv(i));
 462
 463                                 tmp_string = substring(tmp_string, 1, strlen(tmp_string) - 1);
 464                                 cvar_set(original_cvar, tmp_string);
 465
 466                                 return;
 467                         }
 468                 }
 469
 470                 default:
 471                         print("Incorrect parameters for ^2removefromlist^7\n");
 472                 case CMD_REQUEST_USAGE:
 473                 {
 474                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " removefromlist variable value\n"));
 475                         print("  Where 'variable' is what cvar to remove 'value' from.\n");
 476                         print("See also: ^2addtolist^7\n");
 477                         return;
 478                 }
 479         }
 480 }
 481
 482 void GenericCommand_restartnotifs(float request)
 483 {
 484         switch(request)
 485         {
 486                 case CMD_REQUEST_COMMAND:
 487                 {
 488                         #ifndef MENUQC
 489                         printf(
 490                                 strcat(
 491                                         "Restart_Notifications(): Restarting %d notifications... ",
 492                                         "Counts: MSG_ANNCE = %d, MSG_INFO = %d, MSG_CENTER = %d, MSG_MULTI = %d, MSG_CHOICE = %d\n"
 493                                 ),
 494                                 (
 495                                         NOTIF_ANNCE_COUNT +
 496                                         NOTIF_INFO_COUNT +
 497                                         NOTIF_CENTER_COUNT +
 498                                         NOTIF_MULTI_COUNT +
 499                                         NOTIF_CHOICE_COUNT
 500                                 ),
 501                                 NOTIF_ANNCE_COUNT,
 502                                 NOTIF_INFO_COUNT,
 503                                 NOTIF_CENTER_COUNT,
 504                                 NOTIF_MULTI_COUNT,
 505                                 NOTIF_CHOICE_COUNT
 506                         );
 507                         Destroy_All_Notifications();
 508                         CALL_ACCUMULATED_FUNCTION(RegisterNotifications);
 509                         #else
 510                         print(_("Notification restart command only works with cl_cmd and sv_cmd.\n"));
 511                         #endif
 512                         return;
 513                 }
 514
 515                 default:
 516                 case CMD_REQUEST_USAGE:
 517                 {
 518                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " restartnotifs"));
 519                         print("  No arguments required.\n");
 520                         return;
 521                 }
 522         }
 523 }
 524
 525 void GenericCommand_settemp(float request, float argc)
 526 {
 527         switch(request)
 528         {
 529                 case CMD_REQUEST_COMMAND:
 530                 {
 531                         if(argc >= 3)
 532                         {
 533                                 float f = cvar_settemp(argv(1), argv(2));
 534                                 if(f == 1)
 535                                         dprint("Creating new settemp tracker for ", argv(1), " and setting it to \"", argv(2), "\" temporarily.\n");
 536                                 else if(f == -1)
 537                                         dprint("Already had a tracker for ", argv(1), ", updating it to \"", argv(2), "\".\n");
 538                                 // else cvar_settemp itself errors out
 539
 540                                 return;
 541                         }
 542                 }
 543
 544                 default:
 545                         print("Incorrect parameters for ^2settemp^7\n");
 546                 case CMD_REQUEST_USAGE:
 547                 {
 548                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp \"cvar\" \"arguments\"\n"));
 549                         print("  Where 'cvar' is the cvar you want to temporarily set with 'arguments'.\n");
 550                         print("See also: ^2settemp_restore^7\n");
 551                         return;
 552                 }
 553         }
 554 }
 555
 556 void GenericCommand_settemp_restore(float request, float argc)
 557 {
 558         switch(request)
 559         {
 560                 case CMD_REQUEST_COMMAND:
 561                 {
 562                         float i = cvar_settemp_restore();
 563
 564                         if(i)
 565                                 dprint("Restored ", ftos(i), " temporary cvar settings to their original values.\n");
 566                         else
 567                                 dprint("Nothing to restore.\n");
 568
 569                         return;
 570                 }
 571
 572                 default:
 573                 case CMD_REQUEST_USAGE:
 574                 {
 575                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " settemp_restore\n"));
 576                         print("  No arguments required.\n");
 577                         print("See also: ^2settemp^7\n");
 578                         return;
 579                 }
 580         }
 581 }
 582
 583 void GenericCommand_runtest(float request, float argc)
 584 {
 585         switch(request)
 586         {
 587                 case CMD_REQUEST_COMMAND:
 588                 {
 589                         if(argc > 1)
 590                         {
 591                                 float i;
 592                                 for(i = 1; i < argc; ++i)
 593                                         TEST_Run(argv(i));
 594                         }
 595                         else
 596                                 TEST_RunAll();
 597                         return;
 598                 }
 599
 600                 default:
 601                 case CMD_REQUEST_USAGE:
 602                 {
 603                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " [function to run]"));
 604                         return;
 605                 }
 606         }
 607 }
 608
 609 /* use this when creating a new command, making sure to place it in alphabetical order... also,
 610 ** ADD ALL NEW COMMANDS TO commands.cfg WITH PROPER ALIASES IN THE SAME FASHION!
 611 void GenericCommand_(float request)
 612 {
 613         switch(request)
 614         {
 615                 case CMD_REQUEST_COMMAND:
 616                 {
 617
 618                         return;
 619                 }
 620
 621                 default:
 622                 case CMD_REQUEST_USAGE:
 623                 {
 624                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " "));
 625                         print("  No arguments required.\n");
 626                         return;
 627                 }
 628         }
 629 }
 630 */
 631
 632 // ==================================
 633 //  Macro system for server commands
 634 // ==================================
 635
 636 // Do not hard code aliases for these, instead create them in commands.cfg... also: keep in alphabetical order, please ;)
 637 #define GENERIC_COMMANDS(request,arguments,command) \
 638         GENERIC_COMMAND("addtolist", GenericCommand_addtolist(request, arguments), "Add a string to a cvar") \
 639         GENERIC_COMMAND("dumpcommands", GenericCommand_dumpcommands(request), "Dump all commands on the program to *_cmd_dump.txt") \
 640         GENERIC_COMMAND("dumpnotifs", GenericCommand_dumpnotifs(request), "Dump all notifications into notifications_dump.txt") \
 641         GENERIC_COMMAND("dumpweapons", GenericCommand_dumpweapons(request), "Dump all weapons into weapons_dump.txt") \
 642         GENERIC_COMMAND("maplist", GenericCommand_maplist(request, arguments), "Automatic control of maplist") \
 643         GENERIC_COMMAND("nextframe", GenericCommand_nextframe(request, arguments, command), "Execute the given command next frame of this VM") \
 644         GENERIC_COMMAND("qc_curl", GenericCommand_qc_curl(request, arguments), "Queries a URL") \
 645         GENERIC_COMMAND("removefromlist", GenericCommand_removefromlist(request, arguments), "Remove a string from a cvar") \
 646         GENERIC_COMMAND("restartnotifs", GenericCommand_restartnotifs(request), "Re-initialize all notifications") \
 647         GENERIC_COMMAND("rpn", GenericCommand_rpn(request, arguments, command), "RPN calculator") \
 648         GENERIC_COMMAND("settemp", GenericCommand_settemp(request, arguments), "Temporarily set a value to a cvar which is restored later") \
 649         GENERIC_COMMAND("settemp_restore", GenericCommand_settemp_restore(request, arguments), "Restore all cvars set by settemp command") \
 650         GENERIC_COMMAND("runtest", GenericCommand_runtest(request, arguments), "Run unit tests") \
 651         /* nothing */
 652
 653 void GenericCommand_macro_help()
 654 {
 655         #define GENERIC_COMMAND(name,function,description) \
 656                 { print("  ^2", name, "^7: ", description, "\n"); }
 657
 658         GENERIC_COMMANDS(0, 0, "")
 659         #undef GENERIC_COMMAND
 660
 661         return;
 662 }
 663
 664 float GenericCommand_macro_command(float argc, string command)
 665 {
 666         #define GENERIC_COMMAND(name,function,description) \
 667                 { if(name == strtolower(argv(0))) { function; return TRUE; } }
 668
 669         GENERIC_COMMANDS(CMD_REQUEST_COMMAND, argc, command)
 670         #undef GENERIC_COMMAND
 671
 672         return FALSE;
 673 }
 674
 675 float GenericCommand_macro_usage(float argc)
 676 {
 677         #define GENERIC_COMMAND(name,function,description) \
 678                 { if(name == strtolower(argv(1))) { function; return TRUE; } }
 679
 680         GENERIC_COMMANDS(CMD_REQUEST_USAGE, argc, "")
 681         #undef GENERIC_COMMAND
 682
 683         return FALSE;
 684 }
 685
 686 void GenericCommand_macro_write_aliases(float fh)
 687 {
 688         #define GENERIC_COMMAND(name,function,description) \
 689                 { CMD_Write_Alias("qc_cmd_svmenu", name, description); }
 690
 691         GENERIC_COMMANDS(0, 0, "")
 692         #undef GENERIC_COMMAND
 693
 694         return;
 695 }
 696
 697
 698 // ===========================================
 699 //  Main Common Function For Generic Commands
 700 // ===========================================
 701 // Commands spread out among all programs (menu, client, and server)
 702
 703 float GenericCommand(string command)
 704 {
 705         float argc = tokenize_console(command);
 706         float n, j, f, i;
 707         string s, s2, c;
 708         vector rgb;
 709
 710         // Guide for working with argc arguments by example:
 711         // argc:   1    - 2      - 3     - 4
 712         // argv:   0    - 1      - 2     - 3
 713         // cmd     vote - master - login - password
 714
 715         if(GenericCommand_macro_command(argc, command)) // continue as usual and scan for normal commands
 716         {
 717                 return TRUE; // handled by one of the above GenericCommand_* functions
 718         }
 719         else if(argc >= 3 && argv(0) == "red")
 720         {
 721                 s = substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2));
 722                 localcmd(strcat(argv(1), " ", GenericCommand_markup(s)));
 723                 return TRUE;
 724         }
 725         else if(argc >= 3 && crc16(0, argv(0)) == 38566 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 59830)
 726         {
 727                 // other test case
 728                 s = strconv(2, 0, 0, substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 729
 730                 n = floor(random() * 6 + 2);
 731
 732                 s2 = "";
 733                 for(i = 0; i < n; ++i)
 734                 {
 735                         s2 = strcat(s2, "AH");
 736                 }
 737
 738                 if(random() < 0.1)
 739                         s2 = strcat(substring(s2, 1, strlen(s2) - 1), "A");
 740
 741                 if(s == "")
 742                         s = s2;
 743                 else
 744                         if(random() < 0.8)
 745                                 s = strcat(s, " ", s2);
 746                         else
 747                                 s = strcat(s2, " ", s);
 748
 749                 s2 = substring(s, strlen(s) - 2, 2);
 750                 if(s2 == "AH" || s2 == "AY")
 751                         s = strcat(s, "))");
 752                 else
 753                         s = strcat(s, " ))");
 754
 755                 if(random() < 0.1)
 756                         s = substring(s, 0, strlen(s) - 1);
 757
 758                 if(random() < 0.1)
 759                         s = strconv(1, 0, 0, s);
 760
 761                 localcmd(strcat(argv(1), " ", s));
 762
 763                 return TRUE;
 764         }
 765         else if(argc >= 3 && crc16(0, argv(0)) == 3826 && crc16(0, strcat(argv(0), argv(0), argv(0))) == 55790)
 766         {
 767                 // test case for terencehill's color codes
 768                 s = strdecolorize(substring(command, argv_start_index(2), argv_end_index(-1) - argv_start_index(2)));
 769                 s2 = "";
 770
 771                 n = strlen(s);
 772                 j = ((6 * max(1, floor(strlen(s)/32 + random() * 2 - 1))) / n) * (1 - 2 * (random() > 0.5));
 773                 f = random() * 6;
 774
 775                 for(i = 0; i < n; ++i)
 776                 {
 777                         c = substring(s, i, 1);
 778
 779                         if(c == ";")
 780                                 c = ":";
 781                         else if(c == "^")
 782                         {
 783                                 c = "^^";
 784                                 if(substring(s, i+1, 1) == "^")
 785                                         ++i;
 786                         }
 787
 788                         if(c != " ")
 789                         {
 790                                 rgb = hsl_to_rgb('1 0 0' * (j * i + f) + '0 1 .5');
 791                                 c = strcat(rgb_to_hexcolor(rgb), c);
 792                         }
 793                         s2 = strcat(s2, c);
 794                 }
 795
 796                 localcmd(strcat(argv(1), " ", s2));
 797
 798                 return TRUE;
 799         }
 800
 801         return FALSE;
 802 }