qcsrc/common/gamemodes/gamemode/domination/cl_domination.qc

   1 #include "cl_domination.qh"
   2
   3 #include <client/hud/panel/modicons.qh>
   4
   5 int autocvar_hud_panel_modicons_dom_layout;
   6
   7 void DrawDomItem(vector myPos, vector mySize, float aspect_ratio, int layout, int i)
   8 {
   9         TC(int, layout); TC(int, i);
  10         float stat = -1;
  11         string pic = "";
  12         vector color = '0 0 0';
  13         switch(i)
  14         {
  15                 case 0: stat = STAT(DOM_PPS_RED); pic = "dom_icon_red"; color = '1 0 0'; break;
  16                 case 1: stat = STAT(DOM_PPS_BLUE); pic = "dom_icon_blue"; color = '0 0 1'; break;
  17                 case 2: stat = STAT(DOM_PPS_YELLOW); pic = "dom_icon_yellow"; color = '1 1 0'; break;
  18                 default:
  19                 case 3: stat = STAT(DOM_PPS_PINK); pic = "dom_icon_pink"; color = '1 0 1'; break;
  20         }
  21         float pps_ratio = 0;
  22         if(STAT(DOM_TOTAL_PPS))
  23                 pps_ratio = stat / STAT(DOM_TOTAL_PPS);
  24
  25         if(mySize.x/mySize.y > aspect_ratio)
  26         {
  27                 i = aspect_ratio * mySize.y;
  28                 myPos.x = myPos.x + (mySize.x - i) / 2;
  29                 mySize.x = i;
  30         }
  31         else
  32         {
  33                 i = 1/aspect_ratio * mySize.x;
  34                 myPos.y = myPos.y + (mySize.y - i) / 2;
  35                 mySize.y = i;
  36         }
  37
  38         if (layout) // show text too
  39         {
  40                 //draw the text
  41                 color *= 0.5 + pps_ratio * (1 - 0.5); // half saturated color at min, full saturated at max
  42                 if (layout == 2) // average pps
  43                         drawstring_aspect(myPos + eX * mySize.y, ftos_decimals(stat, 2), vec2((2/3) * mySize.x, mySize.y), color, panel_fg_alpha, DRAWFLAG_NORMAL);
  44                 else // percentage of average pps
  45                         drawstring_aspect(myPos + eX * mySize.y, strcat( ftos(floor(pps_ratio*100 + 0.5)), "%" ), vec2((2/3) * mySize.x, mySize.y), color, panel_fg_alpha, DRAWFLAG_NORMAL);
  46         }
  47
  48         //draw the icon
  49         drawpic_aspect_skin(myPos, pic, '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  50         if (stat > 0)
  51         {
  52                 drawsetcliparea(myPos.x, myPos.y + mySize.y * (1 - pps_ratio), mySize.y, mySize.y * pps_ratio);
  53                 drawpic_aspect_skin(myPos, strcat(pic, "-highlighted"), '1 1 0' * mySize.y, '1 1 1', panel_fg_alpha, DRAWFLAG_NORMAL);
  54                 drawresetcliparea();
  55         }
  56 }
  57
  58 void HUD_Mod_Dom(vector myPos, vector mySize)
  59 {
  60         mod_active = 1; // required in each mod function that always shows something
  61
  62         int layout = autocvar_hud_panel_modicons_dom_layout;
  63         int rows, columns;
  64         float aspect_ratio;
  65         aspect_ratio = (layout) ? 3 : 1;
  66         rows = HUD_GetRowCount(team_count, mySize, aspect_ratio);
  67         columns = ceil(team_count/rows);
  68
  69         int i;
  70         float row = 0, column = 0;
  71         vector pos, itemSize;
  72         itemSize = vec2(mySize.x / columns, mySize.y / rows);
  73         for(i=0; i<team_count; ++i)
  74         {
  75                 pos = myPos + vec2(column * itemSize.x, row * itemSize.y);
  76
  77                 DrawDomItem(pos, itemSize, aspect_ratio, layout, i);
  78
  79                 ++row;
  80                 if(row >= rows)
  81                 {
  82                         row = 0;
  83                         ++column;
  84                 }
  85         }
  86 }