Don't send casings data if client has casings turned off. Toggling cl_casings on...
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / effects / qc / casings.qc
1 #include "casings.qh"
2
3 #include <common/util.qh>
4
5 #ifdef CSQC
6 #include <common/physics/movetypes/movetypes.qh>
7 #include "rubble.qh"
8 #endif
9
10 REGISTER_NET_TEMP(casings)
11
12 #ifdef SVQC
13
14 .bool cvar_cl_casings;
15 REPLICATE(cvar_cl_casings, bool, "cl_casings");
16
17 void SpawnCasing(vector vel, float randomvel, vector ang, vector avel, float randomavel, int casingtype, entity casingowner, .entity weaponentity)
18 {
19         if (!(CS(casingowner).cvar_cl_casings))
20                 return;
21
22     entity wep = casingowner.(weaponentity);
23     vector org = casingowner.origin + casingowner.view_ofs + wep.spawnorigin.x * v_forward - wep.spawnorigin.y * v_right + wep.spawnorigin.z * v_up;
24
25     if (!sound_allowed(MSG_BROADCAST, casingowner))
26         casingtype |= 0x80;
27
28     WriteHeader(MSG_ALL, casings);
29     WriteByte(MSG_ALL, casingtype);
30     WriteVector(MSG_ALL, org);
31     WriteShort(MSG_ALL, compressShortVector(vel)); // actually compressed velocity
32     WriteByte(MSG_ALL, ang.x * 256 / 360);
33     WriteByte(MSG_ALL, ang.y * 256 / 360);
34     WriteByte(MSG_ALL, ang.z * 256 / 360);
35 }
36 #endif
37
38 #ifdef CSQC
39 entityclass(Casing);
40 classfield(Casing) .float alpha;
41 classfield(Casing) .bool silent;
42 classfield(Casing) .int state;
43 classfield(Casing) .float cnt;
44
45 void Casing_Delete(entity this)
46 {
47     delete(this);
48 }
49
50 void Casing_Draw(entity this)
51 {
52     if (IS_ONGROUND(this))
53     {
54         this.angles_x = 0;
55         this.angles_z = 0;
56         //UNSET_ONGROUND(this);
57     }
58
59     Movetype_Physics_MatchTicrate(this, autocvar_cl_casings_ticrate, autocvar_cl_casings_sloppy);
60     if (wasfreed(this))
61         return; // deleted by touch function
62
63     this.renderflags = 0;
64     this.alpha = bound(0, this.cnt - time, 1);
65
66     if (this.alpha < ALPHA_MIN_VISIBLE)
67     {
68         Casing_Delete(this);
69         this.drawmask = 0;
70     }
71 }
72
73 SOUND(BRASS1, W_Sound("brass1"));
74 SOUND(BRASS2, W_Sound("brass2"));
75 SOUND(BRASS3, W_Sound("brass3"));
76 Sound SND_BRASS_RANDOM() {
77     return Sounds_from(SND_BRASS1.m_id + floor(prandom() * 3));
78 }
79 SOUND(CASINGS1, W_Sound("casings1"));
80 SOUND(CASINGS2, W_Sound("casings2"));
81 SOUND(CASINGS3, W_Sound("casings3"));
82 Sound SND_CASINGS_RANDOM() {
83     return Sounds_from(SND_CASINGS1.m_id + floor(prandom() * 3));
84 }
85
86 void Casing_Touch(entity this, entity toucher)
87 {
88     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
89     {
90         Casing_Delete(this);
91         return;
92     }
93
94     if (!this.silent)
95     if (!trace_ent || trace_ent.solid == SOLID_BSP)
96     {
97         if(vdist(this.velocity, >, 50))
98         {
99             if (time >= this.nextthink)
100             {
101                 Sound s;
102                 switch (this.state)
103                 {
104                     case 1:
105                         s = SND_CASINGS_RANDOM();
106                         break;
107                     default:
108                         s = SND_BRASS_RANDOM();
109                         break;
110                 }
111
112                 sound (this, CH_SHOTS, s, VOL_BASE, ATTEN_LARGE);
113             }
114         }
115     }
116
117     this.nextthink = time + 0.2;
118 }
119
120 void Casing_Damage(entity this, float thisdmg, int hittype, vector org, vector thisforce)
121 {
122     if (thisforce.z < 0)
123         thisforce.z = 0;
124     this.velocity = this.velocity + thisforce + '0 0 100';
125     UNSET_ONGROUND(this);
126 }
127
128 NET_HANDLE(casings, bool isNew)
129 {
130     int _state = ReadByte();
131     vector org = ReadVector();
132     vector vel = decompressShortVector(ReadShort());
133     vector ang;
134     ang_x = ReadByte() * 360 / 256;
135     ang_y = ReadByte() * 360 / 256;
136     ang_z = ReadByte() * 360 / 256;
137     return = true;
138
139     if (!autocvar_cl_casings) return;
140
141     Casing casing = RubbleNew("casing");
142     casing.silent = (_state & 0x80);
143     casing.state = (_state & 0x7F);
144     casing.origin = org;
145     setorigin(casing, casing.origin);
146     casing.velocity = vel;
147     casing.angles = ang;
148     casing.drawmask = MASK_NORMAL;
149
150     casing.draw = Casing_Draw;
151     if (isNew) IL_PUSH(g_drawables, casing);
152     casing.velocity = casing.velocity + 2 * prandomvec();
153     casing.avelocity = '0 250 0' + 100 * prandomvec();
154     set_movetype(casing, MOVETYPE_BOUNCE);
155     settouch(casing, Casing_Touch);
156     casing.move_time = time;
157     casing.event_damage = Casing_Damage;
158     casing.solid = SOLID_TRIGGER;
159
160     switch (casing.state)
161     {
162         case 1:
163             setmodel(casing, MDL_CASING_SHELL);
164             casing.cnt = time + autocvar_cl_casings_shell_time;
165             break;
166         default:
167             setmodel(casing, MDL_CASING_BULLET);
168             casing.cnt = time + autocvar_cl_casings_bronze_time;
169             break;
170     }
171
172     setsize(casing, '0 0 -1', '0 0 -1');
173
174     RubbleLimit("casing", autocvar_cl_casings_maxcount, Casing_Delete);
175 }
176
177 #endif