qcsrc/common/gamemodes/gamemode/freezetag/sv_freezetag.qc

   1 #include "sv_freezetag.qh"
   2
   3 #include <server/resources.qh>
   4
   5 float autocvar_g_freezetag_frozen_maxtime;
   6 float autocvar_g_freezetag_revive_clearspeed;
   7 float autocvar_g_freezetag_round_timelimit;
   8 //int autocvar_g_freezetag_teams;
   9 int autocvar_g_freezetag_teams_override;
  10 float autocvar_g_freezetag_warmup;
  11
  12 void freezetag_count_alive_players()
  13 {
  14         total_players = 0;
  15         for (int i = 1; i <= NUM_TEAMS; ++i)
  16         {
  17                 Team_SetNumberOfAlivePlayers(Team_GetTeamFromIndex(i), 0);
  18         }
  19         FOREACH_CLIENT(IS_PLAYER(it) && Entity_HasValidTeam(it),
  20         {
  21                 ++total_players;
  22                 if (GetResource(it, RES_HEALTH) < 1 || STAT(FROZEN, it) == FROZEN_NORMAL)
  23                 {
  24                         continue;
  25                 }
  26                 entity team_ = Entity_GetTeam(it);
  27                 int num_alive = Team_GetNumberOfAlivePlayers(team_);
  28                 ++num_alive;
  29                 Team_SetNumberOfAlivePlayers(team_, num_alive);
  30         });
  31         FOREACH_CLIENT(IS_REAL_CLIENT(it),
  32         {
  33                 STAT(REDALIVE, it) = Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(
  34                         1));
  35                 STAT(BLUEALIVE, it) = Team_GetNumberOfAlivePlayers(
  36                         Team_GetTeamFromIndex(2));
  37                 STAT(YELLOWALIVE, it) = Team_GetNumberOfAlivePlayers(
  38                         Team_GetTeamFromIndex(3));
  39                 STAT(PINKALIVE, it) = Team_GetNumberOfAlivePlayers(
  40                         Team_GetTeamFromIndex(4));
  41         });
  42
  43         eliminatedPlayers.SendFlags |= 1;
  44 }
  45
  46 bool freezetag_CheckTeams()
  47 {
  48         static float prev_missing_teams_mask;
  49         if (Team_GetNumberOfAliveTeams() == NumTeams(freezetag_teams))
  50         {
  51                 if(prev_missing_teams_mask > 0)
  52                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
  53                 prev_missing_teams_mask = -1;
  54                 return true;
  55         }
  56         if(total_players == 0)
  57         {
  58                 if(prev_missing_teams_mask > 0)
  59                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
  60                 prev_missing_teams_mask = -1;
  61                 return false;
  62         }
  63         int missing_teams_mask = 0;
  64         for (int i = 1; i <= NUM_TEAMS; ++i)
  65         {
  66                 if ((freezetag_teams & Team_IndexToBit(i)) &&
  67                         (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(i)) == 0))
  68                 {
  69                         missing_teams_mask |= Team_IndexToBit(i);
  70                 }
  71         }
  72         if(prev_missing_teams_mask != missing_teams_mask)
  73         {
  74                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
  75                 prev_missing_teams_mask = missing_teams_mask;
  76         }
  77         return false;
  78 }
  79
  80 int freezetag_getWinnerTeam()
  81 {
  82         int winner_team = 0;
  83         if (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(1)) >= 1)
  84         {
  85                 winner_team = NUM_TEAM_1;
  86         }
  87         for (int i = 2; i <= NUM_TEAMS; ++i)
  88         {
  89                 if (Team_GetNumberOfAlivePlayers(Team_GetTeamFromIndex(i)) >= 1)
  90                 {
  91                         if (winner_team != 0)
  92                         {
  93                                 return 0;
  94                         }
  95                         winner_team = Team_IndexToTeam(i);
  96                 }
  97         }
  98         if (winner_team)
  99         {
 100                 return winner_team;
 101         }
 102         return -1; // no player left
 103 }
 104
 105 void nades_Clear(entity);
 106 void nades_GiveBonus(entity player, float score);
 107
 108 bool freezetag_CheckWinner()
 109 {
 110         if(round_handler_GetEndTime() > 0 && round_handler_GetEndTime() - time <= 0)
 111         {
 112                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_OVER);
 113                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_OVER);
 114                 FOREACH_CLIENT(IS_PLAYER(it), {
 115                         it.freezetag_frozen_timeout = 0;
 116                         nades_Clear(it);
 117                 });
 118                 game_stopped = true;
 119                 round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 120                 return true;
 121         }
 122
 123         if (Team_GetNumberOfAliveTeams() > 1)
 124         {
 125                 return false;
 126         }
 127
 128         int winner_team = freezetag_getWinnerTeam();
 129         if(winner_team > 0)
 130         {
 131                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 132                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_ROUND_TEAM_WIN));
 133                 TeamScore_AddToTeam(winner_team, ST_FT_ROUNDS, +1);
 134         }
 135         else if(winner_team == -1)
 136         {
 137                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_ROUND_TIED);
 138                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_ROUND_TIED);
 139         }
 140
 141         FOREACH_CLIENT(IS_PLAYER(it), {
 142                 it.freezetag_frozen_timeout = 0;
 143                 nades_Clear(it);
 144         });
 145
 146         game_stopped = true;
 147         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 148         return true;
 149 }
 150
 151 entity freezetag_LastPlayerForTeam(entity this)
 152 {
 153         entity last_pl = NULL;
 154         FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), {
 155                 if (STAT(FROZEN, it) != FROZEN_NORMAL && GetResource(it, RES_HEALTH) >= 1)
 156                 {
 157                         if (!last_pl)
 158                                 last_pl = it;
 159                         else
 160                                 return NULL;
 161                 }
 162         });
 163         return last_pl;
 164 }
 165
 166 void freezetag_LastPlayerForTeam_Notify(entity this)
 167 {
 168         if(round_handler_IsActive())
 169         if(round_handler_IsRoundStarted())
 170         {
 171                 entity pl = freezetag_LastPlayerForTeam(this);
 172                 if(pl)
 173                         Send_Notification(NOTIF_ONE, pl, MSG_CENTER, CENTER_ALONE);
 174         }
 175 }
 176
 177 void freezetag_Add_Score(entity targ, entity attacker)
 178 {
 179         if(attacker == targ)
 180         {
 181                 // you froze your own dumb targ
 182                 // counted as "suicide" already
 183                 GameRules_scoring_add(targ, SCORE, -1);
 184         }
 185         else if(IS_PLAYER(attacker))
 186         {
 187                 // got frozen by an enemy
 188                 // counted as "kill" and "death" already
 189                 GameRules_scoring_add(targ, SCORE, -1);
 190                 GameRules_scoring_add(attacker, SCORE, +1);
 191         }
 192         // else nothing - got frozen by the game type rules themselves
 193 }
 194
 195 // to be called when the player is frozen by freezetag (on death, spectator join etc), gives the score
 196 void freezetag_Freeze(entity targ, entity attacker)
 197 {
 198         if(STAT(FROZEN, targ))
 199                 return;
 200
 201         if(autocvar_g_freezetag_frozen_maxtime > 0)
 202                 targ.freezetag_frozen_timeout = time + autocvar_g_freezetag_frozen_maxtime;
 203
 204         Freeze(targ, 0, FROZEN_NORMAL, true);
 205
 206         freezetag_count_alive_players();
 207
 208         freezetag_Add_Score(targ, attacker);
 209 }
 210
 211 bool freezetag_isEliminated(entity e)
 212 {
 213         if(IS_PLAYER(e) && (STAT(FROZEN, e) == FROZEN_NORMAL || IS_DEAD(e)))
 214                 return true;
 215         return false;
 216 }
 217
 218
 219 // ================
 220 // Bot player logic
 221 // ================
 222
 223 void(entity this) havocbot_role_ft_freeing;
 224 void(entity this) havocbot_role_ft_offense;
 225
 226 void havocbot_goalrating_ft_freeplayers(entity this, float ratingscale, vector org, float sradius)
 227 {
 228         entity best_pl = NULL;
 229         float best_dist2 = FLOAT_MAX;
 230         FOREACH_CLIENT(IS_PLAYER(it) && it != this && SAME_TEAM(it, this), {
 231                 if (STAT(FROZEN, it) == FROZEN_NORMAL)
 232                 {
 233                         if(vdist(it.origin - org, >, sradius))
 234                                 continue;
 235                         navigation_routerating(this, it, ratingscale, 2000);
 236                 }
 237                 else if (best_dist2
 238                         && GetResource(it, RES_HEALTH) < GetResource(this, RES_HEALTH) + 30
 239                         && vlen2(it.origin - org) < best_dist2)
 240                 {
 241                         // If teamate is not frozen still seek them out as fight better
 242                         // in a group.
 243                         best_dist2 = vlen2(it.origin - org);
 244                         if (best_dist2 < 700 ** 2)
 245                         {
 246                                 best_pl = NULL;
 247                                 best_dist2 = 0; // already close to a teammate
 248                         }
 249                         else
 250                                 best_pl = it;
 251                 }
 252         });
 253         if (best_pl)
 254                 navigation_routerating(this, best_pl, ratingscale / 2, 2000);
 255 }
 256
 257 void havocbot_role_ft_offense(entity this)
 258 {
 259         if(IS_DEAD(this))
 260                 return;
 261
 262         if (!this.havocbot_role_timeout)
 263                 this.havocbot_role_timeout = time + random() * 10 + 20;
 264
 265         // Count how many players on team are unfrozen.
 266         int unfrozen = 0;
 267         FOREACH_CLIENT(IS_PLAYER(it) && SAME_TEAM(it, this) && STAT(FROZEN, it) != FROZEN_NORMAL, {
 268                 unfrozen++;
 269         });
 270
 271         // If only one left on team or if role has timed out then start trying to free players.
 272         if ((!unfrozen && STAT(FROZEN, this) != FROZEN_NORMAL) || time > this.havocbot_role_timeout)
 273         {
 274                 LOG_TRACE("changing role to freeing");
 275                 this.havocbot_role = havocbot_role_ft_freeing;
 276                 this.havocbot_role_timeout = 0;
 277                 return;
 278         }
 279
 280         if (navigation_goalrating_timeout(this))
 281         {
 282                 navigation_goalrating_start(this);
 283                 havocbot_goalrating_items(this, 12000, this.origin, 10000);
 284                 havocbot_goalrating_enemyplayers(this, 10000, this.origin, 10000);
 285                 havocbot_goalrating_ft_freeplayers(this, 9000, this.origin, 10000);
 286                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 287                 navigation_goalrating_end(this);
 288
 289                 navigation_goalrating_timeout_set(this);
 290         }
 291 }
 292
 293 void havocbot_role_ft_freeing(entity this)
 294 {
 295         if(IS_DEAD(this))
 296                 return;
 297
 298         if (!this.havocbot_role_timeout)
 299                 this.havocbot_role_timeout = time + random() * 10 + 20;
 300
 301         if (time > this.havocbot_role_timeout)
 302         {
 303                 LOG_TRACE("changing role to offense");
 304                 this.havocbot_role = havocbot_role_ft_offense;
 305                 this.havocbot_role_timeout = 0;
 306                 return;
 307         }
 308
 309         if (navigation_goalrating_timeout(this))
 310         {
 311                 navigation_goalrating_start(this);
 312                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 313                 havocbot_goalrating_enemyplayers(this, 5000, this.origin, 10000);
 314                 havocbot_goalrating_ft_freeplayers(this, 20000, this.origin, 10000);
 315                 havocbot_goalrating_waypoints(this, 1, this.origin, 3000);
 316                 navigation_goalrating_end(this);
 317
 318                 navigation_goalrating_timeout_set(this);
 319         }
 320 }
 321
 322
 323 // ==============
 324 // Hook Functions
 325 // ==============
 326
 327 void ft_RemovePlayer(entity this)
 328 {
 329         if (STAT(FROZEN, this) != FROZEN_NORMAL)
 330                 freezetag_LastPlayerForTeam_Notify(this);
 331         Unfreeze(this, false);
 332
 333         SetResourceExplicit(this, RES_HEALTH, 0); // neccessary to correctly count alive players
 334         freezetag_count_alive_players();
 335 }
 336
 337 MUTATOR_HOOKFUNCTION(ft, ClientDisconnect)
 338 {
 339         entity player = M_ARGV(0, entity);
 340
 341         ft_RemovePlayer(player);
 342         return true;
 343 }
 344
 345 MUTATOR_HOOKFUNCTION(ft, MakePlayerObserver)
 346 {
 347         entity player = M_ARGV(0, entity);
 348
 349         ft_RemovePlayer(player);
 350 }
 351
 352 MUTATOR_HOOKFUNCTION(ft, PlayerDies)
 353 {
 354         entity frag_attacker = M_ARGV(1, entity);
 355         entity frag_target = M_ARGV(2, entity);
 356         float frag_deathtype = M_ARGV(3, float);
 357
 358         if(round_handler_IsActive())
 359         if(round_handler_CountdownRunning())
 360         {
 361                 if (STAT(FROZEN, frag_target) == FROZEN_NORMAL)
 362                         Unfreeze(frag_target, true);
 363                 freezetag_count_alive_players();
 364                 frag_target.respawn_time = time;
 365                 frag_target.respawn_flags |= RESPAWN_FORCE;
 366                 return true;
 367         }
 368
 369         // Cases DEATH_TEAMCHANGE and DEATH_AUTOTEAMCHANGE are needed to fix a bug whe
 370         // you succeed changing team through the menu: you both really die (gibbing) and get frozen
 371         if(ITEM_DAMAGE_NEEDKILL(frag_deathtype)
 372                 || frag_deathtype == DEATH_TEAMCHANGE.m_id || frag_deathtype == DEATH_AUTOTEAMCHANGE.m_id)
 373         {
 374                 // let the player die, he will be automatically frozen when he respawns
 375                 if (STAT(FROZEN, frag_target) != FROZEN_NORMAL)
 376                 {
 377                         freezetag_Add_Score(frag_target, frag_attacker);
 378                         freezetag_count_alive_players();
 379                         freezetag_LastPlayerForTeam_Notify(frag_target);
 380                 }
 381                 else
 382                         Unfreeze(frag_target, false); // remove ice
 383                 frag_target.freezetag_frozen_timeout = -2; // freeze on respawn
 384                 return true;
 385         }
 386
 387         if (STAT(FROZEN, frag_target) == FROZEN_NORMAL)
 388                 return true;
 389
 390         freezetag_Freeze(frag_target, frag_attacker);
 391         freezetag_LastPlayerForTeam_Notify(frag_target);
 392
 393         if(frag_attacker == frag_target || frag_attacker == NULL)
 394         {
 395                 if(IS_PLAYER(frag_target))
 396                         Send_Notification(NOTIF_ONE, frag_target, MSG_CENTER, CENTER_FREEZETAG_SELF);
 397                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_SELF, frag_target.netname);
 398         }
 399         else
 400         {
 401                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_FREEZE, frag_target.netname, frag_attacker.netname);
 402         }
 403
 404         return true;
 405 }
 406
 407 MUTATOR_HOOKFUNCTION(ft, PlayerSpawn)
 408 {
 409         entity player = M_ARGV(0, entity);
 410
 411         if(player.freezetag_frozen_timeout == -1) // if PlayerSpawn is called by reset_map_players
 412                 return true; // do nothing, round is starting right now
 413
 414         if(player.freezetag_frozen_timeout == -2) // player was dead
 415         {
 416                 freezetag_Freeze(player, NULL);
 417                 return true;
 418         }
 419
 420         freezetag_count_alive_players();
 421
 422         if(round_handler_IsActive())
 423         if(round_handler_IsRoundStarted())
 424         {
 425                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_SPAWN_LATE);
 426                 freezetag_Freeze(player, NULL);
 427         }
 428
 429         return true;
 430 }
 431
 432 MUTATOR_HOOKFUNCTION(ft, reset_map_players)
 433 {
 434         FOREACH_CLIENT(IS_PLAYER(it), {
 435                 CS(it).killcount = 0;
 436                 it.freezetag_frozen_timeout = -1;
 437                 PutClientInServer(it);
 438                 it.freezetag_frozen_timeout = 0;
 439         });
 440         freezetag_count_alive_players();
 441         return true;
 442 }
 443
 444 MUTATOR_HOOKFUNCTION(ft, GiveFragsForKill, CBC_ORDER_FIRST)
 445 {
 446         M_ARGV(2, float) = 0; // no frags counted in Freeze Tag
 447         return true;
 448 }
 449
 450 MUTATOR_HOOKFUNCTION(ft, Unfreeze)
 451 {
 452         entity targ = M_ARGV(0, entity);
 453         targ.freezetag_frozen_time = 0;
 454         targ.freezetag_frozen_timeout = 0;
 455 }
 456
 457 #ifdef IS_REVIVING
 458         #undef IS_REVIVING
 459 #endif
 460
 461 // returns true if player is reviving it
 462 #define IS_REVIVING(player, it, revive_extra_size) \
 463         (it != player && !STAT(FROZEN, it) && !IS_DEAD(it) && SAME_TEAM(it, player) \
 464         && boxesoverlap(player.absmin - revive_extra_size, player.absmax + revive_extra_size, it.absmin, it.absmax))
 465
 466 MUTATOR_HOOKFUNCTION(ft, PlayerPreThink, CBC_ORDER_FIRST)
 467 {
 468         if(game_stopped)
 469                 return true;
 470
 471         if(round_handler_IsActive())
 472         if(!round_handler_IsRoundStarted())
 473                 return true;
 474
 475         entity player = M_ARGV(0, entity);
 476         //if (STAT(FROZEN, player) == FROZEN_NORMAL)
 477         //if(player.freezetag_frozen_timeout > 0 && time < player.freezetag_frozen_timeout)
 478                 //player.iceblock.alpha = ICE_MIN_ALPHA + (ICE_MAX_ALPHA - ICE_MIN_ALPHA) * (player.freezetag_frozen_timeout - time) / (player.freezetag_frozen_timeout - player.freezetag_frozen_time);
 479
 480         if (!(frametime && IS_PLAYER(player)))
 481                 return true;
 482
 483         entity reviving_players_last = NULL;
 484         entity reviving_players_first = NULL;
 485
 486         int n;
 487         if(player.freezetag_frozen_timeout > 0 && time >= player.freezetag_frozen_timeout)
 488                 n = -1;
 489         else
 490         {
 491                 n = 0;
 492                 vector revive_extra_size = '1 1 1' * autocvar_g_freezetag_revive_extra_size;
 493                 FOREACH_CLIENT(IS_PLAYER(it) && IS_REVIVING(player, it, revive_extra_size), {
 494                         if (reviving_players_last)
 495                                 reviving_players_last.chain = it;
 496                         reviving_players_last = it;
 497                         if (!reviving_players_first)
 498                                 reviving_players_first = it;
 499                         ++n;
 500                 });
 501                 if (reviving_players_last)
 502                         reviving_players_last.chain = NULL;
 503         }
 504
 505         if (!n) // no teammate nearby
 506         {
 507                 if (STAT(FROZEN, player) == FROZEN_NORMAL)
 508                 {
 509                         STAT(REVIVE_PROGRESS, player) = bound(0, STAT(REVIVE_PROGRESS, player) - frametime * autocvar_g_freezetag_revive_clearspeed, 1);
 510                         SetResourceExplicit(player, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, player) * ((warmup_stage) ? warmup_start_health : start_health)));
 511                 }
 512                 else if (!STAT(FROZEN, player))
 513                         STAT(REVIVE_PROGRESS, player) = 0; // thawing nobody
 514         }
 515         else if (STAT(FROZEN, player) == FROZEN_NORMAL) // OK, there is at least one teammate reviving us
 516         {
 517                 STAT(REVIVE_PROGRESS, player) = bound(0, STAT(REVIVE_PROGRESS, player) + frametime * max(1/60, autocvar_g_freezetag_revive_speed), 1);
 518                 SetResourceExplicit(player, RES_HEALTH, max(1, STAT(REVIVE_PROGRESS, player) * ((warmup_stage) ? warmup_start_health : start_health)));
 519
 520                 if(STAT(REVIVE_PROGRESS, player) >= 1)
 521                 {
 522                         Unfreeze(player, false);
 523                         freezetag_count_alive_players();
 524
 525                         if(n == -1)
 526                         {
 527                                 Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_AUTO_REVIVED, autocvar_g_freezetag_frozen_maxtime);
 528                                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_AUTO_REVIVED, player.netname, autocvar_g_freezetag_frozen_maxtime);
 529                                 return true;
 530                         }
 531
 532                         // EVERY team mate nearby gets a point (even if multiple!)
 533                         for(entity it = reviving_players_first; it; it = it.chain)
 534                         {
 535                                 GameRules_scoring_add(it, FREEZETAG_REVIVALS, +1);
 536                                 GameRules_scoring_add(it, SCORE, +1);
 537                                 nades_GiveBonus(it, autocvar_g_nades_bonus_score_low);
 538                         }
 539
 540                         entity first = reviving_players_first;
 541                         Send_Notification(NOTIF_ONE, player, MSG_CENTER, CENTER_FREEZETAG_REVIVED, first.netname);
 542                         Send_Notification(NOTIF_ONE, first, MSG_CENTER, CENTER_FREEZETAG_REVIVE, player.netname);
 543                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, INFO_FREEZETAG_REVIVED, player.netname, first.netname);
 544                 }
 545
 546                 for(entity it = reviving_players_first; it; it = it.chain)
 547                         STAT(REVIVE_PROGRESS, it) = STAT(REVIVE_PROGRESS, player);
 548         }
 549
 550         return true;
 551 }
 552
 553 MUTATOR_HOOKFUNCTION(ft, SetStartItems)
 554 {
 555         start_items &= ~(IT_UNLIMITED_AMMO | IT_UNLIMITED_SUPERWEAPONS);
 556         //start_health       = warmup_start_health       = cvar("g_lms_start_health");
 557         //start_armorvalue   = warmup_start_armorvalue   = cvar("g_lms_start_armor");
 558         start_ammo_shells  = warmup_start_ammo_shells  = cvar("g_lms_start_ammo_shells");
 559         start_ammo_nails   = warmup_start_ammo_nails   = cvar("g_lms_start_ammo_nails");
 560         start_ammo_rockets = warmup_start_ammo_rockets = cvar("g_lms_start_ammo_rockets");
 561         start_ammo_cells   = warmup_start_ammo_cells   = cvar("g_lms_start_ammo_cells");
 562         start_ammo_plasma  = warmup_start_ammo_plasma  = cvar("g_lms_start_ammo_plasma");
 563         start_ammo_fuel    = warmup_start_ammo_fuel    = cvar("g_lms_start_ammo_fuel");
 564 }
 565
 566 MUTATOR_HOOKFUNCTION(ft, HavocBot_ChooseRole)
 567 {
 568         entity bot = M_ARGV(0, entity);
 569
 570         if (!IS_DEAD(bot))
 571         {
 572                 if (random() < 0.5)
 573                         bot.havocbot_role = havocbot_role_ft_freeing;
 574                 else
 575                         bot.havocbot_role = havocbot_role_ft_offense;
 576         }
 577
 578         // if bots spawn all at once assign them a more appropriated role after a while
 579         if (time < CS(bot).jointime + 1)
 580                 bot.havocbot_role_timeout = time + 10 + random() * 10;
 581
 582         return true;
 583 }
 584
 585 MUTATOR_HOOKFUNCTION(ft, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
 586 {
 587         M_ARGV(0, float) = freezetag_teams;
 588         return true;
 589 }
 590
 591 MUTATOR_HOOKFUNCTION(ft, SetWeaponArena)
 592 {
 593         if(M_ARGV(0, string) == "0" || M_ARGV(0, string) == "")
 594                 M_ARGV(0, string) = autocvar_g_freezetag_weaponarena;
 595 }
 596
 597 MUTATOR_HOOKFUNCTION(ft, FragCenterMessage)
 598 {
 599         entity frag_attacker = M_ARGV(0, entity);
 600         entity frag_target = M_ARGV(1, entity);
 601         //float frag_deathtype = M_ARGV(2, float);
 602         int kill_count_to_attacker = M_ARGV(3, int);
 603         int kill_count_to_target = M_ARGV(4, int);
 604
 605         if(STAT(FROZEN, frag_target) == FROZEN_NORMAL)
 606                 return; // target was already frozen, so this is just pushing them off the cliff
 607
 608         Send_Notification(NOTIF_ONE, frag_attacker, MSG_CHOICE, CHOICE_FRAG_FREEZE, frag_target.netname, kill_count_to_attacker, (IS_BOT_CLIENT(frag_target) ? -1 : CS(frag_target).ping));
 609         Send_Notification(NOTIF_ONE, frag_target, MSG_CHOICE, CHOICE_FRAGGED_FREEZE, frag_attacker.netname, kill_count_to_target,
 610                 GetResource(frag_attacker, RES_HEALTH), GetResource(frag_attacker, RES_ARMOR), (IS_BOT_CLIENT(frag_attacker) ? -1 : CS(frag_attacker).ping));
 611
 612         return true;
 613 }
 614
 615 MUTATOR_HOOKFUNCTION(ft, SV_ParseServerCommand)
 616 {
 617         string cmd_name = M_ARGV(0, string);
 618         if (cmd_name == "shuffleteams")
 619                 shuffleteams_on_reset_map = !(round_handler_IsActive() && !round_handler_IsRoundStarted());
 620         return false;
 621 }
 622
 623 MUTATOR_HOOKFUNCTION(ft, Scores_CountFragsRemaining)
 624 {
 625         // announce remaining frags
 626         return true;
 627 }
 628
 629 void freezetag_Initialize()
 630 {
 631         freezetag_teams = autocvar_g_freezetag_teams_override;
 632         if(freezetag_teams < 2)
 633                 freezetag_teams = cvar("g_freezetag_teams"); // read the cvar directly as it gets written earlier in the same frame
 634
 635         freezetag_teams = BITS(bound(2, freezetag_teams, 4));
 636         GameRules_scoring(freezetag_teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, {
 637                 field_team(ST_FT_ROUNDS, "rounds", SFL_SORT_PRIO_PRIMARY);
 638                 field(SP_FREEZETAG_REVIVALS, "revivals", 0);
 639         });
 640
 641         round_handler_Spawn(freezetag_CheckTeams, freezetag_CheckWinner, func_null);
 642         round_handler_Init(5, autocvar_g_freezetag_warmup, autocvar_g_freezetag_round_timelimit);
 643
 644         EliminatedPlayers_Init(freezetag_isEliminated);
 645 }