qcsrc/common/gamemodes/gamemode/cts/sv_cts.qc

   1 #include "sv_cts.qh"
   2
   3 #include <server/client.qh>
   4 #include <server/race.qh>
   5 #include <server/world.qh>
   6 #include <server/gamelog.qh>
   7 #include <server/items/spawning.qh>
   8 #include <server/weapons/common.qh>
   9 #include <common/mapobjects/triggers.qh>
  10
  11 float autocvar_g_cts_finish_kill_delay;
  12 bool autocvar_g_cts_selfdamage;
  13 bool autocvar_g_cts_removeprojectiles;
  14
  15 // legacy bot roles
  16 .float race_checkpoint;
  17 void havocbot_role_cts(entity this)
  18 {
  19         if(IS_DEAD(this))
  20                 return;
  21
  22         if (navigation_goalrating_timeout(this))
  23         {
  24                 navigation_goalrating_start(this);
  25
  26                 bool raw_touch_check = true;
  27                 int cp = this.race_checkpoint;
  28
  29                 LABEL(search_racecheckpoints)
  30                 IL_EACH(g_racecheckpoints, true,
  31                 {
  32                         if(it.cnt == cp || cp == -1)
  33                         {
  34                                 // redirect bot to next goal if it touched the waypoint of an untouchable checkpoint
  35                                 // e.g. checkpoint in front of Stormkeep's warpzone
  36                                 // the same workaround is applied in Race game mode
  37                                 if (raw_touch_check && vdist(this.origin - it.nearestwaypoint.origin, <, 30))
  38                                 {
  39                                         cp = race_NextCheckpoint(cp);
  40                                         raw_touch_check = false;
  41                                         goto search_racecheckpoints;
  42                                 }
  43                                 navigation_routerating(this, it, 1000000, 5000);
  44                         }
  45                 });
  46
  47                 navigation_goalrating_end(this);
  48
  49                 navigation_goalrating_timeout_set(this);
  50         }
  51 }
  52
  53 void cts_ScoreRules()
  54 {
  55     GameRules_score_enabled(false);
  56     GameRules_scoring(0, 0, 0, {
  57         if (g_race_qualifying) {
  58             field(SP_RACE_FASTEST, "fastest", SFL_SORT_PRIO_PRIMARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  59         } else {
  60             field(SP_RACE_LAPS, "laps", SFL_SORT_PRIO_PRIMARY);
  61             field(SP_RACE_TIME, "time", SFL_SORT_PRIO_SECONDARY | SFL_LOWER_IS_BETTER | SFL_TIME);
  62             field(SP_RACE_FASTEST, "fastest", SFL_LOWER_IS_BETTER | SFL_TIME);
  63         }
  64     });
  65 }
  66
  67 void cts_EventLog(string mode, entity actor) // use an alias for easy changing and quick editing later
  68 {
  69         if(autocvar_sv_eventlog)
  70                 GameLogEcho(strcat(":cts:", mode, ":", ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  71 }
  72
  73 MUTATOR_HOOKFUNCTION(cts, PlayerPhysics)
  74 {
  75         entity player = M_ARGV(0, entity);
  76         float dt = M_ARGV(1, float);
  77
  78         player.race_movetime_frac += dt;
  79         float f = floor(player.race_movetime_frac);
  80         player.race_movetime_frac -= f;
  81         player.race_movetime_count += f;
  82         player.race_movetime = player.race_movetime_frac + player.race_movetime_count;
  83
  84         if(IS_PLAYER(player))
  85         {
  86                 if (player.race_penalty)
  87                         if (time > player.race_penalty)
  88                                 player.race_penalty = 0;
  89                 if(player.race_penalty)
  90                 {
  91                         player.velocity = '0 0 0';
  92                         set_movetype(player, MOVETYPE_NONE);
  93                         player.disableclientprediction = 2;
  94                 }
  95         }
  96
  97         // force kbd movement for fairness
  98         float wishspeed;
  99         vector wishvel;
 100
 101         // if record times matter
 102         // ensure nothing EVIL is being done (i.e. div0_evade)
 103         // this hinders joystick users though
 104         // but it still gives SOME analog control
 105         wishvel.x = fabs(CS(player).movement.x);
 106         wishvel.y = fabs(CS(player).movement.y);
 107         if(wishvel.x != 0 && wishvel.y != 0 && wishvel.x != wishvel.y)
 108         {
 109                 wishvel.z = 0;
 110                 wishspeed = vlen(wishvel);
 111                 if(wishvel.x >= 2 * wishvel.y)
 112                 {
 113                         // pure X motion
 114                         if(CS(player).movement.x > 0)
 115                                 CS(player).movement_x = wishspeed;
 116                         else
 117                                 CS(player).movement_x = -wishspeed;
 118                         CS(player).movement_y = 0;
 119                 }
 120                 else if(wishvel.y >= 2 * wishvel.x)
 121                 {
 122                         // pure Y motion
 123                         CS(player).movement_x = 0;
 124                         if(CS(player).movement.y > 0)
 125                                 CS(player).movement_y = wishspeed;
 126                         else
 127                                 CS(player).movement_y = -wishspeed;
 128                 }
 129                 else
 130                 {
 131                         // diagonal
 132                         if(CS(player).movement.x > 0)
 133                                 CS(player).movement_x = M_SQRT1_2 * wishspeed;
 134                         else
 135                                 CS(player).movement_x = -M_SQRT1_2 * wishspeed;
 136                         if(CS(player).movement.y > 0)
 137                                 CS(player).movement_y = M_SQRT1_2 * wishspeed;
 138                         else
 139                                 CS(player).movement_y = -M_SQRT1_2 * wishspeed;
 140                 }
 141         }
 142 }
 143
 144 MUTATOR_HOOKFUNCTION(cts, reset_map_global)
 145 {
 146         float s;
 147
 148         Score_NicePrint(NULL);
 149
 150         race_ClearRecords();
 151         PlayerScore_Sort(race_place, 0, 1, 0);
 152
 153         FOREACH_CLIENT(true, {
 154                 if(it.race_place)
 155                 {
 156                         s = GameRules_scoring_add(it, RACE_FASTEST, 0);
 157                         if(!s)
 158                                 it.race_place = 0;
 159                 }
 160                 cts_EventLog(ftos(it.race_place), it);
 161         });
 162
 163         if(g_race_qualifying == 2)
 164         {
 165                 g_race_qualifying = 0;
 166                 independent_players = 0;
 167                 cvar_set("fraglimit", ftos(race_fraglimit));
 168                 cvar_set("leadlimit", ftos(race_leadlimit));
 169                 cvar_set("timelimit", ftos(race_timelimit));
 170                 cts_ScoreRules();
 171         }
 172 }
 173
 174 MUTATOR_HOOKFUNCTION(cts, ClientConnect)
 175 {
 176         entity player = M_ARGV(0, entity);
 177
 178         race_PreparePlayer(player);
 179         player.race_checkpoint = -1;
 180
 181         if(IS_REAL_CLIENT(player))
 182         {
 183                 string rr = CTS_RECORD;
 184
 185                 msg_entity = player;
 186                 race_send_recordtime(MSG_ONE);
 187                 race_send_speedaward(MSG_ONE);
 188
 189                 speedaward_alltimebest = stof(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed")));
 190                 speedaward_alltimebest_holder = uid2name(db_get(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp")));
 191                 race_send_speedaward_alltimebest(MSG_ONE);
 192
 193                 float i;
 194                 int m = min(RANKINGS_CNT, autocvar_g_cts_send_rankings_cnt);
 195                 race_send_rankings_cnt(MSG_ONE);
 196                 for (i = 1; i <= m; ++i)
 197                 {
 198                         race_SendRankings(i, 0, 0, MSG_ONE);
 199                 }
 200         }
 201 }
 202
 203 MUTATOR_HOOKFUNCTION(cts, AbortSpeedrun)
 204 {
 205         entity player = M_ARGV(0, entity);
 206
 207         if(autocvar_g_allow_checkpoints)
 208                 race_PreparePlayer(player); // nice try
 209 }
 210
 211 MUTATOR_HOOKFUNCTION(cts, MakePlayerObserver)
 212 {
 213         entity player = M_ARGV(0, entity);
 214
 215         if(GameRules_scoring_add(player, RACE_FASTEST, 0))
 216                 player.frags = FRAGS_PLAYER_OUT_OF_GAME;
 217         else
 218                 player.frags = FRAGS_SPECTATOR;
 219
 220         race_PreparePlayer(player);
 221         player.race_checkpoint = -1;
 222 }
 223
 224 MUTATOR_HOOKFUNCTION(cts, PlayerSpawn)
 225 {
 226         entity player = M_ARGV(0, entity);
 227         entity spawn_spot = M_ARGV(1, entity);
 228
 229         if(spawn_spot.target == "")
 230                 // Emergency: this wasn't a real spawnpoint. Can this ever happen?
 231                 race_PreparePlayer(player);
 232
 233         // if we need to respawn, do it right
 234         player.race_respawn_checkpoint = player.race_checkpoint;
 235         player.race_respawn_spotref = spawn_spot;
 236
 237         player.race_place = 0;
 238 }
 239
 240 MUTATOR_HOOKFUNCTION(cts, PutClientInServer)
 241 {
 242         entity player = M_ARGV(0, entity);
 243
 244         if(IS_PLAYER(player))
 245         if(!game_stopped)
 246         {
 247                 if(CS(player).killcount == FRAGS_SPECTATOR /* initial spawn */ || g_race_qualifying) // spawn
 248                         race_PreparePlayer(player);
 249                 else // respawn
 250                         race_RetractPlayer(player);
 251
 252                 race_AbandonRaceCheck(player);
 253         }
 254 }
 255
 256 MUTATOR_HOOKFUNCTION(cts, PlayerDies)
 257 {
 258         entity frag_target = M_ARGV(2, entity);
 259
 260         frag_target.respawn_flags |= RESPAWN_FORCE;
 261         race_AbandonRaceCheck(frag_target);
 262
 263         if(autocvar_g_cts_removeprojectiles)
 264         {
 265                 IL_EACH(g_projectiles, it.owner == frag_target && (it.flags & FL_PROJECTILE),
 266                 {
 267                         delete(it);
 268                 });
 269         }
 270 }
 271
 272 MUTATOR_HOOKFUNCTION(cts, HavocBot_ChooseRole)
 273 {
 274         entity bot = M_ARGV(0, entity);
 275
 276         bot.havocbot_role = havocbot_role_cts;
 277         return true;
 278 }
 279
 280 MUTATOR_HOOKFUNCTION(cts, GetPressedKeys)
 281 {
 282         entity player = M_ARGV(0, entity);
 283
 284         if(CS(player).cvar_cl_allow_uidtracking == 1 && CS(player).cvar_cl_allow_uid2name == 1)
 285         {
 286                 if (!player.stored_netname)
 287                         player.stored_netname = strzone(uid2name(player.crypto_idfp));
 288                 if(player.stored_netname != player.netname)
 289                 {
 290                         db_put(ServerProgsDB, strcat("/uid2name/", player.crypto_idfp), player.netname);
 291                         strcpy(player.stored_netname, player.netname);
 292                 }
 293         }
 294
 295         if (!IS_OBSERVER(player))
 296         {
 297                 if(vdist(player.velocity - player.velocity_z * '0 0 1', >, speedaward_speed))
 298                 {
 299                         speedaward_speed = vlen(player.velocity - player.velocity_z * '0 0 1');
 300                         speedaward_holder = player.netname;
 301                         speedaward_uid = player.crypto_idfp;
 302                         speedaward_lastupdate = time;
 303                 }
 304                 if (speedaward_speed > speedaward_lastsent && time - speedaward_lastupdate > 1)
 305                 {
 306                         string rr = CTS_RECORD;
 307                         race_send_speedaward(MSG_ALL);
 308                         speedaward_lastsent = speedaward_speed;
 309                         if (speedaward_speed > speedaward_alltimebest && speedaward_uid != "")
 310                         {
 311                                 speedaward_alltimebest = speedaward_speed;
 312                                 speedaward_alltimebest_holder = speedaward_holder;
 313                                 speedaward_alltimebest_uid = speedaward_uid;
 314                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/speed"), ftos(speedaward_alltimebest));
 315                                 db_put(ServerProgsDB, strcat(GetMapname(), rr, "speed/crypto_idfp"), speedaward_alltimebest_uid);
 316                                 race_send_speedaward_alltimebest(MSG_ALL);
 317                         }
 318                 }
 319         }
 320 }
 321
 322 MUTATOR_HOOKFUNCTION(cts, ForbidThrowCurrentWeapon)
 323 {
 324         // no weapon dropping in CTS
 325         return true;
 326 }
 327
 328 MUTATOR_HOOKFUNCTION(cts, FilterItem)
 329 {
 330         entity item = M_ARGV(0, entity);
 331
 332         if (Item_IsLoot(item))
 333         {
 334                 return true;
 335         }
 336 }
 337
 338 MUTATOR_HOOKFUNCTION(cts, Damage_Calculate)
 339 {
 340         entity frag_attacker = M_ARGV(1, entity);
 341         entity frag_target = M_ARGV(2, entity);
 342         float frag_deathtype = M_ARGV(3, float);
 343         float frag_damage = M_ARGV(4, float);
 344
 345         if(frag_target == frag_attacker || frag_deathtype == DEATH_FALL.m_id)
 346         if(!autocvar_g_cts_selfdamage)
 347         {
 348                 frag_damage = 0;
 349                 M_ARGV(4, float) = frag_damage;
 350         }
 351 }
 352
 353 MUTATOR_HOOKFUNCTION(cts, ForbidPlayerScore_Clear)
 354 {
 355         return true; // in CTS, you don't lose score by observing
 356 }
 357
 358 MUTATOR_HOOKFUNCTION(cts, GetRecords)
 359 {
 360         int record_page = M_ARGV(0, int);
 361         string ret_string = M_ARGV(1, string);
 362
 363         for(int i = record_page * 200; i < MapInfo_count && i < record_page * 200 + 200; ++i)
 364         {
 365                 if(MapInfo_Get_ByID(i))
 366                 {
 367                         float r = race_readTime(MapInfo_Map_bspname, 1);
 368
 369                         if(!r)
 370                                 continue;
 371
 372                         string h = race_readName(MapInfo_Map_bspname, 1);
 373                         ret_string = strcat(ret_string, strpad(32, MapInfo_Map_bspname), " ", strpad(-8, TIME_ENCODED_TOSTRING(r)), " ", h, "\n");
 374                 }
 375         }
 376
 377         M_ARGV(1, string) = ret_string;
 378 }
 379
 380 MUTATOR_HOOKFUNCTION(cts, ClientKill)
 381 {
 382         M_ARGV(1, float) = 0; // kill delay
 383 }
 384
 385 MUTATOR_HOOKFUNCTION(cts, Race_FinalCheckpoint)
 386 {
 387         entity player = M_ARGV(0, entity);
 388
 389         // useful to prevent cheating by running back to the start line and starting out with more speed
 390         if(autocvar_g_cts_finish_kill_delay)
 391                 ClientKill_Silent(player, autocvar_g_cts_finish_kill_delay);
 392 }
 393
 394 MUTATOR_HOOKFUNCTION(cts, HideTeamNagger)
 395 {
 396         return true; // doesn't work so well (but isn't cts a teamless mode?)
 397 }
 398
 399 MUTATOR_HOOKFUNCTION(cts, FixClientCvars)
 400 {
 401         entity player = M_ARGV(0, entity);
 402
 403         stuffcmd(player, "cl_cmd settemp cl_movecliptokeyboard 2\n");
 404 }
 405
 406 MUTATOR_HOOKFUNCTION(cts, WantWeapon)
 407 {
 408         M_ARGV(1, float) = (M_ARGV(0, entity) == WEP_SHOTGUN); // want weapon = weapon info
 409         M_ARGV(3, bool) = true; // want mutator blocked
 410         return true;
 411 }
 412
 413 MUTATOR_HOOKFUNCTION(cts, ForbidDropCurrentWeapon)
 414 {
 415         return true;
 416 }
 417
 418 void cts_Initialize()
 419 {
 420         cts_ScoreRules();
 421 }