qcsrc/common/effects/qc/casings.qc

   1 #include "casings.qh"
   2
   3 #include <common/util.qh>
   4
   5 #ifdef CSQC
   6 #include <common/physics/movetypes/movetypes.qh>
   7 #include "rubble.qh"
   8 #endif
   9
  10 REGISTER_NET_TEMP(casings)
  11
  12 #ifdef SVQC
  13 void SpawnCasing(vector vel, float randomvel, vector ang, vector avel, float randomavel, int casingtype, entity casingowner, .entity weaponentity)
  14 {
  15     entity wep = casingowner.(weaponentity);
  16     vector org = casingowner.origin + casingowner.view_ofs + wep.spawnorigin.x * v_forward - wep.spawnorigin.y * v_right + wep.spawnorigin.z * v_up;
  17
  18     if (!sound_allowed(MSG_BROADCAST, casingowner))
  19         casingtype |= 0x80;
  20
  21     WriteHeader(MSG_ALL, casings);
  22     WriteByte(MSG_ALL, casingtype);
  23     WriteVector(MSG_ALL, org);
  24     WriteShort(MSG_ALL, compressShortVector(vel)); // actually compressed velocity
  25     WriteByte(MSG_ALL, ang.x * 256 / 360);
  26     WriteByte(MSG_ALL, ang.y * 256 / 360);
  27     WriteByte(MSG_ALL, ang.z * 256 / 360);
  28 }
  29 #endif
  30
  31 #ifdef CSQC
  32 entityclass(Casing);
  33 classfield(Casing) .float alpha;
  34 classfield(Casing) .bool silent;
  35 classfield(Casing) .int state;
  36 classfield(Casing) .float cnt;
  37
  38 void Casing_Delete(entity this)
  39 {
  40     delete(this);
  41 }
  42
  43 void Casing_Draw(entity this)
  44 {
  45     if (IS_ONGROUND(this))
  46     {
  47         this.angles_x = 0;
  48         this.angles_z = 0;
  49         //UNSET_ONGROUND(this);
  50     }
  51
  52     Movetype_Physics_MatchTicrate(this, autocvar_cl_casings_ticrate, autocvar_cl_casings_sloppy);
  53     if (wasfreed(this))
  54         return; // deleted by touch function
  55
  56     this.renderflags = 0;
  57     this.alpha = bound(0, this.cnt - time, 1);
  58
  59     if (this.alpha < ALPHA_MIN_VISIBLE)
  60     {
  61         Casing_Delete(this);
  62         this.drawmask = 0;
  63     }
  64 }
  65
  66 SOUND(BRASS1, W_Sound("brass1"));
  67 SOUND(BRASS2, W_Sound("brass2"));
  68 SOUND(BRASS3, W_Sound("brass3"));
  69 Sound SND_BRASS_RANDOM() {
  70     return Sounds_from(SND_BRASS1.m_id + floor(prandom() * 3));
  71 }
  72 SOUND(CASINGS1, W_Sound("casings1"));
  73 SOUND(CASINGS2, W_Sound("casings2"));
  74 SOUND(CASINGS3, W_Sound("casings3"));
  75 Sound SND_CASINGS_RANDOM() {
  76     return Sounds_from(SND_CASINGS1.m_id + floor(prandom() * 3));
  77 }
  78
  79 void Casing_Touch(entity this, entity toucher)
  80 {
  81     if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT)
  82     {
  83         Casing_Delete(this);
  84         return;
  85     }
  86
  87     if (!this.silent)
  88     if (!trace_ent || trace_ent.solid == SOLID_BSP)
  89     {
  90         if(vdist(this.velocity, >, 50))
  91         {
  92             if (time >= this.nextthink)
  93             {
  94                 Sound s;
  95                 switch (this.state)
  96                 {
  97                     case 1:
  98                         s = SND_CASINGS_RANDOM();
  99                         break;
 100                     default:
 101                         s = SND_BRASS_RANDOM();
 102                         break;
 103                 }
 104
 105                 sound (this, CH_SHOTS, s, VOL_BASE, ATTEN_LARGE);
 106             }
 107         }
 108     }
 109
 110     this.nextthink = time + 0.2;
 111 }
 112
 113 void Casing_Damage(entity this, float thisdmg, int hittype, vector org, vector thisforce)
 114 {
 115     if (thisforce.z < 0)
 116         thisforce.z = 0;
 117     this.velocity = this.velocity + thisforce + '0 0 100';
 118     UNSET_ONGROUND(this);
 119 }
 120
 121 NET_HANDLE(casings, bool isNew)
 122 {
 123     int _state = ReadByte();
 124     vector org = ReadVector();
 125     vector vel = decompressShortVector(ReadShort());
 126     vector ang;
 127     ang_x = ReadByte() * 360 / 256;
 128     ang_y = ReadByte() * 360 / 256;
 129     ang_z = ReadByte() * 360 / 256;
 130     return = true;
 131
 132     if (!autocvar_cl_casings) return;
 133
 134     Casing casing = RubbleNew("casing");
 135     casing.silent = (_state & 0x80);
 136     casing.state = (_state & 0x7F);
 137     casing.origin = org;
 138     setorigin(casing, casing.origin);
 139     casing.velocity = vel;
 140     casing.angles = ang;
 141     casing.drawmask = MASK_NORMAL;
 142
 143     casing.draw = Casing_Draw;
 144     if (isNew) IL_PUSH(g_drawables, casing);
 145     casing.velocity = casing.velocity + 2 * prandomvec();
 146     casing.avelocity = '0 250 0' + 100 * prandomvec();
 147     set_movetype(casing, MOVETYPE_BOUNCE);
 148     settouch(casing, Casing_Touch);
 149     casing.move_time = time;
 150     casing.event_damage = Casing_Damage;
 151     casing.solid = SOLID_TRIGGER;
 152
 153     switch (casing.state)
 154     {
 155         case 1:
 156             setmodel(casing, MDL_CASING_SHELL);
 157             casing.cnt = time + autocvar_cl_casings_shell_time;
 158             break;
 159         default:
 160             setmodel(casing, MDL_CASING_BULLET);
 161             casing.cnt = time + autocvar_cl_casings_bronze_time;
 162             break;
 163     }
 164
 165     setsize(casing, '0 0 -1', '0 0 -1');
 166
 167     RubbleLimit("casing", autocvar_cl_casings_maxcount, Casing_Delete);
 168 }
 169
 170 #endif