qcsrc/common/gamemodes/gamemode/clanarena/sv_clanarena.qc

   1 #include "sv_clanarena.qh"
   2
   3 float autocvar_g_ca_damage2score_multiplier;
   4 bool autocvar_g_ca_spectate_enemies;
   5
   6 void CA_count_alive_players()
   7 {
   8         total_players = 0;
   9         for (int i = 1; i <= NUM_TEAMS; ++i)
  10         {
  11                 Team_SetNumberOfAlivePlayers(Team_GetTeamFromIndex(i), 0);
  12         }
  13         FOREACH_CLIENT(IS_PLAYER(it) && Entity_HasValidTeam(it),
  14         {
  15                 ++total_players;
  16                 if (IS_DEAD(it))
  17                 {
  18                         continue;
  19                 }
  20                 entity team_ = Entity_GetTeam(it);
  21                 int num_alive = Team_GetNumberOfAlivePlayers(team_);
  22                 ++num_alive;
  23                 Team_SetNumberOfAlivePlayers(team_, num_alive);
  24         });
  25         FOREACH_CLIENT(IS_REAL_CLIENT(it),
  26         {
  27                 STAT(REDALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(
  28                         1));
  29                 STAT(BLUEALIVE, it) = Team_GetNumberOfAlivePlayers(
  30                         Team_GetTeamFromIndex(2));
  31                 STAT(YELLOWALIVE, it) = Team_GetNumberOfAlivePlayers(
  32                         Team_GetTeamFromIndex(3));
  33                 STAT(PINKALIVE, it) = Team_GetNumberOfAlivePlayers(
  34                         Team_GetTeamFromIndex(4));
  35         });
  36 }
  37
  38 int CA_GetWinnerTeam()
  39 {
  40         int winner_team = 0;
  41         if (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(1)) >= 1)
  42         {
  43                 winner_team = NUM_TEAM_1;
  44         }
  45         for (int i = 2; i <= NUM_TEAMS; ++i)
  46         {
  47                 if (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(i)) >= 1)
  48                 {
  49                         if (winner_team != 0)
  50                         {
  51                                 return 0;
  52                         }
  53                         winner_team = Team_IndexToTeam(i);
  54                 }
  55         }
  56         if (winner_team)
  57         {
  58                 return winner_team;
  59         }
  60         return -1; // no player left
  61 }
  62
  63 void nades_Clear(entity player);
  64
  65 float CA_CheckWinner()
  66 {
  67         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
  68         {
  69                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
  70                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
  71                 FOREACH_CLIENT(IS_PLAYER(it), { nades_Clear(it); });
  72
  73                 allowed_to_spawn = false;
  74                 game_stopped = true;
  75                 round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
  76                 return 1;
  77         }
  78
  79         CA_count_alive_players();
  80         if (Team_GetNumberOfAliveTeams() > 1)
  81         {
  82                 return 0;
  83         }
  84
  85         int winner_team = CA_GetWinnerTeam();
  86         if(winner_team > 0)
  87         {
  88                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
  89                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
  90                 TeamScore_AddToTeam(winner_team, ST_CA_ROUNDS, +1);
  91         }
  92         else if(winner_team == -1)
  93         {
  94                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
  95                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
  96         }
  97
  98         allowed_to_spawn = false;
  99         game_stopped = true;
 100         round_handler_Init(5, autocvar_g_ca_warmup, autocvar_g_ca_round_timelimit);
 101
 102         FOREACH_CLIENT(IS_PLAYER(it), { nades_Clear(it); });
 103
 104         return 1;
 105 }
 106
 107 void CA_RoundStart()
 108 {
 109         allowed_to_spawn = boolean(warmup_stage);
 110 }
 111
 112 bool CA_CheckTeams()
 113 {
 114         static int prev_missing_teams_mask;
 115         allowed_to_spawn = true;
 116         CA_count_alive_players();
 117         if (Team_GetNumberOfAliveTeams() == NumTeams(ca_teams))
 118         {
 119                 if(prev_missing_teams_mask > 0)
 120                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 121                 prev_missing_teams_mask = -1;
 122                 return true;
 123         }
 124         if(total_players == 0)
 125         {
 126                 if(prev_missing_teams_mask > 0)
 127                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 128                 prev_missing_teams_mask = -1;
 129                 return false;
 130         }
 131         int missing_teams_mask = 0;
 132         for (int i = 1; i <= NUM_TEAMS; ++i)
 133         {
 134                 if ((ca_teams & Team_IndexToBit(i)) &&
 135                         (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(i)) == 0))
 136                 {
 137                         missing_teams_mask |= Team_IndexToBit(i);
 138                 }
 139         }
 140         if(prev_missing_teams_mask != missing_teams_mask)
 141         {
 142                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 143                 prev_missing_teams_mask = missing_teams_mask;
 144         }
 145         return false;
 146 }
 147
 148 bool ca_isEliminated(entity e)
 149 {
 150         if(e.caplayer == 1 && (IS_DEAD(e) || e.frags == FRAGS_LMS_LOSER))
 151                 return true;
 152         if(e.caplayer == 0.5)
 153                 return true;
 154         return false;
 155 }
 156
 157 /** Returns next available player to spectate if g_ca_spectate_enemies == 0 */
 158 entity CA_SpectateNext(entity player, entity start)
 159 {
 160         if (SAME_TEAM(start, player)) return start;
 161         // continue from current player
 162         for (entity e = start; (e = find(e, classname, STR_PLAYER)); )
 163         {
 164                 if (SAME_TEAM(player, e)) return e;
 165         }
 166         // restart from begining
 167         for (entity e = NULL; (e = find(e, classname, STR_PLAYER)); )
 168         {
 169                 if (SAME_TEAM(player, e)) return e;
 170         }
 171         return start;
 172 }
 173
 174
 175 MUTATOR_HOOKFUNCTION(ca, PlayerSpawn)
 176 {
 177         entity player = M_ARGV(0, entity);
 178
 179         player.caplayer = 1;
 180         if (!warmup_stage)
 181                 eliminatedPlayers.SendFlags |= 1;
 182 }
 183
 184 MUTATOR_HOOKFUNCTION(ca, ForbidSpawn)
 185 {
 186         entity player = M_ARGV(0, entity);
 187
 188         // spectators / observers that weren't playing can join; they are
 189         // immediately forced to observe in the PutClientInServer hook
 190         // this way they are put in a team and can play in the next round
 191         if (!allowed_to_spawn && player.caplayer)
 192                 return true;
 193         return false;
 194 }
 195
 196 MUTATOR_HOOKFUNCTION(ca, PutClientInServer)
 197 {
 198         entity player = M_ARGV(0, entity);
 199
 200         if (!allowed_to_spawn && IS_PLAYER(player)) // this is true even when player is trying to join
 201         {
 202                 TRANSMUTE(Observer, player);
 203                 if (CS(player).jointime != time && !player.caplayer) // not when connecting
 204                 {
 205                         player.caplayer = 0.5;
 206                         Send_Notification(NOTIF_ONE_ONLY, player, MSG_INFO, INFO_CA_JOIN_LATE);
 207                 }
 208         }
 209 }
 210
 211 MUTATOR_HOOKFUNCTION(ca, reset_map_players)
 212 {
 213         FOREACH_CLIENT(true, {
 214                 CS(it).killcount = 0;
 215                 if (!it.caplayer && IS_BOT_CLIENT(it))
 216                 {
 217                         it.team = -1;
 218                         it.caplayer = 1;
 219                 }
 220                 if (it.caplayer)
 221                 {
 222                         TRANSMUTE(Player, it);
 223                         it.caplayer = 1;
 224                         PutClientInServer(it);
 225                 }
 226         });
 227         bot_relinkplayerlist();
 228         return true;
 229 }
 230
 231 MUTATOR_HOOKFUNCTION(ca, ClientConnect)
 232 {
 233         entity player = M_ARGV(0, entity);
 234
 235         TRANSMUTE(Observer, player);
 236         return true;
 237 }
 238
 239 MUTATOR_HOOKFUNCTION(ca, reset_map_global)
 240 {
 241         allowed_to_spawn = true;
 242         return true;
 243 }
 244
 245 MUTATOR_HOOKFUNCTION(ca, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
 246 {
 247         M_ARGV(0, float) = ca_teams;
 248         return true;
 249 }
 250
 251 entity ca_LastPlayerForTeam(entity this)
 252 {
 253         entity last_pl = NULL;
 254         FOREACH_CLIENT(IS_PLAYER(it) && it != this, {
 255                 if (!IS_DEAD(it) && SAME_TEAM(this, it))
 256                 {
 257                         if (!last_pl)
 258                                 last_pl = it;
 259                         else
 260                                 return NULL;
 261                 }
 262         });
 263         return last_pl;
 264 }
 265
 266 void ca_LastPlayerForTeam_Notify(entity this)
 267 {
 268         if (!warmup_stage && round_handler_IsActive() && round_handler_IsRoundStarted())
 269         {
 270                 entity pl = ca_LastPlayerForTeam(this);
 271                 if (pl)
 272                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 273         }
 274 }
 275
 276 MUTATOR_HOOKFUNCTION(ca, PlayerDies)
 277 {
 278         entity frag_target = M_ARGV(2, entity);
 279
 280         ca_LastPlayerForTeam_Notify(frag_target);
 281         if (!allowed_to_spawn)
 282         {
 283                 frag_target.respawn_flags = RESPAWN_SILENT;
 284                 // prevent unwanted sudden rejoin as spectator and movement of spectator camera
 285                 frag_target.respawn_time = time + 2;
 286         }
 287         frag_target.respawn_flags |= RESPAWN_FORCE;
 288         if (!warmup_stage)
 289         {
 290                 eliminatedPlayers.SendFlags |= 1;
 291                 if (IS_BOT_CLIENT(frag_target))
 292                         bot_clear(frag_target);
 293         }
 294         return true;
 295 }
 296
 297 MUTATOR_HOOKFUNCTION(ca, ClientDisconnect)
 298 {
 299         entity player = M_ARGV(0, entity);
 300
 301         if (IS_PLAYER(player) && !IS_DEAD(player))
 302                 ca_LastPlayerForTeam_Notify(player);
 303         return true;
 304 }
 305
 306 MUTATOR_HOOKFUNCTION(ca, MakePlayerObserver)
 307 {
 308         entity player = M_ARGV(0, entity);
 309
 310         if (IS_PLAYER(player) && !IS_DEAD(player))
 311                 ca_LastPlayerForTeam_Notify(player);
 312         if (player.killindicator_teamchange == -2) // player wants to spectate
 313                 player.caplayer = 0;
 314         if (player.caplayer)
 315                 player.frags = FRAGS_LMS_LOSER;
 316         if (!warmup_stage)
 317                 eliminatedPlayers.SendFlags |= 1;
 318         if (!player.caplayer)
 319                 return false;  // allow team reset
 320         return true;  // prevent team reset
 321 }
 322
 323 MUTATOR_HOOKFUNCTION(ca, ForbidThrowCurrentWeapon)
 324 {
 325         return true;
 326 }
 327
 328 MUTATOR_HOOKFUNCTION(ca, GiveFragsForKill, CBC_ORDER_FIRST)
 329 {
 330         M_ARGV(2, float) = 0; // score will be given to the winner team when the round ends
 331         return true;
 332 }
 333
 334 MUTATOR_HOOKFUNCTION(ca, SetStartItems)
 335 {
 336         start_items       &= ~IT_UNLIMITED_AMMO;
 337         start_health       = warmup_start_health       = cvar("g_lms_start_health");
 338         start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 339         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 340         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 341         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 342         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 343         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 344         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 345 }
 346
 347 MUTATOR_HOOKFUNCTION(ca, Damage_Calculate)
 348 {
 349         entity frag_attacker = M_ARGV(1, entity);
 350         entity frag_target = M_ARGV(2, entity);
 351         float frag_deathtype = M_ARGV(3, float);
 352         float frag_damage = M_ARGV(4, float);
 353         float frag_mirrordamage = M_ARGV(5, float);
 354
 355         if (IS_PLAYER(frag_target))
 356         if (!IS_DEAD(frag_target))
 357         if (frag_target == frag_attacker || SAME_TEAM(frag_target, frag_attacker) || frag_deathtype == DEATH_FALL.m_id)
 358                 frag_damage = 0;
 359
 360         frag_mirrordamage = 0;
 361
 362         M_ARGV(4, float) = frag_damage;
 363         M_ARGV(5, float) = frag_mirrordamage;
 364 }
 365
 366 MUTATOR_HOOKFUNCTION(ca, FilterItem)
 367 {
 368         entity item = M_ARGV(0, entity);
 369
 370         if (autocvar_g_powerups <= 0)
 371         if (item.flags & FL_POWERUP)
 372                 return true;
 373
 374         if (autocvar_g_pickup_items <= 0)
 375                 return true;
 376 }
 377
 378 MUTATOR_HOOKFUNCTION(ca, PlayerDamage_SplitHealthArmor)
 379 {
 380         entity frag_attacker = M_ARGV(1, entity);
 381         entity frag_target = M_ARGV(2, entity);
 382         float frag_damage = M_ARGV(7, float);
 383         float damage_take = bound(0, M_ARGV(4, float), GetResource(frag_target, RES_HEALTH));
 384         float damage_save = bound(0, M_ARGV(5, float), GetResource(frag_target, RES_ARMOR));
 385
 386         float excess = max(0, frag_damage - damage_take - damage_save);
 387
 388         if (frag_target != frag_attacker && IS_PLAYER(frag_attacker) && DIFF_TEAM(frag_target, frag_attacker))
 389                 GameRules_scoring_add_team(frag_attacker, SCORE, (frag_damage - excess) * autocvar_g_ca_damage2score_multiplier);
 390 }
 391
 392 MUTATOR_HOOKFUNCTION(ca, CalculateRespawnTime)
 393 {
 394         // no respawn calculations needed, player is forced to spectate anyway
 395         return true;
 396 }
 397
 398 MUTATOR_HOOKFUNCTION(ca, PlayerRegen)
 399 {
 400         // no regeneration in CA
 401         return true;
 402 }
 403
 404 MUTATOR_HOOKFUNCTION(ca, Scores_CountFragsRemaining)
 405 {
 406         // announce remaining frags
 407         return true;
 408 }
 409
 410 MUTATOR_HOOKFUNCTION(ca, SpectateSet)
 411 {
 412         entity client = M_ARGV(0, entity);
 413         entity targ = M_ARGV(1, entity);
 414
 415         if (!autocvar_g_ca_spectate_enemies && client.caplayer)
 416         if (DIFF_TEAM(targ, client))
 417                 return true;
 418 }
 419
 420 MUTATOR_HOOKFUNCTION(ca, SpectateNext)
 421 {
 422         entity client = M_ARGV(0, entity);
 423
 424         if (!autocvar_g_ca_spectate_enemies && client.caplayer
 425                 && Team_GetNumberOfAlivePlayers(Entity_GetTeam(client)))
 426         {
 427                 entity targ = M_ARGV(1, entity);
 428                 M_ARGV(1, entity) = CA_SpectateNext(client, targ);
 429                 return true;
 430         }
 431 }
 432
 433 MUTATOR_HOOKFUNCTION(ca, SpectatePrev)
 434 {
 435         entity client = M_ARGV(0, entity);
 436         entity targ = M_ARGV(1, entity);
 437         entity first = M_ARGV(2, entity);
 438
 439         if (!autocvar_g_ca_spectate_enemies && client.caplayer
 440                 && Team_GetNumberOfAlivePlayers(Entity_GetTeam(client)))
 441         {
 442                 do { targ = targ.chain; }
 443                 while(targ && DIFF_TEAM(targ, client));
 444
 445                 if (!targ)
 446                 {
 447                         for (targ = first; targ && DIFF_TEAM(targ, client); targ = targ.chain);
 448
 449                         if (targ == client.enemy)
 450                                 return MUT_SPECPREV_RETURN;
 451                 }
 452         }
 453         else
 454                 return MUT_SPECPREV_CONTINUE;
 455
 456         M_ARGV(1, entity) = targ;
 457
 458         return MUT_SPECPREV_FOUND;
 459 }
 460
 461 MUTATOR_HOOKFUNCTION(ca, Bot_FixCount, CBC_ORDER_EXCLUSIVE)
 462 {
 463         FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 464                 if (IS_PLAYER(it) || it.caplayer == 1)
 465                         ++M_ARGV(0, int);
 466                 ++M_ARGV(1, int);
 467         });
 468         return true;
 469 }
 470
 471 MUTATOR_HOOKFUNCTION(ca, ClientCommand_Spectate)
 472 {
 473         entity player = M_ARGV(0, entity);
 474
 475         if (player.caplayer)
 476         {
 477                 // they're going to spec, we can do other checks
 478                 if (autocvar_sv_spectate && (IS_SPEC(player) || IS_OBSERVER(player)))
 479                         Send_Notification(NOTIF_ONE_ONLY, player, MSG_INFO, INFO_CA_LEAVE);
 480                 return MUT_SPECCMD_FORCE;
 481         }
 482
 483         return MUT_SPECCMD_CONTINUE;
 484 }
 485
 486 MUTATOR_HOOKFUNCTION(ca, WantWeapon)
 487 {
 488         M_ARGV(2, bool) = true; // all weapons
 489 }
 490
 491 MUTATOR_HOOKFUNCTION(ca, HideTeamNagger)
 492 {
 493         return true; // doesn't work well with the whole spectator as player thing
 494 }
 495
 496 MUTATOR_HOOKFUNCTION(ca, GetPlayerStatus)
 497 {
 498         entity player = M_ARGV(0, entity);
 499
 500         return player.caplayer == 1;
 501 }
 502
 503 MUTATOR_HOOKFUNCTION(ca, SetWeaponArena)
 504 {
 505         // most weapons arena
 506         if (M_ARGV(0, string) == "0" || M_ARGV(0, string) == "") M_ARGV(0, string) = "most";
 507 }