qcsrc/common/gamemodes/gamemode/domination/sv_domination.qc

   1 #include "sv_domination.qh"
   2
   3 #include <server/teamplay.qh>
   4
   5 bool g_domination;
   6
   7 int autocvar_g_domination_default_teams;
   8 bool autocvar_g_domination_disable_frags;
   9 int autocvar_g_domination_point_amt;
  10 bool autocvar_g_domination_point_fullbright;
  11 float autocvar_g_domination_round_timelimit;
  12 float autocvar_g_domination_warmup;
  13 float autocvar_g_domination_point_rate;
  14 int autocvar_g_domination_teams_override;
  15
  16 void dom_EventLog(string mode, float team_before, entity actor) // use an alias for easy changing and quick editing later
  17 {
  18         if(autocvar_sv_eventlog)
  19                 GameLogEcho(strcat(":dom:", mode, ":", ftos(team_before), ((actor != NULL) ? (strcat(":", ftos(actor.playerid))) : "")));
  20 }
  21
  22 void set_dom_state(entity e)
  23 {
  24         STAT(DOM_TOTAL_PPS, e) = total_pps;
  25         STAT(DOM_PPS_RED, e) = pps_red;
  26         STAT(DOM_PPS_BLUE, e) = pps_blue;
  27         if(domination_teams >= 3)
  28                 STAT(DOM_PPS_YELLOW, e) = pps_yellow;
  29         if(domination_teams >= 4)
  30                 STAT(DOM_PPS_PINK, e) = pps_pink;
  31 }
  32
  33 void dompoint_captured(entity this)
  34 {
  35         float old_delay, old_team, real_team;
  36
  37         // now that the delay has expired, switch to the latest team to lay claim to this point
  38         entity head = this.owner;
  39
  40         real_team = this.cnt;
  41         this.cnt = -1;
  42
  43         dom_EventLog("taken", this.team, this.dmg_inflictor);
  44         this.dmg_inflictor = NULL;
  45
  46         this.goalentity = head;
  47         this.model = head.mdl;
  48         this.modelindex = head.dmg;
  49         this.skin = head.skin;
  50
  51         float points, wait_time;
  52         if (autocvar_g_domination_point_amt)
  53                 points = autocvar_g_domination_point_amt;
  54         else
  55                 points = this.frags;
  56         if (autocvar_g_domination_point_rate)
  57                 wait_time = autocvar_g_domination_point_rate;
  58         else
  59                 wait_time = this.wait;
  60
  61         if(domination_roundbased)
  62                 bprint(sprintf("^3%s^3%s\n", head.netname, this.message));
  63         else
  64                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_DOMINATION_CAPTURE_TIME, head.netname, this.message, points, wait_time);
  65
  66         if(this.enemy.playerid == this.enemy_playerid)
  67                 GameRules_scoring_add(this.enemy, DOM_TAKES, 1);
  68         else
  69                 this.enemy = NULL;
  70
  71         if (head.noise != "")
  72                 if(this.enemy)
  73                         _sound(this.enemy, CH_TRIGGER, head.noise, VOL_BASE, ATTEN_NORM);
  74                 else
  75                         _sound(this, CH_TRIGGER, head.noise, VOL_BASE, ATTEN_NORM);
  76         if (head.noise1 != "")
  77                 play2all(head.noise1);
  78
  79         this.delay = time + wait_time;
  80
  81         // do trigger work
  82         old_delay = this.delay;
  83         old_team = this.team;
  84         this.team = real_team;
  85         this.delay = 0;
  86         SUB_UseTargets (this, this, NULL);
  87         this.delay = old_delay;
  88         this.team = old_team;
  89
  90         entity msg = WP_DomNeut;
  91         switch(real_team)
  92         {
  93                 case NUM_TEAM_1: msg = WP_DomRed; break;
  94                 case NUM_TEAM_2: msg = WP_DomBlue; break;
  95                 case NUM_TEAM_3: msg = WP_DomYellow; break;
  96                 case NUM_TEAM_4: msg = WP_DomPink; break;
  97         }
  98
  99         WaypointSprite_UpdateSprites(this.sprite, msg, WP_Null, WP_Null);
 100
 101         total_pps = 0, pps_red = 0, pps_blue = 0, pps_yellow = 0, pps_pink = 0;
 102         IL_EACH(g_dompoints, true,
 103         {
 104                 if (autocvar_g_domination_point_amt)
 105                         points = autocvar_g_domination_point_amt;
 106                 else
 107                         points = it.frags;
 108                 if (autocvar_g_domination_point_rate)
 109                         wait_time = autocvar_g_domination_point_rate;
 110                 else
 111                         wait_time = it.wait;
 112                 switch(it.goalentity.team)
 113                 {
 114                         case NUM_TEAM_1: pps_red += points/wait_time; break;
 115                         case NUM_TEAM_2: pps_blue += points/wait_time; break;
 116                         case NUM_TEAM_3: pps_yellow += points/wait_time; break;
 117                         case NUM_TEAM_4: pps_pink += points/wait_time; break;
 118                 }
 119                 total_pps += points/wait_time;
 120         });
 121
 122         WaypointSprite_UpdateTeamRadar(this.sprite, RADARICON_DOMPOINT, colormapPaletteColor(this.goalentity.team - 1, 0));
 123         WaypointSprite_Ping(this.sprite);
 124
 125         this.captime = time;
 126
 127         FOREACH_CLIENT(IS_REAL_CLIENT(it), { set_dom_state(it); });
 128 }
 129
 130 void AnimateDomPoint(entity this)
 131 {
 132         if(this.pain_finished > time)
 133                 return;
 134         this.pain_finished = time + this.t_width;
 135         if(this.nextthink > this.pain_finished)
 136                 this.nextthink = this.pain_finished;
 137
 138         this.frame = this.frame + 1;
 139         if(this.frame > this.t_length)
 140                 this.frame = 0;
 141 }
 142
 143 void dompointthink(entity this)
 144 {
 145         float fragamt;
 146
 147         this.nextthink = time + 0.1;
 148
 149         //this.frame = this.frame + 1;
 150         //if(this.frame > 119)
 151         //      this.frame = 0;
 152         AnimateDomPoint(this);
 153
 154         // give points
 155
 156         if (game_stopped || this.delay > time || time < game_starttime) // game has ended, don't keep giving points
 157                 return;
 158
 159         if(autocvar_g_domination_point_rate)
 160                 this.delay = time + autocvar_g_domination_point_rate;
 161         else
 162                 this.delay = time + this.wait;
 163
 164         // give credit to the team
 165         // NOTE: this defaults to 0
 166         if (!domination_roundbased)
 167         if (this.goalentity.netname != "")
 168         {
 169                 if(autocvar_g_domination_point_amt)
 170                         fragamt = autocvar_g_domination_point_amt;
 171                 else
 172                         fragamt = this.frags;
 173                 TeamScore_AddToTeam(this.goalentity.team, ST_SCORE, fragamt);
 174                 TeamScore_AddToTeam(this.goalentity.team, ST_DOM_TICKS, fragamt);
 175
 176                 // give credit to the individual player, if he is still there
 177                 if (this.enemy.playerid == this.enemy_playerid)
 178                 {
 179                         GameRules_scoring_add(this.enemy, SCORE, fragamt);
 180                         GameRules_scoring_add(this.enemy, DOM_TICKS, fragamt);
 181                 }
 182                 else
 183                         this.enemy = NULL;
 184         }
 185 }
 186
 187 void dompointtouch(entity this, entity toucher)
 188 {
 189         if(!IS_PLAYER(toucher))
 190                 return;
 191         if(GetResourceAmount(toucher, RESOURCE_HEALTH) < 1)
 192                 return;
 193
 194         if(round_handler_IsActive() && !round_handler_IsRoundStarted())
 195                 return;
 196
 197         if(time < this.captime + 0.3)
 198                 return;
 199
 200         // only valid teams can claim it
 201         entity head = find(NULL, classname, "dom_team");
 202         while (head && head.team != toucher.team)
 203                 head = find(head, classname, "dom_team");
 204         if (!head || head.netname == "" || head == this.goalentity)
 205                 return;
 206
 207         // delay capture
 208
 209         this.team = this.goalentity.team; // this stores the PREVIOUS team!
 210
 211         this.cnt = toucher.team;
 212         this.owner = head; // team to switch to after the delay
 213         this.dmg_inflictor = toucher;
 214
 215         // this.state = 1;
 216         // this.delay = time + cvar("g_domination_point_capturetime");
 217         //this.nextthink = time + cvar("g_domination_point_capturetime");
 218         //this.think = dompoint_captured;
 219
 220         // go to neutral team in the mean time
 221         head = find(NULL, classname, "dom_team");
 222         while (head && head.netname != "")
 223                 head = find(head, classname, "dom_team");
 224         if(head == NULL)
 225                 return;
 226
 227         WaypointSprite_UpdateSprites(this.sprite, WP_DomNeut, WP_Null, WP_Null);
 228         WaypointSprite_UpdateTeamRadar(this.sprite, RADARICON_DOMPOINT, '0 1 1');
 229         WaypointSprite_Ping(this.sprite);
 230
 231         this.goalentity = head;
 232         this.model = head.mdl;
 233         this.modelindex = head.dmg;
 234         this.skin = head.skin;
 235
 236         this.enemy = toucher; // individual player scoring
 237         this.enemy_playerid = toucher.playerid;
 238         dompoint_captured(this);
 239 }
 240
 241 void dom_controlpoint_setup(entity this)
 242 {
 243         entity head;
 244         // find the spawnfunc_dom_team representing unclaimed points
 245         head = find(NULL, classname, "dom_team");
 246         while(head && head.netname != "")
 247                 head = find(head, classname, "dom_team");
 248         if (!head)
 249                 objerror(this, "no spawnfunc_dom_team with netname \"\" found\n");
 250
 251         // copy important properties from spawnfunc_dom_team entity
 252         this.goalentity = head;
 253         _setmodel(this, head.mdl); // precision already set
 254         this.skin = head.skin;
 255
 256         this.cnt = -1;
 257
 258         if(this.message == "")
 259                 this.message = " has captured a control point";
 260
 261         if(this.frags <= 0)
 262                 this.frags = 1;
 263         if(this.wait <= 0)
 264                 this.wait = 5;
 265
 266         float points, waittime;
 267         if (autocvar_g_domination_point_amt)
 268                 points = autocvar_g_domination_point_amt;
 269         else
 270                 points = this.frags;
 271         if (autocvar_g_domination_point_rate)
 272                 waittime = autocvar_g_domination_point_rate;
 273         else
 274                 waittime = this.wait;
 275
 276         total_pps += points/waittime;
 277
 278         if(!this.t_width)
 279                 this.t_width = 0.02; // frame animation rate
 280         if(!this.t_length)
 281                 this.t_length = 239; // maximum frame
 282
 283         setthink(this, dompointthink);
 284         this.nextthink = time;
 285         settouch(this, dompointtouch);
 286         this.solid = SOLID_TRIGGER;
 287         if(!this.flags & FL_ITEM)
 288                 IL_PUSH(g_items, this);
 289         this.flags = FL_ITEM;
 290         setsize(this, '-32 -32 -32', '32 32 32');
 291         setorigin(this, this.origin + '0 0 20');
 292         droptofloor(this);
 293
 294         waypoint_spawnforitem(this);
 295         WaypointSprite_SpawnFixed(WP_DomNeut, this.origin + '0 0 32', this, sprite, RADARICON_DOMPOINT);
 296 }
 297
 298 int total_control_points;
 299 void Domination_count_controlpoints()
 300 {
 301         total_control_points = 0;
 302         for (int i = 1; i <= NUM_TEAMS; ++i)
 303         {
 304                 Team_SetNumberOfControlPoints(Team_GetTeamFromIndex(i), 0);
 305         }
 306         IL_EACH(g_dompoints, true,
 307         {
 308                 ++total_control_points;
 309                 if (!Entity_HasValidTeam(it.goalentity))
 310                 {
 311                         continue;
 312                 }
 313                 entity team_ = Entity_GetTeam(it.goalentity);
 314                 int num_control_points = Team_GetNumberOfControlPoints(team_);
 315                 ++num_control_points;
 316                 Team_SetNumberOfControlPoints(team_, num_control_points);
 317         });
 318 }
 319
 320 int Domination_GetWinnerTeam()
 321 {
 322         int winner_team = 0;
 323         if (Team_GetNumberOfControlPoints(Team_GetTeamFromIndex(1)) ==
 324                 total_control_points)
 325         {
 326                 winner_team = NUM_TEAM_1;
 327         }
 328         for (int i = 2; i <= NUM_TEAMS; ++i)
 329         {
 330                 if (Team_GetNumberOfControlPoints(Team_GetTeamFromIndex(i)) ==
 331                         total_control_points)
 332                 {
 333                         if (winner_team != 0)
 334                         {
 335                                 return 0;
 336                         }
 337                         winner_team = Team_IndexToTeam(i);
 338                 }
 339         }
 340         if (winner_team)
 341         {
 342                 return winner_team;
 343         }
 344         return -1; // no control points left?
 345 }
 346
 347 bool Domination_CheckWinner()
 348 {
 349         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
 350         {
 351                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
 352                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
 353
 354                 game_stopped = true;
 355                 round_handler_Init(5, autocvar_g_domination_warmup, autocvar_g_domination_round_timelimit);
 356                 return true;
 357         }
 358
 359         Domination_count_controlpoints();
 360
 361         float winner_team = Domination_GetWinnerTeam();
 362
 363         if(winner_team == -1)
 364                 return false;
 365
 366         if(winner_team > 0)
 367         {
 368                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 369                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 370                 TeamScore_AddToTeam(winner_team, ST_DOM_CAPS, +1);
 371         }
 372         else if(winner_team == -1)
 373         {
 374                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
 375                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
 376         }
 377
 378         game_stopped = true;
 379         round_handler_Init(5, autocvar_g_domination_warmup, autocvar_g_domination_round_timelimit);
 380
 381         return true;
 382 }
 383
 384 bool Domination_CheckPlayers()
 385 {
 386         return true;
 387 }
 388
 389 void Domination_RoundStart()
 390 {
 391         FOREACH_CLIENT(IS_PLAYER(it), { it.player_blocked = false; });
 392 }
 393
 394 //go to best items, or control points you don't own
 395 void havocbot_goalrating_controlpoints(entity this, float ratingscale, vector org, float sradius)
 396 {
 397         IL_EACH(g_dompoints, vdist((((it.absmin + it.absmax) * 0.5) - org), <, sradius),
 398         {
 399                 if(it.cnt > -1) // this is just being fought
 400                         navigation_routerating(this, it, ratingscale, 5000);
 401                 else if(it.goalentity.cnt == 0) // unclaimed
 402                         navigation_routerating(this, it, ratingscale, 5000);
 403                 else if(it.goalentity.team != this.team) // other team's point
 404                         navigation_routerating(this, it, ratingscale, 5000);
 405         });
 406 }
 407
 408 void havocbot_role_dom(entity this)
 409 {
 410         if(IS_DEAD(this))
 411                 return;
 412
 413         if (navigation_goalrating_timeout(this))
 414         {
 415                 navigation_goalrating_start(this);
 416                 havocbot_goalrating_controlpoints(this, 10000, this.origin, 15000);
 417                 havocbot_goalrating_items(this, 20000, this.origin, 8000);
 418                 //havocbot_goalrating_enemyplayers(this, 1500, this.origin, 2000);
 419                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 420                 navigation_goalrating_end(this);
 421
 422                 navigation_goalrating_timeout_set(this);
 423         }
 424 }
 425
 426 MUTATOR_HOOKFUNCTION(dom, TeamBalance_CheckAllowedTeams)
 427 {
 428         // fallback?
 429         M_ARGV(0, float) = domination_teams;
 430         string ret_string = "dom_team";
 431
 432         entity head = find(NULL, classname, ret_string);
 433         while(head)
 434         {
 435                 if(head.netname != "")
 436                 {
 437                         if (Team_IsValidTeam(head.team))
 438                         {
 439                                 M_ARGV(0, float) |= Team_TeamToBit(head.team);
 440                         }
 441                 }
 442
 443                 head = find(head, classname, ret_string);
 444         }
 445
 446         M_ARGV(1, string) = string_null;
 447
 448         return true;
 449 }
 450
 451 MUTATOR_HOOKFUNCTION(dom, reset_map_players)
 452 {
 453         total_pps = 0, pps_red = 0, pps_blue = 0, pps_yellow = 0, pps_pink = 0;
 454         FOREACH_CLIENT(IS_PLAYER(it), {
 455                 PutClientInServer(it);
 456                 if(domination_roundbased)
 457                         it.player_blocked = 1;
 458                 if(IS_REAL_CLIENT(it))
 459                         set_dom_state(it);
 460         });
 461         return true;
 462 }
 463
 464 MUTATOR_HOOKFUNCTION(dom, PlayerSpawn)
 465 {
 466         entity player = M_ARGV(0, entity);
 467
 468         if(domination_roundbased)
 469         if(!round_handler_IsRoundStarted())
 470                 player.player_blocked = 1;
 471         else
 472                 player.player_blocked = 0;
 473 }
 474
 475 MUTATOR_HOOKFUNCTION(dom, ClientConnect)
 476 {
 477         entity player = M_ARGV(0, entity);
 478
 479         set_dom_state(player);
 480 }
 481
 482 MUTATOR_HOOKFUNCTION(dom, HavocBot_ChooseRole)
 483 {
 484         entity bot = M_ARGV(0, entity);
 485
 486         bot.havocbot_role = havocbot_role_dom;
 487         return true;
 488 }
 489
 490 /*QUAKED spawnfunc_dom_controlpoint (0 .5 .8) (-16 -16 -24) (16 16 32)
 491 Control point for Domination gameplay.
 492 */
 493 spawnfunc(dom_controlpoint)
 494 {
 495         if(!g_domination)
 496         {
 497                 delete(this);
 498                 return;
 499         }
 500         setthink(this, dom_controlpoint_setup);
 501         this.nextthink = time + 0.1;
 502         this.reset = dom_controlpoint_setup;
 503
 504         if(!this.scale)
 505                 this.scale = 0.6;
 506
 507         this.effects = this.effects | EF_LOWPRECISION;
 508         if (autocvar_g_domination_point_fullbright)
 509                 this.effects |= EF_FULLBRIGHT;
 510
 511         IL_PUSH(g_dompoints, this);
 512 }
 513
 514 /*QUAKED spawnfunc_dom_team (0 .5 .8) (-32 -32 -24) (32 32 32)
 515 Team declaration for Domination gameplay, this allows you to decide what team
 516 names and control point models are used in your map.
 517
 518 Note: If you use spawnfunc_dom_team entities you must define at least 3 and only two
 519 can have netname set!  The nameless team owns all control points at start.
 520
 521 Keys:
 522 "netname"
 523  Name of the team (for example Red Team, Blue Team, Green Team, Yellow Team, Life, Death, etc)
 524 "cnt"
 525  Scoreboard color of the team (for example 4 is red and 13 is blue)
 526 "model"
 527  Model to use for control points owned by this team (for example
 528  "progs/b_g_key.mdl" is a gold keycard, and "progs/b_s_key.mdl" is a silver
 529  keycard)
 530 "skin"
 531  Skin of the model to use (for team skins on a single model)
 532 "noise"
 533  Sound to play when this team captures a point.
 534  (this is a localized sound, like a small alarm or other effect)
 535 "noise1"
 536  Narrator speech to play when this team captures a point.
 537  (this is a global sound, like "Red team has captured a control point")
 538 */
 539
 540 spawnfunc(dom_team)
 541 {
 542         if(!g_domination || autocvar_g_domination_teams_override >= 2)
 543         {
 544                 delete(this);
 545                 return;
 546         }
 547         precache_model(this.model);
 548         if (this.noise != "")
 549                 precache_sound(this.noise);
 550         if (this.noise1 != "")
 551                 precache_sound(this.noise1);
 552         this.classname = "dom_team";
 553         _setmodel(this, this.model); // precision not needed
 554         this.mdl = this.model;
 555         this.dmg = this.modelindex;
 556         this.model = "";
 557         this.modelindex = 0;
 558         // this would have to be changed if used in quakeworld
 559         if(this.cnt)
 560                 this.team = this.cnt + 1; // WHY are these different anyway?
 561 }
 562
 563 // scoreboard setup
 564 void ScoreRules_dom(int teams)
 565 {
 566         if(domination_roundbased)
 567         {
 568             GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, 0, {
 569             field_team(ST_DOM_CAPS, "caps", SFL_SORT_PRIO_PRIMARY);
 570             field(SP_DOM_TAKES, "takes", 0);
 571             });
 572         }
 573         else
 574         {
 575                 float sp_domticks, sp_score;
 576                 sp_score = sp_domticks = 0;
 577                 if(autocvar_g_domination_disable_frags)
 578                         sp_domticks = SFL_SORT_PRIO_PRIMARY;
 579                 else
 580                         sp_score = SFL_SORT_PRIO_PRIMARY;
 581                 GameRules_scoring(teams, sp_score, sp_score, {
 582             field_team(ST_DOM_TICKS, "ticks", sp_domticks);
 583             field(SP_DOM_TICKS, "ticks", sp_domticks);
 584             field(SP_DOM_TAKES, "takes", 0);
 585                 });
 586         }
 587 }
 588
 589 // code from here on is just to support maps that don't have control point and team entities
 590 void dom_spawnteam(string teamname, float teamcolor, string pointmodel, float pointskin, Sound capsound, string capnarration, string capmessage)
 591 {
 592         TC(Sound, capsound);
 593         entity e = new_pure(dom_team);
 594         e.netname = strzone(teamname);
 595         e.cnt = teamcolor;
 596         e.model = pointmodel;
 597         e.skin = pointskin;
 598         e.noise = strzone(Sound_fixpath(capsound));
 599         e.noise1 = strzone(capnarration);
 600         e.message = strzone(capmessage);
 601
 602         // this code is identical to spawnfunc_dom_team
 603         _setmodel(e, e.model); // precision not needed
 604         e.mdl = e.model;
 605         e.dmg = e.modelindex;
 606         e.model = "";
 607         e.modelindex = 0;
 608         // this would have to be changed if used in quakeworld
 609         e.team = e.cnt + 1;
 610
 611         //eprint(e);
 612 }
 613
 614 void dom_spawnpoint(vector org)
 615 {
 616         entity e = spawn();
 617         e.classname = "dom_controlpoint";
 618         setthink(e, spawnfunc_dom_controlpoint);
 619         e.nextthink = time;
 620         setorigin(e, org);
 621         spawnfunc_dom_controlpoint(e);
 622 }
 623
 624 // spawn some default teams if the map is not set up for domination
 625 void dom_spawnteams(int teams)
 626 {
 627         TC(int, teams);
 628         dom_spawnteam(Team_ColoredFullName(NUM_TEAM_1), NUM_TEAM_1-1, "models/domination/dom_red.md3", 0, SND_DOM_CLAIM, "", "Red team has captured a control point");
 629         dom_spawnteam(Team_ColoredFullName(NUM_TEAM_2), NUM_TEAM_2-1, "models/domination/dom_blue.md3", 0, SND_DOM_CLAIM, "", "Blue team has captured a control point");
 630         if(teams >= 3)
 631                 dom_spawnteam(Team_ColoredFullName(NUM_TEAM_3), NUM_TEAM_3-1, "models/domination/dom_yellow.md3", 0, SND_DOM_CLAIM, "", "Yellow team has captured a control point");
 632         if(teams >= 4)
 633                 dom_spawnteam(Team_ColoredFullName(NUM_TEAM_4), NUM_TEAM_4-1, "models/domination/dom_pink.md3", 0, SND_DOM_CLAIM, "", "Pink team has captured a control point");
 634         dom_spawnteam("", 0, "models/domination/dom_unclaimed.md3", 0, SND_Null, "", "");
 635 }
 636
 637 void dom_DelayedInit(entity this) // Do this check with a delay so we can wait for teams to be set up.
 638 {
 639         // if no teams are found, spawn defaults
 640         if(find(NULL, classname, "dom_team") == NULL || autocvar_g_domination_teams_override >= 2)
 641         {
 642                 LOG_TRACE("No \"dom_team\" entities found on this map, creating them anyway.");
 643                 domination_teams = autocvar_g_domination_teams_override;
 644                 if (domination_teams < 2)
 645                         domination_teams = autocvar_g_domination_default_teams;
 646                 domination_teams = bound(2, domination_teams, 4);
 647                 dom_spawnteams(domination_teams);
 648         }
 649
 650         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 651         int teams = TeamBalance_GetAllowedTeams(balance);
 652         TeamBalance_Destroy(balance);
 653         domination_teams = teams;
 654
 655         domination_roundbased = autocvar_g_domination_roundbased;
 656
 657         ScoreRules_dom(domination_teams);
 658
 659         if(domination_roundbased)
 660         {
 661                 round_handler_Spawn(Domination_CheckPlayers, Domination_CheckWinner, Domination_RoundStart);
 662                 round_handler_Init(5, autocvar_g_domination_warmup, autocvar_g_domination_round_timelimit);
 663         }
 664 }
 665
 666 void dom_Initialize()
 667 {
 668         g_domination = true;
 669         InitializeEntity(NULL, dom_DelayedInit, INITPRIO_GAMETYPE);
 670 }