qcsrc/common/command/rpn.qc

   1 #if defined(CSQC)
   2         #include "../../dpdefs/csprogsdefs.qh"
   3         #include "../../warpzonelib/mathlib.qh"
   4         #include "../util.qh"
   5         #include "rpn.qh"
   6         #include "generic.qh"
   7         #include "shared_defs.qh"
   8 #elif defined(MENUQC)
   9 #elif defined(SVQC)
  10         #include "../../dpdefs/progsdefs.qh"
  11     #include "../../dpdefs/dpextensions.qh"
  12     #include "../../server/sys-post.qh"
  13     #include "../../warpzonelib/mathlib.qh"
  14     #include "../util.qh"
  15     #include "rpn.qh"
  16     #include "generic.qh"
  17     #include "shared_defs.qh"
  18 #endif
  19
  20 // ========================================
  21 //  RPN command code, written by divVerent
  22 //  Last updated: December 28th, 2011
  23 // ========================================
  24
  25 string rpn_pop()
  26 {
  27         if(rpn_sp > 0) {
  28                 --rpn_sp;
  29                 return rpn_stack[rpn_sp];
  30         } else {
  31                 print("rpn: stack underflow\n");
  32                 rpn_error = true;
  33                 return "";
  34         }
  35 }
  36 void rpn_push(string s)
  37 {
  38         if(rpn_sp < MAX_RPN_STACK) {
  39                 rpn_stack[rpn_sp] = s;
  40                 ++rpn_sp;
  41         } else {
  42                 print("rpn: stack overflow\n");
  43                 rpn_error = true;
  44         }
  45 }
  46 string rpn_get()
  47 {
  48         if(rpn_sp > 0) {
  49                 return rpn_stack[rpn_sp - 1];
  50         } else {
  51                 print("rpn: empty stack\n");
  52                 rpn_error = true;
  53                 return "";
  54         }
  55 }
  56 void rpn_set(string s)
  57 {
  58         if(rpn_sp > 0) {
  59                 rpn_stack[rpn_sp - 1] = s;
  60         } else {
  61                 print("rpn: empty stack\n");
  62                 rpn_error = true;
  63         }
  64 }
  65
  66 float rpn_getf() { return stof(rpn_get()); }
  67 float rpn_popf() { return stof(rpn_pop()); }
  68 void rpn_pushf(float f) { return rpn_push(sprintf("%.9g", f)); }
  69 void rpn_setf(float f) { return rpn_set(sprintf("%.9g", f)); }
  70
  71 void GenericCommand_rpn(float request, float argc, string command)
  72 {
  73         switch(request)
  74         {
  75                 case CMD_REQUEST_COMMAND:
  76                 {
  77                         float i, j, f, f2, f3, rpnpos;
  78                         //vector rgb;
  79                         string s, s2, rpncmd;
  80
  81                         if(!rpn_db)
  82                         {
  83                                 rpn_db = db_create();
  84                                 db_put(rpn_db, "stack.pointer", "0");
  85                                 db_put(rpn_db, "stack.pos", "-1");
  86                         }
  87
  88                         if(argc >= 2)
  89                         {
  90                                 rpn_sp = 0;
  91                                 rpn_error = false;
  92                                 for(rpnpos = 1; rpnpos < argc; ++rpnpos)
  93                                 {
  94                                         rpncmd = argv(rpnpos);
  95                                         f = strlen(rpncmd);
  96                                         if(rpncmd == "") {
  97                                         } else if(stof(substring(rpncmd, 0, 1)) > 0) {
  98                                                 rpn_push(rpncmd);
  99                                         } else if(substring(rpncmd, 0, 1) == "0") {
 100                                                 rpn_push(rpncmd);
 101                                         } else if(f >= 2 && substring(rpncmd, 0, 1) == "+") {
 102                                                 rpn_push(rpncmd);
 103                                         } else if(f >= 2 && substring(rpncmd, 0, 1) == "-") {
 104                                                 rpn_push(rpncmd);
 105                                         } else if(f >= 2 && substring(rpncmd, 0, 1) == "/") {
 106                                                 rpn_push(substring(rpncmd, 1, strlen(rpncmd) - 1));
 107                                         } else if(rpncmd == "clear") {
 108                                                 rpn_sp = 0;
 109                                         } else if(rpncmd == "def" || rpncmd == "=") {
 110                                                 s = rpn_pop();
 111                                                 s2 = rpn_pop();
 112
 113                                                 if(s2 != "")
 114                                                 {
 115                                                         #ifdef MENUQC
 116                                                         registercvar(s2, "", 0);
 117                                                         #else
 118                                                         registercvar(s2, "");
 119                                                         #endif
 120                                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 121                                                                 cvar_set(s2, s);
 122                                                 }
 123                                                 else
 124                                                 {
 125                                                         print("rpn: empty cvar name for 'def'\n");
 126                                                         rpn_error = true;
 127                                                 }
 128                                         } else if(rpncmd == "defs" || rpncmd == "@") {
 129                                                 s = "";
 130                                                 i = rpn_popf();
 131                                                 j = (i == 0);
 132                                                 while(rpn_sp > 1 && (j || i > 0))
 133                                                 {
 134                                                         s = strcat("/", rpn_pop(), " ", s);
 135                                                         --i;
 136                                                 }
 137                                                 s2 = rpn_pop();
 138                                                 if(s2 != "")
 139                                                 {
 140                                                         #ifdef MENUQC
 141                                                         registercvar(s2, "", 0);
 142                                                         #else
 143                                                         registercvar(s2, "");
 144                                                         #endif
 145                                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 146                                                                 cvar_set(s2, s);
 147                                                 }
 148                                                 else
 149                                                 {
 150                                                         print("rpn: empty cvar name for 'defs'\n");
 151                                                         rpn_error = true;
 152                                                 }
 153                                         } else if(rpncmd == "load") {
 154                                                 rpn_set(cvar_string(rpn_get()));
 155                                         } else if(rpncmd == "exch") {
 156                                                 s = rpn_pop();
 157                                                 s2 = rpn_get();
 158                                                 rpn_set(s);
 159                                                 rpn_push(s2);
 160                                         } else if(rpncmd == "dup") {
 161                                                 rpn_push(rpn_get());
 162                                         } else if(rpncmd == "pop") {
 163                                                 rpn_pop();
 164                                         } else if(rpncmd == "add" || rpncmd == "+") {
 165                                                 f = rpn_popf();
 166                                                 rpn_setf(rpn_getf() + f);
 167                                         } else if(rpncmd == "sub" || rpncmd == "-") {
 168                                                 f = rpn_popf();
 169                                                 rpn_setf(rpn_getf() - f);
 170                                         } else if(rpncmd == "mul" || rpncmd == "*") {
 171                                                 f = rpn_popf();
 172                                                 rpn_setf(rpn_getf() * f);
 173                                         } else if(rpncmd == "div" || rpncmd == "/") {
 174                                                 f = rpn_popf();
 175                                                 rpn_setf(rpn_getf() / f);
 176                                         } else if(rpncmd == "mod" || rpncmd == "%") {
 177                                                 f = rpn_popf();
 178                                                 f2 = rpn_getf();
 179                                                 rpn_setf(f2 - f * floor(f2 / f));
 180                                         } else if(rpncmd == "pow" || rpncmd == "**") {
 181                                                 f = rpn_popf();
 182                                                 rpn_setf(pow(rpn_getf(), f));
 183                                         } else if(rpncmd == "bitand" || rpncmd == "&") {
 184                                                 f = rpn_popf();
 185                                                 rpn_setf(rpn_getf() & f);
 186                                         } else if(rpncmd == "bitor" || rpncmd == "|") {
 187                                                 f = rpn_popf();
 188                                                 rpn_setf(rpn_getf() | f);
 189                                         } else if(rpncmd == "bitxor" || rpncmd == "^") {
 190                                                 f = rpn_popf();
 191                                                 rpn_setf(rpn_getf() ^ f);
 192                                         } else if(rpncmd == "and" || rpncmd == "&&") {
 193                                                 f = rpn_popf();
 194                                                 rpn_setf(rpn_getf() && f);
 195                                         } else if(rpncmd == "or" || rpncmd == "||") {
 196                                                 f = rpn_popf();
 197                                                 rpn_setf(rpn_getf() || f);
 198                                         } else if(rpncmd == "xor" || rpncmd == "^^") {
 199                                                 f = rpn_popf();
 200                                                 rpn_setf(!rpn_getf() != !f);
 201                                         } else if(rpncmd == "bitnot") {
 202                                                 rpn_setf(~rpn_popf());
 203                                         } else if(rpncmd == "not") {
 204                                                 rpn_setf(!rpn_popf());
 205                                         } else if(rpncmd == "abs") {
 206                                                 rpn_setf(fabs(rpn_getf()));
 207                                         } else if(rpncmd == "sgn") {
 208                                                 f = rpn_getf();
 209                                                 if(f < 0)
 210                                                         rpn_set("-1");
 211                                                 else if(f > 0)
 212                                                         rpn_set("1");
 213                                                 else
 214                                                         rpn_set("0");
 215                                         } else if(rpncmd == "neg" || rpncmd == "~") {
 216                                                 rpn_setf(-rpn_getf());
 217                                         } else if(rpncmd == "floor" || rpncmd == "f") {
 218                                                 rpn_setf(floor(rpn_getf()));
 219                                         } else if(rpncmd == "ceil" || rpncmd == "c") {
 220                                                 rpn_setf(ceil(rpn_getf()));
 221                                         } else if(rpncmd == "exp") {
 222                                                 rpn_setf(exp(rpn_getf()));
 223                                         } else if(rpncmd == "log") {
 224                                                 rpn_setf(exp(rpn_getf()));
 225                                         } else if(rpncmd == "sin") {
 226                                                 rpn_setf(sin(rpn_getf()));
 227                                         } else if(rpncmd == "cos") {
 228                                                 rpn_setf(cos(rpn_getf()));
 229                                         } else if(rpncmd == "max") {
 230                                                 f = rpn_popf();
 231                                                 f2 = rpn_getf();
 232                                                 rpn_setf(max(f2, f));
 233                                         } else if(rpncmd == "min") {
 234                                                 f = rpn_popf();
 235                                                 f2 = rpn_getf();
 236                                                 rpn_setf(min(f2, f));
 237                                         } else if(rpncmd == "bound") {
 238                                                 f = rpn_popf();
 239                                                 f2 = rpn_popf();
 240                                                 f3 = rpn_getf();
 241                                                 rpn_setf(bound(f3, f2, f));
 242                                         } else if(rpncmd == "when") {
 243                                                 f = rpn_popf();
 244                                                 s = rpn_pop();
 245                                                 s2 = rpn_get();
 246                                                 if(f)
 247                                                         rpn_set(s2);
 248                                                 else
 249                                                         rpn_set(s);
 250                                         } else if(rpncmd == ">" || rpncmd == "gt") {
 251                                                 f = rpn_popf();
 252                                                 rpn_setf(rpn_getf() > f);
 253                                         } else if(rpncmd == "<" || rpncmd == "lt") {
 254                                                 f = rpn_popf();
 255                                                 rpn_setf(rpn_getf() < f);
 256                                         } else if(rpncmd == "==" || rpncmd == "eq") {
 257                                                 f = rpn_popf();
 258                                                 rpn_setf(rpn_getf() == f);
 259                                         } else if(rpncmd == ">=" || rpncmd == "ge") {
 260                                                 f = rpn_popf();
 261                                                 rpn_setf(rpn_getf() >= f);
 262                                         } else if(rpncmd == "<=" || rpncmd == "le") {
 263                                                 f = rpn_popf();
 264                                                 rpn_setf(rpn_getf() <= f);
 265                                         } else if(rpncmd == "!=" || rpncmd == "ne") {
 266                                                 f = rpn_popf();
 267                                                 rpn_setf(rpn_getf() != f);
 268                                         } else if(rpncmd == "rand") {
 269                                                 rpn_setf(ceil(random() * rpn_getf()) - 1);
 270                                         } else if(rpncmd == "crc16") {
 271                                                 rpn_setf(crc16(false, rpn_get()));
 272                                         } else if(rpncmd == "put") {
 273                                                 s2 = rpn_pop();
 274                                                 if (!rpn_error)
 275                                                 {
 276                                                         s = rpn_pop();
 277                                                         if (!rpn_error)
 278                                                                 db_put(rpn_db, s, s2);
 279                                                 }
 280                                         } else if(rpncmd == "get") {
 281                                                 s = rpn_pop();
 282                                                 if (!rpn_error)
 283                                                         rpn_push(db_get(rpn_db, s));
 284                                         } else if(rpncmd == "dbpush") {
 285                                                 s = rpn_pop();
 286                                                 if(!rpn_error)
 287                                                 {
 288                                                         i = stof(db_get(rpn_db, "stack.pointer"));
 289                                                         db_put(rpn_db, "stack.pointer", ftos(i+1));
 290                                                         db_put(rpn_db, strcat("stack.", ftos(i)), s);
 291                                                         if(!i)
 292                                                                 db_put(rpn_db, "stack.pos", "0");
 293                                                 }
 294                                         } else if(rpncmd == "dbpop") {
 295                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 296                                                 if(i)
 297                                                 {
 298                                                         s = ftos(i-1);
 299                                                         db_put(rpn_db, "stack.pointer", s);
 300                                                         rpn_push(db_get(rpn_db, strcat("stack.", s)));
 301                                                         j = stof(db_get(rpn_db, "stack.pos"));
 302                                                         if(j >= i)
 303                                                                 db_put(rpn_db, "stack.pos", ftos(i-2));
 304                                                 } else {
 305                                                         rpn_error = 1;
 306                                                         print("rpn: database underflow\n");
 307                                                 }
 308                                         } else if(rpncmd == "dbget") {
 309
 310                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 311                                                 if(i)
 312                                                 {
 313                                                         rpn_push(db_get(rpn_db, strcat("stack.", ftos(i-1))));
 314                                                 } else {
 315                                                         rpn_error = 1;
 316                                                         print("rpn: database empty\n");
 317                                                 }
 318                                         } else if(rpncmd == "dblen") {
 319                                                 rpn_push(db_get(rpn_db, "stack.pointer"));
 320                                         } else if(rpncmd == "dbclr") {
 321                                                 db_close(rpn_db);
 322                                                 rpn_db = db_create();
 323                                                 db_put(rpn_db, "stack.pointer", "0");
 324                                                 db_put(rpn_db, "stack.pos", "-1");
 325                                         } else if(rpncmd == "dbsave") {
 326                                                 s = rpn_pop();
 327                                                 if(!rpn_error)
 328                                                         db_save(rpn_db, s);
 329                                         } else if(rpncmd == "dbload") {
 330                                                 s = rpn_pop();
 331                                                 if(!rpn_error)
 332                                                 {
 333                                                         db_close(rpn_db);
 334                                                         rpn_db = db_load(s);
 335                                                 }
 336                                         } else if(rpncmd == "dbins") {
 337                                                 s = rpn_pop();
 338                                                 if(!rpn_error)
 339                                                         //if(rpn_sp > 0)
 340                                                 {
 341                                                         j = stof(db_get(rpn_db, "stack.pointer"));
 342                                                         i = stof(db_get(rpn_db, "stack.pos"));
 343
 344                                                         if(i < 0)
 345                                                         {
 346                                                                 i = 0;
 347                                                                 db_put(rpn_db, "stack.pos", "0");
 348                                                         }
 349
 350                                                         db_put(rpn_db, "stack.pointer", ftos(j+1));
 351                                                         for(--j; j >= i; --j)
 352                                                         {
 353                                                                 db_put(rpn_db, strcat("stack.", ftos(j+1)),
 354                                                                                          db_get(rpn_db, (strcat("stack.", ftos(j))))
 355                                                                         );
 356                                                         }
 357                                                         db_put(rpn_db, strcat("stack.", ftos(i)), s);
 358                                                 }
 359                                         } else if(rpncmd == "dbext") {
 360                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 361                                                 i = stof(db_get(rpn_db, "stack.pos"));
 362                                                 if(!j)
 363                                                 {
 364                                                         rpn_error = true;
 365                                                         print("rpn: empty database\n");
 366                                                 } else {
 367                                                         --j;
 368                                                         rpn_push(db_get(rpn_db, strcat("stack.", ftos(i))));
 369                                                         db_put(rpn_db, "stack.pointer", ftos(j));
 370                                                         if(i == j)
 371                                                         {
 372                                                                 db_put(rpn_db, "stack.pos", ftos(j-1));
 373                                                         } else {
 374                                                                 while(i < j)
 375                                                                 {
 376                                                                         db_put(rpn_db, strcat("stack.", ftos(i)),
 377                                                                                                  db_get(rpn_db, (strcat("stack.", ftos(i+1))))
 378                                                                                 );
 379                                                                         ++i;
 380                                                                 }
 381                                                         }
 382                                                 }
 383                                         } else if(rpncmd == "dbread") {
 384                                                 s = db_get(rpn_db, "stack.pos");
 385                                                 if(stof(s) >= 0)
 386                                                 {
 387                                                         rpn_push(db_get(rpn_db, strcat("stack.", s)));
 388                                                 } else {
 389                                                         rpn_error = 1;
 390                                                         print("rpn: empty database\n");
 391                                                 }
 392                                         } else if(rpncmd == "dbat") {
 393                                                 rpn_push(db_get(rpn_db, "stack.pos"));
 394                                         } else if(rpncmd == "dbmov") {
 395                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 396                                                 i = stof(db_get(rpn_db, "stack.pos"));
 397                                                 i += rpn_popf();
 398                                                 if(!rpn_error)
 399                                                 {
 400                                                         if(i < 0 || i >= j)
 401                                                         {
 402                                                                 print("rpn: database cursor out of bounds\n");
 403                                                                 rpn_error = true;
 404                                                         }
 405                                                         if(!rpn_error)
 406                                                         {
 407                                                                 db_put(rpn_db, "stack.pos", ftos(i));
 408                                                         }
 409                                                 }
 410                                         } else if(rpncmd == "dbgoto") {
 411                                                 s = rpn_pop();
 412                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 413                                                 if(!j)
 414                                                 {
 415                                                         rpn_error = true;
 416                                                         print("rpn: empty database, cannot move cursor\n");
 417                                                 }
 418                                                 if(!rpn_error)
 419                                                 {
 420                                                         if(s == "end")
 421                                                                 i = stof(db_get(rpn_db, "stack.pointer"))-1;
 422                                                         else if(s == "beg")
 423                                                                 i = 0;
 424                                                         else
 425                                                                 i = stof(s);
 426
 427                                                         j = stof(db_get(rpn_db, "stack.pointer"));
 428                                                         if(i < 0 || i >= j)
 429                                                         {
 430                                                                 print("rpn: database cursor destination out of bounds\n");
 431                                                                 rpn_error = true;
 432                                                         }
 433                                                         if(!rpn_error)
 434                                                         {
 435                                                                 db_put(rpn_db, "stack.pos", ftos(i));
 436                                                         }
 437                                                 }
 438                                         } else if(rpncmd == "union") {
 439                                                 // s s2 union
 440                                                 s2 = rpn_pop();
 441                                                 s = rpn_get();
 442                                                 f = tokenize_console(s);
 443                                                 f2 = tokenize_console(strcat(s, " ", s2));
 444                                                 // tokens 0..(f-1) represent s
 445                                                 // tokens f..f2 represent s2
 446                                                 // UNION: add all tokens to s that are in s2 but not in s
 447                                                 s = "";
 448                                                 for(i = 0; i < f; ++i)
 449                                                         s = strcat(s, " ", argv(i));
 450                                                 for(i = f; i < f2; ++i) {
 451                                                         for(j = 0; j < f; ++j)
 452                                                                 if(argv(i) == argv(j))
 453                                                                         goto skip_union;
 454                                                         s = strcat(s, " ", argv(i));
 455                                                         :skip_union
 456                                                 }
 457                                                 if(substring(s, 0, 1) == " ")
 458                                                         s = substring(s, 1, 99999);
 459                                                 rpn_set(s);
 460                                                 tokenize_console(command);
 461                                         } else if(rpncmd == "intersection") {
 462                                                 // s s2 intersection
 463                                                 s2 = rpn_pop();
 464                                                 s = rpn_get();
 465                                                 f = tokenize_console(s);
 466                                                 f2 = tokenize_console(strcat(s, " ", s2));
 467                                                 // tokens 0..(f-1) represent s
 468                                                 // tokens f..f2 represent s2
 469                                                 // INTERSECTION: keep only the tokens from s that are also in s2
 470                                                 s = "";
 471                                                 for(i = 0; i < f; ++i) {
 472                                                         for(j = f; j < f2; ++j)
 473                                                                 if(argv(i) == argv(j))
 474                                                                 {
 475                                                                         s = strcat(s, " ", argv(i));
 476                                                                         break;
 477                                                                 }
 478                                                 }
 479                                                 if(substring(s, 0, 1) == " ")
 480                                                         s = substring(s, 1, 99999);
 481                                                 rpn_set(s);
 482                                                 tokenize_console(command);
 483                                         } else if(rpncmd == "difference") {
 484                                                 // s s2 difference
 485                                                 s2 = rpn_pop();
 486                                                 s = rpn_get();
 487                                                 f = tokenize_console(s);
 488                                                 f2 = tokenize_console(strcat(s, " ", s2));
 489                                                 // tokens 0..(f-1) represent s
 490                                                 // tokens f..f2 represent s2
 491                                                 // DIFFERENCE: keep only the tokens from s that are not in s2
 492                                                 s = "";
 493                                                 for(i = 0; i < f; ++i) {
 494                                                         for(j = f; j < f2; ++j)
 495                                                                 if(argv(i) == argv(j))
 496                                                                         goto skip_difference;
 497                                                         s = strcat(s, " ", argv(i));
 498                                                         :skip_difference
 499                                                 }
 500                                                 if(substring(s, 0, 1) == " ")
 501                                                         s = substring(s, 1, 99999);
 502                                                 rpn_set(s);
 503                                                 tokenize_console(command);
 504                                         } else if(rpncmd == "shuffle") {
 505                                                 // s shuffle
 506                                                 s = rpn_get();
 507                                                 f = tokenize_console(s);
 508
 509                                                 for(i = 0; i < f - 1; ++i) {
 510                                                         // move a random item from i..f-1 to position i
 511                                                         s = "";
 512                                                         f2 = floor(random() * (f - i) + i);
 513                                                         for(j = 0; j < i; ++j)
 514                                                                 s = strcat(s, " ", argv(j));
 515                                                         s = strcat(s, " ", argv(f2));
 516                                                         for(j = i; j < f; ++j)
 517                                                                 if(j != f2)
 518                                                                         s = strcat(s, " ", argv(j));
 519                                                         f = tokenize_console(s);
 520                                                 }
 521
 522                                                 if(substring(s, 0, 1) == " ")
 523                                                         s = substring(s, 1, 99999);
 524                                                 rpn_set(s);
 525                                                 tokenize_console(command);
 526                                         } else if(rpncmd == "fexists_assert") {
 527                                                 s = rpn_pop();
 528                                                 if(!rpn_error)
 529                                                 {
 530                                                         if (!fexists(s))
 531                                                         {
 532                                                                 print("rpn: ERROR: ", s, " does not exist!\n");
 533                                                                 rpn_error = true;
 534                                                         }
 535                                                 }
 536                                         } else if(rpncmd == "fexists") {
 537                                                 s = rpn_get();
 538                                                 if(!rpn_error)
 539                                                 {
 540                                                         if (fexists(s))
 541                                                                 rpn_setf(1);
 542                                                         else
 543                                                                 rpn_setf(0);
 544                                                 }
 545                                         } else if(rpncmd == "localtime") {
 546                                                 rpn_set(strftime(true, rpn_get()));
 547                                         } else if(rpncmd == "gmtime") {
 548                                                 rpn_set(strftime(false, rpn_get()));
 549                                         } else if(rpncmd == "time") {
 550                                                 rpn_pushf(time);
 551                                         } else if(rpncmd == "digest") {
 552                                                 s = rpn_pop();
 553                                                 rpn_set(digest_hex(s, rpn_get()));
 554                                         } else if(rpncmd == "sprintf1s") {
 555                                                 s = rpn_pop();
 556                                                 rpn_set(sprintf(s, rpn_get()));
 557                                         } else if(rpncmd == "eval") {
 558                                                 s = rpn_pop();
 559                                                 command = strcat(s, substring(command, argv_end_index(rpnpos), -1));
 560                                                 argc = tokenize_console(command);
 561                                                 rpnpos = -1;
 562                                         } else {
 563                                                 rpn_push(cvar_string(rpncmd));
 564                                         }
 565                                         if(rpn_error)
 566                                                 break;
 567                                 }
 568                                 while(rpn_sp > 0)
 569                                 {
 570                                         s = rpn_pop();
 571                                         print("rpn: still on stack: ", s, "\n");
 572                                 }
 573                         }
 574
 575                         return;
 576                 }
 577
 578                 default:
 579                 case CMD_REQUEST_USAGE:
 580                 {
 581                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " rpn EXPRESSION...\n"));
 582                         print("    Operator description (x: string, s: set, f: float):\n");
 583                         print("    x pop ----------------------------->     : removes the top\n");
 584                         print("    x dup -----------------------------> x x : duplicates the top\n");
 585                         print("    x x exch --------------------------> x x : swap the top two\n");
 586                         print("    /cvarname load --------------------> x   : loads a cvar\n");
 587                         print("    /cvarname x def ------------------->     : writes to a cvar\n");
 588                         print("    f f add|sub|mul|div|mod|pow -------> f   : adds/... two numbers\n");
 589                         print("    f f and|or|xor|bitand|bitor|bitxor > f   : logical and bitwise operations\n");
 590                         print("    f f eq|ne|gt|ge|lt|le|max|min -----> f   : compares two numbers\n");
 591                         print("    f neg|abs|sgn|rand|floor|ceil------> f   : negates/... a number\n");
 592                         print("    f not|bitnot ----------------------> f   : logical and bitwise negation\n");
 593                         print("    f exp|log|sin|cos -----------------> f   : exponential function & Co.\n");
 594                         print("    f f f bound -----------------------> f   : bounds the middle number\n");
 595                         print("    f1 f2 b when ----------------------> f   : f1 if b, f2 otherwise\n");
 596                         print("    s s union|intersection|difference -> s   : set operations\n");
 597                         print("    s shuffle -------------------------> s   : randomly arrange elements\n");
 598                         print("    /key /value put ------------------->     : set a database key\n");
 599                         print("    /key get --------------------------> s   : get a database value\n");
 600                         print("    x dbpush -------------------------->     : pushes the top onto the database\n");
 601                         print("    dbpop|dbget -----------------------> x   : removes/reads DB's top\n");
 602                         print("    dblen|dbat ------------------------> f   : gets the DB's size/cursor pos\n");
 603                         print("    dbclr ----------------------------->     : clear the DB\n");
 604                         print("    s dbsave|dbload-------------------->     : save/load the DB to/from a file\n");
 605                         print("    x dbins --------------------------->     : moves the top into the DB\n");
 606                         print("    dbext|dbread ----------------------> x   : extract/get from the DB's cursor\n");
 607                         print("    f dbmov|dbgoto -------------------->     : move or set the DB's cursor\n");
 608                         print("    s localtime -----------------------> s   : formats the current local time\n");
 609                         print("    s gmtime --------------------------> s   : formats the current UTC time\n");
 610                         print("    time ------------------------------> f   : seconds since VM start\n");
 611                         print("    s /MD4 digest ---------------------> s   : MD4 digest\n");
 612                         print("    s /SHA256 digest ------------------> s   : SHA256 digest\n");
 613                         print("    s /formatstring sprintf1s ---------> s   : sprintf with 1 string (pad, cut)\n");
 614                         print("    s eval ---------------------------->     : does something eval\n");
 615                         print("    Set operations operate on 'such''strings'.\n");
 616                         print("    Unknown tokens insert their cvar value.\n");
 617                         return;
 618                 }
 619         }
 620 }