c0a44b111477e1d688d486b15dd6836cc70a8827
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / ent_cs.qc
1 #include "ent_cs.qh"
2 #include <common/gamemodes/_mod.qh>
3 #include <common/resources.qh>
4 #ifdef SVQC
5 #include <server/resources.qh>
6 #endif
7
8 REGISTRY(EntCSProps, BITS(16) - 1)
9 #define EntCSProps_from(i) _EntCSProps_from(i, NULL)
10 REGISTER_REGISTRY(EntCSProps)
11 REGISTRY_SORT(EntCSProps)
12 REGISTRY_CHECK(EntCSProps)
13 STATIC_INIT(EntCSProps_renumber) { FOREACH(EntCSProps, true, it.m_id = i); }
14
15 // these entcs_props ids need to be referenced directly
16 int ENTCS_PROP_ENTNUM_id = 0;
17 int ENTCS_PROP_ORIGIN_id = 0;
18 STATIC_INIT(EntCSProps_setglobalids)
19 {
20         FOREACH(EntCSProps, true, {
21                 if (it.registered_id == "ENTCS_PROP_ENTNUM")
22                         ENTCS_PROP_ENTNUM_id = it.m_id;
23                 if (it.registered_id == "ENTCS_PROP_ORIGIN")
24                         ENTCS_PROP_ORIGIN_id = it.m_id;
25         });
26 }
27
28 #ifdef SVQC
29 // Force an origin update, for player sounds
30 void entcs_force_origin(entity player)
31 {
32         CS(player).entcs.m_forceupdate = BIT(ENTCS_PROP_ORIGIN_id);
33 }
34 #endif
35
36 .bool m_public;
37 .bool(entity ent, entity player) m_check;
38 .void(entity ent, entity player) m_set;
39 .void(int chan, entity ent) m_send;
40 .void(entity ent) m_receive;
41
42 #ifdef SVQC
43 #define _ENTCS_PROP(id, ispublic, checkprop, setprop, svsend, clreceive) \
44         void id##_set(entity ent, entity player) { setprop(ent.(checkprop), player.(checkprop)); } \
45         void id##_send(int chan, entity ent) { LAMBDA(svsend); } \
46         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
47                 this.m_public = ispublic; \
48                 this.m_check = id##_check; \
49                 this.m_set = id##_set; \
50                 this.m_send = id##_send; \
51         }
52
53 #define ENTCS_PROP(id, ispublic, checkprop, setprop, svsend, clreceive) \
54         bool id##_check(entity ent, entity player) { return (ent.(checkprop) != player.(checkprop)); } \
55         _ENTCS_PROP(id, ispublic, checkprop, setprop, svsend, clreceive)
56
57 #define ENTCS_PROP_CODED(id, ispublic, checkprop, setprop, decfactor, svsend, clreceive) \
58         bool id##_check(entity ent, entity player) { \
59                 return (floor(ent.(checkprop)) / decfactor != floor(player.(checkprop)) / decfactor); \
60         } \
61         _ENTCS_PROP(id, ispublic, checkprop, setprop, svsend, clreceive)
62
63 #elif defined(CSQC)
64 #define ENTCS_PROP(id, ispublic, checkprop, setprop, svsend, clreceive) \
65         void id##_receive(entity ent) { LAMBDA(clreceive); } \
66         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
67                 this.m_public = ispublic; \
68                 this.m_receive = id##_receive; \
69         }
70
71 #define ENTCS_PROP_CODED(id, ispublic, checkprop, setprop, decfactor, svsend, clreceive) \
72         ENTCS_PROP(id, ispublic, checkprop, setprop, svsend, clreceive)
73 #endif
74
75 #ifdef SVQC
76 #define ENTCS_PROP_RESOURCE(id, ispublic, checkprop, setprop, decfactor, svsend, clreceive) \
77         bool id##_check(entity ent, entity player) { \
78                 return (floor(GetResource(ent, checkprop) / decfactor) != floor(GetResource(player, checkprop) / decfactor)); \
79         } \
80         void id##_set(entity ent, entity player) { SetResourceExplicit(ent, checkprop, GetResource(player, checkprop)); } \
81         void id##_send(int chan, entity ent) { LAMBDA(svsend); } \
82         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
83                 this.m_public = ispublic; \
84                 this.m_check = id##_check; \
85                 this.m_set = id##_set; \
86                 this.m_send = id##_send; \
87         }
88 #elif defined(CSQC)
89 #define ENTCS_PROP_RESOURCE(id, ispublic, checkprop, setprop, decfactor, svsend, clreceive) \
90         void id##_receive(entity ent) { LAMBDA(clreceive); } \
91         REGISTER(EntCSProps, ENTCS_PROP, id, m_id, new_pure(entcs_prop)) { \
92                 this.m_public = ispublic; \
93                 this.m_receive = id##_receive; \
94         }
95 #endif
96
97 #define ENTCS_SET_NORMAL(var, x) MACRO_BEGIN \
98         var = x; \
99 MACRO_END
100
101 /** the engine player name strings are mutable! */
102 #define ENTCS_SET_MUTABLE_STRING(var, x) MACRO_BEGIN \
103         strcpy(var, x); \
104 MACRO_END
105
106 ENTCS_PROP(ENTNUM, false, sv_entnum, ENTCS_SET_NORMAL, {}, {}) /* sentinel */
107
108 ENTCS_PROP(ORIGIN, false, origin, ENTCS_SET_NORMAL,
109         { WriteVector(chan, ent.origin); },
110         { ent.has_sv_origin = true; vector v = ReadVector(); setorigin(ent, v); })
111
112 #define DEC_FACTOR (360 / 32)
113 ENTCS_PROP_CODED(ANGLES, false, angles_y, ENTCS_SET_NORMAL, DEC_FACTOR,
114         { WriteByte(chan, ent.angles.y / DEC_FACTOR); },
115         { vector v = '0 0 0'; v.y = ReadByte() * DEC_FACTOR; ent.angles = v; })
116 #undef DEC_FACTOR
117
118 // FIXME: use a better scale?
119 #define DEC_FACTOR 10
120 ENTCS_PROP_RESOURCE(HEALTH, false, RES_HEALTH, ENTCS_SET_NORMAL, DEC_FACTOR,
121         { WriteByte(chan, bound(0, GetResource(ent, RES_HEALTH) / DEC_FACTOR, 255)); },
122         { ent.healthvalue = ReadByte() * DEC_FACTOR; })
123
124 ENTCS_PROP_RESOURCE(ARMOR, false, RES_ARMOR, ENTCS_SET_NORMAL, DEC_FACTOR,
125         { WriteByte(chan, bound(0, GetResource(ent, RES_ARMOR) / DEC_FACTOR, 255)); },
126         { SetResourceExplicit(ent, RES_ARMOR, ReadByte() * DEC_FACTOR); })
127 #undef DEC_FACTOR
128
129 ENTCS_PROP(NAME, true, netname, ENTCS_SET_MUTABLE_STRING,
130         { WriteString(chan, ent.netname); },
131         { strcpy(ent.netname, ReadString()); })
132
133 ENTCS_PROP(MODEL, true, model, ENTCS_SET_NORMAL,
134         { WriteString(chan, ent.model); },
135         { strcpy(ent.model, ReadString()); })
136
137 ENTCS_PROP(SKIN, true, skin, ENTCS_SET_NORMAL,
138         { WriteByte(chan, ent.skin); },
139         { ent.skin = ReadByte(); })
140
141 ENTCS_PROP(CLIENTCOLORS, true, clientcolors, ENTCS_SET_NORMAL,
142         { WriteByte(chan, ent.clientcolors); },
143         { ent.colormap = ReadByte(); })
144
145 ENTCS_PROP(FRAGS, true, frags, ENTCS_SET_NORMAL,
146         { WriteShort(chan, ent.frags); },
147         { ent.frags = ReadShort(); })
148
149 ENTCS_PROP(SOLID, true, solid, ENTCS_SET_NORMAL,
150         { WriteByte(chan, ent.solid); },
151         { ent.solid = ReadByte(); })
152
153 #ifdef SVQC
154
155         int ENTCS_PUBLICMASK = 0;
156         STATIC_INIT(ENTCS_PUBLICMASK)
157         {
158                 FOREACH(EntCSProps, it.m_public,
159                 {
160                         ENTCS_PUBLICMASK |= BIT(it.m_id);
161                 });
162         }
163
164         bool _entcs_send(entity this, entity to, int sf, int chan)
165         {
166                 entity player = this.owner;
167                 sf |= BIT(ENTCS_PROP_ENTNUM_id); // assume private
168                 do {
169                         if (IS_PLAYER(player))
170                         {
171                                 if (radar_showennemies) break;
172                                 if (SAME_TEAM(to, player)) break;
173                                 if (!(IS_PLAYER(to) || to.caplayer) && time > game_starttime) break;
174                         }
175                         sf &= ENTCS_PUBLICMASK; // no private updates
176                 } while (0);
177
178                 sf |= this.m_forceupdate;
179                 this.m_forceupdate = 0;
180                 if (chan == MSG_ENTITY)
181                         WriteHeader(chan, ENT_CLIENT_ENTCS);
182                 else
183                         WriteHeader(chan, CLIENT_ENTCS);
184                 WriteByte(chan, etof(player) - 1);
185                 WriteShort(chan, sf);
186                 FOREACH(EntCSProps, sf & BIT(it.m_id),
187                 {
188                         it.m_send(chan, this);
189                 });
190                 return true;
191         }
192
193         bool entcs_send(entity this, entity to, int sf)
194         {
195                 return _entcs_send(this, to, sf, MSG_ENTITY);
196         }
197
198         void entcs_think(entity this)
199         {
200                 this.nextthink = time + 0.033333333333;  // TODO: increase this to like 0.15 once the client can do smoothing
201                 entity player = this.owner;
202                 FOREACH(EntCSProps, it.m_check(this, player),
203                 {
204                         it.m_set(this, player);
205                         this.SendFlags |= BIT(it.m_id);
206                 });
207                 setorigin(this, this.origin); // relink
208         }
209
210         void entcs_attach(entity player)
211         {
212                 entity e = CS(player).entcs = new(entcs_sender);
213                 e.owner = player;
214                 setthink(e, entcs_think);
215                 e.nextthink = time;
216                 Net_LinkEntity(e, false, 0, entcs_send);
217                 if (!IS_REAL_CLIENT(player)) return;
218                 FOREACH_CLIENT(true, {
219                         assert(CS(it).entcs);
220                         _entcs_send(CS(it).entcs, msg_entity = player, BITS(23), MSG_ONE);
221                 });
222         }
223
224         void entcs_detach(entity player)
225         {
226                 if (!CS(player).entcs) return;
227                 delete(CS(player).entcs);
228                 CS(player).entcs = NULL;
229         }
230
231 #endif
232
233 #ifdef CSQC
234
235         void Ent_RemoveEntCS(entity this)
236         {
237                 int n = this.sv_entnum;
238                 entity e = entcs_receiver(n);
239                 entcs_receiver(n, NULL);
240                 strfree(e.netname);
241                 strfree(e.model);
242                 if (e != this) delete(e);
243         }
244
245         void entcs_think(entity this)
246         {
247                 entity e = CSQCModel_server2csqc(this.sv_entnum);
248                 if (e == NULL)
249                 {
250                         this.has_origin = this.has_sv_origin;
251                         return;
252                 }
253                 this.has_origin = true;
254                 this.origin = e.origin;
255                 // `cl_forceplayermodels 1` sounds will be wrong until the player has been in the PVS, but so be it
256                 if (this.model != e.model)
257                 {
258                         strcpy(this.model, e.model);
259                 }
260         }
261
262         bool ReadEntcs(entity this)
263         {
264                 int n = ReadByte();
265                 entity e = entcs_receiver(n);
266                 if (e == NULL)
267                 {
268                         if (!this)
269                                 // initial = temp
270                                 e = new_pure(entcs_receiver);
271                         else
272                                 // initial = linked
273                                 e = this;
274                         setthink(e, entcs_think);
275                         entcs_receiver(n, e);
276                 }
277                 else if (e != this && this)
278                 {
279                         // upgrade to linked
280                         delete(e);
281                         e = this;
282                         setthink(e, entcs_think);
283                         entcs_receiver(n, e);
284                 }
285
286                 InterpolateOrigin_Undo(e);
287                 e.sv_entnum = n;
288                 int sf = ReadShort();
289                 e.has_sv_origin = false;
290                 e.m_entcs_private = boolean(sf & BIT(ENTCS_PROP_ENTNUM_id));
291                 FOREACH(EntCSProps, sf & BIT(it.m_id),
292                 {
293                         it.m_receive(e);
294                 });
295                 e.iflags |= IFLAG_ORIGIN;
296                 InterpolateOrigin_Note(e);
297                 getthink(e)(e);
298                 return true;
299         }
300
301         NET_HANDLE(ENT_CLIENT_ENTCS, bool isnew)
302         {
303                 if (isnew)
304                 {
305                         make_pure(this);
306                         this.classname = "entcs_receiver";
307                         this.entremove = Ent_RemoveEntCS;
308                 }
309                 return ReadEntcs(this);
310         }
311
312         NET_HANDLE(CLIENT_ENTCS, bool isnew)
313         {
314                 return ReadEntcs(NULL);
315         }
316
317 #endif