qcsrc/common/command/rpn.qc

   1 #include "command.qh"
   2 #include "rpn.qh"
   3
   4 #include "../../warpzonelib/mathlib.qh"
   5
   6 // ========================================
   7 //  RPN command code, written by divVerent
   8 //  Last updated: December 28th, 2011
   9 // ========================================
  10
  11 string rpn_pop()
  12 {
  13         if(rpn_sp > 0) {
  14                 --rpn_sp;
  15                 return rpn_stack[rpn_sp];
  16         } else {
  17                 print("rpn: stack underflow\n");
  18                 rpn_error = true;
  19                 return "";
  20         }
  21 }
  22 void rpn_push(string s)
  23 {
  24         if(rpn_sp < MAX_RPN_STACK) {
  25                 rpn_stack[rpn_sp] = s;
  26                 ++rpn_sp;
  27         } else {
  28                 print("rpn: stack overflow\n");
  29                 rpn_error = true;
  30         }
  31 }
  32 string rpn_get()
  33 {
  34         if(rpn_sp > 0) {
  35                 return rpn_stack[rpn_sp - 1];
  36         } else {
  37                 print("rpn: empty stack\n");
  38                 rpn_error = true;
  39                 return "";
  40         }
  41 }
  42 void rpn_set(string s)
  43 {
  44         if(rpn_sp > 0) {
  45                 rpn_stack[rpn_sp - 1] = s;
  46         } else {
  47                 print("rpn: empty stack\n");
  48                 rpn_error = true;
  49         }
  50 }
  51
  52 float rpn_getf() { return stof(rpn_get()); }
  53 float rpn_popf() { return stof(rpn_pop()); }
  54 void rpn_pushf(float f) { return rpn_push(sprintf("%.9g", f)); }
  55 void rpn_setf(float f) { return rpn_set(sprintf("%.9g", f)); }
  56
  57 void GenericCommand_rpn(float request, float argc, string command)
  58 {
  59         switch(request)
  60         {
  61                 case CMD_REQUEST_COMMAND:
  62                 {
  63                         float i, j, f, f2, f3, rpnpos;
  64                         //vector rgb;
  65                         string s, s2, rpncmd;
  66
  67                         if(!rpn_db)
  68                         {
  69                                 rpn_db = db_create();
  70                                 db_put(rpn_db, "stack.pointer", "0");
  71                                 db_put(rpn_db, "stack.pos", "-1");
  72                         }
  73
  74                         if(argc >= 2)
  75                         {
  76                                 rpn_sp = 0;
  77                                 rpn_error = false;
  78                                 for(rpnpos = 1; rpnpos < argc; ++rpnpos)
  79                                 {
  80                                         rpncmd = argv(rpnpos);
  81                                         f = strlen(rpncmd);
  82                                         if(rpncmd == "") {
  83                                         } else if(stof(substring(rpncmd, 0, 1)) > 0) {
  84                                                 rpn_push(rpncmd);
  85                                         } else if(substring(rpncmd, 0, 1) == "0") {
  86                                                 rpn_push(rpncmd);
  87                                         } else if(f >= 2 && substring(rpncmd, 0, 1) == "+") {
  88                                                 rpn_push(rpncmd);
  89                                         } else if(f >= 2 && substring(rpncmd, 0, 1) == "-") {
  90                                                 rpn_push(rpncmd);
  91                                         } else if(f >= 2 && substring(rpncmd, 0, 1) == "/") {
  92                                                 rpn_push(substring(rpncmd, 1, strlen(rpncmd) - 1));
  93                                         } else if(rpncmd == "clear") {
  94                                                 rpn_sp = 0;
  95                                         } else if(rpncmd == "def" || rpncmd == "=") {
  96                                                 s = rpn_pop();
  97                                                 s2 = rpn_pop();
  98
  99                                                 if(s2 != "")
 100                                                 {
 101                                                         #ifdef MENUQC
 102                                                         registercvar(s2, "", 0);
 103                                                         #else
 104                                                         registercvar(s2, "");
 105                                                         #endif
 106                                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 107                                                                 cvar_set(s2, s);
 108                                                 }
 109                                                 else
 110                                                 {
 111                                                         print("rpn: empty cvar name for 'def'\n");
 112                                                         rpn_error = true;
 113                                                 }
 114                                         } else if(rpncmd == "defs" || rpncmd == "@") {
 115                                                 s = "";
 116                                                 i = rpn_popf();
 117                                                 j = (i == 0);
 118                                                 while(rpn_sp > 1 && (j || i > 0))
 119                                                 {
 120                                                         s = strcat("/", rpn_pop(), " ", s);
 121                                                         --i;
 122                                                 }
 123                                                 s2 = rpn_pop();
 124                                                 if(s2 != "")
 125                                                 {
 126                                                         #ifdef MENUQC
 127                                                         registercvar(s2, "", 0);
 128                                                         #else
 129                                                         registercvar(s2, "");
 130                                                         #endif
 131                                                         if(!rpn_error) // don't change cvars if a stack error had happened!
 132                                                                 cvar_set(s2, s);
 133                                                 }
 134                                                 else
 135                                                 {
 136                                                         print("rpn: empty cvar name for 'defs'\n");
 137                                                         rpn_error = true;
 138                                                 }
 139                                         } else if(rpncmd == "load") {
 140                                                 rpn_set(cvar_string(rpn_get()));
 141                                         } else if(rpncmd == "exch") {
 142                                                 s = rpn_pop();
 143                                                 s2 = rpn_get();
 144                                                 rpn_set(s);
 145                                                 rpn_push(s2);
 146                                         } else if(rpncmd == "dup") {
 147                                                 rpn_push(rpn_get());
 148                                         } else if(rpncmd == "pop") {
 149                                                 rpn_pop();
 150                                         } else if(rpncmd == "add" || rpncmd == "+") {
 151                                                 f = rpn_popf();
 152                                                 rpn_setf(rpn_getf() + f);
 153                                         } else if(rpncmd == "sub" || rpncmd == "-") {
 154                                                 f = rpn_popf();
 155                                                 rpn_setf(rpn_getf() - f);
 156                                         } else if(rpncmd == "mul" || rpncmd == "*") {
 157                                                 f = rpn_popf();
 158                                                 rpn_setf(rpn_getf() * f);
 159                                         } else if(rpncmd == "div" || rpncmd == "/") {
 160                                                 f = rpn_popf();
 161                                                 rpn_setf(rpn_getf() / f);
 162                                         } else if(rpncmd == "mod" || rpncmd == "%") {
 163                                                 f = rpn_popf();
 164                                                 f2 = rpn_getf();
 165                                                 rpn_setf(f2 - f * floor(f2 / f));
 166                                         } else if(rpncmd == "pow" || rpncmd == "**") {
 167                                                 f = rpn_popf();
 168                                                 rpn_setf(pow(rpn_getf(), f));
 169                                         } else if(rpncmd == "bitand" || rpncmd == "&") {
 170                                                 f = rpn_popf();
 171                                                 rpn_setf(rpn_getf() & f);
 172                                         } else if(rpncmd == "bitor" || rpncmd == "|") {
 173                                                 f = rpn_popf();
 174                                                 rpn_setf(rpn_getf() | f);
 175                                         } else if(rpncmd == "bitxor" || rpncmd == "^") {
 176                                                 f = rpn_popf();
 177                                                 rpn_setf(rpn_getf() ^ f);
 178                                         } else if(rpncmd == "and" || rpncmd == "&&") {
 179                                                 f = rpn_popf();
 180                                                 rpn_setf(rpn_getf() && f);
 181                                         } else if(rpncmd == "or" || rpncmd == "||") {
 182                                                 f = rpn_popf();
 183                                                 rpn_setf(rpn_getf() || f);
 184                                         } else if(rpncmd == "xor" || rpncmd == "^^") {
 185                                                 f = rpn_popf();
 186                                                 rpn_setf(!rpn_getf() != !f);
 187                                         } else if(rpncmd == "bitnot") {
 188                                                 rpn_setf(~rpn_popf());
 189                                         } else if(rpncmd == "not") {
 190                                                 rpn_setf(!rpn_popf());
 191                                         } else if(rpncmd == "abs") {
 192                                                 rpn_setf(fabs(rpn_getf()));
 193                                         } else if(rpncmd == "sgn") {
 194                                                 f = rpn_getf();
 195                                                 if(f < 0)
 196                                                         rpn_set("-1");
 197                                                 else if(f > 0)
 198                                                         rpn_set("1");
 199                                                 else
 200                                                         rpn_set("0");
 201                                         } else if(rpncmd == "neg" || rpncmd == "~") {
 202                                                 rpn_setf(-rpn_getf());
 203                                         } else if(rpncmd == "floor" || rpncmd == "f") {
 204                                                 rpn_setf(floor(rpn_getf()));
 205                                         } else if(rpncmd == "ceil" || rpncmd == "c") {
 206                                                 rpn_setf(ceil(rpn_getf()));
 207                                         } else if(rpncmd == "exp") {
 208                                                 rpn_setf(exp(rpn_getf()));
 209                                         } else if(rpncmd == "log") {
 210                                                 rpn_setf(exp(rpn_getf()));
 211                                         } else if(rpncmd == "sin") {
 212                                                 rpn_setf(sin(rpn_getf()));
 213                                         } else if(rpncmd == "cos") {
 214                                                 rpn_setf(cos(rpn_getf()));
 215                                         } else if(rpncmd == "max") {
 216                                                 f = rpn_popf();
 217                                                 f2 = rpn_getf();
 218                                                 rpn_setf(max(f2, f));
 219                                         } else if(rpncmd == "min") {
 220                                                 f = rpn_popf();
 221                                                 f2 = rpn_getf();
 222                                                 rpn_setf(min(f2, f));
 223                                         } else if(rpncmd == "bound") {
 224                                                 f = rpn_popf();
 225                                                 f2 = rpn_popf();
 226                                                 f3 = rpn_getf();
 227                                                 rpn_setf(bound(f3, f2, f));
 228                                         } else if(rpncmd == "when") {
 229                                                 f = rpn_popf();
 230                                                 s = rpn_pop();
 231                                                 s2 = rpn_get();
 232                                                 if(f)
 233                                                         rpn_set(s2);
 234                                                 else
 235                                                         rpn_set(s);
 236                                         } else if(rpncmd == ">" || rpncmd == "gt") {
 237                                                 f = rpn_popf();
 238                                                 rpn_setf(rpn_getf() > f);
 239                                         } else if(rpncmd == "<" || rpncmd == "lt") {
 240                                                 f = rpn_popf();
 241                                                 rpn_setf(rpn_getf() < f);
 242                                         } else if(rpncmd == "==" || rpncmd == "eq") {
 243                                                 f = rpn_popf();
 244                                                 rpn_setf(rpn_getf() == f);
 245                                         } else if(rpncmd == ">=" || rpncmd == "ge") {
 246                                                 f = rpn_popf();
 247                                                 rpn_setf(rpn_getf() >= f);
 248                                         } else if(rpncmd == "<=" || rpncmd == "le") {
 249                                                 f = rpn_popf();
 250                                                 rpn_setf(rpn_getf() <= f);
 251                                         } else if(rpncmd == "!=" || rpncmd == "ne") {
 252                                                 f = rpn_popf();
 253                                                 rpn_setf(rpn_getf() != f);
 254                                         } else if(rpncmd == "rand") {
 255                                                 rpn_setf(ceil(random() * rpn_getf()) - 1);
 256                                         } else if(rpncmd == "crc16") {
 257                                                 rpn_setf(crc16(false, rpn_get()));
 258                                         } else if(rpncmd == "put") {
 259                                                 s2 = rpn_pop();
 260                                                 if (!rpn_error)
 261                                                 {
 262                                                         s = rpn_pop();
 263                                                         if (!rpn_error)
 264                                                                 db_put(rpn_db, s, s2);
 265                                                 }
 266                                         } else if(rpncmd == "get") {
 267                                                 s = rpn_pop();
 268                                                 if (!rpn_error)
 269                                                         rpn_push(db_get(rpn_db, s));
 270                                         } else if(rpncmd == "dbpush") {
 271                                                 s = rpn_pop();
 272                                                 if(!rpn_error)
 273                                                 {
 274                                                         i = stof(db_get(rpn_db, "stack.pointer"));
 275                                                         db_put(rpn_db, "stack.pointer", ftos(i+1));
 276                                                         db_put(rpn_db, strcat("stack.", ftos(i)), s);
 277                                                         if(!i)
 278                                                                 db_put(rpn_db, "stack.pos", "0");
 279                                                 }
 280                                         } else if(rpncmd == "dbpop") {
 281                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 282                                                 if(i)
 283                                                 {
 284                                                         s = ftos(i-1);
 285                                                         db_put(rpn_db, "stack.pointer", s);
 286                                                         rpn_push(db_get(rpn_db, strcat("stack.", s)));
 287                                                         j = stof(db_get(rpn_db, "stack.pos"));
 288                                                         if(j >= i)
 289                                                                 db_put(rpn_db, "stack.pos", ftos(i-2));
 290                                                 } else {
 291                                                         rpn_error = 1;
 292                                                         print("rpn: database underflow\n");
 293                                                 }
 294                                         } else if(rpncmd == "dbget") {
 295
 296                                                 i = stof(db_get(rpn_db, "stack.pointer"));
 297                                                 if(i)
 298                                                 {
 299                                                         rpn_push(db_get(rpn_db, strcat("stack.", ftos(i-1))));
 300                                                 } else {
 301                                                         rpn_error = 1;
 302                                                         print("rpn: database empty\n");
 303                                                 }
 304                                         } else if(rpncmd == "dblen") {
 305                                                 rpn_push(db_get(rpn_db, "stack.pointer"));
 306                                         } else if(rpncmd == "dbclr") {
 307                                                 db_close(rpn_db);
 308                                                 rpn_db = db_create();
 309                                                 db_put(rpn_db, "stack.pointer", "0");
 310                                                 db_put(rpn_db, "stack.pos", "-1");
 311                                         } else if(rpncmd == "dbsave") {
 312                                                 s = rpn_pop();
 313                                                 if(!rpn_error)
 314                                                         db_save(rpn_db, s);
 315                                         } else if(rpncmd == "dbload") {
 316                                                 s = rpn_pop();
 317                                                 if(!rpn_error)
 318                                                 {
 319                                                         db_close(rpn_db);
 320                                                         rpn_db = db_load(s);
 321                                                 }
 322                                         } else if(rpncmd == "dbins") {
 323                                                 s = rpn_pop();
 324                                                 if(!rpn_error)
 325                                                         //if(rpn_sp > 0)
 326                                                 {
 327                                                         j = stof(db_get(rpn_db, "stack.pointer"));
 328                                                         i = stof(db_get(rpn_db, "stack.pos"));
 329
 330                                                         if(i < 0)
 331                                                         {
 332                                                                 i = 0;
 333                                                                 db_put(rpn_db, "stack.pos", "0");
 334                                                         }
 335
 336                                                         db_put(rpn_db, "stack.pointer", ftos(j+1));
 337                                                         for(--j; j >= i; --j)
 338                                                         {
 339                                                                 db_put(rpn_db, strcat("stack.", ftos(j+1)),
 340                                                                                          db_get(rpn_db, (strcat("stack.", ftos(j))))
 341                                                                         );
 342                                                         }
 343                                                         db_put(rpn_db, strcat("stack.", ftos(i)), s);
 344                                                 }
 345                                         } else if(rpncmd == "dbext") {
 346                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 347                                                 i = stof(db_get(rpn_db, "stack.pos"));
 348                                                 if(!j)
 349                                                 {
 350                                                         rpn_error = true;
 351                                                         print("rpn: empty database\n");
 352                                                 } else {
 353                                                         --j;
 354                                                         rpn_push(db_get(rpn_db, strcat("stack.", ftos(i))));
 355                                                         db_put(rpn_db, "stack.pointer", ftos(j));
 356                                                         if(i == j)
 357                                                         {
 358                                                                 db_put(rpn_db, "stack.pos", ftos(j-1));
 359                                                         } else {
 360                                                                 while(i < j)
 361                                                                 {
 362                                                                         db_put(rpn_db, strcat("stack.", ftos(i)),
 363                                                                                                  db_get(rpn_db, (strcat("stack.", ftos(i+1))))
 364                                                                                 );
 365                                                                         ++i;
 366                                                                 }
 367                                                         }
 368                                                 }
 369                                         } else if(rpncmd == "dbread") {
 370                                                 s = db_get(rpn_db, "stack.pos");
 371                                                 if(stof(s) >= 0)
 372                                                 {
 373                                                         rpn_push(db_get(rpn_db, strcat("stack.", s)));
 374                                                 } else {
 375                                                         rpn_error = 1;
 376                                                         print("rpn: empty database\n");
 377                                                 }
 378                                         } else if(rpncmd == "dbat") {
 379                                                 rpn_push(db_get(rpn_db, "stack.pos"));
 380                                         } else if(rpncmd == "dbmov") {
 381                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 382                                                 i = stof(db_get(rpn_db, "stack.pos"));
 383                                                 i += rpn_popf();
 384                                                 if(!rpn_error)
 385                                                 {
 386                                                         if(i < 0 || i >= j)
 387                                                         {
 388                                                                 print("rpn: database cursor out of bounds\n");
 389                                                                 rpn_error = true;
 390                                                         }
 391                                                         if(!rpn_error)
 392                                                         {
 393                                                                 db_put(rpn_db, "stack.pos", ftos(i));
 394                                                         }
 395                                                 }
 396                                         } else if(rpncmd == "dbgoto") {
 397                                                 s = rpn_pop();
 398                                                 j = stof(db_get(rpn_db, "stack.pointer"));
 399                                                 if(!j)
 400                                                 {
 401                                                         rpn_error = true;
 402                                                         print("rpn: empty database, cannot move cursor\n");
 403                                                 }
 404                                                 if(!rpn_error)
 405                                                 {
 406                                                         if(s == "end")
 407                                                                 i = stof(db_get(rpn_db, "stack.pointer"))-1;
 408                                                         else if(s == "beg")
 409                                                                 i = 0;
 410                                                         else
 411                                                                 i = stof(s);
 412
 413                                                         j = stof(db_get(rpn_db, "stack.pointer"));
 414                                                         if(i < 0 || i >= j)
 415                                                         {
 416                                                                 print("rpn: database cursor destination out of bounds\n");
 417                                                                 rpn_error = true;
 418                                                         }
 419                                                         if(!rpn_error)
 420                                                         {
 421                                                                 db_put(rpn_db, "stack.pos", ftos(i));
 422                                                         }
 423                                                 }
 424                                         } else if(rpncmd == "union") {
 425                                                 // s s2 union
 426                                                 s2 = rpn_pop();
 427                                                 s = rpn_get();
 428                                                 f = tokenize_console(s);
 429                                                 f2 = tokenize_console(strcat(s, " ", s2));
 430                                                 // tokens 0..(f-1) represent s
 431                                                 // tokens f..f2 represent s2
 432                                                 // UNION: add all tokens to s that are in s2 but not in s
 433                                                 s = "";
 434                                                 for(i = 0; i < f; ++i)
 435                                                         s = strcat(s, " ", argv(i));
 436                                                 for(i = f; i < f2; ++i) {
 437                                                         for(j = 0; j < f; ++j)
 438                                                                 if(argv(i) == argv(j))
 439                                                                         goto skip_union;
 440                                                         s = strcat(s, " ", argv(i));
 441                                                         :skip_union
 442                                                 }
 443                                                 if(substring(s, 0, 1) == " ")
 444                                                         s = substring(s, 1, 99999);
 445                                                 rpn_set(s);
 446                                                 tokenize_console(command);
 447                                         } else if(rpncmd == "intersection") {
 448                                                 // s s2 intersection
 449                                                 s2 = rpn_pop();
 450                                                 s = rpn_get();
 451                                                 f = tokenize_console(s);
 452                                                 f2 = tokenize_console(strcat(s, " ", s2));
 453                                                 // tokens 0..(f-1) represent s
 454                                                 // tokens f..f2 represent s2
 455                                                 // INTERSECTION: keep only the tokens from s that are also in s2
 456                                                 s = "";
 457                                                 for(i = 0; i < f; ++i) {
 458                                                         for(j = f; j < f2; ++j)
 459                                                                 if(argv(i) == argv(j))
 460                                                                 {
 461                                                                         s = strcat(s, " ", argv(i));
 462                                                                         break;
 463                                                                 }
 464                                                 }
 465                                                 if(substring(s, 0, 1) == " ")
 466                                                         s = substring(s, 1, 99999);
 467                                                 rpn_set(s);
 468                                                 tokenize_console(command);
 469                                         } else if(rpncmd == "difference") {
 470                                                 // s s2 difference
 471                                                 s2 = rpn_pop();
 472                                                 s = rpn_get();
 473                                                 f = tokenize_console(s);
 474                                                 f2 = tokenize_console(strcat(s, " ", s2));
 475                                                 // tokens 0..(f-1) represent s
 476                                                 // tokens f..f2 represent s2
 477                                                 // DIFFERENCE: keep only the tokens from s that are not in s2
 478                                                 s = "";
 479                                                 for(i = 0; i < f; ++i) {
 480                                                         for(j = f; j < f2; ++j)
 481                                                                 if(argv(i) == argv(j))
 482                                                                         goto skip_difference;
 483                                                         s = strcat(s, " ", argv(i));
 484                                                         :skip_difference
 485                                                 }
 486                                                 if(substring(s, 0, 1) == " ")
 487                                                         s = substring(s, 1, 99999);
 488                                                 rpn_set(s);
 489                                                 tokenize_console(command);
 490                                         } else if(rpncmd == "shuffle") {
 491                                                 // s shuffle
 492                                                 s = rpn_get();
 493                                                 f = tokenize_console(s);
 494
 495                                                 for(i = 0; i < f - 1; ++i) {
 496                                                         // move a random item from i..f-1 to position i
 497                                                         s = "";
 498                                                         f2 = floor(random() * (f - i) + i);
 499                                                         for(j = 0; j < i; ++j)
 500                                                                 s = strcat(s, " ", argv(j));
 501                                                         s = strcat(s, " ", argv(f2));
 502                                                         for(j = i; j < f; ++j)
 503                                                                 if(j != f2)
 504                                                                         s = strcat(s, " ", argv(j));
 505                                                         f = tokenize_console(s);
 506                                                 }
 507
 508                                                 if(substring(s, 0, 1) == " ")
 509                                                         s = substring(s, 1, 99999);
 510                                                 rpn_set(s);
 511                                                 tokenize_console(command);
 512                                         } else if(rpncmd == "fexists_assert") {
 513                                                 s = rpn_pop();
 514                                                 if(!rpn_error)
 515                                                 {
 516                                                         if (!fexists(s))
 517                                                         {
 518                                                                 print("rpn: ERROR: ", s, " does not exist!\n");
 519                                                                 rpn_error = true;
 520                                                         }
 521                                                 }
 522                                         } else if(rpncmd == "fexists") {
 523                                                 s = rpn_get();
 524                                                 if(!rpn_error)
 525                                                 {
 526                                                         if (fexists(s))
 527                                                                 rpn_setf(1);
 528                                                         else
 529                                                                 rpn_setf(0);
 530                                                 }
 531                                         } else if(rpncmd == "localtime") {
 532                                                 rpn_set(strftime(true, rpn_get()));
 533                                         } else if(rpncmd == "gmtime") {
 534                                                 rpn_set(strftime(false, rpn_get()));
 535                                         } else if(rpncmd == "time") {
 536                                                 rpn_pushf(time);
 537                                         } else if(rpncmd == "digest") {
 538                                                 s = rpn_pop();
 539                                                 rpn_set(digest_hex(s, rpn_get()));
 540                                         } else if(rpncmd == "sprintf1s") {
 541                                                 s = rpn_pop();
 542                                                 rpn_set(sprintf(s, rpn_get()));
 543                                         } else if(rpncmd == "eval") {
 544                                                 s = rpn_pop();
 545                                                 command = strcat(s, substring(command, argv_end_index(rpnpos), -1));
 546                                                 argc = tokenize_console(command);
 547                                                 rpnpos = -1;
 548                                         } else {
 549                                                 rpn_push(cvar_string(rpncmd));
 550                                         }
 551                                         if(rpn_error)
 552                                                 break;
 553                                 }
 554                                 while(rpn_sp > 0)
 555                                 {
 556                                         s = rpn_pop();
 557                                         print("rpn: still on stack: ", s, "\n");
 558                                 }
 559                         }
 560
 561                         return;
 562                 }
 563
 564                 default:
 565                 case CMD_REQUEST_USAGE:
 566                 {
 567                         print(strcat("\nUsage:^3 ", GetProgramCommandPrefix(), " rpn EXPRESSION...\n"));
 568                         print("    Operator description (x: string, s: set, f: float):\n");
 569                         print("    x pop ----------------------------->     : removes the top\n");
 570                         print("    x dup -----------------------------> x x : duplicates the top\n");
 571                         print("    x x exch --------------------------> x x : swap the top two\n");
 572                         print("    /cvarname load --------------------> x   : loads a cvar\n");
 573                         print("    /cvarname x def ------------------->     : writes to a cvar\n");
 574                         print("    f f add|sub|mul|div|mod|pow -------> f   : adds/... two numbers\n");
 575                         print("    f f and|or|xor|bitand|bitor|bitxor > f   : logical and bitwise operations\n");
 576                         print("    f f eq|ne|gt|ge|lt|le|max|min -----> f   : compares two numbers\n");
 577                         print("    f neg|abs|sgn|rand|floor|ceil------> f   : negates/... a number\n");
 578                         print("    f not|bitnot ----------------------> f   : logical and bitwise negation\n");
 579                         print("    f exp|log|sin|cos -----------------> f   : exponential function & Co.\n");
 580                         print("    f f f bound -----------------------> f   : bounds the middle number\n");
 581                         print("    f1 f2 b when ----------------------> f   : f1 if b, f2 otherwise\n");
 582                         print("    s s union|intersection|difference -> s   : set operations\n");
 583                         print("    s shuffle -------------------------> s   : randomly arrange elements\n");
 584                         print("    /key /value put ------------------->     : set a database key\n");
 585                         print("    /key get --------------------------> s   : get a database value\n");
 586                         print("    x dbpush -------------------------->     : pushes the top onto the database\n");
 587                         print("    dbpop|dbget -----------------------> x   : removes/reads DB's top\n");
 588                         print("    dblen|dbat ------------------------> f   : gets the DB's size/cursor pos\n");
 589                         print("    dbclr ----------------------------->     : clear the DB\n");
 590                         print("    s dbsave|dbload-------------------->     : save/load the DB to/from a file\n");
 591                         print("    x dbins --------------------------->     : moves the top into the DB\n");
 592                         print("    dbext|dbread ----------------------> x   : extract/get from the DB's cursor\n");
 593                         print("    f dbmov|dbgoto -------------------->     : move or set the DB's cursor\n");
 594                         print("    s localtime -----------------------> s   : formats the current local time\n");
 595                         print("    s gmtime --------------------------> s   : formats the current UTC time\n");
 596                         print("    time ------------------------------> f   : seconds since VM start\n");
 597                         print("    s /MD4 digest ---------------------> s   : MD4 digest\n");
 598                         print("    s /SHA256 digest ------------------> s   : SHA256 digest\n");
 599                         print("    s /formatstring sprintf1s ---------> s   : sprintf with 1 string (pad, cut)\n");
 600                         print("    s eval ---------------------------->     : does something eval\n");
 601                         print("    Set operations operate on 'such''strings'.\n");
 602                         print("    Unknown tokens insert their cvar value.\n");
 603                         return;
 604                 }
 605         }
 606 }