qcsrc/common/command/rpn.qc

   1 // ========================================
   2 //  RPN command code, written by divVerent
   3 //  Last updated: December 28th, 2011
   4 // ========================================
   5
   6 string rpn_pop()
   7 {
   8         if(rpn_sp > 0) {
   9                 --rpn_sp;
  10                 return rpn_stack[rpn_sp];
  11         } else {
  12                 print("rpn: stack underflow\n");
  13                 rpn_error = TRUE;
  14                 return "";
  15         }
  16 }
  17 void rpn_push(string s)
  18 {
  19         if(rpn_sp < MAX_RPN_STACK) {
  20                 rpn_stack[rpn_sp] = s;
  21                 ++rpn_sp;
  22         } else {
  23                 print("rpn: stack overflow\n");
  24                 rpn_error = TRUE;
  25         }
  26 }
  27 string rpn_get()
  28 {
  29         if(rpn_sp > 0) {
  30                 return rpn_stack[rpn_sp - 1];
  31         } else {
  32                 print("rpn: empty stack\n");
  33                 rpn_error = TRUE;
  34                 return "";
  35         }
  36 }
  37 void rpn_set(string s)
  38 {
  39         if(rpn_sp > 0) {
  40                 rpn_stack[rpn_sp - 1] = s;
  41         } else {
  42                 print("rpn: empty stack\n");
  43                 rpn_error = TRUE;
  44         }
  45 }
  46
  47 float rpn_getf() { return stof(rpn_get()); }
  48 float rpn_popf() { return stof(rpn_pop()); }
  49 void rpn_pushf(float f) { return rpn_push(sprintf("%.9g", f)); }
  50 void rpn_setf(float f) { return rpn_set(sprintf("%.9g", f)); }
  51
  52 void GenericCommand_rpn(float request, float argc, string command)
  53 {
  54         switch(request)
  55         {
  56                 case CMD_REQUEST_COMMAND:
  57                 {
  58                         float i, j, f, f2, f3, rpnpos;
  59                         //vector rgb;
  60                         string s, s2, rpncmd;
  61
  62                         if(!rpn_db)
  63                         {
  64                                 rpn_db = db_create();
  65                                 db_put(rpn_db, "stack.pointer", "0");
  66                                 db_put(rpn_db, "stack.pos", "-1");
  67                         }
  68
  69                         if(argc >= 2)
  70                         {
  71                                 rpn_sp = 0;
  72                                 rpn_error = FALSE;
  73                                 for(rpnpos = 1; rpnpos < argc; ++rpnpos)
  74                                 {
  75                                         rpncmd = argv(rpnpos);
  76                                         f = strlen(rpncmd);
  77                                         if(rpncmd == "") {
  78                                         } else if(stof(substring(rpncmd, 0, 1)) > 0) {
  79                                                 rpn_push(rpncmd);
  80                                         } else if(substring(rpncmd, 0, 1) == "0") {
  81                                                 rpn_push(rpncmd);
  82                                         } else if(f >= 2 && substring(rpncmd, 0, 1) == "+") {
  83                                                 rpn_push(rpncmd);
  84                                         } else if(f >= 2 && substring(rpncmd, 0, 1) == "-") {
  85                                                 rpn_push(rpncmd);
  86                                         } else if(f >= 2 && substring(rpncmd, 0, 1) == "/") {
  87                                                 rpn_push(substring(rpncmd, 1, strlen(rpncmd) - 1));
  88                                         } else if(rpncmd == "clear") {
  89                                                 rpn_sp = 0;
  90                                         } else if(rpncmd == "def" || rpncmd == "=") {
  91                                                 s = rpn_pop();
  92                                                 s2 = rpn_pop();
  93
  94                                                 if(s2 != "")
  95                                                 {
  96                                                         #ifdef MENUQC
  97                                                         registercvar(s2, "", 0);
  98                                                         #else
  99                                                         registercvar(s2, "");
 100                                                         #endif
 101                                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 102                                                                 cvar_set(s2, s);
 103                                                 }
 104                                                 else
 105                                                 {
 106                                                         print("rpn: empty cvar name for 'def'\n");
 107                                                         rpn_error = TRUE;
 108                                                 }
 109                                         } else if(rpncmd == "defs" || rpncmd == "@") {
 110                                                 s = "";
 111                                                 i = rpn_popf();
 112                                                 j = (i == 0);
 113                                                 while(rpn_sp > 1 && (j || i > 0))
 114                                                 {
 115                                                         s = strcat("/", rpn_pop(), " ", s);
 116                                                         --i;
 117                                                 }
 118                                                 s2 = rpn_pop();
 119                                                 if(s2 != "")
 120                                                 {
 121                                                         #ifdef MENUQC
 122                                                         registercvar(s2, "", 0);
 123                                                         #else
 124                                                         registercvar(s2, "");
 125                                                         #endif
 126                                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 127                                                                 cvar_set(s2, s);
 128                                                 }
 129                                                 else
 130                                                 {
 131                                                         print("rpn: empty cvar name for 'defs'\n");
 132                                                         rpn_error = TRUE;
 133                                                 }
 134                                         } else if(rpncmd == "load") {
 135                                                 rpn_set(cvar_string(rpn_get()));
 136                                         } else if(rpncmd == "exch") {
 137                                                 s = rpn_pop();
 138                                                 s2 = rpn_get();
 139                                                 rpn_set(s);
 140                                                 rpn_push(s2);
 141                                         } else if(rpncmd == "dup") {
 142                                                 rpn_push(rpn_get());
 143                                         } else if(rpncmd == "pop") {
 144                                                 rpn_pop();
 145                                         } else if(rpncmd == "add" || rpncmd == "+") {
 146                                                 f = rpn_popf();
 147                                                 rpn_setf(rpn_getf() + f);
 148                                         } else if(rpncmd == "sub" || rpncmd == "-") {
 149                                                 f = rpn_popf();
 150                                                 rpn_setf(rpn_getf() - f);
 151                                         } else if(rpncmd == "mul" || rpncmd == "*") {
 152                                                 f = rpn_popf();
 153                                                 rpn_setf(rpn_getf() * f);
 154                                         } else if(rpncmd == "div" || rpncmd == "/") {
 155                                                 f = rpn_popf();
 156                                                 rpn_setf(rpn_getf() / f);
 157                                         } else if(rpncmd == "mod" || rpncmd == "%") {
 158                                                 f = rpn_popf();
 159                                                 f2 = rpn_getf();
 160                                                 rpn_setf(f2 - f * floor(f2 / f));
 161                                         } else if(rpncmd == "pow" || rpncmd == "**") {
 162                                                 f = rpn_popf();
 163                                                 rpn_setf(pow(rpn_getf(), f));
 164                                         } else if(rpncmd == "bitand" || rpncmd == "&") {
 165                                                 f = rpn_popf();
 166                                                 rpn_setf(rpn_getf() & f);
 167                                         } else if(rpncmd == "bitor" || rpncmd == "|") {
 168                                                 f = rpn_popf();
 169                                                 rpn_setf(rpn_getf() | f);
 170                                         } else if(rpncmd == "bitxor" || rpncmd == "^") {
 171                                                 f = rpn_popf();
 172                                                 rpn_setf(rpn_getf() ^ f);
 173                                         } else if(rpncmd == "and" || rpncmd == "&&") {
 174                                                 f = rpn_popf();
 175                                                 rpn_setf(rpn_getf() && f);
 176                                         } else if(rpncmd == "or" || rpncmd == "||") {
 177                                                 f = rpn_popf();
 178                                                 rpn_setf(rpn_getf() || f);
 179                                         } else if(rpncmd == "xor" || rpncmd == "^^") {
 180                                                 f = rpn_popf();
 181                                                 rpn_setf(!rpn_getf() != !f);
 182                                         } else if(rpncmd == "bitnot") {
 183                                                 rpn_setf(~rpn_popf());
 184                                         } else if(rpncmd == "not") {
 185                                                 rpn_setf(!rpn_popf());
 186                                         } else if(rpncmd == "abs") {
 187                                                 rpn_setf(fabs(rpn_getf()));
 188                                         } else if(rpncmd == "sgn") {
 189                                                 f = rpn_getf();
 190                                                 if(f < 0)
 191                                                         rpn_set("-1");
 192                                                 else if(f > 0)
 193                                                         rpn_set("1");
 194                                                 else
 195                                                         rpn_set("0");
 196                                         } else if(rpncmd == "neg" || rpncmd == "~") {
 197                                                 rpn_setf(-rpn_getf());
 198                                         } else if(rpncmd == "floor" || rpncmd == "f") {
 199                                                 rpn_setf(floor(rpn_getf()));
 200                                         } else if(rpncmd == "ceil" || rpncmd == "c") {
 201                                                 rpn_setf(ceil(rpn_getf()));
 202                                         } else if(rpncmd == "exp") {
 203                                                 rpn_setf(exp(rpn_getf()));
 204                                         } else if(rpncmd == "log") {
 205                                                 rpn_setf(exp(rpn_getf()));
 206                                         } else if(rpncmd == "sin") {
 207                                                 rpn_setf(sin(rpn_getf()));
 208                                         } else if(rpncmd == "cos") {
 209                                                 rpn_setf(cos(rpn_getf()));
 210                                         } else if(rpncmd == "max") {
 211                                                 f = rpn_popf();
 212                                                 f2 = rpn_getf();
 213                                                 rpn_setf(max(f2, f));
 214                                         } else if(rpncmd == "min") {
 215                                                 f = rpn_popf();
 216                                                 f2 = rpn_getf();
 217                                                 rpn_setf(min(f2, f));
 218                                         } else if(rpncmd == "bound") {
 219                                                 f = rpn_popf();
 220                                                 f2 = rpn_popf();
 221                                                 f3 = rpn_getf();
 222                                                 rpn_setf(bound(f3, f2, f));
 223                                         } else if(rpncmd == "when") {
 224                                                 f = rpn_popf();
 225                                                 s = rpn_pop();
 226                                                 s2 = rpn_get();
 227                                                 if(f)
 228                                                         rpn_set(s2);
 229                                                 else
 230                                                         rpn_set(s);
 231                                         } else if(rpncmd == ">" || rpncmd == "gt") {
 232                                                 f = rpn_popf();
 233                                                 rpn_setf(rpn_getf() > f);
 234                                         } else if(rpncmd == "<" || rpncmd == "lt") {
 235                                                 f = rpn_popf();
 236                                                 rpn_setf(rpn_getf() < f);
 237                                         } else if(rpncmd == "==" || rpncmd == "eq") {
 238                                                 f = rpn_popf();
 239                                                 rpn_setf(rpn_getf() == f);
 240                                         } else if(rpncmd == ">=" || rpncmd == "ge") {
 241                                                 f = rpn_popf();
 242                                                 rpn_setf(rpn_getf() >= f);
 243                                         } else if(rpncmd == "<=" || rpncmd == "le") {
 244                                                 f = rpn_popf();
 245                                                 rpn_setf(rpn_getf() <= f);
 246                                         } else if(rpncmd == "!=" || rpncmd == "ne") {
 247                                                 f = rpn_popf();
 248                                                 rpn_setf(rpn_getf() != f);
 249                                         } else if(rpncmd == "rand") {
 250                                                 rpn_setf(ceil(random() * rpn_getf()) - 1);
 251                                         } else if(rpncmd == "crc16") {
 252                                                 rpn_setf(crc16(FALSE, rpn_get()));
 253                                         } else if(rpncmd == "put") {
 254                                                 s2 = rpn_pop();
 255                                                 if (!rpn_error)
 256                                                 {
 257                                                         s = rpn_pop();
 258                                                         if (!rpn_error)
 259                                                                 db_put(rpn_db, s, s2);
 260                                                 }
 261                                         } else if(rpncmd == "get") {
 262                                                 s = rpn_pop();
 263                                                 if (!rpn_error)
 264                                                         rpn_push(db_get(rpn_db, s));
 265                                         } else if(rpncmd == "dbpush") {
 266                                                 s = rpn_pop();
 267                                                 if(!rpn_error)
 268                                                 {
 269                                                         i = stof(db_get(rpn_db, "stack.pointer"));
 270                                                         db_put(rpn_db, "stack.pointer", ftos(i+1));
 271                                                         db_put(rpn_db, strcat("stack.", ftos(i)), s);
 272                                                         if(!i)
 273                                                                 db_put(rpn_db, "stack.pos", "0");
 274                                                 }
 275                                         } else if(rpncmd == "dbpop") {
 276                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 277                                                 if(i)
 278                                                 {
 279                                                         s = ftos(i-1);
 280                                                         db_put(rpn_db, "stack.pointer", s);
 281                                                         rpn_push(db_get(rpn_db, strcat("stack.", s)));
 282                                                         j = stof(db_get(rpn_db, "stack.pos"));
 283                                                         if(j >= i)
 284                                                                 db_put(rpn_db, "stack.pos", ftos(i-2));
 285                                                 } else {
 286                                                         rpn_error = 1;
 287                                                         print("rpn: database underflow\n");
 288                                                 }
 289                                         } else if(rpncmd == "dbget") {
 290
 291                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 292                                                 if(i)
 293                                                 {
 294                                                         rpn_push(db_get(rpn_db, strcat("stack.", ftos(i-1))));
 295                                                 } else {
 296                                                         rpn_error = 1;
 297                                                         print("rpn: database empty\n");
 298                                                 }
 299                                         } else if(rpncmd == "dblen") {
 300                                                 rpn_push(db_get(rpn_db, "stack.pointer"));
 301                                         } else if(rpncmd == "dbclr") {
 302                                                 db_close(rpn_db);
 303                                                 rpn_db = db_create();
 304                                                 db_put(rpn_db, "stack.pointer", "0");
 305                                                 db_put(rpn_db, "stack.pos", "-1");
 306                                         } else if(rpncmd == "dbsave") {
 307                                                 s = rpn_pop();
 308                                                 if(!rpn_error)
 309                                                         db_save(rpn_db, s);
 310                                         } else if(rpncmd == "dbload") {
 311                                                 s = rpn_pop();
 312                                                 if(!rpn_error)
 313                                                 {
 314                                                         db_close(rpn_db);
 315                                                         rpn_db = db_load(s);
 316                                                 }
 317                                         } else if(rpncmd == "dbins") {
 318                                                 s = rpn_pop();
 319                                                 if(!rpn_error)
 320                                                         //if(rpn_sp > 0)
 321                                                 {
 322                                                         j = stof(db_get(rpn_db, "stack.pointer"));
 323                                                         i = stof(db_get(rpn_db, "stack.pos"));
 324
 325                                                         if(i < 0)
 326                                                         {
 327                                                                 i = 0;
 328                                                                 db_put(rpn_db, "stack.pos", "0");
 329                                                         }
 330
 331                                                         db_put(rpn_db, "stack.pointer", ftos(j+1));
 332                                                         for(--j; j >= i; --j)
 333                                                         {
 334                                                                 db_put(rpn_db, strcat("stack.", ftos(j+1)),
 335                                                                                          db_get(rpn_db, (strcat("stack.", ftos(j))))
 336                                                                         );
 337                                                         }
 338                                                         db_put(rpn_db, strcat("stack.", ftos(i)), s);
 339                                                 }
 340                                         } else if(rpncmd == "dbext") {
 341                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 342                                                 i = stof(db_get(rpn_db, "stack.pos"));
 343                                                 if(!j)
 344                                                 {
 345                                                         rpn_error = TRUE;
 346                                                         print("rpn: empty database\n");
 347                                                 } else {
 348                                                         --j;
 349                                                         rpn_push(db_get(rpn_db, strcat("stack.", ftos(i))));
 350                                                         db_put(rpn_db, "stack.pointer", ftos(j));
 351                                                         if(i == j)
 352                                                         {
 353                                                                 db_put(rpn_db, "stack.pos", ftos(j-1));
 354                                                         } else {
 355                                                                 while(i < j)
 356                                                                 {
 357                                                                         db_put(rpn_db, strcat("stack.", ftos(i)),
 358                                                                                                  db_get(rpn_db, (strcat("stack.", ftos(i+1))))
 359                                                                                 );
 360                                                                         ++i;
 361                                                                 }
 362                                                         }
 363                                                 }
 364                                         } else if(rpncmd == "dbread") {
 365                                                 s = db_get(rpn_db, "stack.pos");
 366                                                 if(stof(s) >= 0)
 367                                                 {
 368                                                         rpn_push(db_get(rpn_db, strcat("stack.", s)));
 369                                                 } else {
 370                                                         rpn_error = 1;
 371                                                         print("rpn: empty database\n");
 372                                                 }
 373                                         } else if(rpncmd == "dbat") {
 374                                                 rpn_push(db_get(rpn_db, "stack.pos"));
 375                                         } else if(rpncmd == "dbmov") {
 376                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 377                                                 i = stof(db_get(rpn_db, "stack.pos"));
 378                                                 i += rpn_popf();
 379                                                 if(!rpn_error)
 380                                                 {
 381                                                         if(i < 0 || i >= j)
 382                                                         {
 383                                                                 print("rpn: database cursor out of bounds\n");
 384                                                                 rpn_error = TRUE;
 385                                                         }
 386                                                         if(!rpn_error)
 387                                                         {
 388                                                                 db_put(rpn_db, "stack.pos", ftos(i));
 389                                                         }
 390                                                 }
 391                                         } else if(rpncmd == "dbgoto") {
 392                                                 s = rpn_pop();
 393                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 394                                                 if(!j)
 395                                                 {
 396                                                         rpn_error = TRUE;
 397                                                         print("rpn: empty database, cannot move cursor\n");
 398                                                 }
 399                                                 if(!rpn_error)
 400                                                 {
 401                                                         if(s == "end")
 402                                                                 i = stof(db_get(rpn_db, "stack.pointer"))-1;
 403                                                         else if(s == "beg")
 404                                                                 i = 0;
 405                                                         else
 406                                                                 i = stof(s);
 407
 408                                                         j = stof(db_get(rpn_db, "stack.pointer"));
 409                                                         if(i < 0 || i >= j)
 410                                                         {
 411                                                                 print("rpn: database cursor destination out of bounds\n");
 412                                                                 rpn_error = TRUE;
 413                                                         }
 414                                                         if(!rpn_error)
 415                                                         {
 416                                                                 db_put(rpn_db, "stack.pos", ftos(i));
 417                                                         }
 418                                                 }
 419                                         } else if(rpncmd == "union") {
 420                                                 // s s2 union
 421                                                 s2 = rpn_pop();
 422                                                 s = rpn_get();
 423                                                 f = tokenize_console(s);
 424                                                 f2 = tokenize_console(strcat(s, " ", s2));
 425                                                 // tokens 0..(f-1) represent s
 426                                                 // tokens f..f2 represent s2
 427                                                 // UNION: add all tokens to s that are in s2 but not in s
 428                                                 s = "";
 429                                                 for(i = 0; i < f; ++i)
 430                                                         s = strcat(s, " ", argv(i));
 431                                                 for(i = f; i < f2; ++i) {
 432                                                         for(j = 0; j < f; ++j)
 433                                                                 if(argv(i) == argv(j))
 434                                                                         goto skip_union;
 435                                                         s = strcat(s, " ", argv(i));
 436                                                         :skip_union
 437                                                 }
 438                                                 if(substring(s, 0, 1) == " ")
 439                                                         s = substring(s, 1, 99999);
 440                                                 rpn_set(s);
 441                                                 tokenize_console(command);
 442                                         } else if(rpncmd == "intersection") {
 443                                                 // s s2 intersection
 444                                                 s2 = rpn_pop();
 445                                                 s = rpn_get();
 446                                                 f = tokenize_console(s);
 447                                                 f2 = tokenize_console(strcat(s, " ", s2));
 448                                                 // tokens 0..(f-1) represent s
 449                                                 // tokens f..f2 represent s2
 450                                                 // INTERSECTION: keep only the tokens from s that are also in s2
 451                                                 s = "";
 452                                                 for(i = 0; i < f; ++i) {
 453                                                         for(j = f; j < f2; ++j)
 454                                                                 if(argv(i) == argv(j))
 455                                                                 {
 456                                                                         s = strcat(s, " ", argv(i));
 457                                                                         break;
 458                                                                 }
 459                                                 }
 460                                                 if(substring(s, 0, 1) == " ")
 461                                                         s = substring(s, 1, 99999);
 462                                                 rpn_set(s);
 463                                                 tokenize_console(command);
 464                                         } else if(rpncmd == "difference") {
 465                                                 // s s2 difference
 466                                                 s2 = rpn_pop();
 467                                                 s = rpn_get();
 468                                                 f = tokenize_console(s);
 469                                                 f2 = tokenize_console(strcat(s, " ", s2));
 470                                                 // tokens 0..(f-1) represent s
 471                                                 // tokens f..f2 represent s2
 472                                                 // DIFFERENCE: keep only the tokens from s that are not in s2
 473                                                 s = "";
 474                                                 for(i = 0; i < f; ++i) {
 475                                                         for(j = f; j < f2; ++j)
 476                                                                 if(argv(i) == argv(j))
 477                                                                         goto skip_difference;
 478                                                         s = strcat(s, " ", argv(i));
 479                                                         :skip_difference
 480                                                 }
 481                                                 if(substring(s, 0, 1) == " ")
 482                                                         s = substring(s, 1, 99999);
 483                                                 rpn_set(s);
 484                                                 tokenize_console(command);
 485                                         } else if(rpncmd == "shuffle") {
 486                                                 // s shuffle
 487                                                 s = rpn_get();
 488                                                 f = tokenize_console(s);
 489
 490                                                 for(i = 0; i < f - 1; ++i) {
 491                                                         // move a random item from i..f-1 to position i
 492                                                         s = "";
 493                                                         f2 = floor(random() * (f - i) + i);
 494                                                         for(j = 0; j < i; ++j)
 495                                                                 s = strcat(s, " ", argv(j));
 496                                                         s = strcat(s, " ", argv(f2));
 497                                                         for(j = i; j < f; ++j)
 498                                                                 if(j != f2)
 499                                                                         s = strcat(s, " ", argv(j));
 500                                                         f = tokenize_console(s);
 501                                                 }
 502
 503                                                 if(substring(s, 0, 1) == " ")
 504                                                         s = substring(s, 1, 99999);
 505                                                 rpn_set(s);
 506                                                 tokenize_console(command);
 507                                         } else if(rpncmd == "fexists_assert") {
 508                                                 s = rpn_pop();
 509                                                 if(!rpn_error)
 510                                                 {
 511                                                         if (!fexists(s))
 512                                                         {
 513                                                                 print("rpn: ERROR: ", s, " does not exist!\n");
 514                                                                 rpn_error = TRUE;
 515                                                         }
 516                                                 }
 517                                         } else if(rpncmd == "fexists") {
 518                                                 s = rpn_get();
 519                                                 if(!rpn_error)
 520                                                 {
 521                                                         if (fexists(s))
 522                                                                 rpn_setf(1);
 523                                                         else
 524                                                                 rpn_setf(0);
 525                                                 }
 526                                         } else if(rpncmd == "localtime") {
 527                                                 rpn_set(strftime(TRUE, rpn_get()));
 528                                         } else if(rpncmd == "gmtime") {
 529                                                 rpn_set(strftime(FALSE, rpn_get()));
 530                                         } else if(rpncmd == "time") {
 531                                                 rpn_pushf(time);
 532                                         } else if(rpncmd == "digest") {
 533                                                 s = rpn_pop();
 534                                                 rpn_set(digest_hex(s, rpn_get()));
 535                                         } else if(rpncmd == "sprintf1s") {
 536                                                 s = rpn_pop();
 537                                                 rpn_set(sprintf(s, rpn_get()));
 538                                         } else if(rpncmd == "eval") {
 539                                                 s = rpn_pop();
 540                                                 command = strcat(s, substring(command, argv_end_index(rpnpos), -1));
 541                                                 argc = tokenize_console(command);
 542                                                 rpnpos = -1;
 543                                         } else {
 544                                                 rpn_push(cvar_string(rpncmd));
 545                                         }
 546                                         if(rpn_error)
 547                                                 break;
 548                                 }
 549                                 while(rpn_sp > 0)
 550                                 {
 551                                         s = rpn_pop();
 552                                         print("rpn: still on stack: ", s, "\n");
 553                                 }
 554                         }
 555
 556                         return;
 557                 }
 558
 559                 default:
 560                 case CMD_REQUEST_USAGE:
 561                 {
 562                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " rpn EXPRESSION...\n"));
 563                         print("    Operator description (x: string, s: set, f: float):\n");
 564                         print("    x pop ----------------------------->     : removes the top\n");
 565                         print("    x dup -----------------------------> x x : duplicates the top\n");
 566                         print("    x x exch --------------------------> x x : swap the top two\n");
 567                         print("    /cvarname load --------------------> x   : loads a cvar\n");
 568                         print("    /cvarname x def ------------------->     : writes to a cvar\n");
 569                         print("    f f add|sub|mul|div|mod|pow -------> f   : adds/... two numbers\n");
 570                         print("    f f and|or|xor|bitand|bitor|bitxor > f   : logical and bitwise operations\n");
 571                         print("    f f eq|ne|gt|ge|lt|le|max|min -----> f   : compares two numbers\n");
 572                         print("    f neg|abs|sgn|rand|floor|ceil------> f   : negates/... a number\n");
 573                         print("    f not|bitnot ----------------------> f   : logical and bitwise negation\n");
 574                         print("    f exp|log|sin|cos -----------------> f   : exponential function & Co.\n");
 575                         print("    f f f bound -----------------------> f   : bounds the middle number\n");
 576                         print("    f1 f2 b when ----------------------> f   : f1 if b, f2 otherwise\n");
 577                         print("    s s union|intersection|difference -> s   : set operations\n");
 578                         print("    s shuffle -------------------------> s   : randomly arrange elements\n");
 579                         print("    /key /value put ------------------->     : set a database key\n");
 580                         print("    /key get --------------------------> s   : get a database value\n");
 581                         print("    x dbpush -------------------------->     : pushes the top onto the database\n");
 582                         print("    dbpop|dbget -----------------------> x   : removes/reads DB's top\n");
 583                         print("    dblen|dbat ------------------------> f   : gets the DB's size/cursor pos\n");
 584                         print("    dbclr ----------------------------->     : clear the DB\n");
 585                         print("    s dbsave|dbload-------------------->     : save/load the DB to/from a file\n");
 586                         print("    x dbins --------------------------->     : moves the top into the DB\n");
 587                         print("    dbext|dbread ----------------------> x   : extract/get from the DB's cursor\n");
 588                         print("    f dbmov|dbgoto -------------------->     : move or set the DB's cursor\n");
 589                         print("    s localtime -----------------------> s   : formats the current local time\n");
 590                         print("    s gmtime --------------------------> s   : formats the current UTC time\n");
 591                         print("    time ------------------------------> f   : seconds since VM start\n");
 592                         print("    s /MD4 digest ---------------------> s   : MD4 digest\n");
 593                         print("    s /SHA256 digest ------------------> s   : SHA256 digest\n");
 594                         print("    s /formatstring sprintf1s ---------> s   : sprintf with 1 string (pad, cut)\n");
 595                         print("    s eval ---------------------------->     : does something eval\n");
 596                         print("    Set operations operate on 'such''strings'.\n");
 597                         print("    Unknown tokens insert their cvar value.\n");
 598                         return;
 599                 }
 600         }
 601 }