qcsrc/common/effects/qc/damageeffects.qc

   1 #include "damageeffects.qh"
   2
   3 REGISTER_NET_LINKED(ENT_CLIENT_DAMAGEINFO)
   4
   5 #ifdef SVQC
   6
   7 bool Damage_DamageInfo_SendEntity(entity this, entity to, int sf)
   8 {
   9         vector org = vec3(floor(this.origin.x), floor(this.origin.y), floor(this.origin.z));
  10         WriteHeader(MSG_ENTITY, ENT_CLIENT_DAMAGEINFO);
  11         WriteShort(MSG_ENTITY, this.projectiledeathtype);
  12         WriteVector(MSG_ENTITY, org);
  13         WriteByte(MSG_ENTITY, bound(1, this.dmg, 255));
  14         WriteByte(MSG_ENTITY, bound(0, this.dmg_radius, 255));
  15         WriteByte(MSG_ENTITY, bound(1, this.dmg_edge, 255));
  16         WriteShort(MSG_ENTITY, this.oldorigin.x);
  17         WriteByte(MSG_ENTITY, this.species);
  18         return true;
  19 }
  20
  21 void Damage_DamageInfo(vector org, float coredamage, float edgedamage, float rad, vector force, int deathtype, float bloodtype, entity dmgowner)
  22 {
  23         // TODO maybe call this from non-edgedamage too?
  24         // TODO maybe make the client do the particle effects for the weapons and the impact sounds using this info?
  25
  26         entity e;
  27
  28         if(!sound_allowed(MSG_BROADCAST, dmgowner))
  29                 deathtype |= 0x8000;
  30
  31         e = new(damageinfo);
  32         setorigin(e, org);
  33         e.projectiledeathtype = deathtype;
  34         e.dmg = coredamage;
  35         e.dmg_edge = edgedamage;
  36         e.dmg_radius = rad;
  37         e.dmg_force = vlen(force);
  38         e.velocity = force;
  39         e.oldorigin_x = compressShortVector(e.velocity);
  40         e.species = bloodtype;
  41
  42         Net_LinkEntity(e, false, 0.2, Damage_DamageInfo_SendEntity);
  43 }
  44
  45 #endif
  46
  47 #ifdef CSQC
  48
  49 /** number of effects which currently are attached to a player */
  50 .int total_damages;
  51
  52 .entity tag_entity;
  53
  54 .float cnt;
  55 .int state;
  56
  57 void DamageEffect_Think(entity this)
  58 {
  59         // if particle distribution is enabled, slow ticrate by total number of damages
  60         if(autocvar_cl_damageeffect_distribute)
  61                 this.nextthink = time + autocvar_cl_damageeffect_ticrate * this.owner.total_damages;
  62         else
  63                 this.nextthink = time + autocvar_cl_damageeffect_ticrate;
  64
  65         if(time >= this.cnt || !this.owner || !this.owner.modelindex || !this.owner.drawmask)
  66         {
  67                 // time is up or the player got gibbed / disconnected
  68                 this.owner.total_damages = max(0, this.owner.total_damages - 1);
  69                 delete(this);
  70                 return;
  71         }
  72         if(this.state && !this.owner.csqcmodel_isdead)
  73         {
  74                 // if the player was dead but is now alive, it means he respawned
  75                 // if so, clear his damage effects, or damages from his dead body will be copied back
  76                 this.owner.total_damages = max(0, this.owner.total_damages - 1);
  77                 delete(this);
  78                 return;
  79         }
  80         this.state = this.owner.csqcmodel_isdead;
  81         if((this.owner.isplayermodel & ISPLAYER_LOCAL) && !autocvar_chase_active)
  82                 return; // if we aren't using a third person camera, hide our own effects
  83
  84         // now generate the particles
  85         vector org = gettaginfo(this, 0); // origin at attached location
  86         __pointparticles(this.team, org, '0 0 0', 1);
  87 }
  88
  89 string species_prefix(int specnum)
  90 {
  91         switch(specnum)
  92         {
  93                 case SPECIES_HUMAN:       return "";
  94                 case SPECIES_ALIEN:       return "alien_";
  95                 case SPECIES_ROBOT_SHINY: return "robot_";
  96                 case SPECIES_ROBOT_RUSTY: return "robot_"; // use the same effects, only different gibs
  97                 case SPECIES_ROBOT_SOLID: return "robot_"; // use the same effects, only different gibs
  98                 case SPECIES_ANIMAL:      return "animal_";
  99                 case SPECIES_RESERVED:    return "reserved_";
 100                 default:         return "";
 101         }
 102 }
 103
 104 void DamageEffect(entity this, vector hitorg, float thedamage, int type, int specnum)
 105 {
 106         // particle effects for players and objects damaged by weapons (eg: flames coming out of victims shot with rockets)
 107
 108         int nearestbone = 0;
 109         float life;
 110         string effectname;
 111         entity e;
 112
 113         if(!autocvar_cl_damageeffect || autocvar_cl_gentle || autocvar_cl_gentle_damage)
 114                 return;
 115         if(!this || !this.modelindex || !this.drawmask)
 116                 return;
 117
 118         // if this is a rigged mesh, the effect will show on the bone where damage was dealt
 119         // we do this by choosing the skeletal bone closest to the impact, and attaching our entity to it
 120         // if there's no skeleton, object origin will automatically be selected
 121         FOR_EACH_TAG(this)
 122         {
 123                 if(!tagnum)
 124                         continue; // skip empty bones
 125                 // blacklist bones positioned outside the mesh, or the effect will be floating
 126                 // TODO: Do we have to do it this way? Why do these bones exist at all?
 127                 if(gettaginfo_name == "master" || gettaginfo_name == "knee_L" || gettaginfo_name == "knee_R" || gettaginfo_name == "leg_L" || gettaginfo_name == "leg_R")
 128                         continue; // player model bone blacklist
 129
 130                 // now choose the bone closest to impact origin
 131                 if(nearestbone == 0 || vlen2(hitorg - gettaginfo(this, tagnum)) <= vlen2(hitorg - gettaginfo(this, nearestbone)))
 132                         nearestbone = tagnum;
 133         }
 134         gettaginfo(this, nearestbone); // set gettaginfo_name
 135
 136         // return if we reached our damage effect limit or damages are disabled
 137         // TODO: When the limit is reached, it would be better if the oldest damage was removed instead of not adding a new one
 138         if(nearestbone)
 139         {
 140                 if(this.total_damages >= autocvar_cl_damageeffect_bones)
 141                         return; // allow multiple damages on skeletal models
 142         }
 143         else
 144         {
 145                 if(autocvar_cl_damageeffect < 2 || this.total_damages)
 146                         return; // allow a single damage on non-skeletal models
 147         }
 148
 149         life = bound(autocvar_cl_damageeffect_lifetime_min, thedamage * autocvar_cl_damageeffect_lifetime, autocvar_cl_damageeffect_lifetime_max);
 150
 151         effectname = strcat("damage_", DEATH_WEAPONOF(type).netname);
 152         if(DEATH_WEAPONOF(type) == WEP_SHOTGUN || DEATH_WEAPONOF(type) == WEP_MACHINEGUN)
 153         {
 154                 if((this.isplayermodel & ISPLAYER_MODEL))
 155                 {
 156                         string specstr = species_prefix(specnum);
 157                         effectname = strcat(specstr, effectname);
 158                 }
 159                 else { return; } // objects don't bleed
 160         }
 161
 162         e = new(damage);
 163         setmodel(e, MDL_Null); // necessary to attach and read origin
 164         setattachment(e, this, gettaginfo_name); // attach to the given bone
 165         e.owner = this;
 166         e.cnt = time + life;
 167         e.team = _particleeffectnum(effectname);
 168         setthink(e, DamageEffect_Think);
 169         e.nextthink = time;
 170         this.total_damages += 1;
 171 }
 172
 173 NET_HANDLE(ENT_CLIENT_DAMAGEINFO, bool isNew)
 174 {
 175         const float ATTEN_LOW = 0.2;
 176         float thedamage, rad, edge, thisdmg;
 177         bool hitplayer = false;
 178         int species, forcemul;
 179         vector force, thisforce;
 180
 181         w_deathtype = ReadShort();
 182         w_issilent = (w_deathtype & 0x8000);
 183         w_deathtype = (w_deathtype & 0x7FFF);
 184
 185         w_org = ReadVector();
 186
 187         thedamage = ReadByte();
 188         rad = ReadByte();
 189         edge = ReadByte();
 190         force = decompressShortVector(ReadShort());
 191         species = ReadByte();
 192
 193         return = true;
 194
 195         if (!isNew)
 196                 return;
 197
 198         if(rad < 0)
 199         {
 200                 rad = -rad;
 201                 forcemul = -1;
 202         }
 203         else
 204                 forcemul = 1;
 205
 206     FOREACH_ENTITY_RADIUS(w_org, rad + MAX_DAMAGEEXTRARADIUS, !it.tag_entity, {
 207                 vector nearest = NearestPointOnBox(it, w_org);
 208                 if (rad)
 209                 {
 210                         thisdmg = ((vlen (nearest - w_org) - bound(MIN_DAMAGEEXTRARADIUS, it.damageextraradius, MAX_DAMAGEEXTRARADIUS)) / rad);
 211                         if(thisdmg >= 1)
 212                                 continue;
 213                         if(thisdmg < 0)
 214                                 thisdmg = 0;
 215                         if(thedamage)
 216                         {
 217                                 thisdmg = thedamage + (edge - thedamage) * thisdmg;
 218                                 thisforce = forcemul * vlen(force) * (thisdmg / thedamage) * normalize(it.origin - w_org);
 219                         }
 220                         else
 221                         {
 222                                 thisdmg = 0;
 223                                 thisforce = forcemul * vlen(force) * normalize(it.origin - w_org);
 224                         }
 225                 }
 226                 else
 227                 {
 228                         if(vdist((nearest - w_org), >, bound(MIN_DAMAGEEXTRARADIUS, it.damageextraradius, MAX_DAMAGEEXTRARADIUS)))
 229                                 continue;
 230
 231                         thisdmg = thedamage;
 232                         thisforce = forcemul * force;
 233                 }
 234
 235                 if(it.damageforcescale)
 236                         if(vdist(thisforce, !=, 0))
 237                         {
 238                                 it.velocity = it.velocity + damage_explosion_calcpush(it.damageforcescale * thisforce, it.velocity, damagepush_speedfactor);
 239                                 UNSET_ONGROUND(it);
 240                         }
 241
 242                 if(w_issilent)
 243                         it.silent = 1;
 244
 245                 if(it.event_damage)
 246                         it.event_damage(it, thisdmg, w_deathtype, w_org, thisforce);
 247
 248                 DamageEffect(it, w_org, thisdmg, w_deathtype, species);
 249
 250                 if((it.isplayermodel & ISPLAYER_MODEL))
 251                         hitplayer = true; // this impact damaged a player
 252         });
 253
 254         if(DEATH_ISVEHICLE(w_deathtype))
 255         {
 256                 traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, NULL);
 257                 if(trace_plane_normal != '0 0 0')
 258                         w_backoff = trace_plane_normal;
 259                 else
 260                         w_backoff = -1 * normalize(w_org - (w_org + normalize(force) * 16));
 261
 262                 setorigin(this, w_org + w_backoff * 2); // for sound() calls
 263
 264                 switch(DEATH_ENT(w_deathtype))
 265                 {
 266                         case DEATH_VH_CRUSH:
 267                                 break;
 268
 269                         // spiderbot
 270                         case DEATH_VH_SPID_MINIGUN:
 271                                 sound(this, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 272                                 pointparticles(EFFECT_SPIDERBOT_MINIGUN_IMPACT, this.origin, w_backoff * 1000, 1);
 273                                 break;
 274                         case DEATH_VH_SPID_ROCKET:
 275                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 276                                 pointparticles(EFFECT_SPIDERBOT_ROCKET_EXPLODE, this.origin, w_backoff * 1000, 1);
 277                                 break;
 278                         case DEATH_VH_SPID_DEATH:
 279                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_LOW);
 280                                 pointparticles(EFFECT_EXPLOSION_BIG, this.origin, w_backoff * 1000, 1);
 281                                 break;
 282
 283                         case DEATH_VH_WAKI_GUN:
 284                                 sound(this, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTEN_NORM);
 285                                 pointparticles(EFFECT_RACER_IMPACT, this.origin, w_backoff * 1000, 1);
 286                                 break;
 287                         case DEATH_VH_WAKI_ROCKET:
 288                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 289                                 pointparticles(EFFECT_RACER_ROCKET_EXPLODE, this.origin, w_backoff * 1000, 1);
 290                                 break;
 291                         case DEATH_VH_WAKI_DEATH:
 292                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_LOW);
 293                                 pointparticles(EFFECT_EXPLOSION_BIG, this.origin, w_backoff * 1000, 1);
 294                                 break;
 295
 296                         case DEATH_VH_RAPT_CANNON:
 297                                 sound(this, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTEN_NORM);
 298                                 pointparticles(EFFECT_RAPTOR_CANNON_IMPACT, this.origin, w_backoff * 1000, 1);
 299                                 break;
 300                         case DEATH_VH_RAPT_FRAGMENT:
 301                                 float i;
 302                                 vector ang, vel;
 303                                 for(i = 1; i < 4; ++i)
 304                                 {
 305                                         vel = normalize(w_org - (w_org + normalize(force) * 16)) + randomvec() * 128;
 306                                         ang = vectoangles(vel);
 307                                         RaptorCBShellfragToss(w_org, vel, ang + '0 0 1' * (120 * i));
 308                                 }
 309                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 310                                 pointparticles(EFFECT_RAPTOR_BOMB_SPREAD, this.origin, w_backoff * 1000, 1);
 311                                 break;
 312                         case DEATH_VH_RAPT_BOMB:
 313                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 314                                 pointparticles(EFFECT_RAPTOR_BOMB_IMPACT, this.origin, w_backoff * 1000, 1);
 315                                 break;
 316                         case DEATH_VH_RAPT_DEATH:
 317                                 sound(this, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTEN_LOW);
 318                                 pointparticles(EFFECT_EXPLOSION_BIG, this.origin, w_backoff * 1000, 1);
 319                                 break;
 320                         case DEATH_VH_BUMB_GUN:
 321                                 sound(this, CH_SHOTS, SND_FIREBALL_IMPACT2, VOL_BASE, ATTEN_NORM);
 322                                 pointparticles(EFFECT_BIGPLASMA_IMPACT, this.origin, w_backoff * 1000, 1);
 323                                 break;
 324                 }
 325         }
 326
 327
 328         if(DEATH_ISTURRET(w_deathtype))
 329         {
 330                 traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, NULL);
 331                 if(trace_plane_normal != '0 0 0')
 332                         w_backoff = trace_plane_normal;
 333                 else
 334                         w_backoff = -1 * normalize(w_org - (w_org + normalize(force) * 16));
 335
 336                 setorigin(this, w_org + w_backoff * 2); // for sound() calls
 337
 338                 switch(DEATH_ENT(w_deathtype))
 339                 {
 340                          case DEATH_TURRET_EWHEEL:
 341                                 sound(this, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTEN_LOW);
 342                                 pointparticles(EFFECT_BLASTER_IMPACT, this.origin, w_backoff * 1000, 1);
 343                                 break;
 344
 345                          case DEATH_TURRET_FLAC:
 346                                 pointparticles(EFFECT_HAGAR_EXPLODE, w_org, '0 0 0', 1);
 347                                 sound(this, CH_SHOTS, SND_HAGEXP_RANDOM(), VOL_BASE, ATTEN_NORM);
 348                                 break;
 349
 350                          case DEATH_TURRET_MLRS:
 351                          case DEATH_TURRET_HK:
 352                          case DEATH_TURRET_WALK_ROCKET:
 353                          case DEATH_TURRET_HELLION:
 354                                 sound(this, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_LOW);
 355                                 pointparticles(EFFECT_ROCKET_EXPLODE, this.origin, w_backoff * 1000, 1);
 356                                 break;
 357
 358                          case DEATH_TURRET_MACHINEGUN:
 359                          case DEATH_TURRET_WALK_GUN:
 360                                 sound(this, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_NORM);
 361                                 pointparticles(EFFECT_MACHINEGUN_IMPACT, this.origin, w_backoff * 1000, 1);
 362                                 break;
 363
 364                          case DEATH_TURRET_PLASMA:
 365                                 sound(this, CH_SHOTS, SND_ELECTRO_IMPACT, VOL_BASE, ATTEN_LOW);
 366                                 pointparticles(EFFECT_ELECTRO_IMPACT, this.origin, w_backoff * 1000, 1);
 367                                 break;
 368
 369                          case DEATH_TURRET_WALK_MELEE:
 370                                 sound(this, CH_SHOTS, SND_RIC_RANDOM(), VOL_BASE, ATTEN_LOW);
 371                                 pointparticles(EFFECT_TE_SPARK, this.origin, w_backoff * 1000, 1);
 372                                 break;
 373
 374                          case DEATH_TURRET_PHASER:
 375                                 break;
 376
 377                          case DEATH_TURRET_TESLA:
 378                                 te_smallflash(this.origin);
 379                                 break;
 380
 381                 }
 382         }
 383
 384         MUTATOR_CALLHOOK(DamageInfo, this, w_deathtype, w_org);
 385
 386         // TODO spawn particle effects and sounds based on w_deathtype
 387         if(!DEATH_ISSPECIAL(w_deathtype))
 388         if(!hitplayer || rad) // don't show ground impacts for hitscan weapons if a player was hit
 389         {
 390                 Weapon hitwep = DEATH_WEAPONOF(w_deathtype);
 391                 w_random = prandom();
 392
 393                 traceline(w_org - normalize(force) * 16, w_org + normalize(force) * 16, MOVE_NOMONSTERS, NULL);
 394                 if(trace_fraction < 1 && hitwep != WEP_VORTEX && hitwep != WEP_VAPORIZER)
 395                         w_backoff = trace_plane_normal;
 396                 else
 397                         w_backoff = -1 * normalize(force);
 398                 setorigin(this, w_org + w_backoff * 2); // for sound() calls
 399
 400                 if(!(trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY))
 401                 {
 402                         if(!MUTATOR_CALLHOOK(Weapon_ImpactEffect, hitwep, this))
 403                                 hitwep.wr_impacteffect(hitwep, this);
 404                 }
 405         }
 406 }
 407
 408 #endif