qcsrc/common/gamemodes/gamemode/keyhunt/sv_keyhunt.qc

   1 #include "sv_keyhunt.qh"
   2
   3 #include <server/gamelog.qh>
   4 #include <server/g_damage.qh>
   5
   6 float autocvar_g_balance_keyhunt_damageforcescale;
   7 float autocvar_g_balance_keyhunt_delay_collect;
   8 float autocvar_g_balance_keyhunt_delay_damage_return;
   9 float autocvar_g_balance_keyhunt_delay_return;
  10 float autocvar_g_balance_keyhunt_delay_round;
  11 float autocvar_g_balance_keyhunt_delay_tracking;
  12 float autocvar_g_balance_keyhunt_return_when_unreachable;
  13 float autocvar_g_balance_keyhunt_dropvelocity;
  14 float autocvar_g_balance_keyhunt_maxdist;
  15 float autocvar_g_balance_keyhunt_protecttime;
  16
  17 int autocvar_g_balance_keyhunt_score_capture;
  18 int autocvar_g_balance_keyhunt_score_carrierfrag;
  19 int autocvar_g_balance_keyhunt_score_collect;
  20 int autocvar_g_balance_keyhunt_score_destroyed;
  21 int autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
  22 int autocvar_g_balance_keyhunt_score_push;
  23 float autocvar_g_balance_keyhunt_throwvelocity;
  24
  25 //int autocvar_g_keyhunt_teams;
  26 int autocvar_g_keyhunt_teams_override;
  27
  28 // #define KH_PLAYER_USE_ATTACHMENT
  29 // TODO? no model exists for this
  30 // #define KH_PLAYER_USE_CARRIEDMODEL
  31
  32 #ifdef KH_PLAYER_USE_ATTACHMENT
  33 const vector KH_PLAYER_ATTACHMENT_DIST_ROTATED = '0 -4 0';
  34 const vector KH_PLAYER_ATTACHMENT_DIST = '4 0 0';
  35 const vector KH_PLAYER_ATTACHMENT = '0 0 0';
  36 const vector KH_PLAYER_ATTACHMENT_ANGLES = '0 0 0';
  37 const string KH_PLAYER_ATTACHMENT_BONE = "";
  38 #else
  39 const float KH_KEY_ZSHIFT = 22;
  40 const float KH_KEY_XYDIST = 24;
  41 const float KH_KEY_XYSPEED = 45;
  42 #endif
  43 const float KH_KEY_WP_ZSHIFT = 20;
  44
  45 const vector KH_KEY_MIN = '-10 -10 -46';
  46 const vector KH_KEY_MAX = '10 10 3';
  47 const float KH_KEY_BRIGHTNESS = 2;
  48
  49 bool kh_no_radar_circles;
  50
  51 // kh_state
  52 //     bits  0- 4: team of key 1, or 0 for no such key, or 30 for dropped, or 31 for self
  53 //     bits  5- 9: team of key 2, or 0 for no such key, or 30 for dropped, or 31 for self
  54 //     bits 10-14: team of key 3, or 0 for no such key, or 30 for dropped, or 31 for self
  55 //     bits 15-19: team of key 4, or 0 for no such key, or 30 for dropped, or 31 for self
  56 .float siren_time;  //  time delay the siren
  57 //.float stuff_time;  //  time delay to stuffcmd a cvar
  58
  59 int kh_Team_ByID(int t)
  60 {
  61         if(t == 0) return NUM_TEAM_1;
  62         if(t == 1) return NUM_TEAM_2;
  63         if(t == 2) return NUM_TEAM_3;
  64         if(t == 3) return NUM_TEAM_4;
  65         return 0;
  66 }
  67
  68 entity kh_controller;
  69 //bool kh_tracking_enabled;
  70 int kh_teams;
  71 int kh_interferemsg_team;
  72 float kh_interferemsg_time;
  73 .entity kh_next, kh_prev; // linked list
  74 .float kh_droptime;
  75 .int kh_dropperteam;
  76 .entity kh_previous_owner;
  77 .int kh_previous_owner_playerid;
  78
  79 int kh_key_dropped, kh_key_carried;
  80
  81 int kh_Key_AllOwnedByWhichTeam();
  82
  83 const int ST_KH_CAPS = 1;
  84 void kh_ScoreRules(int teams)
  85 {
  86         GameRules_scoring(teams, SFL_SORT_PRIO_PRIMARY, SFL_SORT_PRIO_PRIMARY, {
  87         field_team(ST_KH_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
  88         field(SP_KH_CAPS, "caps", SFL_SORT_PRIO_SECONDARY);
  89         field(SP_KH_PUSHES, "pushes", 0);
  90         field(SP_KH_DESTROYS, "destroyed", SFL_LOWER_IS_BETTER);
  91         field(SP_KH_PICKUPS, "pickups", 0);
  92         field(SP_KH_KCKILLS, "kckills", 0);
  93         field(SP_KH_LOSSES, "losses", SFL_LOWER_IS_BETTER);
  94         });
  95 }
  96
  97 bool kh_KeyCarrier_waypointsprite_visible_for_player(entity this, entity player, entity view)  // runs all the time
  98 {
  99         if(!IS_PLAYER(view) || DIFF_TEAM(this, view))
 100                 if(!kh_tracking_enabled)
 101                         return false;
 102
 103         return true;
 104 }
 105
 106 bool kh_Key_waypointsprite_visible_for_player(entity this, entity player, entity view)
 107 {
 108         if(!kh_tracking_enabled)
 109                 return false;
 110         if(!this.owner)
 111                 return true;
 112         if(!this.owner.owner)
 113                 return true;
 114         return false;  // draw only when key is not owned
 115 }
 116
 117 void kh_update_state()
 118 {
 119         entity key;
 120         int f;
 121         int s = 0;
 122         FOR_EACH_KH_KEY(key)
 123         {
 124                 if(key.owner)
 125                         f = key.team;
 126                 else
 127                         f = 30;
 128                 s |= (32 ** key.count) * f;
 129         }
 130
 131         FOREACH_CLIENT(true, { STAT(KH_KEYS, it) = s; });
 132
 133         FOR_EACH_KH_KEY(key)
 134         {
 135                 if(key.owner)
 136                         STAT(KH_KEYS, key.owner) |= (32 ** key.count) * 31;
 137         }
 138         //print(ftos((nextent(NULL)).kh_state), "\n");
 139 }
 140
 141
 142
 143
 144 var kh_Think_t kh_Controller_Thinkfunc;
 145 void kh_Controller_SetThink(float t, kh_Think_t func)  // runs occasionaly
 146 {
 147         kh_Controller_Thinkfunc = func;
 148         kh_controller.cnt = ceil(t);
 149         if(t == 0)
 150                 kh_controller.nextthink = time; // force
 151 }
 152 void kh_WaitForPlayers();
 153 void kh_Controller_Think(entity this)  // called a lot
 154 {
 155         if(game_stopped)
 156                 return;
 157         if(this.cnt > 0)
 158         {
 159                 if(getthink(this) != kh_WaitForPlayers)
 160                         this.cnt -= 1;
 161         }
 162         else if(this.cnt == 0)
 163         {
 164                 this.cnt -= 1;
 165                 kh_Controller_Thinkfunc();
 166         }
 167         this.nextthink = time + 1;
 168 }
 169
 170 // frags f: take from cvar * f
 171 // frags 0: no frags
 172 void kh_Scores_Event(entity player, entity key, string what, float frags_player, float frags_owner)  // update the score when a key is captured
 173 {
 174         string s;
 175         if(game_stopped)
 176                 return;
 177
 178         if(frags_player)
 179                 UpdateFrags(player, frags_player);
 180
 181         if(key && key.owner && frags_owner)
 182                 UpdateFrags(key.owner, frags_owner);
 183
 184         if(!autocvar_sv_eventlog)  //output extra info to the console or text file
 185                 return;
 186
 187         s = strcat(":keyhunt:", what, ":", ftos(player.playerid), ":", ftos(frags_player));
 188
 189         if(key && key.owner)
 190                 s = strcat(s, ":", ftos(key.owner.playerid));
 191         else
 192                 s = strcat(s, ":0");
 193
 194         s = strcat(s, ":", ftos(frags_owner), ":");
 195
 196         if(key)
 197                 s = strcat(s, key.netname);
 198
 199         GameLogEcho(s);
 200 }
 201
 202 vector kh_AttachedOrigin(entity e)  // runs when a team captures the flag, it can run 2 or 3 times.
 203 {
 204         if(e.tag_entity)
 205         {
 206                 makevectors(e.tag_entity.angles);
 207                 return e.tag_entity.origin + e.origin.x * v_forward - e.origin.y * v_right + e.origin.z * v_up;
 208         }
 209         else
 210                 return e.origin;
 211 }
 212
 213 void kh_Key_Attach(entity key)  // runs when a player picks up a key and several times when a key is assigned to a player at the start of a round
 214 {
 215 #ifdef KH_PLAYER_USE_ATTACHMENT
 216         entity first = key.owner.kh_next;
 217         if(key == first)
 218         {
 219                 setattachment(key, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 220                 if(key.kh_next)
 221                 {
 222                         setattachment(key.kh_next, key, "");
 223                         setorigin(key, key.kh_next.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 224                         setorigin(key.kh_next, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 225                         key.kh_next.angles = '0 0 0';
 226                 }
 227                 else
 228                         setorigin(key, KH_PLAYER_ATTACHMENT);
 229                 key.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 230         }
 231         else
 232         {
 233                 setattachment(key, key.kh_prev, "");
 234                 if(key.kh_next)
 235                         setattachment(key.kh_next, key, "");
 236                 setorigin(key, KH_PLAYER_ATTACHMENT_DIST_ROTATED);
 237                 setorigin(first, first.origin - 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 238                 key.angles = '0 0 0';
 239         }
 240 #else
 241         setattachment(key, key.owner, "");
 242         setorigin(key, '0 0 1' * KH_KEY_ZSHIFT);  // fixing x, y in think
 243         key.angles_y -= key.owner.angles.y;
 244 #endif
 245         key.flags = 0;
 246         if(IL_CONTAINS(g_items, key))
 247                 IL_REMOVE(g_items, key);
 248         key.solid = SOLID_NOT;
 249         set_movetype(key, MOVETYPE_NONE);
 250         key.team = key.owner.team;
 251         key.nextthink = time;
 252         key.damageforcescale = 0;
 253         key.takedamage = DAMAGE_NO;
 254         key.modelindex = kh_key_carried;
 255         navigation_dynamicgoal_unset(key);
 256 }
 257
 258 void kh_Key_Detach(entity key) // runs every time a key is dropped or lost. Runs several times times when all the keys are captured
 259 {
 260 #ifdef KH_PLAYER_USE_ATTACHMENT
 261         entity first = key.owner.kh_next;
 262         if(key == first)
 263         {
 264                 if(key.kh_next)
 265                 {
 266                         setattachment(key.kh_next, key.owner, KH_PLAYER_ATTACHMENT_BONE);
 267                         setorigin(key.kh_next, key.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 268                         key.kh_next.angles = KH_PLAYER_ATTACHMENT_ANGLES;
 269                 }
 270         }
 271         else
 272         {
 273                 if(key.kh_next)
 274                         setattachment(key.kh_next, key.kh_prev, "");
 275                 setorigin(first, first.origin + 0.5 * KH_PLAYER_ATTACHMENT_DIST);
 276         }
 277         // in any case:
 278         setattachment(key, NULL, "");
 279         setorigin(key, key.owner.origin + '0 0 1' * (STAT(PL_MIN, key.owner).z - KH_KEY_MIN_z));
 280         key.angles = key.owner.angles;
 281 #else
 282         setorigin(key, key.owner.origin + key.origin.z * '0 0 1');
 283         setattachment(key, NULL, "");
 284         key.angles_y += key.owner.angles.y;
 285 #endif
 286         key.flags = FL_ITEM;
 287         if(!IL_CONTAINS(g_items, key))
 288                 IL_PUSH(g_items, key);
 289         key.solid = SOLID_TRIGGER;
 290         set_movetype(key, MOVETYPE_TOSS);
 291         key.pain_finished = time + autocvar_g_balance_keyhunt_delay_return;
 292         key.damageforcescale = autocvar_g_balance_keyhunt_damageforcescale;
 293         key.takedamage = DAMAGE_YES;
 294         // let key.team stay
 295         key.modelindex = kh_key_dropped;
 296         navigation_dynamicgoal_set(key, key.owner);
 297         key.kh_previous_owner = key.owner;
 298         key.kh_previous_owner_playerid = key.owner.playerid;
 299 }
 300
 301 void kh_Key_AssignTo(entity key, entity player)  // runs every time a key is picked up or assigned. Runs prior to kh_key_attach
 302 {
 303         if(key.owner == player)
 304                 return;
 305
 306         int ownerteam0 = kh_Key_AllOwnedByWhichTeam();
 307
 308         if(key.owner)
 309         {
 310                 kh_Key_Detach(key);
 311
 312                 // remove from linked list
 313                 if(key.kh_next)
 314                         key.kh_next.kh_prev = key.kh_prev;
 315                 key.kh_prev.kh_next = key.kh_next;
 316                 key.kh_next = NULL;
 317                 key.kh_prev = NULL;
 318
 319                 if(key.owner.kh_next == NULL)
 320                 {
 321                         // No longer a key carrier
 322                         if(!kh_no_radar_circles)
 323                                 WaypointSprite_Ping(key.owner.waypointsprite_attachedforcarrier);
 324                         WaypointSprite_DetachCarrier(key.owner);
 325                 }
 326         }
 327
 328         key.owner = player;
 329
 330         if(player)
 331         {
 332                 // insert into linked list
 333                 key.kh_next = player.kh_next;
 334                 key.kh_prev = player;
 335                 player.kh_next = key;
 336                 if(key.kh_next)
 337                         key.kh_next.kh_prev = key;
 338
 339                 kh_Key_Attach(key);
 340
 341                 if(key.kh_next == NULL)
 342                 {
 343                         // player is now a key carrier
 344                         entity wp = WaypointSprite_AttachCarrier(WP_Null, player, RADARICON_FLAGCARRIER);
 345                         wp.colormod = colormapPaletteColor(player.team - 1, 0);
 346                         player.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_KeyCarrier_waypointsprite_visible_for_player;
 347                         WaypointSprite_UpdateRule(player.waypointsprite_attachedforcarrier, player.team, SPRITERULE_TEAMPLAY);
 348                         if(player.team == NUM_TEAM_1)
 349                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierRed, WP_KeyCarrierFriend, WP_KeyCarrierRed);
 350                         else if(player.team == NUM_TEAM_2)
 351                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierBlue, WP_KeyCarrierFriend, WP_KeyCarrierBlue);
 352                         else if(player.team == NUM_TEAM_3)
 353                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierYellow, WP_KeyCarrierFriend, WP_KeyCarrierYellow);
 354                         else if(player.team == NUM_TEAM_4)
 355                                 WaypointSprite_UpdateSprites(player.waypointsprite_attachedforcarrier, WP_KeyCarrierPink, WP_KeyCarrierFriend, WP_KeyCarrierPink);
 356                         if(!kh_no_radar_circles)
 357                                 WaypointSprite_Ping(player.waypointsprite_attachedforcarrier);
 358                 }
 359         }
 360
 361         // moved that here, also update if there's no player
 362         kh_update_state();
 363
 364         key.pusher = NULL;
 365
 366         int ownerteam = kh_Key_AllOwnedByWhichTeam();
 367         if(ownerteam != ownerteam0)
 368         {
 369                 entity k;
 370                 if(ownerteam != -1)
 371                 {
 372                         kh_interferemsg_time = time + 0.2;
 373                         kh_interferemsg_team = player.team;
 374
 375                         // audit all key carrier sprites, update them to "Run here"
 376                         FOR_EACH_KH_KEY(k)
 377                         {
 378                                 if (!k.owner) continue;
 379                                 entity first = WP_Null;
 380                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, { first = it; break; });
 381                                 entity third = WP_Null;
 382                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, { third = it; break; });
 383                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFinish, third);
 384                         }
 385                 }
 386                 else
 387                 {
 388                         kh_interferemsg_time = 0;
 389
 390                         // audit all key carrier sprites, update them to "Key Carrier"
 391                         FOR_EACH_KH_KEY(k)
 392                         {
 393                                 if (!k.owner) continue;
 394                                 entity first = WP_Null;
 395                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model1, { first = it; break; });
 396                                 entity third = WP_Null;
 397                                 FOREACH(Waypoints, it.netname == k.owner.waypointsprite_attachedforcarrier.model3, { third = it; break; });
 398                                 WaypointSprite_UpdateSprites(k.owner.waypointsprite_attachedforcarrier, first, WP_KeyCarrierFriend, third);
 399                         }
 400                 }
 401         }
 402 }
 403
 404 void kh_Key_Damage(entity this, entity inflictor, entity attacker, float damage, int deathtype, .entity weaponentity, vector hitloc, vector force)
 405 {
 406         if(this.owner)
 407                 return;
 408         if(ITEM_DAMAGE_NEEDKILL(deathtype))
 409         {
 410                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 411                 return;
 412         }
 413         if(force == '0 0 0')
 414                 return;
 415         if(time > this.pushltime)
 416                 if(IS_PLAYER(attacker))
 417                         this.team = attacker.team;
 418 }
 419
 420 void kh_Key_Collect(entity key, entity player)  //a player picks up a dropped key
 421 {
 422         sound(player, CH_TRIGGER, SND_KH_COLLECT, VOL_BASE, ATTEN_NORM);
 423
 424         if(key.kh_dropperteam != player.team)
 425         {
 426                 kh_Scores_Event(player, key, "collect", autocvar_g_balance_keyhunt_score_collect, 0);
 427                 GameRules_scoring_add(player, KH_PICKUPS, 1);
 428         }
 429         key.kh_dropperteam = 0;
 430         int realteam = kh_Team_ByID(key.count);
 431         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PICKUP), player.netname);
 432
 433         kh_Key_AssignTo(key, player); // this also updates .kh_state
 434 }
 435
 436 void kh_Key_Touch(entity this, entity toucher)  // runs many, many times when a key has been dropped and can be picked up
 437 {
 438         if(game_stopped)
 439                 return;
 440
 441         if(this.owner) // already carried
 442                 return;
 443
 444         if(ITEM_TOUCH_NEEDKILL())
 445         {
 446                 this.pain_finished = bound(time, time + autocvar_g_balance_keyhunt_delay_damage_return, this.pain_finished);
 447                 return;
 448         }
 449
 450         if (!IS_PLAYER(toucher))
 451                 return;
 452         if(IS_DEAD(toucher))
 453                 return;
 454         if(toucher == this.enemy)
 455                 if(time < this.kh_droptime + autocvar_g_balance_keyhunt_delay_collect)
 456                         return;  // you just dropped it!
 457         kh_Key_Collect(this, toucher);
 458 }
 459
 460 void kh_Key_Remove(entity key)  // runs after when all the keys have been collected or when a key has been dropped for more than X seconds
 461 {
 462         entity o = key.owner;
 463         kh_Key_AssignTo(key, NULL);
 464         if(o) // it was attached
 465                 WaypointSprite_Kill(key.waypointsprite_attachedforcarrier);
 466         else // it was dropped
 467                 WaypointSprite_DetachCarrier(key);
 468
 469         // remove key from key list
 470         if (kh_worldkeylist == key)
 471                 kh_worldkeylist = kh_worldkeylist.kh_worldkeynext;
 472         else
 473         {
 474                 o = kh_worldkeylist;
 475                 while (o)
 476                 {
 477                         if (o.kh_worldkeynext == key)
 478                         {
 479                                 o.kh_worldkeynext = o.kh_worldkeynext.kh_worldkeynext;
 480                                 break;
 481                         }
 482                         o = o.kh_worldkeynext;
 483                 }
 484         }
 485
 486         delete(key);
 487
 488         kh_update_state();
 489 }
 490
 491 void kh_FinishRound()  // runs when a team captures the keys
 492 {
 493         // prepare next round
 494         kh_interferemsg_time = 0;
 495         entity key;
 496
 497         kh_no_radar_circles = true;
 498         FOR_EACH_KH_KEY(key)
 499                 kh_Key_Remove(key);
 500         kh_no_radar_circles = false;
 501
 502         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 503         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 504 }
 505
 506 void nades_GiveBonus(entity player, float score);
 507
 508 void kh_WinnerTeam(int winner_team)  // runs when a team wins
 509 {
 510         // all key carriers get some points
 511         entity key;
 512         float score = (NumTeams(kh_teams) - 1) * autocvar_g_balance_keyhunt_score_capture;
 513         DistributeEvenly_Init(score, NumTeams(kh_teams));
 514         // twice the score for 3 team games, three times the score for 4 team games!
 515         // note: for a win by destroying the key, this should NOT be applied
 516         FOR_EACH_KH_KEY(key)
 517         {
 518                 float f = DistributeEvenly_Get(1);
 519                 kh_Scores_Event(key.owner, key, "capture", f, 0);
 520                 GameRules_scoring_add_team(key.owner, KH_CAPS, 1);
 521                 nades_GiveBonus(key.owner, autocvar_g_nades_bonus_score_high);
 522         }
 523
 524         bool first = true;
 525         string keyowner = "";
 526         FOR_EACH_KH_KEY(key)
 527                 if(key.owner.kh_next == key)
 528                 {
 529                         if(!first)
 530                                 keyowner = strcat(keyowner, ", ");
 531                         keyowner = key.owner.netname;
 532                         first = false;
 533                 }
 534
 535         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(winner_team, CENTER_ROUND_TEAM_WIN));
 536         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(winner_team, INFO_KEYHUNT_CAPTURE), keyowner);
 537
 538         first = true;
 539         vector firstorigin = '0 0 0', lastorigin = '0 0 0', midpoint = '0 0 0';
 540         FOR_EACH_KH_KEY(key)
 541         {
 542                 vector thisorigin = kh_AttachedOrigin(key);
 543                 //dprint("Key origin: ", vtos(thisorigin), "\n");
 544                 midpoint += thisorigin;
 545
 546                 if(!first)
 547                 {
 548                         // TODO: this effect has been replaced due to a possible crash it causes
 549                         // see https://gitlab.com/xonotic/darkplaces/issues/123
 550                         //te_lightning2(NULL, lastorigin, thisorigin);
 551                         Send_Effect(EFFECT_TR_NEXUIZPLASMA, lastorigin, thisorigin, 1);
 552                 }
 553                 lastorigin = thisorigin;
 554                 if(first)
 555                         firstorigin = thisorigin;
 556                 first = false;
 557         }
 558         if(NumTeams(kh_teams) > 2)
 559         {
 560                 //te_lightning2(NULL, lastorigin, firstorigin); // TODO see above
 561                 Send_Effect(EFFECT_TR_NEXUIZPLASMA, lastorigin, firstorigin, 1);
 562         }
 563         midpoint = midpoint * (1 / NumTeams(kh_teams));
 564         te_customflash(midpoint, 1000, 1, Team_ColorRGB(winner_team) * 0.5 + '0.5 0.5 0.5');  // make the color >=0.5 in each component
 565
 566         play2all(SND(KH_CAPTURE));
 567         kh_FinishRound();
 568 }
 569
 570 void kh_LoserTeam(int loser_team, entity lostkey)  // runs when a player pushes a flag carrier off the map
 571 {
 572         float f;
 573         entity attacker = NULL;
 574         if(lostkey.pusher)
 575                 if(lostkey.pusher.team != loser_team)
 576                         if(IS_PLAYER(lostkey.pusher))
 577                                 attacker = lostkey.pusher;
 578
 579         if(attacker)
 580         {
 581                 if(lostkey.kh_previous_owner)
 582                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "pushed", 0, -autocvar_g_balance_keyhunt_score_push);
 583                         // don't actually GIVE him the -nn points, just log
 584                 kh_Scores_Event(attacker, NULL, "push", autocvar_g_balance_keyhunt_score_push, 0);
 585                 GameRules_scoring_add(attacker, KH_PUSHES, 1);
 586                 //centerprint(attacker, "Your push is the best!"); // does this really need to exist?
 587         }
 588         else
 589         {
 590                 int players = 0;
 591                 float of = autocvar_g_balance_keyhunt_score_destroyed_ownfactor;
 592
 593                 FOREACH_CLIENT(IS_PLAYER(it) && it.team != loser_team, { ++players; });
 594
 595                 entity key;
 596                 int keys = 0;
 597                 FOR_EACH_KH_KEY(key)
 598                         if(key.owner && key.team != loser_team)
 599                                 ++keys;
 600
 601                 if(lostkey.kh_previous_owner)
 602                         kh_Scores_Event(lostkey.kh_previous_owner, NULL, "destroyed", 0, -autocvar_g_balance_keyhunt_score_destroyed);
 603                         // don't actually GIVE him the -nn points, just log
 604
 605                 if(lostkey.kh_previous_owner.playerid == lostkey.kh_previous_owner_playerid)
 606                         GameRules_scoring_add(lostkey.kh_previous_owner, KH_DESTROYS, 1);
 607
 608                 DistributeEvenly_Init(autocvar_g_balance_keyhunt_score_destroyed, keys * of + players);
 609
 610                 FOR_EACH_KH_KEY(key)
 611                         if(key.owner && key.team != loser_team)
 612                         {
 613                                 f = DistributeEvenly_Get(of);
 614                                 kh_Scores_Event(key.owner, NULL, "destroyed_holdingkey", f, 0);
 615                         }
 616
 617                 int fragsleft = DistributeEvenly_Get(players);
 618
 619                 // Now distribute these among all other teams...
 620                 int j = NumTeams(kh_teams) - 1;
 621                 for(int i = 0; i < NumTeams(kh_teams); ++i)
 622                 {
 623                         int thisteam = kh_Team_ByID(i);
 624                         if(thisteam == loser_team) // bad boy, no cookie - this WILL happen
 625                                 continue;
 626
 627                         players = 0;
 628                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, { ++players; });
 629
 630                         DistributeEvenly_Init(fragsleft, j);
 631                         fragsleft = DistributeEvenly_Get(j - 1);
 632                         DistributeEvenly_Init(DistributeEvenly_Get(1), players);
 633
 634                         FOREACH_CLIENT(IS_PLAYER(it) && it.team == thisteam, {
 635                                 f = DistributeEvenly_Get(1);
 636                                 kh_Scores_Event(it, NULL, "destroyed", f, 0);
 637                         });
 638
 639                         --j;
 640                 }
 641         }
 642
 643         int realteam = kh_Team_ByID(lostkey.count);
 644         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, APP_TEAM_NUM(loser_team, CENTER_ROUND_TEAM_LOSS));
 645         if(attacker)
 646                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_PUSHED), attacker.netname, lostkey.kh_previous_owner.netname);
 647         else
 648                 Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DESTROYED), lostkey.kh_previous_owner.netname);
 649
 650         play2all(SND(KH_DESTROY));
 651         te_tarexplosion(lostkey.origin);
 652
 653         kh_FinishRound();
 654 }
 655
 656 void kh_Key_Think(entity this)  // runs all the time
 657 {
 658         if(game_stopped)
 659                 return;
 660
 661         if(this.owner)
 662         {
 663 #ifndef KH_PLAYER_USE_ATTACHMENT
 664                 makevectors('0 1 0' * (this.cnt + (time % 360) * KH_KEY_XYSPEED));
 665                 setorigin(this, v_forward * KH_KEY_XYDIST + '0 0 1' * this.origin.z);
 666 #endif
 667         }
 668
 669         // if in nodrop or time over, end the round
 670         if(!this.owner)
 671                 if(time > this.pain_finished)
 672                         kh_LoserTeam(this.team, this);
 673
 674         if(this.owner)
 675         if(kh_Key_AllOwnedByWhichTeam() != -1)
 676         {
 677                 if(this.siren_time < time)
 678                 {
 679                         sound(this.owner, CH_TRIGGER, SND_KH_ALARM, VOL_BASE, ATTEN_NORM);  // play a simple alarm
 680                         this.siren_time = time + 2.5;  // repeat every 2.5 seconds
 681                 }
 682
 683                 entity key;
 684                 vector p = this.owner.origin;
 685                 FOR_EACH_KH_KEY(key)
 686                         if(vdist(key.owner.origin - p, >, autocvar_g_balance_keyhunt_maxdist))
 687                                 goto not_winning;
 688                 kh_WinnerTeam(this.team);
 689 LABEL(not_winning)
 690         }
 691
 692         if(kh_interferemsg_time && time > kh_interferemsg_time)
 693         {
 694                 kh_interferemsg_time = 0;
 695                 FOREACH_CLIENT(IS_PLAYER(it), {
 696                         if(it.team == kh_interferemsg_team)
 697                         {
 698                                 if(it.kh_next)
 699                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_MEET);
 700                                 else
 701                                         Send_Notification(NOTIF_ONE, it, MSG_CENTER, CENTER_KEYHUNT_HELP);
 702                         }
 703                         else
 704                                 Send_Notification(NOTIF_ONE, it, MSG_CENTER, APP_TEAM_NUM(kh_interferemsg_team, CENTER_KEYHUNT_INTERFERE));
 705                 });
 706         }
 707
 708         this.nextthink = time + 0.05;
 709 }
 710
 711 void key_reset(entity this)
 712 {
 713         kh_Key_AssignTo(this, NULL);
 714         kh_Key_Remove(this);
 715 }
 716
 717 const string STR_ITEM_KH_KEY = "item_kh_key";
 718 void kh_Key_Spawn(entity initial_owner, float _angle, float i)  // runs every time a new flag is created, ie after all the keys have been collected
 719 {
 720         entity key = spawn();
 721         key.count = i;
 722         key.classname = STR_ITEM_KH_KEY;
 723         settouch(key, kh_Key_Touch);
 724         setthink(key, kh_Key_Think);
 725         key.nextthink = time;
 726         key.items = IT_KEY1 | IT_KEY2;
 727         key.cnt = _angle;
 728         key.angles = '0 360 0' * random();
 729         key.event_damage = kh_Key_Damage;
 730         key.takedamage = DAMAGE_YES;
 731         key.damagedbytriggers = autocvar_g_balance_keyhunt_return_when_unreachable;
 732         key.damagedbycontents = autocvar_g_balance_keyhunt_return_when_unreachable;
 733         key.modelindex = kh_key_dropped;
 734         key.model = "key";
 735         key.kh_dropperteam = 0;
 736         key.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 737         setsize(key, KH_KEY_MIN, KH_KEY_MAX);
 738         key.colormod = Team_ColorRGB(initial_owner.team) * KH_KEY_BRIGHTNESS;
 739         key.reset = key_reset;
 740         navigation_dynamicgoal_init(key, false);
 741
 742         switch(initial_owner.team)
 743         {
 744                 case NUM_TEAM_1:
 745                         key.netname = "^1red key";
 746                         break;
 747                 case NUM_TEAM_2:
 748                         key.netname = "^4blue key";
 749                         break;
 750                 case NUM_TEAM_3:
 751                         key.netname = "^3yellow key";
 752                         break;
 753                 case NUM_TEAM_4:
 754                         key.netname = "^6pink key";
 755                         break;
 756                 default:
 757                         key.netname = "NETGIER key";
 758                         break;
 759         }
 760
 761         // link into key list
 762         key.kh_worldkeynext = kh_worldkeylist;
 763         kh_worldkeylist = key;
 764
 765         Send_Notification(NOTIF_ONE, initial_owner, MSG_CENTER, APP_TEAM_NUM(initial_owner.team, CENTER_KEYHUNT_START));
 766
 767         WaypointSprite_Spawn(WP_KeyDropped, 0, 0, key, '0 0 1' * KH_KEY_WP_ZSHIFT, NULL, key.team, key, waypointsprite_attachedforcarrier, false, RADARICON_FLAG);
 768         key.waypointsprite_attachedforcarrier.waypointsprite_visible_for_player = kh_Key_waypointsprite_visible_for_player;
 769
 770         kh_Key_AssignTo(key, initial_owner);
 771 }
 772
 773 // -1 when no team completely owns all keys yet
 774 int kh_Key_AllOwnedByWhichTeam()  // constantly called. check to see if all the keys are owned by the same team
 775 {
 776         entity key;
 777         int teem = -1;
 778         int keys = NumTeams(kh_teams);
 779         FOR_EACH_KH_KEY(key)
 780         {
 781                 if(!key.owner)
 782                         return -1;
 783                 if(teem == -1)
 784                         teem = key.team;
 785                 else if(teem != key.team)
 786                         return -1;
 787                 --keys;
 788         }
 789         if(keys != 0)
 790                 return -1;
 791         return teem;
 792 }
 793
 794 void kh_Key_DropOne(entity key)
 795 {
 796         // prevent collecting this one for some time
 797         entity player = key.owner;
 798
 799         key.kh_droptime = time;
 800         key.enemy = player;
 801
 802         kh_Scores_Event(player, key, "dropkey", 0, 0);
 803         GameRules_scoring_add(player, KH_LOSSES, 1);
 804         int realteam = kh_Team_ByID(key.count);
 805         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_DROP), player.netname);
 806
 807         kh_Key_AssignTo(key, NULL);
 808         makevectors(player.v_angle);
 809         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_throwvelocity * v_forward, false);
 810         key.pusher = NULL;
 811         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 812         key.kh_dropperteam = key.team;
 813
 814         sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 815 }
 816
 817 void kh_Key_DropAll(entity player, float suicide) // runs whenever a player dies
 818 {
 819         if(player.kh_next)
 820         {
 821                 entity mypusher = NULL;
 822                 if(player.pusher)
 823                         if(time < player.pushltime)
 824                                 mypusher = player.pusher;
 825
 826                 entity key;
 827                 while((key = player.kh_next))
 828                 {
 829                         kh_Scores_Event(player, key, "losekey", 0, 0);
 830                         GameRules_scoring_add(player, KH_LOSSES, 1);
 831                         int realteam = kh_Team_ByID(key.count);
 832                         Send_Notification(NOTIF_ALL, NULL, MSG_INFO, APP_TEAM_NUM(realteam, INFO_KEYHUNT_LOST), player.netname);
 833                         kh_Key_AssignTo(key, NULL);
 834                         makevectors('-1 0 0' * (45 + 45 * random()) + '0 360 0' * random());
 835                         key.velocity = W_CalculateProjectileVelocity(player, player.velocity, autocvar_g_balance_keyhunt_dropvelocity * v_forward, false);
 836                         key.pusher = mypusher;
 837                         key.pushltime = time + autocvar_g_balance_keyhunt_protecttime;
 838                         if(suicide)
 839                                 key.kh_dropperteam = player.team;
 840                 }
 841                 sound(player, CH_TRIGGER, SND_KH_DROP, VOL_BASE, ATTEN_NORM);
 842         }
 843 }
 844
 845 int kh_GetMissingTeams()
 846 {
 847         int missing_teams = 0;
 848         for(int i = 0; i < NumTeams(kh_teams); ++i)
 849         {
 850                 int teem = kh_Team_ByID(i);
 851                 int players = 0;
 852                 FOREACH_CLIENT(IS_PLAYER(it), {
 853                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 854                                 ++players;
 855                 });
 856                 if (!players)
 857                         missing_teams |= (2 ** i);
 858         }
 859         return missing_teams;
 860 }
 861
 862 void kh_WaitForPlayers()  // delay start of the round until enough players are present
 863 {
 864         static int prev_missing_teams_mask;
 865         if(time < game_starttime)
 866         {
 867                 if (prev_missing_teams_mask > 0)
 868                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 869                 prev_missing_teams_mask = -1;
 870                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 871                 return;
 872         }
 873
 874         int missing_teams_mask = kh_GetMissingTeams();
 875         if(!missing_teams_mask)
 876         {
 877                 if(prev_missing_teams_mask > 0)
 878                         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 879                 prev_missing_teams_mask = -1;
 880                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_ROUNDSTART, autocvar_g_balance_keyhunt_delay_round);
 881                 kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_round, kh_StartRound);
 882         }
 883         else
 884         {
 885                 if(player_count == 0)
 886                 {
 887                         if(prev_missing_teams_mask > 0)
 888                                 Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_MISSING_TEAMS);
 889                         prev_missing_teams_mask = -1;
 890                 }
 891                 else
 892                 {
 893                         if(prev_missing_teams_mask != missing_teams_mask)
 894                         {
 895                                 Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_MISSING_TEAMS, missing_teams_mask);
 896                                 prev_missing_teams_mask = missing_teams_mask;
 897                         }
 898                 }
 899                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 900         }
 901 }
 902
 903 void kh_EnableTrackingDevice()  // runs after each round
 904 {
 905         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 906         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 907
 908         kh_tracking_enabled = true;
 909 }
 910
 911 void kh_StartRound()  // runs at the start of each round
 912 {
 913         if(time < game_starttime)
 914         {
 915                 kh_Controller_SetThink(game_starttime - time + 0.1, kh_WaitForPlayers);
 916                 return;
 917         }
 918
 919         if(kh_GetMissingTeams())
 920         {
 921                 kh_Controller_SetThink(1, kh_WaitForPlayers);
 922                 return;
 923         }
 924
 925         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT);
 926         Kill_Notification(NOTIF_ALL, NULL, MSG_CENTER, CPID_KEYHUNT_OTHER);
 927
 928         for(int i = 0; i < NumTeams(kh_teams); ++i)
 929         {
 930                 int teem = kh_Team_ByID(i);
 931                 int players = 0;
 932                 entity my_player = NULL;
 933                 FOREACH_CLIENT(IS_PLAYER(it), {
 934                         if(!IS_DEAD(it) && !PHYS_INPUT_BUTTON_CHAT(it) && it.team == teem)
 935                         {
 936                                 ++players;
 937                                 if(random() * players <= 1)
 938                                         my_player = it;
 939                         }
 940                 });
 941                 kh_Key_Spawn(my_player, 360 * i / NumTeams(kh_teams), i);
 942         }
 943
 944         kh_tracking_enabled = false;
 945         Send_Notification(NOTIF_ALL, NULL, MSG_CENTER, CENTER_KEYHUNT_SCAN, autocvar_g_balance_keyhunt_delay_tracking);
 946         kh_Controller_SetThink(autocvar_g_balance_keyhunt_delay_tracking, kh_EnableTrackingDevice);
 947 }
 948
 949 float kh_HandleFrags(entity attacker, entity targ, float f)  // adds to the player score
 950 {
 951         if(attacker == targ)
 952                 return f;
 953
 954         if(targ.kh_next)
 955         {
 956                 if(attacker.team == targ.team)
 957                 {
 958                         int nk = 0;
 959                         for(entity k = targ.kh_next; k != NULL; k = k.kh_next)
 960                                 ++nk;
 961                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", -nk * autocvar_g_balance_keyhunt_score_collect, 0);
 962                 }
 963                 else
 964                 {
 965                         kh_Scores_Event(attacker, targ.kh_next, "carrierfrag", autocvar_g_balance_keyhunt_score_carrierfrag-1, 0);
 966                         GameRules_scoring_add(attacker, KH_KCKILLS, 1);
 967                         // the frag gets added later
 968                 }
 969         }
 970
 971         return f;
 972 }
 973
 974 void kh_Initialize()  // sets up th KH environment
 975 {
 976         // setup variables
 977         kh_teams = autocvar_g_keyhunt_teams_override;
 978         if(kh_teams < 2)
 979                 kh_teams = cvar("g_keyhunt_teams"); // read the cvar directly as it gets written earlier in the same frame
 980         kh_teams = BITS(bound(2, kh_teams, 4));
 981
 982         // make a KH entity for controlling the game
 983         kh_controller = spawn();
 984         setthink(kh_controller, kh_Controller_Think);
 985         kh_Controller_SetThink(0, kh_WaitForPlayers);
 986
 987         setmodel(kh_controller, MDL_KH_KEY);
 988         kh_key_dropped = kh_controller.modelindex;
 989         /*
 990         dprint(vtos(kh_controller.mins));
 991         dprint(vtos(kh_controller.maxs));
 992         dprint("\n");
 993         */
 994 #ifdef KH_PLAYER_USE_CARRIEDMODEL
 995         setmodel(kh_controller, MDL_KH_KEY_CARRIED);
 996         kh_key_carried = kh_controller.modelindex;
 997 #else
 998         kh_key_carried = kh_key_dropped;
 999 #endif
1000
1001         kh_controller.model = "";
1002         kh_controller.modelindex = 0;
1003
1004         kh_ScoreRules(kh_teams);
1005 }
1006
1007 void kh_finalize()
1008 {
1009         // to be called before intermission
1010         kh_FinishRound();
1011         delete(kh_controller);
1012         kh_controller = NULL;
1013 }
1014
1015 // legacy bot role
1016
1017 void(entity this) havocbot_role_kh_carrier;
1018 void(entity this) havocbot_role_kh_defense;
1019 void(entity this) havocbot_role_kh_offense;
1020 void(entity this) havocbot_role_kh_freelancer;
1021
1022
1023 void havocbot_goalrating_kh(entity this, float ratingscale_team, float ratingscale_dropped, float ratingscale_enemy)
1024 {
1025         entity head;
1026         for (head = kh_worldkeylist; head; head = head.kh_worldkeynext)
1027         {
1028                 if(head.owner == this)
1029                         continue;
1030                 if(!kh_tracking_enabled)
1031                 {
1032                         // if it's carried by our team we know about it
1033                         // otherwise we have to see it to know about it
1034                         if(!head.owner || head.team != this.team)
1035                         {
1036                                 traceline(this.origin + this.view_ofs, head.origin, MOVE_NOMONSTERS, this);
1037                                 if (trace_fraction < 1 && trace_ent != head)
1038                                         continue; // skip what I can't see
1039                         }
1040                 }
1041                 if(!head.owner)
1042                         navigation_routerating(this, head, ratingscale_dropped * 10000, 100000);
1043                 else if(head.team == this.team)
1044                         navigation_routerating(this, head.owner, ratingscale_team * 10000, 100000);
1045                 else
1046                         navigation_routerating(this, head.owner, ratingscale_enemy * 10000, 100000);
1047         }
1048
1049         havocbot_goalrating_items(this, 80000, this.origin, 10000);
1050 }
1051
1052 void havocbot_role_kh_carrier(entity this)
1053 {
1054         if(IS_DEAD(this))
1055                 return;
1056
1057         if (!(this.kh_next))
1058         {
1059                 LOG_TRACE("changing role to freelancer");
1060                 this.havocbot_role = havocbot_role_kh_freelancer;
1061                 this.havocbot_role_timeout = 0;
1062                 return;
1063         }
1064
1065         if (navigation_goalrating_timeout(this))
1066         {
1067                 navigation_goalrating_start(this);
1068
1069                 if(kh_Key_AllOwnedByWhichTeam() == this.team)
1070                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // bring home
1071                 else
1072                         havocbot_goalrating_kh(this, 4, 4, 0.5); // play defensively
1073
1074                 navigation_goalrating_end(this);
1075
1076                 navigation_goalrating_timeout_set(this);
1077         }
1078 }
1079
1080 void havocbot_role_kh_defense(entity this)
1081 {
1082         if(IS_DEAD(this))
1083                 return;
1084
1085         if (this.kh_next)
1086         {
1087                 LOG_TRACE("changing role to carrier");
1088                 this.havocbot_role = havocbot_role_kh_carrier;
1089                 this.havocbot_role_timeout = 0;
1090                 return;
1091         }
1092
1093         if (!this.havocbot_role_timeout)
1094                 this.havocbot_role_timeout = time + random() * 10 + 20;
1095         if (time > this.havocbot_role_timeout)
1096         {
1097                 LOG_TRACE("changing role to freelancer");
1098                 this.havocbot_role = havocbot_role_kh_freelancer;
1099                 this.havocbot_role_timeout = 0;
1100                 return;
1101         }
1102
1103         if (navigation_goalrating_timeout(this))
1104         {
1105                 float key_owner_team;
1106                 navigation_goalrating_start(this);
1107
1108                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1109                 if(key_owner_team == this.team)
1110                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend key carriers
1111                 else if(key_owner_team == -1)
1112                         havocbot_goalrating_kh(this, 4, 1, 0.05); // play defensively
1113                 else
1114                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK ANYWAY
1115
1116                 navigation_goalrating_end(this);
1117
1118                 navigation_goalrating_timeout_set(this);
1119         }
1120 }
1121
1122 void havocbot_role_kh_offense(entity this)
1123 {
1124         if(IS_DEAD(this))
1125                 return;
1126
1127         if (this.kh_next)
1128         {
1129                 LOG_TRACE("changing role to carrier");
1130                 this.havocbot_role = havocbot_role_kh_carrier;
1131                 this.havocbot_role_timeout = 0;
1132                 return;
1133         }
1134
1135         if (!this.havocbot_role_timeout)
1136                 this.havocbot_role_timeout = time + random() * 10 + 20;
1137         if (time > this.havocbot_role_timeout)
1138         {
1139                 LOG_TRACE("changing role to freelancer");
1140                 this.havocbot_role = havocbot_role_kh_freelancer;
1141                 this.havocbot_role_timeout = 0;
1142                 return;
1143         }
1144
1145         if (navigation_goalrating_timeout(this))
1146         {
1147                 float key_owner_team;
1148
1149                 navigation_goalrating_start(this);
1150
1151                 key_owner_team = kh_Key_AllOwnedByWhichTeam();
1152                 if(key_owner_team == this.team)
1153                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend anyway
1154                 else if(key_owner_team == -1)
1155                         havocbot_goalrating_kh(this, 0.1, 1, 2); // play offensively
1156                 else
1157                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK! EMERGENCY!
1158
1159                 navigation_goalrating_end(this);
1160
1161                 navigation_goalrating_timeout_set(this);
1162         }
1163 }
1164
1165 void havocbot_role_kh_freelancer(entity this)
1166 {
1167         if(IS_DEAD(this))
1168                 return;
1169
1170         if (this.kh_next)
1171         {
1172                 LOG_TRACE("changing role to carrier");
1173                 this.havocbot_role = havocbot_role_kh_carrier;
1174                 this.havocbot_role_timeout = 0;
1175                 return;
1176         }
1177
1178         if (!this.havocbot_role_timeout)
1179                 this.havocbot_role_timeout = time + random() * 10 + 10;
1180         if (time > this.havocbot_role_timeout)
1181         {
1182                 if (random() < 0.5)
1183                 {
1184                         LOG_TRACE("changing role to offense");
1185                         this.havocbot_role = havocbot_role_kh_offense;
1186                 }
1187                 else
1188                 {
1189                         LOG_TRACE("changing role to defense");
1190                         this.havocbot_role = havocbot_role_kh_defense;
1191                 }
1192                 this.havocbot_role_timeout = 0;
1193                 return;
1194         }
1195
1196         if (navigation_goalrating_timeout(this))
1197         {
1198                 navigation_goalrating_start(this);
1199
1200                 int key_owner_team = kh_Key_AllOwnedByWhichTeam();
1201                 if(key_owner_team == this.team)
1202                         havocbot_goalrating_kh(this, 10, 0.1, 0.05); // defend anyway
1203                 else if(key_owner_team == -1)
1204                         havocbot_goalrating_kh(this, 1, 10, 2); // prefer dropped keys
1205                 else
1206                         havocbot_goalrating_kh(this, 0.1, 0.1, 5); // ATTACK ANYWAY
1207
1208                 navigation_goalrating_end(this);
1209
1210                 navigation_goalrating_timeout_set(this);
1211         }
1212 }
1213
1214
1215 // register this as a mutator
1216
1217 MUTATOR_HOOKFUNCTION(kh, ClientDisconnect)
1218 {
1219         entity player = M_ARGV(0, entity);
1220
1221         kh_Key_DropAll(player, true);
1222 }
1223
1224 MUTATOR_HOOKFUNCTION(kh, MakePlayerObserver)
1225 {
1226         entity player = M_ARGV(0, entity);
1227
1228         kh_Key_DropAll(player, true);
1229 }
1230
1231 MUTATOR_HOOKFUNCTION(kh, PlayerDies)
1232 {
1233         entity frag_attacker = M_ARGV(1, entity);
1234         entity frag_target = M_ARGV(2, entity);
1235
1236         if(frag_target == frag_attacker)
1237                 kh_Key_DropAll(frag_target, true);
1238         else if(IS_PLAYER(frag_attacker))
1239                 kh_Key_DropAll(frag_target, false);
1240         else
1241                 kh_Key_DropAll(frag_target, true);
1242 }
1243
1244 MUTATOR_HOOKFUNCTION(kh, GiveFragsForKill, CBC_ORDER_FIRST)
1245 {
1246         entity frag_attacker = M_ARGV(0, entity);
1247         entity frag_target = M_ARGV(1, entity);
1248         float frag_score = M_ARGV(2, float);
1249         M_ARGV(2, float) = kh_HandleFrags(frag_attacker, frag_target, frag_score);
1250 }
1251
1252 MUTATOR_HOOKFUNCTION(kh, MatchEnd)
1253 {
1254         kh_finalize();
1255 }
1256
1257 MUTATOR_HOOKFUNCTION(kh, TeamBalance_CheckAllowedTeams, CBC_ORDER_EXCLUSIVE)
1258 {
1259         M_ARGV(0, float) = kh_teams;
1260         return true;
1261 }
1262
1263 MUTATOR_HOOKFUNCTION(kh, SpectateCopy)
1264 {
1265         entity spectatee = M_ARGV(0, entity);
1266         entity client = M_ARGV(1, entity);
1267
1268         STAT(KH_KEYS, client) = STAT(KH_KEYS, spectatee);
1269 }
1270
1271 MUTATOR_HOOKFUNCTION(kh, PlayerUseKey)
1272 {
1273         entity player = M_ARGV(0, entity);
1274
1275         if(MUTATOR_RETURNVALUE == 0)
1276         {
1277                 entity k = player.kh_next;
1278                 if(k)
1279                 {
1280                         kh_Key_DropOne(k);
1281                         return true;
1282                 }
1283         }
1284 }
1285
1286 MUTATOR_HOOKFUNCTION(kh, HavocBot_ChooseRole)
1287 {
1288     entity bot = M_ARGV(0, entity);
1289
1290         if(IS_DEAD(bot))
1291                 return true;
1292
1293         float r = random() * 3;
1294         if (r < 1)
1295                 bot.havocbot_role = havocbot_role_kh_offense;
1296         else if (r < 2)
1297                 bot.havocbot_role = havocbot_role_kh_defense;
1298         else
1299                 bot.havocbot_role = havocbot_role_kh_freelancer;
1300
1301         return true;
1302 }
1303
1304 MUTATOR_HOOKFUNCTION(kh, LogDeath_AppendItemCodes)
1305 {
1306         entity player = M_ARGV(0, entity);
1307         if(player.kh_next)
1308                 M_ARGV(1, string) = strcat(M_ARGV(1, string), "K"); // item codes
1309 }
1310
1311 MUTATOR_HOOKFUNCTION(kh, DropSpecialItems)
1312 {
1313         entity frag_target = M_ARGV(0, entity);
1314
1315         kh_Key_DropAll(frag_target, false);
1316 }
1317
1318 MUTATOR_HOOKFUNCTION(kh, reset_map_global)
1319 {
1320         kh_WaitForPlayers(); // takes care of killing the "missing teams" message
1321 }